data/qcsrc/menu-div0test/menu.qc

   1 ///////////////////////////////////////////////
   2 // Menu Source File
   3 ///////////////////////
   4 // This file belongs to dpmod/darkplaces
   5 // AK contains all menu functions (especially the required ones)
   6 ///////////////////////////////////////////////
   7
   8 float mouseButtonsPressed;
   9 vector menuMousePos;
  10 float menuShiftState;
  11 float menuPrevTime;
  12 float menuAlpha;
  13 float prevMenuAlpha;
  14
  15 void SUB_Null() { };
  16
  17 void() m_init =
  18 {
  19         dprint_load();
  20         GameCommand_Init();
  21
  22         draw_setMousePointer("gfx/cursor");
  23
  24         main = spawnMainWindow(); main.configureMainWindow(main);
  25         draw_reset();
  26         main.resizeNotify(main, draw_shift, draw_scale, draw_shift, draw_scale);
  27         main.focused = 1;
  28         menuShiftState = 0;
  29 };
  30
  31 void(float key, float ascii) m_keyup =
  32 {
  33         if(!Menu_Active)
  34                 return;
  35         draw_reset();
  36         main.keyUp(main, key, ascii, menuShiftState);
  37         if(key >= K_MOUSE1 && key <= K_MOUSE10)
  38         {
  39                 --mouseButtonsPressed;
  40                 if(!mouseButtonsPressed)
  41                         main.mouseRelease(main, menuMousePos);
  42                 if(mouseButtonsPressed < 0)
  43                 {
  44                         mouseButtonsPressed = 0;
  45                         print("Warning: released an already released button\n");
  46                 }
  47         }
  48         if(key == K_ALT) menuShiftState -= (menuShiftState & S_ALT);
  49         if(key == K_CTRL) menuShiftState -= (menuShiftState & S_CTRL);
  50         if(key == K_SHIFT) menuShiftState -= (menuShiftState & S_SHIFT);
  51 };
  52
  53 void(float key, float ascii) m_keydown =
  54 {
  55         if(!Menu_Active)
  56                 return;
  57         if(keyGrabber)
  58         {
  59                 entity e;
  60                 e = keyGrabber;
  61                 keyGrabber = NULL;
  62                 e.keyGrabbed(e, key, ascii);
  63         }
  64         else
  65         {
  66                 draw_reset();
  67                 if(!main.keyDown(main, key, ascii, menuShiftState))
  68                         if(key == K_ESCAPE)
  69                                 if(gamestatus & (GAME_ISSERVER | GAME_CONNECTED)) // don't back out to console only
  70                                         m_hide(); // disable menu on unhandled ESC
  71                 if(key >= K_MOUSE1 && key <= K_MOUSE10)
  72                         if(!mouseButtonsPressed)
  73                                 main.mousePress(main, menuMousePos);
  74         }
  75         if(key >= K_MOUSE1 && key <= K_MOUSE10)
  76         {
  77                 ++mouseButtonsPressed;
  78                 if(mouseButtonsPressed > 10)
  79                 {
  80                         mouseButtonsPressed = 10;
  81                         print("Warning: pressed an already pressed button\n");
  82                 }
  83         }
  84         if(key == K_ALT) menuShiftState |= S_ALT;
  85         if(key == K_CTRL) menuShiftState |= S_CTRL;
  86         if(key == K_SHIFT) menuShiftState |= S_SHIFT;
  87 };
  88
  89 void() m_draw =
  90 {
  91         float t;
  92         float realFrametime;
  93         t = gettime();
  94         realFrametime = frametime = min(0.2, t - menuPrevTime);
  95         menuPrevTime = t;
  96
  97         if(Menu_Active)
  98                 if(getkeydest() != KEY_MENU || getmousetarget() != MT_MENU)
  99                         m_hide();
 100
 101         if(cvar("cl_capturevideo"))
 102                 frametime = 1 / cvar("cl_capturevideo_fps"); // make capturevideo work smoothly
 103
 104         prevMenuAlpha = menuAlpha;
 105         if(Menu_Active)
 106                 menuAlpha = min(1, menuAlpha + frametime * 5);
 107         else
 108                 menuAlpha = max(0, menuAlpha - frametime * 5);
 109
 110         if(menuAlpha <= 0)
 111         {
 112                 if(prevMenuAlpha > 0)
 113                         main.initializeDialog(main, main.firstChild);
 114                 return;
 115         }
 116
 117         dprint_load();
 118         gamestatus = 0;
 119         if(isserver())
 120                 gamestatus = gamestatus | GAME_ISSERVER;
 121         if(clientstate() == CS_CONNECTED)
 122                 gamestatus = gamestatus | GAME_CONNECTED;
 123         if(cvar("developer"))
 124                 gamestatus = gamestatus | GAME_DEVELOPER;
 125
 126         draw_reset();
 127         draw_alpha *= menuAlpha;
 128
 129         vector dMouse;
 130         dMouse = getmousepos();
 131         dMouse *= frametime / realFrametime; // for capturevideo
 132         if(dMouse != '0 0 0')
 133         {
 134                 dMouse = globalToBoxSize(dMouse, draw_scale);
 135                 menuMousePos += dMouse * 1; // TODO use a cvar here
 136                 menuMousePos_x = bound(0, menuMousePos_x, 1);
 137                 menuMousePos_y = bound(0, menuMousePos_y, 1);
 138                 if(mouseButtonsPressed)
 139                         main.mouseDrag(main, menuMousePos);
 140                 else
 141                         main.mouseMove(main, menuMousePos);
 142         }
 143         main.draw(main);
 144         draw_drawMousePointer(menuMousePos);
 145 };
 146
 147 void() m_display =
 148 {
 149         Menu_Active = true;
 150
 151         if(mouseButtonsPressed)
 152                 main.mouseRelease(main, menuMousePos);
 153         mouseButtonsPressed = 0;
 154
 155         setkeydest(KEY_MENU);
 156         setmousetarget(MT_MENU);
 157
 158         main.focusEnter(main);
 159 };
 160
 161 void() m_hide =
 162 {
 163         Menu_Active = false;
 164         setkeydest(KEY_GAME);
 165         setmousetarget(MT_CLIENT);
 166
 167         main.focusLeave(main);
 168 };
 169
 170 void() m_toggle =
 171 {
 172         if(Menu_Active)
 173                 m_hide();
 174         else
 175                 m_display();
 176 };
 177
 178 void() m_shutdown =
 179 {
 180         m_hide();
 181 };
 182
 183 void(string itemname) m_goto =
 184 {
 185         entity e;
 186         if(itemname == "")
 187         {
 188                 m_hide();
 189         }
 190         else
 191         {
 192                 e = findstring(NULL, name, itemname);
 193                 if(e && e.parent == main)
 194                 {
 195                         main.initializeDialog(main, e);
 196                         m_display();
 197                 }
 198         }
 199 }