data/qcsrc/menu/nexuiz/dialog_multiplayer_create_mutators.c

   1 #ifdef INTERFACE
   2 CLASS(NexuizMutatorsDialog) EXTENDS(NexuizDialog)
   3         METHOD(NexuizMutatorsDialog, toString, string(entity))
   4         METHOD(NexuizMutatorsDialog, fill, void(entity))
   5         METHOD(NexuizMutatorsDialog, showNotify, void(entity))
   6         METHOD(NexuizMutatorsDialog, close, void(entity))
   7         ATTRIB(NexuizMutatorsDialog, title, string, "Mutators")
   8         ATTRIB(NexuizMutatorsDialog, color, vector, SKINCOLOR_DIALOG_MUTATORS)
   9         ATTRIB(NexuizMutatorsDialog, intendedWidth, float, 0.8)
  10         ATTRIB(NexuizMutatorsDialog, rows, float, 17)
  11         ATTRIB(NexuizMutatorsDialog, columns, float, 6)
  12         ATTRIB(NexuizMutatorsDialog, refilterEntity, entity, NULL)
  13 ENDCLASS(NexuizMutatorsDialog)
  14 #endif
  15
  16 #ifdef IMPLEMENTATION
  17 void showNotifyNexuizMutatorsDialog(entity me)
  18 {
  19         loadAllCvars(me);
  20 }
  21
  22 string weaponarenastring;
  23 string weaponarenastring_cvar;
  24 string WeaponArenaString()
  25 {
  26         string s;
  27         float n, i, j;
  28         entity e;
  29         s = cvar_string("g_weaponarena");
  30         if(s == "0")
  31                 return "";
  32         if(s == "all")
  33                 return "All Weapons Arena";
  34         if(s == "most")
  35                 return "Most Weapons Arena";
  36         if(s == weaponarenastring_cvar)
  37                 return weaponarenastring;
  38         if(weaponarenastring)
  39                 strunzone(weaponarenastring);
  40         if(weaponarenastring_cvar)
  41                 strunzone(weaponarenastring_cvar);
  42
  43         weaponarenastring_cvar = strzone(s);
  44
  45         n = tokenize_sane(s);
  46         s = "";
  47         for(i = 0; i < n; ++i)
  48         {
  49                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  50                 {
  51                         e = get_weaponinfo(j);
  52                         if(argv(i) == e.netname)
  53                                 s = strcat(s, " & ", e.message);
  54                 }
  55         }
  56         s = strcat(substring(s, 3, strlen(s) - 3), " Arena");
  57
  58         weaponarenastring = strzone(s);
  59
  60         return weaponarenastring;
  61 }
  62
  63 string toStringNexuizMutatorsDialog(entity me)
  64 {
  65         string s;
  66         s = "";
  67         if(cvar("g_minstagib"))
  68                 s = strcat(s, ", MinstaGib");
  69         if(cvar("g_nixnex"))
  70                 s = strcat(s, ", NixNex");
  71         if(cvar_string("g_weaponarena") != "0")
  72                 s = strcat(s, ", ", WeaponArenaString());
  73         if(cvar("sv_gravity") < 800)
  74                 s = strcat(s, ", Low gravity");
  75         if(cvar("g_cloaked"))
  76                 s = strcat(s, ", Cloaked");
  77         if(cvar("g_footsteps"))
  78                 s = strcat(s, ", Steps");
  79         if(cvar("g_grappling_hook"))
  80                 s = strcat(s, ", Hook");
  81         if(cvar("g_laserguided_missile"))
  82                 s = strcat(s, ", LG missiles");
  83         if(cvar("g_midair"))
  84                 s = strcat(s, ", Midair");
  85         if(cvar("g_vampire"))
  86                 s = strcat(s, ", Vampire");
  87         if(cvar("g_weapon_stay"))
  88                 s = strcat(s, ", Weapons stay");
  89         if(cvar("g_bloodloss") > 0)
  90                 s = strcat(s, ", Bloodloss");
  91         if(s == "")
  92                 return "None";
  93         else
  94                 return substring(s, 2, strlen(s) - 2);
  95 }
  96
  97
  98
  99 // WARNING: dirty hack. TODO clean this up by putting this behaviour in extra classes.
 100 void loadCvarsLaserWeaponArenaWeaponButton(entity me)
 101 {
 102         tokenize_sane(cvar_string("g_weaponarena"));
 103         me.checked = (argv(0) == me.cvarValue);
 104 }
 105
 106 void saveCvarsLaserWeaponArenaWeaponButton(entity me)
 107 {
 108         string suffix;
 109
 110         suffix = "";
 111         if(me.cvarValue != "laser")
 112                 if(cvar("menu_weaponarena_with_laser"))
 113                         suffix = " laser";
 114         if(me.checked)
 115                 cvar_set("g_weaponarena", strcat(me.cvarValue, suffix));
 116         else
 117                 cvar_set("g_weaponarena", me.cvarOffValue);
 118 }
 119
 120 .void(entity) draw_weaponarena;
 121 .void(entity) saveCvars_weaponarena;
 122 void saveCvarsLaserWeaponArenaLaserButton(entity me)
 123 {
 124         // run the old function
 125         me.saveCvars_weaponarena(me);
 126
 127         me.disabled = ((cvar_string("g_weaponarena") == "0") || (cvar_string("g_weaponarena") == "laser"));
 128
 129         if not(me.disabled)
 130         {
 131                 // check for the laser suffix
 132                 string s;
 133                 s = cvar_string("g_weaponarena");
 134                 if(me.checked && substring(s, strlen(s) - 6, 6) != " laser")
 135                         s = strcat(s, " laser");
 136                 else if(!me.checked && substring(s, strlen(s) - 6, 6) == " laser")
 137                         s = substring(s, 0, strlen(s) - 6);
 138                 cvar_set("g_weaponarena", s);
 139         }
 140 }
 141
 142 void preDrawLaserWeaponArenaLaserButton(entity me)
 143 {
 144         me.disabled = ((cvar_string("g_weaponarena") == "0") || (cvar_string("g_weaponarena") == "laser"));
 145         // run the old function
 146         me.draw_weaponarena(me);
 147 }
 148 // WARNING: end of dirty hack. Do not try this at home.
 149
 150
 151
 152 void fillNexuizMutatorsDialog(entity me)
 153 {
 154         entity e, s, w;
 155         float i, j;
 156         string str, hstr;
 157         me.TR(me);
 158                 me.TD(me, 1, 2, makeNexuizTextLabel(0, "Game mutators:"));
 159         me.TR(me);
 160                 me.TD(me, 1, 2, e = makeNexuizCheckBox(0, "g_cloaked", "Cloaked"));
 161         me.TR(me);
 162                 me.TD(me, 1, 2, e = makeNexuizCheckBox(0, "g_footsteps", "Footsteps"));
 163         me.TR(me);
 164                 me.TD(me, 1, 2, e = makeNexuizCheckBox(0, "g_grappling_hook", "Grappling hook"));
 165         me.TR(me);
 166                 me.TD(me, 1, 2, e = makeNexuizCheckBox(0, "g_laserguided_missile", "Laser guided missiles"));
 167         me.TR(me);
 168                 me.TD(me, 1, 2, e = makeNexuizCheckBox(0, "g_midair", "Midair"));
 169         me.TR(me);
 170                 me.TD(me, 1, 2, e = makeNexuizCheckBox(0, "g_vampire", "Vampire"));
 171         me.TR(me);
 172                 me.TD(me, 1, 2, e = makeNexuizCheckBox(0, "g_weapon_stay", "Weapons stay"));
 173         me.TR(me);
 174                 s = makeNexuizSlider(80, 400, 8, "sv_gravity");
 175                         s.valueDigits = 0;
 176                         s.valueDisplayMultiplier = 0.125; // show gravity in percent
 177                 me.TD(me, 1, 2, e = makeNexuizSliderCheckBox(800, 1, s, "Low gravity"));
 178                         e.savedValue = 200; // good on silvercity
 179         me.TR(me);
 180                 me.TDempty(me, 0.2);
 181                 me.TD(me, 1, 1.8, s);
 182         me.TR(me);
 183                 s = makeNexuizSlider(10, 50, 1, "g_bloodloss");
 184                 me.TD(me, 1, 2, e = makeNexuizSliderCheckBox(0, 1, s, "Blood loss"));
 185         me.TR(me);
 186                 me.TDempty(me, 0.2);
 187                 me.TD(me, 1, 1.8, s);
 188
 189         me.gotoRC(me, 0, 2); me.setFirstColumn(me, me.currentColumn);
 190                 me.TD(me, 1, 4, makeNexuizTextLabel(0, "Weapon arenas:"));
 191         me.TR(me);
 192                 me.TD(me, 1, 4, e = makeNexuizRadioButton(1, string_null, string_null, "Regular (no arena)"));
 193         for(i = WEP_FIRST, j = 0; i <= WEP_LAST; ++i, ++j)
 194         {
 195                 w = get_weaponinfo(i);
 196                 if(j & 1 == 0)
 197                         me.TR(me);
 198                 str = w.netname;
 199                 hstr = w.message;
 200                 me.TD(me, 1, 2, e = makeNexuizRadioButton(1, "g_weaponarena", strzone(str), strzone(hstr)));
 201                         e.cvarOffValue = "0";
 202                         // custom load/save logic that ignores a " laser" suffix, or adds it
 203                         e.loadCvars = loadCvarsLaserWeaponArenaWeaponButton;
 204                         e.saveCvars = saveCvarsLaserWeaponArenaWeaponButton;
 205                         e.loadCvars(e);
 206         }
 207         me.TR(me);
 208                 me.TDempty(me, 0.2);
 209                 me.TD(me, 1, 3.8, e = makeNexuizCheckBox(0, "menu_weaponarena_with_laser", "with laser"));
 210                         // hook the draw function to gray it out
 211                         e.draw_weaponarena = e.draw;
 212                         e.draw = preDrawLaserWeaponArenaLaserButton;
 213                         // hook the save function to notify about the cvar
 214                         e.saveCvars_weaponarena = e.saveCvars;
 215                         e.saveCvars = saveCvarsLaserWeaponArenaLaserButton;
 216         me.TR(me);
 217                 me.TD(me, 1, 4, makeNexuizTextLabel(0, "Special arenas:"));
 218         me.TR(me);
 219                 me.TD(me, 1, 4, e = makeNexuizRadioButton(1, "g_minstagib", string_null, "MinstaGib"));
 220         me.TR(me);
 221                 me.TD(me, 1, 4, e = makeNexuizRadioButton(1, "g_nixnex", string_null, "NixNex"));
 222         me.TR(me);
 223                 me.TDempty(me, 0.2);
 224                 me.TD(me, 1, 3.8, e = makeNexuizCheckBox(0, "g_nixnex_with_laser", "with laser"));
 225                         setDependent(e, "g_nixnex", 1, 1);
 226         me.TR(me);
 227                 me.TD(me, 1, 4, e = makeNexuizRadioButton(1, "g_weaponarena", "all", "All weapons"));
 228                         e.cvarOffValue = "0";
 229
 230         me.gotoRC(me, me.rows - 1, 0);
 231                 me.TD(me, 1, me.columns, e = makeNexuizButton("OK", '0 0 0'));
 232                         e.onClick = Dialog_Close;
 233                         e.onClickEntity = me;
 234 }
 235
 236 void closeNexuizMutatorsDialog(entity me)
 237 {
 238         if(me.refilterEntity)
 239                 me.refilterEntity.refilter(me.refilterEntity);
 240         closeDialog(me);
 241 }
 242 #endif