data/qcsrc/menu/nexuiz/demolist.c

   1 #ifdef INTERFACE
   2 CLASS(NexuizDemoList) EXTENDS(NexuizListBox)
   3     METHOD(NexuizDemoList, configureNexuizDemoList, void(entity))
   4     ATTRIB(NexuizDemoList, rowsPerItem, float, 1)
   5     METHOD(NexuizDemoList, resizeNotify, void(entity, vector, vector, vector, vector))
   6     METHOD(NexuizDemoList, drawListBoxItem, void(entity, float, vector, float))
   7     METHOD(NexuizDemoList, getDemos, void(entity))
   8     METHOD(NexuizDemoList, startDemo, void(entity))
   9     METHOD(NexuizDemoList, demoName, string(entity, float))
  10     METHOD(NexuizDemoList, clickListBoxItem, void(entity, float, vector))
  11     METHOD(NexuizDemoList, keyDown, float(entity, float, float, float))
  12     METHOD(NexuizDemoList, destroy, void(entity))
  13     METHOD(NexuizDemoList, showNotify, void(entity))
  14     ATTRIB(NexuizDemoList, listDemo, float, -1)
  15     ATTRIB(NexuizDemoList, realFontSize, vector, '0 0 0')
  16     ATTRIB(NexuizDemoList, columnNameOrigin, float, 0)
  17     ATTRIB(NexuizDemoList, columnNameSize, float, 0)
  18     ATTRIB(NexuizDemoList, realUpperMargin, float, 0)
  19     ATTRIB(NexuizDemoList, origin, vector, '0 0 0')
  20     ATTRIB(NexuizDemoList, itemAbsSize, vector, '0 0 0')
  21     ATTRIB(NexuizDemoList, lastClickedDemo, float, -1)
  22     ATTRIB(NexuizDemoList, lastClickedTime, float, 0)
  23     ATTRIB(NexuizDemoList, filterString, string, string_null)
  24 ENDCLASS(NexuizDemoList)
  25
  26 entity makeNexuizDemoList();
  27 void StartDemo_Click(entity btn, entity me);
  28 void DemoList_Filter_Change(entity box, entity me);
  29 #endif
  30
  31 #ifdef IMPLEMENTATION
  32
  33 entity makeNexuizDemoList()
  34 {
  35     entity me;
  36     me = spawnNexuizDemoList();
  37     me.configureNexuizDemoList(me);
  38     return me;
  39 }
  40
  41 void configureNexuizDemoListNexuizDemoList(entity me)
  42 {
  43     me.configureNexuizListBox(me);
  44     me.getDemos(me);
  45 }
  46
  47 string demoNameNexuizDemoList(entity me, float i )
  48 {
  49     string s;
  50     s = search_getfilename(me.listDemo, i);
  51     s = substring(s, 6, strlen(s) - 6 - 4);  // demos/, .dem
  52     return s;
  53 }
  54
  55
  56 void getDemosNexuizDemoList(entity me)
  57 {
  58     string s;
  59
  60     if(me.filterString)
  61         //subdirectory in filterString allowed
  62         s=strcat("demos/*", me.filterString, "*.dem");
  63     else
  64         s="demos/*.dem";
  65
  66     //dprint("Search demos with the pattern ", s, "\n");
  67     me.listDemo = search_begin(s, FALSE, TRUE);
  68     if(me.listDemo < 0)
  69         me.nItems=0;
  70     else
  71         me.nItems=search_getsize(me.listDemo);
  72 }
  73
  74 void destroyNexuizDemoList(entity me)
  75 {
  76     search_end(me.listDemo);
  77 }
  78
  79 void resizeNotifyNexuizDemoList(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  80 {
  81     me.origin = absOrigin;
  82     me.itemAbsSize = '0 0 0';
  83     resizeNotifyNexuizListBox(me, relOrigin, relSize, absOrigin, absSize);
  84
  85     me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
  86     me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
  87     me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
  88
  89     me.columnNameOrigin = me.realFontSize_x;
  90     me.columnNameSize = 1 - 2 * me.realFontSize_x;
  91 }
  92
  93 void drawListBoxItemNexuizDemoList(entity me, float i, vector absSize, float isSelected)
  94 {
  95     string s;
  96     if(isSelected)
  97         draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
  98
  99     s = me.demoName(me,i);
 100     s = draw_TextShortenToWidth(s, me.columnNameSize / me.realFontSize_x, 0);
 101     draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0) * me.realFontSize_x)) * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 102 }
 103
 104 void showNotifyNexuizDemoList(entity me)
 105 {
 106     me.getDemos(me);
 107 }
 108
 109 void DemoList_Filter_Change(entity box, entity me)
 110 {
 111     if(me.filterString)
 112         strunzone(me.filterString);
 113
 114     if(box.text != "")
 115         me.filterString = strzone(box.text);
 116     else
 117         me.filterString = string_null;
 118
 119     me.getDemos(me);
 120 }
 121
 122 void startDemoNexuizDemoList(entity me)
 123 {
 124     string s;
 125     s = me.demoName(me,me.selectedItem);
 126     localcmd("playdemo demos/", s, ".dem\nwait\ntogglemenu\n");
 127 }
 128
 129 void StartDemo_Click(entity btn, entity me)
 130 {
 131     me.startDemo(me);
 132 }
 133
 134 void clickListBoxItemNexuizDemoList(entity me, float i, vector where)
 135 {
 136     if(i == me.lastClickedDemo)
 137         if(time < me.lastClickedTime + 0.3)
 138         {
 139             // DOUBLE CLICK!
 140             me.setSelected(me, i);
 141             me.startDemo(me);
 142         }
 143     me.lastClickedDemo = i;
 144     me.lastClickedTime = time;
 145 }
 146
 147 float keyDownNexuizDemoList(entity me, float scan, float ascii, float shift)
 148 {
 149     if(scan == K_ENTER) {
 150         me.startDemo(me);
 151         return 1;
 152     }
 153     else
 154         return keyDownListBox(me, scan, ascii, shift);
 155 }
 156 #endif
 157