data/qcsrc/menu/nexuiz/demolist.c

   1 #ifdef INTERFACE
   2 CLASS(NexuizDemoList) EXTENDS(NexuizListBox)
   3     METHOD(NexuizDemoList, configureNexuizDemoList, void(entity))
   4     ATTRIB(NexuizDemoList, rowsPerItem, float, 1)
   5     METHOD(NexuizDemoList, resizeNotify, void(entity, vector, vector, vector, vector))
   6     METHOD(NexuizDemoList, drawListBoxItem, void(entity, float, vector, float))
   7     METHOD(NexuizDemoList, getDemos, void(entity))
   8     METHOD(NexuizDemoList, startDemo, void(entity))
   9     METHOD(NexuizDemoList, demoName, string(entity, float))
  10     METHOD(NexuizDemoList, clickListBoxItem, void(entity, float, vector))
  11     METHOD(NexuizDemoList, keyDown, float(entity, float, float, float))
  12     METHOD(NexuizDemoList, destroy, void(entity))
  13     ATTRIB(NexuizDemoList, listDemo, float, -1)
  14     ATTRIB(NexuizDemoList, realFontSize, vector, '0 0 0')
  15     ATTRIB(NexuizDemoList, columnNameOrigin, float, 0)
  16     ATTRIB(NexuizDemoList, columnNameSize, float, 0)
  17     ATTRIB(NexuizDemoList, realUpperMargin, float, 0)
  18     ATTRIB(NexuizDemoList, origin, vector, '0 0 0')
  19     ATTRIB(NexuizDemoList, itemAbsSize, vector, '0 0 0')
  20     ATTRIB(NexuizDemoList, lastClickedDemo, float, -1)
  21     ATTRIB(NexuizDemoList, lastClickedTime, float, 0)
  22     ATTRIB(NexuizDemoList, filterString, string, string_null)
  23 ENDCLASS(NexuizDemoList)
  24
  25 entity makeNexuizDemoList();
  26 void StartDemo_Click(entity btn, entity me);
  27 void DemoList_Filter_Change(entity box, entity me);
  28 #endif
  29
  30 #ifdef IMPLEMENTATION
  31
  32 entity makeNexuizDemoList()
  33 {
  34     entity me;
  35     me = spawnNexuizDemoList();
  36     me.configureNexuizDemoList(me);
  37     return me;
  38 }
  39
  40 void configureNexuizDemoListNexuizDemoList(entity me)
  41 {
  42     me.configureNexuizListBox(me);
  43     me.getDemos(me);
  44 }
  45
  46 string demoNameNexuizDemoList(entity me, float i )
  47 {
  48     string s;
  49     s = search_getfilename(me.listDemo, i);
  50     s = substring(s, 6, strlen(s) - 6 - 4);  // demos/, .dem
  51     return s;
  52 }
  53
  54
  55 void getDemosNexuizDemoList(entity me)
  56 {
  57     string s;
  58
  59     if(me.filterString)
  60         //subdirectory in filterString allowed
  61         s=strcat("demos/*", me.filterString, "*.dem");
  62     else
  63         s="demos/*.dem";
  64
  65     //dprint("Search demos with the pattern ", s, "\n");
  66     me.listDemo = search_begin(s, FALSE, TRUE);
  67     if(me.listDemo < 0)
  68         me.nItems=0;
  69     else
  70         me.nItems=search_getsize(me.listDemo);
  71 }
  72
  73 void destroyNexuizDemoList(entity me)
  74 {
  75     search_end(me.listDemo);
  76 }
  77
  78 void resizeNotifyNexuizDemoList(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  79 {
  80     me.origin = absOrigin;
  81     me.itemAbsSize = '0 0 0';
  82     resizeNotifyNexuizListBox(me, relOrigin, relSize, absOrigin, absSize);
  83
  84     me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
  85     me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
  86     me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
  87
  88     me.columnNameOrigin = me.realFontSize_x;
  89     me.columnNameSize = 1 - 2 * me.realFontSize_x;
  90 }
  91
  92 void drawListBoxItemNexuizDemoList(entity me, float i, vector absSize, float isSelected)
  93 {
  94     string s;
  95     if(isSelected)
  96         draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
  97
  98     s = me.demoName(me,i);
  99     s = draw_TextShortenToWidth(s, me.columnNameSize / me.realFontSize_x, 0);
 100     draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0) * me.realFontSize_x)) * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 101 }
 102
 103 void DemoList_Filter_Change(entity box, entity me)
 104 {
 105     if(me.filterString)
 106         strunzone(me.filterString);
 107
 108     if(box.text != "")
 109         me.filterString = strzone(box.text);
 110     else
 111         me.filterString = string_null;
 112
 113     me.getDemos(me);
 114 }
 115
 116 void startDemoNexuizDemoList(entity me)
 117 {
 118     string s;
 119     s = me.demoName(me,me.selectedItem);
 120     localcmd("playdemo demos/", s, ".dem\nwait\ntogglemenu\n");
 121 }
 122
 123 void StartDemo_Click(entity btn, entity me)
 124 {
 125     me.startDemo(me);
 126 }
 127
 128 void clickListBoxItemNexuizDemoList(entity me, float i, vector where)
 129 {
 130     if(i == me.lastClickedDemo)
 131         if(time < me.lastClickedTime + 0.3)
 132         {
 133             // DOUBLE CLICK!
 134             me.setSelected(me, i);
 135             me.startDemo(me);
 136         }
 137     me.lastClickedDemo = i;
 138     me.lastClickedTime = time;
 139 }
 140
 141 float keyDownNexuizDemoList(entity me, float scan, float ascii, float shift)
 142 {
 143     if(scan == K_ENTER) {
 144         me.startDemo(me);
 145         return 1;
 146     }
 147     else
 148         return keyDownListBox(me, scan, ascii, shift);
 149 }
 150 #endif
 151