data/qcsrc/menu/nexuiz/campaign.c

   1 #ifdef INTERFACE
   2 CLASS(NexuizCampaignList) EXTENDS(NexuizListBox)
   3         METHOD(NexuizCampaignList, configureNexuizCampaignList, void(entity))
   4         ATTRIB(NexuizCampaignList, rowsPerItem, float, 10)
   5         METHOD(NexuizCampaignList, draw, void(entity))
   6         METHOD(NexuizCampaignList, drawListBoxItem, void(entity, float, vector, float))
   7         METHOD(NexuizCampaignList, clickListBoxItem, void(entity, float, vector))
   8         METHOD(NexuizCampaignList, resizeNotify, void(entity, vector, vector, vector, vector))
   9         METHOD(NexuizCampaignList, setSelected, void(entity, float))
  10         METHOD(NexuizCampaignList, keyDown, float(entity, float, float, float))
  11         METHOD(NexuizCampaignList, campaignGo, void(entity, float))
  12
  13         ATTRIB(NexuizCampaignList, campaignGlob, float, 0)
  14         ATTRIB(NexuizCampaignList, realFontSize, vector, '0 0 0')
  15         ATTRIB(NexuizCampaignList, columnPreviewOrigin, float, 0)
  16         ATTRIB(NexuizCampaignList, columnPreviewSize, float, 0)
  17         ATTRIB(NexuizCampaignList, columnNameOrigin, float, 0)
  18         ATTRIB(NexuizCampaignList, columnNameSize, float, 0)
  19         ATTRIB(NexuizCampaignList, columnCheckMarkOrigin, float, 0)
  20         ATTRIB(NexuizCampaignList, columnCheckMarkSize, float, 0)
  21         ATTRIB(NexuizCampaignList, checkMarkOrigin, vector, '0 0 0')
  22         ATTRIB(NexuizCampaignList, checkMarkSize, vector, '0 0 0')
  23         ATTRIB(NexuizCampaignList, realUpperMargin1, float, 0)
  24         ATTRIB(NexuizCampaignList, realUpperMargin2, float, 0)
  25
  26         ATTRIB(NexuizCampaignList, lastClickedMap, float, -1)
  27         ATTRIB(NexuizCampaignList, lastClickedTime, float, 0)
  28
  29         ATTRIB(NexuizCampaignList, origin, vector, '0 0 0')
  30         ATTRIB(NexuizCampaignList, itemAbsSize, vector, '0 0 0')
  31         ATTRIB(NexuizCampaignList, emptyLineHeight, float, 0.5)
  32
  33         ATTRIB(NexuizCampaignList, campaignIndex, float, 0)
  34         ATTRIB(NexuizCampaignList, cvarName, string, string_null)
  35         METHOD(NexuizCampaignList, loadCvars, void(entity))
  36         METHOD(NexuizCampaignList, saveCvars, void(entity))
  37
  38         ATTRIB(NexuizCampaignList, buttonNext, entity, NULL)
  39         ATTRIB(NexuizCampaignList, buttonPrev, entity, NULL)
  40         ATTRIB(NexuizCampaignList, labelTitle, entity, NULL)
  41         ATTRIB(NexuizCampaignList, campaignTitle, string, string_null)
  42 ENDCLASS(NexuizCampaignList)
  43 entity makeNexuizCampaignList();
  44 void CampaignList_LoadMap(entity btn, entity me);
  45 void MultiCampaign_Next(entity btn, entity me);
  46 void MultiCampaign_Prev(entity btn, entity me);
  47 #endif
  48
  49 #ifdef IMPLEMENTATION
  50 string campaign_longdesc_wrapped[CAMPAIGN_MAX_ENTRIES];
  51
  52 void rewrapCampaign(float w, float l0, float emptyheight)
  53 {
  54         float i, j;
  55         float n, take, cantake, l;
  56         string r, s;
  57         for(i = 0; i < campaign_entries; ++i)
  58         {
  59                 l = l0;
  60                 if(campaign_longdesc_wrapped[i])
  61                         strunzone(campaign_longdesc_wrapped[i]);
  62                 n = tokenizebyseparator(campaign_longdesc[i], "\n");
  63                 r = "";
  64                 for(j = 0; j < n; ++j)
  65                 {
  66                         s = argv(j);
  67                         if(s == "")
  68                         {
  69                                 l -= emptyheight;
  70                                 r = strcat(r, "\n");
  71                                 continue;
  72                         }
  73                         for(;;)
  74                         {
  75                                 cantake = draw_TextLengthUpToWidth(s, w, 0);
  76                                 if(cantake > 0 && cantake < strlen(s))
  77                                 {
  78                                         take = cantake - 1;
  79                                         while(take > 0 && substring(s, take, 1) != " ")
  80                                                 --take;
  81                                         if(take == 0)
  82                                         {
  83                                                 if(--l < 0) goto toolong;
  84                                                 r = strcat(r, substring(s, 0, cantake), "\n");
  85                                                 s = substring(s, cantake, strlen(s) - cantake);
  86                                         }
  87                                         else
  88                                         {
  89                                                 if(--l < 0) goto toolong;
  90                                                 r = strcat(r, substring(s, 0, take), "\n");
  91                                                 s = substring(s, take + 1, strlen(s) - take);
  92                                         }
  93                                 }
  94                                 else
  95                                 {
  96                                         if(--l < 0) goto toolong;
  97                                         r = strcat(r, s, "\n");
  98                                         break;
  99                                 }
 100                         }
 101                 }
 102                 goto nottoolong;
 103 :toolong
 104                 while(substring(r, strlen(r) - 1, 1) == "\n")
 105                         r = substring(r, 0, strlen(r) - 1);
 106                 r = strcat(r, "...\n");
 107 :nottoolong
 108                 campaign_longdesc_wrapped[i] = strzone(substring(r, 0, strlen(r) - 1));
 109         }
 110 }
 111
 112 entity makeNexuizCampaignList()
 113 {
 114         entity me;
 115         me = spawnNexuizCampaignList();
 116         me.configureNexuizCampaignList(me);
 117         return me;
 118 }
 119 void configureNexuizCampaignListNexuizCampaignList(entity me)
 120 {
 121         me.configureNexuizListBox(me);
 122         me.campaignGlob = search_begin("maps/campaign*.txt", TRUE, TRUE);
 123         me.loadCvars(me);
 124         me.campaignGo(me, 0); // takes care of enabling/disabling buttons too
 125 }
 126
 127 void loadCvarsNexuizCampaignList(entity me)
 128 {
 129         // read campaign cvars
 130         if(campaign_name)
 131                 strunzone(campaign_name);
 132         if(me.cvarName)
 133                 strunzone(me.cvarName);
 134         campaign_name = strzone(cvar_string("g_campaign_name"));
 135         me.cvarName = strzone(strcat("g_campaign", campaign_name, "_index"));
 136         registercvar(me.cvarName, "", 0); // saved by server QC anyway
 137         CampaignFile_Load(0, CAMPAIGN_MAX_ENTRIES);
 138         me.campaignIndex = bound(0, cvar(me.cvarName), campaign_entries);
 139         cvar_set(me.cvarName, ftos(me.campaignIndex));
 140         if(me.columnNameSize)
 141                 rewrapCampaign(me.columnNameSize / me.realFontSize_x, me.rowsPerItem - 3, me.emptyLineHeight);
 142         me.nItems = min(me.campaignIndex + 2, campaign_entries);
 143         me.selectedItem = min(me.campaignIndex, me.nItems - 1);
 144         me.scrollPos = me.nItems * me.itemHeight - 1;
 145         if(me.campaignTitle)
 146                 strunzone(me.campaignTitle);
 147         if(campaign_name == "")
 148                 me.campaignTitle = strzone("Nexuiz Multiplayer Training Campaign");
 149         else
 150                 me.campaignTitle = strzone(strreplace("_", " ", campaign_name));
 151         if(me.labelTitle)
 152                 me.labelTitle.setText(me.labelTitle, me.campaignTitle);
 153 }
 154
 155 void saveCvarsNexuizCampaignList(entity me)
 156 {
 157         // write campaign cvars
 158         // no reason to do this!
 159         // cvar_set("g_campaign_name", campaign_name);
 160         // cvar_set(me.cvarName, ftos(me.campaignIndex)); // NOTE: only server QC does that!
 161 }
 162
 163 void campaignGoNexuizCampaignList(entity me, float step)
 164 {
 165         float canNext, canPrev;
 166         string s;
 167         float i, j, n;
 168
 169         canNext = canPrev = 0;
 170
 171         if(me.campaignGlob >= 0)
 172         {
 173                 n = search_getsize(me.campaignGlob);
 174                 if(n > 0)
 175                 {
 176                         j = -1;
 177                         s = strcat("maps/campaign", campaign_name, ".txt");
 178                         for(i = 0; i < n; ++i)
 179                         {
 180                                 if(search_getfilename(me.campaignGlob, i) == s)
 181                                         j = i;
 182                         }
 183                         if(j < 0)
 184                         {
 185                                 if(step >= 0)
 186                                         j = 0;
 187                                 else
 188                                         j = n - 1;
 189                         }
 190                         else
 191                                 j = mod(j + step, n);
 192                         s = search_getfilename(me.campaignGlob, j);
 193                         print(s, "\n");
 194                         s = substring(s, 13, strlen(s) - 17);
 195                         cvar_set("g_campaign_name", s);
 196                         me.loadCvars(me);
 197                 }
 198         }
 199
 200         if(me.buttonNext)
 201                 me.buttonNext.disabled = !canNext;
 202         if(me.buttonPrev)
 203                 me.buttonPrev.disabled = !canPrev;
 204 }
 205
 206 void MultiCampaign_Next(entity btn, entity me)
 207 {
 208         me.campaignGo(me, +1);
 209 }
 210 void MultiCampaign_Prev(entity btn, entity me)
 211 {
 212         me.campaignGo(me, -1);
 213 }
 214
 215 void drawNexuizCampaignList(entity me)
 216 {
 217         if(cvar(me.cvarName) != me.campaignIndex || cvar_string("g_campaign_name") != campaign_name)
 218                 me.loadCvars(me);
 219         drawListBox(me);
 220 }
 221
 222 void resizeNotifyNexuizCampaignList(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 223 {
 224         me.origin = absOrigin;
 225         me.itemAbsSize = '0 0 0';
 226         resizeNotifyNexuizListBox(me, relOrigin, relSize, absOrigin, absSize);
 227
 228         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
 229         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
 230         me.realUpperMargin1 = 0.5 * me.realFontSize_y;
 231         me.realUpperMargin2 = me.realUpperMargin1 + 2 * me.realFontSize_y;
 232
 233         me.checkMarkSize = (eX * (me.itemAbsSize_y / me.itemAbsSize_x) + eY) * 0.5;
 234
 235         me.columnPreviewOrigin = 0;
 236         me.columnPreviewSize = me.itemAbsSize_y / me.itemAbsSize_x * 4 / 3;
 237         me.columnCheckMarkSize = me.checkMarkSize_x;
 238         me.columnNameSize = 1 - me.columnPreviewSize - me.columnCheckMarkSize - 4 * me.realFontSize_x;
 239         me.columnNameOrigin = me.columnPreviewOrigin + me.columnPreviewSize + me.realFontSize_x;
 240         me.columnCheckMarkOrigin = me.columnNameOrigin + me.columnNameSize + me.realFontSize_x * 2;
 241
 242         me.checkMarkOrigin = eY + eX * (me.columnCheckMarkOrigin + me.columnCheckMarkSize) - me.checkMarkSize;
 243
 244         rewrapCampaign(me.columnNameSize / me.realFontSize_x, me.rowsPerItem - 3, me.emptyLineHeight);
 245 }
 246 void clickListBoxItemNexuizCampaignList(entity me, float i, vector where)
 247 {
 248         if(i == me.lastClickedMap)
 249                 if(time < me.lastClickedTime + 0.3)
 250                 {
 251                         // DOUBLE CLICK!
 252                         // start game
 253                         CampaignList_LoadMap(me, me);
 254                         return;
 255                 }
 256         me.lastClickedMap = i;
 257         me.lastClickedTime = time;
 258 }
 259 void drawListBoxItemNexuizCampaignList(entity me, float i, vector absSize, float isSelected)
 260 {
 261         string s;
 262         float p;
 263         vector theColor;
 264         float theAlpha;
 265         float j, n;
 266         vector o;
 267
 268         if(i < me.campaignIndex)
 269         {
 270                 theAlpha = SKINALPHA_CAMPAIGN_SELECTABLE;
 271                 theColor = SKINCOLOR_CAMPAIGN_SELECTABLE;
 272         }
 273         else if(i == me.campaignIndex)
 274         {
 275                 theAlpha = SKINALPHA_CAMPAIGN_CURRENT;
 276                 theColor = SKINCOLOR_CAMPAIGN_CURRENT;
 277         }
 278         else
 279         {
 280                 theAlpha = SKINALPHA_CAMPAIGN_FUTURE;
 281                 theColor = SKINCOLOR_CAMPAIGN_FUTURE;
 282         }
 283
 284         if(isSelected)
 285                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 286
 287         s = ftos(p);
 288         draw_Picture(me.columnPreviewOrigin * eX, strcat("/maps/", campaign_mapname[i]), me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 289         if(i < me.campaignIndex)
 290                 draw_Picture(me.checkMarkOrigin, "checkmark", me.checkMarkSize, '1 1 1', 1);
 291         if(i <= me.campaignIndex)
 292                 s = campaign_shortdesc[i]; // fteqcc sucks
 293         else
 294                 s = "???";
 295         s = draw_TextShortenToWidth(strcat("Level ", ftos(i + 1), ": ", s), me.columnNameSize / me.realFontSize_x, 0);
 296         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0) * me.realFontSize_x)) * eX, s, me.realFontSize, theColor, theAlpha, 0);
 297
 298         if(i <= me.campaignIndex)
 299         {
 300                 s = campaign_longdesc_wrapped[i];
 301                 n = tokenizebyseparator(s, "\n");
 302                 o = me.realUpperMargin2 * eY + me.columnNameOrigin * eX;
 303                 for(j = 0; j < n; ++j)
 304                         if(argv(j) != "")
 305                         {
 306                                 draw_Text(o, argv(j), me.realFontSize, theColor, theAlpha * SKINALPHA_CAMPAIGN_DESCRIPTION, 0);
 307                                 o_y += me.realFontSize_y;
 308                         }
 309                         else
 310                                 o_y += me.realFontSize_y * me.emptyLineHeight;
 311         }
 312 }
 313 void CampaignList_LoadMap(entity btn, entity me)
 314 {
 315         if(me.selectedItem >= me.nItems || me.selectedItem < 0)
 316                 return;
 317         CampaignSetup(me.selectedItem);
 318 }
 319
 320 void setSelectedNexuizCampaignList(entity me, float i)
 321 {
 322         // prevent too late items from being played
 323         setSelectedListBox(me, min(i, me.campaignIndex));
 324 }
 325
 326 float keyDownNexuizCampaignList(entity me, float scan, float ascii, float shift)
 327 {
 328         if(scan == K_ENTER || scan == K_SPACE)
 329                 CampaignList_LoadMap(me, me);
 330         else
 331                 return keyDownListBox(me, scan, ascii, shift);
 332         return 1;
 333 }
 334 #endif