data/qcsrc/menu/item/label.c

   1 #ifdef INTERFACE
   2 CLASS(Label) EXTENDS(Item)
   3         METHOD(Label, configureLabel, void(entity, string, float, float))
   4         METHOD(Label, draw, void(entity))
   5         METHOD(Label, resizeNotify, void(entity, vector, vector, vector, vector))
   6         METHOD(Label, setText, void(entity, string))
   7         METHOD(Label, toString, string(entity))
   8         ATTRIB(Label, text, string, string_null)
   9         ATTRIB(Label, fontSize, float, 8)
  10         ATTRIB(Label, align, float, 0.5)
  11         ATTRIB(Label, allowCut, float, 0)
  12         ATTRIB(Label, keepspaceLeft, float, 0) // for use by subclasses (radiobuttons for example)
  13         ATTRIB(Label, keepspaceRight, float, 0)
  14         ATTRIB(Label, marginLeft, float, 0) // alternate way to specify keepspace* (in characters from the font)
  15         ATTRIB(Label, marginRight, float, 0)
  16         ATTRIB(Label, realFontSize, vector, '0 0 0')
  17         ATTRIB(Label, realOrigin, vector, '0 0 0')
  18         ATTRIB(Label, alpha, float, 0.7)
  19         ATTRIB(Label, colorL, vector, '1 1 1')
  20         ATTRIB(Label, disabled, float, 0)
  21         ATTRIB(Label, disabledAlpha, float, 0.3)
  22         ATTRIB(Label, textEntity, entity, NULL)
  23 ENDCLASS(Label)
  24 #endif
  25
  26 #ifdef IMPLEMENTATION
  27 string toStringLabel(entity me)
  28 {
  29         return me.text;
  30 }
  31 void setTextLabel(entity me, string txt)
  32 {
  33         me.text = txt;
  34         me.realOrigin_x = me.align * (1 - me.keepspaceLeft - me.keepspaceRight - min(me.realFontSize_x * draw_TextWidth(me.text, 0), (1 - me.keepspaceLeft - me.keepspaceRight))) + me.keepspaceLeft;
  35 }
  36 void resizeNotifyLabel(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  37 {
  38         // absSize_y is height of label
  39         me.realFontSize_y = me.fontSize / absSize_y;
  40         me.realFontSize_x = me.fontSize / absSize_x;
  41         if(me.marginLeft)
  42                 me.keepspaceLeft = me.marginLeft * me.realFontSize_x;
  43         if(me.marginRight)
  44                 me.keepspaceRight = me.marginRight * me.realFontSize_x;
  45         me.realOrigin_x = me.align * (1 - me.keepspaceLeft - me.keepspaceRight - min(me.realFontSize_x * draw_TextWidth(me.text, 0), (1 - me.keepspaceLeft - me.keepspaceRight))) + me.keepspaceLeft;
  46         me.realOrigin_y = 0.5 * (1 - me.realFontSize_y);
  47 }
  48 void configureLabelLabel(entity me, string txt, float sz, float algn)
  49 {
  50         me.fontSize = sz;
  51         me.align = algn;
  52         me.setText(me, txt);
  53 }
  54 void drawLabel(entity me)
  55 {
  56         string t;
  57         if(me.disabled)
  58                 draw_alpha *= me.disabledAlpha;
  59
  60         if(me.textEntity)
  61         {
  62                 t = me.textEntity.toString(me.textEntity);
  63                 me.realOrigin_x = me.align * (1 - me.keepspaceLeft - me.keepspaceRight - min(me.realFontSize_x * draw_TextWidth(t, 0), (1 - me.keepspaceLeft - me.keepspaceRight))) + me.keepspaceLeft;
  64         }
  65         else
  66                 t = me.text;
  67
  68         if(me.fontSize)
  69                 if(t)
  70                 {
  71                         if(me.allowCut)
  72                                 draw_Text(me.realOrigin, draw_TextShortenToWidth(t, (1 - me.keepspaceLeft - me.keepspaceRight) / me.realFontSize_x, 0), me.realFontSize, me.colorL, me.alpha, 0);
  73                         else
  74                                 draw_Text(me.realOrigin, t, me.realFontSize, me.colorL, me.alpha, 0);
  75                 }
  76 }
  77 #endif