data/qcsrc/common/util.qc

   1 string wordwrap_buffer;
   2
   3 void wordwrap_buffer_put(string s)
   4 {
   5         wordwrap_buffer = strcat(wordwrap_buffer, s);
   6 }
   7
   8 string wordwrap(string s, float l)
   9 {
  10         string r;
  11         wordwrap_buffer = "";
  12         wordwrap_cb(s, l, wordwrap_buffer_put);
  13         r = wordwrap_buffer;
  14         wordwrap_buffer = "";
  15         return r;
  16 }
  17
  18 #ifndef MENUQC
  19 #ifndef CSQC
  20 void wordwrap_buffer_sprint(string s)
  21 {
  22         wordwrap_buffer = strcat(wordwrap_buffer, s);
  23         if(s == "\n")
  24         {
  25                 sprint(self, wordwrap_buffer);
  26                 wordwrap_buffer = "";
  27         }
  28 }
  29
  30 void wordwrap_sprint(string s, float l)
  31 {
  32         wordwrap_buffer = "";
  33         wordwrap_cb(s, l, wordwrap_buffer_sprint);
  34         if(wordwrap_buffer != "")
  35                 sprint(self, strcat(wordwrap_buffer, "\n"));
  36         wordwrap_buffer = "";
  37         return;
  38 }
  39 #endif
  40 #endif
  41
  42 string unescape(string in)
  43 {
  44         local float i, len;
  45         local string str, s;
  46
  47         // but it doesn't seem to be necessary in my tests at least
  48         in = strzone(in);
  49
  50         len = strlen(in);
  51         str = "";
  52         for(i = 0; i < len; ++i)
  53         {
  54                 s = substring(in, i, 1);
  55                 if(s == "\\")
  56                 {
  57                         s = substring(in, i+1, 1);
  58                         if(s == "n")
  59                                 str = strcat(str, "\n");
  60                         else if(s == "\\")
  61                                 str = strcat(str, "\\");
  62                         else
  63                                 str = strcat(str, substring(in, i, 2));
  64                         ++i;
  65                 } else
  66                         str = strcat(str, s);
  67         }
  68
  69         strunzone(in);
  70         return str;
  71 }
  72
  73 void wordwrap_cb(string s, float l, void(string) callback)
  74 {
  75         local string c;
  76         local float lleft, i, j, wlen;
  77
  78         s = strzone(s);
  79         lleft = l;
  80         for (i = 0;i < strlen(s);++i)
  81         {
  82                 if (substring(s, i, 2) == "\\n")
  83                 {
  84                         callback("\n");
  85                         lleft = l;
  86                         ++i;
  87                 }
  88                 else if (substring(s, i, 1) == "\n")
  89                 {
  90                         callback("\n");
  91                         lleft = l;
  92                 }
  93                 else if (substring(s, i, 1) == " ")
  94                 {
  95                         if (lleft > 0)
  96                         {
  97                                 callback(" ");
  98                                 lleft = lleft - 1;
  99                         }
 100                 }
 101                 else
 102                 {
 103                         for (j = i+1;j < strlen(s);++j)
 104                                 //    ^^ this skips over the first character of a word, which
 105                                 //       is ALWAYS part of the word
 106                                 //       this is safe since if i+1 == strlen(s), i will become
 107                                 //       strlen(s)-1 at the end of this block and the function
 108                                 //       will terminate. A space can't be the first character we
 109                                 //       read here, and neither can a \n be the start, since these
 110                                 //       two cases have been handled above.
 111                         {
 112                                 c = substring(s, j, 1);
 113                                 if (c == " ")
 114                                         break;
 115                                 if (c == "\\")
 116                                         break;
 117                                 if (c == "\n")
 118                                         break;
 119                                 // we need to keep this tempstring alive even if substring is
 120                                 // called repeatedly, so call strcat even though we're not
 121                                 // doing anything
 122                                 callback("");
 123                         }
 124                         wlen = j - i;
 125                         if (lleft < wlen)
 126                         {
 127                                 callback("\n");
 128                                 lleft = l;
 129                         }
 130                         callback(substring(s, i, wlen));
 131                         lleft = lleft - wlen;
 132                         i = j - 1;
 133                 }
 134         }
 135         strunzone(s);
 136 }
 137
 138 float dist_point_line(vector p, vector l0, vector ldir)
 139 {
 140         ldir = normalize(ldir);
 141
 142         // remove the component in line direction
 143         p = p - (p * ldir) * ldir;
 144
 145         // vlen of the remaining vector
 146         return vlen(p);
 147 }
 148
 149 void depthfirst(entity start, .entity up, .entity downleft, .entity right, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
 150 {
 151         entity e;
 152         e = start;
 153         funcPre(pass, e);
 154         while(e.downleft)
 155         {
 156                 e = e.downleft;
 157                 funcPre(pass, e);
 158         }
 159         funcPost(pass, e);
 160         while(e != start)
 161         {
 162                 if(e.right)
 163                 {
 164                         e = e.right;
 165                         funcPre(pass, e);
 166                         while(e.downleft)
 167                         {
 168                                 e = e.downleft;
 169                                 funcPre(pass, e);
 170                         }
 171                 }
 172                 else
 173                         e = e.up;
 174                 funcPost(pass, e);
 175         }
 176 }
 177
 178 float median(float a, float b, float c)
 179 {
 180         if(a < c)
 181                 return bound(a, b, c);
 182         return bound(c, b, a);
 183 }
 184
 185 // converts a number to a string with the indicated number of decimals
 186 // works for up to 10 decimals!
 187 string ftos_decimals(float number, float decimals)
 188 {
 189         string result;
 190         string tmp;
 191         float len;
 192
 193         // if negative, cut off the sign first
 194         if(number < 0)
 195                 return strcat("-", ftos_decimals(-number, decimals));
 196         // it now is always positive!
 197
 198         // 3.516 -> 352
 199         number = floor(number * pow(10, decimals) + 0.5);
 200
 201         // 352 -> "352"
 202         result = ftos(number);
 203         len = strlen(result);
 204         // does it have a decimal point (should not happen)? If there is one, it is always at len-7)
 205                 // if ftos had messed it up, which should never happen: "34278.000000"
 206         if(len >= 7)
 207                 if(substring(result, len - 7, 1) == ".")
 208                 {
 209                         dprint("ftos(integer) has comma? Can't be. Affected result: ", result, "\n");
 210                         result = substring(result, 0, len - 7);
 211                         len -= 7;
 212                 }
 213                 // "34278"
 214         if(decimals == 0)
 215                 return result; // don't insert a point for zero decimals
 216         // is it too short? If yes, insert leading zeroes
 217         if(len <= decimals)
 218         {
 219                 result = strcat(substring("0000000000", 0, decimals - len + 1), result);
 220                 len = decimals + 1;
 221         }
 222         // and now... INSERT THE POINT!
 223         tmp = substring(result, len - decimals, decimals);
 224         result = strcat(substring(result, 0, len - decimals), ".", tmp);
 225         return result;
 226 }
 227
 228 float time;
 229 vector colormapPaletteColor(float c, float isPants)
 230 {
 231         switch(c)
 232         {
 233                 case  0: return '0.800000 0.800000 0.800000';
 234                 case  1: return '0.600000 0.400000 0.000000';
 235                 case  2: return '0.000000 1.000000 0.501961';
 236                 case  3: return '0.000000 1.000000 0.000000';
 237                 case  4: return '1.000000 0.000000 0.000000';
 238                 case  5: return '0.000000 0.501961 1.000000';
 239                 case  6: return '0.000000 1.000000 1.000000';
 240                 case  7: return '0.501961 1.000000 0.000000';
 241                 case  8: return '0.501961 0.000000 1.000000';
 242                 case  9: return '1.000000 0.000000 1.000000';
 243                 case 10: return '1.000000 0.000000 0.501961';
 244                 case 11: return '0.600000 0.600000 0.600000';
 245                 case 12: return '1.000000 1.000000 0.000000';
 246                 case 13: return '0.000000 0.000000 1.000000';
 247                 case 14: return '1.000000 0.501961 0.000000';
 248                 case 15:
 249                         if(isPants)
 250                                 return
 251                                           '1 0 0' * (0.502 + 0.498 * sin(time / 2.7182818285 + 0.0000000000))
 252                                         + '0 1 0' * (0.502 + 0.498 * sin(time / 2.7182818285 + 2.0943951024))
 253                                         + '0 0 1' * (0.502 + 0.498 * sin(time / 2.7182818285 + 4.1887902048));
 254                         else
 255                                 return
 256                                           '1 0 0' * (0.502 + 0.498 * sin(time / 3.1415926536 + 5.2359877560))
 257                                         + '0 1 0' * (0.502 + 0.498 * sin(time / 3.1415926536 + 3.1415926536))
 258                                         + '0 0 1' * (0.502 + 0.498 * sin(time / 3.1415926536 + 1.0471975512));
 259                 default: return '0.000 0.000 0.000';
 260         }
 261 }
 262
 263 // unzone the string, and return it as tempstring. Safe to be called on string_null
 264 string fstrunzone(string s)
 265 {
 266         string sc;
 267         if not(s)
 268                 return s;
 269         sc = strcat(s, "");
 270         strunzone(s);
 271         return sc;
 272 }
 273
 274 // Databases (hash tables)
 275 #define DB_BUCKETS 8192
 276 void db_save(float db, string pFilename)
 277 {
 278         float fh, i, n;
 279         fh = fopen(pFilename, FILE_WRITE);
 280         if(fh < 0)
 281         {
 282                 print(strcat("^1Can't write DB to ", pFilename));
 283                 return;
 284         }
 285         n = buf_getsize(db);
 286         fputs(fh, strcat(ftos(DB_BUCKETS), "\n"));
 287         for(i = 0; i < n; ++i)
 288                 fputs(fh, strcat(bufstr_get(db, i), "\n"));
 289         fclose(fh);
 290 }
 291
 292 float db_create()
 293 {
 294         return buf_create();
 295 }
 296
 297 float db_load(string pFilename)
 298 {
 299         float db, fh, i, j, n;
 300         string l;
 301         db = buf_create();
 302         if(db < 0)
 303                 return -1;
 304         fh = fopen(pFilename, FILE_READ);
 305         if(fh < 0)
 306                 return db;
 307         if(stof(fgets(fh)) == DB_BUCKETS)
 308         {
 309                 i = 0;
 310                 while((l = fgets(fh)))
 311                 {
 312                         if(l != "")
 313                                 bufstr_set(db, i, l);
 314                         ++i;
 315                 }
 316         }
 317         else
 318         {
 319                 // different count of buckets?
 320                 // need to reorganize the database then (SLOW)
 321                 while((l = fgets(fh)))
 322                 {
 323                         n = tokenizebyseparator(l, "\\");
 324                         for(j = 2; j < n; j += 2)
 325                                 db_put(db, argv(j-1), uri_unescape(argv(j)));
 326                 }
 327         }
 328         fclose(fh);
 329         return db;
 330 }
 331
 332 void db_dump(float db, string pFilename)
 333 {
 334         float fh, i, j, n, m;
 335         fh = fopen(pFilename, FILE_WRITE);
 336         if(fh < 0)
 337                 error(strcat("Can't dump DB to ", pFilename));
 338         n = buf_getsize(db);
 339         fputs(fh, "0\n");
 340         for(i = 0; i < n; ++i)
 341         {
 342                 m = tokenizebyseparator(bufstr_get(db, i), "\\");
 343                 for(j = 2; j < m; j += 2)
 344                         fputs(fh, strcat("\\", argv(j-1), "\\", argv(j), "\n"));
 345         }
 346         fclose(fh);
 347 }
 348
 349 void db_close(float db)
 350 {
 351         buf_del(db);
 352 }
 353
 354 string db_get(float db, string pKey)
 355 {
 356         float h;
 357         h = mod(crc16(FALSE, pKey), DB_BUCKETS);
 358         return uri_unescape(infoget(bufstr_get(db, h), pKey));
 359 }
 360
 361 void db_put(float db, string pKey, string pValue)
 362 {
 363         float h;
 364         h = mod(crc16(FALSE, pKey), DB_BUCKETS);
 365         bufstr_set(db, h, infoadd(bufstr_get(db, h), pKey, uri_escape(pValue)));
 366 }
 367
 368 void db_test()
 369 {
 370         float db, i;
 371         print("LOAD...\n");
 372         db = db_load("foo.db");
 373         print("LOADED. FILL...\n");
 374         for(i = 0; i < DB_BUCKETS; ++i)
 375                 db_put(db, ftos(random()), "X");
 376         print("FILLED. SAVE...\n");
 377         db_save(db, "foo.db");
 378         print("SAVED. CLOSE...\n");
 379         db_close(db);
 380         print("CLOSED.\n");
 381 }
 382
 383 // Multiline text file buffers
 384 float buf_load(string pFilename)
 385 {
 386         float buf, fh, i;
 387         string l;
 388         buf = buf_create();
 389         if(buf < 0)
 390                 return -1;
 391         fh = fopen(pFilename, FILE_READ);
 392         if(fh < 0)
 393                 return buf;
 394         i = 0;
 395         while((l = fgets(fh)))
 396         {
 397                 bufstr_set(buf, i, l);
 398                 ++i;
 399         }
 400         fclose(fh);
 401         return buf;
 402 }
 403
 404 void buf_save(float buf, string pFilename)
 405 {
 406         float fh, i, n;
 407         fh = fopen(pFilename, FILE_WRITE);
 408         if(fh < 0)
 409                 error(strcat("Can't write buf to ", pFilename));
 410         n = buf_getsize(buf);
 411         for(i = 0; i < n; ++i)
 412                 fputs(fh, strcat(bufstr_get(buf, i), "\n"));
 413         fclose(fh);
 414 }
 415
 416 string GametypeNameFromType(float g)
 417 {
 418         if      (g == GAME_DEATHMATCH) return "dm";
 419         else if (g == GAME_TEAM_DEATHMATCH) return "tdm";
 420         else if (g == GAME_DOMINATION) return "dom";
 421         else if (g == GAME_CTF) return "ctf";
 422         else if (g == GAME_RUNEMATCH) return "rune";
 423         else if (g == GAME_LMS) return "lms";
 424         else if (g == GAME_ARENA) return "arena";
 425         else if (g == GAME_KEYHUNT) return "kh";
 426         else if (g == GAME_ONSLAUGHT) return "ons";
 427         else if (g == GAME_ASSAULT) return "as";
 428         else if (g == GAME_RACE) return "race";
 429         return "dm";
 430 }
 431
 432 string mmsss(float tenths)
 433 {
 434         float minutes;
 435         string s;
 436         tenths = floor(tenths + 0.5);
 437         minutes = floor(tenths / 600);
 438         tenths -= minutes * 600;
 439         s = ftos(1000 + tenths);
 440         return strcat(ftos(minutes), ":", substring(s, 1, 2), ".", substring(s, 3, 1));
 441 }
 442
 443 string ScoreString(float pFlags, float pValue)
 444 {
 445         string valstr;
 446         float l;
 447
 448         pValue = floor(pValue + 0.5); // round
 449
 450         if((pValue == 0) && (pFlags & (SFL_HIDE_ZERO | SFL_RANK | SFL_TIME)))
 451                 valstr = "";
 452         else if(pFlags & SFL_RANK)
 453         {
 454                 valstr = ftos(pValue);
 455                 l = strlen(valstr);
 456                 if((l >= 2) && (substring(valstr, l - 2, 1) == "1"))
 457                         valstr = strcat(valstr, "th");
 458                 else if(substring(valstr, l - 1, 1) == "1")
 459                         valstr = strcat(valstr, "st");
 460                 else if(substring(valstr, l - 1, 1) == "2")
 461                         valstr = strcat(valstr, "nd");
 462                 else if(substring(valstr, l - 1, 1) == "3")
 463                         valstr = strcat(valstr, "rd");
 464                 else
 465                         valstr = strcat(valstr, "th");
 466         }
 467         else if(pFlags & SFL_TIME)
 468                 valstr = mmsss(pValue);
 469         else
 470                 valstr = ftos(pValue);
 471
 472         return valstr;
 473 }
 474
 475 vector cross(vector a, vector b)
 476 {
 477         return
 478                 '1 0 0' * (a_y * b_z - a_z * b_y)
 479         +       '0 1 0' * (a_z * b_x - a_x * b_z)
 480         +       '0 0 1' * (a_x * b_y - a_y * b_x);
 481 }
 482
 483 // compressed vector format:
 484 // like MD3, just even shorter
 485 //   4 bit pitch (16 angles), 0 is -90, 8 is 0, 16 would be 90
 486 //   5 bit yaw (32 angles), 0=0, 8=90, 16=180, 24=270
 487 //   7 bit length (logarithmic encoding), 1/8 .. about 7844
 488 //     length = 2^(length_encoded/8) / 8
 489 // if pitch is 90, yaw does nothing and therefore indicates the sign (yaw is then either 11111 or 11110); 11111 is pointing DOWN
 490 // thus, valid values are from 0000.11110.0000000 to 1111.11111.1111111
 491 // the special value 0 indicates the zero vector
 492
 493 float lengthLogTable[128];
 494
 495 float invertLengthLog(float x)
 496 {
 497         float l, r, m, lerr, rerr;
 498
 499         if(x >= lengthLogTable[127])
 500                 return 127;
 501         if(x <= lengthLogTable[0])
 502                 return 0;
 503
 504         l = 0;
 505         r = 127;
 506
 507         while(r - l > 1)
 508         {
 509                 m = floor((l + r) / 2);
 510                 if(lengthLogTable[m] < x)
 511                         l = m;
 512                 else
 513                         r = m;
 514         }
 515
 516         // now: r is >=, l is <
 517         lerr = (x - lengthLogTable[l]);
 518         rerr = (lengthLogTable[r] - x);
 519         if(lerr < rerr)
 520                 return l;
 521         return r;
 522 }
 523
 524 vector decompressShortVector(float data)
 525 {
 526         vector out;
 527         float pitch, yaw, len;
 528         if(data == 0)
 529                 return '0 0 0';
 530         pitch = (data & 0xF000) / 0x1000;
 531         yaw =   (data & 0x0F80) / 0x80;
 532         len =   (data & 0x007F);
 533
 534         //print("\ndecompress: pitch ", ftos(pitch)); print("yaw ", ftos(yaw)); print("len ", ftos(len), "\n");
 535
 536         if(pitch == 0)
 537         {
 538                 out_x = 0;
 539                 out_y = 0;
 540                 if(yaw == 31)
 541                         out_z = -1;
 542                 else
 543                         out_z = +1;
 544         }
 545         else
 546         {
 547                 yaw   = .19634954084936207740 * yaw;
 548                 pitch = .19634954084936207740 * pitch - 1.57079632679489661922;
 549                 out_x = cos(yaw) *  cos(pitch);
 550                 out_y = sin(yaw) *  cos(pitch);
 551                 out_z =            -sin(pitch);
 552         }
 553
 554         //print("decompressed: ", vtos(out), "\n");
 555
 556         return out * lengthLogTable[len];
 557 }
 558
 559 float compressShortVector(vector vec)
 560 {
 561         vector ang;
 562         float pitch, yaw, len;
 563         if(vlen(vec) == 0)
 564                 return 0;
 565         //print("compress: ", vtos(vec), "\n");
 566         ang = vectoangles(vec);
 567         ang_x = -ang_x;
 568         if(ang_x < -90)
 569                 ang_x += 360;
 570         if(ang_x < -90 && ang_x > +90)
 571                 error("BOGUS vectoangles");
 572         //print("angles: ", vtos(ang), "\n");
 573
 574         pitch = floor(0.5 + (ang_x + 90) * 16 / 180) & 15; // -90..90 to 0..14
 575         if(pitch == 0)
 576         {
 577                 if(vec_z < 0)
 578                         yaw = 31;
 579                 else
 580                         yaw = 30;
 581         }
 582         else
 583                 yaw = floor(0.5 + ang_y * 32 / 360)          & 31; // 0..360 to 0..32
 584         len = invertLengthLog(vlen(vec));
 585
 586         //print("compressed: pitch ", ftos(pitch)); print("yaw ", ftos(yaw)); print("len ", ftos(len), "\n");
 587
 588         return (pitch * 0x1000) + (yaw * 0x80) + len;
 589 }
 590
 591 void compressShortVector_init()
 592 {
 593         float l, f, i;
 594         l = 1;
 595         f = pow(2, 1/8);
 596         for(i = 0; i < 128; ++i)
 597         {
 598                 lengthLogTable[i] = l;
 599                 l *= f;
 600         }
 601
 602         if(cvar("developer"))
 603         {
 604                 print("Verifying vector compression table...\n");
 605                 for(i = 0x0F00; i < 0xFFFF; ++i)
 606                         if(i != compressShortVector(decompressShortVector(i)))
 607                         {
 608                                 print("BROKEN vector compression: ", ftos(i));
 609                                 print(" -> ", vtos(decompressShortVector(i)));
 610                                 print(" -> ", ftos(compressShortVector(decompressShortVector(i))));
 611                                 print("\n");
 612                                 error("b0rk");
 613                         }
 614                 print("Done.\n");
 615         }
 616 }
 617
 618 #ifndef MENUQC
 619 float CheckWireframeBox(entity forent, vector v0, vector dvx, vector dvy, vector dvz)
 620 {
 621         traceline(v0, v0 + dvx, TRUE, forent); if(trace_fraction < 1) return 0;
 622         traceline(v0, v0 + dvy, TRUE, forent); if(trace_fraction < 1) return 0;
 623         traceline(v0, v0 + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 624         traceline(v0 + dvx, v0 + dvx + dvy, TRUE, forent); if(trace_fraction < 1) return 0;
 625         traceline(v0 + dvx, v0 + dvx + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 626         traceline(v0 + dvy, v0 + dvy + dvx, TRUE, forent); if(trace_fraction < 1) return 0;
 627         traceline(v0 + dvy, v0 + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 628         traceline(v0 + dvz, v0 + dvz + dvx, TRUE, forent); if(trace_fraction < 1) return 0;
 629         traceline(v0 + dvz, v0 + dvz + dvy, TRUE, forent); if(trace_fraction < 1) return 0;
 630         traceline(v0 + dvx + dvy, v0 + dvx + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 631         traceline(v0 + dvx + dvz, v0 + dvx + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 632         traceline(v0 + dvy + dvz, v0 + dvx + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 633         return 1;
 634 }
 635
 636 void fixedmakevectors(vector a)
 637 {
 638         // a makevectors that actually inverts vectoangles
 639         a_x = -a_x;
 640         makevectors(a);
 641 }
 642 #endif
 643
 644 string fixPriorityList(string order, float from, float to, float subtract, float complete)
 645 {
 646         string neworder;
 647         float i, n, w;
 648
 649         n = tokenize_sane(order);
 650         for(i = 0; i < n; ++i)
 651         {
 652                 w = stof(argv(i));
 653                 if(w == floor(w))
 654                 {
 655                         if(w >= from && w <= to)
 656                                 neworder = strcat(neworder, ftos(w), " ");
 657                         else
 658                         {
 659                                 w -= subtract;
 660                                 if(w >= from && w <= to)
 661                                         neworder = strcat(neworder, ftos(w), " ");
 662                         }
 663                 }
 664         }
 665
 666         if(complete)
 667         {
 668                 n = tokenize_sane(neworder);
 669                 for(w = to; w >= from; --w)
 670                 {
 671                         for(i = 0; i < n; ++i)
 672                                 if(stof(argv(i)) == w)
 673                                         break;
 674                         if(i == n) // not found
 675                                 neworder = strcat(neworder, ftos(w), " ");
 676                 }
 677         }
 678
 679         return substring(neworder, 0, strlen(neworder) - 1);
 680 }
 681
 682 string swapInPriorityList(string order, float i, float j)
 683 {
 684         string s;
 685         float w, n;
 686
 687         n = tokenize_sane(order);
 688
 689         if(i >= 0 && i < n && j >= 0 && j < n && i != j)
 690         {
 691                 s = "";
 692                 for(w = 0; w < n; ++w)
 693                 {
 694                         if(w == i)
 695                                 s = strcat(s, argv(j), " ");
 696                         else if(w == j)
 697                                 s = strcat(s, argv(i), " ");
 698                         else
 699                                 s = strcat(s, argv(w), " ");
 700                 }
 701                 return substring(s, 0, strlen(s) - 1);
 702         }
 703
 704         return order;
 705 }
 706
 707 float cvar_value_issafe(string s)
 708 {
 709         if(strstrofs(s, "\"", 0) >= 0)
 710                 return 0;
 711         if(strstrofs(s, "\\", 0) >= 0)
 712                 return 0;
 713         if(strstrofs(s, ";", 0) >= 0)
 714                 return 0;
 715         if(strstrofs(s, "$", 0) >= 0)
 716                 return 0;
 717         if(strstrofs(s, "\r", 0) >= 0)
 718                 return 0;
 719         if(strstrofs(s, "\n", 0) >= 0)
 720                 return 0;
 721         return 1;
 722 }
 723
 724 #ifndef MENUQC
 725 void get_mi_min_max(float mode)
 726 {
 727         vector mi, ma;
 728
 729         if(mi_shortname)
 730                 strunzone(mi_shortname);
 731         mi_shortname = mapname;
 732         if(!strcasecmp(substring(mi_shortname, 0, 5), "maps/"))
 733                 mi_shortname = substring(mi_shortname, 5, strlen(mi_shortname) - 5);
 734         if(!strcasecmp(substring(mi_shortname, strlen(mi_shortname) - 4, 4), ".bsp"))
 735                 mi_shortname = substring(mi_shortname, 0, strlen(mi_shortname) - 4);
 736         mi_shortname = strzone(mi_shortname);
 737
 738 #ifdef CSQC
 739         mi = world.mins;
 740         ma = world.maxs;
 741 #else
 742         mi = world.absmin;
 743         ma = world.absmax;
 744 #endif
 745
 746         mi_min = mi;
 747         mi_max = ma;
 748         MapInfo_Get_ByName(mi_shortname, 0, 0);
 749         if(MapInfo_Map_mins_x < MapInfo_Map_maxs_x)
 750         {
 751                 mi_min = MapInfo_Map_mins;
 752                 mi_max = MapInfo_Map_maxs;
 753         }
 754         else
 755         {
 756                 // not specified
 757                 if(mode)
 758                 {
 759                         // be clever
 760                         tracebox('1 0 0' * mi_x,
 761                                          '0 1 0' * mi_y + '0 0 1' * mi_z,
 762                                          '0 1 0' * ma_y + '0 0 1' * ma_z,
 763                                          '1 0 0' * ma_x,
 764                                          MOVE_WORLDONLY,
 765                                          world);
 766                         if(!trace_startsolid)
 767                                 mi_min_x = trace_endpos_x;
 768
 769                         tracebox('0 1 0' * mi_y,
 770                                          '1 0 0' * mi_x + '0 0 1' * mi_z,
 771                                          '1 0 0' * ma_x + '0 0 1' * ma_z,
 772                                          '0 1 0' * ma_y,
 773                                          MOVE_WORLDONLY,
 774                                          world);
 775                         if(!trace_startsolid)
 776                                 mi_min_y = trace_endpos_y;
 777
 778                         tracebox('0 0 1' * mi_z,
 779                                          '1 0 0' * mi_x + '0 1 0' * mi_y,
 780                                          '1 0 0' * ma_x + '0 1 0' * ma_y,
 781                                          '0 0 1' * ma_z,
 782                                          MOVE_WORLDONLY,
 783                                          world);
 784                         if(!trace_startsolid)
 785                                 mi_min_z = trace_endpos_z;
 786
 787                         tracebox('1 0 0' * ma_x,
 788                                          '0 1 0' * mi_y + '0 0 1' * mi_z,
 789                                          '0 1 0' * ma_y + '0 0 1' * ma_z,
 790                                          '1 0 0' * mi_x,
 791                                          MOVE_WORLDONLY,
 792                                          world);
 793                         if(!trace_startsolid)
 794                                 mi_max_x = trace_endpos_x;
 795
 796                         tracebox('0 1 0' * ma_y,
 797                                          '1 0 0' * mi_x + '0 0 1' * mi_z,
 798                                          '1 0 0' * ma_x + '0 0 1' * ma_z,
 799                                          '0 1 0' * mi_y,
 800                                          MOVE_WORLDONLY,
 801                                          world);
 802                         if(!trace_startsolid)
 803                                 mi_max_y = trace_endpos_y;
 804
 805                         tracebox('0 0 1' * ma_z,
 806                                          '1 0 0' * mi_x + '0 1 0' * mi_y,
 807                                          '1 0 0' * ma_x + '0 1 0' * ma_y,
 808                                          '0 0 1' * mi_z,
 809                                          MOVE_WORLDONLY,
 810                                          world);
 811                         if(!trace_startsolid)
 812                                 mi_max_z = trace_endpos_z;
 813                 }
 814         }
 815 }
 816
 817 void get_mi_min_max_texcoords(float mode)
 818 {
 819         vector extend;
 820
 821         get_mi_min_max(mode);
 822
 823         mi_picmin = mi_min;
 824         mi_picmax = mi_max;
 825
 826         // extend mi_picmax to get a square aspect ratio
 827         // center the map in that area
 828         extend = mi_picmax - mi_picmin;
 829         if(extend_y > extend_x)
 830         {
 831                 mi_picmin_x -= (extend_y - extend_x) * 0.5;
 832                 mi_picmax_x += (extend_y - extend_x) * 0.5;
 833         }
 834         else
 835         {
 836                 mi_picmin_y -= (extend_x - extend_y) * 0.5;
 837                 mi_picmax_y += (extend_x - extend_y) * 0.5;
 838         }
 839
 840         // add another some percent
 841         extend = (mi_picmax - mi_picmin) * (1 / 64.0);
 842         mi_picmin -= extend;
 843         mi_picmax += extend;
 844
 845         // calculate the texcoords
 846         mi_pictexcoord0 = mi_pictexcoord1 = mi_pictexcoord2 = mi_pictexcoord3 = '0 0 0';
 847         // first the two corners of the origin
 848         mi_pictexcoord0_x = (mi_min_x - mi_picmin_x) / (mi_picmax_x - mi_picmin_x);
 849         mi_pictexcoord0_y = (mi_min_y - mi_picmin_y) / (mi_picmax_y - mi_picmin_y);
 850         mi_pictexcoord2_x = (mi_max_x - mi_picmin_x) / (mi_picmax_x - mi_picmin_x);
 851         mi_pictexcoord2_y = (mi_max_y - mi_picmin_y) / (mi_picmax_y - mi_picmin_y);
 852         // then the other corners
 853         mi_pictexcoord1_x = mi_pictexcoord0_x;
 854         mi_pictexcoord1_y = mi_pictexcoord2_y;
 855         mi_pictexcoord3_x = mi_pictexcoord2_x;
 856         mi_pictexcoord3_y = mi_pictexcoord0_y;
 857 }
 858 #endif
 859
 860 #ifdef CSQC
 861 void cvar_settemp(string pKey, string pValue)
 862 {
 863         error("cvar_settemp called from CSQC - use cvar_clientsettemp instead!");
 864 }
 865 void cvar_settemp_restore()
 866 {
 867         error("cvar_settemp_restore called from CSQC - use cvar_clientsettemp instead!");
 868 }
 869 #else
 870 void cvar_settemp(string pKey, string pValue)
 871 {
 872         cvar_set("settemp_list", strcat("1 ", pKey, " ", cvar_string("settemp_var"), " ", cvar_string("settemp_list")));
 873 #ifdef MENUQC
 874         registercvar(cvar_string("settemp_var"), "", 0);
 875 #else
 876         registercvar(cvar_string("settemp_var"), "");
 877 #endif
 878         cvar_set(cvar_string("settemp_var"), cvar_string(pKey));
 879         cvar_set("settemp_var", strcat(cvar_string("settemp_var"), "x"));
 880         cvar_set(pKey, pValue);
 881 }
 882
 883 void cvar_settemp_restore()
 884 {
 885         // undo what cvar_settemp did
 886         string s1, s2;
 887         float n, i;
 888         n = tokenize_sane(cvar_string("settemp_list"));
 889         for(i = 0; i < n - 3; i += 3)
 890         {
 891                 s1 = argv(i + 1);
 892                 s2 = argv(i + 2);
 893                 cvar_set(s1, s2); // fteqcc sucks
 894         }
 895         cvar_set("settemp_list", "0");
 896 }
 897 #endif
 898
 899 float almost_equals(float a, float b)
 900 {
 901         float eps;
 902         eps = (max(a, -a) + max(b, -b)) * 0.001;
 903         if(a - b < eps && b - a < eps)
 904                 return TRUE;
 905         return FALSE;
 906 }
 907
 908 float almost_in_bounds(float a, float b, float c)
 909 {
 910         float eps;
 911         eps = (max(a, -a) + max(c, -c)) * 0.001;
 912         return b == median(a - eps, b, c + eps);
 913 }
 914
 915
 916
 917 #ifdef MENUQC
 918 float (string s) _tokenize_builtin = #58;
 919 string (float argnum) _argv_builtin = #59;
 920 float (string s, string sep) _tokenizebyseparator_builtin = #479;
 921 #else
 922 float (string s) _tokenize_builtin = #441;
 923 string (float argnum) _argv_builtin = #442;
 924 float (string s, string sep) _tokenizebyseparator_builtin = #479;
 925 #endif
 926 float(string s) _tokenize_console = #514;
 927 float(float i) _argv_start_index_builtin = #515;
 928 float(float i) _argv_end_index_builtin = #516;
 929
 930 float MAX_TOKENS = 256;
 931 string _argv_sane_buffer[MAX_TOKENS];
 932 float _argv_sane_startpos[MAX_TOKENS];
 933 float _argv_sane_endpos[MAX_TOKENS];
 934 float _argc_sane;
 935
 936 string _argv_sane(float i)
 937 {
 938         // Perl-ish -1 for the last argument
 939         if(i < 0)
 940                 i = _argc_sane + i;
 941         return strcat("", _argv_sane_buffer[i]); // force tempstring
 942 }
 943
 944 float _argv_start_index_sane(float i)
 945 {
 946         // Perl-ish -1 for the last argument
 947         if(i < 0)
 948                 i = _argc_sane + i;
 949         return _argv_sane_startpos[i];
 950 }
 951
 952 float _argv_end_index_sane(float i)
 953 {
 954         // Perl-ish -1 for the last argument
 955         if(i < 0)
 956                 i = _argc_sane + i;
 957         return _argv_sane_endpos[i];
 958 }
 959
 960 //string TOKENIZE_SANE_WHITESPACE_CHARS = "\x01\x02\x03\x04\x05\x06\x07\x08\x09\x0a\x0b\x0c\x0d\x0e\x0f\x10\x11\x12\x13\x14\x15\x16\x17\x18\x19\x1a\x1b\x1c\x1d\x1e\x1f\x20\x80\x81\x82\x83\x84\x85\x86\x87\x88\x89\x8a\x8b\x8c\x8d\x8e\x8f\x90\x91\x92\x93\x94\x95\x96\x97\x98\x99\x9a\x9b\x9c\x9d\x9e\x9f\xa0\xa1\xa2\xa3\xa4\xa5\xa6\xa7\xa8\xa9\xaa\xab\xac\xad\xae\xaf\xb0\xb1\xb2\xb3\xb4\xb5\xb6\xb7\xb8\xb9\xba\xbb\xbc\xbd\xbe\xbf\xc0\xc1\xc2\xc3\xc4\xc5\xc6\xc7\xc8\xc9\xca\xcb\xcc\xcd\xce\xcf\xd0\xd1\xd2\xd3\xd4\xd5\xd6\xd7\xd8\xd9\xda\xdb\xdc\xdd\xde\xdf\xe0\xe1\xe2\xe3\xe4\xe5\xe6\xe7\xe8\xe9\xea\xeb\xec\xed\xee\xef\xf0\xf1\xf2\xf3\xf4\xf5\xf6\xf7\xf8\xf9\xfa\xfb\xfc\xfd\xfe\xff";
 961 string TOKENIZE_SANE_WHITESPACE_CHARS = "\x20\x0d\x0a\x09";
 962 string TOKENIZE_SANE_COMMENT_BREAKERS = "\x0d\x0a";
 963 // change this if DP changes its type to "char"!
 964
 965 float _tokenize_sane(string s)
 966 {
 967         // This MUST match COM_ParseToken_Console!
 968         string com_token, tmp;
 969         float data;
 970         float end;
 971         float i;
 972
 973         for(i = 0; i < _argc_sane; ++i)
 974         {
 975                 if(_argv_sane_buffer[i])
 976                         strunzone(_argv_sane_buffer[i]);
 977                 _argv_sane_buffer[i] = string_null;
 978                 _argv_sane_startpos[i] = 0;
 979         }
 980
 981         _argc_sane = 0;
 982         data = 0;
 983         end = strlen(s);
 984
 985         for(;;)
 986         {
 987                 // skip whitespace
 988                 for(; data < end && strstrofs(TOKENIZE_SANE_WHITESPACE_CHARS, substring(s, data, 1), 0) >= 0; ++data)
 989                         ;
 990                 if(data == end)
 991                         break;
 992
 993                 if(substring(s, data, 2) == "//")
 994                 {
 995                         // comment
 996
 997                         // Any call to the tokenizer ALREADY assumes it's a single line, so we can safely abort if we see a comment.
 998                         /*
 999                         data += 2;
1000                         while(data < end && strstrofs(TOKENIZE_SANE_COMMENT_BREAKERS, substring(s, data, 1), 0) >= 0)
1001                                 ++data;
1002                         continue; // go to skipwhite again
1003                         */
1004
1005                         // I'd like to simply put a "break" here, but then fteqcc says this function has unreachable code
1006                         return _argc_sane;
1007                 }
1008                 else if(substring(s, data, 1) == "\"")
1009                 {
1010                         // quoted string
1011                         com_token = "";
1012                         _argv_sane_startpos[_argc_sane] = data;
1013                         for(++data; data < end && substring(s, data, 1) != "\""; ++data)
1014                         {
1015                                 // allow escaped " and \ case
1016                                 tmp = substring(s, data, 2);
1017                                 if(tmp == "\\\"" || tmp == "\\\\")
1018                                         ++data;
1019                                 com_token = strcat(com_token, substring(s, data, 1));
1020                         }
1021                         if(substring(s, data, 1) == "\"")
1022                                 ++data;
1023                         _argv_sane_endpos[_argc_sane] = data;
1024                         _argv_sane_buffer[_argc_sane] = strzone(com_token);
1025                         ++_argc_sane;
1026                 }
1027                 else
1028                 {
1029                         // regular word
1030                         com_token = "";
1031                         _argv_sane_startpos[_argc_sane] = data;
1032                         for(; data < end && strstrofs(TOKENIZE_SANE_WHITESPACE_CHARS, substring(s, data, 1), 0) < 0; ++data)
1033                                 com_token = strcat(com_token, substring(s, data, 1));
1034                         _argv_sane_endpos[_argc_sane] = data;
1035                         _argv_sane_buffer[_argc_sane] = strzone(com_token);
1036                         ++_argc_sane;
1037                 }
1038         }
1039
1040         return _argc_sane;
1041 }
1042
1043
1044
1045 // "sane" tokenizer
1046 // matching the console 1:1
1047
1048 float tokenize_sane_force_native(string s)
1049 {
1050         argv = _argv_builtin;
1051         argv_start_index = _argv_start_index_builtin;
1052         argv_end_index = _argv_end_index_builtin;
1053         return _tokenize_console(s);
1054 }
1055
1056 float tokenize_sane_force_emulation(string s)
1057 {
1058         argv = _argv_sane;
1059         argv_start_index = _argv_start_index_sane;
1060         argv_end_index = _argv_end_index_sane;
1061         return _tokenize_sane(s);
1062 }
1063
1064 float tokenize_sane(string s)
1065 {
1066         if(checkextension("DP_QC_TOKENIZE_CONSOLE"))
1067                 return tokenize_sane_force_native(s);
1068         return tokenize_sane_force_emulation(s);
1069 }
1070
1071 float tokenize_insane(string s)
1072 {
1073         argv = _argv_builtin;
1074         argv_start_index = _argv_start_index_builtin;
1075         argv_end_index = _argv_end_index_builtin;
1076         return _tokenize_builtin(s);
1077 }
1078
1079 float tokenizebyseparator(string s, string sep)
1080 {
1081         argv = _argv_builtin;
1082         argv_start_index = _argv_start_index_builtin;
1083         argv_end_index = _argv_end_index_builtin;
1084         return _tokenizebyseparator_builtin(s, sep);
1085 }
1086
1087 float power2of(float e)
1088 {
1089         return pow(2, e);
1090 }
1091 float log2of(float x)
1092 {
1093         // NOTE: generated code
1094         if(x > 2048)
1095                 if(x > 131072)
1096                         if(x > 1048576)
1097                                 if(x > 4194304)
1098                                         return 23;
1099                                 else
1100                                         if(x > 2097152)
1101                                                 return 22;
1102                                         else
1103                                                 return 21;
1104                         else
1105                                 if(x > 524288)
1106                                         return 20;
1107                                 else
1108                                         if(x > 262144)
1109                                                 return 19;
1110                                         else
1111                                                 return 18;
1112                 else
1113                         if(x > 16384)
1114                                 if(x > 65536)
1115                                         return 17;
1116                                 else
1117                                         if(x > 32768)
1118                                                 return 16;
1119                                         else
1120                                                 return 15;
1121                         else
1122                                 if(x > 8192)
1123                                         return 14;
1124                                 else
1125                                         if(x > 4096)
1126                                                 return 13;
1127                                         else
1128                                                 return 12;
1129         else
1130                 if(x > 32)
1131                         if(x > 256)
1132                                 if(x > 1024)
1133                                         return 11;
1134                                 else
1135                                         if(x > 512)
1136                                                 return 10;
1137                                         else
1138                                                 return 9;
1139                         else
1140                                 if(x > 128)
1141                                         return 8;
1142                                 else
1143                                         if(x > 64)
1144                                                 return 7;
1145                                         else
1146                                                 return 6;
1147                 else
1148                         if(x > 4)
1149                                 if(x > 16)
1150                                         return 5;
1151                                 else
1152                                         if(x > 8)
1153                                                 return 4;
1154                                         else
1155                                                 return 3;
1156                         else
1157                                 if(x > 2)
1158                                         return 2;
1159                                 else
1160                                         if(x > 1)
1161                                                 return 1;
1162                                         else
1163                                                 return 0;
1164 }
1165
1166 float rgb_mi_ma_to_hue(vector rgb, float mi, float ma)
1167 {
1168         if(mi == ma)
1169                 return 0;
1170         else if(ma == rgb_x)
1171         {
1172                 if(rgb_y >= rgb_z)
1173                         return (rgb_y - rgb_z) / (ma - mi);
1174                 else
1175                         return (rgb_y - rgb_z) / (ma - mi) + 6;
1176         }
1177         else if(ma == rgb_y)
1178                 return (rgb_z - rgb_x) / (ma - mi) + 2;
1179         else // if(ma == rgb_z)
1180                 return (rgb_x - rgb_y) / (ma - mi) + 4;
1181 }
1182
1183 vector hue_mi_ma_to_rgb(float hue, float mi, float ma)
1184 {
1185         vector rgb;
1186
1187         hue -= 6 * floor(hue / 6);
1188
1189         //else if(ma == rgb_x)
1190         //      hue = 60 * (rgb_y - rgb_z) / (ma - mi);
1191         if(hue <= 1)
1192         {
1193                 rgb_x = ma;
1194                 rgb_y = hue * (ma - mi) + mi;
1195                 rgb_z = mi;
1196         }
1197         //else if(ma == rgb_y)
1198         //      hue = 60 * (rgb_z - rgb_x) / (ma - mi) + 120;
1199         else if(hue <= 2)
1200         {
1201                 rgb_x = (2 - hue) * (ma - mi) + mi;
1202                 rgb_y = ma;
1203                 rgb_z = mi;
1204         }
1205         else if(hue <= 3)
1206         {
1207                 rgb_x = mi;
1208                 rgb_y = ma;
1209                 rgb_z = (hue - 2) * (ma - mi) + mi;
1210         }
1211         //else // if(ma == rgb_z)
1212         //      hue = 60 * (rgb_x - rgb_y) / (ma - mi) + 240;
1213         else if(hue <= 4)
1214         {
1215                 rgb_x = mi;
1216                 rgb_y = (4 - hue) * (ma - mi) + mi;
1217                 rgb_z = ma;
1218         }
1219         else if(hue <= 5)
1220         {
1221                 rgb_x = (hue - 4) * (ma - mi) + mi;
1222                 rgb_y = mi;
1223                 rgb_z = ma;
1224         }
1225         //else if(ma == rgb_x)
1226         //      hue = 60 * (rgb_y - rgb_z) / (ma - mi);
1227         else // if(hue <= 6)
1228         {
1229                 rgb_x = ma;
1230                 rgb_y = mi;
1231                 rgb_z = (6 - hue) * (ma - mi) + mi;
1232         }
1233
1234         return rgb;
1235 }
1236
1237 vector rgb_to_hsv(vector rgb)
1238 {
1239         float mi, ma;
1240         vector hsv;
1241
1242         mi = min3(rgb_x, rgb_y, rgb_z);
1243         ma = max3(rgb_x, rgb_y, rgb_z);
1244
1245         hsv_x = rgb_mi_ma_to_hue(rgb, mi, ma);
1246         hsv_z = ma;
1247
1248         if(ma == 0)
1249                 hsv_y = 0;
1250         else
1251                 hsv_y = 1 - mi/ma;
1252
1253         return hsv;
1254 }
1255
1256 vector hsv_to_rgb(vector hsv)
1257 {
1258         return hue_mi_ma_to_rgb(hsv_x, hsv_z * (1 - hsv_y), hsv_z);
1259 }
1260
1261 vector rgb_to_hsl(vector rgb)
1262 {
1263         float mi, ma;
1264         vector hsl;
1265
1266         mi = min3(rgb_x, rgb_y, rgb_z);
1267         ma = max3(rgb_x, rgb_y, rgb_z);
1268
1269         hsl_x = rgb_mi_ma_to_hue(rgb, mi, ma);
1270
1271         hsl_z = 0.5 * (mi + ma);
1272         if(mi == ma)
1273                 hsl_y = 0;
1274         else if(hsl_z <= 0.5)
1275                 hsl_y = (ma - mi) / (2*hsl_z);
1276         else // if(hsl_z > 0.5)
1277                 hsl_y = (ma - mi) / (2 - 2*hsl_z);
1278
1279         return hsl;
1280 }
1281
1282 vector hsl_to_rgb(vector hsl)
1283 {
1284         float mi, ma, maminusmi;
1285
1286         if(hsl_z <= 0.5)
1287                 maminusmi = hsl_y * 2 * hsl_z;
1288         else
1289                 maminusmi = hsl_y * (2 - 2 * hsl_z);
1290
1291         // hsl_z     = 0.5 * mi + 0.5 * ma
1292         // maminusmi =     - mi +       ma
1293         mi = hsl_z - 0.5 * maminusmi;
1294         ma = hsl_z + 0.5 * maminusmi;
1295
1296         return hue_mi_ma_to_rgb(hsl_x, mi, ma);
1297 }
1298
1299 string rgb_to_hexcolor(vector rgb)
1300 {
1301         return
1302                 strcat(
1303                         "^x",
1304                         DEC_TO_HEXDIGIT(floor(rgb_x * 15 + 0.5)),
1305                         DEC_TO_HEXDIGIT(floor(rgb_y * 15 + 0.5)),
1306                         DEC_TO_HEXDIGIT(floor(rgb_z * 15 + 0.5))
1307                 );
1308 }
1309
1310 // requires that m2>m1 in all coordinates, and that m4>m3
1311 float boxesoverlap(vector m1, vector m2, vector m3, vector m4) {return m2_x >= m3_x && m1_x <= m4_x && m2_y >= m3_y && m1_y <= m4_y && m2_z >= m3_z && m1_z <= m4_z;};
1312
1313 // requires the same, but is a stronger condition
1314 float boxinsidebox(vector smins, vector smaxs, vector bmins, vector bmaxs) {return smins_x >= bmins_x && smaxs_x <= bmaxs_x && smins_y >= bmins_y && smaxs_y <= bmaxs_y && smins_z >= bmins_z && smaxs_z <= bmaxs_z;};
1315
1316 #ifndef MENUQC
1317 // angles transforms
1318 // angles in fixedmakevectors/fixedvectoangles space
1319 vector AnglesTransform_Apply(vector transform, vector v)
1320 {
1321         fixedmakevectors(transform);
1322         return v_forward * v_x
1323              + v_right   * (-v_y)
1324                  + v_up      * v_z;
1325 }
1326
1327 vector AnglesTransform_Multiply(vector t1, vector t2)
1328 {
1329         vector m_forward, m_up;
1330         fixedmakevectors(t2); m_forward = v_forward; m_up = v_up;
1331         m_forward = AnglesTransform_Apply(t1, m_forward); m_up = AnglesTransform_Apply(t1, m_up);
1332         return fixedvectoangles2(m_forward, m_up);
1333 }
1334
1335 vector AnglesTransform_Invert(vector transform)
1336 {
1337         vector i_forward, i_up;
1338         fixedmakevectors(transform);
1339         // we want angles that turn v_forward into '1 0 0', v_right into '0 1 0' and v_up into '0 0 1'
1340         // but these are orthogonal unit vectors!
1341         // so to invert, we can simply fixedvectoangles the TRANSPOSED matrix
1342         // TODO is this always -transform?
1343         i_forward_x = v_forward_x;
1344         i_forward_y = -v_right_x;
1345         i_forward_z = v_up_x;
1346         i_up_x = v_forward_z;
1347         i_up_y = -v_right_z;
1348         i_up_z = v_up_z;
1349         return fixedvectoangles2(i_forward, i_up);
1350 }
1351
1352 vector AnglesTransform_TurnDirection(vector transform)
1353 {
1354         // turn 180 degrees around v_up
1355         // changes in-direction to out-direction
1356         fixedmakevectors(transform);
1357         return fixedvectoangles2(-1 * v_forward, 1 * v_up);
1358 }
1359
1360 vector AnglesTransform_Divide(vector to_transform, vector from_transform)
1361 {
1362         return AnglesTransform_Multiply(to_transform, AnglesTransform_Invert(from_transform));
1363 }
1364 #endif
1365
1366 float textLengthUpToWidth(string theText, float maxWidth, textLengthUpToWidth_widthFunction_t w)
1367 {
1368         float ICanHasKallerz;
1369
1370         // detect color codes support in the width function
1371         ICanHasKallerz = (w("^7") == 0);
1372
1373         // STOP.
1374         // The following function is SLOW.
1375         // For your safety and for the protection of those around you...
1376         // DO NOT CALL THIS AT HOME.
1377         // No really, don't.
1378         if(w(theText) <= maxWidth)
1379                 return strlen(theText); // yeah!
1380
1381         // binary search for right place to cut string
1382         float ch;
1383         float left, right, middle; // this always works
1384         left = 0;
1385         right = strlen(theText); // this always fails
1386         do
1387         {
1388                 middle = floor((left + right) / 2);
1389                 if(w(substring(theText, 0, middle)) <= maxWidth)
1390                         left = middle;
1391                 else
1392                         right = middle;
1393         }
1394         while(left < right - 1);
1395
1396         if(ICanHasKallerz)
1397         {
1398                 // NOTE: when color codes are involved, this binary search is,
1399                 // mathematically, BROKEN. However, it is obviously guaranteed to
1400                 // terminate, as the range still halves each time - but nevertheless, it is
1401                 // guaranteed that it finds ONE valid cutoff place (where "left" is in
1402                 // range, and "right" is outside).
1403
1404                 // terencehill: the following code detects truncated ^xrgb tags (e.g. ^x or ^x4)
1405                 // and decrease left on the basis of the chars detected of the truncated tag
1406                 // Even if the ^xrgb tag is not complete/correct, left is decreased
1407                 // (sometimes too much but with a correct result)
1408                 // it fixes also ^[0-9]
1409                 while(left >= 1 && substring(theText, left-1, 1) == "^")
1410                         left-=1;
1411
1412                 if (left >= 2 && substring(theText, left-2, 2) == "^x") // ^x/
1413                         left-=2;
1414                 else if (left >= 3 && substring(theText, left-3, 2) == "^x")
1415                         {
1416                                 ch = str2chr(theText, left-1);
1417                                 if( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xr/
1418                                         left-=3;
1419                         }
1420                 else if (left >= 4 && substring(theText, left-4, 2) == "^x")
1421                         {
1422                                 ch = str2chr(theText, left-2);
1423                                 if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') )
1424                                 {
1425                                         ch = str2chr(theText, left-1);
1426                                         if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xrg/
1427                                                 left-=4;
1428                                 }
1429                         }
1430         }
1431
1432         return left;
1433 }
1434
1435 string getWrappedLine(float w, textLengthUpToWidth_widthFunction_t tw)
1436 {
1437         float cantake;
1438         float take;
1439         string s;
1440
1441         s = getWrappedLine_remaining;
1442
1443         cantake = textLengthUpToWidth(s, w, tw);
1444         if(cantake > 0 && cantake < strlen(s))
1445         {
1446                 take = cantake - 1;
1447                 while(take > 0 && substring(s, take, 1) != " ")
1448                         --take;
1449                 if(take == 0)
1450                 {
1451                         getWrappedLine_remaining = substring(s, cantake, strlen(s) - cantake);
1452                         if(getWrappedLine_remaining == "")
1453                                 getWrappedLine_remaining = string_null;
1454                         return substring(s, 0, cantake);
1455                 }
1456                 else
1457                 {
1458                         getWrappedLine_remaining = substring(s, take + 1, strlen(s) - take);
1459                         if(getWrappedLine_remaining == "")
1460                                 getWrappedLine_remaining = string_null;
1461                         return substring(s, 0, take);
1462                 }
1463         }
1464         else
1465         {
1466                 getWrappedLine_remaining = string_null;
1467                 return s;
1468         }
1469 }
1470
1471 string textShortenToWidth(string theText, float maxWidth, textLengthUpToWidth_widthFunction_t tw)
1472 {
1473         if(tw(theText) <= maxWidth)
1474                 return theText;
1475         else
1476                 return strcat(substring(theText, 0, textLengthUpToWidth(theText, maxWidth - tw("..."), tw)), "...");
1477 }
1478
1479 float isGametypeInFilter(float gt, float tp, string pattern)
1480 {
1481         string subpattern, subpattern2;
1482         subpattern = strcat(",", GametypeNameFromType(gt), ",");
1483         if(tp)
1484                 subpattern2 = ",teams,";
1485         else
1486                 subpattern2 = ",noteams,";
1487
1488         if(substring(pattern, 0, 1) == "-")
1489         {
1490                 pattern = substring(pattern, 1, strlen(pattern) - 1);
1491                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) >= 0)
1492                         return 0;
1493                 if(strstrofs(strcat(",", pattern, ","), subpattern2, 0) >= 0)
1494                         return 0;
1495         }
1496         else
1497         {
1498                 if(substring(pattern, 0, 1) == "+")
1499                         pattern = substring(pattern, 1, strlen(pattern) - 1);
1500                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) < 0)
1501                 if(strstrofs(strcat(",", pattern, ","), subpattern2, 0) < 0)
1502                         return 0;
1503         }
1504         return 1;
1505 }
1506
1507 void shuffle(float n, shuffle_swapfunc_t swap)
1508 {
1509         float i, j;
1510         for(i = 1; i < n; ++i)
1511         {
1512                 // swap i-th item at a random position from 0 to i
1513                 // proof for even distribution:
1514                 //   n = 1: obvious
1515                 //   n -> n+1:
1516                 //     item n+1 gets at any position with chance 1/(n+1)
1517                 //     all others will get their 1/n chance reduced by factor n/(n+1)
1518                 //     to be on place n+1, their chance will be 1/(n+1)
1519                 //     1/n * n/(n+1) = 1/(n+1)
1520                 //     q.e.d.
1521                 j = floor(random() * (i + 1));
1522                 if(j != i)
1523                         swap(j, i);
1524         }
1525 }
1526
1527 string substring_range(string s, float b, float e)
1528 {
1529         return substring(s, b, e - b);
1530 }
1531
1532 string swapwords(string str, float i, float j)
1533 {
1534         float n;
1535         string s1, s2, s3, s4, s5;
1536         float si, ei, sj, ej, s0, en;
1537         n = tokenizebyseparator(str, " "); // must match g_maplist processing in ShuffleMaplist and "shuffle"
1538         si = argv_start_index(i);
1539         sj = argv_start_index(j);
1540         ei = argv_end_index(i);
1541         ej = argv_end_index(j);
1542         s0 = argv_start_index(0);
1543         en = argv_end_index(n-1);
1544         s1 = substring_range(str, s0, si);
1545         s2 = substring_range(str, si, ei);
1546         s3 = substring_range(str, ei, sj);
1547         s4 = substring_range(str, sj, ej);
1548         s5 = substring_range(str, ej, en);
1549         return strcat(s1, s4, s3, s2, s5);
1550 }
1551
1552 string _shufflewords_str;
1553 void _shufflewords_swapfunc(float i, float j)
1554 {
1555         _shufflewords_str = swapwords(_shufflewords_str, i, j);
1556 }
1557 string shufflewords(string str)
1558 {
1559         float n;
1560         _shufflewords_str = str;
1561         n = tokenizebyseparator(str, " ");
1562         shuffle(n, _shufflewords_swapfunc);
1563         str = _shufflewords_str;
1564         _shufflewords_str = string_null;
1565         return str;
1566 }
1567
1568 vector solve_quadratic(float a, float b, float c) // ax^2 + bx + c = 0
1569 {
1570         vector v;
1571         float D;
1572         v = '0 0 0';
1573         if(a == 0)
1574         {
1575                 if(b != 0)
1576                 {
1577                         v_x = v_y = -c / b;
1578                         v_z = 1;
1579                 }
1580                 else
1581                 {
1582                         if(c == 0)
1583                         {
1584                                 // actually, every number solves the equation!
1585                                 v_z = 1;
1586                         }
1587                 }
1588         }
1589         else
1590         {
1591                 D = b*b - 4*a*c;
1592                 if(D >= 0)
1593                 {
1594                         D = sqrt(D);
1595                         if(a > 0) // put the smaller solution first
1596                         {
1597                                 v_x = ((-b)-D) / (2*a);
1598                                 v_y = ((-b)+D) / (2*a);
1599                         }
1600                         else
1601                         {
1602                                 v_x = (-b+D) / (2*a);
1603                                 v_y = (-b-D) / (2*a);
1604                         }
1605                         v_z = 1;
1606                 }
1607                 else
1608                 {
1609                         // complex solutions!
1610                         D = sqrt(-D);
1611                         v_x = -b / (2*a);
1612                         if(a > 0)
1613                                 v_y =  D / (2*a);
1614                         else
1615                                 v_y = -D / (2*a);
1616                         v_z = 0;
1617                 }
1618         }
1619         return v;
1620 }
1621
1622
1623 float _unacceptable_compiler_bug_1_a(float b, float c) { return b == c; }
1624 float _unacceptable_compiler_bug_1_b() { return 1; }
1625 float _unacceptable_compiler_bug_1_c(float d) { return 2 * d; }
1626 float _unacceptable_compiler_bug_1_d() { return 1; }
1627
1628 void check_unacceptable_compiler_bugs()
1629 {
1630         if(cvar("_allow_unacceptable_compiler_bugs"))
1631                 return;
1632         tokenize_sane("foo bar");
1633         if(strcat(argv(0), substring("foo bar", 4, 7 - argv_start_index(1))) == "barbar")
1634                 error("fteqcc bug introduced with revision 3178 detected. Please upgrade fteqcc to a later revision, downgrade fteqcc to revision 3177, or pester Spike until he fixes it. You can set _allow_unacceptable_compiler_bugs 1 to skip this check, but expect stuff to be horribly broken then.");
1635 }