data/qcsrc/common/gamecommand.qc

   1 #define MAX_RPN_STACK 16
   2 float rpn_db;
   3 float rpn_error;
   4 float rpn_sp;
   5 string rpn_stack[MAX_RPN_STACK];
   6 string rpn_pop() {
   7         if(rpn_sp > 0) {
   8                 --rpn_sp;
   9                 return rpn_stack[rpn_sp];
  10         } else {
  11                 print("rpn: stack underflow\n");
  12                 rpn_error = TRUE;
  13                 return "";
  14         }
  15 }
  16 void rpn_push(string s) {
  17         if(rpn_sp < MAX_RPN_STACK) {
  18                 rpn_stack[rpn_sp] = s;
  19                 ++rpn_sp;
  20         } else {
  21                 print("rpn: stack overflow\n");
  22                 rpn_error = TRUE;
  23         }
  24 }
  25 string rpn_get() {
  26         if(rpn_sp > 0) {
  27                 return rpn_stack[rpn_sp - 1];
  28         } else {
  29                 print("rpn: empty stack\n");
  30                 rpn_error = TRUE;
  31                 return "";
  32         }
  33 }
  34 void rpn_set(string s) {
  35         if(rpn_sp > 0) {
  36                 rpn_stack[rpn_sp - 1] = s;
  37         } else {
  38                 print("rpn: empty stack\n");
  39                 rpn_error = TRUE;
  40         }
  41 }
  42 float rpn_getf() { return stof(rpn_get()); }
  43 float rpn_popf() { return stof(rpn_pop()); }
  44 void rpn_pushf(float f) { return rpn_push(ftos(f)); }
  45 void rpn_setf(float f) { return rpn_set(ftos(f)); }
  46
  47 float GameCommand_Generic(string command)
  48 {
  49         float argc;
  50         float i, j, f, n;
  51         vector rgb;
  52         string s, s2, c;
  53         argc = tokenize_sane(command);
  54         if(argv(0) == "help")
  55         {
  56                 print("  rpn EXPRESSION... - a RPN calculator.\n");
  57                 print("    Operator description (x: string, s: set, f: float):\n");
  58                 print("    x pop ----------------------------->     : removes the top\n");
  59                 print("    x dup -----------------------------> x x : duplicates the top\n");
  60                 print("    x x exch --------------------------> x x : swap the top two\n");
  61                 print("    /cvarname load --------------------> x   : loads a cvar\n");
  62                 print("    /cvarname x def ------------------->     : writes to a cvar\n");
  63                 print("    f f add|sub|mul|div|mod|max|min ---> f   : adds/... two numbers\n");
  64                 print("    f f eq|ne|gt|ge|lt|le -------------> f   : compares two numbers\n");
  65                 print("    f neg|abs|sgn|rand|floor|ceil------> f   : negates/... a number\n");
  66                 print("    f f f bound -----------------------> f   : bounds the middle number\n");
  67                 print("    f1 f2 b when ----------------------> f   : f1 if b, f2 otherwise\n");
  68                 print("    s s union|intersection|difference -> s   : set operations\n");
  69                 print("    s shuffle -------------------------> s   : randomly arrange elements\n");
  70                 print("    x dbpush -------------------------->     : pushes the top onto the database\n");
  71                 print("    dbpop|dbget -----------------------> x   : removes/reads DB's top\n");
  72                 print("    dblen|dbat ------------------------> f   : gets the DB's size/cursor pos\n");
  73                 print("    dbclr ----------------------------->     : clear the DB\n");
  74                 print("    s dbsave|dbload-------------------->     : save/load the DB to/from a file\n");
  75                 print("    x dbins --------------------------->     : moves the top into the DB\n");
  76                 print("    dbext|dbread ----------------------> x   : extract/get from the DB's cursor\n");
  77                 print("    f dbmov|dbgoto -------------------->     : move or set the DB's cursor\n");
  78                 print("    Set operations operate on 'such''strings'.\n");
  79                 print("    Unknown tokens insert their cvar value.\n");
  80                 print("  maplist add map\n");
  81                 print("  maplist remove map\n");
  82                 print("  maplist shuffle\n");
  83                 return TRUE;
  84         }
  85
  86         if(argv(0) == "maplist")
  87         {
  88                 if(argv(1) == "add" && argc == 3)
  89                 {
  90                         f = fopen(strcat("maps/", argv(2), ".bsp"), FILE_READ);
  91                         if(f != -1)
  92                                 fclose(f);
  93                         else {
  94                                 print("maplist: ERROR: ", argv(2), " does not exist!\n");
  95                                 return TRUE;
  96                         }
  97                         if(cvar_string("g_maplist") == "")
  98                                 cvar_set("g_maplist", argv(2));
  99                         else
 100                                 cvar_set("g_maplist", strcat(argv(2), " ", cvar_string("g_maplist")));
 101                         return TRUE;
 102                 }
 103                 else if(argv(1) == "remove" && argc == 3)
 104                 {
 105                         s = argv(2);
 106                         n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 107                         s2 = "";
 108                         for(i = 0; i < n; ++i)
 109                                 if(argv(i) != s)
 110                                 {
 111                                         s2 = strcat(s2, " ", argv(i));
 112                                 }
 113                         s2 = substring(s2, 1, strlen(s2) - 1);
 114                         cvar_set("g_maplist", s2);
 115                         return TRUE;
 116                 }
 117                 else if(argv(1) == "shuffle" && argc == 2)
 118                 {
 119                         s = cvar_string("g_maplist");
 120                         for(i = 1; i < (n = tokenizebyseparator(s, " ")); ++i)
 121                         {
 122                                 // swap i-th item at a random position from 0 to i
 123                                 // proof for even distribution:
 124                                 //   n = 1: obvious
 125                                 //   n -> n+1:
 126                                 //     item n+1 gets at any position with chance 1/(n+1)
 127                                 //     all others will get their 1/n chance reduced by factor n/(n+1)
 128                                 //     to be on place n+1, their chance will be 1/(n+1)
 129                                 //     1/n * n/(n+1) = 1/(n+1)
 130                                 //     q.e.d.
 131                                 f = floor(random() * (i + 1)); // 0 to i
 132                                 if(f == i)
 133                                         continue; // no change
 134
 135                                 s2 = "";
 136                                 for(j = 0; j < n; ++j)
 137                                         s2 = strcat(s2, " ", argv((j == i) ? f : (j == f) ? i : j));
 138                                 s = substring(s2, 1, strlen(s2) - 1);
 139                         }
 140                         cvar_set("g_maplist", s);
 141                         return TRUE;
 142                 }
 143         }
 144         else if(argc >= 3 && crc16(0, argv(0)) == 3029 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 38159)
 145         {
 146                 // test case for terrencehill's color codes
 147                 s = strdecolorize(substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 148                 s2 = "";
 149
 150                 n = strlen(s);
 151                 j = (6 * max(1, floor(strlen(s)/32 + random() * 2 - 1))) / n;
 152                 f = random() * 6;
 153
 154                 for(i = 0; i < n; ++i)
 155                 {
 156                         c = substring(s, i, 1);
 157
 158                         if(c == ";")
 159                                 c = ":";
 160                         else if(c == "^")
 161                         {
 162                                 c = "^^";
 163                                 if(substring(s, i+1, 1) == "^")
 164                                         ++i;
 165                         }
 166
 167                         if(c != " ")
 168                         {
 169                                 rgb = hsl_to_rgb('1 0 0' * (j * i + f) + '0 1 .5');
 170                                 c = strcat(rgb_to_hexcolor(rgb), c);
 171                         }
 172                         s2 = strcat(s2, c);
 173                 }
 174
 175                 localcmd(strcat(argv(1), " ", s2));
 176
 177                 return TRUE;
 178         }
 179         else if(argv(0) == "rpn")
 180         {
 181                 if(!rpn_db)
 182                 {
 183                         rpn_db = db_create();
 184                         db_put(rpn_db, "stack.pointer", "0");
 185                         db_put(rpn_db, "stack.pos", "-1");
 186                 }
 187                 if(argc >= 2)
 188                 {
 189                         float rpnpos;
 190                         string rpncmd;
 191                         float f2, f3;
 192                         rpn_sp = 0;
 193                         rpn_error = FALSE;
 194                         for(rpnpos = 1; rpnpos < argc; ++rpnpos)
 195                         {
 196                                 rpncmd = argv(rpnpos);
 197                                 f = strlen(rpncmd);
 198                                 if(rpncmd == "") {
 199                                 } else if(stof(substring(rpncmd, 0, 1)) > 0) {
 200                                         rpn_push(rpncmd);
 201                                 } else if(substring(rpncmd, 0, 1) == "0") {
 202                                         rpn_push(rpncmd);
 203                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "+") {
 204                                         rpn_push(rpncmd);
 205                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "-") {
 206                                         rpn_push(rpncmd);
 207                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "/") {
 208                                         rpn_push(substring(rpncmd, 1, strlen(rpncmd) - 1));
 209                                 } else if(rpncmd == "clear") {
 210                                         rpn_sp = 0;
 211                                 } else if(rpncmd == "def" || rpncmd == "=") {
 212                                         s = rpn_pop();
 213                                         s2 = rpn_pop();
 214 #ifdef MENUQC
 215                                         registercvar(s2, "", 0);
 216 #else
 217                                         registercvar(s2, "");
 218 #endif
 219                                         if(!rpn_error) // don't change cvars if a stack error had happened!
 220                                                 cvar_set(s2, s);
 221                                 } else if(rpncmd == "defs" || rpncmd == "@") {
 222                                         s = "";
 223                                         i = rpn_popf();
 224                                         j = (i == 0);
 225                                         while(rpn_sp > 1 && (j || i > 0))
 226                                         {
 227                                                 s = strcat("/", rpn_pop(), " ", s);
 228                                                 --i;
 229                                         }
 230                                         s2 = rpn_pop();
 231 #ifdef MENUQC
 232                                         registercvar(s2, "", 0);
 233 #else
 234                                         registercvar(s2, "");
 235 #endif
 236                                         if(!rpn_error) // don't change cvars if a stack error had happened!
 237                                                 cvar_set(s2, s);
 238                                 } else if(rpncmd == "load") {
 239                                         rpn_set(cvar_string(rpn_get()));
 240                                 } else if(rpncmd == "exch") {
 241                                         s = rpn_pop();
 242                                         s2 = rpn_get();
 243                                         rpn_set(s);
 244                                         rpn_push(s2);
 245                                 } else if(rpncmd == "dup") {
 246                                         rpn_push(rpn_get());
 247                                 } else if(rpncmd == "pop") {
 248                                         rpn_pop();
 249                                 } else if(rpncmd == "add" || rpncmd == "+") {
 250                                         f = rpn_popf();
 251                                         rpn_setf(rpn_getf() + f);
 252                                 } else if(rpncmd == "sub" || rpncmd == "-") {
 253                                         f = rpn_popf();
 254                                         rpn_setf(rpn_getf() - f);
 255                                 } else if(rpncmd == "mul" || rpncmd == "*") {
 256                                         f = rpn_popf();
 257                                         rpn_setf(rpn_getf() * f);
 258                                 } else if(rpncmd == "div" || rpncmd == "/") {
 259                                         f = rpn_popf();
 260                                         rpn_setf(rpn_getf() / f);
 261                                 } else if(rpncmd == "mod" || rpncmd == "%") {
 262                                         f = rpn_popf();
 263                                         f2 = rpn_getf();
 264                                         rpn_setf(f2 - f * floor(f2 / f));
 265                                 } else if(rpncmd == "abs") {
 266                                         rpn_setf(fabs(rpn_getf()));
 267                                 } else if(rpncmd == "sgn") {
 268                                         f = rpn_getf();
 269                                         if(f < 0)
 270                                                 rpn_set("-1");
 271                                         else if(f > 0)
 272                                                 rpn_set("1");
 273                                         else
 274                                                 rpn_set("0");
 275                                 } else if(rpncmd == "neg" || rpncmd == "~") {
 276                                         rpn_setf(-rpn_getf());
 277                                 } else if(rpncmd == "floor" || rpncmd == "f") {
 278                                         rpn_setf(floor(rpn_getf()));
 279                                 } else if(rpncmd == "ceil" || rpncmd == "c") {
 280                                         rpn_setf(ceil(rpn_getf()));
 281                                 } else if(rpncmd == "max") {
 282                                         f = rpn_popf();
 283                                         f2 = rpn_getf();
 284                                         rpn_setf(max(f2, f));
 285                                 } else if(rpncmd == "min") {
 286                                         f = rpn_popf();
 287                                         f2 = rpn_getf();
 288                                         rpn_setf(min(f2, f));
 289                                 } else if(rpncmd == "bound") {
 290                                         f = rpn_popf();
 291                                         f2 = rpn_popf();
 292                                         f3 = rpn_getf();
 293                                         rpn_setf(bound(f3, f2, f));
 294                                 } else if(rpncmd == "when") {
 295                                         f = rpn_popf();
 296                                         f2 = rpn_popf();
 297                                         f3 = rpn_getf();
 298                                         if(f)
 299                                                 rpn_setf(f3);
 300                                         else
 301                                                 rpn_setf(f2);
 302                                 } else if(rpncmd == ">" || rpncmd == "gt") {
 303                                         f = rpn_popf();
 304                                         rpn_setf(rpn_getf() > f);
 305                                 } else if(rpncmd == "<" || rpncmd == "lt") {
 306                                         f = rpn_popf();
 307                                         rpn_setf(rpn_getf() < f);
 308                                 } else if(rpncmd == "==" || rpncmd == "eq") {
 309                                         f = rpn_popf();
 310                                         rpn_setf(rpn_getf() == f);
 311                                 } else if(rpncmd == ">=" || rpncmd == "ge") {
 312                                         f = rpn_popf();
 313                                         rpn_setf(rpn_getf() >= f);
 314                                 } else if(rpncmd == "<=" || rpncmd == "le") {
 315                                         f = rpn_popf();
 316                                         rpn_setf(rpn_getf() <= f);
 317                                 } else if(rpncmd == "!=" || rpncmd == "ne") {
 318                                         f = rpn_popf();
 319                                         rpn_setf(rpn_getf() != f);
 320                                 } else if(rpncmd == "rand") {
 321                                         rpn_setf(ceil(random() * rpn_getf()) - 1);
 322                                 } else if(rpncmd == "crc16") {
 323                                         rpn_setf(crc16(FALSE, rpn_get()));
 324                                 } else if(rpncmd == "dbpush") {
 325                                         s = rpn_pop();
 326                                         if(!rpn_error)
 327                                         {
 328                                                 i = stof(db_get(rpn_db, "stack.pointer"));
 329                                                 db_put(rpn_db, "stack.pointer", ftos(i+1));
 330                                                 db_put(rpn_db, strcat("stack.", ftos(i)), s);
 331                                         }
 332                                         if(!i)
 333                                                 db_put(rpn_db, "stack.pos", "0");
 334                                 } else if(rpncmd == "dbpop") {
 335                                         i = stof(db_get(rpn_db, "stack.pointer"));
 336                                         if(i)
 337                                         {
 338                                                 s = ftos(i-1);
 339                                                 db_put(rpn_db, "stack.pointer", s);
 340                                                 rpn_push(db_get(rpn_db, strcat("stack.", s)));
 341                                                 j = stof(db_get(rpn_db, "stack.pos"));
 342                                                 if(j >= i)
 343                                                         db_put(rpn_db, "stack.pos", ftos(i-2));
 344                                         } else {
 345                                                 rpn_error = 1;
 346                                                 print("rpn: database underflow\n");
 347                                         }
 348                                 } else if(rpncmd == "dbget") {
 349
 350                                         i = stof(db_get(rpn_db, "stack.pointer"));
 351                                         if(i)
 352                                         {
 353                                                 rpn_push(db_get(rpn_db, strcat("stack.", ftos(i-1))));
 354                                         } else {
 355                                                 rpn_error = 1;
 356                                                 print("rpn: database empty\n");
 357                                         }
 358                                 } else if(rpncmd == "dblen") {
 359                                         rpn_push(db_get(rpn_db, "stack.pointer"));
 360                                 } else if(rpncmd == "dbclr") {
 361                                         db_close(rpn_db);
 362                                         rpn_db = db_create();
 363                                         db_put(rpn_db, "stack.pointer", "0");
 364                                         db_put(rpn_db, "stack.pos", "-1");
 365                                 } else if(rpncmd == "dbsave") {
 366                                         s = rpn_pop();
 367                                         if(!rpn_error)
 368                                                 db_save(rpn_db, s);
 369                                 } else if(rpncmd == "dbload") {
 370                                         s = rpn_pop();
 371                                         if(!rpn_error)
 372                                         {
 373                                                 db_close(rpn_db);
 374                                                 rpn_db = db_load(s);
 375                                         }
 376                                 } else if(rpncmd == "dbins") {
 377                                         s = rpn_pop();
 378                                         if(!rpn_error)
 379                                                 //if(rpn_sp > 0)
 380                                         {
 381                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 382                                                 i = stof(db_get(rpn_db, "stack.pos"));
 383
 384                                                 if(i < 0)
 385                                                 {
 386                                                         i = 0;
 387                                                         db_put(rpn_db, "stack.pos", "0");
 388                                                 }
 389
 390                                                 db_put(rpn_db, "stack.pointer", ftos(j+1));
 391                                                 for(--j; j >= i; --j)
 392                                                 {
 393                                                         db_put(rpn_db, strcat("stack.", ftos(j+1)),
 394                                                                db_get(rpn_db, (strcat("stack.", ftos(j))))
 395                                                                 );
 396                                                 }
 397                                                 db_put(rpn_db, strcat("stack.", ftos(i)), s);
 398                                         }
 399                                 } else if(rpncmd == "dbext") {
 400                                         j = stof(db_get(rpn_db, "stack.pointer"));
 401                                         i = stof(db_get(rpn_db, "stack.pos"));
 402                                         if(!j)
 403                                         {
 404                                                 rpn_error = TRUE;
 405                                                 print("rpn: empty database\n");
 406                                         } else {
 407                                                 --j;
 408                                                 rpn_push(db_get(rpn_db, strcat("stack.", ftos(i))));
 409                                                 db_put(rpn_db, "stack.pointer", ftos(j));
 410                                                 if(i == j)
 411                                                 {
 412                                                         db_put(rpn_db, "stack.pos", ftos(j-1));
 413                                                 } else {
 414                                                         while(i < j)
 415                                                         {
 416                                                                 db_put(rpn_db, strcat("stack.", ftos(i)),
 417                                                                        db_get(rpn_db, (strcat("stack.", ftos(i+1))))
 418                                                                         );
 419                                                                 ++i;
 420                                                         }
 421                                                 }
 422                                         }
 423                                 } else if(rpncmd == "dbread") {
 424                                         s = db_get(rpn_db, "stack.pos");
 425                                         if(stof(s) >= 0)
 426                                         {
 427                                                 rpn_push(db_get(rpn_db, strcat("stack.", s)));
 428                                         } else {
 429                                                 rpn_error = 1;
 430                                                 print("rpn: empty database\n");
 431                                         }
 432                                 } else if(rpncmd == "dbat") {
 433                                         rpn_push(db_get(rpn_db, "stack.pos"));
 434                                 } else if(rpncmd == "dbmov") {
 435                                         j = stof(db_get(rpn_db, "stack.pointer"));
 436                                         i = stof(db_get(rpn_db, "stack.pos"));
 437                                         i += rpn_popf();
 438                                         if(!rpn_error)
 439                                         {
 440                                                 if(i < 0 || i >= j)
 441                                                 {
 442                                                         print("rpn: database cursor out of bounds\n");
 443                                                         rpn_error = TRUE;
 444                                                 }
 445                                                 if(!rpn_error)
 446                                                 {
 447                                                         db_put(rpn_db, "stack.pos", ftos(i));
 448                                                 }
 449                                         }
 450                                 } else if(rpncmd == "dbgoto") {
 451                                         s = rpn_pop();
 452                                         j = stof(db_get(rpn_db, "stack.pointer"));
 453                                         if(!j)
 454                                         {
 455                                                 rpn_error = TRUE;
 456                                                 print("rpn: empty database, cannot move cursor\n");
 457                                         }
 458                                         if(!rpn_error)
 459                                         {
 460                                                 if(s == "end")
 461                                                         i = stof(db_get(rpn_db, "stack.pointer"))-1;
 462                                                 else if(s == "beg")
 463                                                         i = 0;
 464                                                 else
 465                                                         i = stof(s);
 466
 467                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 468                                                 if(i < 0 || i >= j)
 469                                                 {
 470                                                         print("rpn: database cursor destination out of bounds\n");
 471                                                         rpn_error = TRUE;
 472                                                 }
 473                                                 if(!rpn_error)
 474                                                 {
 475                                                         db_put(rpn_db, "stack.pos", ftos(i));
 476                                                 }
 477                                         }
 478                                 } else if(rpncmd == "union") {
 479                                         // s s2 union
 480                                         s2 = rpn_pop();
 481                                         s = rpn_get();
 482                                         f = tokenize_sane(s);
 483                                         f2 = tokenize_sane(strcat(s, " ", s2));
 484                                         // tokens 0..(f-1) represent s
 485                                         // tokens f..f2 represent s2
 486                                         // UNION: add all tokens to s that are in s2 but not in s
 487                                         s = "";
 488                                         for(i = 0; i < f; ++i)
 489                                                 s = strcat(s, " ", argv(i));
 490                                         for(i = f; i < f2; ++i) {
 491                                                 for(j = 0; j < f; ++j)
 492                                                         if(argv(i) == argv(j))
 493                                                                 goto skip_union;
 494                                                 s = strcat(s, " ", argv(i));
 495 :skip_union
 496                                         }
 497                                         if(substring(s, 0, 1) == " ")
 498                                                 s = substring(s, 1, 99999);
 499                                         rpn_set(s);
 500                                         tokenize_sane(command);
 501                                 } else if(rpncmd == "intersection") {
 502                                         // s s2 intersection
 503                                         s2 = rpn_pop();
 504                                         s = rpn_get();
 505                                         f = tokenize_sane(s);
 506                                         f2 = tokenize_sane(strcat(s, " ", s2));
 507                                         // tokens 0..(f-1) represent s
 508                                         // tokens f..f2 represent s2
 509                                         // INTERSECTION: keep only the tokens from s that are also in s2
 510                                         s = "";
 511                                         for(i = 0; i < f; ++i) {
 512                                                 for(j = f; j < f2; ++j)
 513                                                         if(argv(i) == argv(j))
 514                                                         {
 515                                                                 s = strcat(s, " ", argv(i));
 516                                                                 break;
 517                                                         }
 518                                         }
 519                                         if(substring(s, 0, 1) == " ")
 520                                                 s = substring(s, 1, 99999);
 521                                         rpn_set(s);
 522                                         tokenize_sane(command);
 523                                 } else if(rpncmd == "difference") {
 524                                         // s s2 difference
 525                                         s2 = rpn_pop();
 526                                         s = rpn_get();
 527                                         f = tokenize_sane(s);
 528                                         f2 = tokenize_sane(strcat(s, " ", s2));
 529                                         // tokens 0..(f-1) represent s
 530                                         // tokens f..f2 represent s2
 531                                         // DIFFERENCE: keep only the tokens from s that are not in s2
 532                                         s = "";
 533                                         for(i = 0; i < f; ++i) {
 534                                                 for(j = f; j < f2; ++j)
 535                                                         if(argv(i) == argv(j))
 536                                                                 goto skip_difference;
 537                                                 s = strcat(s, " ", argv(i));
 538 :skip_difference
 539                                         }
 540                                         if(substring(s, 0, 1) == " ")
 541                                                 s = substring(s, 1, 99999);
 542                                         rpn_set(s);
 543                                         tokenize_sane(command);
 544                                 } else if(rpncmd == "shuffle") {
 545                                         // s shuffle
 546                                         s = rpn_get();
 547                                         f = tokenize_sane(s);
 548
 549                                         for(i = 0; i < f - 1; ++i) {
 550                                                 // move a random item from i..f-1 to position i
 551                                                 s = "";
 552                                                 f2 = floor(random() * (f - i) + i);
 553                                                 for(j = 0; j < i; ++j)
 554                                                         s = strcat(s, " ", argv(j));
 555                                                 s = strcat(s, " ", argv(f2));
 556                                                 for(j = i; j < f; ++j)
 557                                                         if(j != f2)
 558                                                                 s = strcat(s, " ", argv(j));
 559                                                 f = tokenize_sane(s);
 560                                         }
 561
 562                                         if(substring(s, 0, 1) == " ")
 563                                                 s = substring(s, 1, 99999);
 564                                         rpn_set(s);
 565                                         tokenize_sane(command);
 566                                         } else if(rpncmd == "fexists_assert") {
 567                                         s = rpn_pop();
 568                                         if(!rpn_error)
 569                                         {
 570                                                 f = fopen(s, FILE_READ);
 571                                                 if(f != -1)
 572                                                         fclose(f);
 573                                                 else {
 574                                                         print("rpn: ERROR: ", s, " does not exist!\n");
 575                                                         rpn_error = TRUE;
 576                                                 }
 577                                         }
 578                                 } else {
 579                                         rpn_push(cvar_string(rpncmd));
 580                                 }
 581                                 if(rpn_error)
 582                                         break;
 583                         }
 584                         while(rpn_sp > 0)
 585                         {
 586                                 s = rpn_pop();
 587                                 print("rpn: still on stack: ", s, "\n");
 588                         }
 589                         return TRUE;
 590                 }
 591 #ifdef MENUQC
 592         } else if(argv(0) == "cp") {
 593                 if(argc >= 2)
 594                 {
 595                         s = argv(1);
 596                         for(i = 2; i < argc; ++i)
 597                                 s = strcat(s, " ", argv(i));
 598                         centerprint(unescape(s));
 599                 }
 600                 return TRUE;
 601 #endif
 602         }
 603
 604         return FALSE;
 605 }