data/qcsrc/common/gamecommand.qc

   1 #define MAX_RPN_STACK 16
   2 float rpn_db;
   3 float rpn_error;
   4 float rpn_sp;
   5 string rpn_stack[MAX_RPN_STACK];
   6 string rpn_pop() {
   7         if(rpn_sp > 0) {
   8                 --rpn_sp;
   9                 return rpn_stack[rpn_sp];
  10         } else {
  11                 print("rpn: stack underflow\n");
  12                 rpn_error = TRUE;
  13                 return "";
  14         }
  15 }
  16 void rpn_push(string s) {
  17         if(rpn_sp < MAX_RPN_STACK) {
  18                 rpn_stack[rpn_sp] = s;
  19                 ++rpn_sp;
  20         } else {
  21                 print("rpn: stack overflow\n");
  22                 rpn_error = TRUE;
  23         }
  24 }
  25 string rpn_get() {
  26         if(rpn_sp > 0) {
  27                 return rpn_stack[rpn_sp - 1];
  28         } else {
  29                 print("rpn: empty stack\n");
  30                 rpn_error = TRUE;
  31                 return "";
  32         }
  33 }
  34 void rpn_set(string s) {
  35         if(rpn_sp > 0) {
  36                 rpn_stack[rpn_sp - 1] = s;
  37         } else {
  38                 print("rpn: empty stack\n");
  39                 rpn_error = TRUE;
  40         }
  41 }
  42 float rpn_getf() { return stof(rpn_get()); }
  43 float rpn_popf() { return stof(rpn_pop()); }
  44 void rpn_pushf(float f) { return rpn_push(ftos(f)); }
  45 void rpn_setf(float f) { return rpn_set(ftos(f)); }
  46
  47 #define NUM_MARKUPS     41
  48 float markup_init;
  49 string markup_from[NUM_MARKUPS];
  50 string markup_to[NUM_MARKUPS];
  51 void GameCommand_MarkupInit()
  52 {
  53         float i;
  54         if (markup_init)
  55                 return;
  56         markup_init = 1;
  57         i = 0;
  58         markup_from[i] = "&alien"; markup_to[i] = "\x12"; ++i;
  59         markup_from[i] = "&:-)"; markup_to[i] = "\x13"; ++i;
  60         markup_from[i] = "&:-("; markup_to[i] = "\x14"; ++i;
  61         markup_from[i] = "&x-P"; markup_to[i] = "\x15"; ++i;
  62         markup_from[i] = "&:-/"; markup_to[i] = "\x16"; ++i;
  63         markup_from[i] = "&:-D"; markup_to[i] = "\x17"; ++i;
  64         markup_from[i] = "&<<"; markup_to[i] = "\x18"; ++i;
  65         markup_from[i] = "&>>"; markup_to[i] = "\x19"; ++i;
  66         markup_from[i] = "&dot"; markup_to[i] = "\x1a"; ++i;
  67         markup_from[i] = "&^_"; markup_to[i] = "\x1b"; ++i;
  68         markup_from[i] = "&ysplat"; markup_to[i] = "\x1c"; ++i;
  69         markup_from[i] = "&-]"; markup_to[i] = "\x1d"; ++i;
  70         markup_from[i] = "&--"; markup_to[i] = "\x1e"; ++i;
  71         markup_from[i] = "&[-"; markup_to[i] = "\x1f"; ++i;
  72         markup_from[i] = "&s<"; markup_to[i] = "\x2c"; ++i;
  73         markup_from[i] = "&s>"; markup_to[i] = "\x2e"; ++i;
  74         markup_from[i] = "&<-"; markup_to[i] = "\x7f"; ++i;
  75         markup_from[i] = "&[="; markup_to[i] = "\x80"; ++i;
  76         markup_from[i] = "&=="; markup_to[i] = "\x81"; ++i;
  77         markup_from[i] = "&=]"; markup_to[i] = "\x82"; ++i;
  78         markup_from[i] = "&r!"; markup_to[i] = "\x84"; ++i;
  79         markup_from[i] = "&|o|"; markup_to[i] = "\x85"; ++i;
  80         markup_from[i] = "&|u|"; markup_to[i] = "\x86"; ++i;
  81         markup_from[i] = "&|i|"; markup_to[i] = "\x87"; ++i;
  82         markup_from[i] = "&|c|"; markup_to[i] = "\x88"; ++i;
  83         markup_from[i] = "&[c]"; markup_to[i] = "\x89"; ++i;
  84         markup_from[i] = "&[n]"; markup_to[i] = "\x8a"; ++i;
  85         markup_from[i] = "&[]"; markup_to[i] = "\x8b"; ++i;
  86         markup_from[i] = "&r?"; markup_to[i] = "\x8c"; ++i;
  87         markup_from[i] = "&|>"; markup_to[i] = "\x8d"; ++i;
  88         markup_from[i] = "&splat0"; markup_to[i] = "\x8e"; ++i;
  89         markup_from[i] = "&splat1"; markup_to[i] = "\x8f"; ++i;
  90         markup_from[i] = "&[["; markup_to[i] = "\x90"; ++i;
  91         markup_from[i] = "&]]"; markup_to[i] = "\x91"; ++i;
  92         markup_from[i] = "&splat2"; markup_to[i] = "\x9a"; ++i;
  93         markup_from[i] = "&)("; markup_to[i] = "\x9b"; ++i;
  94         markup_from[i] = "&splat3"; markup_to[i] = "\x9c"; ++i;
  95         markup_from[i] = "&(."; markup_to[i] = "\x9d"; ++i;
  96         markup_from[i] = "&.."; markup_to[i] = "\x9e"; ++i;
  97         markup_from[i] = "&.)"; markup_to[i] = "\x9f"; ++i;
  98         markup_from[i] = "&<|"; markup_to[i] = "\xff"; ++i;
  99 }
 100
 101 string GameCommand_Markup(string s2)
 102 {
 103         float red, ccase, i, j;
 104         string s, s3;
 105
 106         GameCommand_MarkupInit();
 107
 108         s = "";
 109
 110         red = 0;
 111         ccase = 0;
 112         for(i = 0; i < strlen(s2); ++i)
 113         {
 114                 for(j = 0; j < NUM_MARKUPS; ++j)
 115                 {
 116                         s3 = substring(s2, i, strlen(markup_from[j]));
 117                         if (s3 == markup_from[j])
 118                         {
 119                                 s = strcat(s, markup_to[j]);
 120                                 i += strlen(markup_from[j]) - 1;
 121                                 break;
 122                         }
 123                 }
 124
 125                 if(j == NUM_MARKUPS)
 126                 {
 127                         if(substring(s2, i, 2) == "&&")
 128                         {
 129                                 s = strcat(s, strconv(ccase, red, red, "&"));
 130                                 ++i;
 131                         }
 132                         else if(substring(s2, i, 2) == "&d")
 133                         {
 134                                 red = 2;
 135                                 ccase = 0;
 136                                 ++i;
 137                         }
 138                         else if(substring(s2, i, 2) == "&a")
 139                         {
 140                                 red = 2;
 141                                 ccase = 2;
 142                                 ++i;
 143                         }
 144                         else if(substring(s2, i, 2) == "&n")
 145                         {
 146                                 red = 0;
 147                                 ccase = 0;
 148                                 ++i;
 149                         }
 150                         else
 151                                 s = strcat(s, strconv(ccase, red, red, substring(s2, i, 1)));
 152                 }
 153         }
 154
 155         return s;
 156 }
 157
 158 float GameCommand_Generic(string command)
 159 {
 160         float argc;
 161         float i, j, f, n;
 162         vector rgb;
 163         string s, s2, c;
 164         argc = tokenize_console(command);
 165         if(argv(0) == "help")
 166         {
 167                 print("  rpn EXPRESSION... - a RPN calculator.\n");
 168                 print("    Operator description (x: string, s: set, f: float):\n");
 169                 print("    x pop ----------------------------->     : removes the top\n");
 170                 print("    x dup -----------------------------> x x : duplicates the top\n");
 171                 print("    x x exch --------------------------> x x : swap the top two\n");
 172                 print("    /cvarname load --------------------> x   : loads a cvar\n");
 173                 print("    /cvarname x def ------------------->     : writes to a cvar\n");
 174                 print("    f f add|sub|mul|div|mod|max|min ---> f   : adds/... two numbers\n");
 175                 print("    f f eq|ne|gt|ge|lt|le -------------> f   : compares two numbers\n");
 176                 print("    f neg|abs|sgn|rand|floor|ceil------> f   : negates/... a number\n");
 177                 print("    f f f bound -----------------------> f   : bounds the middle number\n");
 178                 print("    f1 f2 b when ----------------------> f   : f1 if b, f2 otherwise\n");
 179                 print("    s s union|intersection|difference -> s   : set operations\n");
 180                 print("    s shuffle -------------------------> s   : randomly arrange elements\n");
 181                 print("    x dbpush -------------------------->     : pushes the top onto the database\n");
 182                 print("    dbpop|dbget -----------------------> x   : removes/reads DB's top\n");
 183                 print("    dblen|dbat ------------------------> f   : gets the DB's size/cursor pos\n");
 184                 print("    dbclr ----------------------------->     : clear the DB\n");
 185                 print("    s dbsave|dbload-------------------->     : save/load the DB to/from a file\n");
 186                 print("    x dbins --------------------------->     : moves the top into the DB\n");
 187                 print("    dbext|dbread ----------------------> x   : extract/get from the DB's cursor\n");
 188                 print("    f dbmov|dbgoto -------------------->     : move or set the DB's cursor\n");
 189                 print("    s localtime -----------------------> s   : formats the current local time\n");
 190                 print("    s gmtime --------------------------> s   : formats the current UTC time\n");
 191                 print("    time ------------------------------> f   : seconds since VM start\n");
 192                 print("    Set operations operate on 'such''strings'.\n");
 193                 print("    Unknown tokens insert their cvar value.\n");
 194                 print("  maplist add map\n");
 195                 print("  maplist remove map\n");
 196                 print("  maplist shuffle\n");
 197                 print("  maplist cleanup\n");
 198                 print("  maplist maplist\n");
 199                 print("  maplist lsmaps\n");
 200                 print("  addtolist variable addedvalue\n");
 201                 print("  records\n");
 202                 print("  rankings (map argument optional)\n");
 203                 return TRUE;
 204         }
 205
 206         if(argv(0) == "maplist")
 207         {
 208                 if(argv(1) == "add" && argc == 3)
 209                 {
 210                         f = fopen(strcat("maps/", argv(2), ".bsp"), FILE_READ);
 211                         if(f != -1)
 212                                 fclose(f);
 213                         else {
 214                                 print("maplist: ERROR: ", argv(2), " does not exist!\n");
 215                                 return TRUE;
 216                         }
 217                         if(cvar_string("g_maplist") == "")
 218                                 cvar_set("g_maplist", argv(2));
 219                         else
 220                                 cvar_set("g_maplist", strcat(argv(2), " ", cvar_string("g_maplist")));
 221                         return TRUE;
 222                 }
 223                 else if(argv(1) == "remove" && argc == 3)
 224                 {
 225                         s = argv(2);
 226                         n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 227                         s2 = "";
 228                         for(i = 0; i < n; ++i)
 229                                 if(argv(i) != s)
 230                                         s2 = strcat(s2, " ", argv(i));
 231                         s2 = substring(s2, 1, strlen(s2) - 1);
 232                         cvar_set("g_maplist", s2);
 233                         return TRUE;
 234                 }
 235                 else if(argv(1) == "shuffle" && argc == 2)
 236                 {
 237                         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
 238                         return TRUE;
 239                 }
 240                 else if(argv(1) == "cleanup")
 241                 {
 242                         MapInfo_Enumerate();
 243                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 244                         n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 245                         s2 = "";
 246                         for(i = 0; i < n; ++i)
 247                                 if(MapInfo_CheckMap(argv(i)))
 248                                         s2 = strcat(s2, " ", argv(i));
 249                         s2 = substring(s2, 1, strlen(s2) - 1);
 250                         cvar_set("g_maplist", s2);
 251                         return TRUE;
 252                 }
 253                 else if(argv(1) == "maplist") {
 254                         print(maplist_reply);
 255                         return TRUE;
 256                 }
 257                 else if(argv(1) == "lsmaps") {
 258                         print(lsmaps_reply);
 259                         return TRUE;
 260                 }
 261         }
 262         else if(argc >= 3 && argv(0) == "red")
 263         {
 264                 s = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 265                 localcmd(strcat(argv(1), " ", GameCommand_Markup(s)));
 266                 return TRUE;
 267         }
 268         else if(argc >= 3 && crc16(0, argv(0)) == 38566 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 59830)
 269         {
 270                 // other test case
 271                 s = strconv(2, 0, 0, substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 272
 273                 n = floor(random() * 6 + 2);
 274
 275                 s2 = "";
 276                 for(i = 0; i < n; ++i)
 277                 {
 278                         s2 = strcat(s2, "AH");
 279                 }
 280
 281                 if(random() < 0.1)
 282                         s2 = strcat(substring(s2, 1, strlen(s2) - 1), "A");
 283
 284                 if(s == "")
 285                         s = s2;
 286                 else
 287                         if(random() < 0.8)
 288                                 s = strcat(s, " ", s2);
 289                         else
 290                                 s = strcat(s2, " ", s);
 291
 292                 s2 = substring(s, strlen(s) - 2, 2);
 293                 if(s2 == "AH" || s2 == "AY")
 294                         s = strcat(s, "))");
 295                 else
 296                         s = strcat(s, " ))");
 297
 298                 if(random() < 0.1)
 299                         s = substring(s, 0, strlen(s) - 1);
 300
 301                 if(random() < 0.1)
 302                         s = strconv(1, 0, 0, s);
 303
 304                 localcmd(strcat(argv(1), " ", s));
 305
 306                 return TRUE;
 307         }
 308         else if(argc >= 3 && crc16(0, argv(0)) == 3826 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 55970)
 309         {
 310                 // test case for terrencehill's color codes
 311                 s = strdecolorize(substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 312                 s2 = "";
 313
 314                 n = strlen(s);
 315                 j = ((6 * max(1, floor(strlen(s)/32 + random() * 2 - 1))) / n) * (1 - 2 * (random() > 0.5));
 316                 f = random() * 6;
 317
 318                 for(i = 0; i < n; ++i)
 319                 {
 320                         c = substring(s, i, 1);
 321
 322                         if(c == ";")
 323                                 c = ":";
 324                         else if(c == "^")
 325                         {
 326                                 c = "^^";
 327                                 if(substring(s, i+1, 1) == "^")
 328                                         ++i;
 329                         }
 330
 331                         if(c != " ")
 332                         {
 333                                 rgb = hsl_to_rgb('1 0 0' * (j * i + f) + '0 1 .5');
 334                                 c = strcat(rgb_to_hexcolor(rgb), c);
 335                         }
 336                         s2 = strcat(s2, c);
 337                 }
 338
 339                 localcmd(strcat(argv(1), " ", s2));
 340
 341                 return TRUE;
 342         }
 343         else if(argv(0) == "rpn")
 344         {
 345                 if(!rpn_db)
 346                 {
 347                         rpn_db = db_create();
 348                         db_put(rpn_db, "stack.pointer", "0");
 349                         db_put(rpn_db, "stack.pos", "-1");
 350                 }
 351                 if(argc >= 2)
 352                 {
 353                         float rpnpos;
 354                         string rpncmd;
 355                         float f2, f3;
 356                         rpn_sp = 0;
 357                         rpn_error = FALSE;
 358                         for(rpnpos = 1; rpnpos < argc; ++rpnpos)
 359                         {
 360                                 rpncmd = argv(rpnpos);
 361                                 f = strlen(rpncmd);
 362                                 if(rpncmd == "") {
 363                                 } else if(stof(substring(rpncmd, 0, 1)) > 0) {
 364                                         rpn_push(rpncmd);
 365                                 } else if(substring(rpncmd, 0, 1) == "0") {
 366                                         rpn_push(rpncmd);
 367                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "+") {
 368                                         rpn_push(rpncmd);
 369                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "-") {
 370                                         rpn_push(rpncmd);
 371                                 } else if(f >= 2 && substring(rpncmd, 0, 1) == "/") {
 372                                         rpn_push(substring(rpncmd, 1, strlen(rpncmd) - 1));
 373                                 } else if(rpncmd == "clear") {
 374                                         rpn_sp = 0;
 375                                 } else if(rpncmd == "def" || rpncmd == "=") {
 376                                         s = rpn_pop();
 377                                         s2 = rpn_pop();
 378
 379                                         if(s2 != "")
 380                                         {
 381 #ifdef MENUQC
 382                                                 registercvar(s2, "", 0);
 383 #else
 384                                                 registercvar(s2, "");
 385 #endif
 386                                                 if(!rpn_error) // don't change cvars if a stack error had happened!
 387                                                         cvar_set(s2, s);
 388                                         }
 389                                         else
 390                                         {
 391                                                 print("rpn: empty cvar name for 'def'\n");
 392                                                 rpn_error = TRUE;
 393                                         }
 394                                 } else if(rpncmd == "defs" || rpncmd == "@") {
 395                                         s = "";
 396                                         i = rpn_popf();
 397                                         j = (i == 0);
 398                                         while(rpn_sp > 1 && (j || i > 0))
 399                                         {
 400                                                 s = strcat("/", rpn_pop(), " ", s);
 401                                                 --i;
 402                                         }
 403                                         s2 = rpn_pop();
 404                                         if(s2 != "")
 405                                         {
 406 #ifdef MENUQC
 407                                                 registercvar(s2, "", 0);
 408 #else
 409                                                 registercvar(s2, "");
 410 #endif
 411                                                 if(!rpn_error) // don't change cvars if a stack error had happened!
 412                                                         cvar_set(s2, s);
 413                                         }
 414                                         else
 415                                         {
 416                                                 print("rpn: empty cvar name for 'defs'\n");
 417                                                 rpn_error = TRUE;
 418                                         }
 419                                 } else if(rpncmd == "load") {
 420 #ifdef SVQC
 421                                         rpn_set(cvar_string_builtin(rpn_get())); // cvar name comes from user
 422 #else
 423                                         rpn_set(cvar_string(rpn_get()));
 424 #endif
 425                                 } else if(rpncmd == "exch") {
 426                                         s = rpn_pop();
 427                                         s2 = rpn_get();
 428                                         rpn_set(s);
 429                                         rpn_push(s2);
 430                                 } else if(rpncmd == "dup") {
 431                                         rpn_push(rpn_get());
 432                                 } else if(rpncmd == "pop") {
 433                                         rpn_pop();
 434                                 } else if(rpncmd == "add" || rpncmd == "+") {
 435                                         f = rpn_popf();
 436                                         rpn_setf(rpn_getf() + f);
 437                                 } else if(rpncmd == "sub" || rpncmd == "-") {
 438                                         f = rpn_popf();
 439                                         rpn_setf(rpn_getf() - f);
 440                                 } else if(rpncmd == "mul" || rpncmd == "*") {
 441                                         f = rpn_popf();
 442                                         rpn_setf(rpn_getf() * f);
 443                                 } else if(rpncmd == "div" || rpncmd == "/") {
 444                                         f = rpn_popf();
 445                                         rpn_setf(rpn_getf() / f);
 446                                 } else if(rpncmd == "mod" || rpncmd == "%") {
 447                                         f = rpn_popf();
 448                                         f2 = rpn_getf();
 449                                         rpn_setf(f2 - f * floor(f2 / f));
 450                                 } else if(rpncmd == "abs") {
 451                                         rpn_setf(fabs(rpn_getf()));
 452                                 } else if(rpncmd == "sgn") {
 453                                         f = rpn_getf();
 454                                         if(f < 0)
 455                                                 rpn_set("-1");
 456                                         else if(f > 0)
 457                                                 rpn_set("1");
 458                                         else
 459                                                 rpn_set("0");
 460                                 } else if(rpncmd == "neg" || rpncmd == "~") {
 461                                         rpn_setf(-rpn_getf());
 462                                 } else if(rpncmd == "floor" || rpncmd == "f") {
 463                                         rpn_setf(floor(rpn_getf()));
 464                                 } else if(rpncmd == "ceil" || rpncmd == "c") {
 465                                         rpn_setf(ceil(rpn_getf()));
 466                                 } else if(rpncmd == "max") {
 467                                         f = rpn_popf();
 468                                         f2 = rpn_getf();
 469                                         rpn_setf(max(f2, f));
 470                                 } else if(rpncmd == "min") {
 471                                         f = rpn_popf();
 472                                         f2 = rpn_getf();
 473                                         rpn_setf(min(f2, f));
 474                                 } else if(rpncmd == "bound") {
 475                                         f = rpn_popf();
 476                                         f2 = rpn_popf();
 477                                         f3 = rpn_getf();
 478                                         rpn_setf(bound(f3, f2, f));
 479                                 } else if(rpncmd == "when") {
 480                                         f = rpn_popf();
 481                                         f2 = rpn_popf();
 482                                         f3 = rpn_getf();
 483                                         if(f)
 484                                                 rpn_setf(f3);
 485                                         else
 486                                                 rpn_setf(f2);
 487                                 } else if(rpncmd == ">" || rpncmd == "gt") {
 488                                         f = rpn_popf();
 489                                         rpn_setf(rpn_getf() > f);
 490                                 } else if(rpncmd == "<" || rpncmd == "lt") {
 491                                         f = rpn_popf();
 492                                         rpn_setf(rpn_getf() < f);
 493                                 } else if(rpncmd == "==" || rpncmd == "eq") {
 494                                         f = rpn_popf();
 495                                         rpn_setf(rpn_getf() == f);
 496                                 } else if(rpncmd == ">=" || rpncmd == "ge") {
 497                                         f = rpn_popf();
 498                                         rpn_setf(rpn_getf() >= f);
 499                                 } else if(rpncmd == "<=" || rpncmd == "le") {
 500                                         f = rpn_popf();
 501                                         rpn_setf(rpn_getf() <= f);
 502                                 } else if(rpncmd == "!=" || rpncmd == "ne") {
 503                                         f = rpn_popf();
 504                                         rpn_setf(rpn_getf() != f);
 505                                 } else if(rpncmd == "rand") {
 506                                         rpn_setf(ceil(random() * rpn_getf()) - 1);
 507                                 } else if(rpncmd == "crc16") {
 508                                         rpn_setf(crc16(FALSE, rpn_get()));
 509                                 } else if(rpncmd == "dbpush") {
 510                                         s = rpn_pop();
 511                                         if(!rpn_error)
 512                                         {
 513                                                 i = stof(db_get(rpn_db, "stack.pointer"));
 514                                                 db_put(rpn_db, "stack.pointer", ftos(i+1));
 515                                                 db_put(rpn_db, strcat("stack.", ftos(i)), s);
 516                                         }
 517                                         if(!i)
 518                                                 db_put(rpn_db, "stack.pos", "0");
 519                                 } else if(rpncmd == "dbpop") {
 520                                         i = stof(db_get(rpn_db, "stack.pointer"));
 521                                         if(i)
 522                                         {
 523                                                 s = ftos(i-1);
 524                                                 db_put(rpn_db, "stack.pointer", s);
 525                                                 rpn_push(db_get(rpn_db, strcat("stack.", s)));
 526                                                 j = stof(db_get(rpn_db, "stack.pos"));
 527                                                 if(j >= i)
 528                                                         db_put(rpn_db, "stack.pos", ftos(i-2));
 529                                         } else {
 530                                                 rpn_error = 1;
 531                                                 print("rpn: database underflow\n");
 532                                         }
 533                                 } else if(rpncmd == "dbget") {
 534
 535                                         i = stof(db_get(rpn_db, "stack.pointer"));
 536                                         if(i)
 537                                         {
 538                                                 rpn_push(db_get(rpn_db, strcat("stack.", ftos(i-1))));
 539                                         } else {
 540                                                 rpn_error = 1;
 541                                                 print("rpn: database empty\n");
 542                                         }
 543                                 } else if(rpncmd == "dblen") {
 544                                         rpn_push(db_get(rpn_db, "stack.pointer"));
 545                                 } else if(rpncmd == "dbclr") {
 546                                         db_close(rpn_db);
 547                                         rpn_db = db_create();
 548                                         db_put(rpn_db, "stack.pointer", "0");
 549                                         db_put(rpn_db, "stack.pos", "-1");
 550                                 } else if(rpncmd == "dbsave") {
 551                                         s = rpn_pop();
 552                                         if(!rpn_error)
 553                                                 db_save(rpn_db, s);
 554                                 } else if(rpncmd == "dbload") {
 555                                         s = rpn_pop();
 556                                         if(!rpn_error)
 557                                         {
 558                                                 db_close(rpn_db);
 559                                                 rpn_db = db_load(s);
 560                                         }
 561                                 } else if(rpncmd == "dbins") {
 562                                         s = rpn_pop();
 563                                         if(!rpn_error)
 564                                                 //if(rpn_sp > 0)
 565                                         {
 566                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 567                                                 i = stof(db_get(rpn_db, "stack.pos"));
 568
 569                                                 if(i < 0)
 570                                                 {
 571                                                         i = 0;
 572                                                         db_put(rpn_db, "stack.pos", "0");
 573                                                 }
 574
 575                                                 db_put(rpn_db, "stack.pointer", ftos(j+1));
 576                                                 for(--j; j >= i; --j)
 577                                                 {
 578                                                         db_put(rpn_db, strcat("stack.", ftos(j+1)),
 579                                                                db_get(rpn_db, (strcat("stack.", ftos(j))))
 580                                                                 );
 581                                                 }
 582                                                 db_put(rpn_db, strcat("stack.", ftos(i)), s);
 583                                         }
 584                                 } else if(rpncmd == "dbext") {
 585                                         j = stof(db_get(rpn_db, "stack.pointer"));
 586                                         i = stof(db_get(rpn_db, "stack.pos"));
 587                                         if(!j)
 588                                         {
 589                                                 rpn_error = TRUE;
 590                                                 print("rpn: empty database\n");
 591                                         } else {
 592                                                 --j;
 593                                                 rpn_push(db_get(rpn_db, strcat("stack.", ftos(i))));
 594                                                 db_put(rpn_db, "stack.pointer", ftos(j));
 595                                                 if(i == j)
 596                                                 {
 597                                                         db_put(rpn_db, "stack.pos", ftos(j-1));
 598                                                 } else {
 599                                                         while(i < j)
 600                                                         {
 601                                                                 db_put(rpn_db, strcat("stack.", ftos(i)),
 602                                                                        db_get(rpn_db, (strcat("stack.", ftos(i+1))))
 603                                                                         );
 604                                                                 ++i;
 605                                                         }
 606                                                 }
 607                                         }
 608                                 } else if(rpncmd == "dbread") {
 609                                         s = db_get(rpn_db, "stack.pos");
 610                                         if(stof(s) >= 0)
 611                                         {
 612                                                 rpn_push(db_get(rpn_db, strcat("stack.", s)));
 613                                         } else {
 614                                                 rpn_error = 1;
 615                                                 print("rpn: empty database\n");
 616                                         }
 617                                 } else if(rpncmd == "dbat") {
 618                                         rpn_push(db_get(rpn_db, "stack.pos"));
 619                                 } else if(rpncmd == "dbmov") {
 620                                         j = stof(db_get(rpn_db, "stack.pointer"));
 621                                         i = stof(db_get(rpn_db, "stack.pos"));
 622                                         i += rpn_popf();
 623                                         if(!rpn_error)
 624                                         {
 625                                                 if(i < 0 || i >= j)
 626                                                 {
 627                                                         print("rpn: database cursor out of bounds\n");
 628                                                         rpn_error = TRUE;
 629                                                 }
 630                                                 if(!rpn_error)
 631                                                 {
 632                                                         db_put(rpn_db, "stack.pos", ftos(i));
 633                                                 }
 634                                         }
 635                                 } else if(rpncmd == "dbgoto") {
 636                                         s = rpn_pop();
 637                                         j = stof(db_get(rpn_db, "stack.pointer"));
 638                                         if(!j)
 639                                         {
 640                                                 rpn_error = TRUE;
 641                                                 print("rpn: empty database, cannot move cursor\n");
 642                                         }
 643                                         if(!rpn_error)
 644                                         {
 645                                                 if(s == "end")
 646                                                         i = stof(db_get(rpn_db, "stack.pointer"))-1;
 647                                                 else if(s == "beg")
 648                                                         i = 0;
 649                                                 else
 650                                                         i = stof(s);
 651
 652                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 653                                                 if(i < 0 || i >= j)
 654                                                 {
 655                                                         print("rpn: database cursor destination out of bounds\n");
 656                                                         rpn_error = TRUE;
 657                                                 }
 658                                                 if(!rpn_error)
 659                                                 {
 660                                                         db_put(rpn_db, "stack.pos", ftos(i));
 661                                                 }
 662                                         }
 663                                 } else if(rpncmd == "union") {
 664                                         // s s2 union
 665                                         s2 = rpn_pop();
 666                                         s = rpn_get();
 667                                         f = tokenize_console(s);
 668                                         f2 = tokenize_console(strcat(s, " ", s2));
 669                                         // tokens 0..(f-1) represent s
 670                                         // tokens f..f2 represent s2
 671                                         // UNION: add all tokens to s that are in s2 but not in s
 672                                         s = "";
 673                                         for(i = 0; i < f; ++i)
 674                                                 s = strcat(s, " ", argv(i));
 675                                         for(i = f; i < f2; ++i) {
 676                                                 for(j = 0; j < f; ++j)
 677                                                         if(argv(i) == argv(j))
 678                                                                 goto skip_union;
 679                                                 s = strcat(s, " ", argv(i));
 680 :skip_union
 681                                         }
 682                                         if(substring(s, 0, 1) == " ")
 683                                                 s = substring(s, 1, 99999);
 684                                         rpn_set(s);
 685                                         tokenize_console(command);
 686                                 } else if(rpncmd == "intersection") {
 687                                         // s s2 intersection
 688                                         s2 = rpn_pop();
 689                                         s = rpn_get();
 690                                         f = tokenize_console(s);
 691                                         f2 = tokenize_console(strcat(s, " ", s2));
 692                                         // tokens 0..(f-1) represent s
 693                                         // tokens f..f2 represent s2
 694                                         // INTERSECTION: keep only the tokens from s that are also in s2
 695                                         s = "";
 696                                         for(i = 0; i < f; ++i) {
 697                                                 for(j = f; j < f2; ++j)
 698                                                         if(argv(i) == argv(j))
 699                                                         {
 700                                                                 s = strcat(s, " ", argv(i));
 701                                                                 break;
 702                                                         }
 703                                         }
 704                                         if(substring(s, 0, 1) == " ")
 705                                                 s = substring(s, 1, 99999);
 706                                         rpn_set(s);
 707                                         tokenize_console(command);
 708                                 } else if(rpncmd == "difference") {
 709                                         // s s2 difference
 710                                         s2 = rpn_pop();
 711                                         s = rpn_get();
 712                                         f = tokenize_console(s);
 713                                         f2 = tokenize_console(strcat(s, " ", s2));
 714                                         // tokens 0..(f-1) represent s
 715                                         // tokens f..f2 represent s2
 716                                         // DIFFERENCE: keep only the tokens from s that are not in s2
 717                                         s = "";
 718                                         for(i = 0; i < f; ++i) {
 719                                                 for(j = f; j < f2; ++j)
 720                                                         if(argv(i) == argv(j))
 721                                                                 goto skip_difference;
 722                                                 s = strcat(s, " ", argv(i));
 723 :skip_difference
 724                                         }
 725                                         if(substring(s, 0, 1) == " ")
 726                                                 s = substring(s, 1, 99999);
 727                                         rpn_set(s);
 728                                         tokenize_console(command);
 729                                 } else if(rpncmd == "shuffle") {
 730                                         // s shuffle
 731                                         s = rpn_get();
 732                                         f = tokenize_console(s);
 733
 734                                         for(i = 0; i < f - 1; ++i) {
 735                                                 // move a random item from i..f-1 to position i
 736                                                 s = "";
 737                                                 f2 = floor(random() * (f - i) + i);
 738                                                 for(j = 0; j < i; ++j)
 739                                                         s = strcat(s, " ", argv(j));
 740                                                 s = strcat(s, " ", argv(f2));
 741                                                 for(j = i; j < f; ++j)
 742                                                         if(j != f2)
 743                                                                 s = strcat(s, " ", argv(j));
 744                                                 f = tokenize_console(s);
 745                                         }
 746
 747                                         if(substring(s, 0, 1) == " ")
 748                                                 s = substring(s, 1, 99999);
 749                                         rpn_set(s);
 750                                         tokenize_console(command);
 751                                 } else if(rpncmd == "fexists_assert") {
 752                                         s = rpn_pop();
 753                                         if(!rpn_error)
 754                                         {
 755                                                 f = fopen(s, FILE_READ);
 756                                                 if(f != -1)
 757                                                         fclose(f);
 758                                                 else {
 759                                                         print("rpn: ERROR: ", s, " does not exist!\n");
 760                                                         rpn_error = TRUE;
 761                                                 }
 762                                         }
 763                                 } else if(rpncmd == "fexists") {
 764                                         s = rpn_get();
 765                                         if(!rpn_error)
 766                                         {
 767                                                 f = fopen(s, FILE_READ);
 768                                                 if(f != -1) {
 769                                                         fclose(f);
 770                                                         rpn_setf(1);
 771                                                 } else {
 772                                                         rpn_setf(0);
 773                                                 }
 774                                         }
 775                                 } else if(rpncmd == "localtime") {
 776                                         rpn_set(strftime(TRUE, rpn_get()));
 777                                 } else if(rpncmd == "gmtime") {
 778                                         rpn_set(strftime(FALSE, rpn_get()));
 779                                 } else if(rpncmd == "time") {
 780                                         rpn_pushf(time);
 781                                 } else {
 782                                         rpn_push(cvar_string(rpncmd));
 783                                 }
 784                                 if(rpn_error)
 785                                         break;
 786                         }
 787                         while(rpn_sp > 0)
 788                         {
 789                                 s = rpn_pop();
 790                                 print("rpn: still on stack: ", s, "\n");
 791                         }
 792                         return TRUE;
 793                 }
 794         } else if(argv(0) == "addtolist") {
 795                 if(argc >= 2)
 796                 {
 797                         s = argv(1);
 798                         s2 = argv(2);
 799                         if(cvar_string(s) == "")
 800                                 cvar_set(s, s2);
 801                         else {
 802                                 n = tokenizebyseparator(cvar_string(s), " ");
 803                                 for(i = 0; i < n; ++i)
 804                                         if(argv(i) == s2)
 805                                                 return TRUE; // already in list
 806                                 cvar_set(s, strcat(s2, " ", cvar_string(s)));
 807                         }
 808                 }
 809                 return TRUE;
 810         }
 811         else if(argv(0) == "records") {
 812                 print(records_reply);
 813                 return TRUE;
 814         }
 815         else if(argv(0) == "rankings") {
 816                 print(rankings_reply);
 817                 return TRUE;
 818 #ifdef MENUQC
 819         } else if(argv(0) == "cp") {
 820                 if(argc >= 2)
 821                 {
 822                         s = argv(1);
 823                         for(i = 2; i < argc; ++i)
 824                                 s = strcat(s, " ", argv(i));
 825                         centerprint(unescape(s));
 826                 }
 827                 return TRUE;
 828 #endif
 829         }
 830
 831         return FALSE;
 832 }