data/qcsrc/client/teamradar.qc

   1 float teamradar_angle; // player yaw angle
   2 vector teamradar_origin3d_in_texcoord; // player origin
   3 vector teamradar_origin2d; // 2D origin
   4 vector teamradar_size2d; // 2D size
   5 float teamradar_size; // 2D scale factor
   6 float cl_teamradar_scale; // window size = ...qu
   7
   8 float vlen_maxnorm2d(vector v)
   9 {
  10         return max4(v_x, v_y, -v_x, -v_y);
  11 }
  12
  13 float vlen_minnorm2d(vector v)
  14 {
  15         return min(max(v_x, -v_x), max(v_y, -v_y));
  16 }
  17
  18 vector teamradar_3dcoord_to_texcoord(vector in)
  19 {
  20         vector out;
  21         out_x = (in_x - mi_picmin_x) / (mi_picmax_x - mi_picmin_x);
  22         out_y = (in_y - mi_picmin_y) / (mi_picmax_y - mi_picmin_y);
  23         out_z = 0;
  24         return out;
  25 }
  26
  27 vector teamradar_texcoord_to_2dcoord(vector in)
  28 {
  29         vector out;
  30         in -= teamradar_origin3d_in_texcoord;
  31
  32         out = rotate(in, teamradar_angle * DEG2RAD);
  33         out_y = - out_y; // screen space is reversed
  34
  35         out = out * teamradar_size;
  36         out += teamradar_origin2d;
  37         return out;
  38 }
  39
  40 vector yinvert(vector v)
  41 {
  42         v_y = 1 - v_y;
  43         return v;
  44 }
  45
  46 void draw_teamradar_background(float bg, float fg)
  47 {
  48         if(bg > 0)
  49         {
  50                 R_BeginPolygon("", 0);
  51                 R_PolygonVertex('1 0 0' * (teamradar_origin2d_x - teamradar_size2d_x * 0.5) + '0 1 0' * (teamradar_origin2d_y - teamradar_size2d_y * 0.5), '0 0 0', '0 0 0', bg);
  52                 R_PolygonVertex('1 0 0' * (teamradar_origin2d_x + teamradar_size2d_x * 0.5) + '0 1 0' * (teamradar_origin2d_y - teamradar_size2d_y * 0.5), '0 0 0', '0 0 0', bg);
  53                 R_PolygonVertex('1 0 0' * (teamradar_origin2d_x + teamradar_size2d_x * 0.5) + '0 1 0' * (teamradar_origin2d_y + teamradar_size2d_y * 0.5), '0 0 0', '0 0 0', bg);
  54                 R_PolygonVertex('1 0 0' * (teamradar_origin2d_x - teamradar_size2d_x * 0.5) + '0 1 0' * (teamradar_origin2d_y + teamradar_size2d_y * 0.5), '0 0 0', '0 0 0', bg);
  55                 R_EndPolygon();
  56         }
  57
  58         if(fg > 0)
  59         {
  60                 if(csqc_flags & CSQC_FLAG_READPICTURE) // not 2.4.2
  61                         R_BeginPolygon(minimapname, DRAWFLAG_SCREEN | DRAWFLAG_MIPMAP);
  62                 else
  63                         R_BeginPolygon(minimapname, DRAWFLAG_ADDITIVE);
  64                 R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord0), yinvert(mi_pictexcoord0), '1 1 1', fg);
  65                 R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord1), yinvert(mi_pictexcoord1), '1 1 1', fg);
  66                 R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord2), yinvert(mi_pictexcoord2), '1 1 1', fg);
  67                 R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord3), yinvert(mi_pictexcoord3), '1 1 1', fg);
  68                 R_EndPolygon();
  69         }
  70 }
  71
  72 void(vector coord3d, vector pangles, vector rgb) draw_teamradar_player =
  73 {
  74         vector coord, rgb2;
  75
  76         coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(coord3d));
  77
  78         makevectors(pangles - '0 1 0' * teamradar_angle);
  79         v_forward_z = 0;
  80         v_forward = normalize(v_forward);
  81         v_forward_y *= -1.0;
  82         v_right_x = -v_forward_y;
  83         v_right_y = v_forward_x;
  84
  85         if(rgb == '1 1 1')
  86                 rgb2 = '0 0 0';
  87         else
  88                 rgb2 = '1 1 1';
  89
  90         R_BeginPolygon("", 0);
  91         R_PolygonVertex(coord+v_forward*3, '0 0 0', rgb2, 1);
  92         R_PolygonVertex(coord+v_right*4-v_forward*2.5, '0 1 0', rgb2, 1);
  93         R_PolygonVertex(coord-v_forward*2, '1 0 0', rgb2, 1);
  94         R_PolygonVertex(coord-v_right*4-v_forward*2.5, '1 1 0', rgb2, 1);
  95         R_EndPolygon();
  96
  97         R_BeginPolygon("", 0);
  98         R_PolygonVertex(coord+v_forward*2, '0 0 0', rgb, 1);
  99         R_PolygonVertex(coord+v_right*3-v_forward*2, '0 1 0', rgb, 1);
 100         R_PolygonVertex(coord-v_forward, '1 0 0', rgb, 1);
 101         R_PolygonVertex(coord-v_right*3-v_forward*2, '1 1 0', rgb, 1);
 102         R_EndPolygon();
 103 };
 104
 105 void draw_teamradar_icon(vector coord, float icon, float pingtime, vector rgb, float a)
 106 {
 107         float dt;
 108         vector v;
 109
 110         coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(coord));
 111         drawpic(coord - '4 4 0', strcat("gfx/teamradar_icon_", ftos(icon)), '8 8 0', rgb, a, 0);
 112         if(pingtime != 0)
 113         {
 114                 dt = time - pingtime;
 115                 if(dt > 1)
 116                         return;
 117                 v = '2 2 0' * teamradar_size * dt;
 118                 drawpic(coord - 0.5 * v, "gfx/teamradar_ping", v, '1 1 1', 1 - dt, DRAWFLAG_ADDITIVE);
 119         }
 120 }
 121
 122 void draw_teamradar_link(vector start, vector end, float colors)
 123 {
 124         float dt;
 125         vector c0, c1, norm;
 126
 127         start = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(start));
 128         end = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(end));
 129         norm = normalize(start - end);
 130         norm_z = norm_x;
 131         norm_x = -norm_y;
 132         norm_y = norm_z;
 133         norm_z = 0;
 134
 135         c0 = colormapPaletteColor(colors & 0x0F, FALSE);
 136         c1 = colormapPaletteColor((colors & 0xF0) / 0x10, FALSE);
 137
 138         R_BeginPolygon("", 0);
 139         R_PolygonVertex(start - norm, '0 0 0', c0, 1);
 140         R_PolygonVertex(start + norm, '0 1 0', c0, 1);
 141         R_PolygonVertex(end + norm, '1 1 0', c1, 1);
 142         R_PolygonVertex(end - norm, '1 0 0', c1, 1);
 143         R_EndPolygon();
 144
 145         print("p\n");
 146 }
 147
 148 float cl_teamradar_scale;
 149 float cl_teamradar_background_alpha;
 150 float cl_teamradar_foreground_alpha;
 151 float cl_teamradar_rotation;
 152 vector cl_teamradar_size;
 153 vector cl_teamradar_position;
 154 float cl_teamradar_zoommode;
 155
 156 void teamradar_loadcvars()
 157 {
 158         cl_teamradar_scale = cvar("cl_teamradar_scale");
 159         cl_teamradar_background_alpha = cvar("cl_teamradar_background_alpha");
 160         cl_teamradar_foreground_alpha = cvar("cl_teamradar_foreground_alpha");
 161         cl_teamradar_rotation = cvar("cl_teamradar_rotation");
 162         cl_teamradar_size = stov(cvar_string("cl_teamradar_size"));
 163         cl_teamradar_position = stov(cvar_string("cl_teamradar_position"));
 164         cl_teamradar_zoommode = cvar("cl_teamradar_zoommode");
 165
 166         // others default to 0
 167         // match this to defaultNexuiz.cfg!
 168         if(!cl_teamradar_scale) cl_teamradar_scale = 4096;
 169         if(!cl_teamradar_background_alpha) cl_teamradar_background_alpha = 0.4;
 170         if(!cl_teamradar_foreground_alpha) cl_teamradar_foreground_alpha = 0.8;
 171         if(!cl_teamradar_size_x) cl_teamradar_size_x = 128;
 172         if(!cl_teamradar_size_y) cl_teamradar_size_y = cl_teamradar_size_x;
 173
 174         cl_teamradar_size_z = 0;
 175         cl_teamradar_position_z = 0;
 176 }
 177
 178 void() teamradar_view =
 179 {
 180         local float color, color2;
 181         local vector rgb;
 182         local entity tm;
 183         float scale2d, normalsize, bigsize;
 184         float f;
 185
 186         if(minimapname == "")
 187                 return;
 188
 189         teamradar_loadcvars();
 190
 191         switch(cl_teamradar_zoommode)
 192         {
 193                 default:
 194                 case 0:
 195                         f = current_zoomfraction;
 196                         break;
 197                 case 1:
 198                         f = 1 - current_zoomfraction;
 199                         break;
 200                 case 2:
 201                         f = 0;
 202                         break;
 203                 case 3:
 204                         f = 1;
 205                         break;
 206         }
 207
 208         switch(cl_teamradar_rotation)
 209         {
 210                 case 0:
 211                         teamradar_angle = input_angles_y - 90;
 212                         break;
 213                 default:
 214                         teamradar_angle = 90 * cl_teamradar_rotation;
 215                         break;
 216         }
 217
 218         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
 219         teamradar_size2d = cl_teamradar_size;
 220         teamradar_origin2d =
 221                   '1 0 0' * (0.5 * teamradar_size2d_x + cl_teamradar_position_x * (vid_conwidth - teamradar_size2d_x))
 222                 + '0 1 0' * (0.5 * teamradar_size2d_y + cl_teamradar_position_y * (vid_conheight - teamradar_size2d_y));
 223
 224         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
 225         if(cl_teamradar_rotation == 0)
 226         {
 227                 // max-min distance must fit the radar in any rotation
 228                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen(mi_max - mi_min));
 229         }
 230         else
 231         {
 232                 vector c0, c1, c2, c3, span;
 233                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
 234                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
 235                 c2 = rotate('1 0 0' * mi_min_x + '0 1 0' * mi_max_y, teamradar_angle * DEG2RAD);
 236                 c3 = rotate('1 0 0' * mi_max_x + '0 1 0' * mi_min_y, teamradar_angle * DEG2RAD);
 237                 span = '0 0 0';
 238                 span_x = max4(c0_x, c1_x, c2_x, c3_x) - min4(c0_x, c1_x, c2_x, c3_x);
 239                 span_y = max4(c0_y, c1_y, c2_y, c3_y) - min4(c0_y, c1_y, c2_y, c3_y);
 240
 241                 // max-min distance must fit the radar in x=x, y=y
 242                 bigsize = min(
 243                         teamradar_size2d_x * scale2d / (1.05 * span_x),
 244                         teamradar_size2d_y * scale2d / (1.05 * span_y)
 245                 );
 246         }
 247
 248         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / cl_teamradar_scale;
 249         if(bigsize > normalsize)
 250                 normalsize = bigsize;
 251
 252         teamradar_size =
 253                   f * bigsize
 254                 + (1 - f) * normalsize;
 255         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
 256                   f * (mi_min + mi_max) * 0.5
 257                 + (1 - f) * pmove_org);
 258
 259         color = GetPlayerColor(player_localentnum-1);
 260         rgb = GetTeamRGB(color);
 261
 262         drawsetcliparea(
 263                 teamradar_origin2d_x - teamradar_size2d_x * 0.5,
 264                 teamradar_origin2d_y - teamradar_size2d_y * 0.5,
 265                 teamradar_size2d_x,
 266                 teamradar_size2d_y
 267         );
 268
 269         draw_teamradar_background(cl_teamradar_background_alpha, cl_teamradar_foreground_alpha);
 270         for(tm = world; (tm = find(tm, classname, "radarlink")); )
 271                 draw_teamradar_link(tm.origin, tm.velocity, tm.team);
 272         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
 273                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm.teamradar_time, tm.teamradar_color, tm.alpha);
 274         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
 275         {
 276                 color2 = GetPlayerColor(tm.sv_entnum);
 277                 //if(color == COLOR_SPECTATOR || color == color2)
 278                         draw_teamradar_player(tm.origin, tm.angles, GetTeamRGB(color2));
 279         }
 280         draw_teamradar_player(pmove_org, input_angles, '1 1 1');
 281
 282         drawresetcliparea();
 283 };
 284
 285
 286
 287 // radar links
 288
 289 void Ent_RadarLink()
 290 {
 291         float sendflags, f;
 292         sendflags = ReadByte();
 293
 294         InterpolateOrigin_Undo();
 295
 296         self.iflags = IFLAG_VELOCITY;
 297         self.classname = "radarlink";
 298
 299         if(sendflags & 1)
 300         {
 301                 self.origin_x = ReadCoord();
 302                 self.origin_y = ReadCoord();
 303                 self.origin_z = ReadCoord();
 304         }
 305
 306         if(sendflags & 2)
 307         {
 308                 self.velocity_x = ReadCoord();
 309                 self.velocity_y = ReadCoord();
 310                 self.velocity_z = ReadCoord();
 311         }
 312
 313         if(sendflags & 4)
 314         {
 315                 self.team = ReadByte();
 316         }
 317
 318         InterpolateOrigin_Note();
 319 }