data/qcsrc/client/mapvoting.qc

   1 float mv_num_maps;
   2
   3 string mv_maps[MAPVOTE_COUNT];
   4 string mv_pics[MAPVOTE_COUNT];
   5 string mv_pk3[MAPVOTE_COUNT];
   6 float mv_preview[MAPVOTE_COUNT];
   7 float mv_votes[MAPVOTE_COUNT];
   8 entity mv_pk3list;
   9 float mv_abstain;
  10 float mv_ownvote;
  11 float mv_detail;
  12 float mv_timeout;
  13
  14 // TODO: First the text, then the image above it, centered
  15 void MapVote_DrawMapItem(vector pos, float isize, string map, string pic, float count, float id)
  16 {
  17         vector img_size;
  18         vector rgb;
  19         string label;
  20         float text_size;
  21
  22         if(id == mv_ownvote)
  23                 rgb = '1 1 0';
  24         else
  25                 rgb = '1 1 1';
  26
  27         isize -= sbar_fontsize_y; // respect the text when calculating the image size
  28
  29         img_size_y = isize;
  30         img_size_x = isize / 0.75; // 4:3 x can be stretched easily, height is defined in isize
  31
  32         drawfont = sbar_font;
  33         pos_y = pos_y + img_size_y;
  34
  35         if(mv_detail)
  36                 label = strcat(ftos(id+1), ". ", ftos(count), ": ", map);
  37         else
  38                 label = strcat(ftos(id+1), ". ", map);
  39
  40         text_size = stringwidth(label, false) * sbar_fontsize_x;
  41
  42         pos_x -= text_size*0.5;
  43         drawstring(pos, label, sbar_fontsize, rgb, 1, DRAWFLAG_NORMAL);
  44
  45         pos_x = pos_x + text_size*0.5 - img_size_x*0.5;
  46         pos_y = pos_y - img_size_y;
  47         drawpic(pos, pic, img_size, '1 1 1', 1, DRAWFLAG_NORMAL);
  48 }
  49
  50 void MapVote_DrawMapNotAvailable(vector pos, float isize, string map, float count, float id)
  51 {
  52         vector img_size, a, b;
  53         vector rgb;
  54         string label;
  55         float text_size;
  56
  57         if(id == mv_ownvote)
  58                 rgb = '1 1 0';
  59         else
  60                 rgb = '1 1 1';
  61
  62         isize -= sbar_fontsize_y; // respect the text when calculating the image size
  63
  64         img_size_y = isize;
  65         img_size_x = isize / 0.75; // 4:3 x can be stretched easily, height is defined in isize
  66
  67         drawfont = sbar_font;
  68         pos_y = pos_y + img_size_y;
  69
  70         if(mv_detail)
  71                 label = strcat(ftos(id+1), ". ", ftos(count), ": ", map);
  72         else
  73                 label = strcat(ftos(id+1), ". ", map);
  74
  75         text_size = stringwidth(label, false) * sbar_fontsize_x;
  76
  77         pos_x -= text_size*0.5;
  78         drawstring(pos, label, sbar_fontsize, rgb, 1, DRAWFLAG_NORMAL);
  79
  80         a_x = img_size_x; // for the lines
  81         b_y = img_size_y;
  82
  83         pos_x = pos_x + text_size*0.5 - img_size_x*0.5;
  84         pos_y = pos_y - img_size_y;
  85
  86         drawfill(pos, img_size, '.5 .5 .5', .7, DRAWFLAG_NORMAL);
  87         drawline(2, pos, pos + a, '1 1 1', 1, DRAWFLAG_NORMAL);
  88         drawline(2, pos, pos + b, '1 1 1', 1, DRAWFLAG_NORMAL);
  89         drawline(2, pos + img_size, pos + a, '1 1 1', 1, DRAWFLAG_NORMAL);
  90         drawline(2, pos + img_size, pos + b, '1 1 1', 1, DRAWFLAG_NORMAL);
  91 }
  92
  93 void MapVote_DrawAbstain(vector pos, float isize, float count, float id)
  94 {
  95         vector img_size;
  96         vector rgb;
  97         float text_size;
  98         string label;
  99
 100         if(id == mv_ownvote)
 101                 rgb = '1 1 0';
 102         else
 103                 rgb = '1 1 1';
 104
 105         drawfont = sbar_font;
 106         pos_y = pos_y + sbar_fontsize_y;
 107
 108         if(mv_detail)
 109                 label = strcat(ftos(id+1), ". ", ftos(count), ": Don't care");
 110         else
 111                 label = strcat(ftos(id+1), ". Don't care");
 112
 113         text_size = stringwidth(label, false) * sbar_fontsize_x;
 114
 115         pos_x -= text_size*0.5;
 116         drawstring(pos, label, sbar_fontsize, rgb, 1, DRAWFLAG_NORMAL);
 117 }
 118
 119 void MapVote_Draw()
 120 {
 121         string map;
 122         float i, tmp;
 123         vector pos;
 124         float isize;
 125         float center;
 126
 127         center = (vid_conwidth - 1)/2;
 128         xmin = vid_conwidth*0.05; // 5% border must suffice
 129         xmax = vid_conwidth - xmin;
 130         ymin = 24;
 131         i = cvar("con_chatpos"); //*cvar("con_chatsize");
 132         if(i < 0)
 133                 ymax = vid_conheight + (i - cvar("con_chat")) * cvar("con_chatsize");
 134         if(i >= 0 || ymax < (vid_conheight*0.5))
 135                 ymax = vid_conheight - ymin;
 136
 137         drawfont = sbar_bigfont;
 138         sbar_fontsize = stov(cvar_string("sbar_fontsize"));
 139         if(sbar_fontsize_x == 0)
 140                 sbar_fontsize = '8 8 0';
 141         if(sbar_fontsize_y == 0)
 142                 sbar_fontsize_y = sbar_fontsize_x;
 143
 144         pos_y = ymin;
 145         pos_z = 0;
 146         pos_x = center - stringwidth("Vote for a map", false) * 0.5 * 24;
 147         drawstring(pos, "Vote for a map", '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
 148         pos_y += 26;
 149
 150         i = ceil(mv_timeout - time);
 151         map = strcat(ftos(i), " seconds left");
 152         pos_x = center - stringwidth(map, false) * 0.5 * 16;
 153         drawstring(pos, map, '16 16 0', '0 1 0', 1, DRAWFLAG_NORMAL);
 154         pos_y += 22;
 155         pos_x = xmin;
 156
 157         drawfont = sbar_bigfont; // FIXME change this to sbar_font when it gets a SANE size later
 158
 159         // base for multi-column stuff...
 160         ymin = pos_y;
 161         if(mv_num_maps > 5)
 162         {
 163                 //xmax = 0.5*(xmax - xmin);
 164                 isize = (ymax - pos_y - mv_num_maps*10) / floor(0.5*mv_num_maps); // or ceil?
 165                 pos_x = xmin + 0.25*(xmax-xmin);
 166         } else {
 167                 isize = (ymax - pos_y - mv_num_maps*10) / mv_num_maps;
 168                 pos_x = xmin + 0.5*(xmax-xmin);
 169         }
 170
 171         ymax -= isize;
 172         for(i = 0; i < (mv_num_maps - mv_abstain); ++i)
 173         {
 174                 // base for multi-column stuff
 175                 if(pos_y >= ymax)
 176                 {
 177                         pos_y = ymin;
 178                         pos_x = xmin + 0.75*(xmax-xmin);
 179                         //xmax = 2*xmax - xmin;
 180                         //xmin = pos_x;
 181                 }
 182
 183                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 184                 if(tmp < 0)
 185                 {
 186                         pos_y += isize + 10;
 187                         continue;
 188                 }
 189                 map = mv_maps[i];
 190                 if(mv_preview[i])
 191                         MapVote_DrawMapItem(pos, isize, map, mv_pics[i], tmp, i);
 192                 else
 193                         MapVote_DrawMapNotAvailable(pos, isize, map, tmp, i);
 194                 pos_y += isize + 10;
 195         }
 196         if(mv_abstain && i < mv_num_maps) {
 197                 tmp = mv_votes[i];
 198                 MapVote_DrawAbstain(pos, isize, tmp, i);
 199         }
 200 }
 201
 202 void Cmd_MapVote_MapDownload(float argc)
 203 {
 204         float id;
 205         entity pak;
 206
 207         if(argc != 2 || !mv_pk3list)
 208         {
 209                 print("mv_mapdownload: ^3You're not supposed to use this command on your own!\n");
 210                 return;
 211         }
 212
 213         id = stof(argv(1));
 214         for(pak = mv_pk3list; pak; pak = pak.chain)
 215                 if(pak.sv_entnum == id)
 216                         break;
 217
 218         if(!pak || pak.sv_entnum != id) {
 219                 print("^1Error:^7 Couldn't find pak index.\n");
 220                 return;
 221         }
 222
 223         //print(strcat("^3Adding: ", ftos(id), " - ", pak.message, " - "));
 224
 225         if(PreviewExists(pak.message))
 226         {
 227                 mv_preview[id] = true;
 228                 //print("^2Found...\n");
 229                 return;
 230         } else if(csqc_flags & CSQC_FLAG_READPICTURE) {
 231                 print("Requesting preview...\n");
 232                 localcmd(strcat("\ncmd mv_getpic ", ftos(id), "\n"));
 233         } else {
 234                 print("^3Missing map preview - Update to a newer build to be able to see them.\n");
 235         }
 236 }
 237
 238 void MapVote_CheckPK3(string pic, string pk3, float id)
 239 {
 240         entity pak;
 241         pak = spawn();
 242         pak.netname = pk3;
 243         pak.message = pic;
 244         pak.sv_entnum = id;
 245
 246         pak.chain = mv_pk3list;
 247         mv_pk3list = pak;
 248
 249         localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 250 }
 251
 252 void MapVote_CheckPic(string pic, string pk3, float id)
 253 {
 254         if(PreviewExists(pic))
 255         {
 256                 mv_preview[id] = true;
 257                 return;
 258         }
 259         MapVote_CheckPK3(pic, pk3, id);
 260 }
 261
 262 void MapVote_Init()
 263 {
 264         float i, power, m;
 265         string map, pk3;
 266
 267         registercmd("+showscores");
 268         registercmd("-showscores");
 269
 270         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 271         mv_abstain = ReadByte();
 272         if(mv_abstain)
 273                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 274         mv_detail = ReadByte();
 275
 276         mv_ownvote = -1;
 277         mv_timeout = time + ReadByte();
 278
 279         if(mv_num_maps <= 8)
 280                 m = ReadByte();
 281         else
 282                 m = ReadShort();
 283
 284         // Assume mv_pk3list is NULL, there should only be 1 mapvote per round
 285         mv_pk3list = NULL; // I'm still paranoid!
 286
 287         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 288         {
 289                 mv_votes[i] = 0;
 290
 291                 if(m & power)
 292                 {
 293                         map = strzone(ReadString());
 294                         pk3 = strzone(ReadString());
 295                         mv_maps[i] = map;
 296                         mv_pk3[i] = pk3;
 297                         map = strzone(strcat(config_get("mv_screenshot_dir", "maps"), "/", map));
 298                         mv_pics[i] = map;
 299
 300                         mv_preview[i] = false;
 301
 302                         //print(strcat("RECV: ", map, " in ", pk3, "\n"));
 303                         MapVote_CheckPic(map, pk3, i);
 304                 }
 305                 else
 306                 {
 307                         mv_maps[i] = strzone("if-you-see-this-the-code-is-broken");
 308                         mv_pk3[i] = strzone("if-you-see-this-the-code-is-broken");
 309                         mv_pics[i] = strzone("if-you-see-this-the-code-is-broken");
 310                         mv_preview[i] = false;
 311                 }
 312         }
 313 }
 314
 315 void MapVote_Update()
 316 {
 317         float i, power;
 318         float m;
 319         if(mv_num_maps <= 8)
 320                 m = ReadByte();
 321         else
 322                 m = ReadShort();
 323         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 324         {
 325                 if(m & power)
 326                 {
 327                         if(mv_detail)
 328                                 mv_votes[i] = ReadByte();
 329                         else
 330                                 mv_votes[i] = 0;
 331                 }
 332                 else
 333                         mv_votes[i] = -1;
 334         }
 335 }
 336
 337 string Net_ReadPicture();
 338 void Net_Mapvote()
 339 {
 340         float type;
 341         type = ReadByte();
 342         switch(type)
 343         {
 344         case MAPVOTE_NET_INIT:
 345                 MapVote_Init();
 346                 // do we NEED this, or can we handle key presses directly in CSQC?
 347                 localcmd("\nin_bind 7 1 \"impulse 1\"; in_bind 7 2 \"impulse 2\"; in_bind 7 3 \"impulse 3\"; in_bind 7 4 \"impulse 4\"; in_bind 7 5 \"impulse 5\"; in_bind 7 6 \"impulse 6\"; in_bind 7 7 \"impulse 7\"; in_bind 7 8 \"impulse 8\"; in_bind 7 9 \"impulse 9\"; in_bind 7 0 \"impulse 10\"; in_bind 7 KP_1 \"impulse 1\"; in_bind 7 KP_2 \"impulse 2\"; in_bind 7 KP_3 \"impulse 3\"; in_bind 7 KP_4 \"impulse 4\"; in_bind 7 KP_5 \"impulse 5\"; in_bind 7 KP_6 \"impulse 6\"; in_bind 7 KP_7 \"impulse 7\"; in_bind 7 KP_8 \"impulse 8\"; in_bind 7 KP_9 \"impulse 9\"; in_bind 7 KP_0 \"impulse 10\"; in_bindmap 7 0\n");
 348                 break;
 349         case MAPVOTE_NET_UPDATE:
 350                 MapVote_Update();
 351                 break;
 352         case MAPVOTE_NET_OWNVOTE:
 353                 mv_ownvote = ReadByte()-1;
 354                 break;
 355         case MAPVOTE_NET_PIC:
 356                 type = ReadByte();
 357                 mv_preview[type] = true;
 358                 mv_pics[type] = strzone(Net_ReadPicture());
 359                 break;
 360         }
 361 }