data/qcsrc/client/mapvoting.qc

   1 float mv_num_maps;
   2
   3 string mv_maps[MAPVOTE_COUNT];
   4 string mv_pics[MAPVOTE_COUNT];
   5 string mv_pk3[MAPVOTE_COUNT];
   6 float mv_preview[MAPVOTE_COUNT];
   7 float mv_votes[MAPVOTE_COUNT];
   8 entity mv_pk3list;
   9 float mv_abstain;
  10 float mv_ownvote;
  11 float mv_detail;
  12 float mv_timeout;
  13
  14 void MapVote_DrawMapItem(vector pos, float isize, string map, string pic, float count, float id)
  15 {
  16         vector img_size;
  17         vector rgb;
  18         //img_size_x = img_size_y = isize;
  19         img_size_y = isize;
  20         img_size_x = isize / 0.75; // 4:3 x can be stretched easily, height is defined in isize
  21
  22         drawpic(pos, pic, img_size, '1 1 1', 1, DRAWFLAG_NORMAL);
  23
  24         // half size for the impulse number
  25         img_size_x = img_size_y = isize*0.5;
  26         pos_y += img_size_y*0.5;
  27
  28         if(id == mv_ownvote)
  29                 rgb = '1 1 0';
  30         else
  31                 rgb = '1 1 1';
  32
  33         drawstring(pos - '40 0', strcat(ftos(id+1), "."), img_size, rgb, 1, DRAWFLAG_NORMAL);
  34
  35         pos_x += isize/0.75 + 10;
  36
  37         if(mv_detail)
  38                 drawstring(pos, strcat(ftos(count), " : ", map), img_size, rgb, 1, DRAWFLAG_NORMAL);
  39         else
  40                 drawstring(pos, map, img_size, rgb, 1, DRAWFLAG_NORMAL);
  41 }
  42
  43 void MapVote_DrawMapNotAvailable(vector pos, float isize, string map, float count, float id)
  44 {
  45         vector img_size, a, b;
  46         vector rgb;
  47         img_size_y = isize;
  48         img_size_x = isize / 0.75;
  49
  50         a_x = img_size_x; // for the lines
  51         b_y = img_size_y;
  52         drawfill(pos, img_size, '.5 .5 .5', .7, DRAWFLAG_NORMAL);
  53         drawline(2, pos, pos + a, '1 1 1', 1, DRAWFLAG_NORMAL);
  54         drawline(2, pos, pos + b, '1 1 1', 1, DRAWFLAG_NORMAL);
  55         drawline(2, pos + img_size, pos + a, '1 1 1', 1, DRAWFLAG_NORMAL);
  56         drawline(2, pos + img_size, pos + b, '1 1 1', 1, DRAWFLAG_NORMAL);
  57
  58         img_size_x = img_size_y = isize*0.5;
  59         pos_y += img_size_y*0.5;
  60
  61         if(id == mv_ownvote)
  62                 rgb = '1 1 0';
  63         else
  64                 rgb = '1 1 1';
  65
  66         drawstring(pos - '40 0', strcat(ftos(id+1), "."), img_size, rgb, 1, DRAWFLAG_NORMAL);
  67
  68         pos_x += isize/0.75 + 10;
  69
  70         if(mv_detail)
  71                 drawstring(pos, strcat(ftos(count), " : ", map), img_size, rgb, 1, DRAWFLAG_NORMAL);
  72         else
  73                 drawstring(pos, map, img_size, rgb, 1, DRAWFLAG_NORMAL);
  74 }
  75
  76 void MapVote_DrawAbstain(vector pos, float isize, float count, float id)
  77 {
  78         vector img_size;
  79         vector rgb;
  80         img_size_y = isize;
  81         img_size_x = isize / 0.75;
  82
  83         img_size_x = img_size_y = isize*0.5;
  84         pos_y += img_size_y*0.5;
  85
  86         if(id == mv_ownvote)
  87                 rgb = '1 1 0';
  88         else
  89                 rgb = '1 1 1';
  90
  91         drawstring(pos - '40 0', strcat(ftos(id+1), "."), img_size, rgb, 1, DRAWFLAG_NORMAL);
  92
  93         pos_x += isize/0.75 + 10;
  94
  95         if(mv_detail)
  96                 drawstring(pos, strcat(ftos(count), " : Don't care"), img_size, rgb, 1, DRAWFLAG_NORMAL);
  97         else
  98                 drawstring(pos, "Don't care", img_size, rgb, 1, DRAWFLAG_NORMAL);
  99 }
 100
 101 void MapVote_Draw()
 102 {
 103         string map;
 104         float i, tmp;
 105         vector pos;
 106         float isize;
 107         float center;
 108         float margin;
 109
 110         center = (vid_conwidth - 1)/2;
 111         xmin = vid_conwidth*0.2;
 112         xmax = vid_conwidth - xmin;
 113         ymin = 24;
 114         i = cvar("con_chatpos"); //*cvar("con_chatsize");
 115         if(i < 0)
 116                 ymax = vid_conheight + (i - cvar("con_chat")) * cvar("con_chatsize");
 117         if(i >= 0 || ymax < (vid_conheight*0.5))
 118                 ymax = vid_conheight - ymin;
 119
 120         drawfont = sbar_font;
 121         sbar_fontsize = stov(cvar_string("sbar_fontsize"));
 122         if(sbar_fontsize_x == 0)
 123                 sbar_fontsize = '8 8 0';
 124         if(sbar_fontsize_y == 0)
 125                 sbar_fontsize_y = sbar_fontsize_x;
 126
 127         pos_y = ymin;
 128         pos_z = 0;
 129         pos_x = center - stringwidth("Vote for a map", false) * 0.5 * 24;
 130         drawstring(pos, "Vote for a map", '24 24', '1 1 1', 1, DRAWFLAG_NORMAL);
 131         pos_y += 26;
 132
 133         i = ceil(mv_timeout - time);
 134         map = strcat(ftos(i), " seconds left");
 135         pos_x = center - stringwidth(map, false) * 0.5 * 16;
 136         drawstring(pos, map, '16 16', '0 1 0', 1, DRAWFLAG_NORMAL);
 137         pos_y += 22;
 138         pos_x = xmin;
 139
 140         isize = (ymax - pos_y - mv_num_maps*10) / mv_num_maps;
 141         isize = min(isize, 64);
 142
 143         for(i = 0; i < (mv_num_maps - mv_abstain); ++i)
 144         {
 145                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 146                 if(tmp < 0)
 147                 {
 148                         pos_y += isize + 10;
 149                         continue;
 150                 }
 151                 map = mv_maps[i];
 152                 if(mv_preview[i])
 153                         MapVote_DrawMapItem(pos, isize, map, mv_pics[i], tmp, i);
 154                 else
 155                         MapVote_DrawMapNotAvailable(pos, isize, map, tmp, i);
 156                 pos_y += isize + 10;
 157         }
 158         if(mv_abstain && i < mv_num_maps) {
 159                 tmp = mv_votes[i];
 160                 MapVote_DrawAbstain(pos, isize, tmp, i);
 161         }
 162 }
 163
 164 void Cmd_MapVote_MapDownload(float argc)
 165 {
 166         float id;
 167         entity pak;
 168
 169         if(argc != 2 || !mv_pk3list)
 170         {
 171                 print("mv_mapdownload: ^3You're not supposed to use this command on your own!\n");
 172                 return;
 173         }
 174
 175         id = stof(argv(1));
 176         for(pak = mv_pk3list; pak; pak = pak.chain)
 177                 if(pak.sv_entnum == id)
 178                         break;
 179
 180         if(!pak || pak.sv_entnum != id) {
 181                 print("^1Error:^7 Couldn't find pak index.\n");
 182                 return;
 183         }
 184
 185         //print(strcat("^3Adding: ", ftos(id), " - ", pak.message, " - "));
 186
 187         if(PreviewExists(pak.message))
 188         {
 189                 mv_preview[id] = true;
 190                 //print("^2Found...\n");
 191                 return;
 192         } else if(csqc_flags & CSQC_FLAG_READPICTURE) {
 193                 print("Requesting preview...\n");
 194                 localcmd(strcat("\ncmd mv_getpic ", ftos(id), "\n"));
 195         } else {
 196                 print("^3Missing map preview - Update to a newer build to be able to see them.\n");
 197         }
 198 }
 199
 200 void MapVote_CheckPK3(string pic, string pk3, float id)
 201 {
 202         entity pak;
 203         pak = spawn();
 204         pak.netname = pk3;
 205         pak.message = pic;
 206         pak.sv_entnum = id;
 207
 208         pak.chain = mv_pk3list;
 209         mv_pk3list = pak;
 210
 211         localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 212 }
 213
 214 void MapVote_CheckPic(string pic, string pk3, float id)
 215 {
 216         if(PreviewExists(pic))
 217         {
 218                 mv_preview[id] = true;
 219                 return;
 220         }
 221         MapVote_CheckPK3(pic, pk3, id);
 222 }
 223
 224 void MapVote_Init()
 225 {
 226         float i, power, m;
 227         string map, pk3;
 228
 229         registercmd("+showscores");
 230         registercmd("-showscores");
 231
 232         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 233         mv_abstain = ReadByte();
 234         if(mv_abstain)
 235                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 236         mv_detail = ReadByte();
 237
 238         mv_ownvote = -1;
 239         mv_timeout = time + ReadByte();
 240
 241         if(mv_num_maps <= 8)
 242                 m = ReadByte();
 243         else
 244                 m = ReadShort();
 245
 246         // Assume mv_pk3list is NULL, there should only be 1 mapvote per round
 247         mv_pk3list = NULL; // I'm still paranoid!
 248
 249         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 250         {
 251                 mv_votes[i] = 0;
 252
 253                 if(m & power)
 254                 {
 255                         map = strzone(ReadString());
 256                         pk3 = strzone(ReadString());
 257                         mv_maps[i] = map;
 258                         mv_pk3[i] = pk3;
 259                         map = strzone(strcat(config_get("mv_screenshot_dir", "maps"), "/", map));
 260                         mv_pics[i] = map;
 261
 262                         mv_preview[i] = false;
 263
 264                         //print(strcat("RECV: ", map, " in ", pk3, "\n"));
 265                         MapVote_CheckPic(map, pk3, i);
 266                 }
 267                 else
 268                 {
 269                         mv_maps[i] = strzone("if-you-see-this-the-code-is-broken");
 270                         mv_pk3[i] = strzone("if-you-see-this-the-code-is-broken");
 271                         mv_pics[i] = strzone("if-you-see-this-the-code-is-broken");
 272                         mv_preview[i] = false;
 273                 }
 274         }
 275 }
 276
 277 void MapVote_Update()
 278 {
 279         float i, power;
 280         float m;
 281         if(mv_num_maps <= 8)
 282                 m = ReadByte();
 283         else
 284                 m = ReadShort();
 285         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 286         {
 287                 if(m & power)
 288                 {
 289                         if(mv_detail)
 290                                 mv_votes[i] = ReadByte();
 291                         else
 292                                 mv_votes[i] = 0;
 293                 }
 294                 else
 295                         mv_votes[i] = -1;
 296         }
 297 }
 298
 299 string Net_ReadPicture();
 300 void Net_Mapvote()
 301 {
 302         float type;
 303         type = ReadByte();
 304         switch(type)
 305         {
 306         case MAPVOTE_NET_INIT:
 307                 MapVote_Init();
 308                 // do we NEED this, or can we handle key presses directly in CSQC?
 309                 localcmd("\nin_bind 7 1 \"impulse 1\"; in_bind 7 2 \"impulse 2\"; in_bind 7 3 \"impulse 3\"; in_bind 7 4 \"impulse 4\"; in_bind 7 5 \"impulse 5\"; in_bind 7 6 \"impulse 6\"; in_bind 7 7 \"impulse 7\"; in_bind 7 8 \"impulse 8\"; in_bind 7 9 \"impulse 9\"; in_bind 7 0 \"impulse 10\"; in_bind 7 KP_1 \"impulse 1\"; in_bind 7 KP_2 \"impulse 2\"; in_bind 7 KP_3 \"impulse 3\"; in_bind 7 KP_4 \"impulse 4\"; in_bind 7 KP_5 \"impulse 5\"; in_bind 7 KP_6 \"impulse 6\"; in_bind 7 KP_7 \"impulse 7\"; in_bind 7 KP_8 \"impulse 8\"; in_bind 7 KP_9 \"impulse 9\"; in_bind 7 KP_0 \"impulse 10\"; in_bindmap 7 0\n");
 310                 break;
 311         case MAPVOTE_NET_UPDATE:
 312                 MapVote_Update();
 313                 break;
 314         case MAPVOTE_NET_OWNVOTE:
 315                 mv_ownvote = ReadByte()-1;
 316                 break;
 317         case MAPVOTE_NET_PIC:
 318                 type = ReadByte();
 319                 mv_preview[type] = true;
 320                 mv_pics[type] = strzone(Net_ReadPicture());
 321                 break;
 322         }
 323 }