data/qcsrc/client/mapvoting.qc

   1 float mv_num_maps;
   2
   3 string mv_maps[MAPVOTE_COUNT];
   4 string mv_pics[MAPVOTE_COUNT];
   5 string mv_pk3[MAPVOTE_COUNT];
   6 float mv_preview[MAPVOTE_COUNT];
   7 float mv_votes[MAPVOTE_COUNT];
   8 entity mv_pk3list;
   9 float mv_abstain;
  10 float mv_ownvote;
  11 float mv_detail;
  12 float mv_timeout;
  13
  14 void MapVote_DrawMapItem(vector pos, float isize, string map, string pic, float count, float id)
  15 {
  16         vector img_size;
  17         vector rgb;
  18         //img_size_x = img_size_y = isize;
  19         img_size_y = isize;
  20         img_size_x = isize / 0.75; // 4:3 x can be stretched easily, height is defined in isize
  21
  22         drawpic(pos, pic, img_size, '1 1 1', 1, DRAWFLAG_NORMAL);
  23
  24         // half size for the impulse number
  25         img_size_x = img_size_y = isize*0.5;
  26         pos_y += img_size_y*0.5;
  27
  28         if(id == mv_ownvote)
  29                 rgb = '1 1 0';
  30         else
  31                 rgb = '1 1 1';
  32
  33         drawstring(pos - '40 0 0', strcat(ftos(id+1), "."), img_size, rgb, 1, DRAWFLAG_NORMAL);
  34
  35         pos_x += isize/0.75 + 10;
  36
  37         if(mv_detail)
  38                 drawstring(pos, strcat(ftos(count), " : ", map), img_size, rgb, 1, DRAWFLAG_NORMAL);
  39         else
  40                 drawstring(pos, map, img_size, rgb, 1, DRAWFLAG_NORMAL);
  41 }
  42
  43 void MapVote_DrawMapNotAvailable(vector pos, float isize, string map, float count, float id)
  44 {
  45         vector img_size, a, b;
  46         vector rgb;
  47         img_size_y = isize;
  48         img_size_x = isize / 0.75;
  49
  50         a_x = img_size_x; // for the lines
  51         b_y = img_size_y;
  52         drawfill(pos, img_size, '.5 .5 .5', .7, DRAWFLAG_NORMAL);
  53         drawline(2, pos, pos + a, '1 1 1', 1, DRAWFLAG_NORMAL);
  54         drawline(2, pos, pos + b, '1 1 1', 1, DRAWFLAG_NORMAL);
  55         drawline(2, pos + img_size, pos + a, '1 1 1', 1, DRAWFLAG_NORMAL);
  56         drawline(2, pos + img_size, pos + b, '1 1 1', 1, DRAWFLAG_NORMAL);
  57
  58         img_size_x = img_size_y = isize*0.5;
  59         pos_y += img_size_y*0.5;
  60
  61         if(id == mv_ownvote)
  62                 rgb = '1 1 0';
  63         else
  64                 rgb = '1 1 1';
  65
  66         drawstring(pos - '40 0 0', strcat(ftos(id+1), "."), img_size, rgb, 1, DRAWFLAG_NORMAL);
  67
  68         pos_x += isize/0.75 + 10;
  69
  70         if(mv_detail)
  71                 drawstring(pos, strcat(ftos(count), " : ", map), img_size, rgb, 1, DRAWFLAG_NORMAL);
  72         else
  73                 drawstring(pos, map, img_size, rgb, 1, DRAWFLAG_NORMAL);
  74 }
  75
  76 void MapVote_DrawAbstain(vector pos, float isize, float count, float id)
  77 {
  78         vector img_size;
  79         vector rgb;
  80         img_size_y = isize;
  81         img_size_x = isize / 0.75;
  82
  83         img_size_x = img_size_y = isize*0.5;
  84         pos_y += img_size_y*0.5;
  85
  86         if(id == mv_ownvote)
  87                 rgb = '1 1 0';
  88         else
  89                 rgb = '1 1 1';
  90
  91         drawstring(pos - '40 0 0', strcat(ftos(id+1), "."), img_size, rgb, 1, DRAWFLAG_NORMAL);
  92
  93         pos_x += isize/0.75 + 10;
  94
  95         if(mv_detail)
  96                 drawstring(pos, strcat(ftos(count), " : Don't care"), img_size, rgb, 1, DRAWFLAG_NORMAL);
  97         else
  98                 drawstring(pos, "Don't care", img_size, rgb, 1, DRAWFLAG_NORMAL);
  99 }
 100
 101 void MapVote_Draw()
 102 {
 103         string map;
 104         float i, tmp;
 105         vector pos;
 106         float isize;
 107         float center;
 108
 109         center = (vid_conwidth - 1)/2;
 110         xmin = vid_conwidth*0.2;
 111         xmax = vid_conwidth - xmin;
 112         ymin = 24;
 113         i = cvar("con_chatpos"); //*cvar("con_chatsize");
 114         if(i < 0)
 115                 ymax = vid_conheight + (i - cvar("con_chat")) * cvar("con_chatsize");
 116         if(i >= 0 || ymax < (vid_conheight*0.5))
 117                 ymax = vid_conheight - ymin;
 118
 119         drawfont = sbar_bigfont;
 120         sbar_fontsize = stov(cvar_string("sbar_fontsize"));
 121         if(sbar_fontsize_x == 0)
 122                 sbar_fontsize = '8 8 0';
 123         if(sbar_fontsize_y == 0)
 124                 sbar_fontsize_y = sbar_fontsize_x;
 125
 126         pos_y = ymin;
 127         pos_z = 0;
 128         pos_x = center - stringwidth("Vote for a map", false) * 0.5 * 24;
 129         drawstring(pos, "Vote for a map", '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
 130         pos_y += 26;
 131
 132         i = ceil(mv_timeout - time);
 133         map = strcat(ftos(i), " seconds left");
 134         pos_x = center - stringwidth(map, false) * 0.5 * 16;
 135         drawstring(pos, map, '16 16 0', '0 1 0', 1, DRAWFLAG_NORMAL);
 136         pos_y += 22;
 137         pos_x = xmin;
 138
 139         drawfont = sbar_font;
 140
 141         isize = (ymax - pos_y - mv_num_maps*10) / mv_num_maps;
 142         isize = min(isize, 64);
 143
 144         for(i = 0; i < (mv_num_maps - mv_abstain); ++i)
 145         {
 146                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 147                 if(tmp < 0)
 148                 {
 149                         pos_y += isize + 10;
 150                         continue;
 151                 }
 152                 map = mv_maps[i];
 153                 if(mv_preview[i])
 154                         MapVote_DrawMapItem(pos, isize, map, mv_pics[i], tmp, i);
 155                 else
 156                         MapVote_DrawMapNotAvailable(pos, isize, map, tmp, i);
 157                 pos_y += isize + 10;
 158         }
 159         if(mv_abstain && i < mv_num_maps) {
 160                 tmp = mv_votes[i];
 161                 MapVote_DrawAbstain(pos, isize, tmp, i);
 162         }
 163 }
 164
 165 void Cmd_MapVote_MapDownload(float argc)
 166 {
 167         float id;
 168         entity pak;
 169
 170         if(argc != 2 || !mv_pk3list)
 171         {
 172                 print("mv_mapdownload: ^3You're not supposed to use this command on your own!\n");
 173                 return;
 174         }
 175
 176         id = stof(argv(1));
 177         for(pak = mv_pk3list; pak; pak = pak.chain)
 178                 if(pak.sv_entnum == id)
 179                         break;
 180
 181         if(!pak || pak.sv_entnum != id) {
 182                 print("^1Error:^7 Couldn't find pak index.\n");
 183                 return;
 184         }
 185
 186         //print(strcat("^3Adding: ", ftos(id), " - ", pak.message, " - "));
 187
 188         if(PreviewExists(pak.message))
 189         {
 190                 mv_preview[id] = true;
 191                 //print("^2Found...\n");
 192                 return;
 193         } else if(csqc_flags & CSQC_FLAG_READPICTURE) {
 194                 print("Requesting preview...\n");
 195                 localcmd(strcat("\ncmd mv_getpic ", ftos(id), "\n"));
 196         } else {
 197                 print("^3Missing map preview - Update to a newer build to be able to see them.\n");
 198         }
 199 }
 200
 201 void MapVote_CheckPK3(string pic, string pk3, float id)
 202 {
 203         entity pak;
 204         pak = spawn();
 205         pak.netname = pk3;
 206         pak.message = pic;
 207         pak.sv_entnum = id;
 208
 209         pak.chain = mv_pk3list;
 210         mv_pk3list = pak;
 211
 212         localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 213 }
 214
 215 void MapVote_CheckPic(string pic, string pk3, float id)
 216 {
 217         if(PreviewExists(pic))
 218         {
 219                 mv_preview[id] = true;
 220                 return;
 221         }
 222         MapVote_CheckPK3(pic, pk3, id);
 223 }
 224
 225 void MapVote_Init()
 226 {
 227         float i, power, m;
 228         string map, pk3;
 229
 230         registercmd("+showscores");
 231         registercmd("-showscores");
 232
 233         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 234         mv_abstain = ReadByte();
 235         if(mv_abstain)
 236                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 237         mv_detail = ReadByte();
 238
 239         mv_ownvote = -1;
 240         mv_timeout = time + ReadByte();
 241
 242         if(mv_num_maps <= 8)
 243                 m = ReadByte();
 244         else
 245                 m = ReadShort();
 246
 247         // Assume mv_pk3list is NULL, there should only be 1 mapvote per round
 248         mv_pk3list = NULL; // I'm still paranoid!
 249
 250         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 251         {
 252                 mv_votes[i] = 0;
 253
 254                 if(m & power)
 255                 {
 256                         map = strzone(ReadString());
 257                         pk3 = strzone(ReadString());
 258                         mv_maps[i] = map;
 259                         mv_pk3[i] = pk3;
 260                         map = strzone(strcat(config_get("mv_screenshot_dir", "maps"), "/", map));
 261                         mv_pics[i] = map;
 262
 263                         mv_preview[i] = false;
 264
 265                         //print(strcat("RECV: ", map, " in ", pk3, "\n"));
 266                         MapVote_CheckPic(map, pk3, i);
 267                 }
 268                 else
 269                 {
 270                         mv_maps[i] = strzone("if-you-see-this-the-code-is-broken");
 271                         mv_pk3[i] = strzone("if-you-see-this-the-code-is-broken");
 272                         mv_pics[i] = strzone("if-you-see-this-the-code-is-broken");
 273                         mv_preview[i] = false;
 274                 }
 275         }
 276 }
 277
 278 void MapVote_Update()
 279 {
 280         float i, power;
 281         float m;
 282         if(mv_num_maps <= 8)
 283                 m = ReadByte();
 284         else
 285                 m = ReadShort();
 286         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 287         {
 288                 if(m & power)
 289                 {
 290                         if(mv_detail)
 291                                 mv_votes[i] = ReadByte();
 292                         else
 293                                 mv_votes[i] = 0;
 294                 }
 295                 else
 296                         mv_votes[i] = -1;
 297         }
 298 }
 299
 300 string Net_ReadPicture();
 301 void Net_Mapvote()
 302 {
 303         float type;
 304         type = ReadByte();
 305         switch(type)
 306         {
 307         case MAPVOTE_NET_INIT:
 308                 MapVote_Init();
 309                 // do we NEED this, or can we handle key presses directly in CSQC?
 310                 localcmd("\nin_bind 7 1 \"impulse 1\"; in_bind 7 2 \"impulse 2\"; in_bind 7 3 \"impulse 3\"; in_bind 7 4 \"impulse 4\"; in_bind 7 5 \"impulse 5\"; in_bind 7 6 \"impulse 6\"; in_bind 7 7 \"impulse 7\"; in_bind 7 8 \"impulse 8\"; in_bind 7 9 \"impulse 9\"; in_bind 7 0 \"impulse 10\"; in_bind 7 KP_1 \"impulse 1\"; in_bind 7 KP_2 \"impulse 2\"; in_bind 7 KP_3 \"impulse 3\"; in_bind 7 KP_4 \"impulse 4\"; in_bind 7 KP_5 \"impulse 5\"; in_bind 7 KP_6 \"impulse 6\"; in_bind 7 KP_7 \"impulse 7\"; in_bind 7 KP_8 \"impulse 8\"; in_bind 7 KP_9 \"impulse 9\"; in_bind 7 KP_0 \"impulse 10\"; in_bindmap 7 0\n");
 311                 break;
 312         case MAPVOTE_NET_UPDATE:
 313                 MapVote_Update();
 314                 break;
 315         case MAPVOTE_NET_OWNVOTE:
 316                 mv_ownvote = ReadByte()-1;
 317                 break;
 318         case MAPVOTE_NET_PIC:
 319                 type = ReadByte();
 320                 mv_preview[type] = true;
 321                 mv_pics[type] = strzone(Net_ReadPicture());
 322                 break;
 323         }
 324 }