data/qcsrc/client/mapvoting.qc

   1 float mv_num_maps;
   2
   3 string mv_maps[MAPVOTE_COUNT];
   4 string mv_pics[MAPVOTE_COUNT];
   5 string mv_pk3[MAPVOTE_COUNT];
   6 float mv_preview[MAPVOTE_COUNT];
   7 float mv_votes[MAPVOTE_COUNT];
   8 entity mv_pk3list;
   9 float mv_abstain;
  10 float mv_ownvote;
  11 float mv_detail;
  12 float mv_timeout;
  13
  14 // TODO: First the text, then the image above it, centered
  15 void MapVote_DrawMapItem(vector pos, float isize, string map, string pic, float count, float id)
  16 {
  17         vector img_size;
  18         vector rgb;
  19         string label;
  20         float text_size;
  21
  22         if(id == mv_ownvote)
  23                 rgb = '1 1 0';
  24         else
  25                 rgb = '1 1 1';
  26
  27         isize -= sbar_fontsize_y; // respect the text when calculating the image size
  28
  29         img_size_y = isize;
  30         img_size_x = isize / 0.75; // 4:3 x can be stretched easily, height is defined in isize
  31
  32         drawfont = sbar_font;
  33         pos_y = pos_y + img_size_y;
  34
  35         if(mv_detail)
  36                 label = strcat(ftos(id+1), ". ", ftos(count), ": ", map);
  37         else
  38                 label = strcat(ftos(id+1), ". ", map);
  39
  40         text_size = stringwidth(label, false) * sbar_fontsize_x;
  41
  42         pos_x -= text_size*0.5;
  43         drawstring(pos, label, sbar_fontsize, rgb, 1, DRAWFLAG_NORMAL);
  44
  45         pos_x = pos_x + text_size*0.5 - img_size_x*0.5;
  46         pos_y = pos_y - img_size_y;
  47         drawpic(pos, pic, img_size, '1 1 1', 1, DRAWFLAG_NORMAL);
  48 }
  49
  50 void MapVote_DrawMapNotAvailable(vector pos, float isize, string map, float count, float id)
  51 {
  52         vector img_size, a, b;
  53         vector rgb;
  54         string label;
  55         float text_size;
  56
  57         if(id == mv_ownvote)
  58                 rgb = '1 1 0';
  59         else
  60                 rgb = '1 1 1';
  61
  62         isize -= sbar_fontsize_y; // respect the text when calculating the image size
  63
  64         img_size_y = isize;
  65         img_size_x = isize / 0.75; // 4:3 x can be stretched easily, height is defined in isize
  66
  67         drawfont = sbar_font;
  68         pos_y = pos_y + img_size_y;
  69
  70         if(mv_detail)
  71                 label = strcat(ftos(id+1), ". ", ftos(count), ": ", map);
  72         else
  73                 label = strcat(ftos(id+1), ". ", map);
  74
  75         text_size = stringwidth(label, false) * sbar_fontsize_x;
  76
  77         pos_x -= text_size*0.5;
  78         drawstring(pos, label, sbar_fontsize, rgb, 1, DRAWFLAG_NORMAL);
  79
  80         a_x = img_size_x; // for the lines
  81         b_y = img_size_y;
  82
  83         pos_x = pos_x + text_size*0.5 - img_size_x*0.5;
  84         pos_y = pos_y - img_size_y;
  85
  86         drawfill(pos, img_size, '.5 .5 .5', .7, DRAWFLAG_NORMAL);
  87         drawline(2, pos, pos + a, '1 1 1', 1, DRAWFLAG_NORMAL);
  88         drawline(2, pos, pos + b, '1 1 1', 1, DRAWFLAG_NORMAL);
  89         drawline(2, pos + img_size, pos + a, '1 1 1', 1, DRAWFLAG_NORMAL);
  90         drawline(2, pos + img_size, pos + b, '1 1 1', 1, DRAWFLAG_NORMAL);
  91 }
  92
  93 void MapVote_DrawAbstain(vector pos, float isize, float count, float id)
  94 {
  95         vector img_size;
  96         vector rgb;
  97         float text_size;
  98         string label;
  99
 100         if(id == mv_ownvote)
 101                 rgb = '1 1 0';
 102         else
 103                 rgb = '1 1 1';
 104
 105         drawfont = sbar_font;
 106         pos_y = pos_y + sbar_fontsize_y;
 107
 108         if(mv_detail)
 109                 label = strcat(ftos(id+1), ". ", ftos(count), ": Don't care");
 110         else
 111                 label = strcat(ftos(id+1), ". Don't care");
 112
 113         text_size = stringwidth(label, false) * sbar_fontsize_x;
 114
 115         pos_x -= text_size*0.5;
 116         drawstring(pos, label, sbar_fontsize, rgb, 1, DRAWFLAG_NORMAL);
 117 }
 118
 119 void MapVote_Draw()
 120 {
 121         string map;
 122         float i, tmp;
 123         vector pos;
 124         float isize;
 125         float center;
 126
 127         center = (vid_conwidth - 1)/2;
 128         xmin = vid_conwidth*0.05; // 5% border must suffice
 129         xmax = vid_conwidth - xmin;
 130         ymin = 24;
 131         i = cvar("con_chatpos"); //*cvar("con_chatsize");
 132         if(i < 0)
 133                 ymax = vid_conheight + (i - cvar("con_chat")) * cvar("con_chatsize");
 134         if(i >= 0 || ymax < (vid_conheight*0.5))
 135                 ymax = vid_conheight - ymin;
 136
 137         drawfont = sbar_bigfont;
 138         sbar_fontsize = stov(cvar_string("sbar_fontsize"));
 139         if(sbar_fontsize_x == 0)
 140                 sbar_fontsize = '8 8 0';
 141         if(sbar_fontsize_y == 0)
 142                 sbar_fontsize_y = sbar_fontsize_x;
 143
 144         pos_y = ymin;
 145         pos_z = 0;
 146         pos_x = center - stringwidth("Vote for a map", false) * 0.5 * 24;
 147         drawstring(pos, "Vote for a map", '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
 148         pos_y += 26;
 149
 150         i = ceil(mv_timeout - time);
 151         map = strcat(ftos(i), " seconds left");
 152         pos_x = center - stringwidth(map, false) * 0.5 * 16;
 153         drawstring(pos, map, '16 16 0', '0 1 0', 1, DRAWFLAG_NORMAL);
 154         pos_y += 22;
 155         pos_x = xmin;
 156
 157         drawfont = sbar_bigfont; // FIXME change this to sbar_font when it gets a SANE size later
 158
 159         // base for multi-column stuff...
 160         ymin = pos_y;
 161         if(mv_abstain)
 162                 mv_num_maps -= 1;
 163
 164         if(mv_num_maps > 5)
 165         {
 166                 isize = (ymax - pos_y - mv_num_maps*10) / ceil(0.5*mv_num_maps);
 167                 pos_x = xmin + 0.25*(xmax-xmin);
 168         } else {
 169                 isize = (ymax - pos_y - mv_num_maps*10) / mv_num_maps;
 170                 pos_x = xmin + 0.5*(xmax-xmin);
 171         }
 172
 173         ymax -= isize;
 174         for(i = 0; i < mv_num_maps; ++i)
 175         {
 176                 // base for multi-column stuff
 177                 if(pos_y > ymax)
 178                 {
 179                         pos_y = ymin;
 180                         pos_x = xmin + 0.75*(xmax-xmin);
 181                         //xmax = 2*xmax - xmin;
 182                         //xmin = pos_x;
 183                 }
 184
 185                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 186                 if(tmp < 0)
 187                 {
 188                         pos_y += isize + 10;
 189                         continue;
 190                 }
 191                 map = mv_maps[i];
 192                 if(mv_preview[i])
 193                         MapVote_DrawMapItem(pos, isize, map, mv_pics[i], tmp, i);
 194                 else
 195                         MapVote_DrawMapNotAvailable(pos, isize, map, tmp, i);
 196                 pos_y += isize + 10;
 197         }
 198
 199         if(mv_abstain)
 200                 mv_num_maps++;
 201
 202         if(mv_abstain && i < mv_num_maps) {
 203                 tmp = mv_votes[i];
 204                 pos_y = ymax + isize - sbar_fontsize_y;
 205                 pos_x = (xmax+xmin)*0.5;
 206                 MapVote_DrawAbstain(pos, isize, tmp, i);
 207         }
 208 }
 209
 210 void Cmd_MapVote_MapDownload(float argc)
 211 {
 212         float id;
 213         entity pak;
 214
 215         if(argc != 2 || !mv_pk3list)
 216         {
 217                 print("mv_mapdownload: ^3You're not supposed to use this command on your own!\n");
 218                 return;
 219         }
 220
 221         id = stof(argv(1));
 222         for(pak = mv_pk3list; pak; pak = pak.chain)
 223                 if(pak.sv_entnum == id)
 224                         break;
 225
 226         if(!pak || pak.sv_entnum != id) {
 227                 print("^1Error:^7 Couldn't find pak index.\n");
 228                 return;
 229         }
 230
 231         //print(strcat("^3Adding: ", ftos(id), " - ", pak.message, " - "));
 232
 233         if(PreviewExists(pak.message))
 234         {
 235                 mv_preview[id] = true;
 236                 //print("^2Found...\n");
 237                 return;
 238         } else if(csqc_flags & CSQC_FLAG_READPICTURE) {
 239                 print("Requesting preview...\n");
 240                 localcmd(strcat("\ncmd mv_getpic ", ftos(id), "\n"));
 241         } else {
 242                 print("^3Missing map preview - Update to a newer build to be able to see them.\n");
 243         }
 244 }
 245
 246 void MapVote_CheckPK3(string pic, string pk3, float id)
 247 {
 248         entity pak;
 249         pak = spawn();
 250         pak.netname = pk3;
 251         pak.message = pic;
 252         pak.sv_entnum = id;
 253
 254         pak.chain = mv_pk3list;
 255         mv_pk3list = pak;
 256
 257         localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 258 }
 259
 260 void MapVote_CheckPic(string pic, string pk3, float id)
 261 {
 262         if(PreviewExists(pic))
 263         {
 264                 mv_preview[id] = true;
 265                 return;
 266         }
 267         MapVote_CheckPK3(pic, pk3, id);
 268 }
 269
 270 void MapVote_Init()
 271 {
 272         float i, power, m;
 273         string map, pk3;
 274
 275         registercmd("+showscores");
 276         registercmd("-showscores");
 277
 278         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 279         mv_abstain = ReadByte();
 280         if(mv_abstain)
 281                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 282         mv_detail = ReadByte();
 283
 284         mv_ownvote = -1;
 285         mv_timeout = time + ReadByte();
 286
 287         if(mv_num_maps <= 8)
 288                 m = ReadByte();
 289         else
 290                 m = ReadShort();
 291
 292         // Assume mv_pk3list is NULL, there should only be 1 mapvote per round
 293         mv_pk3list = NULL; // I'm still paranoid!
 294
 295         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 296         {
 297                 mv_votes[i] = 0;
 298
 299                 if(m & power)
 300                 {
 301                         map = strzone(ReadString());
 302                         pk3 = strzone(ReadString());
 303                         mv_maps[i] = map;
 304                         mv_pk3[i] = pk3;
 305                         map = strzone(strcat(config_get("mv_screenshot_dir", "maps"), "/", map));
 306                         mv_pics[i] = map;
 307
 308                         mv_preview[i] = false;
 309
 310                         //print(strcat("RECV: ", map, " in ", pk3, "\n"));
 311                         MapVote_CheckPic(map, pk3, i);
 312                 }
 313                 else
 314                 {
 315                         mv_maps[i] = strzone("if-you-see-this-the-code-is-broken");
 316                         mv_pk3[i] = strzone("if-you-see-this-the-code-is-broken");
 317                         mv_pics[i] = strzone("if-you-see-this-the-code-is-broken");
 318                         mv_preview[i] = false;
 319                 }
 320         }
 321 }
 322
 323 void MapVote_Update()
 324 {
 325         float i, power;
 326         float m;
 327         if(mv_num_maps <= 8)
 328                 m = ReadByte();
 329         else
 330                 m = ReadShort();
 331         for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 332         {
 333                 if(m & power)
 334                 {
 335                         if(mv_detail)
 336                                 mv_votes[i] = ReadByte();
 337                         else
 338                                 mv_votes[i] = 0;
 339                 }
 340                 else
 341                         mv_votes[i] = -1;
 342         }
 343 }
 344
 345 string Net_ReadPicture();
 346 void Net_Mapvote()
 347 {
 348         float type;
 349         type = ReadByte();
 350         switch(type)
 351         {
 352         case MAPVOTE_NET_INIT:
 353                 MapVote_Init();
 354                 // do we NEED this, or can we handle key presses directly in CSQC?
 355                 localcmd("\nin_bind 7 1 \"impulse 1\"; in_bind 7 2 \"impulse 2\"; in_bind 7 3 \"impulse 3\"; in_bind 7 4 \"impulse 4\"; in_bind 7 5 \"impulse 5\"; in_bind 7 6 \"impulse 6\"; in_bind 7 7 \"impulse 7\"; in_bind 7 8 \"impulse 8\"; in_bind 7 9 \"impulse 9\"; in_bind 7 0 \"impulse 10\"; in_bind 7 KP_1 \"impulse 1\"; in_bind 7 KP_2 \"impulse 2\"; in_bind 7 KP_3 \"impulse 3\"; in_bind 7 KP_4 \"impulse 4\"; in_bind 7 KP_5 \"impulse 5\"; in_bind 7 KP_6 \"impulse 6\"; in_bind 7 KP_7 \"impulse 7\"; in_bind 7 KP_8 \"impulse 8\"; in_bind 7 KP_9 \"impulse 9\"; in_bind 7 KP_0 \"impulse 10\"; in_bindmap 7 0\n");
 356                 break;
 357         case MAPVOTE_NET_UPDATE:
 358                 MapVote_Update();
 359                 break;
 360         case MAPVOTE_NET_OWNVOTE:
 361                 mv_ownvote = ReadByte()-1;
 362                 break;
 363         case MAPVOTE_NET_PIC:
 364                 type = ReadByte();
 365                 mv_preview[type] = true;
 366                 mv_pics[type] = strzone(Net_ReadPicture());
 367                 break;
 368         }
 369 }