data/qcsrc/client/casings.qc

   1 void Casing_Draw()
   2 {
   3         if(self.move_flags & FL_ONGROUND)
   4         {
   5                 self.move_angles_x = 0;
   6                 self.move_angles_z = 0;
   7                 self.flags &~= FL_ONGROUND;
   8         }
   9
  10         Movetype_Physics(FALSE);
  11
  12         self.renderflags = 0;
  13         self.alpha = bound(0, self.cnt - time, 1);
  14
  15         if(self.alpha == 0)
  16                 remove(self);
  17         else
  18                 R_AddEntity(self);
  19 }
  20
  21 float trace_networkentity;
  22 void Casing_Touch()
  23 {
  24         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  25         {
  26                 remove(self);
  27                 return;
  28         }
  29
  30         if(!trace_ent || trace_ent.solid == SOLID_BSP)
  31         {
  32                 if(vlen(self.velocity) > 50)
  33                 {
  34                         if(time >= self.nextthink)
  35                         {
  36                                 string s;
  37                                 float f;
  38
  39                                 f = floor(random() * 3) + 1;
  40                                 switch(self.state)
  41                                 {
  42                                         case 1:
  43                                                 s = strcat("weapons/casings", ftos(f), ".wav");
  44                                                 break;
  45                                         default:
  46                                                 s = strcat("weapons/brass", ftos(f), ".wav");
  47                                                 break;
  48                                 }
  49
  50                                 sound (self, CHAN_PROJECTILE, s, VOL_BASE, ATTN_NORM);
  51                                 self.nextthink = time + 0.7;
  52                         }
  53                 }
  54         }
  55 }
  56
  57 void Casing_Damage(float thisdmg, float hittype, vector org, vector thisforce)
  58 {
  59         if(thisforce_z < 0)
  60                 thisforce_z = 0;
  61         self.move_velocity = self.move_velocity + thisforce + '0 0 100';
  62         self.move_flags &~= FL_ONGROUND;
  63 }
  64
  65 void Ent_Casing()
  66 {
  67         entity casing;
  68
  69         casing = spawn();
  70         casing.state = ReadByte();
  71         casing.origin_x = ReadCoord();
  72         casing.origin_y = ReadCoord();
  73         casing.origin_z = ReadCoord();
  74         casing.velocity = decompressShortVector(ReadShort());
  75         casing.angles_x = ReadByte() * 360 / 256;
  76         casing.angles_y = ReadByte() * 360 / 256;
  77         casing.angles_z = ReadByte() * 360 / 256;
  78
  79         casing.draw = Casing_Draw;
  80         casing.move_origin = casing.origin;
  81         casing.move_velocity = casing.velocity + 2 * randomvec();
  82         casing.move_angles = casing.angles;
  83         casing.move_avelocity = '0 250 0' + 100 * randomvec();
  84         casing.move_movetype = MOVETYPE_BOUNCE;
  85         casing.move_touch = Casing_Touch;
  86         casing.move_time = time;
  87         casing.event_damage = Casing_Damage;
  88         casing.solid = SOLID_TRIGGER;
  89
  90         switch(casing.state)
  91         {
  92                 case 1:
  93                         setmodel(casing, "models/casing_shell.mdl");
  94                         casing.cnt = time + 30;
  95                         break;
  96                 default:
  97                         setmodel(casing, "models/casing_bronze.mdl");
  98                         casing.cnt = time + 10;
  99                         break;
 100         }
 101
 102         setsize(casing, '0 0 -1', '0 0 -1');
 103 }
 104
 105 void Casings_Precache()
 106 {
 107         precache_model("models/casing_shell.mdl");
 108         precache_model("models/casing_bronze.mdl");
 109         precache_sound("weapons/brass1.wav");
 110         precache_sound("weapons/brass2.wav");
 111         precache_sound("weapons/brass3.wav");
 112         precache_sound("weapons/casings1.wav");
 113         precache_sound("weapons/casings2.wav");
 114         precache_sound("weapons/casings3.wav");
 115 }