data/qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/spiderbot/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/spiderbot/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 entity porto;
   9 vector polyline[16];
  10 float trace_dphitcontents;
  11 float trace_networkentity;
  12 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  13 float DPCONTENTS_SOLID = 1; // blocks player movement
  14 float DPCONTENTS_BODY = 32; // blocks player movement
  15 float DPCONTENTS_CORPSE = 64; // blocks player movement
  16 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  17 void Porto_Draw()
  18 {
  19         vector p, dir, ang, q, nextdir;
  20         float idx, portal_number, portal1_idx;
  21
  22         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  23                 return;
  24         if(intermission == 1)
  25                 return;
  26         if(intermission == 2)
  27                 return;
  28         if (getstati(STAT_HEALTH) <= 0)
  29                 return;
  30
  31         dir = view_forward;
  32
  33         if(angles_held_status)
  34         {
  35                 makevectors(angles_held);
  36                 dir = v_forward;
  37         }
  38
  39         p = view_origin;
  40
  41         polyline[0] = p;
  42         idx = 1;
  43         portal_number = 0;
  44         nextdir = dir;
  45
  46         for(;;)
  47         {
  48                 dir = nextdir;
  49                 traceline(p, p + 65536 * dir, TRUE, porto);
  50                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  51                         return;
  52                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  53                 p = trace_endpos;
  54                 polyline[idx] = p;
  55                 ++idx;
  56                 if(idx >= 16)
  57                         return;
  58                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  59                         continue;
  60                 ++portal_number;
  61                 ang = vectoangles2(trace_plane_normal, dir);
  62                 ang_x = -ang_x;
  63                 makevectors(ang);
  64                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  65                         return;
  66                 if(portal_number == 1)
  67                         portal1_idx = idx;
  68                 if(portal_number >= 2)
  69                         break;
  70         }
  71
  72         while(idx >= 2)
  73         {
  74                 p = polyline[idx-2];
  75                 q = polyline[idx-1];
  76                 if(idx == 2)
  77                         p = p - view_up * 16;
  78                 if(idx-1 >= portal1_idx)
  79                 {
  80                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL);
  81                 }
  82                 else
  83                 {
  84                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL);
  85                 }
  86                 --idx;
  87         }
  88 }
  89
  90 /**
  91  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  92  *
  93  * TODO: Use a better solution where a common shared entitiy is used that contains
  94  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  95  * and STAT_FRAGLIMIT to be auto-sent)
  96  */
  97 void CheckForGamestartChange() {
  98         float startTime;
  99         startTime = getstatf(STAT_GAMESTARTTIME);
 100         if (previous_game_starttime != startTime) {
 101                 if ((time + 5.0) < startTime) {
 102                         //if connecting to server while restart was active don't always play prepareforbattle
 103                         sound(self, CHAN_VOICE, "announcer/robotic/prepareforbattle.wav", VOL_BASEVOICE, ATTN_NONE);
 104                 }
 105                 if (time < startTime) {
 106                         restartAnnouncer = spawn();
 107                         restartAnnouncer.think = restartAnnouncer_Think;
 108                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 109                 }
 110         }
 111         previous_game_starttime = startTime;
 112 }
 113
 114 void Porto_Init()
 115 {
 116         porto = spawn();
 117         porto.classname = "porto";
 118         porto.draw = Porto_Draw;
 119         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 120 }
 121
 122 float drawtime;
 123
 124 float tan(float x)
 125 {
 126         return sin(x) / cos(x);
 127 }
 128 float atan2(float y, float x)
 129 {
 130         vector v;
 131         v = '1 0 0' * x + '0 1 0' * y;
 132         v = vectoangles(v);
 133         return v_y * 0.01745329251994329576;
 134 }
 135
 136 vector GetCurrentFov(float fov)
 137 {
 138         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 139
 140         zoomsensitivity = cvar("cl_zoomsensitivity");
 141         zoomfactor = cvar("cl_zoomfactor");
 142         if(zoomfactor < 1 || zoomfactor > 16)
 143                 zoomfactor = 2.5;
 144         zoomspeed = cvar("cl_zoomspeed");
 145         if(zoomspeed >= 0)
 146                 if(zoomspeed < 0.5 || zoomspeed > 16)
 147                         zoomspeed = 3.5;
 148
 149         zoomdir = button_zoom;
 150         if(getstati(STAT_ACTIVEWEAPON) == WEP_NEX) // do NOT use switchweapon here
 151                 zoomdir += button_attack2;
 152         if(spectatee_status > 0 || isdemo())
 153         {
 154                 if(spectatorbutton_zoom)
 155                         zoomdir = 0 + !zoomdir;
 156                         // do not even THINK about removing this 0
 157                         // _I_ know what I am doing
 158                         // fteqcc does not
 159         }
 160
 161         if(zoomdir)
 162                 zoomin_effect = 0;
 163
 164         if(zoomin_effect || camera_active)
 165         {
 166                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 167         }
 168         else
 169         {
 170                 if(zoomspeed < 0) // instant zoom
 171                 {
 172                         if(zoomdir)
 173                                 current_viewzoom = 1 / zoomfactor;
 174                         else
 175                                 current_viewzoom = 1;
 176                 }
 177                 else
 178                 {
 179                         if(zoomdir)
 180                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 181                         else
 182                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 183                 }
 184         }
 185
 186         if(almost_equals(current_viewzoom, 1))
 187                 current_zoomfraction = 0;
 188         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 189                 current_zoomfraction = 1;
 190         else
 191                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 192
 193         if(zoomsensitivity < 1)
 194                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 195         else
 196                 setsensitivityscale(1);
 197
 198         float frustumx, frustumy, fovx, fovy;
 199         frustumy = tan(fov * 0.00872664625997164788) * 0.75 * current_viewzoom;
 200         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 201         fovx = atan2(frustumx, 1) / 0.00872664625997164788;
 202         fovy = atan2(frustumy, 1) / 0.00872664625997164788;
 203
 204         return '1 0 0' * fovx + '0 1 0' * fovy;
 205 }
 206
 207 // this function must match W_SetupShot!
 208 float zoomscript_caught;
 209 entity trueaim;
 210
 211 #define SHOTTYPE_HITTEAM 1
 212 #define SHOTTYPE_HITOBSTRUCTION 2
 213 #define SHOTTYPE_HITWORLD 3
 214 #define SHOTTYPE_HITENEMY 4
 215
 216 void TrueAim_Init()
 217 {
 218         trueaim = spawn();
 219         trueaim.classname = "trueaim";
 220         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 221 }
 222
 223 float EnemyHitCheck(vector start, vector mi, vector ma, vector end)
 224 {
 225         float t;
 226         tracebox(start, mi, ma, end, MOVE_NORMAL, trueaim);
 227         if(trace_networkentity < 1)
 228                 return SHOTTYPE_HITWORLD;
 229         if(trace_networkentity > maxclients)
 230                 return SHOTTYPE_HITWORLD;
 231         t = GetPlayerColor(trace_networkentity - 1);
 232         if(teamplay)
 233         if(t == myteam)
 234                 return SHOTTYPE_HITTEAM;
 235         if(t == COLOR_SPECTATOR)
 236                 return SHOTTYPE_HITWORLD;
 237         return SHOTTYPE_HITENEMY;
 238 }
 239
 240 float TrueAimCheck()
 241 {
 242         float nudge = 1; // added to traceline target and subtracted from result
 243         vector vecs, trueaimpoint, w_shotorg;
 244         vector mi, ma, dv;
 245         float shottype;
 246
 247         mi = ma = '0 0 0';
 248
 249         switch(activeweapon)
 250         {
 251                 case WEP_TUBA: // no aim
 252                 case WEP_PORTO: // shoots from eye
 253                 case WEP_HOOK: // no trueaim
 254                 case WEP_GRENADE_LAUNCHER: // toss curve
 255                         return SHOTTYPE_HITWORLD;
 256                 case WEP_CAMPINGRIFLE:
 257                         if(zoomscript_caught)
 258                                 return EnemyHitCheck(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE);
 259                         break;
 260                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 261                         mi = '-3 -3 -3';
 262                         ma = '3 3 3';
 263                         break;
 264                 case WEP_SEEKER: // projectile has a size!
 265                         mi = '-2 -2 -2';
 266                         ma = '2 2 2';
 267                         break;
 268                 case WEP_ELECTRO: // projectile has a size!
 269                         mi = '0 0 -3';
 270                         ma = '0 0 -3';
 271                         break;
 272         }
 273
 274         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 275
 276         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, MOVE_NOMONSTERS, trueaim);
 277         trueaimpoint = trace_endpos;
 278
 279         if(vecs_x > 0)
 280                 vecs_y = -vecs_y;
 281         else
 282                 vecs = '0 0 0';
 283
 284         dv = view_right * vecs_y + view_up * vecs_z;
 285         w_shotorg = view_origin + dv;
 286
 287         // now move the vecs forward as much as requested if possible
 288         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, trueaim); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 289         w_shotorg = trace_endpos - view_forward * nudge;
 290
 291         shottype = EnemyHitCheck(w_shotorg, mi, ma, trueaimpoint);
 292         if(shottype != SHOTTYPE_HITWORLD)
 293                 return shottype;
 294
 295         // now test whether we will actually hit the trueaimpoint...
 296         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NOMONSTERS, trueaim);
 297
 298         if(vlen(trace_endpos - trueaimpoint) > vlen(ma - mi) + 1)
 299                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 300                 return SHOTTYPE_HITOBSTRUCTION;
 301
 302         return SHOTTYPE_HITWORLD;
 303 }
 304
 305 void CSQC_common_hud(void);
 306
 307 void CSQC_kh_hud(void);
 308 void CSQC_ctf_hud(void);
 309 void PostInit(void);
 310 void CSQC_Demo_Camera();
 311 float Sbar_WouldDrawScoreboard ();
 312 float view_set;
 313 float camera_mode;
 314 string NextFrameCommand;
 315 void CSQC_spider_HUD();
 316 void CSQC_UpdateView(float w, float h)
 317 {
 318         entity e;
 319         float fov;
 320         float f, i, j;
 321
 322         dprint_load();
 323         WaypointSprite_Load();
 324
 325         if(spectatee_status)
 326                 myteam = GetPlayerColor(spectatee_status - 1);
 327         else
 328                 myteam = GetPlayerColor(player_localentnum - 1);
 329
 330         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 331
 332         // Render the Scene
 333         if(!intermission || !view_set)
 334         {
 335                 view_origin = pmove_org + '0 0 1' * getstati(STAT_VIEWHEIGHT);
 336                 view_angles = input_angles;
 337                 makevectors(view_angles);
 338                 view_forward = v_forward;
 339                 view_right = v_right;
 340                 view_up = v_up;
 341                 view_set = 1;
 342         }
 343
 344         vid_width = w;
 345         vid_height = h;
 346
 347 #ifdef BLURTEST
 348         if(time > blurtest_time0 && time < blurtest_time1)
 349         {
 350                 float r, t;
 351
 352                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 353                 r = t * blurtest_radius;
 354                 f = 1 / pow(t, blurtest_power) - 1;
 355
 356                 cvar_set("r_glsl_postprocess", "1");
 357                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 358         }
 359         else
 360         {
 361                 cvar_set("r_glsl_postprocess", "0");
 362                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 363         }
 364 #endif
 365
 366         Fog_Force();
 367
 368         drawframetime = max(0.000001, time - drawtime);
 369         drawtime = time;
 370
 371         // watch for gametype changes here...
 372         // in ParseStuffCMD the cmd isn't executed yet :/
 373         // might even be better to add the gametype to TE_CSQC_INIT...?
 374         if(!postinit)
 375                 PostInit();
 376
 377         CheckForGamestartChange();
 378         maptimeAnnouncer();
 379
 380         fov = cvar("fov");
 381         if(button_zoom || fov <= 59.5)
 382         {
 383                 if(!zoomscript_caught)
 384                 {
 385                         localcmd("+button4\n");
 386                         zoomscript_caught = 1;
 387                         ignore_plus_zoom += 1;
 388                 }
 389         }
 390         else
 391         {
 392                 if(zoomscript_caught)
 393                 {
 394                         localcmd("-button4\n");
 395                         zoomscript_caught = 0;
 396                         ignore_minus_zoom += 1;
 397                 }
 398         }
 399
 400         sbar_alpha_fg = cvar("sbar_alpha_fg" );
 401         sbar_currentammo = cvar("sbar_showcurrentammo");
 402         sbar_hudselector = cvar("sbar_hudselector");
 403         sbar_hud_accuracy = cvar("sbar_hud_accuracy");
 404         ColorTranslateMode = cvar("cl_stripcolorcodes");
 405         activeweapon = getstati(STAT_SWITCHWEAPON);
 406         f = cvar("teamplay");
 407         if(f != teamplay)
 408         {
 409                 teamplay = f;
 410                 Sbar_InitScores();
 411         }
 412
 413         if(last_weapon != activeweapon) {
 414                 weapontime = time;
 415                 last_weapon = activeweapon;
 416         }
 417
 418         // ALWAYS Clear Current Scene First
 419         R_ClearScene();
 420
 421         // Assign Standard Viewflags
 422         // Draw the World (and sky)
 423         R_SetView(VF_DRAWWORLD, 1);
 424
 425         // Set the console size vars
 426         vid_conwidth = cvar("vid_conwidth");
 427         vid_conheight = cvar("vid_conheight");
 428         vid_pixelheight = cvar("vid_pixelheight");
 429
 430         R_SetView(VF_FOV, GetCurrentFov(fov));
 431
 432         // Camera for demo playback
 433         if(camera_active)
 434         {
 435                 if(cvar("camera_enable"))
 436                         CSQC_Demo_Camera();
 437                 else
 438                 {
 439                         cvar_set("chase_active", ftos(chase_active_backup));
 440                         cvar_set("cl_demo_mousegrab", "0");
 441                         camera_active = FALSE;
 442                 }
 443         }
 444 #ifdef CAMERATEST
 445         else if(cvar("camera_enable"))
 446 #else
 447         else if(cvar("camera_enable") && isdemo())
 448 #endif
 449         {
 450                 // Enable required Darkplaces cvars
 451                 chase_active_backup = cvar("chase_active");
 452                 cvar_set("chase_active", "2");
 453                 cvar_set("cl_demo_mousegrab", "1");
 454                 camera_active = TRUE;
 455                 camera_mode = FALSE;
 456         }
 457
 458         // Draw the Crosshair
 459         float scoreboard_active;
 460         scoreboard_active = Sbar_WouldDrawScoreboard();
 461         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 462
 463         // Draw the Engine Status Bar (the default Quake HUD)
 464         R_SetView(VF_DRAWENGINESBAR, 0);
 465
 466         // fetch this one only once per frame
 467         sbar_showbinds = cvar("sbar_showbinds");
 468         sbar_showbinds_limit = cvar("sbar_showbinds_limit");
 469
 470         // Update the mouse position
 471         /*
 472         mousepos_x = vid_conwidth;
 473         mousepos_y = vid_conheight;
 474         mousepos = mousepos*0.5 + getmousepos();
 475         */
 476
 477         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 478
 479         e = self;
 480         for(self = world; (self = nextent(self)); )
 481                 if(self.draw)
 482                         self.draw();
 483         self = e;
 484         R_RenderScene();
 485
 486         // now switch to 2D drawing mode by calling a 2D drawing function
 487         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 488         // next R_RenderScene call
 489         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 490
 491         // Draw the mouse cursor
 492         // NOTE: drawpic must happen after R_RenderScene for some reason
 493         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 494         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 495         //self = edict_num(player_localnum);
 496         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 497         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 498         // as long as the ctf part isn't in, this is useless
 499         if(menu_visible)
 500                 menu_show();
 501
 502         /*if(gametype == GAME_CTF)
 503         {
 504                 ctf_view();
 505         } else */
 506
 507         // draw 2D entities
 508         e = self;
 509         for(self = world; (self = nextent(self)); )
 510                 if(self.draw2d)
 511                         self.draw2d();
 512         self = e;
 513
 514         // draw radar
 515         if(
 516                 ons_showmap
 517                 ||
 518                 (
 519                         !scoreboard_active
 520                         &&
 521                         cvar_string("cl_teamradar") != "0"
 522                         &&
 523                         (
 524                                 cvar("cl_teamradar") == 2
 525                                 ||
 526                                 teamplay
 527                         )
 528                 )
 529         )
 530                 teamradar_view();
 531
 532         if (cvar("cl_showpressedkeys")) // draw pressed keys when spectating and playing
 533         {
 534                 if(spectatee_status > 0 || cvar("cl_showpressedkeys") >= 2)
 535                         Sbar_DrawPressedKeys();
 536         }
 537
 538         if (cvar("cl_showspeed"))
 539                 Sbar_ShowSpeed();
 540
 541         // draw sbar
 542         if(cvar("r_letterbox") == 0)
 543                 Sbar_DrawCenterPrint(); // draw centerprint messages even if viewsize >= 120
 544
 545     float hud;
 546     hud = getstati(STAT_HUD);
 547     if(hud == HUD_SPIDEBOT)
 548     {
 549         vector sz;
 550         CSQC_spider_HUD();
 551         sz = drawgetimagesize(SPIDER_CROSS);
 552         sz_x *= cvar_or("cl_vehicle_spiderbot_cross_size",1);
 553         sz_y *= cvar_or("cl_vehicle_spiderbot_cross_size",1);
 554         drawpic('0.5 0 0' * (vid_conwidth - sz_x) + '0 0.5 0' * (vid_conheight - sz_y), SPIDER_CROSS, sz, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
 555     }
 556     else
 557     {
 558         if(cvar("r_letterbox") == 0)
 559             if(cvar("viewsize") < 120)
 560                 CSQC_common_hud();
 561
 562         // crosshair goes VERY LAST
 563         if(!scoreboard_active && !ons_showmap && !camera_active) {
 564             // TrueAim check
 565             float shottype;
 566                         float bullets, ring_scale;
 567
 568             if(cvar("crosshair_hittest"))
 569                 shottype = TrueAimCheck();
 570             else
 571                 shottype = SHOTTYPE_HITWORLD;
 572
 573             string wcross_style;
 574             wcross_style = cvar_string("crosshair");
 575
 576             if (wcross_style != "0") {
 577                 vector wcross_color, wcross_size;
 578                 string wcross_wep, wcross_name;
 579                 float wcross_alpha, wcross_sizefloat;
 580
 581                 wcross_color_x = cvar("crosshair_color_red");
 582                 wcross_color_y = cvar("crosshair_color_green");
 583                 wcross_color_z = cvar("crosshair_color_blue");
 584                 wcross_alpha = cvar("crosshair_color_alpha");
 585                 wcross_sizefloat = cvar("crosshair_size");
 586                 if (cvar("crosshair_per_weapon")) {
 587                     e = get_weaponinfo(activeweapon);
 588                     if (e && e.netname != "")
 589                     {
 590                         wcross_wep = e.netname;
 591                         wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 592                         if(wcross_style == "")
 593                             wcross_style = e.netname;
 594
 595                         if(!cvar("crosshair_color_override"))
 596                         {
 597                             wcross_color_x = cvar(strcat("crosshair_", wcross_wep, "_color_red"));
 598                             wcross_color_y = cvar(strcat("crosshair_", wcross_wep, "_color_green"));
 599                             wcross_color_z = cvar(strcat("crosshair_", wcross_wep, "_color_blue"));
 600                         }
 601
 602                         wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_color_alpha"));
 603                         wcross_sizefloat *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 604                     }
 605                 }
 606
 607                 wcross_name = strcat("gfx/crosshair", wcross_style);
 608
 609                                 if(shottype == SHOTTYPE_HITENEMY)
 610                                         wcross_sizefloat *= cvar("crosshair_hittest"); // is not queried if hittest is 0
 611                                 if(shottype == SHOTTYPE_HITTEAM)
 612                                         wcross_sizefloat /= cvar("crosshair_hittest"); // is not queried if hittest is 0
 613
 614                 wcross_size = drawgetimagesize(wcross_name);
 615                 wcross_size_x *= wcross_sizefloat;
 616                 wcross_size_y *= wcross_sizefloat;
 617
 618                                 // ring around crosshair representing bullets left in camping rifle clip
 619                                 if (activeweapon == WEP_CAMPINGRIFLE)
 620                                 {
 621                                         ring_scale = cvar("crosshair_campingrifle_ring_size");
 622                                         bullets = bound(0, getstati(STAT_BULLETS_LOADED), 8);
 623                                 }
 624                                 else
 625                                         bullets = 0;
 626
 627                 if(shottype == SHOTTYPE_HITENEMY || shottype == SHOTTYPE_HITWORLD)
 628                 {
 629                                         if (bullets)
 630                                                 drawpic('0.5 0 0' * (vid_conwidth - wcross_size_x * ring_scale) + '0 0.5 0' * (vid_conheight - wcross_size_y * ring_scale), strcat("gfx/hud/rifle_ring_", ftos(bullets)), wcross_size * ring_scale, wcross_color, wcross_alpha, DRAWFLAG_NORMAL);
 631                     drawpic('0.5 0 0' * (vid_conwidth - wcross_size_x) + '0 0.5 0' * (vid_conheight - wcross_size_y), wcross_name, wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL);
 632                 }
 633                 else
 634                 {
 635                     wcross_alpha *= 0.04 * 0.75;
 636                     for(i = -2; i <= 2; ++i)
 637                         for(j = -2; j <= 2; ++j)
 638                                                 {
 639                                                         if (bullets)
 640                                                                 drawpic('0.5 0 0' * (vid_conwidth - wcross_size_x * ring_scale + i) + '0 0.5 0' * (vid_conheight - wcross_size_y * ring_scale + j), strcat("gfx/hud/rifle_ring_", ftos(bullets)), wcross_size * ring_scale, wcross_color, wcross_alpha, DRAWFLAG_NORMAL);
 641                             drawpic('0.5 0 0' * (vid_conwidth - wcross_size_x + i) + '0 0.5 0' * (vid_conheight - wcross_size_y + j), wcross_name, wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL);
 642                                                 }
 643                 }
 644             }
 645         }
 646     }
 647
 648         if(NextFrameCommand)
 649         {
 650                 localcmd("\n", NextFrameCommand, "\n");
 651                 NextFrameCommand = string_null;
 652         }
 653 }
 654
 655 void Sbar_Draw();
 656 void CSQC_spider_HUD()
 657 {
 658     float rockets,reload,heat,hp,shield,i;
 659     vector p,pp;
 660
 661     rockets = getstati(STAT_SPIDERBOT_ROCKETS);
 662     heat    = min(getstatf(STAT_SPIDERBOT_HEAT),1);
 663     reload  = min(getstatf(STAT_SPIDERBOT_RELOAD),1);
 664     hp      = min(getstatf(STAT_SPIDERBOT_HEALTH),1);
 665     shield  = min(getstatf(STAT_SPIDERBOT_SHIELD),1);
 666
 667     // Draw health bar
 668     p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 669     p = p + '0 1 0' * vid_conheight - '0 32 0';
 670     //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
 671     drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
 672     p_y += 8;
 673     drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
 674     p_x += 256 * hp;
 675     drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
 676
 677     // Draw minigun heat indicator
 678     p = '0.5 0 0' * (vid_conwidth - 256);
 679     p = p + '0 1 0' * vid_conheight - '0 34  0';
 680     drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
 681     p_x += 256 * (1-heat);
 682     drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
 683
 684     // Draw rocket icons for loaded/empty tubes.
 685     pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 686     pp += '0 1 0' * vid_conheight - '0 64 0';
 687     for(i = 0; i < 8; ++i)
 688     {
 689         p = pp + '1 0 0' * (rkt_size * i);
 690         if(rockets == 8)
 691         {
 692             if(floor(reload * 8) == i)
 693             {
 694                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
 695             }
 696             else if(i < reload * 8)
 697                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
 698             else
 699                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
 700         }
 701         else
 702         {
 703             if(i < rockets)
 704                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
 705             else
 706                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
 707         }
 708     }
 709
 710         if (sb_showscores)
 711         {
 712                 Sbar_DrawScoreboard();
 713                 Sbar_DrawCenterPrint();
 714         }
 715
 716 }
 717 void CSQC_common_hud(void)
 718 {
 719
 720         // Sbar_SortFrags(); done in Sbar_Draw
 721     float hud;
 722     hud = getstati(STAT_HUD);
 723
 724     //hud = 10;
 725     switch(hud)
 726     {
 727         case HUD_NORMAL:
 728             Sbar_Draw();
 729             break;
 730
 731         case HUD_SPIDEBOT:
 732             CSQC_spider_HUD();
 733             break;
 734     }
 735 }
 736
 737
 738 // following vectors must be global to allow seamless switching between camera modes
 739 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
 740 void CSQC_Demo_Camera()
 741 {
 742         float speed, attenuation, dimensions;
 743         vector tmp, delta;
 744
 745         if( cvar("camera_reset") || !camera_mode )
 746         {
 747                 camera_offset = '0 0 0';
 748                 current_angles = '0 0 0';
 749                 camera_direction = '0 0 0';
 750                 camera_offset_z += 30;
 751                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
 752                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
 753                 current_origin = view_origin;
 754                 current_camera_offset  = camera_offset;
 755                 cvar_set("camera_reset", "0");
 756                 camera_mode = CAMERA_CHASE;
 757         }
 758
 759         // Camera angles
 760         if( camera_roll )
 761                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");
 762
 763         if(cvar("camera_look_player"))
 764         {
 765                 local vector dir;
 766                 local float n;
 767
 768                 dir = normalize(view_origin - current_position);
 769                 n = mouse_angles_z;
 770                 mouse_angles = vectoangles(dir);
 771                 mouse_angles_x = mouse_angles_x * -1;
 772                 mouse_angles_z = n;
 773         }
 774         else
 775         {
 776                 tmp = getmousepos() * 0.1;
 777                 if(vlen(tmp)>cvar("camera_mouse_treshold"))
 778                 {
 779                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
 780                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
 781                 }
 782         }
 783
 784         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
 785         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
 786         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
 787         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
 788
 789         // Fix difference when angles don't have the same sign
 790         delta = '0 0 0';
 791         if(mouse_angles_y < -60 && current_angles_y > 60)
 792                 delta = '0 360 0';
 793         if(mouse_angles_y > 60 && current_angles_y < -60)
 794                 delta = '0 -360 0';
 795
 796         if(cvar("camera_look_player"))
 797                 attenuation = cvar("camera_look_attenuation");
 798         else
 799                 attenuation = cvar("camera_speed_attenuation");
 800
 801         attenuation = 1 / max(1, attenuation);
 802         current_angles += (mouse_angles - current_angles + delta) * attenuation;
 803
 804         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
 805         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
 806         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
 807         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
 808
 809         // Camera position
 810         tmp = '0 0 0';
 811         dimensions = 0;
 812
 813         if( camera_direction_x )
 814         {
 815                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
 816                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
 817                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )
 818                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
 819                 ++dimensions;
 820         }
 821
 822         if( camera_direction_y )
 823         {
 824                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
 825                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
 826                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
 827                 ++dimensions;
 828         }
 829
 830         if( camera_direction_z )
 831         {
 832                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
 833                 ++dimensions;
 834         }
 835
 836         if(cvar("camera_free"))
 837                 speed = cvar("camera_speed_free");
 838         else
 839                 speed = cvar("camera_speed_chase");
 840
 841         if(dimensions)
 842         {
 843                 speed = speed * sqrt(1 / dimensions);
 844                 camera_offset += tmp * speed;
 845         }
 846
 847         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
 848
 849         // Camera modes
 850         if( cvar("camera_free") )
 851         {
 852                 if ( camera_mode == CAMERA_CHASE )
 853                 {
 854                         current_camera_offset = current_origin + current_camera_offset;
 855                         camera_offset = current_origin + camera_offset;
 856                 }
 857
 858                 camera_mode = CAMERA_FREE;
 859                 current_position = current_camera_offset;
 860         }
 861         else
 862         {
 863                 if ( camera_mode == CAMERA_FREE )
 864                 {
 865                         current_origin = view_origin;
 866                         camera_offset = camera_offset - current_origin;
 867                         current_camera_offset = current_camera_offset - current_origin;
 868                 }
 869
 870                 camera_mode = CAMERA_CHASE;
 871
 872                 if(cvar("camera_chase_smoothly"))
 873                         current_origin += (view_origin - current_origin) * attenuation;
 874                 else
 875                         current_origin = view_origin;
 876
 877                 current_position = current_origin + current_camera_offset;
 878         }
 879
 880         R_SetView(VF_ANGLES, current_angles);
 881         R_SetView(VF_ORIGIN, current_position);
 882 }