data/qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/spiderbot/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/spiderbot/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 entity porto;
   9 vector polyline[16];
  10 float trace_dphitcontents;
  11 float trace_networkentity;
  12 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  13 float DPCONTENTS_SOLID = 1; // blocks player movement
  14 float DPCONTENTS_BODY = 32; // blocks player movement
  15 float DPCONTENTS_CORPSE = 64; // blocks player movement
  16 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  17 void Porto_Draw()
  18 {
  19         vector p, dir, ang, q, nextdir;
  20         float idx, portal_number, portal1_idx;
  21
  22         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  23                 return;
  24         if(intermission == 1)
  25                 return;
  26         if(intermission == 2)
  27                 return;
  28         if (getstati(STAT_HEALTH) <= 0)
  29                 return;
  30
  31         dir = view_forward;
  32
  33         if(angles_held_status)
  34         {
  35                 makevectors(angles_held);
  36                 dir = v_forward;
  37         }
  38
  39         p = view_origin;
  40
  41         polyline[0] = p;
  42         idx = 1;
  43         portal_number = 0;
  44         nextdir = dir;
  45
  46         for(;;)
  47         {
  48                 dir = nextdir;
  49                 traceline(p, p + 65536 * dir, TRUE, porto);
  50                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  51                         return;
  52                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  53                 p = trace_endpos;
  54                 polyline[idx] = p;
  55                 ++idx;
  56                 if(idx >= 16)
  57                         return;
  58                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  59                         continue;
  60                 ++portal_number;
  61                 ang = vectoangles2(trace_plane_normal, dir);
  62                 ang_x = -ang_x;
  63                 makevectors(ang);
  64                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  65                         return;
  66                 if(portal_number == 1)
  67                         portal1_idx = idx;
  68                 if(portal_number >= 2)
  69                         break;
  70         }
  71
  72         while(idx >= 2)
  73         {
  74                 p = polyline[idx-2];
  75                 q = polyline[idx-1];
  76                 if(idx == 2)
  77                         p = p - view_up * 16;
  78                 if(idx-1 >= portal1_idx)
  79                 {
  80                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL);
  81                 }
  82                 else
  83                 {
  84                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL);
  85                 }
  86                 --idx;
  87         }
  88 }
  89
  90 /**
  91  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  92  *
  93  * TODO: Use a better solution where a common shared entitiy is used that contains
  94  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  95  * and STAT_FRAGLIMIT to be auto-sent)
  96  */
  97 void CheckForGamestartChange() {
  98         float startTime;
  99         startTime = getstatf(STAT_GAMESTARTTIME);
 100         if (previous_game_starttime != startTime) {
 101                 if ((time + 5.0) < startTime) {
 102                         //if connecting to server while restart was active don't always play prepareforbattle
 103                         sound(self, CHAN_VOICE, "announcer/robotic/prepareforbattle.wav", VOL_BASEVOICE, ATTN_NONE);
 104                 }
 105                 if (time < startTime) {
 106                         restartAnnouncer = spawn();
 107                         restartAnnouncer.think = restartAnnouncer_Think;
 108                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 109                 }
 110         }
 111         previous_game_starttime = startTime;
 112 }
 113
 114 void Porto_Init()
 115 {
 116         porto = spawn();
 117         porto.classname = "porto";
 118         porto.draw = Porto_Draw;
 119         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 120 }
 121
 122 float drawtime;
 123
 124 float tan(float x)
 125 {
 126         return sin(x) / cos(x);
 127 }
 128 float atan2(float y, float x)
 129 {
 130         vector v;
 131         v = '1 0 0' * x + '0 1 0' * y;
 132         v = vectoangles(v);
 133         return v_y * 0.01745329251994329576;
 134 }
 135
 136 vector GetCurrentFov(float fov)
 137 {
 138         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 139
 140         zoomsensitivity = cvar("cl_zoomsensitivity");
 141         zoomfactor = cvar("cl_zoomfactor");
 142         if(zoomfactor < 1 || zoomfactor > 16)
 143                 zoomfactor = 2.5;
 144         zoomspeed = cvar("cl_zoomspeed");
 145         if(zoomspeed >= 0)
 146                 if(zoomspeed < 0.5 || zoomspeed > 16)
 147                         zoomspeed = 3.5;
 148
 149         zoomdir = button_zoom;
 150         if(getstati(STAT_ACTIVEWEAPON) == WEP_NEX) // do NOT use switchweapon here
 151                 zoomdir += button_attack2;
 152         if(spectatee_status > 0 || isdemo())
 153         {
 154                 if(spectatorbutton_zoom)
 155                         zoomdir = 0 + !zoomdir;
 156                         // do not even THINK about removing this 0
 157                         // _I_ know what I am doing
 158                         // fteqcc does not
 159         }
 160
 161         if(zoomdir)
 162                 zoomin_effect = 0;
 163
 164         if(zoomin_effect || camera_active)
 165         {
 166                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 167         }
 168         else
 169         {
 170                 if(zoomspeed < 0) // instant zoom
 171                 {
 172                         if(zoomdir)
 173                                 current_viewzoom = 1 / zoomfactor;
 174                         else
 175                                 current_viewzoom = 1;
 176                 }
 177                 else
 178                 {
 179                         if(zoomdir)
 180                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 181                         else
 182                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 183                 }
 184         }
 185
 186         if(almost_equals(current_viewzoom, 1))
 187                 current_zoomfraction = 0;
 188         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 189                 current_zoomfraction = 1;
 190         else
 191                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 192
 193         if(zoomsensitivity < 1)
 194                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 195         else
 196                 setsensitivityscale(1);
 197
 198         float frustumx, frustumy, fovx, fovy;
 199         frustumy = tan(fov * 0.00872664625997164788) * 0.75 * current_viewzoom;
 200         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 201         fovx = atan2(frustumx, 1) / 0.00872664625997164788;
 202         fovy = atan2(frustumy, 1) / 0.00872664625997164788;
 203
 204         return '1 0 0' * fovx + '0 1 0' * fovy;
 205 }
 206
 207 // this function must match W_SetupShot!
 208 float zoomscript_caught;
 209
 210 vector wcross_origin;
 211 entity trueaim;
 212
 213 #define SHOTTYPE_HITTEAM 1
 214 #define SHOTTYPE_HITOBSTRUCTION 2
 215 #define SHOTTYPE_HITWORLD 3
 216 #define SHOTTYPE_HITENEMY 4
 217
 218 void TrueAim_Init()
 219 {
 220         trueaim = spawn();
 221         trueaim.classname = "trueaim";
 222         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 223 }
 224
 225 float EnemyHitCheck()
 226 {
 227         float t;
 228         wcross_origin = project_3d_to_2d(trace_endpos);
 229         wcross_origin_z = 0;
 230         if(trace_networkentity < 1)
 231                 return SHOTTYPE_HITWORLD;
 232         if(trace_networkentity > maxclients)
 233                 return SHOTTYPE_HITWORLD;
 234         t = GetPlayerColor(trace_networkentity - 1);
 235         if(teamplay)
 236         if(t == myteam)
 237                 return SHOTTYPE_HITTEAM;
 238         if(t == COLOR_SPECTATOR)
 239                 return SHOTTYPE_HITWORLD;
 240         return SHOTTYPE_HITENEMY;
 241 }
 242
 243 float TrueAimCheck()
 244 {
 245         float nudge = 1; // added to traceline target and subtracted from result
 246         vector vecs, trueaimpoint, w_shotorg;
 247         vector mi, ma, dv;
 248         float shottype;
 249
 250         mi = ma = '0 0 0';
 251
 252         switch(activeweapon)
 253         {
 254                 case WEP_TUBA: // no aim
 255                 case WEP_PORTO: // shoots from eye
 256                 case WEP_HOOK: // no trueaim
 257                 case WEP_GRENADE_LAUNCHER: // toss curve
 258                         return SHOTTYPE_HITWORLD;
 259                 case WEP_CAMPINGRIFLE:
 260                         if(zoomscript_caught)
 261                         {
 262                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, trueaim);
 263                                 return EnemyHitCheck();
 264                         }
 265                         break;
 266                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 267                         mi = '-3 -3 -3';
 268                         ma = '3 3 3';
 269                         break;
 270                 case WEP_FIREBALL: // projectile has a size!
 271                         mi = '-16 -16 -16';
 272                         ma = '16 16 16';
 273                         break;
 274                 case WEP_ELECTRO: // projectile has a size!
 275                         mi = '0 0 -3';
 276                         ma = '0 0 -3';
 277                         break;
 278         }
 279
 280         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 281
 282         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, MOVE_NOMONSTERS, trueaim);
 283         trueaimpoint = trace_endpos;
 284
 285         if(vecs_x > 0)
 286                 vecs_y = -vecs_y;
 287         else
 288                 vecs = '0 0 0';
 289
 290         dv = view_right * vecs_y + view_up * vecs_z;
 291         w_shotorg = view_origin + dv;
 292
 293         // now move the vecs forward as much as requested if possible
 294         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, trueaim); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 295         w_shotorg = trace_endpos - view_forward * nudge;
 296
 297         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, trueaim);
 298         shottype = EnemyHitCheck();
 299         if(shottype != SHOTTYPE_HITWORLD)
 300                 return shottype;
 301
 302 #if 0
 303         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 304         // or rather, I know why, but see no fix
 305         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 306                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 307                 return SHOTTYPE_HITOBSTRUCTION;
 308 #endif
 309
 310         return SHOTTYPE_HITWORLD;
 311 }
 312
 313 void CSQC_common_hud(void);
 314
 315 void CSQC_kh_hud(void);
 316 void CSQC_ctf_hud(void);
 317 void PostInit(void);
 318 void CSQC_Demo_Camera();
 319 float Sbar_WouldDrawScoreboard ();
 320 float view_set;
 321 float camera_mode;
 322 string NextFrameCommand;
 323 void CSQC_spider_HUD();
 324 void CSQC_UpdateView(float w, float h)
 325 {
 326         entity e;
 327         float fov;
 328         float f, i, j;
 329         vector v;
 330
 331         dprint_load();
 332         WaypointSprite_Load();
 333
 334         if(spectatee_status)
 335                 myteam = GetPlayerColor(spectatee_status - 1);
 336         else
 337                 myteam = GetPlayerColor(player_localentnum - 1);
 338
 339         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 340
 341         // Render the Scene
 342         if(!intermission || !view_set)
 343         {
 344                 view_origin = pmove_org + '0 0 1' * getstati(STAT_VIEWHEIGHT);
 345                 view_angles = input_angles;
 346                 makevectors(view_angles);
 347                 view_forward = v_forward;
 348                 view_right = v_right;
 349                 view_up = v_up;
 350                 view_set = 1;
 351         }
 352
 353         vid_width = w;
 354         vid_height = h;
 355
 356 #ifdef BLURTEST
 357         if(time > blurtest_time0 && time < blurtest_time1)
 358         {
 359                 float r, t;
 360
 361                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 362                 r = t * blurtest_radius;
 363                 f = 1 / pow(t, blurtest_power) - 1;
 364
 365                 cvar_set("r_glsl_postprocess", "1");
 366                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 367         }
 368         else
 369         {
 370                 cvar_set("r_glsl_postprocess", "0");
 371                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 372         }
 373 #endif
 374
 375         Fog_Force();
 376
 377         drawframetime = max(0.000001, time - drawtime);
 378         drawtime = time;
 379
 380         // watch for gametype changes here...
 381         // in ParseStuffCMD the cmd isn't executed yet :/
 382         // might even be better to add the gametype to TE_CSQC_INIT...?
 383         if(!postinit)
 384                 PostInit();
 385
 386         CheckForGamestartChange();
 387         maptimeAnnouncer();
 388
 389         fov = cvar("fov");
 390         if(button_zoom || fov <= 59.5)
 391         {
 392                 if(!zoomscript_caught)
 393                 {
 394                         localcmd("+button4\n");
 395                         zoomscript_caught = 1;
 396                         ignore_plus_zoom += 1;
 397                 }
 398         }
 399         else
 400         {
 401                 if(zoomscript_caught)
 402                 {
 403                         localcmd("-button4\n");
 404                         zoomscript_caught = 0;
 405                         ignore_minus_zoom += 1;
 406                 }
 407         }
 408
 409         sbar_alpha_fg = cvar("sbar_alpha_fg" );
 410         sbar_currentammo = cvar("sbar_showcurrentammo");
 411         sbar_hudselector = cvar("sbar_hudselector");
 412         sbar_hud_accuracy = cvar("sbar_hud_accuracy");
 413         ColorTranslateMode = cvar("cl_stripcolorcodes");
 414         activeweapon = getstati(STAT_SWITCHWEAPON);
 415         f = cvar("teamplay");
 416         if(f != teamplay)
 417         {
 418                 teamplay = f;
 419                 Sbar_InitScores();
 420         }
 421
 422         if(last_weapon != activeweapon) {
 423                 weapontime = time;
 424                 last_weapon = activeweapon;
 425         }
 426
 427         // ALWAYS Clear Current Scene First
 428         R_ClearScene();
 429
 430         // Assign Standard Viewflags
 431         // Draw the World (and sky)
 432         R_SetView(VF_DRAWWORLD, 1);
 433
 434         // Set the console size vars
 435         vid_conwidth = cvar("vid_conwidth");
 436         vid_conheight = cvar("vid_conheight");
 437         vid_pixelheight = cvar("vid_pixelheight");
 438
 439         R_SetView(VF_FOV, GetCurrentFov(fov));
 440
 441         // Camera for demo playback
 442         if(camera_active)
 443         {
 444                 if(cvar("camera_enable"))
 445                         CSQC_Demo_Camera();
 446                 else
 447                 {
 448                         cvar_set("chase_active", ftos(chase_active_backup));
 449                         cvar_set("cl_demo_mousegrab", "0");
 450                         camera_active = FALSE;
 451                 }
 452         }
 453 #ifdef CAMERATEST
 454         else if(cvar("camera_enable"))
 455 #else
 456         else if(cvar("camera_enable") && isdemo())
 457 #endif
 458         {
 459                 // Enable required Darkplaces cvars
 460                 chase_active_backup = cvar("chase_active");
 461                 cvar_set("chase_active", "2");
 462                 cvar_set("cl_demo_mousegrab", "1");
 463                 camera_active = TRUE;
 464                 camera_mode = FALSE;
 465         }
 466
 467         // Draw the Crosshair
 468         float scoreboard_active;
 469         scoreboard_active = Sbar_WouldDrawScoreboard();
 470         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 471
 472         // Draw the Engine Status Bar (the default Quake HUD)
 473         R_SetView(VF_DRAWENGINESBAR, 0);
 474
 475         // fetch this one only once per frame
 476         sbar_showbinds = cvar("sbar_showbinds");
 477         sbar_showbinds_limit = cvar("sbar_showbinds_limit");
 478
 479         // Update the mouse position
 480         /*
 481         mousepos_x = vid_conwidth;
 482         mousepos_y = vid_conheight;
 483         mousepos = mousepos*0.5 + getmousepos();
 484         */
 485
 486         e = self;
 487         for(self = world; (self = nextent(self)); )
 488                 if(self.draw)
 489                         self.draw();
 490         self = e;
 491
 492         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 493         R_RenderScene();
 494
 495         // now switch to 2D drawing mode by calling a 2D drawing function
 496         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 497         // next R_RenderScene call
 498         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 499
 500         // Draw the mouse cursor
 501         // NOTE: drawpic must happen after R_RenderScene for some reason
 502         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 503         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 504         //self = edict_num(player_localnum);
 505         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 506         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 507         // as long as the ctf part isn't in, this is useless
 508         if(menu_visible)
 509                 menu_show();
 510
 511         /*if(gametype == GAME_CTF)
 512         {
 513                 ctf_view();
 514         } else */
 515
 516         // draw 2D entities
 517         e = self;
 518         for(self = world; (self = nextent(self)); )
 519                 if(self.draw2d)
 520                         self.draw2d();
 521         self = e;
 522
 523         // draw radar
 524         if(
 525                 ons_showmap
 526                 ||
 527                 (
 528                         !scoreboard_active
 529                         &&
 530                         cvar_string("cl_teamradar") != "0"
 531                         &&
 532                         (
 533                                 cvar("cl_teamradar") == 2
 534                                 ||
 535                                 teamplay
 536                         )
 537                 )
 538         )
 539                 teamradar_view();
 540
 541         // draw sbar
 542         if(cvar("r_letterbox") == 0) {
 543                 if (cvar("cl_showpressedkeys")) { // draw pressed keys when spectating and playing
 544                         if(spectatee_status > 0 || cvar("cl_showpressedkeys") >= 2)
 545                                 Sbar_DrawPressedKeys();
 546                 }
 547
 548                 if (cvar("cl_showspeed"))
 549                         Sbar_ShowSpeed();
 550
 551                 Sbar_DrawCenterPrint(); // draw centerprint messages even if viewsize >= 120
 552         }
 553
 554     float hud;
 555     hud = getstati(STAT_HUD);
 556     if(hud == HUD_SPIDERBOT)
 557     {
 558         vector sz;
 559         CSQC_spider_HUD();
 560         sz = drawgetimagesize(SPIDER_CROSS);
 561         sz_x *= cvar_or("cl_vehicle_spiderbot_cross_size",1);
 562         sz_y *= cvar_or("cl_vehicle_spiderbot_cross_size",1);
 563         drawpic('0.5 0 0' * (vid_conwidth - sz_x) + '0 0.5 0' * (vid_conheight - sz_y), SPIDER_CROSS, sz, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
 564     }
 565     else
 566     {
 567         if(cvar("r_letterbox") == 0)
 568             if(cvar("viewsize") < 120)
 569                 CSQC_common_hud();
 570
 571         // crosshair goes VERY LAST
 572         if(!scoreboard_active && !ons_showmap && !camera_active) {
 573                         // TrueAim check
 574                         float shottype;
 575                         float bullets, ring_scale;
 576                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 577                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 578                         wcross_origin_z = 0;
 579             if(cvar("crosshair_hittest"))
 580                         {
 581                                 vector wcross_oldorigin;
 582                                 wcross_oldorigin = wcross_origin;
 583                 shottype = TrueAimCheck();
 584                                 if(shottype == SHOTTYPE_HITWORLD)
 585                                 {
 586                                         v = wcross_origin - wcross_oldorigin;
 587                                         v_x /= vid_conwidth;
 588                                         v_y /= vid_conheight;
 589                                         if(vlen(v) > 0.01)
 590                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 591                                 }
 592                                 if(!cvar("crosshair_hittest_showimpact"))
 593                                         wcross_origin = wcross_oldorigin;
 594                         }
 595             else
 596                 shottype = SHOTTYPE_HITWORLD;
 597
 598             string wcross_style;
 599             wcross_style = cvar_string("crosshair");
 600
 601             if (wcross_style != "0") {
 602                 vector wcross_color, wcross_size;
 603                 string wcross_wep, wcross_name;
 604                 float wcross_alpha, wcross_sizefloat;
 605
 606                 wcross_color_x = cvar("crosshair_color_red");
 607                 wcross_color_y = cvar("crosshair_color_green");
 608                 wcross_color_z = cvar("crosshair_color_blue");
 609                 wcross_alpha = cvar("crosshair_color_alpha");
 610                 wcross_sizefloat = cvar("crosshair_size");
 611                 if (cvar("crosshair_per_weapon")) {
 612                     e = get_weaponinfo(activeweapon);
 613                     if (e && e.netname != "")
 614                     {
 615                         wcross_wep = e.netname;
 616                         wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 617                         if(wcross_style == "")
 618                             wcross_style = e.netname;
 619
 620                         if(!cvar("crosshair_color_override"))
 621                         {
 622                             wcross_color_x = cvar(strcat("crosshair_", wcross_wep, "_color_red"));
 623                             wcross_color_y = cvar(strcat("crosshair_", wcross_wep, "_color_green"));
 624                             wcross_color_z = cvar(strcat("crosshair_", wcross_wep, "_color_blue"));
 625                         }
 626
 627                         wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_color_alpha"));
 628                         wcross_sizefloat *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 629                     }
 630                 }
 631
 632                 wcross_name = strcat("gfx/crosshair", wcross_style);
 633
 634                                 if(shottype == SHOTTYPE_HITENEMY)
 635                                         wcross_sizefloat *= cvar("crosshair_hittest"); // is not queried if hittest is 0
 636                                 if(shottype == SHOTTYPE_HITTEAM)
 637                                         wcross_sizefloat /= cvar("crosshair_hittest"); // is not queried if hittest is 0
 638
 639                 wcross_size = drawgetimagesize(wcross_name);
 640                 wcross_size_x *= wcross_sizefloat;
 641                 wcross_size_y *= wcross_sizefloat;
 642
 643                                 // ring around crosshair representing bullets left in camping rifle clip
 644                                 if (activeweapon == WEP_CAMPINGRIFLE)
 645                                 {
 646                                         ring_scale = cvar("crosshair_campingrifle_ring_size");
 647                                         bullets = bound(0, getstati(STAT_BULLETS_LOADED), 8);
 648                                 }
 649                                 else
 650                                         bullets = 0;
 651
 652                 if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && cvar("crosshair_hittest_blur")))
 653                 {
 654                     wcross_alpha *= 0.04 * 0.75;
 655                     for(i = -2; i <= 2; ++i)
 656                         for(j = -2; j <= 2; ++j)
 657                                                 {
 658                                                         if (bullets)
 659                                                                 drawpic(wcross_origin - '0.5 0 0' * (wcross_size_x * ring_scale + i) - '0 0.5 0' * (wcross_size_y * ring_scale + j), strcat("gfx/hud/rifle_ring_", ftos(bullets)), wcross_size * ring_scale, wcross_color, wcross_alpha, DRAWFLAG_NORMAL);
 660                             drawpic(wcross_origin - '0.5 0 0' * (wcross_size_x + i) - '0 0.5 0' * (wcross_size_y + j), wcross_name, wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL);
 661                                                 }
 662                 }
 663                 else
 664                 {
 665                                         if (bullets)
 666                                                 drawpic(wcross_origin - '0.5 0 0' * (wcross_size_x * ring_scale) - '0 0.5 0' * (wcross_size_y * ring_scale), strcat("gfx/hud/rifle_ring_", ftos(bullets)), wcross_size * ring_scale, wcross_color, wcross_alpha, DRAWFLAG_NORMAL);
 667                     drawpic(wcross_origin - '0.5 0 0' * (wcross_size_x) - '0 0.5 0' * ( wcross_size_y), wcross_name, wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL);
 668                 }
 669             }
 670         }
 671     }
 672
 673         if(NextFrameCommand)
 674         {
 675                 localcmd("\n", NextFrameCommand, "\n");
 676                 NextFrameCommand = string_null;
 677         }
 678
 679         // we must do this check AFTER a frame was rendered, or it won't work
 680         if(cs_project_is_b0rked == 0)
 681         {
 682                 string w0, h0;
 683                 w0 = cvar_string("vid_conwidth");
 684                 h0 = cvar_string("vid_conheight");
 685                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
 686                 //R_SetView(VF_FOV, '90 90 0');
 687                 R_SetView(VF_ORIGIN, '0 0 0');
 688                 R_SetView(VF_ANGLES, '0 0 0');
 689                 R_SetView(VF_PERSPECTIVE, 1);
 690                 makevectors('0 0 0');
 691                 vector v1, v2;
 692                 cvar_set("vid_conwidth", "800");
 693                 cvar_set("vid_conheight", "600");
 694                 v1 = cs_project(v_forward);
 695                 cvar_set("vid_conwidth", "640");
 696                 cvar_set("vid_conheight", "480");
 697                 v2 = cs_project(v_forward);
 698                 if(v1 == v2)
 699                         cs_project_is_b0rked = 1;
 700                 else
 701                         cs_project_is_b0rked = -1;
 702                 cvar_set("vid_conwidth", w0);
 703                 cvar_set("vid_conheight", h0);
 704         }
 705 }
 706
 707 void Sbar_Draw();
 708 void CSQC_spider_HUD()
 709 {
 710     float rockets,reload,heat,hp,shield,i;
 711     vector p,pp;
 712
 713     rockets = getstati(STAT_SPIDERBOT_ROCKETS);
 714     heat    = min(getstatf(STAT_SPIDERBOT_HEAT),1);
 715     reload  = min(getstatf(STAT_SPIDERBOT_RELOAD),1);
 716     hp      = min(getstatf(STAT_SPIDERBOT_HEALTH),1);
 717     shield  = min(getstatf(STAT_SPIDERBOT_SHIELD),1);
 718
 719     // Draw health bar
 720     p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 721     p = p + '0 1 0' * vid_conheight - '0 32 0';
 722     //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
 723     drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
 724     p_y += 8;
 725     drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
 726     p_x += 256 * hp;
 727     drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
 728
 729     // Draw minigun heat indicator
 730     p = '0.5 0 0' * (vid_conwidth - 256);
 731     p = p + '0 1 0' * vid_conheight - '0 34  0';
 732     drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
 733     p_x += 256 * (1-heat);
 734     drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
 735
 736     // Draw rocket icons for loaded/empty tubes.
 737     pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
 738     pp += '0 1 0' * vid_conheight - '0 64 0';
 739     for(i = 0; i < 8; ++i)
 740     {
 741         p = pp + '1 0 0' * (rkt_size * i);
 742         if(rockets == 8)
 743         {
 744             if(floor(reload * 8) == i)
 745             {
 746                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
 747             }
 748             else if(i < reload * 8)
 749                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
 750             else
 751                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
 752         }
 753         else
 754         {
 755             if(i < rockets)
 756                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
 757             else
 758                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
 759         }
 760     }
 761
 762         if (sb_showscores)
 763         {
 764                 Sbar_DrawScoreboard();
 765                 Sbar_DrawCenterPrint();
 766         }
 767
 768 }
 769 void CSQC_common_hud(void)
 770 {
 771
 772         // Sbar_SortFrags(); done in Sbar_Draw
 773     float hud;
 774     hud = getstati(STAT_HUD);
 775
 776     //hud = 10;
 777     switch(hud)
 778     {
 779         case HUD_NORMAL:
 780             Sbar_Draw();
 781             break;
 782
 783         case HUD_SPIDERBOT:
 784             CSQC_spider_HUD();
 785             break;
 786     }
 787 }
 788
 789
 790 // following vectors must be global to allow seamless switching between camera modes
 791 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
 792 void CSQC_Demo_Camera()
 793 {
 794         float speed, attenuation, dimensions;
 795         vector tmp, delta;
 796
 797         if( cvar("camera_reset") || !camera_mode )
 798         {
 799                 camera_offset = '0 0 0';
 800                 current_angles = '0 0 0';
 801                 camera_direction = '0 0 0';
 802                 camera_offset_z += 30;
 803                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
 804                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
 805                 current_origin = view_origin;
 806                 current_camera_offset  = camera_offset;
 807                 cvar_set("camera_reset", "0");
 808                 camera_mode = CAMERA_CHASE;
 809         }
 810
 811         // Camera angles
 812         if( camera_roll )
 813                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");
 814
 815         if(cvar("camera_look_player"))
 816         {
 817                 local vector dir;
 818                 local float n;
 819
 820                 dir = normalize(view_origin - current_position);
 821                 n = mouse_angles_z;
 822                 mouse_angles = vectoangles(dir);
 823                 mouse_angles_x = mouse_angles_x * -1;
 824                 mouse_angles_z = n;
 825         }
 826         else
 827         {
 828                 tmp = getmousepos() * 0.1;
 829                 if(vlen(tmp)>cvar("camera_mouse_treshold"))
 830                 {
 831                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
 832                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
 833                 }
 834         }
 835
 836         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
 837         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
 838         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
 839         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
 840
 841         // Fix difference when angles don't have the same sign
 842         delta = '0 0 0';
 843         if(mouse_angles_y < -60 && current_angles_y > 60)
 844                 delta = '0 360 0';
 845         if(mouse_angles_y > 60 && current_angles_y < -60)
 846                 delta = '0 -360 0';
 847
 848         if(cvar("camera_look_player"))
 849                 attenuation = cvar("camera_look_attenuation");
 850         else
 851                 attenuation = cvar("camera_speed_attenuation");
 852
 853         attenuation = 1 / max(1, attenuation);
 854         current_angles += (mouse_angles - current_angles + delta) * attenuation;
 855
 856         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
 857         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
 858         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
 859         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
 860
 861         // Camera position
 862         tmp = '0 0 0';
 863         dimensions = 0;
 864
 865         if( camera_direction_x )
 866         {
 867                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
 868                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
 869                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )
 870                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
 871                 ++dimensions;
 872         }
 873
 874         if( camera_direction_y )
 875         {
 876                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
 877                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
 878                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
 879                 ++dimensions;
 880         }
 881
 882         if( camera_direction_z )
 883         {
 884                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
 885                 ++dimensions;
 886         }
 887
 888         if(cvar("camera_free"))
 889                 speed = cvar("camera_speed_free");
 890         else
 891                 speed = cvar("camera_speed_chase");
 892
 893         if(dimensions)
 894         {
 895                 speed = speed * sqrt(1 / dimensions);
 896                 camera_offset += tmp * speed;
 897         }
 898
 899         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
 900
 901         // Camera modes
 902         if( cvar("camera_free") )
 903         {
 904                 if ( camera_mode == CAMERA_CHASE )
 905                 {
 906                         current_camera_offset = current_origin + current_camera_offset;
 907                         camera_offset = current_origin + camera_offset;
 908                 }
 909
 910                 camera_mode = CAMERA_FREE;
 911                 current_position = current_camera_offset;
 912         }
 913         else
 914         {
 915                 if ( camera_mode == CAMERA_FREE )
 916                 {
 917                         current_origin = view_origin;
 918                         camera_offset = camera_offset - current_origin;
 919                         current_camera_offset = current_camera_offset - current_origin;
 920                 }
 921
 922                 camera_mode = CAMERA_CHASE;
 923
 924                 if(cvar("camera_chase_smoothly"))
 925                         current_origin += (view_origin - current_origin) * attenuation;
 926                 else
 927                         current_origin = view_origin;
 928
 929                 current_position = current_origin + current_camera_offset;
 930         }
 931
 932         R_SetView(VF_ANGLES, current_angles);
 933         R_SetView(VF_ORIGIN, current_position);
 934 }