data/qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------\r
   2 // BEGIN REQUIRED CSQC FUNCTIONS\r
   3 //include "main.qh"\r
   4 \r
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
   6 \r
   7 void cvar_clientsettemp(string cv, string val)\r
   8 {\r
   9         entity e;\r
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  11                 if(e.netname == cv)\r
  12                         goto saved;\r
  13         e = spawn();\r
  14         e.classname = "saved_cvar_value";\r
  15         e.netname = strzone(cv);\r
  16         e.message = strzone(cvar_string(cv));\r
  17 :saved\r
  18         cvar_set(cv, val);\r
  19 }\r
  20 \r
  21 void cvar_clientsettemp_restore()\r
  22 {\r
  23         entity e;\r
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  25                         cvar_set(e.netname, e.message);\r
  26 }\r
  27 \r
  28 void() menu_show_error =\r
  29 {\r
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);\r
  31 };\r
  32 \r
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)\r
  34 // Useful for precaching things\r
  35 \r
  36 void() menu_sub_null =\r
  37 {\r
  38 };\r
  39 \r
  40 #ifdef USE_FTE\r
  41 float __engine_check;\r
  42 #endif\r
  43 \r
  44 string config_get(string key, string defaultvalue)\r
  45 {\r
  46         string s;\r
  47         s = db_get(configdb, strcat("/s/", key));\r
  48         if(s == "")\r
  49                 return defaultvalue;\r
  50         else\r
  51                 return db_get(configdb, strcat("/v/", key));\r
  52 }\r
  53 \r
  54 string forcefog;\r
  55 void WaypointSprite_Load();\r
  56 void CSQC_Init(void)\r
  57 {\r
  58 #ifdef USE_FTE\r
  59 #pragma target ID\r
  60         __engine_check = checkextension("DP_SV_WRITEPICTURE");\r
  61         if(!__engine_check)\r
  62         {\r
  63                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");\r
  64                 localcmd("\ndisconnect\n");\r
  65                 return;\r
  66         }\r
  67 #pragma target FTE\r
  68 #endif\r
  69         \r
  70         float i;\r
  71         CSQC_CheckEngine();\r
  72         dprint_load();\r
  73 \r
  74         configdb = db_create();\r
  75         binddb = db_create();\r
  76         tempdb = db_create();\r
  77         compressShortVector_init();\r
  78 \r
  79         drawfont = 0;\r
  80         menu_visible = FALSE;\r
  81         menu_show = menu_show_error;\r
  82         menu_action = menu_sub_null;\r
  83         maxclients = 255; // we later get the real maxclients to speed up stuff\r
  84         //ctf_temp_1 = "";\r
  85         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used\r
  86         //registercmd("ctf_menu");\r
  87         registercmd("ons_map");\r
  88         //registercmd("menu_action");\r
  89         registercmd("sbar_columns_set");\r
  90         registercmd("sbar_columns_help");\r
  91 \r
  92         registercmd("+button3");\r
  93         registercmd("-button3");\r
  94         registercmd("+button4");\r
  95         registercmd("-button4");\r
  96 \r
  97         registercvar("sbar_usecsqc", "1");\r
  98         registercvar("sbar_columns", "default", CVAR_SAVE);\r
  99 \r
 100         gametype = 0;\r
 101 \r
 102         // sbar_fields uses strunzone on the titles!\r
 103         for(i = 0; i < MAX_SBAR_FIELDS; ++i)\r
 104                 sbar_title[i] = strzone("(null)");\r
 105 \r
 106         postinit = false;\r
 107 \r
 108         teams = Sort_Spawn();\r
 109         players = Sort_Spawn();\r
 110         \r
 111         GetTeam(COLOR_SPECTATOR, true); // add specs first\r
 112 \r
 113         cvar_clientsettemp("_supports_weaponpriority", "1");\r
 114 \r
 115 \r
 116 \r
 117 \r
 118         cs_project_is_b0rked = TRUE;\r
 119         R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');\r
 120         R_SetView(VF_FOV, '90 90 0');\r
 121         R_SetView(VF_ORIGIN, '0 0 0');\r
 122         R_SetView(VF_ANGLES, '0 0 0');\r
 123         R_SetView(VF_PERSPECTIVE, 1);\r
 124         makevectors('0 0 0');\r
 125         vector v;\r
 126         v = cs_project(v_forward);\r
 127         if(v_x - 320 < +1)\r
 128         if(v_x - 320 > -1)\r
 129         if(v_y - 240 < +1)\r
 130         if(v_y - 240 > -1)\r
 131                 cs_project_is_b0rked = FALSE;\r
 132 \r
 133         WaypointSprite_Load();\r
 134 }\r
 135 \r
 136 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)\r
 137 void CSQC_Shutdown(void)\r
 138 {\r
 139 #ifdef USE_FTE\r
 140 #pragma TARGET id\r
 141         if(!__engine_check)\r
 142                 return 0;\r
 143 #pragma TARGET fte\r
 144 #endif\r
 145 \r
 146         remove(teams);\r
 147         remove(players);\r
 148         db_close(configdb);\r
 149         db_close(binddb);\r
 150         db_close(tempdb);\r
 151 \r
 152         cvar_clientsettemp_restore();\r
 153 }\r
 154 \r
 155 .float has_team;\r
 156 float SetTeam(entity o, float Team)\r
 157 {\r
 158         entity tm;\r
 159         if(Team == -1) // leave\r
 160         {\r
 161                 if(o.has_team)\r
 162                 {\r
 163                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");\r
 164                         tm = GetTeam(o.team, false);\r
 165                         tm.team_size -= 1;\r
 166                         o.has_team = 0;\r
 167                         return TRUE;\r
 168                 }\r
 169         }\r
 170         else\r
 171         {\r
 172                 if not(o.has_team)\r
 173                 {\r
 174                         //print("(CONNECT) enter team ", ftos(o.team), "\n");\r
 175                         o.team = Team;\r
 176                         tm = GetTeam(Team, true);\r
 177                         tm.team_size += 1;\r
 178                         o.has_team = 1;\r
 179                         return TRUE;\r
 180                 }\r
 181                 else if(Team != o.team)\r
 182                 {\r
 183                         //print("(CHANGE) leave team ", ftos(o.team), "\n");\r
 184                         tm = GetTeam(o.team, false);\r
 185                         tm.team_size -= 1;\r
 186                         o.team = Team;\r
 187                         //print("(CHANGE) enter team ", ftos(o.team), "\n");\r
 188                         tm = GetTeam(Team, true);\r
 189                         tm.team_size += 1;\r
 190                         return TRUE;\r
 191                 }\r
 192         }\r
 193         return FALSE;\r
 194 }\r
 195 \r
 196 void Playerchecker_Think()\r
 197 {\r
 198         float i;\r
 199         entity e;\r
 200         for(i = 0; i < maxclients; ++i)\r
 201         {\r
 202                 e = playerslots[i];\r
 203                 if(getplayerkey(i, "name") == "")\r
 204                 {\r
 205                         if(e.sort_prev)\r
 206                         {\r
 207                                 //print("playerchecker: KILL KILL KILL\n");\r
 208                                 // player disconnected\r
 209                                 SetTeam(e, -1);\r
 210                                 RemovePlayer(e);\r
 211                                 e.sort_prev = world;\r
 212                                 //e.gotscores = 0;\r
 213                         }\r
 214                 }\r
 215                 else\r
 216                 {\r
 217                         if not(e.sort_prev)\r
 218                         {\r
 219                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");\r
 220                                 // player connected\r
 221                                 if not(e)\r
 222                                         playerslots[i] = e = spawn();\r
 223                                 e.sv_entnum = i;\r
 224                                 //e.gotscores = 0; // we might already have the scores...\r
 225                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with Sbar_UpdatePlayerTeams\r
 226                                 RegisterPlayer(e);\r
 227                                 Sbar_UpdatePlayerPos(e);\r
 228                         }\r
 229                 }\r
 230         }\r
 231         self.nextthink = time + 0.2;\r
 232 }\r
 233 \r
 234 void Porto_Init();\r
 235 void PostInit(void)\r
 236 {\r
 237         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));\r
 238         localcmd(strcat("\nsbar_columns_set ", cvar_string("sbar_columns"), ";\n"));\r
 239 \r
 240         entity playerchecker;\r
 241         playerchecker = spawn();\r
 242         playerchecker.think = Playerchecker_Think;\r
 243         playerchecker.nextthink = time + 0.2;\r
 244 \r
 245         Porto_Init();\r
 246 \r
 247         postinit = true;\r
 248 }\r
 249 \r
 250 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function\r
 251 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.\r
 252 float button_zoom;\r
 253 void Cmd_Sbar_SetFields(float);\r
 254 void Cmd_Sbar_Help(float);\r
 255 float CSQC_ConsoleCommand(string strMessage)\r
 256 {\r
 257         float argc;\r
 258         // Tokenize String\r
 259         //argc = tokenize(strMessage);\r
 260         argc = tokenize_sane(strMessage);\r
 261         \r
 262         // Acquire Command\r
 263         local string strCmd;\r
 264         strCmd = argv(0);\r
 265 \r
 266         if(strCmd == "+button4") { // zoom\r
 267                 // return false, because the message shall be sent to the server anyway (for demos/speccing)\r
 268                 if(ignore_plus_zoom)\r
 269                 {\r
 270                         --ignore_plus_zoom;\r
 271                         return false;\r
 272                 }\r
 273                 button_zoom = 1;\r
 274                 return true;\r
 275         } else if(strCmd == "-button4") { // zoom\r
 276                 if(ignore_minus_zoom)\r
 277                 {\r
 278                         --ignore_minus_zoom;\r
 279                         return false;\r
 280                 }\r
 281                 button_zoom = 0;\r
 282                 return true;\r
 283         } else if(strCmd == "+button3") { // secondary\r
 284                 button_attack2 = 1;\r
 285                 return false;\r
 286         } else if(strCmd == "-button3") { // secondary\r
 287                 button_attack2 = 0;\r
 288                 return false;\r
 289         } else if(strCmd == "ons_map") {\r
 290                 Cmd_ons_map();\r
 291                 return true;\r
 292         } else if(strCmd == "sbar_columns_set") {\r
 293                 Cmd_Sbar_SetFields(argc);\r
 294                 return true;\r
 295         } else if(strCmd == "sbar_columns_help") {\r
 296                 Cmd_Sbar_Help(argc);\r
 297                 return true;\r
 298         } else if(strCmd == "+showscores") {\r
 299                 sb_showscores = true;\r
 300                 return true;\r
 301         } else if(strCmd == "-showscores") {\r
 302                 sb_showscores = false;\r
 303                 return true;\r
 304         }\r
 305         \r
 306         return false;\r
 307 }\r
 308 \r
 309 float GameCommand(string msg)\r
 310 {\r
 311         float argc;\r
 312         argc = tokenize_sane(msg);\r
 313         string cmd;\r
 314         cmd = argv(0);\r
 315         if(cmd == "mv_download") {\r
 316                 Cmd_MapVote_MapDownload(argc);\r
 317                 return true;\r
 318         }\r
 319         else if(cmd == "settemp") {\r
 320                 cvar_clientsettemp(argv(1), argv(2));\r
 321         }\r
 322         \r
 323         return false;\r
 324 }\r
 325 \r
 326 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.\r
 327 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.\r
 328 // All keys are in ascii.\r
 329 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.\r
 330 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.\r
 331 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.\r
 332 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)\r
 333 {\r
 334         local float bSkipKey;\r
 335         bSkipKey = false;\r
 336         \r
 337         if(menu_visible)\r
 338                 if(menu_action(bInputType, nPrimary, nSecondary))\r
 339                         return TRUE;\r
 340         return bSkipKey;\r
 341 }\r
 342 \r
 343 // END REQUIRED CSQC FUNCTIONS\r
 344 // --------------------------------------------------------------------------\r
 345 \r
 346 // --------------------------------------------------------------------------\r
 347 // BEGIN OPTIONAL CSQC FUNCTIONS\r
 348 void Ent_ReadEntCS()\r
 349 {\r
 350         InterpolateOrigin_Undo();\r
 351 \r
 352         self.classname = "entcs_receiver";\r
 353         self.sv_entnum = ReadByte() - 1;\r
 354         self.origin_x = ReadShort();\r
 355         self.origin_y = ReadShort();\r
 356         self.origin_z = ReadShort();\r
 357         self.angles_y = ReadByte() * 360.0 / 256;\r
 358         self.origin_z = self.angles_x = self.angles_z = 0;\r
 359 \r
 360         InterpolateOrigin_Note();\r
 361 }\r
 362 \r
 363 void Ent_RemoveEntCS()\r
 364 {\r
 365 }\r
 366 \r
 367 void Ent_Remove();\r
 368 void Ent_ReadPlayerScore()\r
 369 {\r
 370         float i, n;\r
 371         float isNew;\r
 372         entity o;\r
 373 \r
 374         // damnit -.- don't want to go change every single .sv_entnum in sbar.qc AGAIN\r
 375         // (no I've never heard of M-x replace-string, sed, or anything like that)\r
 376         isNew = !self.owner; // workaround for DP bug\r
 377         n = ReadByte()-1;\r
 378 \r
 379 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 380         if(!isNew && n != self.sv_entnum)\r
 381         {\r
 382                 print("A CSQC entity changed its owner!\n");\r
 383                 isNew = true;\r
 384                 Ent_Remove();\r
 385                 self.enttype = ENT_CLIENT_SCORES;\r
 386         }\r
 387 #endif\r
 388 \r
 389         self.sv_entnum = n;\r
 390 \r
 391         if not(playerslots[self.sv_entnum])\r
 392                 playerslots[self.sv_entnum] = spawn();\r
 393         o = self.owner = playerslots[self.sv_entnum];\r
 394         o.sv_entnum = self.sv_entnum;\r
 395         o.gotscores = 1;\r
 396 \r
 397         //if not(o.sort_prev)\r
 398         //      RegisterPlayer(o);\r
 399         //playerchecker will do this for us later, if it has not already done so\r
 400 \r
 401 #if MAX_SCORE <= 3\r
 402         for(i = 0; i < MAX_SCORE; ++i)\r
 403                 o.(scores[i]) = ReadShort();\r
 404 #else\r
 405         float sf;\r
 406 #if MAX_SCORE <= 8\r
 407         sf = ReadByte();\r
 408 #else\r
 409         sf = ReadShort();\r
 410 #endif\r
 411         float p;\r
 412         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)\r
 413                 if(sf & p)\r
 414                         o.(scores[i]) = ReadShort();\r
 415 #endif\r
 416 \r
 417         if(o.sort_prev)\r
 418                 Sbar_UpdatePlayerPos(o); // if not registered, we cannot do this yet!\r
 419 }\r
 420 \r
 421 void Ent_ReadTeamScore()\r
 422 {\r
 423         float i;\r
 424         entity o;\r
 425         \r
 426         self.team = ReadByte();\r
 427         o = self.owner = GetTeam(self.team, true);\r
 428 \r
 429 #if MAX_TEAMSCORE <= 3\r
 430         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 431                 o.(teamscores[i]) = ReadShort();\r
 432 #else\r
 433         float sf;\r
 434 #if MAX_TEAMSCORE <= 8\r
 435         sf = ReadByte();\r
 436 #else\r
 437         sf = ReadShort();\r
 438 #endif\r
 439         float p;\r
 440         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)\r
 441                 if(sf & p)\r
 442                         o.(teamscores[i]) = ReadShort();\r
 443 #endif\r
 444 \r
 445         Sbar_UpdateTeamPos(o);\r
 446 }\r
 447 \r
 448 void Ent_Nagger()\r
 449 {\r
 450         float nags;\r
 451 \r
 452         nags = ReadByte();\r
 453 \r
 454         if(nags & 128)\r
 455         {\r
 456                 if(vote_called_vote)\r
 457                         strunzone(vote_called_vote);\r
 458                 vote_called_vote = strzone(ReadString());\r
 459         }\r
 460 \r
 461         ready_waiting = (nags & 1);\r
 462         ready_waiting_for_me = (nags & 2);\r
 463         vote_waiting = (nags & 4);\r
 464         vote_waiting_for_me = (nags & 8);\r
 465 }\r
 466 \r
 467 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.\r
 468 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.\r
 469 void(float bIsNewEntity) CSQC_Ent_Update =\r
 470 {\r
 471         float t;\r
 472         t = ReadByte();\r
 473 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 474         if(self.enttype)\r
 475                 if(t != self.enttype)\r
 476                 {\r
 477                         print("A CSQC entity changed its type!\n");\r
 478                         Ent_Remove();\r
 479                 }\r
 480 #endif\r
 481         self.enttype = t;\r
 482         if(self.enttype == ENT_CLIENT_ENTCS)\r
 483                 Ent_ReadEntCS();\r
 484         else if(self.enttype == ENT_CLIENT_SCORES)\r
 485                 Ent_ReadPlayerScore();\r
 486         else if(self.enttype == ENT_CLIENT_TEAMSCORES)\r
 487                 Ent_ReadTeamScore();\r
 488         else if(self.enttype == ENT_CLIENT_POINTPARTICLES)\r
 489                 Ent_PointParticles();\r
 490         else if(self.enttype == ENT_CLIENT_RAINSNOW)\r
 491                 Ent_RainOrSnow();\r
 492         else if(self.enttype == ENT_CLIENT_LASER)\r
 493                 Ent_Laser();\r
 494         else if(self.enttype == ENT_CLIENT_NAGGER)\r
 495                 Ent_Nagger();\r
 496         else if(self.enttype == ENT_CLIENT_WAYPOINT)\r
 497                 Ent_WaypointSprite();\r
 498         else\r
 499                 error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));\r
 500         \r
 501 };\r
 502 // Destructor, but does NOT deallocate the entity by calling remove(). Also\r
 503 // used when an entity changes its type. For an entity that someone interacts\r
 504 // with others, make sure it can no longer do so.\r
 505 void Ent_Remove()\r
 506 {\r
 507         float i;\r
 508         if(self.enttype == ENT_CLIENT_ENTCS)\r
 509         {\r
 510                 Ent_RemoveEntCS();\r
 511         } else if(self.enttype == ENT_CLIENT_SCORES)\r
 512         {\r
 513                 if(self.owner)\r
 514                 {\r
 515                         SetTeam(self.owner, -1);\r
 516                         self.owner.gotscores = 0;\r
 517                         for(i = 0; i < MAX_SCORE; ++i)\r
 518                                 self.owner.(scores[i]) = 0; // clear all scores\r
 519                 }\r
 520         } else if(self.enttype == ENT_CLIENT_TEAMSCORES)\r
 521         {\r
 522                 /*\r
 523                 if(self.owner)\r
 524                         RemoveTeam(self.owner);\r
 525                 */\r
 526                 // we don't NEED to remove them... they won't display anyway\r
 527                 // plus, svqc never does this anyway\r
 528         } else if(self.enttype == ENT_CLIENT_POINTPARTICLES)\r
 529         {\r
 530                 Ent_PointParticles_Remove();\r
 531         }\r
 532         else if(self.enttype == ENT_CLIENT_WAYPOINT)\r
 533                 Ent_RemoveWaypointSprite();\r
 534 \r
 535         self.enttype = 0;\r
 536         self.classname = "";\r
 537         self.draw = menu_sub_null;\r
 538         // TODO possibly set more stuff to defaults\r
 539 }\r
 540 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.\r
 541 void CSQC_Ent_Remove()\r
 542 {\r
 543         if(self.enttype)\r
 544                 Ent_Remove();\r
 545         remove(self);\r
 546 }\r
 547 \r
 548 void Gamemode_Init()\r
 549 {\r
 550         get_mi_min_max_texcoords(1); // try the CLEVER way first\r
 551         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");\r
 552         shortmapname = mi_shortname;\r
 553 \r
 554         if(precache_pic(minimapname) == "")\r
 555         {\r
 556                 // but maybe we have a non-clever minimap\r
 557                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");\r
 558                 if(precache_pic(minimapname) == "")\r
 559                         minimapname = ""; // FAIL\r
 560                 else\r
 561                         get_mi_min_max_texcoords(0); // load new texcoords\r
 562         }\r
 563 \r
 564         mi_center = (mi_min + mi_max) * 0.5;\r
 565         mi_scale = mi_max - mi_min;\r
 566         minimapname = strzone(minimapname);\r
 567 \r
 568         if(gametype == GAME_ONSLAUGHT) {\r
 569                 print(strcat("Using ", minimapname, " as minimap.\n"));\r
 570                 precache_pic("gfx/ons-cp-neutral.tga");\r
 571                 precache_pic("gfx/ons-cp-red.tga");\r
 572                 precache_pic("gfx/ons-cp-blue.tga");\r
 573                 precache_pic("gfx/ons-frame.tga");\r
 574                 precache_pic("gfx/ons-frame-team.tga");\r
 575         } else if(gametype == GAME_KEYHUNT) {\r
 576                 precache_pic("gfx/sb_key_carrying");\r
 577                 precache_pic("gfx/sb_key_carrying_outline");\r
 578         }\r
 579 }\r
 580 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.\r
 581 void CSQC_Parse_StuffCmd(string strMessage)\r
 582 {\r
 583         localcmd(strMessage);\r
 584 }\r
 585 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.\r
 586 void CSQC_Parse_Print(string strMessage)\r
 587 {\r
 588         print(strMessage);\r
 589 }\r
 590 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.  To execute standard behavior, simply execute cprint with the string.\r
 591 void CSQC_Parse_CenterPrint(string strMessage)\r
 592 {\r
 593         cprint(strMessage);\r
 594 }\r
 595 \r
 596 void CSQC_CheckRevision();\r
 597 \r
 598 void Fog_Force()\r
 599 {\r
 600         // TODO somehow thwart prvm_globalset client ...\r
 601 \r
 602         if(forcefog != "")\r
 603                 localcmd(strcat("\nfog ", forcefog, "\nr_fog_exp2 0\nr_drawfog 1\n"));\r
 604 }\r
 605 \r
 606 void Net_ReadFog()\r
 607 {\r
 608         if(forcefog)\r
 609                 strunzone(forcefog);\r
 610         ReadCoord(); // ignore fog interval\r
 611         forcefog = strzone(ReadString());\r
 612 }\r
 613 \r
 614 void Gamemode_Init();\r
 615 void Net_ReadScoresInfo()\r
 616 {\r
 617         float i;\r
 618         gametype = ReadByte();\r
 619         for(i = 0; i < MAX_SCORE; ++i)\r
 620         {\r
 621                 scores_label[i] = strzone(ReadString());\r
 622                 scores_flags[i] = ReadByte();\r
 623         }\r
 624         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 625         {\r
 626                 teamscores_label[i] = strzone(ReadString());\r
 627                 teamscores_flags[i] = ReadByte();\r
 628         }\r
 629         Sbar_InitScores();\r
 630         Gamemode_Init();\r
 631 }\r
 632 \r
 633 void Net_ReadInit()\r
 634 {\r
 635         float i;\r
 636         csqc_revision = ReadShort();\r
 637         maxclients = ReadByte();\r
 638         for(i = 0; i < 24; ++i)\r
 639                 weaponimpulse[i] = ReadByte() - 1;\r
 640         CSQC_CheckRevision();\r
 641 }\r
 642 \r
 643 string Net_ReadPicture()\r
 644 {\r
 645         string img;\r
 646         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
 647         {\r
 648                 img = ReadPicture();\r
 649                 print(strcat("Got Picture: ", img, "\n"));\r
 650         } else {\r
 651                 img = ReadString();\r
 652                 print(strcat("^3Warning: ^7Couldn't download ", img, ". This is probably because your engine build is outdated.\n"));\r
 653                 float psize, i;\r
 654                 psize = ReadShort();\r
 655                 // Can I be sure that ReadShort is 2 bytes and ReadLong is 4 bytes?\r
 656                 // Because then this could be optimized to first get all 4-byte-groups,\r
 657                 // then the remaining 2, then the remaining 1\r
 658                 for(i = 0; i < psize; ++i)\r
 659                         ReadByte();\r
 660         }\r
 661         return img;\r
 662 }\r
 663 \r
 664 void Net_Config()\r
 665 {\r
 666         string key, value;\r
 667         key = ReadString();\r
 668         value = ReadString();\r
 669         db_put(configdb, strcat("/v/", key), value);\r
 670         db_put(configdb, strcat("/s/", key), "1");\r
 671 }\r
 672 \r
 673 void Net_ReadRace()\r
 674 {\r
 675         float b;\r
 676 \r
 677         b = ReadByte();\r
 678 \r
 679         switch(b)\r
 680         {\r
 681                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:\r
 682                         race_checkpoint = ReadByte();\r
 683                         race_time = ReadShort();\r
 684                         race_previousbesttime = ReadShort();\r
 685                         if(race_previousbestname)\r
 686                                 strunzone(race_previousbestname);\r
 687                         race_previousbestname = strzone(ReadString());\r
 688 \r
 689                         race_checkpointtime = time;\r
 690 \r
 691                         if(race_checkpoint == 0)\r
 692                                 race_laptime = time; // valid\r
 693 \r
 694                         break;\r
 695 \r
 696                 case RACE_NET_CHECKPOINT_CLEAR:\r
 697                         race_laptime = 0;\r
 698                         race_checkpointtime = 0;\r
 699                         break;\r
 700 \r
 701                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:\r
 702                         race_laptime = ReadCoord();\r
 703                         race_checkpointtime = -99999;\r
 704                         // fall through\r
 705                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:\r
 706                         race_nextcheckpoint = ReadByte();\r
 707 \r
 708                         race_nextbesttime = ReadShort();\r
 709                         if(race_nextbestname)\r
 710                                 strunzone(race_nextbestname);\r
 711                         race_nextbestname = strzone(ReadString());\r
 712                         break;\r
 713 \r
 714                 case RACE_NET_CHECKPOINT_HIT_RACE:\r
 715                         race_mycheckpoint = ReadByte();\r
 716                         race_mycheckpointtime = time;\r
 717                         race_mycheckpointdelta = ReadShort();\r
 718                         race_mycheckpointlapsdelta = ReadByte();\r
 719                         if(race_mycheckpointlapsdelta >= 128)\r
 720                                 race_mycheckpointlapsdelta -= 256;\r
 721                         if(race_mycheckpointenemy)\r
 722                                 strunzone(race_mycheckpointenemy);\r
 723                         race_mycheckpointenemy = strzone(ReadString());\r
 724                         break;\r
 725 \r
 726                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:\r
 727                         race_othercheckpoint = ReadByte();\r
 728                         race_othercheckpointtime = time;\r
 729                         race_othercheckpointdelta = ReadShort();\r
 730                         race_othercheckpointlapsdelta = ReadByte();\r
 731                         if(race_othercheckpointlapsdelta >= 128)\r
 732                                 race_othercheckpointlapsdelta -= 256;\r
 733                         if(race_othercheckpointenemy)\r
 734                                 strunzone(race_othercheckpointenemy);\r
 735                         race_othercheckpointenemy = strzone(ReadString());\r
 736                         break;\r
 737         }\r
 738 }\r
 739 \r
 740 void Net_ReadForceScoreboard()\r
 741 {\r
 742         sb_showscores_force = ReadByte();\r
 743 }\r
 744 \r
 745 void Net_Reset()\r
 746 {\r
 747         float i;\r
 748         race_laptime = 0;\r
 749         race_checkpointtime = 0;\r
 750         for(i = 0; i < 24; ++i)\r
 751                 angles_held_status[i] = 0;\r
 752 }\r
 753 \r
 754 void Net_ReadSpectating()\r
 755 {\r
 756         float newspectatee_status;\r
 757         newspectatee_status = ReadByte();\r
 758         if(newspectatee_status == player_localentnum)\r
 759                 newspectatee_status = -1; // observing\r
 760         if(newspectatee_status != spectatee_status)\r
 761                 Net_Reset();\r
 762         spectatee_status = newspectatee_status;\r
 763 }\r
 764 \r
 765 void Net_ReadZoomNotify()\r
 766 {\r
 767         spectatorbutton_zoom = ReadByte();\r
 768 }\r
 769 \r
 770 void Net_ReadSpawn()\r
 771 {\r
 772         zoomin_effect = 1;\r
 773         current_viewzoom = 0.6;\r
 774 }\r
 775 \r
 776 void Net_ReadWarmupStage()\r
 777 {\r
 778         warmup_stage = ReadByte();\r
 779 }\r
 780 \r
 781 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.\r
 782 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.\r
 783 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.\r
 784 void Net_ReadHoldAngles();\r
 785 float CSQC_Parse_TempEntity()\r
 786 {\r
 787         local float bHandled;\r
 788                 bHandled  = true;\r
 789         // Acquire TE ID\r
 790         local float nTEID;\r
 791                 nTEID = ReadByte();\r
 792 \r
 793                 // NOTE: Could just do return instead of break...\r
 794         switch(nTEID)\r
 795         {\r
 796                 case TE_CSQC_INIT:\r
 797                         Net_ReadInit();\r
 798                         bHandled = true;\r
 799                         break;\r
 800                 case TE_CSQC_MAPVOTE:\r
 801                         Net_Mapvote();\r
 802                         bHandled = true;\r
 803                         break;\r
 804                 case TE_CSQC_CONFIG:\r
 805                         Net_Config();\r
 806                         bHandled = true;\r
 807                         break;\r
 808                 case TE_CSQC_SCORESINFO:\r
 809                         Net_ReadScoresInfo();\r
 810                         bHandled = true;\r
 811                         break;\r
 812                 case TE_CSQC_RACE:\r
 813                         Net_ReadRace();\r
 814                         bHandled = true;\r
 815                         break;\r
 816                 case TE_CSQC_FORCESCOREBOARD:\r
 817                         Net_ReadForceScoreboard();\r
 818                         bHandled = true;\r
 819                         break;\r
 820                 case TE_CSQC_SPECTATING:\r
 821                         Net_ReadSpectating();\r
 822                         bHandled = true;\r
 823                         break;\r
 824                 case 13: // TE_BEAM\r
 825                         Net_GrapplingHook();\r
 826                         bHandled = true;\r
 827                         break;\r
 828                 case TE_CSQC_SPAWN:\r
 829                         Net_ReadSpawn();\r
 830                         bHandled = true;\r
 831                         break;\r
 832                 case TE_CSQC_ZOOMNOTIFY:\r
 833                         Net_ReadZoomNotify();\r
 834                         bHandled = true;\r
 835                         break;\r
 836                 case TE_CSQC_HOLDANGLES:\r
 837                         Net_ReadHoldAngles();\r
 838                         bHandled = true;\r
 839                         break;\r
 840                 case TE_CSQC_WARMUP:\r
 841                         Net_ReadWarmupStage();\r
 842                         bHandled = true;\r
 843                         break;\r
 844                 case TE_CSQC_FOG:\r
 845                         Net_ReadFog();\r
 846                         bHandled = true;\r
 847                         break;\r
 848                 default:\r
 849                         // No special logic for this temporary entity; return 0 so the engine can handle it\r
 850                         bHandled = false;\r
 851                         break;\r
 852         }\r
 853         \r
 854         if(!postinit)\r
 855                 PostInit();\r
 856                 \r
 857         return bHandled;\r
 858 }\r
 859 \r
 860 // COMMIT-TODO: Update if necessare, before committing\r
 861 void CSQC_CheckRevision()\r
 862 {\r
 863         if(csqc_revision == CSQC_REVISION)\r
 864         {\r
 865                 print("^2SVQC and CSQC revisions are compatible.\n");\r
 866         } else if(csqc_revision < CSQC_REVISION) {\r
 867                 print("^1Your csprogs.dat (CSQC) version is newer than the one on the server.\n");\r
 868         } else if(csqc_revision > CSQC_REVISION) {\r
 869                 print("^1Your csprogs.dat (CSQC) is too old for this server.\n");\r
 870                 print("^1Please update to a newer version.\n");\r
 871         }\r
 872 }\r
 873 \r
 874 string getcommandkey(string text, string command)\r
 875 {\r
 876         string keys;\r
 877         float n, j, k, l;\r
 878 \r
 879         if (!sbar_showbinds)\r
 880                 return text;\r
 881 \r
 882         keys = db_get(binddb, command);\r
 883         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
 884         {\r
 885                 if (!keys) \r
 886                 {\r
 887                         n = tokenize_insane(findkeysforcommand(command)); // uses '...' strings\r
 888                         for(j = 0; j < n; ++j)\r
 889                         {\r
 890                                 k = stof(argv(j));\r
 891                                 if(k != -1) \r
 892                                 {\r
 893                                         if ("" == keys)\r
 894                                                 keys = keynumtostring(k);\r
 895                                         else\r
 896                                                 keys = strcat(keys, ", ", keynumtostring(k));\r
 897 \r
 898                                         ++l;\r
 899                                         if (sbar_showbinds_limit > 0 && sbar_showbinds_limit >= l) break;\r
 900                                 }\r
 901                         \r
 902                         }\r
 903                         db_put(binddb, command, keys);\r
 904                 }\r
 905         }\r
 906         \r
 907         if ("" == keys) {\r
 908                 if (sbar_showbinds > 1)\r
 909                         return strcat(text, " (not bound)");\r
 910                 else\r
 911                         return text;\r
 912         }\r
 913         else if (sbar_showbinds > 1)\r
 914                 return strcat(text, " (", keys, ")");\r
 915         else\r
 916                 return keys;\r
 917 }\r