data/qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------\r
   2 // BEGIN REQUIRED CSQC FUNCTIONS\r
   3 //include "main.qh"\r
   4 \r
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
   6 \r
   7 void cvar_clientsettemp(string cv, string val)\r
   8 {\r
   9         entity e;\r
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  11                 if(e.netname == cv)\r
  12                         goto saved;\r
  13         e = spawn();\r
  14         e.classname = "saved_cvar_value";\r
  15         e.netname = strzone(cv);\r
  16         e.message = strzone(cvar_string(cv));\r
  17 :saved\r
  18         cvar_set(cv, val);\r
  19 }\r
  20 \r
  21 void cvar_clientsettemp_restore()\r
  22 {\r
  23         entity e;\r
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  25                         cvar_set(e.netname, e.message);\r
  26 }\r
  27 \r
  28 void() menu_show_error =\r
  29 {\r
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);\r
  31 };\r
  32 \r
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)\r
  34 // Useful for precaching things\r
  35 \r
  36 void() menu_sub_null =\r
  37 {\r
  38 };\r
  39 \r
  40 #ifdef USE_FTE\r
  41 float __engine_check;\r
  42 #endif\r
  43 \r
  44 string config_get(string key, string defaultvalue)\r
  45 {\r
  46         string s;\r
  47         s = db_get(configdb, strcat("/s/", key));\r
  48         if(s == "")\r
  49                 return defaultvalue;\r
  50         else\r
  51                 return db_get(configdb, strcat("/v/", key));\r
  52 }\r
  53 \r
  54 string forcefog;\r
  55 void WaypointSprite_Load();\r
  56 void CSQC_Init(void)\r
  57 {\r
  58 #ifdef USE_FTE\r
  59 #pragma target ID\r
  60         __engine_check = checkextension("DP_SV_WRITEPICTURE");\r
  61         if(!__engine_check)\r
  62         {\r
  63                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");\r
  64                 localcmd("\ndisconnect\n");\r
  65                 return;\r
  66         }\r
  67 #pragma target FTE\r
  68 #endif\r
  69         \r
  70         float i;\r
  71         CSQC_CheckEngine();\r
  72         dprint_load();\r
  73 \r
  74         configdb = db_create();\r
  75         binddb = db_create();\r
  76         tempdb = db_create();\r
  77         compressShortVector_init();\r
  78 \r
  79         drawfont = 0;\r
  80         menu_visible = FALSE;\r
  81         menu_show = menu_show_error;\r
  82         menu_action = menu_sub_null;\r
  83         maxclients = 255; // we later get the real maxclients to speed up stuff\r
  84         //ctf_temp_1 = "";\r
  85         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used\r
  86         //registercmd("ctf_menu");\r
  87         registercmd("ons_map");\r
  88         //registercmd("menu_action");\r
  89         registercmd("sbar_columns_set");\r
  90         registercmd("sbar_columns_help");\r
  91 \r
  92         registercmd("+button3");\r
  93         registercmd("-button3");\r
  94         registercmd("+button4");\r
  95         registercmd("-button4");\r
  96 \r
  97         registercvar("sbar_usecsqc", "1");\r
  98         registercvar("sbar_columns", "default", CVAR_SAVE);\r
  99 \r
 100         gametype = 0;\r
 101 \r
 102         // sbar_fields uses strunzone on the titles!\r
 103         for(i = 0; i < MAX_SBAR_FIELDS; ++i)\r
 104                 sbar_title[i] = strzone("(null)");\r
 105 \r
 106         postinit = false;\r
 107 \r
 108         teams = Sort_Spawn();\r
 109         players = Sort_Spawn();\r
 110         \r
 111         GetTeam(COLOR_SPECTATOR, true); // add specs first\r
 112 \r
 113         cvar_clientsettemp("_supports_weaponpriority", "1");\r
 114 \r
 115 \r
 116 \r
 117 \r
 118         cs_project_is_b0rked = TRUE;\r
 119         R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');\r
 120         R_SetView(VF_FOV, '90 90 0');\r
 121         R_SetView(VF_ORIGIN, '0 0 0');\r
 122         R_SetView(VF_ANGLES, '0 0 0');\r
 123         R_SetView(VF_PERSPECTIVE, 1);\r
 124         makevectors('0 0 0');\r
 125         vector v;\r
 126         v = cs_project(v_forward);\r
 127         if(v_x - 320 < +1)\r
 128         if(v_x - 320 > -1)\r
 129         if(v_y - 240 < +1)\r
 130         if(v_y - 240 > -1)\r
 131                 cs_project_is_b0rked = FALSE;\r
 132 \r
 133         WaypointSprite_Load();\r
 134 }\r
 135 \r
 136 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)\r
 137 void CSQC_Shutdown(void)\r
 138 {\r
 139 #ifdef USE_FTE\r
 140 #pragma TARGET id\r
 141         if(!__engine_check)\r
 142                 return 0;\r
 143 #pragma TARGET fte\r
 144 #endif\r
 145 \r
 146         remove(teams);\r
 147         remove(players);\r
 148         db_close(configdb);\r
 149         db_close(binddb);\r
 150         db_close(tempdb);\r
 151 \r
 152         cvar_clientsettemp_restore();\r
 153 }\r
 154 \r
 155 .float has_team;\r
 156 float SetTeam(entity o, float Team)\r
 157 {\r
 158         entity tm;\r
 159         if(Team == -1) // leave\r
 160         {\r
 161                 if(o.has_team)\r
 162                 {\r
 163                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");\r
 164                         tm = GetTeam(o.team, false);\r
 165                         tm.team_size -= 1;\r
 166                         o.has_team = 0;\r
 167                         return TRUE;\r
 168                 }\r
 169         }\r
 170         else\r
 171         {\r
 172                 if not(o.has_team)\r
 173                 {\r
 174                         //print("(CONNECT) enter team ", ftos(o.team), "\n");\r
 175                         o.team = Team;\r
 176                         tm = GetTeam(Team, true);\r
 177                         tm.team_size += 1;\r
 178                         o.has_team = 1;\r
 179                         return TRUE;\r
 180                 }\r
 181                 else if(Team != o.team)\r
 182                 {\r
 183                         //print("(CHANGE) leave team ", ftos(o.team), "\n");\r
 184                         tm = GetTeam(o.team, false);\r
 185                         tm.team_size -= 1;\r
 186                         o.team = Team;\r
 187                         //print("(CHANGE) enter team ", ftos(o.team), "\n");\r
 188                         tm = GetTeam(Team, true);\r
 189                         tm.team_size += 1;\r
 190                         return TRUE;\r
 191                 }\r
 192         }\r
 193         return FALSE;\r
 194 }\r
 195 \r
 196 void Playerchecker_Think()\r
 197 {\r
 198         float i;\r
 199         entity e;\r
 200         for(i = 0; i < maxclients; ++i)\r
 201         {\r
 202                 e = playerslots[i];\r
 203                 if(GetPlayerName(i) == "")\r
 204                 {\r
 205                         if(e.sort_prev)\r
 206                         {\r
 207                                 //print("playerchecker: KILL KILL KILL\n");\r
 208                                 // player disconnected\r
 209                                 SetTeam(e, -1);\r
 210                                 RemovePlayer(e);\r
 211                                 e.sort_prev = world;\r
 212                                 //e.gotscores = 0;\r
 213                         }\r
 214                 }\r
 215                 else\r
 216                 {\r
 217                         if not(e.sort_prev)\r
 218                         {\r
 219                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");\r
 220                                 // player connected\r
 221                                 if not(e)\r
 222                                         playerslots[i] = e = spawn();\r
 223                                 e.sv_entnum = i;\r
 224                                 //e.gotscores = 0; // we might already have the scores...\r
 225                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with Sbar_UpdatePlayerTeams\r
 226                                 RegisterPlayer(e);\r
 227                                 Sbar_UpdatePlayerPos(e);\r
 228                         }\r
 229                 }\r
 230         }\r
 231         self.nextthink = time + 0.2;\r
 232 }\r
 233 \r
 234 void Porto_Init();\r
 235 void PostInit(void)\r
 236 {\r
 237         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));\r
 238         localcmd(strcat("\nsbar_columns_set ", cvar_string("sbar_columns"), ";\n"));\r
 239 \r
 240         entity playerchecker;\r
 241         playerchecker = spawn();\r
 242         playerchecker.think = Playerchecker_Think;\r
 243         playerchecker.nextthink = time + 0.2;\r
 244 \r
 245         Porto_Init();\r
 246 \r
 247         postinit = true;\r
 248 }\r
 249 \r
 250 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function\r
 251 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.\r
 252 float button_zoom;\r
 253 void Cmd_Sbar_SetFields(float);\r
 254 void Cmd_Sbar_Help(float);\r
 255 float CSQC_ConsoleCommand(string strMessage)\r
 256 {\r
 257         float argc;\r
 258         // Tokenize String\r
 259         //argc = tokenize(strMessage);\r
 260         argc = tokenize_sane(strMessage);\r
 261         \r
 262         // Acquire Command\r
 263         local string strCmd;\r
 264         strCmd = argv(0);\r
 265 \r
 266         if(strCmd == "+button4") { // zoom\r
 267                 // return false, because the message shall be sent to the server anyway (for demos/speccing)\r
 268                 if(ignore_plus_zoom)\r
 269                 {\r
 270                         --ignore_plus_zoom;\r
 271                         return false;\r
 272                 }\r
 273                 button_zoom = 1;\r
 274                 return true;\r
 275         } else if(strCmd == "-button4") { // zoom\r
 276                 if(ignore_minus_zoom)\r
 277                 {\r
 278                         --ignore_minus_zoom;\r
 279                         return false;\r
 280                 }\r
 281                 button_zoom = 0;\r
 282                 return true;\r
 283         } else if(strCmd == "+button3") { // secondary\r
 284                 button_attack2 = 1;\r
 285                 return false;\r
 286         } else if(strCmd == "-button3") { // secondary\r
 287                 button_attack2 = 0;\r
 288                 return false;\r
 289         } else if(strCmd == "+showscores") {\r
 290                 sb_showscores = true;\r
 291                 return true;\r
 292         } else if(strCmd == "-showscores") {\r
 293                 sb_showscores = false;\r
 294                 return true;\r
 295         }\r
 296         \r
 297         return false;\r
 298 }\r
 299 \r
 300 float GameCommand(string msg)\r
 301 {\r
 302         float argc;\r
 303         argc = tokenize_sane(msg);\r
 304         string cmd;\r
 305         cmd = argv(0);\r
 306         if(cmd == "mv_download") {\r
 307                 Cmd_MapVote_MapDownload(argc);\r
 308                 return true;\r
 309         }\r
 310         else if(cmd == "settemp") {\r
 311                 cvar_clientsettemp(argv(1), argv(2));\r
 312         }\r
 313         else if(cmd == "radar") {\r
 314                 ons_showmap = !ons_showmap;\r
 315         }\r
 316         else if(cmd == "sbar_columns_set") {\r
 317                 Cmd_Sbar_SetFields(argc);\r
 318         }\r
 319         else if(cmd == "sbar_columns_help") {\r
 320                 Cmd_Sbar_Help(argc);\r
 321         }\r
 322 #ifdef BLURTEST\r
 323         else if(cmd == "blurtest") {\r
 324                 blurtest_time0 = time;\r
 325                 blurtest_time1 = time + stof(argv(1));\r
 326                 blurtest_radius = stof(argv(2));\r
 327                 blurtest_power = stof(argv(3));\r
 328         }\r
 329 #endif\r
 330         \r
 331         return false;\r
 332 }\r
 333 \r
 334 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.\r
 335 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.\r
 336 // All keys are in ascii.\r
 337 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.\r
 338 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.\r
 339 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.\r
 340 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)\r
 341 {\r
 342         local float bSkipKey;\r
 343         bSkipKey = false;\r
 344         \r
 345         if(menu_visible)\r
 346                 if(menu_action(bInputType, nPrimary, nSecondary))\r
 347                         return TRUE;\r
 348         return bSkipKey;\r
 349 }\r
 350 \r
 351 // END REQUIRED CSQC FUNCTIONS\r
 352 // --------------------------------------------------------------------------\r
 353 \r
 354 // --------------------------------------------------------------------------\r
 355 // BEGIN OPTIONAL CSQC FUNCTIONS\r
 356 void Ent_ReadEntCS()\r
 357 {\r
 358         InterpolateOrigin_Undo();\r
 359 \r
 360         self.classname = "entcs_receiver";\r
 361         self.sv_entnum = ReadByte() - 1;\r
 362         self.origin_x = ReadShort();\r
 363         self.origin_y = ReadShort();\r
 364         self.origin_z = ReadShort();\r
 365         self.angles_y = ReadByte() * 360.0 / 256;\r
 366         self.origin_z = self.angles_x = self.angles_z = 0;\r
 367 \r
 368         InterpolateOrigin_Note();\r
 369 }\r
 370 \r
 371 void Ent_RemoveEntCS()\r
 372 {\r
 373 }\r
 374 \r
 375 void Ent_Remove();\r
 376 void Ent_ReadPlayerScore()\r
 377 {\r
 378         float i, n;\r
 379         float isNew;\r
 380         entity o;\r
 381 \r
 382         // damnit -.- don't want to go change every single .sv_entnum in sbar.qc AGAIN\r
 383         // (no I've never heard of M-x replace-string, sed, or anything like that)\r
 384         isNew = !self.owner; // workaround for DP bug\r
 385         n = ReadByte()-1;\r
 386 \r
 387 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 388         if(!isNew && n != self.sv_entnum)\r
 389         {\r
 390                 print("A CSQC entity changed its owner!\n");\r
 391                 isNew = true;\r
 392                 Ent_Remove();\r
 393                 self.enttype = ENT_CLIENT_SCORES;\r
 394         }\r
 395 #endif\r
 396 \r
 397         self.sv_entnum = n;\r
 398 \r
 399         if not(playerslots[self.sv_entnum])\r
 400                 playerslots[self.sv_entnum] = spawn();\r
 401         o = self.owner = playerslots[self.sv_entnum];\r
 402         o.sv_entnum = self.sv_entnum;\r
 403         o.gotscores = 1;\r
 404 \r
 405         //if not(o.sort_prev)\r
 406         //      RegisterPlayer(o);\r
 407         //playerchecker will do this for us later, if it has not already done so\r
 408 \r
 409 #if MAX_SCORE <= 3\r
 410         for(i = 0; i < MAX_SCORE; ++i)\r
 411                 o.(scores[i]) = ReadShort();\r
 412 #else\r
 413         float sf;\r
 414 #if MAX_SCORE <= 8\r
 415         sf = ReadByte();\r
 416 #else\r
 417         sf = ReadShort();\r
 418 #endif\r
 419         float p;\r
 420         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)\r
 421                 if(sf & p)\r
 422                         o.(scores[i]) = ReadShort();\r
 423 #endif\r
 424 \r
 425         if(o.sort_prev)\r
 426                 Sbar_UpdatePlayerPos(o); // if not registered, we cannot do this yet!\r
 427 }\r
 428 \r
 429 void Ent_ReadTeamScore()\r
 430 {\r
 431         float i;\r
 432         entity o;\r
 433         \r
 434         self.team = ReadByte();\r
 435         o = self.owner = GetTeam(self.team, true);\r
 436 \r
 437 #if MAX_TEAMSCORE <= 3\r
 438         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 439                 o.(teamscores[i]) = ReadShort();\r
 440 #else\r
 441         float sf;\r
 442 #if MAX_TEAMSCORE <= 8\r
 443         sf = ReadByte();\r
 444 #else\r
 445         sf = ReadShort();\r
 446 #endif\r
 447         float p;\r
 448         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)\r
 449                 if(sf & p)\r
 450                         o.(teamscores[i]) = ReadShort();\r
 451 #endif\r
 452 \r
 453         Sbar_UpdateTeamPos(o);\r
 454 }\r
 455 \r
 456 void Ent_Nagger()\r
 457 {\r
 458         float nags;\r
 459 \r
 460         nags = ReadByte();\r
 461 \r
 462         if(nags & 128)\r
 463         {\r
 464                 if(vote_called_vote)\r
 465                         strunzone(vote_called_vote);\r
 466                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));\r
 467         }\r
 468 \r
 469         ready_waiting = (nags & 1);\r
 470         ready_waiting_for_me = (nags & 2);\r
 471         vote_waiting = (nags & 4);\r
 472         vote_waiting_for_me = (nags & 8);\r
 473 }\r
 474 \r
 475 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.\r
 476 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.\r
 477 void Ent_RadarLink();\r
 478 void(float bIsNewEntity) CSQC_Ent_Update =\r
 479 {\r
 480         float t;\r
 481         t = ReadByte();\r
 482 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 483         if(self.enttype)\r
 484                 if(t != self.enttype)\r
 485                 {\r
 486                         print("A CSQC entity changed its type!\n");\r
 487                         Ent_Remove();\r
 488                 }\r
 489 #endif\r
 490         self.enttype = t;\r
 491         if(self.enttype == ENT_CLIENT_ENTCS)\r
 492                 Ent_ReadEntCS();\r
 493         else if(self.enttype == ENT_CLIENT_SCORES)\r
 494                 Ent_ReadPlayerScore();\r
 495         else if(self.enttype == ENT_CLIENT_TEAMSCORES)\r
 496                 Ent_ReadTeamScore();\r
 497         else if(self.enttype == ENT_CLIENT_POINTPARTICLES)\r
 498                 Ent_PointParticles();\r
 499         else if(self.enttype == ENT_CLIENT_RAINSNOW)\r
 500                 Ent_RainOrSnow();\r
 501         else if(self.enttype == ENT_CLIENT_LASER)\r
 502                 Ent_Laser();\r
 503         else if(self.enttype == ENT_CLIENT_NAGGER)\r
 504                 Ent_Nagger();\r
 505         else if(self.enttype == ENT_CLIENT_WAYPOINT)\r
 506                 Ent_WaypointSprite();\r
 507         else if(self.enttype == ENT_CLIENT_RADARLINK)\r
 508                 Ent_RadarLink();\r
 509         else\r
 510                 error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));\r
 511         \r
 512 };\r
 513 // Destructor, but does NOT deallocate the entity by calling remove(). Also\r
 514 // used when an entity changes its type. For an entity that someone interacts\r
 515 // with others, make sure it can no longer do so.\r
 516 void Ent_Remove()\r
 517 {\r
 518         float i;\r
 519         if(self.enttype == ENT_CLIENT_ENTCS)\r
 520         {\r
 521                 Ent_RemoveEntCS();\r
 522         } else if(self.enttype == ENT_CLIENT_SCORES)\r
 523         {\r
 524                 if(self.owner)\r
 525                 {\r
 526                         SetTeam(self.owner, -1);\r
 527                         self.owner.gotscores = 0;\r
 528                         for(i = 0; i < MAX_SCORE; ++i)\r
 529                                 self.owner.(scores[i]) = 0; // clear all scores\r
 530                 }\r
 531         } else if(self.enttype == ENT_CLIENT_TEAMSCORES)\r
 532         {\r
 533                 /*\r
 534                 if(self.owner)\r
 535                         RemoveTeam(self.owner);\r
 536                 */\r
 537                 // we don't NEED to remove them... they won't display anyway\r
 538                 // plus, svqc never does this anyway\r
 539         } else if(self.enttype == ENT_CLIENT_POINTPARTICLES)\r
 540         {\r
 541                 Ent_PointParticles_Remove();\r
 542         }\r
 543         else if(self.enttype == ENT_CLIENT_WAYPOINT)\r
 544                 Ent_RemoveWaypointSprite();\r
 545 \r
 546         self.enttype = 0;\r
 547         self.classname = "";\r
 548         self.draw = menu_sub_null;\r
 549         // TODO possibly set more stuff to defaults\r
 550 }\r
 551 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.\r
 552 void CSQC_Ent_Remove()\r
 553 {\r
 554         if(self.enttype)\r
 555                 Ent_Remove();\r
 556         remove(self);\r
 557 }\r
 558 \r
 559 void Gamemode_Init()\r
 560 {\r
 561         get_mi_min_max_texcoords(1); // try the CLEVER way first\r
 562         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");\r
 563         shortmapname = mi_shortname;\r
 564 \r
 565         if(precache_pic(minimapname) == "")\r
 566         {\r
 567                 // but maybe we have a non-clever minimap\r
 568                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");\r
 569                 if(precache_pic(minimapname) == "")\r
 570                         minimapname = ""; // FAIL\r
 571                 else\r
 572                         get_mi_min_max_texcoords(0); // load new texcoords\r
 573         }\r
 574 \r
 575         mi_center = (mi_min + mi_max) * 0.5;\r
 576         mi_scale = mi_max - mi_min;\r
 577         minimapname = strzone(minimapname);\r
 578 \r
 579         if(gametype == GAME_ONSLAUGHT) {\r
 580                 print(strcat("Using ", minimapname, " as minimap.\n"));\r
 581                 precache_pic("gfx/ons-cp-neutral.tga");\r
 582                 precache_pic("gfx/ons-cp-red.tga");\r
 583                 precache_pic("gfx/ons-cp-blue.tga");\r
 584                 precache_pic("gfx/ons-frame.tga");\r
 585                 precache_pic("gfx/ons-frame-team.tga");\r
 586         } else if(gametype == GAME_KEYHUNT) {\r
 587                 precache_pic("gfx/sb_key_carrying");\r
 588                 precache_pic("gfx/sb_key_carrying_outline");\r
 589         }\r
 590 }\r
 591 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.\r
 592 void CSQC_Parse_StuffCmd(string strMessage)\r
 593 {\r
 594         localcmd(strMessage);\r
 595 }\r
 596 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.\r
 597 void CSQC_Parse_Print(string strMessage)\r
 598 {\r
 599         print(ColorTranslateRGB(strMessage));\r
 600 }\r
 601 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.  To execute standard behavior, simply execute cprint with the string.\r
 602 void CSQC_Parse_CenterPrint(string strMessage)\r
 603 {\r
 604         cprint(ColorTranslateRGB(strMessage));\r
 605 }\r
 606 \r
 607 void CSQC_CheckRevision();\r
 608 \r
 609 void Fog_Force()\r
 610 {\r
 611         // TODO somehow thwart prvm_globalset client ...\r
 612 \r
 613         if(forcefog != "")\r
 614                 localcmd(strcat("\nfog ", forcefog, "\nr_fog_exp2 0\nr_drawfog 1\n"));\r
 615 }\r
 616 \r
 617 void Net_ReadFog()\r
 618 {\r
 619         if(forcefog)\r
 620                 strunzone(forcefog);\r
 621         ReadCoord(); // ignore fog interval\r
 622         forcefog = strzone(ReadString());\r
 623 }\r
 624 \r
 625 void Gamemode_Init();\r
 626 void Net_ReadScoresInfo()\r
 627 {\r
 628         float i;\r
 629         gametype = ReadByte();\r
 630         for(i = 0; i < MAX_SCORE; ++i)\r
 631         {\r
 632                 scores_label[i] = strzone(ReadString());\r
 633                 scores_flags[i] = ReadByte();\r
 634         }\r
 635         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 636         {\r
 637                 teamscores_label[i] = strzone(ReadString());\r
 638                 teamscores_flags[i] = ReadByte();\r
 639         }\r
 640         Sbar_InitScores();\r
 641         Gamemode_Init();\r
 642 }\r
 643 \r
 644 void Net_ReadInit()\r
 645 {\r
 646         float i;\r
 647         csqc_revision = ReadShort();\r
 648         maxclients = ReadByte();\r
 649         for(i = 0; i < 24; ++i)\r
 650                 weaponimpulse[i] = ReadByte() - 1;\r
 651         hook_shotorigin_x = ReadCoord();\r
 652         hook_shotorigin_y = ReadCoord();\r
 653         hook_shotorigin_z = ReadCoord();\r
 654         CSQC_CheckRevision();\r
 655 }\r
 656 \r
 657 string Net_ReadPicture()\r
 658 {\r
 659         string img;\r
 660         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
 661         {\r
 662                 img = ReadPicture();\r
 663                 print(strcat("Got Picture: ", img, "\n"));\r
 664         } else {\r
 665                 img = ReadString();\r
 666                 print(strcat("^3Warning: ^7Couldn't download ", img, ". This is probably because your engine build is outdated.\n"));\r
 667                 float psize, i;\r
 668                 psize = ReadShort();\r
 669                 // Can I be sure that ReadShort is 2 bytes and ReadLong is 4 bytes?\r
 670                 // Because then this could be optimized to first get all 4-byte-groups,\r
 671                 // then the remaining 2, then the remaining 1\r
 672                 for(i = 0; i < psize; ++i)\r
 673                         ReadByte();\r
 674         }\r
 675         return img;\r
 676 }\r
 677 \r
 678 void Net_Config()\r
 679 {\r
 680         string key, value;\r
 681         key = ReadString();\r
 682         value = ReadString();\r
 683         db_put(configdb, strcat("/v/", key), value);\r
 684         db_put(configdb, strcat("/s/", key), "1");\r
 685 }\r
 686 \r
 687 void Net_ReadRace()\r
 688 {\r
 689         float b;\r
 690 \r
 691         b = ReadByte();\r
 692 \r
 693         switch(b)\r
 694         {\r
 695                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:\r
 696                         race_checkpoint = ReadByte();\r
 697                         race_time = ReadShort();\r
 698                         race_previousbesttime = ReadShort();\r
 699                         if(race_previousbestname)\r
 700                                 strunzone(race_previousbestname);\r
 701                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));\r
 702 \r
 703                         race_checkpointtime = time;\r
 704 \r
 705                         if(race_checkpoint == 0)\r
 706                                 race_laptime = time; // valid\r
 707 \r
 708                         break;\r
 709 \r
 710                 case RACE_NET_CHECKPOINT_CLEAR:\r
 711                         race_laptime = 0;\r
 712                         race_checkpointtime = 0;\r
 713                         break;\r
 714 \r
 715                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:\r
 716                         race_laptime = ReadCoord();\r
 717                         race_checkpointtime = -99999;\r
 718                         // fall through\r
 719                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:\r
 720                         race_nextcheckpoint = ReadByte();\r
 721 \r
 722                         race_nextbesttime = ReadShort();\r
 723                         if(race_nextbestname)\r
 724                                 strunzone(race_nextbestname);\r
 725                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));\r
 726                         break;\r
 727 \r
 728                 case RACE_NET_CHECKPOINT_HIT_RACE:\r
 729                         race_mycheckpoint = ReadByte();\r
 730                         race_mycheckpointtime = time;\r
 731                         race_mycheckpointdelta = ReadShort();\r
 732                         race_mycheckpointlapsdelta = ReadByte();\r
 733                         if(race_mycheckpointlapsdelta >= 128)\r
 734                                 race_mycheckpointlapsdelta -= 256;\r
 735                         if(race_mycheckpointenemy)\r
 736                                 strunzone(race_mycheckpointenemy);\r
 737                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));\r
 738                         break;\r
 739 \r
 740                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:\r
 741                         race_othercheckpoint = ReadByte();\r
 742                         race_othercheckpointtime = time;\r
 743                         race_othercheckpointdelta = ReadShort();\r
 744                         race_othercheckpointlapsdelta = ReadByte();\r
 745                         if(race_othercheckpointlapsdelta >= 128)\r
 746                                 race_othercheckpointlapsdelta -= 256;\r
 747                         if(race_othercheckpointenemy)\r
 748                                 strunzone(race_othercheckpointenemy);\r
 749                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));\r
 750                         break;\r
 751         }\r
 752 }\r
 753 \r
 754 void Net_ReadForceScoreboard()\r
 755 {\r
 756         sb_showscores_force = ReadByte();\r
 757 }\r
 758 \r
 759 void Net_Reset()\r
 760 {\r
 761         float i;\r
 762         race_laptime = 0;\r
 763         race_checkpointtime = 0;\r
 764         for(i = 0; i < 24; ++i)\r
 765                 angles_held_status[i] = 0;\r
 766 }\r
 767 \r
 768 void Net_ReadSpectating()\r
 769 {\r
 770         float newspectatee_status;\r
 771         newspectatee_status = ReadByte();\r
 772         if(newspectatee_status == player_localentnum)\r
 773                 newspectatee_status = -1; // observing\r
 774         if(newspectatee_status != spectatee_status)\r
 775                 Net_Reset();\r
 776         spectatee_status = newspectatee_status;\r
 777 }\r
 778 \r
 779 void Net_ReadZoomNotify()\r
 780 {\r
 781         spectatorbutton_zoom = ReadByte();\r
 782 }\r
 783 \r
 784 void Net_ReadSpawn()\r
 785 {\r
 786         zoomin_effect = 1;\r
 787         current_viewzoom = 0.6;\r
 788 }\r
 789 \r
 790 void Net_ReadWarmupStage()\r
 791 {\r
 792         warmup_stage = ReadByte();\r
 793 }\r
 794 \r
 795 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.\r
 796 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.\r
 797 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.\r
 798 void Net_ReadHoldAngles();\r
 799 float CSQC_Parse_TempEntity()\r
 800 {\r
 801         local float bHandled;\r
 802                 bHandled  = true;\r
 803         // Acquire TE ID\r
 804         local float nTEID;\r
 805                 nTEID = ReadByte();\r
 806 \r
 807                 // NOTE: Could just do return instead of break...\r
 808         switch(nTEID)\r
 809         {\r
 810                 case TE_CSQC_INIT:\r
 811                         Net_ReadInit();\r
 812                         bHandled = true;\r
 813                         break;\r
 814                 case TE_CSQC_MAPVOTE:\r
 815                         Net_Mapvote();\r
 816                         bHandled = true;\r
 817                         break;\r
 818                 case TE_CSQC_CONFIG:\r
 819                         Net_Config();\r
 820                         bHandled = true;\r
 821                         break;\r
 822                 case TE_CSQC_SCORESINFO:\r
 823                         Net_ReadScoresInfo();\r
 824                         bHandled = true;\r
 825                         break;\r
 826                 case TE_CSQC_RACE:\r
 827                         Net_ReadRace();\r
 828                         bHandled = true;\r
 829                         break;\r
 830                 case TE_CSQC_FORCESCOREBOARD:\r
 831                         Net_ReadForceScoreboard();\r
 832                         bHandled = true;\r
 833                         break;\r
 834                 case TE_CSQC_SPECTATING:\r
 835                         Net_ReadSpectating();\r
 836                         bHandled = true;\r
 837                         break;\r
 838                 case 13: // TE_BEAM\r
 839                         Net_GrapplingHook();\r
 840                         bHandled = true;\r
 841                         break;\r
 842                 case TE_CSQC_SPAWN:\r
 843                         Net_ReadSpawn();\r
 844                         bHandled = true;\r
 845                         break;\r
 846                 case TE_CSQC_ZOOMNOTIFY:\r
 847                         Net_ReadZoomNotify();\r
 848                         bHandled = true;\r
 849                         break;\r
 850                 case TE_CSQC_HOLDANGLES:\r
 851                         Net_ReadHoldAngles();\r
 852                         bHandled = true;\r
 853                         break;\r
 854                 case TE_CSQC_WARMUP:\r
 855                         Net_ReadWarmupStage();\r
 856                         bHandled = true;\r
 857                         break;\r
 858                 case TE_CSQC_FOG:\r
 859                         Net_ReadFog();\r
 860                         bHandled = true;\r
 861                         break;\r
 862                 default:\r
 863                         // No special logic for this temporary entity; return 0 so the engine can handle it\r
 864                         bHandled = false;\r
 865                         break;\r
 866         }\r
 867         \r
 868         if(!postinit)\r
 869                 PostInit();\r
 870                 \r
 871         return bHandled;\r
 872 }\r
 873 \r
 874 // COMMIT-TODO: Update if necessare, before committing\r
 875 void CSQC_CheckRevision()\r
 876 {\r
 877         if(csqc_revision == CSQC_REVISION)\r
 878         {\r
 879                 print("^2SVQC and CSQC revisions are compatible.\n");\r
 880         } else if(csqc_revision < CSQC_REVISION) {\r
 881                 print("^1Your csprogs.dat (CSQC) version is newer than the one on the server.\n");\r
 882         } else if(csqc_revision > CSQC_REVISION) {\r
 883                 print("^1Your csprogs.dat (CSQC) is too old for this server.\n");\r
 884                 print("^1Please update to a newer version.\n");\r
 885         }\r
 886 }\r
 887 \r
 888 string getcommandkey(string text, string command)\r
 889 {\r
 890         string keys;\r
 891         float n, j, k, l;\r
 892 \r
 893         if (!sbar_showbinds)\r
 894                 return text;\r
 895 \r
 896         keys = db_get(binddb, command);\r
 897         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
 898         {\r
 899                 if (!keys) \r
 900                 {\r
 901                         n = tokenize_insane(findkeysforcommand(command)); // uses '...' strings\r
 902                         for(j = 0; j < n; ++j)\r
 903                         {\r
 904                                 k = stof(argv(j));\r
 905                                 if(k != -1) \r
 906                                 {\r
 907                                         if ("" == keys)\r
 908                                                 keys = keynumtostring(k);\r
 909                                         else\r
 910                                                 keys = strcat(keys, ", ", keynumtostring(k));\r
 911 \r
 912                                         ++l;\r
 913                                         if (sbar_showbinds_limit > 0 && sbar_showbinds_limit >= l) break;\r
 914                                 }\r
 915                         \r
 916                         }\r
 917                         db_put(binddb, command, keys);\r
 918                 }\r
 919         }\r
 920         \r
 921         if ("" == keys) {\r
 922                 if (sbar_showbinds > 1)\r
 923                         return strcat(text, " (not bound)");\r
 924                 else\r
 925                         return text;\r
 926         }\r
 927         else if (sbar_showbinds > 1)\r
 928                 return strcat(text, " (", keys, ")");\r
 929         else\r
 930                 return keys;\r
 931 }\r