data/qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------\r
   2 // BEGIN REQUIRED CSQC FUNCTIONS\r
   3 //include "main.qh"\r
   4 \r
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
   6 \r
   7 void cvar_clientsettemp(string cv, string val)\r
   8 {\r
   9         entity e;\r
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  11                 if(e.netname == cv)\r
  12                         goto saved;\r
  13         e = spawn();\r
  14         e.classname = "saved_cvar_value";\r
  15         e.netname = strzone(cv);\r
  16         e.message = strzone(cvar_string(cv));\r
  17 :saved\r
  18         cvar_set(cv, val);\r
  19 }\r
  20 \r
  21 void cvar_clientsettemp_restore()\r
  22 {\r
  23         entity e;\r
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  25                         cvar_set(e.netname, e.message);\r
  26 }\r
  27 \r
  28 void() menu_show_error =\r
  29 {\r
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);\r
  31 };\r
  32 \r
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)\r
  34 // Useful for precaching things\r
  35 \r
  36 void() menu_sub_null =\r
  37 {\r
  38 };\r
  39 \r
  40 #ifdef USE_FTE\r
  41 float __engine_check;\r
  42 #endif\r
  43 \r
  44 string forcefog;\r
  45 void WaypointSprite_Load();\r
  46 void CSQC_Init(void)\r
  47 {\r
  48 #ifdef USE_FTE\r
  49 #pragma target ID\r
  50         __engine_check = checkextension("DP_SV_WRITEPICTURE");\r
  51         if(!__engine_check)\r
  52         {\r
  53                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");\r
  54                 localcmd("\ndisconnect\n");\r
  55                 return;\r
  56         }\r
  57 #pragma target FTE\r
  58 #endif\r
  59         \r
  60         float i;\r
  61         CSQC_CheckEngine();\r
  62         dprint_load();\r
  63 \r
  64         binddb = db_create();\r
  65         tempdb = db_create();\r
  66         compressShortVector_init();\r
  67 \r
  68         drawfont = 0;\r
  69         menu_visible = FALSE;\r
  70         menu_show = menu_show_error;\r
  71         menu_action = menu_sub_null;\r
  72         maxclients = 255; // we later get the real maxclients to speed up stuff\r
  73         //ctf_temp_1 = "";\r
  74         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used\r
  75         //registercmd("ctf_menu");\r
  76         registercmd("ons_map");\r
  77         //registercmd("menu_action");\r
  78         registercmd("sbar_columns_set");\r
  79         registercmd("sbar_columns_help");\r
  80 \r
  81         registercmd("+button3");\r
  82         registercmd("-button3");\r
  83         registercmd("+button4");\r
  84         registercmd("-button4");\r
  85 \r
  86 #ifndef CAMERATEST\r
  87         if(isdemo())\r
  88         {\r
  89 #endif\r
  90                 registercmd("+forward");registercmd("-forward");\r
  91                 registercmd("+back");registercmd("-back");\r
  92                 registercmd("+moveup");registercmd("-moveup");\r
  93                 registercmd("+movedown");registercmd("-movedown");\r
  94                 registercmd("+moveright");registercmd("-moveright");\r
  95                 registercmd("+moveleft");registercmd("-moveleft");\r
  96                 registercmd("+roll_right");registercmd("-roll_right");\r
  97                 registercmd("+roll_left");registercmd("-roll_left");\r
  98 #ifndef CAMERATEST\r
  99         }\r
 100 #endif\r
 101         registercvar("sbar_usecsqc", "1");\r
 102         registercvar("sbar_columns", "default", CVAR_SAVE);\r
 103 \r
 104         gametype = 0;\r
 105 \r
 106         // sbar_fields uses strunzone on the titles!\r
 107         for(i = 0; i < MAX_SBAR_FIELDS; ++i)\r
 108                 sbar_title[i] = strzone("(null)");\r
 109 \r
 110         postinit = false;\r
 111 \r
 112         teams = Sort_Spawn();\r
 113         players = Sort_Spawn();\r
 114         \r
 115         GetTeam(COLOR_SPECTATOR, true); // add specs first\r
 116 \r
 117         cvar_clientsettemp("_supports_weaponpriority", "1");\r
 118 \r
 119 \r
 120 \r
 121 \r
 122         cs_project_is_b0rked = TRUE;\r
 123         R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');\r
 124         R_SetView(VF_FOV, '90 90 0');\r
 125         R_SetView(VF_ORIGIN, '0 0 0');\r
 126         R_SetView(VF_ANGLES, '0 0 0');\r
 127         R_SetView(VF_PERSPECTIVE, 1);\r
 128         makevectors('0 0 0');\r
 129         vector v;\r
 130         v = cs_project(v_forward);\r
 131         if(v_x - 320 < +1)\r
 132         if(v_x - 320 > -1)\r
 133         if(v_y - 240 < +1)\r
 134         if(v_y - 240 > -1)\r
 135                 cs_project_is_b0rked = FALSE;\r
 136 \r
 137         RegisterWeapons();\r
 138 \r
 139         WaypointSprite_Load();\r
 140 \r
 141         Projectile_Precache();\r
 142         GibSplash_Precache();\r
 143         Casings_Precache();\r
 144         DamageInfo_Precache();\r
 145 \r
 146         get_mi_min_max_texcoords(1); // try the CLEVER way first\r
 147         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");\r
 148         shortmapname = mi_shortname;\r
 149 \r
 150         if(precache_pic(minimapname) == "")\r
 151         {\r
 152                 // but maybe we have a non-clever minimap\r
 153                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");\r
 154                 if(precache_pic(minimapname) == "")\r
 155                         minimapname = ""; // FAIL\r
 156                 else\r
 157                         get_mi_min_max_texcoords(0); // load new texcoords\r
 158         }\r
 159 \r
 160         mi_center = (mi_min + mi_max) * 0.5;\r
 161         mi_scale = mi_max - mi_min;\r
 162         minimapname = strzone(minimapname);\r
 163 }\r
 164 \r
 165 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)\r
 166 void CSQC_Shutdown(void)\r
 167 {\r
 168 #ifdef USE_FTE\r
 169 #pragma TARGET id\r
 170         if(!__engine_check)\r
 171                 return 0;\r
 172 #pragma TARGET fte\r
 173 #endif\r
 174 \r
 175         remove(teams);\r
 176         remove(players);\r
 177         db_close(binddb);\r
 178         db_close(tempdb);\r
 179 \r
 180         cvar_clientsettemp_restore();\r
 181 \r
 182         if(camera_active)\r
 183                 cvar_set("chase_active",ftos(chase_active_backup));\r
 184 }\r
 185 \r
 186 .float has_team;\r
 187 float SetTeam(entity o, float Team)\r
 188 {\r
 189         entity tm;\r
 190         if(Team == -1) // leave\r
 191         {\r
 192                 if(o.has_team)\r
 193                 {\r
 194                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");\r
 195                         tm = GetTeam(o.team, false);\r
 196                         tm.team_size -= 1;\r
 197                         o.has_team = 0;\r
 198                         return TRUE;\r
 199                 }\r
 200         }\r
 201         else\r
 202         {\r
 203                 if not(o.has_team)\r
 204                 {\r
 205                         //print("(CONNECT) enter team ", ftos(o.team), "\n");\r
 206                         o.team = Team;\r
 207                         tm = GetTeam(Team, true);\r
 208                         tm.team_size += 1;\r
 209                         o.has_team = 1;\r
 210                         return TRUE;\r
 211                 }\r
 212                 else if(Team != o.team)\r
 213                 {\r
 214                         //print("(CHANGE) leave team ", ftos(o.team), "\n");\r
 215                         tm = GetTeam(o.team, false);\r
 216                         tm.team_size -= 1;\r
 217                         o.team = Team;\r
 218                         //print("(CHANGE) enter team ", ftos(o.team), "\n");\r
 219                         tm = GetTeam(Team, true);\r
 220                         tm.team_size += 1;\r
 221                         return TRUE;\r
 222                 }\r
 223         }\r
 224         return FALSE;\r
 225 }\r
 226 \r
 227 void Playerchecker_Think()\r
 228 {\r
 229         float i;\r
 230         entity e;\r
 231         for(i = 0; i < maxclients; ++i)\r
 232         {\r
 233                 e = playerslots[i];\r
 234                 if(GetPlayerName(i) == "")\r
 235                 {\r
 236                         if(e.sort_prev)\r
 237                         {\r
 238                                 //print("playerchecker: KILL KILL KILL\n");\r
 239                                 // player disconnected\r
 240                                 SetTeam(e, -1);\r
 241                                 RemovePlayer(e);\r
 242                                 e.sort_prev = world;\r
 243                                 //e.gotscores = 0;\r
 244                         }\r
 245                 }\r
 246                 else\r
 247                 {\r
 248                         if not(e.sort_prev)\r
 249                         {\r
 250                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");\r
 251                                 // player connected\r
 252                                 if not(e)\r
 253                                         playerslots[i] = e = spawn();\r
 254                                 e.sv_entnum = i;\r
 255                                 //e.gotscores = 0; // we might already have the scores...\r
 256                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with Sbar_UpdatePlayerTeams\r
 257                                 RegisterPlayer(e);\r
 258                                 Sbar_UpdatePlayerPos(e);\r
 259                         }\r
 260                 }\r
 261         }\r
 262         self.nextthink = time + 0.2;\r
 263 }\r
 264 \r
 265 void Porto_Init();\r
 266 void PostInit(void)\r
 267 {\r
 268         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));\r
 269         localcmd(strcat("\nsbar_columns_set ", cvar_string("sbar_columns"), ";\n"));\r
 270 \r
 271         entity playerchecker;\r
 272         playerchecker = spawn();\r
 273         playerchecker.think = Playerchecker_Think;\r
 274         playerchecker.nextthink = time + 0.2;\r
 275 \r
 276         Porto_Init();\r
 277 \r
 278         postinit = true;\r
 279 }\r
 280 \r
 281 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function\r
 282 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.\r
 283 float button_zoom;\r
 284 void Cmd_Sbar_SetFields(float);\r
 285 void Cmd_Sbar_Help(float);\r
 286 float CSQC_ConsoleCommand(string strMessage)\r
 287 {\r
 288         float argc;\r
 289         // Tokenize String\r
 290         //argc = tokenize(strMessage);\r
 291         argc = tokenize_sane(strMessage);\r
 292         \r
 293         // Acquire Command\r
 294         local string strCmd;\r
 295         strCmd = argv(0);\r
 296 \r
 297         if(strCmd == "+button4") { // zoom\r
 298                 // return false, because the message shall be sent to the server anyway (for demos/speccing)\r
 299                 if(ignore_plus_zoom)\r
 300                 {\r
 301                         --ignore_plus_zoom;\r
 302                         return false;\r
 303                 }\r
 304                 button_zoom = 1;\r
 305                 return true;\r
 306         } else if(strCmd == "-button4") { // zoom\r
 307                 if(ignore_minus_zoom)\r
 308                 {\r
 309                         --ignore_minus_zoom;\r
 310                         return false;\r
 311                 }\r
 312                 button_zoom = 0;\r
 313                 return true;\r
 314         } else if(strCmd == "+button3") { // secondary\r
 315                 button_attack2 = 1;\r
 316                 return false;\r
 317         } else if(strCmd == "-button3") { // secondary\r
 318                 button_attack2 = 0;\r
 319                 return false;\r
 320         } else if(strCmd == "+showscores") {\r
 321                 sb_showscores = true;\r
 322                 return true;\r
 323         } else if(strCmd == "-showscores") {\r
 324                 sb_showscores = false;\r
 325                 return true;\r
 326         }\r
 327 \r
 328         if(camera_active)\r
 329         if(strCmd == "+forward" || strCmd == "-back") {\r
 330                 ++camera_direction_x;\r
 331                 return true;\r
 332         } else if(strCmd == "-forward" || strCmd == "+back") {\r
 333                 --camera_direction_x;\r
 334                 return true;\r
 335         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {\r
 336                 --camera_direction_y;\r
 337                 return true;\r
 338         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {\r
 339                 ++camera_direction_y;\r
 340                 return true;\r
 341         } else if(strCmd == "+moveup" || strCmd == "-movedown") {\r
 342                 ++camera_direction_z;\r
 343                 return true;\r
 344         } else if(strCmd == "-moveup" || strCmd == "+movedown") {\r
 345                 --camera_direction_z;\r
 346                 return true;\r
 347         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {\r
 348                 ++camera_roll;\r
 349                 return true;\r
 350         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {\r
 351                 --camera_roll;\r
 352                 return true;\r
 353         }\r
 354 \r
 355         return false;\r
 356 }\r
 357 \r
 358 .vector view_ofs;\r
 359 entity debug_shotorg;\r
 360 void ShotOrg_Draw()\r
 361 {\r
 362         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;\r
 363         self.angles = view_angles;\r
 364         self.angles_x = -self.angles_x;\r
 365         R_AddEntity(self);\r
 366 }\r
 367 \r
 368 void ShotOrg_Spawn()\r
 369 {\r
 370         debug_shotorg = spawn();\r
 371         debug_shotorg.draw = ShotOrg_Draw;\r
 372         debug_shotorg.renderflags = RF_VIEWMODEL;\r
 373         debug_shotorg.effects = EF_FULLBRIGHT;\r
 374         precache_model("models/shotorg_adjuster.md3");\r
 375         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");\r
 376         debug_shotorg.scale = 3;\r
 377         debug_shotorg.alpha = 0.8;\r
 378         debug_shotorg.view_ofs = '25 8 -8';\r
 379 }\r
 380 \r
 381 void GameCommand(string msg)\r
 382 {\r
 383         float argc;\r
 384         argc = tokenize_sane(msg);\r
 385 \r
 386         if(argv(0) == "help" || argc == 0)\r
 387         {\r
 388                 print("Usage: sv_cmd COMMAND..., where possible commands are:\n");\r
 389                 print("  settemp cvar value\n");\r
 390                 print("  radar\n");\r
 391                 print("  sbar_columns_set ...\n");\r
 392                 print("  sbar_columns_help\n");\r
 393                 GameCommand_Generic("help");\r
 394         }\r
 395 \r
 396         if(GameCommand_Generic(msg))\r
 397                 return;\r
 398 \r
 399         string cmd;\r
 400         cmd = argv(0);\r
 401         if(cmd == "mv_download") {\r
 402                 Cmd_MapVote_MapDownload(argc);\r
 403         }\r
 404         else if(cmd == "settemp") {\r
 405                 cvar_clientsettemp(argv(1), argv(2));\r
 406         }\r
 407         else if(cmd == "radar") {\r
 408                 ons_showmap = !ons_showmap;\r
 409         }\r
 410         else if(cmd == "sbar_columns_set") {\r
 411                 Cmd_Sbar_SetFields(argc);\r
 412         }\r
 413         else if(cmd == "sbar_columns_help") {\r
 414                 Cmd_Sbar_Help(argc);\r
 415         }\r
 416 #ifdef BLURTEST\r
 417         else if(cmd == "blurtest") {\r
 418                 blurtest_time0 = time;\r
 419                 blurtest_time1 = time + stof(argv(1));\r
 420                 blurtest_radius = stof(argv(2));\r
 421                 blurtest_power = stof(argv(3));\r
 422         }\r
 423 #endif\r
 424         else if(cmd == "shotorg_move") {\r
 425                 if(!debug_shotorg)\r
 426                         ShotOrg_Spawn();\r
 427                 else\r
 428                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));\r
 429                 print(vtos(debug_shotorg.view_ofs), "\n");\r
 430         }\r
 431         else if(cmd == "shotorg_movez") {\r
 432                 if(!debug_shotorg)\r
 433                         ShotOrg_Spawn();\r
 434                 else\r
 435                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos\r
 436                 print(vtos(debug_shotorg.view_ofs), "\n");\r
 437         }\r
 438         else if(cmd == "shotorg_set") {\r
 439                 if(!debug_shotorg)\r
 440                         ShotOrg_Spawn();\r
 441                 else\r
 442                         debug_shotorg.view_ofs = stov(argv(1));\r
 443                 print(vtos(debug_shotorg.view_ofs), "\n");\r
 444         }\r
 445         else if(cmd == "shotorg_setz") {\r
 446                 if(!debug_shotorg)\r
 447                         ShotOrg_Spawn();\r
 448                 else\r
 449                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos\r
 450                 print(vtos(debug_shotorg.view_ofs), "\n");\r
 451         }\r
 452         else if(cmd == "shotorg_end") {\r
 453                 if(debug_shotorg)\r
 454                 {\r
 455                         print(vtos(debug_shotorg.view_ofs), "\n");\r
 456                         remove(debug_shotorg);\r
 457                         debug_shotorg = world;\r
 458                 }\r
 459         }\r
 460         else\r
 461         {\r
 462                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");\r
 463         }\r
 464         \r
 465         return;\r
 466 }\r
 467 \r
 468 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.\r
 469 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.\r
 470 // All keys are in ascii.\r
 471 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.\r
 472 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.\r
 473 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.\r
 474 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)\r
 475 {\r
 476         local float bSkipKey;\r
 477         bSkipKey = false;\r
 478         \r
 479         if(menu_visible)\r
 480                 if(menu_action(bInputType, nPrimary, nSecondary))\r
 481                         return TRUE;\r
 482         return bSkipKey;\r
 483 }\r
 484 \r
 485 // END REQUIRED CSQC FUNCTIONS\r
 486 // --------------------------------------------------------------------------\r
 487 \r
 488 // --------------------------------------------------------------------------\r
 489 // BEGIN OPTIONAL CSQC FUNCTIONS\r
 490 void Ent_ReadEntCS()\r
 491 {\r
 492         InterpolateOrigin_Undo();\r
 493 \r
 494         self.classname = "entcs_receiver";\r
 495         self.sv_entnum = ReadByte() - 1;\r
 496         self.origin_x = ReadShort();\r
 497         self.origin_y = ReadShort();\r
 498         self.origin_z = ReadShort();\r
 499         self.angles_y = ReadByte() * 360.0 / 256;\r
 500         self.origin_z = self.angles_x = self.angles_z = 0;\r
 501 \r
 502         InterpolateOrigin_Note();\r
 503 }\r
 504 \r
 505 void Ent_Remove();\r
 506 \r
 507 void Ent_RemovePlayerScore()\r
 508 {\r
 509         float i;\r
 510 \r
 511         if(self.owner)\r
 512         {\r
 513                 SetTeam(self.owner, -1);\r
 514                 self.owner.gotscores = 0;\r
 515                 for(i = 0; i < MAX_SCORE; ++i)\r
 516                         self.owner.(scores[i]) = 0; // clear all scores\r
 517         }\r
 518 }\r
 519 \r
 520 void Ent_ReadPlayerScore()\r
 521 {\r
 522         float i, n;\r
 523         float isNew;\r
 524         entity o;\r
 525 \r
 526         // damnit -.- don't want to go change every single .sv_entnum in sbar.qc AGAIN\r
 527         // (no I've never heard of M-x replace-string, sed, or anything like that)\r
 528         isNew = !self.owner; // workaround for DP bug\r
 529         n = ReadByte()-1;\r
 530 \r
 531 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 532         if(!isNew && n != self.sv_entnum)\r
 533         {\r
 534                 print("A CSQC entity changed its owner!\n");\r
 535                 isNew = true;\r
 536                 Ent_Remove();\r
 537                 self.enttype = ENT_CLIENT_SCORES;\r
 538         }\r
 539 #endif\r
 540 \r
 541         self.sv_entnum = n;\r
 542 \r
 543         if not(playerslots[self.sv_entnum])\r
 544                 playerslots[self.sv_entnum] = spawn();\r
 545         o = self.owner = playerslots[self.sv_entnum];\r
 546         o.sv_entnum = self.sv_entnum;\r
 547         o.gotscores = 1;\r
 548 \r
 549         //if not(o.sort_prev)\r
 550         //      RegisterPlayer(o);\r
 551         //playerchecker will do this for us later, if it has not already done so\r
 552 \r
 553 #if MAX_SCORE <= 3\r
 554         for(i = 0; i < MAX_SCORE; ++i)\r
 555                 o.(scores[i]) = ReadShort();\r
 556 #else\r
 557         float sf;\r
 558 #if MAX_SCORE <= 8\r
 559         sf = ReadByte();\r
 560 #else\r
 561         sf = ReadShort();\r
 562 #endif\r
 563         float p;\r
 564         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)\r
 565                 if(sf & p)\r
 566                         o.(scores[i]) = ReadShort();\r
 567 #endif\r
 568 \r
 569         if(o.sort_prev)\r
 570                 Sbar_UpdatePlayerPos(o); // if not registered, we cannot do this yet!\r
 571         \r
 572         self.entremove = Ent_RemovePlayerScore;\r
 573 }\r
 574 \r
 575 void Ent_ReadTeamScore()\r
 576 {\r
 577         float i;\r
 578         entity o;\r
 579         \r
 580         self.team = ReadByte();\r
 581         o = self.owner = GetTeam(self.team, true);\r
 582 \r
 583 #if MAX_TEAMSCORE <= 3\r
 584         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 585                 o.(teamscores[i]) = ReadShort();\r
 586 #else\r
 587         float sf;\r
 588 #if MAX_TEAMSCORE <= 8\r
 589         sf = ReadByte();\r
 590 #else\r
 591         sf = ReadShort();\r
 592 #endif\r
 593         float p;\r
 594         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)\r
 595                 if(sf & p)\r
 596                         o.(teamscores[i]) = ReadShort();\r
 597 #endif\r
 598 \r
 599         Sbar_UpdateTeamPos(o);\r
 600 }\r
 601 \r
 602 void Net_Reset()\r
 603 {\r
 604 }\r
 605 \r
 606 void Ent_ClientData()\r
 607 {\r
 608         float f;\r
 609         float newspectatee_status;\r
 610 \r
 611         f = ReadByte();\r
 612 \r
 613         sb_showscores_force = (f & 1);\r
 614 \r
 615         if(f & 2)\r
 616         {\r
 617                 newspectatee_status = ReadByte();\r
 618                 if(newspectatee_status == player_localentnum)\r
 619                         newspectatee_status = -1; // observing\r
 620         }\r
 621         else\r
 622                 newspectatee_status = 0;\r
 623 \r
 624         spectatorbutton_zoom = (f & 4);\r
 625 \r
 626         if(f & 8)\r
 627         {\r
 628                 angles_held_status = 1;\r
 629                 angles_held_x = ReadAngle();\r
 630                 angles_held_y = ReadAngle();\r
 631                 angles_held_z = 0;\r
 632         }\r
 633         \r
 634         if(newspectatee_status != spectatee_status)\r
 635         {\r
 636                 // clear race stuff\r
 637                 race_laptime = 0;\r
 638                 race_checkpointtime = 0;\r
 639         }\r
 640         spectatee_status = newspectatee_status;\r
 641 }\r
 642 \r
 643 void Ent_Nagger()\r
 644 {\r
 645         float nags;\r
 646 \r
 647         nags = ReadByte();\r
 648 \r
 649         if(nags & 128)\r
 650         {\r
 651                 if(vote_called_vote)\r
 652                         strunzone(vote_called_vote);\r
 653                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));\r
 654         }\r
 655 \r
 656         ready_waiting = (nags & 1);\r
 657         ready_waiting_for_me = (nags & 2);\r
 658         vote_waiting = (nags & 4);\r
 659         vote_waiting_for_me = (nags & 8);\r
 660         warmup_stage = (nags & 16);\r
 661 }\r
 662 \r
 663 void Ent_RandomSeed()\r
 664 {\r
 665         float s;\r
 666         prandom_debug();\r
 667         s = ReadShort();\r
 668         psrandom(s);\r
 669 }\r
 670 \r
 671 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.\r
 672 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.\r
 673 void Ent_RadarLink();\r
 674 void Ent_Init();\r
 675 void Ent_ScoresInfo();\r
 676 void(float bIsNewEntity) CSQC_Ent_Update =\r
 677 {\r
 678         float t;\r
 679         float savetime;\r
 680         t = ReadByte();\r
 681 \r
 682         // set up the "time" global for received entities to be correct for interpolation purposes\r
 683         savetime = time;\r
 684         if(servertime)\r
 685                 time = servertime;\r
 686 \r
 687 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 688         if(self.enttype)\r
 689                 if(t != self.enttype)\r
 690                 {\r
 691                         print("A CSQC entity changed its type!\n");\r
 692                         Ent_Remove();\r
 693                 }\r
 694 #endif\r
 695         self.enttype = t;\r
 696         switch(t)\r
 697         {\r
 698                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;\r
 699                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;\r
 700                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;\r
 701                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;\r
 702                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;\r
 703                 case ENT_CLIENT_LASER: Ent_Laser(); break;\r
 704                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;\r
 705                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;\r
 706                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;\r
 707                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;\r
 708                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(); break;\r
 709                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(); break;\r
 710                 case ENT_CLIENT_CASING: Ent_Casing(); break;\r
 711                 case ENT_CLIENT_INIT: Ent_Init(); break;\r
 712                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;\r
 713                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;\r
 714                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;\r
 715                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;\r
 716                 default:\r
 717                         error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));\r
 718                         break;\r
 719         }\r
 720         \r
 721         time = savetime;\r
 722 };\r
 723 // Destructor, but does NOT deallocate the entity by calling remove(). Also\r
 724 // used when an entity changes its type. For an entity that someone interacts\r
 725 // with others, make sure it can no longer do so.\r
 726 void Ent_Remove()\r
 727 {\r
 728         if(self.entremove)\r
 729                 self.entremove();\r
 730 \r
 731         self.enttype = 0;\r
 732         self.classname = "";\r
 733         self.draw = menu_sub_null;\r
 734         self.entremove = menu_sub_null;\r
 735         // TODO possibly set more stuff to defaults\r
 736 }\r
 737 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.\r
 738 void CSQC_Ent_Remove()\r
 739 {\r
 740         if(self.enttype)\r
 741                 Ent_Remove();\r
 742         remove(self);\r
 743 }\r
 744 \r
 745 void Gamemode_Init()\r
 746 {\r
 747         if(gametype == GAME_ONSLAUGHT) {\r
 748                 print(strcat("Using ", minimapname, " as minimap.\n"));\r
 749                 precache_pic("gfx/ons-cp-neutral.tga");\r
 750                 precache_pic("gfx/ons-cp-red.tga");\r
 751                 precache_pic("gfx/ons-cp-blue.tga");\r
 752                 precache_pic("gfx/ons-frame.tga");\r
 753                 precache_pic("gfx/ons-frame-team.tga");\r
 754         } else if(gametype == GAME_KEYHUNT) {\r
 755                 precache_pic("gfx/sb_key_carrying");\r
 756                 precache_pic("gfx/sb_key_carrying_outline");\r
 757         }\r
 758 }\r
 759 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.\r
 760 void CSQC_Parse_StuffCmd(string strMessage)\r
 761 {\r
 762         localcmd(strMessage);\r
 763 }\r
 764 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.\r
 765 void CSQC_Parse_Print(string strMessage)\r
 766 {\r
 767         print(ColorTranslateRGB(strMessage));\r
 768 }\r
 769 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.  To execute standard behavior, simply execute cprint with the string.\r
 770 void CSQC_Parse_CenterPrint(string strMessage)\r
 771 {\r
 772         cprint(ColorTranslateRGB(strMessage));\r
 773 }\r
 774 \r
 775 void CSQC_CheckRevision();\r
 776 \r
 777 void Fog_Force()\r
 778 {\r
 779         // TODO somehow thwart prvm_globalset client ...\r
 780 \r
 781         if(forcefog != "")\r
 782                 localcmd(strcat("\nfog ", forcefog, "\nr_fog_exp2 0\nr_drawfog 1\n"));\r
 783 }\r
 784 \r
 785 void Gamemode_Init();\r
 786 void Ent_ScoresInfo()\r
 787 {\r
 788         float i;\r
 789         self.classname = "ent_client_scores_info";\r
 790         gametype = ReadByte();\r
 791         for(i = 0; i < MAX_SCORE; ++i)\r
 792         {\r
 793                 scores_label[i] = strzone(ReadString());\r
 794                 scores_flags[i] = ReadByte();\r
 795         }\r
 796         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 797         {\r
 798                 teamscores_label[i] = strzone(ReadString());\r
 799                 teamscores_flags[i] = ReadByte();\r
 800         }\r
 801         Sbar_InitScores();\r
 802         Gamemode_Init();\r
 803 }\r
 804 \r
 805 void Ent_Init()\r
 806 {\r
 807         float i;\r
 808         self.classname = "ent_client_init";\r
 809 \r
 810         csqc_revision = ReadShort();\r
 811 \r
 812         maxclients = ReadByte();\r
 813         for(i = 0; i < 24; ++i)\r
 814                 weaponimpulse[i] = ReadByte() - 1;\r
 815         hook_shotorigin_x = ReadCoord();\r
 816         hook_shotorigin_y = ReadCoord();\r
 817         hook_shotorigin_z = ReadCoord();\r
 818 \r
 819         if(forcefog)\r
 820                 strunzone(forcefog);\r
 821         forcefog = strzone(ReadString());\r
 822 \r
 823         CSQC_CheckRevision();\r
 824         if(!postinit)\r
 825                 PostInit();\r
 826 }\r
 827 \r
 828 string Net_ReadPicture()\r
 829 {\r
 830         string img;\r
 831         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
 832         {\r
 833                 img = ReadPicture();\r
 834                 print(strcat("Got Picture: ", img, "\n"));\r
 835         } else {\r
 836                 img = ReadString();\r
 837                 print(strcat("^3Warning: ^7Couldn't download ", img, ". This is probably because your engine build is outdated.\n"));\r
 838                 float psize, i;\r
 839                 psize = ReadShort();\r
 840                 // Can I be sure that ReadShort is 2 bytes and ReadLong is 4 bytes?\r
 841                 // Because then this could be optimized to first get all 4-byte-groups,\r
 842                 // then the remaining 2, then the remaining 1\r
 843                 for(i = 0; i < psize; ++i)\r
 844                         ReadByte();\r
 845         }\r
 846         return img;\r
 847 }\r
 848 \r
 849 void Net_ReadRace()\r
 850 {\r
 851         float b;\r
 852 \r
 853         b = ReadByte();\r
 854 \r
 855         switch(b)\r
 856         {\r
 857                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:\r
 858                         race_checkpoint = ReadByte();\r
 859                         race_time = ReadShort();\r
 860                         race_previousbesttime = ReadShort();\r
 861                         if(race_previousbestname)\r
 862                                 strunzone(race_previousbestname);\r
 863                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));\r
 864 \r
 865                         race_checkpointtime = time;\r
 866 \r
 867                         if(race_checkpoint == 0)\r
 868                                 race_laptime = time; // valid\r
 869 \r
 870                         break;\r
 871 \r
 872                 case RACE_NET_CHECKPOINT_CLEAR:\r
 873                         race_laptime = 0;\r
 874                         race_checkpointtime = 0;\r
 875                         break;\r
 876 \r
 877                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:\r
 878                         race_laptime = ReadCoord();\r
 879                         race_checkpointtime = -99999;\r
 880                         // fall through\r
 881                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:\r
 882                         race_nextcheckpoint = ReadByte();\r
 883 \r
 884                         race_nextbesttime = ReadShort();\r
 885                         if(race_nextbestname)\r
 886                                 strunzone(race_nextbestname);\r
 887                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));\r
 888                         break;\r
 889 \r
 890                 case RACE_NET_CHECKPOINT_HIT_RACE:\r
 891                         race_mycheckpoint = ReadByte();\r
 892                         race_mycheckpointtime = time;\r
 893                         race_mycheckpointdelta = ReadShort();\r
 894                         race_mycheckpointlapsdelta = ReadByte();\r
 895                         if(race_mycheckpointlapsdelta >= 128)\r
 896                                 race_mycheckpointlapsdelta -= 256;\r
 897                         if(race_mycheckpointenemy)\r
 898                                 strunzone(race_mycheckpointenemy);\r
 899                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));\r
 900                         break;\r
 901 \r
 902                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:\r
 903                         race_othercheckpoint = ReadByte();\r
 904                         race_othercheckpointtime = time;\r
 905                         race_othercheckpointdelta = ReadShort();\r
 906                         race_othercheckpointlapsdelta = ReadByte();\r
 907                         if(race_othercheckpointlapsdelta >= 128)\r
 908                                 race_othercheckpointlapsdelta -= 256;\r
 909                         if(race_othercheckpointenemy)\r
 910                                 strunzone(race_othercheckpointenemy);\r
 911                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));\r
 912                         break;\r
 913         }\r
 914 }\r
 915 \r
 916 void Net_ReadSpawn()\r
 917 {\r
 918         zoomin_effect = 1;\r
 919         current_viewzoom = 0.6;\r
 920 }\r
 921 \r
 922 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.\r
 923 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.\r
 924 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.\r
 925 float CSQC_Parse_TempEntity()\r
 926 {\r
 927         local float bHandled;\r
 928                 bHandled  = true;\r
 929         // Acquire TE ID\r
 930         local float nTEID;\r
 931                 nTEID = ReadByte();\r
 932 \r
 933                 // NOTE: Could just do return instead of break...\r
 934         switch(nTEID)\r
 935         {\r
 936                 case TE_CSQC_PICTURE:\r
 937                         Net_MapVote_Picture();\r
 938                         bHandled = true;\r
 939                         break;\r
 940                 case TE_CSQC_RACE:\r
 941                         Net_ReadRace();\r
 942                         bHandled = true;\r
 943                         break;\r
 944                 case 13: // TE_BEAM\r
 945                         Net_GrapplingHook();\r
 946                         bHandled = true;\r
 947                         break;\r
 948                 case TE_CSQC_SPAWN:\r
 949                         Net_ReadSpawn();\r
 950                         bHandled = true;\r
 951                         break;\r
 952                 default:\r
 953                         // No special logic for this temporary entity; return 0 so the engine can handle it\r
 954                         bHandled = false;\r
 955                         break;\r
 956         }\r
 957                 \r
 958         return bHandled;\r
 959 }\r
 960 \r
 961 // COMMIT-TODO: Update if necessare, before committing\r
 962 void CSQC_CheckRevision()\r
 963 {\r
 964         if(csqc_revision == CSQC_REVISION)\r
 965         {\r
 966                 print("^2SVQC and CSQC revisions are compatible.\n");\r
 967         } else if(csqc_revision < CSQC_REVISION) {\r
 968                 print("^1Your csprogs.dat (CSQC) version is newer than the one on the server.\n");\r
 969         } else if(csqc_revision > CSQC_REVISION) {\r
 970                 print("^1Your csprogs.dat (CSQC) is too old for this server.\n");\r
 971                 print("^1Please update to a newer version.\n");\r
 972         }\r
 973 }\r
 974 \r
 975 string getcommandkey(string text, string command)\r
 976 {\r
 977         string keys;\r
 978         float n, j, k, l;\r
 979 \r
 980         if (!sbar_showbinds)\r
 981                 return text;\r
 982 \r
 983         keys = db_get(binddb, command);\r
 984         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
 985         {\r
 986                 if (!keys) \r
 987                 {\r
 988                         n = tokenize_insane(findkeysforcommand(command)); // uses '...' strings\r
 989                         for(j = 0; j < n; ++j)\r
 990                         {\r
 991                                 k = stof(argv(j));\r
 992                                 if(k != -1) \r
 993                                 {\r
 994                                         if ("" == keys)\r
 995                                                 keys = keynumtostring(k);\r
 996                                         else\r
 997                                                 keys = strcat(keys, ", ", keynumtostring(k));\r
 998 \r
 999                                         ++l;\r
1000                                         if (sbar_showbinds_limit > 0 && sbar_showbinds_limit >= l) break;\r
1001                                 }\r
1002                         \r
1003                         }\r
1004                         db_put(binddb, command, keys);\r
1005                 }\r
1006         }\r
1007         \r
1008         if ("" == keys) {\r
1009                 if (sbar_showbinds > 1)\r
1010                         return strcat(text, " (not bound)");\r
1011                 else\r
1012                         return text;\r
1013         }\r
1014         else if (sbar_showbinds > 1)\r
1015                 return strcat(text, " (", keys, ")");\r
1016         else\r
1017                 return keys;\r
1018 }\r