data/qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------\r
   2 // BEGIN REQUIRED CSQC FUNCTIONS\r
   3 //include "main.qh"\r
   4 \r
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
   6 \r
   7 void() menu_show_error =\r
   8 {\r
   9         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);\r
  10 };\r
  11 \r
  12 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)\r
  13 // Useful for precaching things\r
  14 \r
  15 void() menu_sub_null =\r
  16 {\r
  17 };\r
  18 \r
  19 // let's make this a general data buffer...\r
  20 float using_gps;\r
  21 \r
  22 #ifdef USE_FTE\r
  23 float __engine_check;\r
  24 #endif\r
  25 \r
  26 string config_get(string key, string defaultvalue)\r
  27 {\r
  28         string s;\r
  29         s = db_get(configdb, strcat("/s/", key));\r
  30         if(s == "")\r
  31                 return defaultvalue;\r
  32         else\r
  33                 return db_get(configdb, strcat("/v/", key));\r
  34 }\r
  35 \r
  36 void CSQC_Init(void)\r
  37 {\r
  38 #ifdef USE_FTE\r
  39 #pragma target ID\r
  40         __engine_check = checkextension("DP_SV_WRITEPICTURE");\r
  41         if(!__engine_check)\r
  42         {\r
  43                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");\r
  44                 localcmd("\ndisconnect\n");\r
  45                 return;\r
  46         }\r
  47 #pragma target FTE\r
  48 #endif\r
  49         \r
  50         float i;\r
  51         CSQC_CheckEngine();\r
  52 \r
  53         configdb = db_create();\r
  54 \r
  55         drawfont = 0;\r
  56         menu_visible = FALSE;\r
  57         menu_show = menu_show_error;\r
  58         menu_action = menu_sub_null;\r
  59         using_gps = false;\r
  60         maxclients = 255; // we later get the real maxclients to speed up stuff\r
  61         //ctf_temp_1 = "";\r
  62         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used\r
  63         //registercmd("ctf_menu");\r
  64         registercmd("ons_map");\r
  65         //registercmd("menu_action");\r
  66         registercmd("sbar_columns_set");\r
  67         registercmd("sbar_columns_help");\r
  68 \r
  69         registercvar("sbar_usecsqc", "1");\r
  70         registercvar("sbar_columns", "default", CVAR_SAVE);\r
  71 \r
  72         gametype = 0;\r
  73 \r
  74         gps_start = world;\r
  75 \r
  76         // sbar_fields uses strunzone on the titles!\r
  77         for(i = 0; i < MAX_SBAR_FIELDS; ++i)\r
  78                 sbar_title[i] = strzone("(null)");\r
  79 \r
  80         postinit = false;\r
  81 \r
  82         teams = Sort_Spawn();\r
  83         players = Sort_Spawn();\r
  84         \r
  85         GetTeam(COLOR_SPECTATOR, true); // add specs first\r
  86 }\r
  87 \r
  88 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)\r
  89 void CSQC_Shutdown(void)\r
  90 {\r
  91 #ifdef USE_FTE\r
  92 #pragma TARGET id\r
  93         if(!__engine_check)\r
  94                 return 0;\r
  95 #pragma TARGET fte\r
  96 #endif\r
  97 \r
  98         remove(teams);\r
  99         remove(players);\r
 100         db_close(configdb);\r
 101 }\r
 102 \r
 103 .float has_team;\r
 104 float SetTeam(entity o, float Team)\r
 105 {\r
 106         entity tm;\r
 107         if(Team == -1) // leave\r
 108         {\r
 109                 if(o.has_team)\r
 110                 {\r
 111                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");\r
 112                         tm = GetTeam(o.team, false);\r
 113                         tm.team_size -= 1;\r
 114                         o.has_team = 0;\r
 115                         return TRUE;\r
 116                 }\r
 117         }\r
 118         else\r
 119         {\r
 120                 if not(o.has_team)\r
 121                 {\r
 122                         //print("(CONNECT) enter team ", ftos(o.team), "\n");\r
 123                         o.team = Team;\r
 124                         tm = GetTeam(Team, true);\r
 125                         tm.team_size += 1;\r
 126                         o.has_team = 1;\r
 127                         return TRUE;\r
 128                 }\r
 129                 else if(Team != o.team)\r
 130                 {\r
 131                         //print("(CHANGE) leave team ", ftos(o.team), "\n");\r
 132                         tm = GetTeam(o.team, false);\r
 133                         tm.team_size -= 1;\r
 134                         o.team = Team;\r
 135                         //print("(CHANGE) enter team ", ftos(o.team), "\n");\r
 136                         tm = GetTeam(Team, true);\r
 137                         tm.team_size += 1;\r
 138                         return TRUE;\r
 139                 }\r
 140         }\r
 141         return FALSE;\r
 142 }\r
 143 \r
 144 void Playerchecker_Think()\r
 145 {\r
 146         float i;\r
 147         for(i = 0; i < maxclients; ++i)\r
 148         {\r
 149                 if(getplayerkey(i, "name") == "")\r
 150                 {\r
 151                         if(playerslots[i].sort_prev)\r
 152                         {\r
 153                                 //print("playerchecker: KILL KILL KILL\n");\r
 154                                 // player disconnected\r
 155                                 SetTeam(playerslots[i], -1);\r
 156                                 RemovePlayer(playerslots[i]);\r
 157                                 playerslots[i].sort_prev = world;\r
 158                                 playerslots[i].gotscores = 0;\r
 159                         }\r
 160                 }\r
 161                 else\r
 162                 {\r
 163                         if not(playerslots[i].sort_prev)\r
 164                         {\r
 165                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");\r
 166                                 // player connected\r
 167                                 if not(playerslots[i])\r
 168                                         playerslots[i] = spawn();\r
 169                                 playerslots[i].sv_entnum = i;\r
 170                                 playerslots[i].gotscores = 0;\r
 171                                 SetTeam(playerslots[i], COLOR_SPECTATOR);\r
 172                                 RegisterPlayer(playerslots[i]);\r
 173                                 Sbar_UpdatePlayerPos(playerslots[i]);\r
 174                         }\r
 175                 }\r
 176         }\r
 177         self.nextthink = time + 0.2;\r
 178 }\r
 179 \r
 180 void PostInit(void)\r
 181 {\r
 182         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));\r
 183         localcmd(strcat("\nsbar_columns_set ", cvar_string("sbar_columns"), ";\n"));\r
 184 \r
 185         entity playerchecker;\r
 186         playerchecker = spawn();\r
 187         playerchecker.think = Playerchecker_Think;\r
 188         playerchecker.nextthink = time + 0.2;\r
 189 \r
 190         postinit = true;\r
 191 }\r
 192 \r
 193 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function\r
 194 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.\r
 195 void Cmd_Sbar_SetFields(float);\r
 196 void Cmd_Sbar_Help(float);\r
 197 float CSQC_ConsoleCommand(string strMessage)\r
 198 {\r
 199         float argc;\r
 200         // Tokenize String\r
 201         //argc = tokenize(strMessage);\r
 202         argc = tokenizebyseparator(strMessage, " ");\r
 203         \r
 204         // Acquire Command\r
 205         local string strCmd;\r
 206         strCmd = argv(0);\r
 207 \r
 208         /*if(strCmd == "ctf_menu") {\r
 209                 ctf_menu_show();\r
 210                 nReturn = true;\r
 211                 } else*/\r
 212         if(strCmd == "ons_map") {\r
 213                 Cmd_ons_map();\r
 214                 return true;\r
 215         } else if(strCmd == "sbar_columns_set") {\r
 216                 Cmd_Sbar_SetFields(argc);\r
 217                 return true;\r
 218         } else if(strCmd == "sbar_columns_help") {\r
 219                 Cmd_Sbar_Help(argc);\r
 220                 return true;\r
 221         } else if(strCmd == "+showscores") {\r
 222                 sb_showscores = true;\r
 223                 return true;\r
 224         } else if(strCmd == "-showscores") {\r
 225                 sb_showscores = false;\r
 226                 return true;\r
 227         }\r
 228         \r
 229         return false;\r
 230 }\r
 231 \r
 232 float GameCommand(string msg)\r
 233 {\r
 234         float argc;\r
 235         argc = tokenize(msg);\r
 236         string cmd;\r
 237         cmd = argv(0);\r
 238         if(cmd == "mv_download") {\r
 239                 Cmd_MapVote_MapDownload(argc);\r
 240                 return true;\r
 241         }\r
 242         \r
 243         return false;\r
 244 }\r
 245 \r
 246 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.\r
 247 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.\r
 248 // All keys are in ascii.\r
 249 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.\r
 250 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.\r
 251 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.\r
 252 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)\r
 253 {\r
 254         local float bSkipKey;\r
 255         bSkipKey = false;\r
 256         \r
 257         if(menu_visible)\r
 258                 if(menu_action(bInputType, nPrimary, nSecondary))\r
 259                         return TRUE;\r
 260         return bSkipKey;\r
 261 }\r
 262 \r
 263 // END REQUIRED CSQC FUNCTIONS\r
 264 // --------------------------------------------------------------------------\r
 265 \r
 266 // --------------------------------------------------------------------------\r
 267 // BEGIN OPTIONAL CSQC FUNCTIONS\r
 268 void Ent_ReadONS()\r
 269 {\r
 270         entity gps;\r
 271         using_gps = true;\r
 272 \r
 273         self.origin_x = ReadCoord();\r
 274         self.origin_y = ReadCoord();\r
 275         self.angles_y = ReadCoord();\r
 276         self.origin_z = self.angles_x = self.angles_z = 0;\r
 277 \r
 278         for(gps = gps_start; gps; gps = gps.chain)\r
 279         {\r
 280                 if(gps == self)\r
 281                         break;\r
 282         }\r
 283         if(!gps)\r
 284         {\r
 285                 self.chain = gps_start;\r
 286                 gps_start = self;\r
 287         }\r
 288 }\r
 289 \r
 290 void Ent_RemoveONS()\r
 291 {\r
 292         if(gps_start == self)\r
 293                 gps_start = self.chain;\r
 294         else\r
 295         {\r
 296                 local entity ent;\r
 297                 ent = gps_start;\r
 298                         \r
 299                 while(ent.chain != self && ent.chain != world)\r
 300                         ent = ent.chain;\r
 301                 if(ent.chain == self)\r
 302                         ent.chain = self.chain;\r
 303         }\r
 304 }\r
 305 \r
 306 void Ent_Remove();\r
 307 void Ent_ReadPlayerScore()\r
 308 {\r
 309         float i, Team, n;\r
 310         float isNew;\r
 311         entity o;\r
 312 \r
 313         // damnit -.- don't want to go change every single .sv_entnum in sbar.qc AGAIN\r
 314         // (no I've never heard of M-x replace-string, sed, or anything like that)\r
 315         isNew = !self.owner; // workaround for DP bug\r
 316         n = ReadByte()-1;\r
 317 \r
 318 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 319         if(!isNew && n != self.sv_entnum)\r
 320         {\r
 321                 print("A CSQC entity changed its owner!\n");\r
 322                 isNew = true;\r
 323                 Ent_Remove();\r
 324                 self.enttype = ENT_CLIENT_SCORES;\r
 325         }\r
 326 #endif\r
 327 \r
 328         self.sv_entnum = n;\r
 329         Team = GetPlayerColor(self.sv_entnum);\r
 330 \r
 331         if not(playerslots[self.sv_entnum])\r
 332                 playerslots[self.sv_entnum] = spawn();\r
 333         o = self.owner = playerslots[self.sv_entnum];\r
 334         o.sv_entnum = self.sv_entnum;\r
 335         o.gotscores = 1;\r
 336         if not(o.sort_prev)\r
 337                 RegisterPlayer(o);\r
 338 \r
 339         SetTeam(o, Team);\r
 340 \r
 341 #if MAX_SCORE <= 3\r
 342         for(i = 0; i < MAX_SCORE; ++i)\r
 343                 o.(scores[i]) = ReadShort();\r
 344 #else\r
 345         float sf;\r
 346 #if MAX_SCORE <= 8\r
 347         sf = ReadByte();\r
 348 #else\r
 349         sf = ReadShort();\r
 350 #endif\r
 351         float p;\r
 352         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)\r
 353                 if(sf & p)\r
 354                         o.(scores[i]) = ReadShort();\r
 355 #endif\r
 356 \r
 357         Sbar_UpdatePlayerPos(o);\r
 358 }\r
 359 \r
 360 void Ent_ReadTeamScore()\r
 361 {\r
 362         float i;\r
 363         entity o;\r
 364         \r
 365         self.team = ReadByte();\r
 366         o = self.owner = GetTeam(self.team, true);\r
 367 \r
 368 #if MAX_TEAMSCORE <= 3\r
 369         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 370                 o.(teamscores[i]) = ReadShort();\r
 371 #else\r
 372         float sf;\r
 373 #if MAX_TEAMSCORE <= 8\r
 374         sf = ReadByte();\r
 375 #else\r
 376         sf = ReadShort();\r
 377 #endif\r
 378         float p;\r
 379         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)\r
 380                 if(sf & p)\r
 381                         o.(teamscores[i]) = ReadShort();\r
 382 #endif\r
 383 \r
 384         Sbar_UpdateTeamPos(o);\r
 385 }\r
 386 \r
 387 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.\r
 388 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.\r
 389 void(float bIsNewEntity) CSQC_Ent_Update =\r
 390 {\r
 391         float msg, t;\r
 392         t = ReadByte();\r
 393 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 394         if(self.enttype)\r
 395                 if(t != self.enttype)\r
 396                 {\r
 397                         print("A CSQC entity changed its type!\n");\r
 398                         Ent_Remove();\r
 399                 }\r
 400 #endif\r
 401         self.enttype = t;\r
 402         if(self.enttype == ENT_CLIENT_ENTCS)\r
 403         {\r
 404                 self.sv_entnum = ReadByte()-1;\r
 405 \r
 406                 for(msg = ReadByte(); msg != ENTCS_MSG_END; msg = ReadByte())\r
 407                 {\r
 408                         switch(msg)\r
 409                         {\r
 410                         case ENTCS_MSG_ONS_GPS: Ent_ReadONS(); break;\r
 411                         case ENTCS_MSG_ONS_REMOVE: Ent_RemoveONS(); break;\r
 412                         default:\r
 413                                 error("unknown ENTCS_MSG type\n");\r
 414                         }\r
 415                 }\r
 416         }\r
 417         else if(self.enttype == ENT_CLIENT_SCORES)\r
 418                 Ent_ReadPlayerScore();\r
 419         else if(self.enttype == ENT_CLIENT_TEAMSCORES)\r
 420                 Ent_ReadTeamScore();\r
 421         else\r
 422                 error("unknown entity type in CSQC_Ent_Update\n");\r
 423         \r
 424 };\r
 425 // Destructor, but does NOT deallocate the entity by calling remove(). Also\r
 426 // used when an entity changes its type. For an entity that someone interacts\r
 427 // with others, make sure it can no longer do so.\r
 428 void Ent_Remove()\r
 429 {\r
 430         if(self.enttype == ENT_CLIENT_ENTCS)\r
 431         {\r
 432                 if(using_gps) //gametype == GAME_ONSLAUGHT)\r
 433                 {\r
 434                         if(gps_start == self)\r
 435                                 gps_start = self.chain;\r
 436                         else\r
 437                         {\r
 438                                 local entity ent;\r
 439                                 ent = gps_start;\r
 440                         \r
 441                                 while(ent.chain != self && ent.chain != world)\r
 442                                         ent = ent.chain;\r
 443                                 if(ent.chain == self)\r
 444                                         ent.chain = self.chain;\r
 445                         }\r
 446                 }\r
 447         } else if(self.enttype == ENT_CLIENT_SCORES)\r
 448         {\r
 449                 if(self.owner)\r
 450                 {\r
 451                         SetTeam(self.owner, -1);\r
 452                         if(self.owner.sort_prev)\r
 453                                 RemovePlayer(self.owner);\r
 454                         self.owner.sort_prev = NULL;\r
 455                 }\r
 456         } else if(self.enttype == ENT_CLIENT_TEAMSCORES)\r
 457         {\r
 458                 /*\r
 459                 if(self.owner)\r
 460                         RemoveTeam(self.owner);\r
 461                 */\r
 462                 // we don't NEED to remove them... they won't display anyway\r
 463                 // plus, svqc never does this anyway\r
 464         }\r
 465 \r
 466         self.enttype = 0;\r
 467         self.classname = "";\r
 468         // TODO possibly set more stuff to defaults\r
 469 }\r
 470 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.\r
 471 void CSQC_Ent_Remove()\r
 472 {\r
 473         if(self.enttype)\r
 474                 Ent_Remove();\r
 475         remove(self);\r
 476 }\r
 477 \r
 478 void Gamemode_Init()\r
 479 {\r
 480         local string mapinfo, infoline;\r
 481         local float len;\r
 482         local float file;\r
 483         local vector mi_min, mi_max;\r
 484 \r
 485         if(!strcasecmp(substring(mapname, 0, 5), "maps/"))\r
 486                 shortmapname = substring(mapname, 5, 999);\r
 487         else\r
 488                 shortmapname = mapname;\r
 489         len = strlen(shortmapname);\r
 490         if(!strcasecmp(substring(shortmapname, len-4, 4), ".bsp"))\r
 491                 shortmapname = substring(shortmapname, 0, len-4);\r
 492         shortmapname = strzone(shortmapname);\r
 493 \r
 494         if(gametype == GAME_ONSLAUGHT) {\r
 495                 mapinfo = strcat("maps/", minimapname, ".info");\r
 496                 minimapname = strzone(strcat("gfx/", shortmapname, "_mini.tga"));\r
 497 \r
 498                 mi_min = world.mins;\r
 499                 mi_max = world.maxs;\r
 500                 \r
 501                 file = fopen(mapinfo, FILE_READ);\r
 502                 if(file >= 0) {\r
 503                         while((infoline = fgets(file))) {\r
 504                                 if(!strncasecmp(infoline, "mins", 4)) {\r
 505                                         mi_min = stov(substring(infoline, 5, 999));\r
 506                                 } else if(!strncasecmp(infoline, "maxs", 4)) {\r
 507                                         mi_max = stov(substring(infoline, 5, 999));\r
 508                                 } else if(strncasecmp(infoline, "//", 2)) { // don't print comment-style lines\r
 509                                         print(strcat("mapinfo: ", infoline, "\n"));\r
 510                                 }\r
 511                         }\r
 512                 } else {\r
 513                         print(strcat("Map has no .info file (", mapinfo, ").\n"));\r
 514                 }\r
 515                 fclose(file);\r
 516 \r
 517                 print(strcat("Mins: ", vtos(mi_min), "    Maxs: ", vtos(mi_max), "\n"));\r
 518                 \r
 519                 mi_center = (mi_min + mi_max) * 0.5;\r
 520                 mi_scale = mi_max - mi_min;\r
 521                 \r
 522                 \r
 523                 print(strcat("Using ", minimapname, " as minimap.\n"));\r
 524                 precache_pic(minimapname);\r
 525                 precache_pic("gfx/ons-cp-neutral.tga");\r
 526                 precache_pic("gfx/ons-cp-red.tga");\r
 527                 precache_pic("gfx/ons-cp-blue.tga");\r
 528                 precache_pic("gfx/ons-frame.tga");\r
 529                 precache_pic("gfx/ons-frame-team.tga");\r
 530         } else if(gametype == GAME_KEYHUNT) {\r
 531                 precache_pic("gfx/sb_key_carrying");\r
 532                 precache_pic("gfx/sb_key_carrying_outline");\r
 533         }\r
 534 }\r
 535 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.\r
 536 void CSQC_Parse_StuffCmd(string strMessage)\r
 537 {\r
 538         localcmd(strMessage);\r
 539 }\r
 540 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.\r
 541 void CSQC_Parse_Print(string strMessage)\r
 542 {\r
 543         print(strMessage);\r
 544 }\r
 545 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.  To execute standard behavior, simply execute cprint with the string.\r
 546 void CSQC_Parse_CenterPrint(string strMessage)\r
 547 {\r
 548         cprint(strMessage);\r
 549 }\r
 550 \r
 551 void CSQC_CheckRevision();\r
 552 \r
 553 void Gamemode_Init();\r
 554 void Net_ReadScoresInfo()\r
 555 {\r
 556         float i;\r
 557         gametype = ReadByte();\r
 558         for(i = 0; i < MAX_SCORE; ++i)\r
 559         {\r
 560                 scores_label[i] = strzone(ReadString());\r
 561                 scores_flags[i] = ReadByte();\r
 562         }\r
 563         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 564         {\r
 565                 teamscores_label[i] = strzone(ReadString());\r
 566                 teamscores_flags[i] = ReadByte();\r
 567         }\r
 568         Sbar_InitScores();\r
 569         Gamemode_Init();\r
 570 }\r
 571 \r
 572 void Net_ReadInit()\r
 573 {\r
 574         csqc_revision = ReadShort();\r
 575         maxclients = ReadByte();\r
 576 \r
 577         CSQC_CheckRevision();\r
 578 }\r
 579 \r
 580 string Net_ReadPicture()\r
 581 {\r
 582         string img;\r
 583         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
 584         {\r
 585                 img = ReadPicture();\r
 586                 print(strcat("Got Picture: ", img, "\n"));\r
 587         } else {\r
 588                 img = ReadString();\r
 589                 print(strcat("^3Warning: ^7Couldn't download ", img, ". This is probably because your engine build is outdated.\n"));\r
 590                 float psize, i;\r
 591                 psize = ReadShort();\r
 592                 // Can I be sure that ReadShort is 2 bytes and ReadLong is 4 bytes?\r
 593                 // Because then this could be optimized to first get all 4-byte-groups,\r
 594                 // then the remaining 2, then the remaining 1\r
 595                 for(i = 0; i < psize; ++i)\r
 596                         ReadByte();\r
 597         }\r
 598         return img;\r
 599 }\r
 600 \r
 601 void Net_Config()\r
 602 {\r
 603         string key, value;\r
 604         key = ReadString();\r
 605         value = ReadString();\r
 606         db_put(configdb, strcat("/v/", key), value);\r
 607         db_put(configdb, strcat("/s/", key), "1");\r
 608 }\r
 609 \r
 610 void Net_ReadRace()\r
 611 {\r
 612         float b;\r
 613 \r
 614         b = ReadByte();\r
 615 \r
 616         switch(b)\r
 617         {\r
 618                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:\r
 619                         race_checkpoint = ReadByte();\r
 620                         race_time = ReadShort();\r
 621                         race_previousbesttime = ReadShort();\r
 622                         if(race_previousbestname)\r
 623                                 strunzone(race_previousbestname);\r
 624                         race_previousbestname = strzone(ReadString());\r
 625 \r
 626                         race_checkpointtime = time;\r
 627 \r
 628                         if(race_checkpoint == 0)\r
 629                                 race_laptime = time; // valid\r
 630 \r
 631                         break;\r
 632 \r
 633                 case RACE_NET_CHECKPOINT_CLEAR:\r
 634                         race_laptime = 0;\r
 635                         race_checkpointtime = 0;\r
 636                         break;\r
 637 \r
 638                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:\r
 639                         race_laptime = ReadCoord();\r
 640                         race_checkpointtime = -99999;\r
 641                         // fall through\r
 642                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:\r
 643                         race_nextcheckpoint = ReadByte();\r
 644 \r
 645                         race_nextbesttime = ReadShort();\r
 646                         if(race_nextbestname)\r
 647                                 strunzone(race_nextbestname);\r
 648                         race_nextbestname = strzone(ReadString());\r
 649                         break;\r
 650 \r
 651                 case RACE_NET_CHECKPOINT_HIT_RACE:\r
 652                         race_mycheckpoint = ReadByte();\r
 653                         race_mycheckpointtime = time;\r
 654                         race_mycheckpointdelta = ReadShort();\r
 655                         race_mycheckpointlapsdelta = ReadByte();\r
 656                         if(race_mycheckpointlapsdelta >= 128)\r
 657                                 race_mycheckpointlapsdelta -= 256;\r
 658                         if(race_mycheckpointenemy)\r
 659                                 strunzone(race_mycheckpointenemy);\r
 660                         race_mycheckpointenemy = strzone(ReadString());\r
 661                         break;\r
 662 \r
 663                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:\r
 664                         race_othercheckpoint = ReadByte();\r
 665                         race_othercheckpointtime = time;\r
 666                         race_othercheckpointdelta = ReadShort();\r
 667                         race_othercheckpointlapsdelta = ReadByte();\r
 668                         if(race_othercheckpointlapsdelta >= 128)\r
 669                                 race_othercheckpointlapsdelta -= 256;\r
 670                         if(race_othercheckpointenemy)\r
 671                                 strunzone(race_othercheckpointenemy);\r
 672                         race_othercheckpointenemy = strzone(ReadString());\r
 673                         break;\r
 674         }\r
 675 }\r
 676 \r
 677 void Net_ReadForceScoreboard()\r
 678 {\r
 679         sb_showscores_force = ReadByte();\r
 680 }\r
 681 \r
 682 void Net_Reset()\r
 683 {\r
 684         race_laptime = 0;\r
 685         race_checkpointtime = 0;\r
 686 }\r
 687 \r
 688 void Net_ReadSpectating()\r
 689 {\r
 690         float newspectatee_status;\r
 691         newspectatee_status = ReadByte();\r
 692         if(newspectatee_status == player_localentnum)\r
 693                 newspectatee_status = -1; // observing\r
 694         if(newspectatee_status != spectatee_status)\r
 695                 Net_Reset();\r
 696         spectatee_status = newspectatee_status;\r
 697 }\r
 698 \r
 699 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.\r
 700 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.\r
 701 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.\r
 702 float CSQC_Parse_TempEntity()\r
 703 {\r
 704         local float bHandled;\r
 705                 bHandled  = true;\r
 706         // Acquire TE ID\r
 707         local float nTEID;\r
 708                 nTEID = ReadByte();\r
 709 \r
 710                 // NOTE: Could just do return instead of break...\r
 711         switch(nTEID)\r
 712         {\r
 713                 case TE_CSQC_INIT:\r
 714                         Net_ReadInit();\r
 715                         bHandled = true;\r
 716                         break;\r
 717                 case TE_CSQC_MAPVOTE:\r
 718                         Net_Mapvote();\r
 719                         bHandled = true;\r
 720                         break;\r
 721                 case TE_CSQC_CONFIG:\r
 722                         Net_Config();\r
 723                         bHandled = true;\r
 724                         break;\r
 725                 case TE_CSQC_SCORESINFO:\r
 726                         Net_ReadScoresInfo();\r
 727                         bHandled = true;\r
 728                         break;\r
 729                 case TE_CSQC_RACE:\r
 730                         Net_ReadRace();\r
 731                         bHandled = true;\r
 732                         break;\r
 733                 case TE_CSQC_FORCESCOREBOARD:\r
 734                         Net_ReadForceScoreboard();\r
 735                         bHandled = true;\r
 736                         break;\r
 737                 case TE_CSQC_SPECTATING:\r
 738                         Net_ReadSpectating();\r
 739                         bHandled = true;\r
 740                         break;\r
 741                 default:\r
 742                         // No special logic for this temporary entity; return 0 so the engine can handle it\r
 743                         bHandled = false;\r
 744                         break;\r
 745         }\r
 746         \r
 747         if(!postinit)\r
 748                 PostInit();\r
 749                 \r
 750         return bHandled;\r
 751 }\r
 752 \r
 753 // COMMIT-TODO: Update if necessare, before committing\r
 754 void CSQC_CheckRevision()\r
 755 {\r
 756         if(csqc_revision == CSQC_REVISION)\r
 757         {\r
 758                 print("^2SVQC and CSQC revisions are compatible.\n");\r
 759         } else if(csqc_revision < CSQC_REVISION) {\r
 760                 print("^1Your csprogs.dat (CSQC) version is newer than the one on the server.\n");\r
 761         } else if(csqc_revision > CSQC_REVISION) {\r
 762                 print("^1Your csprogs.dat (CSQC) is too old for this server.\n");\r
 763                 print("^1Please update to a newer version.\n");\r
 764         }\r
 765 }\r