data/qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------\r
   2 // BEGIN REQUIRED CSQC FUNCTIONS\r
   3 //include "main.qh"\r
   4 \r
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
   6 \r
   7 void cvar_clientsettemp(string cv, string val)\r
   8 {\r
   9         entity e;\r
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  11                 if(e.netname == cv)\r
  12                         goto saved;\r
  13         e = spawn();\r
  14         e.classname = "saved_cvar_value";\r
  15         e.netname = strzone(cv);\r
  16         e.message = strzone(cvar_string(cv));\r
  17 :saved\r
  18         cvar_set(cv, val);\r
  19 }\r
  20 \r
  21 void cvar_clientsettemp_restore()\r
  22 {\r
  23         entity e;\r
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  25                         cvar_set(e.netname, e.message);\r
  26 }\r
  27 \r
  28 void() menu_show_error =\r
  29 {\r
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);\r
  31 };\r
  32 \r
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)\r
  34 // Useful for precaching things\r
  35 \r
  36 void() menu_sub_null =\r
  37 {\r
  38 };\r
  39 \r
  40 #ifdef USE_FTE\r
  41 float __engine_check;\r
  42 #endif\r
  43 \r
  44 string forcefog;\r
  45 void WaypointSprite_Load();\r
  46 void CSQC_Init(void)\r
  47 {\r
  48 #ifdef USE_FTE\r
  49 #pragma target ID\r
  50         __engine_check = checkextension("DP_SV_WRITEPICTURE");\r
  51         if(!__engine_check)\r
  52         {\r
  53                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");\r
  54                 localcmd("\ndisconnect\n");\r
  55                 return;\r
  56         }\r
  57 #pragma target FTE\r
  58 #endif\r
  59         \r
  60         float i;\r
  61         CSQC_CheckEngine();\r
  62         dprint_load();\r
  63 \r
  64         binddb = db_create();\r
  65         tempdb = db_create();\r
  66         compressShortVector_init();\r
  67 \r
  68         drawfont = 0;\r
  69         menu_visible = FALSE;\r
  70         menu_show = menu_show_error;\r
  71         menu_action = menu_sub_null;\r
  72         maxclients = 255; // we later get the real maxclients to speed up stuff\r
  73         //ctf_temp_1 = "";\r
  74         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used\r
  75         //registercmd("ctf_menu");\r
  76         registercmd("ons_map");\r
  77         //registercmd("menu_action");\r
  78         registercmd("sbar_columns_set");\r
  79         registercmd("sbar_columns_help");\r
  80 \r
  81         registercmd("+button3");\r
  82         registercmd("-button3");\r
  83         registercmd("+button4");\r
  84         registercmd("-button4");\r
  85 \r
  86 #ifndef CAMERATEST\r
  87         if(isdemo())\r
  88         {\r
  89 #endif\r
  90                 registercmd("+forward");registercmd("-forward");\r
  91                 registercmd("+back");registercmd("-back");\r
  92                 registercmd("+moveup");registercmd("-moveup");\r
  93                 registercmd("+movedown");registercmd("-movedown");\r
  94                 registercmd("+moveright");registercmd("-moveright");\r
  95                 registercmd("+moveleft");registercmd("-moveleft");\r
  96                 registercmd("+roll_right");registercmd("-roll_right");\r
  97                 registercmd("+roll_left");registercmd("-roll_left");\r
  98 #ifndef CAMERATEST\r
  99         }\r
 100 #endif\r
 101         registercvar("sbar_usecsqc", "1");\r
 102         registercvar("sbar_columns", "default", CVAR_SAVE);\r
 103 \r
 104         gametype = 0;\r
 105 \r
 106         // sbar_fields uses strunzone on the titles!\r
 107         for(i = 0; i < MAX_SBAR_FIELDS; ++i)\r
 108                 sbar_title[i] = strzone("(null)");\r
 109 \r
 110         postinit = false;\r
 111 \r
 112         teams = Sort_Spawn();\r
 113         players = Sort_Spawn();\r
 114         \r
 115         GetTeam(COLOR_SPECTATOR, true); // add specs first\r
 116 \r
 117         cvar_clientsettemp("_supports_weaponpriority", "1");\r
 118 \r
 119 \r
 120 \r
 121 \r
 122         cs_project_is_b0rked = TRUE;\r
 123         R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');\r
 124         R_SetView(VF_FOV, '90 90 0');\r
 125         R_SetView(VF_ORIGIN, '0 0 0');\r
 126         R_SetView(VF_ANGLES, '0 0 0');\r
 127         R_SetView(VF_PERSPECTIVE, 1);\r
 128         makevectors('0 0 0');\r
 129         vector v;\r
 130         v = cs_project(v_forward);\r
 131         if(v_x - 320 < +1)\r
 132         if(v_x - 320 > -1)\r
 133         if(v_y - 240 < +1)\r
 134         if(v_y - 240 > -1)\r
 135                 cs_project_is_b0rked = FALSE;\r
 136 \r
 137         RegisterWeapons();\r
 138 \r
 139         WaypointSprite_Load();\r
 140 \r
 141         Projectile_Precache();\r
 142         GibSplash_Precache();\r
 143         Casings_Precache();\r
 144         DamageInfo_Precache();\r
 145 \r
 146         get_mi_min_max_texcoords(1); // try the CLEVER way first\r
 147         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");\r
 148         shortmapname = mi_shortname;\r
 149 \r
 150         if(precache_pic(minimapname) == "")\r
 151         {\r
 152                 // but maybe we have a non-clever minimap\r
 153                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");\r
 154                 if(precache_pic(minimapname) == "")\r
 155                         minimapname = ""; // FAIL\r
 156                 else\r
 157                         get_mi_min_max_texcoords(0); // load new texcoords\r
 158         }\r
 159 \r
 160         mi_center = (mi_min + mi_max) * 0.5;\r
 161         mi_scale = mi_max - mi_min;\r
 162         minimapname = strzone(minimapname);\r
 163 }\r
 164 \r
 165 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)\r
 166 void CSQC_Shutdown(void)\r
 167 {\r
 168 #ifdef USE_FTE\r
 169 #pragma TARGET id\r
 170         if(!__engine_check)\r
 171                 return 0;\r
 172 #pragma TARGET fte\r
 173 #endif\r
 174 \r
 175         remove(teams);\r
 176         remove(players);\r
 177         db_close(binddb);\r
 178         db_close(tempdb);\r
 179 \r
 180         cvar_clientsettemp_restore();\r
 181 \r
 182         if(camera_active)\r
 183                 cvar_set("chase_active",ftos(chase_active_backup));\r
 184 }\r
 185 \r
 186 .float has_team;\r
 187 float SetTeam(entity o, float Team)\r
 188 {\r
 189         entity tm;\r
 190         if(Team == -1) // leave\r
 191         {\r
 192                 if(o.has_team)\r
 193                 {\r
 194                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");\r
 195                         tm = GetTeam(o.team, false);\r
 196                         tm.team_size -= 1;\r
 197                         o.has_team = 0;\r
 198                         return TRUE;\r
 199                 }\r
 200         }\r
 201         else\r
 202         {\r
 203                 if not(o.has_team)\r
 204                 {\r
 205                         //print("(CONNECT) enter team ", ftos(o.team), "\n");\r
 206                         o.team = Team;\r
 207                         tm = GetTeam(Team, true);\r
 208                         tm.team_size += 1;\r
 209                         o.has_team = 1;\r
 210                         return TRUE;\r
 211                 }\r
 212                 else if(Team != o.team)\r
 213                 {\r
 214                         //print("(CHANGE) leave team ", ftos(o.team), "\n");\r
 215                         tm = GetTeam(o.team, false);\r
 216                         tm.team_size -= 1;\r
 217                         o.team = Team;\r
 218                         //print("(CHANGE) enter team ", ftos(o.team), "\n");\r
 219                         tm = GetTeam(Team, true);\r
 220                         tm.team_size += 1;\r
 221                         return TRUE;\r
 222                 }\r
 223         }\r
 224         return FALSE;\r
 225 }\r
 226 \r
 227 void Playerchecker_Think()\r
 228 {\r
 229         float i;\r
 230         entity e;\r
 231         for(i = 0; i < maxclients; ++i)\r
 232         {\r
 233                 e = playerslots[i];\r
 234                 if(GetPlayerName(i) == "")\r
 235                 {\r
 236                         if(e.sort_prev)\r
 237                         {\r
 238                                 //print("playerchecker: KILL KILL KILL\n");\r
 239                                 // player disconnected\r
 240                                 SetTeam(e, -1);\r
 241                                 RemovePlayer(e);\r
 242                                 e.sort_prev = world;\r
 243                                 //e.gotscores = 0;\r
 244                         }\r
 245                 }\r
 246                 else\r
 247                 {\r
 248                         if not(e.sort_prev)\r
 249                         {\r
 250                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");\r
 251                                 // player connected\r
 252                                 if not(e)\r
 253                                         playerslots[i] = e = spawn();\r
 254                                 e.sv_entnum = i;\r
 255                                 //e.gotscores = 0; // we might already have the scores...\r
 256                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with Sbar_UpdatePlayerTeams\r
 257                                 RegisterPlayer(e);\r
 258                                 Sbar_UpdatePlayerPos(e);\r
 259                         }\r
 260                 }\r
 261         }\r
 262         self.nextthink = time + 0.2;\r
 263 }\r
 264 \r
 265 void Porto_Init();\r
 266 void PostInit(void)\r
 267 {\r
 268         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));\r
 269         localcmd(strcat("\nsbar_columns_set ", cvar_string("sbar_columns"), ";\n"));\r
 270 \r
 271         entity playerchecker;\r
 272         playerchecker = spawn();\r
 273         playerchecker.think = Playerchecker_Think;\r
 274         playerchecker.nextthink = time + 0.2;\r
 275 \r
 276         Porto_Init();\r
 277 \r
 278         postinit = true;\r
 279 }\r
 280 \r
 281 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function\r
 282 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.\r
 283 float button_zoom;\r
 284 void Cmd_Sbar_SetFields(float);\r
 285 void Cmd_Sbar_Help(float);\r
 286 float CSQC_ConsoleCommand(string strMessage)\r
 287 {\r
 288         float argc;\r
 289         // Tokenize String\r
 290         //argc = tokenize(strMessage);\r
 291         argc = tokenize_sane(strMessage);\r
 292         \r
 293         // Acquire Command\r
 294         local string strCmd;\r
 295         strCmd = argv(0);\r
 296 \r
 297         if(strCmd == "+button4") { // zoom\r
 298                 // return false, because the message shall be sent to the server anyway (for demos/speccing)\r
 299                 if(ignore_plus_zoom)\r
 300                 {\r
 301                         --ignore_plus_zoom;\r
 302                         return false;\r
 303                 }\r
 304                 button_zoom = 1;\r
 305                 return true;\r
 306         } else if(strCmd == "-button4") { // zoom\r
 307                 if(ignore_minus_zoom)\r
 308                 {\r
 309                         --ignore_minus_zoom;\r
 310                         return false;\r
 311                 }\r
 312                 button_zoom = 0;\r
 313                 return true;\r
 314         } else if(strCmd == "+button3") { // secondary\r
 315                 button_attack2 = 1;\r
 316                 return false;\r
 317         } else if(strCmd == "-button3") { // secondary\r
 318                 button_attack2 = 0;\r
 319                 return false;\r
 320         } else if(strCmd == "+showscores") {\r
 321                 sb_showscores = true;\r
 322                 return true;\r
 323         } else if(strCmd == "-showscores") {\r
 324                 sb_showscores = false;\r
 325                 return true;\r
 326         }\r
 327 \r
 328         if(camera_active)\r
 329         if(strCmd == "+forward" || strCmd == "-back") {\r
 330                 ++camera_direction_x;\r
 331                 return true;\r
 332         } else if(strCmd == "-forward" || strCmd == "+back") {\r
 333                 --camera_direction_x;\r
 334                 return true;\r
 335         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {\r
 336                 --camera_direction_y;\r
 337                 return true;\r
 338         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {\r
 339                 ++camera_direction_y;\r
 340                 return true;\r
 341         } else if(strCmd == "+moveup" || strCmd == "-movedown") {\r
 342                 ++camera_direction_z;\r
 343                 return true;\r
 344         } else if(strCmd == "-moveup" || strCmd == "+movedown") {\r
 345                 --camera_direction_z;\r
 346                 return true;\r
 347         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {\r
 348                 ++camera_roll;\r
 349                 return true;\r
 350         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {\r
 351                 --camera_roll;\r
 352                 return true;\r
 353         }\r
 354 \r
 355         return false;\r
 356 }\r
 357 \r
 358 .vector view_ofs;\r
 359 entity debug_shotorg;\r
 360 void ShotOrg_Draw()\r
 361 {\r
 362         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;\r
 363         self.angles = view_angles;\r
 364         self.angles_x = -self.angles_x;\r
 365         R_AddEntity(self);\r
 366 }\r
 367 \r
 368 void ShotOrg_Spawn()\r
 369 {\r
 370         debug_shotorg = spawn();\r
 371         debug_shotorg.draw = ShotOrg_Draw;\r
 372         debug_shotorg.renderflags = RF_VIEWMODEL;\r
 373         debug_shotorg.effects = EF_FULLBRIGHT;\r
 374         precache_model("models/shotorg_adjuster.md3");\r
 375         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");\r
 376         debug_shotorg.scale = 4;\r
 377         debug_shotorg.view_ofs = '25 8 -8';\r
 378 }\r
 379 \r
 380 void GameCommand(string msg)\r
 381 {\r
 382         float argc;\r
 383         argc = tokenize_sane(msg);\r
 384 \r
 385         if(argv(0) == "help" || argc == 0)\r
 386         {\r
 387                 print("Usage: sv_cmd COMMAND..., where possible commands are:\n");\r
 388                 print("  settemp cvar value\n");\r
 389                 print("  radar\n");\r
 390                 print("  sbar_columns_set ...\n");\r
 391                 print("  sbar_columns_help\n");\r
 392                 GameCommand_Generic("help");\r
 393         }\r
 394 \r
 395         if(GameCommand_Generic(msg))\r
 396                 return;\r
 397 \r
 398         string cmd;\r
 399         cmd = argv(0);\r
 400         if(cmd == "mv_download") {\r
 401                 Cmd_MapVote_MapDownload(argc);\r
 402         }\r
 403         else if(cmd == "settemp") {\r
 404                 cvar_clientsettemp(argv(1), argv(2));\r
 405         }\r
 406         else if(cmd == "radar") {\r
 407                 ons_showmap = !ons_showmap;\r
 408         }\r
 409         else if(cmd == "sbar_columns_set") {\r
 410                 Cmd_Sbar_SetFields(argc);\r
 411         }\r
 412         else if(cmd == "sbar_columns_help") {\r
 413                 Cmd_Sbar_Help(argc);\r
 414         }\r
 415 #ifdef BLURTEST\r
 416         else if(cmd == "blurtest") {\r
 417                 blurtest_time0 = time;\r
 418                 blurtest_time1 = time + stof(argv(1));\r
 419                 blurtest_radius = stof(argv(2));\r
 420                 blurtest_power = stof(argv(3));\r
 421         }\r
 422 #endif\r
 423         else if(cmd == "shotorg_move") {\r
 424                 if(!debug_shotorg)\r
 425                         ShotOrg_Spawn();\r
 426                 else\r
 427                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));\r
 428                 print(vtos(debug_shotorg.view_ofs), "\n");\r
 429         }\r
 430         else if(cmd == "shotorg_movez") {\r
 431                 if(!debug_shotorg)\r
 432                         ShotOrg_Spawn();\r
 433                 else\r
 434                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos\r
 435                 print(vtos(debug_shotorg.view_ofs), "\n");\r
 436         }\r
 437         else if(cmd == "shotorg_set") {\r
 438                 if(!debug_shotorg)\r
 439                         ShotOrg_Spawn();\r
 440                 else\r
 441                         debug_shotorg.view_ofs = stov(argv(1));\r
 442                 print(vtos(debug_shotorg.view_ofs), "\n");\r
 443         }\r
 444         else if(cmd == "shotorg_setz") {\r
 445                 if(!debug_shotorg)\r
 446                         ShotOrg_Spawn();\r
 447                 else\r
 448                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos\r
 449                 print(vtos(debug_shotorg.view_ofs), "\n");\r
 450         }\r
 451         else if(cmd == "shotorg_end") {\r
 452                 if(debug_shotorg)\r
 453                 {\r
 454                         print(vtos(debug_shotorg.view_ofs), "\n");\r
 455                         remove(debug_shotorg);\r
 456                         debug_shotorg = world;\r
 457                 }\r
 458         }\r
 459         else\r
 460         {\r
 461                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");\r
 462         }\r
 463         \r
 464         return;\r
 465 }\r
 466 \r
 467 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.\r
 468 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.\r
 469 // All keys are in ascii.\r
 470 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.\r
 471 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.\r
 472 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.\r
 473 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)\r
 474 {\r
 475         local float bSkipKey;\r
 476         bSkipKey = false;\r
 477         \r
 478         if(menu_visible)\r
 479                 if(menu_action(bInputType, nPrimary, nSecondary))\r
 480                         return TRUE;\r
 481         return bSkipKey;\r
 482 }\r
 483 \r
 484 // END REQUIRED CSQC FUNCTIONS\r
 485 // --------------------------------------------------------------------------\r
 486 \r
 487 // --------------------------------------------------------------------------\r
 488 // BEGIN OPTIONAL CSQC FUNCTIONS\r
 489 void Ent_ReadEntCS()\r
 490 {\r
 491         InterpolateOrigin_Undo();\r
 492 \r
 493         self.classname = "entcs_receiver";\r
 494         self.sv_entnum = ReadByte() - 1;\r
 495         self.origin_x = ReadShort();\r
 496         self.origin_y = ReadShort();\r
 497         self.origin_z = ReadShort();\r
 498         self.angles_y = ReadByte() * 360.0 / 256;\r
 499         self.origin_z = self.angles_x = self.angles_z = 0;\r
 500 \r
 501         InterpolateOrigin_Note();\r
 502 }\r
 503 \r
 504 void Ent_Remove();\r
 505 \r
 506 void Ent_RemovePlayerScore()\r
 507 {\r
 508         float i;\r
 509 \r
 510         if(self.owner)\r
 511         {\r
 512                 SetTeam(self.owner, -1);\r
 513                 self.owner.gotscores = 0;\r
 514                 for(i = 0; i < MAX_SCORE; ++i)\r
 515                         self.owner.(scores[i]) = 0; // clear all scores\r
 516         }\r
 517 }\r
 518 \r
 519 void Ent_ReadPlayerScore()\r
 520 {\r
 521         float i, n;\r
 522         float isNew;\r
 523         entity o;\r
 524 \r
 525         // damnit -.- don't want to go change every single .sv_entnum in sbar.qc AGAIN\r
 526         // (no I've never heard of M-x replace-string, sed, or anything like that)\r
 527         isNew = !self.owner; // workaround for DP bug\r
 528         n = ReadByte()-1;\r
 529 \r
 530 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 531         if(!isNew && n != self.sv_entnum)\r
 532         {\r
 533                 print("A CSQC entity changed its owner!\n");\r
 534                 isNew = true;\r
 535                 Ent_Remove();\r
 536                 self.enttype = ENT_CLIENT_SCORES;\r
 537         }\r
 538 #endif\r
 539 \r
 540         self.sv_entnum = n;\r
 541 \r
 542         if not(playerslots[self.sv_entnum])\r
 543                 playerslots[self.sv_entnum] = spawn();\r
 544         o = self.owner = playerslots[self.sv_entnum];\r
 545         o.sv_entnum = self.sv_entnum;\r
 546         o.gotscores = 1;\r
 547 \r
 548         //if not(o.sort_prev)\r
 549         //      RegisterPlayer(o);\r
 550         //playerchecker will do this for us later, if it has not already done so\r
 551 \r
 552 #if MAX_SCORE <= 3\r
 553         for(i = 0; i < MAX_SCORE; ++i)\r
 554                 o.(scores[i]) = ReadShort();\r
 555 #else\r
 556         float sf;\r
 557 #if MAX_SCORE <= 8\r
 558         sf = ReadByte();\r
 559 #else\r
 560         sf = ReadShort();\r
 561 #endif\r
 562         float p;\r
 563         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)\r
 564                 if(sf & p)\r
 565                         o.(scores[i]) = ReadShort();\r
 566 #endif\r
 567 \r
 568         if(o.sort_prev)\r
 569                 Sbar_UpdatePlayerPos(o); // if not registered, we cannot do this yet!\r
 570         \r
 571         self.entremove = Ent_RemovePlayerScore;\r
 572 }\r
 573 \r
 574 void Ent_ReadTeamScore()\r
 575 {\r
 576         float i;\r
 577         entity o;\r
 578         \r
 579         self.team = ReadByte();\r
 580         o = self.owner = GetTeam(self.team, true);\r
 581 \r
 582 #if MAX_TEAMSCORE <= 3\r
 583         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 584                 o.(teamscores[i]) = ReadShort();\r
 585 #else\r
 586         float sf;\r
 587 #if MAX_TEAMSCORE <= 8\r
 588         sf = ReadByte();\r
 589 #else\r
 590         sf = ReadShort();\r
 591 #endif\r
 592         float p;\r
 593         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)\r
 594                 if(sf & p)\r
 595                         o.(teamscores[i]) = ReadShort();\r
 596 #endif\r
 597 \r
 598         Sbar_UpdateTeamPos(o);\r
 599 }\r
 600 \r
 601 void Net_Reset()\r
 602 {\r
 603 }\r
 604 \r
 605 void Ent_ClientData()\r
 606 {\r
 607         float f;\r
 608         float newspectatee_status;\r
 609 \r
 610         f = ReadByte();\r
 611 \r
 612         sb_showscores_force = (f & 1);\r
 613 \r
 614         if(f & 2)\r
 615         {\r
 616                 newspectatee_status = ReadByte();\r
 617                 if(newspectatee_status == player_localentnum)\r
 618                         newspectatee_status = -1; // observing\r
 619         }\r
 620         else\r
 621                 newspectatee_status = 0;\r
 622 \r
 623         spectatorbutton_zoom = (f & 4);\r
 624 \r
 625         if(f & 8)\r
 626         {\r
 627                 angles_held_status = 1;\r
 628                 angles_held_x = ReadAngle();\r
 629                 angles_held_y = ReadAngle();\r
 630                 angles_held_z = 0;\r
 631         }\r
 632         \r
 633         if(newspectatee_status != spectatee_status)\r
 634         {\r
 635                 // clear race stuff\r
 636                 race_laptime = 0;\r
 637                 race_checkpointtime = 0;\r
 638         }\r
 639         spectatee_status = newspectatee_status;\r
 640 }\r
 641 \r
 642 void Ent_Nagger()\r
 643 {\r
 644         float nags;\r
 645 \r
 646         nags = ReadByte();\r
 647 \r
 648         if(nags & 128)\r
 649         {\r
 650                 if(vote_called_vote)\r
 651                         strunzone(vote_called_vote);\r
 652                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));\r
 653         }\r
 654 \r
 655         ready_waiting = (nags & 1);\r
 656         ready_waiting_for_me = (nags & 2);\r
 657         vote_waiting = (nags & 4);\r
 658         vote_waiting_for_me = (nags & 8);\r
 659         warmup_stage = (nags & 16);\r
 660 }\r
 661 \r
 662 void Ent_RandomSeed()\r
 663 {\r
 664         float s;\r
 665         prandom_debug();\r
 666         s = ReadShort();\r
 667         psrandom(s);\r
 668 }\r
 669 \r
 670 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.\r
 671 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.\r
 672 void Ent_RadarLink();\r
 673 void Ent_Init();\r
 674 void Ent_ScoresInfo();\r
 675 void(float bIsNewEntity) CSQC_Ent_Update =\r
 676 {\r
 677         float t;\r
 678         float savetime;\r
 679         t = ReadByte();\r
 680 \r
 681         // set up the "time" global for received entities to be correct for interpolation purposes\r
 682         savetime = time;\r
 683         if(servertime)\r
 684                 time = servertime;\r
 685 \r
 686 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 687         if(self.enttype)\r
 688                 if(t != self.enttype)\r
 689                 {\r
 690                         print("A CSQC entity changed its type!\n");\r
 691                         Ent_Remove();\r
 692                 }\r
 693 #endif\r
 694         self.enttype = t;\r
 695         switch(t)\r
 696         {\r
 697                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;\r
 698                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;\r
 699                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;\r
 700                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;\r
 701                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;\r
 702                 case ENT_CLIENT_LASER: Ent_Laser(); break;\r
 703                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;\r
 704                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;\r
 705                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;\r
 706                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;\r
 707                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(); break;\r
 708                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(); break;\r
 709                 case ENT_CLIENT_CASING: Ent_Casing(); break;\r
 710                 case ENT_CLIENT_INIT: Ent_Init(); break;\r
 711                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;\r
 712                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;\r
 713                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;\r
 714                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;\r
 715                 default:\r
 716                         error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));\r
 717                         break;\r
 718         }\r
 719         \r
 720         time = savetime;\r
 721 };\r
 722 // Destructor, but does NOT deallocate the entity by calling remove(). Also\r
 723 // used when an entity changes its type. For an entity that someone interacts\r
 724 // with others, make sure it can no longer do so.\r
 725 void Ent_Remove()\r
 726 {\r
 727         if(self.entremove)\r
 728                 self.entremove();\r
 729 \r
 730         self.enttype = 0;\r
 731         self.classname = "";\r
 732         self.draw = menu_sub_null;\r
 733         self.entremove = menu_sub_null;\r
 734         // TODO possibly set more stuff to defaults\r
 735 }\r
 736 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.\r
 737 void CSQC_Ent_Remove()\r
 738 {\r
 739         if(self.enttype)\r
 740                 Ent_Remove();\r
 741         remove(self);\r
 742 }\r
 743 \r
 744 void Gamemode_Init()\r
 745 {\r
 746         if(gametype == GAME_ONSLAUGHT) {\r
 747                 print(strcat("Using ", minimapname, " as minimap.\n"));\r
 748                 precache_pic("gfx/ons-cp-neutral.tga");\r
 749                 precache_pic("gfx/ons-cp-red.tga");\r
 750                 precache_pic("gfx/ons-cp-blue.tga");\r
 751                 precache_pic("gfx/ons-frame.tga");\r
 752                 precache_pic("gfx/ons-frame-team.tga");\r
 753         } else if(gametype == GAME_KEYHUNT) {\r
 754                 precache_pic("gfx/sb_key_carrying");\r
 755                 precache_pic("gfx/sb_key_carrying_outline");\r
 756         }\r
 757 }\r
 758 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.\r
 759 void CSQC_Parse_StuffCmd(string strMessage)\r
 760 {\r
 761         localcmd(strMessage);\r
 762 }\r
 763 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.\r
 764 void CSQC_Parse_Print(string strMessage)\r
 765 {\r
 766         print(ColorTranslateRGB(strMessage));\r
 767 }\r
 768 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.  To execute standard behavior, simply execute cprint with the string.\r
 769 void CSQC_Parse_CenterPrint(string strMessage)\r
 770 {\r
 771         cprint(ColorTranslateRGB(strMessage));\r
 772 }\r
 773 \r
 774 void CSQC_CheckRevision();\r
 775 \r
 776 void Fog_Force()\r
 777 {\r
 778         // TODO somehow thwart prvm_globalset client ...\r
 779 \r
 780         if(forcefog != "")\r
 781                 localcmd(strcat("\nfog ", forcefog, "\nr_fog_exp2 0\nr_drawfog 1\n"));\r
 782 }\r
 783 \r
 784 void Gamemode_Init();\r
 785 void Ent_ScoresInfo()\r
 786 {\r
 787         float i;\r
 788         self.classname = "ent_client_scores_info";\r
 789         gametype = ReadByte();\r
 790         for(i = 0; i < MAX_SCORE; ++i)\r
 791         {\r
 792                 scores_label[i] = strzone(ReadString());\r
 793                 scores_flags[i] = ReadByte();\r
 794         }\r
 795         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 796         {\r
 797                 teamscores_label[i] = strzone(ReadString());\r
 798                 teamscores_flags[i] = ReadByte();\r
 799         }\r
 800         Sbar_InitScores();\r
 801         Gamemode_Init();\r
 802 }\r
 803 \r
 804 void Ent_Init()\r
 805 {\r
 806         float i;\r
 807         self.classname = "ent_client_init";\r
 808 \r
 809         csqc_revision = ReadShort();\r
 810 \r
 811         maxclients = ReadByte();\r
 812         for(i = 0; i < 24; ++i)\r
 813                 weaponimpulse[i] = ReadByte() - 1;\r
 814         hook_shotorigin_x = ReadCoord();\r
 815         hook_shotorigin_y = ReadCoord();\r
 816         hook_shotorigin_z = ReadCoord();\r
 817 \r
 818         if(forcefog)\r
 819                 strunzone(forcefog);\r
 820         forcefog = strzone(ReadString());\r
 821 \r
 822         CSQC_CheckRevision();\r
 823         if(!postinit)\r
 824                 PostInit();\r
 825 }\r
 826 \r
 827 string Net_ReadPicture()\r
 828 {\r
 829         string img;\r
 830         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
 831         {\r
 832                 img = ReadPicture();\r
 833                 print(strcat("Got Picture: ", img, "\n"));\r
 834         } else {\r
 835                 img = ReadString();\r
 836                 print(strcat("^3Warning: ^7Couldn't download ", img, ". This is probably because your engine build is outdated.\n"));\r
 837                 float psize, i;\r
 838                 psize = ReadShort();\r
 839                 // Can I be sure that ReadShort is 2 bytes and ReadLong is 4 bytes?\r
 840                 // Because then this could be optimized to first get all 4-byte-groups,\r
 841                 // then the remaining 2, then the remaining 1\r
 842                 for(i = 0; i < psize; ++i)\r
 843                         ReadByte();\r
 844         }\r
 845         return img;\r
 846 }\r
 847 \r
 848 void Net_ReadRace()\r
 849 {\r
 850         float b;\r
 851 \r
 852         b = ReadByte();\r
 853 \r
 854         switch(b)\r
 855         {\r
 856                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:\r
 857                         race_checkpoint = ReadByte();\r
 858                         race_time = ReadShort();\r
 859                         race_previousbesttime = ReadShort();\r
 860                         if(race_previousbestname)\r
 861                                 strunzone(race_previousbestname);\r
 862                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));\r
 863 \r
 864                         race_checkpointtime = time;\r
 865 \r
 866                         if(race_checkpoint == 0)\r
 867                                 race_laptime = time; // valid\r
 868 \r
 869                         break;\r
 870 \r
 871                 case RACE_NET_CHECKPOINT_CLEAR:\r
 872                         race_laptime = 0;\r
 873                         race_checkpointtime = 0;\r
 874                         break;\r
 875 \r
 876                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:\r
 877                         race_laptime = ReadCoord();\r
 878                         race_checkpointtime = -99999;\r
 879                         // fall through\r
 880                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:\r
 881                         race_nextcheckpoint = ReadByte();\r
 882 \r
 883                         race_nextbesttime = ReadShort();\r
 884                         if(race_nextbestname)\r
 885                                 strunzone(race_nextbestname);\r
 886                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));\r
 887                         break;\r
 888 \r
 889                 case RACE_NET_CHECKPOINT_HIT_RACE:\r
 890                         race_mycheckpoint = ReadByte();\r
 891                         race_mycheckpointtime = time;\r
 892                         race_mycheckpointdelta = ReadShort();\r
 893                         race_mycheckpointlapsdelta = ReadByte();\r
 894                         if(race_mycheckpointlapsdelta >= 128)\r
 895                                 race_mycheckpointlapsdelta -= 256;\r
 896                         if(race_mycheckpointenemy)\r
 897                                 strunzone(race_mycheckpointenemy);\r
 898                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));\r
 899                         break;\r
 900 \r
 901                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:\r
 902                         race_othercheckpoint = ReadByte();\r
 903                         race_othercheckpointtime = time;\r
 904                         race_othercheckpointdelta = ReadShort();\r
 905                         race_othercheckpointlapsdelta = ReadByte();\r
 906                         if(race_othercheckpointlapsdelta >= 128)\r
 907                                 race_othercheckpointlapsdelta -= 256;\r
 908                         if(race_othercheckpointenemy)\r
 909                                 strunzone(race_othercheckpointenemy);\r
 910                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));\r
 911                         break;\r
 912         }\r
 913 }\r
 914 \r
 915 void Net_ReadSpawn()\r
 916 {\r
 917         zoomin_effect = 1;\r
 918         current_viewzoom = 0.6;\r
 919 }\r
 920 \r
 921 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.\r
 922 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.\r
 923 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.\r
 924 float CSQC_Parse_TempEntity()\r
 925 {\r
 926         local float bHandled;\r
 927                 bHandled  = true;\r
 928         // Acquire TE ID\r
 929         local float nTEID;\r
 930                 nTEID = ReadByte();\r
 931 \r
 932                 // NOTE: Could just do return instead of break...\r
 933         switch(nTEID)\r
 934         {\r
 935                 case TE_CSQC_PICTURE:\r
 936                         Net_MapVote_Picture();\r
 937                         bHandled = true;\r
 938                         break;\r
 939                 case TE_CSQC_RACE:\r
 940                         Net_ReadRace();\r
 941                         bHandled = true;\r
 942                         break;\r
 943                 case 13: // TE_BEAM\r
 944                         Net_GrapplingHook();\r
 945                         bHandled = true;\r
 946                         break;\r
 947                 case TE_CSQC_SPAWN:\r
 948                         Net_ReadSpawn();\r
 949                         bHandled = true;\r
 950                         break;\r
 951                 default:\r
 952                         // No special logic for this temporary entity; return 0 so the engine can handle it\r
 953                         bHandled = false;\r
 954                         break;\r
 955         }\r
 956                 \r
 957         return bHandled;\r
 958 }\r
 959 \r
 960 // COMMIT-TODO: Update if necessare, before committing\r
 961 void CSQC_CheckRevision()\r
 962 {\r
 963         if(csqc_revision == CSQC_REVISION)\r
 964         {\r
 965                 print("^2SVQC and CSQC revisions are compatible.\n");\r
 966         } else if(csqc_revision < CSQC_REVISION) {\r
 967                 print("^1Your csprogs.dat (CSQC) version is newer than the one on the server.\n");\r
 968         } else if(csqc_revision > CSQC_REVISION) {\r
 969                 print("^1Your csprogs.dat (CSQC) is too old for this server.\n");\r
 970                 print("^1Please update to a newer version.\n");\r
 971         }\r
 972 }\r
 973 \r
 974 string getcommandkey(string text, string command)\r
 975 {\r
 976         string keys;\r
 977         float n, j, k, l;\r
 978 \r
 979         if (!sbar_showbinds)\r
 980                 return text;\r
 981 \r
 982         keys = db_get(binddb, command);\r
 983         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
 984         {\r
 985                 if (!keys) \r
 986                 {\r
 987                         n = tokenize_insane(findkeysforcommand(command)); // uses '...' strings\r
 988                         for(j = 0; j < n; ++j)\r
 989                         {\r
 990                                 k = stof(argv(j));\r
 991                                 if(k != -1) \r
 992                                 {\r
 993                                         if ("" == keys)\r
 994                                                 keys = keynumtostring(k);\r
 995                                         else\r
 996                                                 keys = strcat(keys, ", ", keynumtostring(k));\r
 997 \r
 998                                         ++l;\r
 999                                         if (sbar_showbinds_limit > 0 && sbar_showbinds_limit >= l) break;\r
1000                                 }\r
1001                         \r
1002                         }\r
1003                         db_put(binddb, command, keys);\r
1004                 }\r
1005         }\r
1006         \r
1007         if ("" == keys) {\r
1008                 if (sbar_showbinds > 1)\r
1009                         return strcat(text, " (not bound)");\r
1010                 else\r
1011                         return text;\r
1012         }\r
1013         else if (sbar_showbinds > 1)\r
1014                 return strcat(text, " (", keys, ")");\r
1015         else\r
1016                 return keys;\r
1017 }\r