data/qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------\r
   2 // BEGIN REQUIRED CSQC FUNCTIONS\r
   3 //include "main.qh"\r
   4 \r
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
   6 \r
   7 void cvar_settemp(string cv, string val)\r
   8 {\r
   9         entity e;\r
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  11                 if(e.netname == cv)\r
  12                         goto saved;\r
  13         e = spawn();\r
  14         e.classname = "saved_cvar_value";\r
  15         e.netname = strzone(cv);\r
  16         e.message = strzone(cvar_string(cv));\r
  17 :saved\r
  18         cvar_set(cv, val);\r
  19 }\r
  20 \r
  21 void cvar_settemp_restore()\r
  22 {\r
  23         entity e;\r
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  25                         cvar_set(e.netname, e.message);\r
  26 }\r
  27 \r
  28 void() menu_show_error =\r
  29 {\r
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);\r
  31 };\r
  32 \r
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)\r
  34 // Useful for precaching things\r
  35 \r
  36 void() menu_sub_null =\r
  37 {\r
  38 };\r
  39 \r
  40 // let's make this a general data buffer...\r
  41 float using_gps;\r
  42 \r
  43 #ifdef USE_FTE\r
  44 float __engine_check;\r
  45 #endif\r
  46 \r
  47 string config_get(string key, string defaultvalue)\r
  48 {\r
  49         string s;\r
  50         s = db_get(configdb, strcat("/s/", key));\r
  51         if(s == "")\r
  52                 return defaultvalue;\r
  53         else\r
  54                 return db_get(configdb, strcat("/v/", key));\r
  55 }\r
  56 \r
  57 string forcefog;\r
  58 void CSQC_Init(void)\r
  59 {\r
  60 #ifdef USE_FTE\r
  61 #pragma target ID\r
  62         __engine_check = checkextension("DP_SV_WRITEPICTURE");\r
  63         if(!__engine_check)\r
  64         {\r
  65                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");\r
  66                 localcmd("\ndisconnect\n");\r
  67                 return;\r
  68         }\r
  69 #pragma target FTE\r
  70 #endif\r
  71         \r
  72         float i;\r
  73         CSQC_CheckEngine();\r
  74 \r
  75         configdb = db_create();\r
  76         binddb = db_create();\r
  77         compressShortVector_init();\r
  78 \r
  79         drawfont = 0;\r
  80         menu_visible = FALSE;\r
  81         menu_show = menu_show_error;\r
  82         menu_action = menu_sub_null;\r
  83         using_gps = false;\r
  84         maxclients = 255; // we later get the real maxclients to speed up stuff\r
  85         //ctf_temp_1 = "";\r
  86         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used\r
  87         //registercmd("ctf_menu");\r
  88         registercmd("ons_map");\r
  89         //registercmd("menu_action");\r
  90         registercmd("sbar_columns_set");\r
  91         registercmd("sbar_columns_help");\r
  92 \r
  93         registercmd("+button3");\r
  94         registercmd("-button3");\r
  95         registercmd("+button4");\r
  96         registercmd("-button4");\r
  97 \r
  98         registercvar("sbar_usecsqc", "1");\r
  99         registercvar("sbar_columns", "default", CVAR_SAVE);\r
 100 \r
 101         gametype = 0;\r
 102 \r
 103         gps_start = world;\r
 104 \r
 105         // sbar_fields uses strunzone on the titles!\r
 106         for(i = 0; i < MAX_SBAR_FIELDS; ++i)\r
 107                 sbar_title[i] = strzone("(null)");\r
 108 \r
 109         postinit = false;\r
 110 \r
 111         teams = Sort_Spawn();\r
 112         players = Sort_Spawn();\r
 113         \r
 114         GetTeam(COLOR_SPECTATOR, true); // add specs first\r
 115 \r
 116         cvar_settemp("_supports_weaponpriority", "1");\r
 117 }\r
 118 \r
 119 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)\r
 120 void CSQC_Shutdown(void)\r
 121 {\r
 122 #ifdef USE_FTE\r
 123 #pragma TARGET id\r
 124         if(!__engine_check)\r
 125                 return 0;\r
 126 #pragma TARGET fte\r
 127 #endif\r
 128 \r
 129         remove(teams);\r
 130         remove(players);\r
 131         db_close(configdb);\r
 132         db_close(binddb);\r
 133 \r
 134         cvar_settemp_restore();\r
 135 }\r
 136 \r
 137 .float has_team;\r
 138 float SetTeam(entity o, float Team)\r
 139 {\r
 140         entity tm;\r
 141         if(Team == -1) // leave\r
 142         {\r
 143                 if(o.has_team)\r
 144                 {\r
 145                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");\r
 146                         tm = GetTeam(o.team, false);\r
 147                         tm.team_size -= 1;\r
 148                         o.has_team = 0;\r
 149                         return TRUE;\r
 150                 }\r
 151         }\r
 152         else\r
 153         {\r
 154                 if not(o.has_team)\r
 155                 {\r
 156                         //print("(CONNECT) enter team ", ftos(o.team), "\n");\r
 157                         o.team = Team;\r
 158                         tm = GetTeam(Team, true);\r
 159                         tm.team_size += 1;\r
 160                         o.has_team = 1;\r
 161                         return TRUE;\r
 162                 }\r
 163                 else if(Team != o.team)\r
 164                 {\r
 165                         //print("(CHANGE) leave team ", ftos(o.team), "\n");\r
 166                         tm = GetTeam(o.team, false);\r
 167                         tm.team_size -= 1;\r
 168                         o.team = Team;\r
 169                         //print("(CHANGE) enter team ", ftos(o.team), "\n");\r
 170                         tm = GetTeam(Team, true);\r
 171                         tm.team_size += 1;\r
 172                         return TRUE;\r
 173                 }\r
 174         }\r
 175         return FALSE;\r
 176 }\r
 177 \r
 178 void Playerchecker_Think()\r
 179 {\r
 180         float i;\r
 181         for(i = 0; i < maxclients; ++i)\r
 182         {\r
 183                 if(getplayerkey(i, "name") == "")\r
 184                 {\r
 185                         if(playerslots[i].sort_prev)\r
 186                         {\r
 187                                 //print("playerchecker: KILL KILL KILL\n");\r
 188                                 // player disconnected\r
 189                                 SetTeam(playerslots[i], -1);\r
 190                                 RemovePlayer(playerslots[i]);\r
 191                                 playerslots[i].sort_prev = world;\r
 192                                 playerslots[i].gotscores = 0;\r
 193                         }\r
 194                 }\r
 195                 else\r
 196                 {\r
 197                         if not(playerslots[i].sort_prev)\r
 198                         {\r
 199                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");\r
 200                                 // player connected\r
 201                                 if not(playerslots[i])\r
 202                                         playerslots[i] = spawn();\r
 203                                 playerslots[i].sv_entnum = i;\r
 204                                 playerslots[i].gotscores = 0;\r
 205                                 SetTeam(playerslots[i], COLOR_SPECTATOR);\r
 206                                 RegisterPlayer(playerslots[i]);\r
 207                                 Sbar_UpdatePlayerPos(playerslots[i]);\r
 208                         }\r
 209                 }\r
 210         }\r
 211         self.nextthink = time + 0.2;\r
 212 }\r
 213 \r
 214 void Porto_Init();\r
 215 void PostInit(void)\r
 216 {\r
 217         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));\r
 218         localcmd(strcat("\nsbar_columns_set ", cvar_string("sbar_columns"), ";\n"));\r
 219 \r
 220         entity playerchecker;\r
 221         playerchecker = spawn();\r
 222         playerchecker.think = Playerchecker_Think;\r
 223         playerchecker.nextthink = time + 0.2;\r
 224 \r
 225         Porto_Init();\r
 226 \r
 227         postinit = true;\r
 228 }\r
 229 \r
 230 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function\r
 231 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.\r
 232 float button_zoom;\r
 233 void Cmd_Sbar_SetFields(float);\r
 234 void Cmd_Sbar_Help(float);\r
 235 float CSQC_ConsoleCommand(string strMessage)\r
 236 {\r
 237         float argc;\r
 238         // Tokenize String\r
 239         //argc = tokenize(strMessage);\r
 240         argc = tokenizebyseparator(strMessage, " ");\r
 241         \r
 242         // Acquire Command\r
 243         local string strCmd;\r
 244         strCmd = argv(0);\r
 245 \r
 246         if(strCmd == "+button4") { // zoom\r
 247                 // return false, because the message shall be sent to the server anyway (for demos/speccing)\r
 248                 if(ignore_plus_zoom)\r
 249                 {\r
 250                         --ignore_plus_zoom;\r
 251                         return false;\r
 252                 }\r
 253                 button_zoom = 1;\r
 254                 return true;\r
 255         } else if(strCmd == "-button4") { // zoom\r
 256                 if(ignore_minus_zoom)\r
 257                 {\r
 258                         --ignore_minus_zoom;\r
 259                         return false;\r
 260                 }\r
 261                 button_zoom = 0;\r
 262                 return true;\r
 263         } else if(strCmd == "+button3") { // secondary\r
 264                 button_attack2 = 1;\r
 265                 return false;\r
 266         } else if(strCmd == "-button3") { // secondary\r
 267                 button_attack2 = 0;\r
 268                 return false;\r
 269         } else if(strCmd == "ons_map") {\r
 270                 Cmd_ons_map();\r
 271                 return true;\r
 272         } else if(strCmd == "sbar_columns_set") {\r
 273                 Cmd_Sbar_SetFields(argc);\r
 274                 return true;\r
 275         } else if(strCmd == "sbar_columns_help") {\r
 276                 Cmd_Sbar_Help(argc);\r
 277                 return true;\r
 278         } else if(strCmd == "+showscores") {\r
 279                 sb_showscores = true;\r
 280                 return true;\r
 281         } else if(strCmd == "-showscores") {\r
 282                 sb_showscores = false;\r
 283                 return true;\r
 284         }\r
 285         \r
 286         return false;\r
 287 }\r
 288 \r
 289 float GameCommand(string msg)\r
 290 {\r
 291         float argc;\r
 292         argc = tokenize(msg);\r
 293         string cmd;\r
 294         cmd = argv(0);\r
 295         if(cmd == "mv_download") {\r
 296                 Cmd_MapVote_MapDownload(argc);\r
 297                 return true;\r
 298         }\r
 299         else if(cmd == "settemp") {\r
 300                 cvar_settemp(argv(1), argv(2));\r
 301         }\r
 302         \r
 303         return false;\r
 304 }\r
 305 \r
 306 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.\r
 307 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.\r
 308 // All keys are in ascii.\r
 309 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.\r
 310 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.\r
 311 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.\r
 312 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)\r
 313 {\r
 314         local float bSkipKey;\r
 315         bSkipKey = false;\r
 316         \r
 317         if(menu_visible)\r
 318                 if(menu_action(bInputType, nPrimary, nSecondary))\r
 319                         return TRUE;\r
 320         return bSkipKey;\r
 321 }\r
 322 \r
 323 // END REQUIRED CSQC FUNCTIONS\r
 324 // --------------------------------------------------------------------------\r
 325 \r
 326 // --------------------------------------------------------------------------\r
 327 // BEGIN OPTIONAL CSQC FUNCTIONS\r
 328 void Ent_ReadONS()\r
 329 {\r
 330         entity gps;\r
 331         using_gps = true;\r
 332 \r
 333         self.origin_x = ReadCoord();\r
 334         self.origin_y = ReadCoord();\r
 335         self.angles_y = ReadCoord();\r
 336         self.origin_z = self.angles_x = self.angles_z = 0;\r
 337 \r
 338         for(gps = gps_start; gps; gps = gps.chain)\r
 339         {\r
 340                 if(gps == self)\r
 341                         break;\r
 342         }\r
 343         if(!gps)\r
 344         {\r
 345                 self.chain = gps_start;\r
 346                 gps_start = self;\r
 347         }\r
 348 }\r
 349 \r
 350 void Ent_RemoveONS()\r
 351 {\r
 352         if(gps_start == self)\r
 353                 gps_start = self.chain;\r
 354         else\r
 355         {\r
 356                 local entity ent;\r
 357                 ent = gps_start;\r
 358                         \r
 359                 while(ent.chain != self && ent.chain != world)\r
 360                         ent = ent.chain;\r
 361                 if(ent.chain == self)\r
 362                         ent.chain = self.chain;\r
 363         }\r
 364 }\r
 365 \r
 366 void Ent_Remove();\r
 367 void Ent_ReadPlayerScore()\r
 368 {\r
 369         float i, Team, n;\r
 370         float isNew;\r
 371         entity o;\r
 372 \r
 373         // damnit -.- don't want to go change every single .sv_entnum in sbar.qc AGAIN\r
 374         // (no I've never heard of M-x replace-string, sed, or anything like that)\r
 375         isNew = !self.owner; // workaround for DP bug\r
 376         n = ReadByte()-1;\r
 377 \r
 378 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 379         if(!isNew && n != self.sv_entnum)\r
 380         {\r
 381                 print("A CSQC entity changed its owner!\n");\r
 382                 isNew = true;\r
 383                 Ent_Remove();\r
 384                 self.enttype = ENT_CLIENT_SCORES;\r
 385         }\r
 386 #endif\r
 387 \r
 388         self.sv_entnum = n;\r
 389         Team = GetPlayerColor(self.sv_entnum);\r
 390 \r
 391         if not(playerslots[self.sv_entnum])\r
 392                 playerslots[self.sv_entnum] = spawn();\r
 393         o = self.owner = playerslots[self.sv_entnum];\r
 394         o.sv_entnum = self.sv_entnum;\r
 395         o.gotscores = 1;\r
 396         if not(o.sort_prev)\r
 397                 RegisterPlayer(o);\r
 398 \r
 399         SetTeam(o, Team);\r
 400 \r
 401 #if MAX_SCORE <= 3\r
 402         for(i = 0; i < MAX_SCORE; ++i)\r
 403                 o.(scores[i]) = ReadShort();\r
 404 #else\r
 405         float sf;\r
 406 #if MAX_SCORE <= 8\r
 407         sf = ReadByte();\r
 408 #else\r
 409         sf = ReadShort();\r
 410 #endif\r
 411         float p;\r
 412         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)\r
 413                 if(sf & p)\r
 414                         o.(scores[i]) = ReadShort();\r
 415 #endif\r
 416 \r
 417         Sbar_UpdatePlayerPos(o);\r
 418 }\r
 419 \r
 420 void Ent_ReadTeamScore()\r
 421 {\r
 422         float i;\r
 423         entity o;\r
 424         \r
 425         self.team = ReadByte();\r
 426         o = self.owner = GetTeam(self.team, true);\r
 427 \r
 428 #if MAX_TEAMSCORE <= 3\r
 429         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 430                 o.(teamscores[i]) = ReadShort();\r
 431 #else\r
 432         float sf;\r
 433 #if MAX_TEAMSCORE <= 8\r
 434         sf = ReadByte();\r
 435 #else\r
 436         sf = ReadShort();\r
 437 #endif\r
 438         float p;\r
 439         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)\r
 440                 if(sf & p)\r
 441                         o.(teamscores[i]) = ReadShort();\r
 442 #endif\r
 443 \r
 444         Sbar_UpdateTeamPos(o);\r
 445 }\r
 446 \r
 447 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.\r
 448 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.\r
 449 void(float bIsNewEntity) CSQC_Ent_Update =\r
 450 {\r
 451         float msg, t;\r
 452         t = ReadByte();\r
 453 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 454         if(self.enttype)\r
 455                 if(t != self.enttype)\r
 456                 {\r
 457                         print("A CSQC entity changed its type!\n");\r
 458                         Ent_Remove();\r
 459                 }\r
 460 #endif\r
 461         self.enttype = t;\r
 462         if(self.enttype == ENT_CLIENT_ENTCS)\r
 463         {\r
 464                 self.sv_entnum = ReadByte()-1;\r
 465 \r
 466                 for(msg = ReadByte(); msg != ENTCS_MSG_END; msg = ReadByte())\r
 467                 {\r
 468                         switch(msg)\r
 469                         {\r
 470                         case ENTCS_MSG_ONS_GPS: Ent_ReadONS(); break;\r
 471                         case ENTCS_MSG_ONS_REMOVE: Ent_RemoveONS(); break;\r
 472                         default:\r
 473                                 error("unknown ENTCS_MSG type\n");\r
 474                         }\r
 475                 }\r
 476         }\r
 477         else if(self.enttype == ENT_CLIENT_SCORES)\r
 478                 Ent_ReadPlayerScore();\r
 479         else if(self.enttype == ENT_CLIENT_TEAMSCORES)\r
 480                 Ent_ReadTeamScore();\r
 481         else if(self.enttype == ENT_CLIENT_POINTPARTICLES)\r
 482                 Ent_PointParticles();\r
 483         else if(self.enttype == ENT_CLIENT_RAINSNOW)\r
 484                 Ent_RainOrSnow();\r
 485         else if(self.enttype == ENT_CLIENT_LASER)\r
 486                 Ent_Laser();\r
 487         else\r
 488                 error("unknown entity type in CSQC_Ent_Update\n");\r
 489         \r
 490 };\r
 491 // Destructor, but does NOT deallocate the entity by calling remove(). Also\r
 492 // used when an entity changes its type. For an entity that someone interacts\r
 493 // with others, make sure it can no longer do so.\r
 494 void Ent_Remove()\r
 495 {\r
 496         if(self.enttype == ENT_CLIENT_ENTCS)\r
 497         {\r
 498                 if(using_gps) //gametype == GAME_ONSLAUGHT)\r
 499                 {\r
 500                         if(gps_start == self)\r
 501                                 gps_start = self.chain;\r
 502                         else\r
 503                         {\r
 504                                 local entity ent;\r
 505                                 ent = gps_start;\r
 506                         \r
 507                                 while(ent.chain != self && ent.chain != world)\r
 508                                         ent = ent.chain;\r
 509                                 if(ent.chain == self)\r
 510                                         ent.chain = self.chain;\r
 511                         }\r
 512                 }\r
 513         } else if(self.enttype == ENT_CLIENT_SCORES)\r
 514         {\r
 515                 if(self.owner)\r
 516                 {\r
 517                         SetTeam(self.owner, -1);\r
 518                         if(self.owner.sort_prev)\r
 519                                 RemovePlayer(self.owner);\r
 520                         self.owner.sort_prev = NULL;\r
 521                 }\r
 522         } else if(self.enttype == ENT_CLIENT_TEAMSCORES)\r
 523         {\r
 524                 /*\r
 525                 if(self.owner)\r
 526                         RemoveTeam(self.owner);\r
 527                 */\r
 528                 // we don't NEED to remove them... they won't display anyway\r
 529                 // plus, svqc never does this anyway\r
 530         } else if(self.enttype == ENT_CLIENT_POINTPARTICLES)\r
 531         {\r
 532                 Ent_PointParticles_Remove();\r
 533         }\r
 534 \r
 535         self.enttype = 0;\r
 536         self.classname = "";\r
 537         self.draw = menu_sub_null;\r
 538         // TODO possibly set more stuff to defaults\r
 539 }\r
 540 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.\r
 541 void CSQC_Ent_Remove()\r
 542 {\r
 543         if(self.enttype)\r
 544                 Ent_Remove();\r
 545         remove(self);\r
 546 }\r
 547 \r
 548 void Gamemode_Init()\r
 549 {\r
 550         local string mapinfo, infoline;\r
 551         local float len;\r
 552         local float file;\r
 553         local vector mi_min, mi_max;\r
 554 \r
 555         if(!strcasecmp(substring(mapname, 0, 5), "maps/"))\r
 556                 shortmapname = substring(mapname, 5, 999);\r
 557         else\r
 558                 shortmapname = mapname;\r
 559         len = strlen(shortmapname);\r
 560         if(!strcasecmp(substring(shortmapname, len-4, 4), ".bsp"))\r
 561                 shortmapname = substring(shortmapname, 0, len-4);\r
 562         shortmapname = strzone(shortmapname);\r
 563 \r
 564         if(gametype == GAME_ONSLAUGHT) {\r
 565                 mapinfo = strcat("maps/", minimapname, ".info");\r
 566                 minimapname = strzone(strcat("gfx/", shortmapname, "_mini.tga"));\r
 567 \r
 568                 mi_min = world.mins;\r
 569                 mi_max = world.maxs;\r
 570                 \r
 571                 file = fopen(mapinfo, FILE_READ);\r
 572                 if(file >= 0) {\r
 573                         while((infoline = fgets(file))) {\r
 574                                 if(!strncasecmp(infoline, "mins", 4)) {\r
 575                                         mi_min = stov(substring(infoline, 5, 999));\r
 576                                 } else if(!strncasecmp(infoline, "maxs", 4)) {\r
 577                                         mi_max = stov(substring(infoline, 5, 999));\r
 578                                 } else if(strncasecmp(infoline, "//", 2)) { // don't print comment-style lines\r
 579                                         print(strcat("mapinfo: ", infoline, "\n"));\r
 580                                 }\r
 581                         }\r
 582                 } else {\r
 583                         print(strcat("Map has no .info file (", mapinfo, ").\n"));\r
 584                 }\r
 585                 fclose(file);\r
 586 \r
 587                 print(strcat("Mins: ", vtos(mi_min), "    Maxs: ", vtos(mi_max), "\n"));\r
 588                 \r
 589                 mi_center = (mi_min + mi_max) * 0.5;\r
 590                 mi_scale = mi_max - mi_min;\r
 591                 \r
 592                 \r
 593                 print(strcat("Using ", minimapname, " as minimap.\n"));\r
 594                 precache_pic(minimapname);\r
 595                 precache_pic("gfx/ons-cp-neutral.tga");\r
 596                 precache_pic("gfx/ons-cp-red.tga");\r
 597                 precache_pic("gfx/ons-cp-blue.tga");\r
 598                 precache_pic("gfx/ons-frame.tga");\r
 599                 precache_pic("gfx/ons-frame-team.tga");\r
 600         } else if(gametype == GAME_KEYHUNT) {\r
 601                 precache_pic("gfx/sb_key_carrying");\r
 602                 precache_pic("gfx/sb_key_carrying_outline");\r
 603         }\r
 604 }\r
 605 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.\r
 606 void CSQC_Parse_StuffCmd(string strMessage)\r
 607 {\r
 608         localcmd(strMessage);\r
 609 }\r
 610 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.\r
 611 void CSQC_Parse_Print(string strMessage)\r
 612 {\r
 613         print(strMessage);\r
 614 }\r
 615 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.  To execute standard behavior, simply execute cprint with the string.\r
 616 void CSQC_Parse_CenterPrint(string strMessage)\r
 617 {\r
 618         cprint(strMessage);\r
 619 }\r
 620 \r
 621 void CSQC_CheckRevision();\r
 622 \r
 623 void Fog_Force()\r
 624 {\r
 625         string s;\r
 626 \r
 627         // TODO somehow thwart prvm_globalset client ...\r
 628 \r
 629         if(forcefog != "")\r
 630                 localcmd(strcat("\nfog ", forcefog, "\nr_fog_exp2 0\nr_drawfog 1\n"));\r
 631 }\r
 632 \r
 633 void Net_ReadFog()\r
 634 {\r
 635         if(forcefog)\r
 636                 strunzone(forcefog);\r
 637         forcefog = strzone(ReadString());\r
 638 }\r
 639 \r
 640 void Gamemode_Init();\r
 641 void Net_ReadScoresInfo()\r
 642 {\r
 643         float i;\r
 644         gametype = ReadByte();\r
 645         for(i = 0; i < MAX_SCORE; ++i)\r
 646         {\r
 647                 scores_label[i] = strzone(ReadString());\r
 648                 scores_flags[i] = ReadByte();\r
 649         }\r
 650         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 651         {\r
 652                 teamscores_label[i] = strzone(ReadString());\r
 653                 teamscores_flags[i] = ReadByte();\r
 654         }\r
 655         Sbar_InitScores();\r
 656         Gamemode_Init();\r
 657 }\r
 658 \r
 659 void Net_ReadInit()\r
 660 {\r
 661         float i;\r
 662         csqc_revision = ReadShort();\r
 663         maxclients = ReadByte();\r
 664         for(i = 0; i < 24; ++i)\r
 665                 weaponimpulse[i] = ReadByte() - 1;\r
 666         CSQC_CheckRevision();\r
 667 }\r
 668 \r
 669 string Net_ReadPicture()\r
 670 {\r
 671         string img;\r
 672         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
 673         {\r
 674                 img = ReadPicture();\r
 675                 print(strcat("Got Picture: ", img, "\n"));\r
 676         } else {\r
 677                 img = ReadString();\r
 678                 print(strcat("^3Warning: ^7Couldn't download ", img, ". This is probably because your engine build is outdated.\n"));\r
 679                 float psize, i;\r
 680                 psize = ReadShort();\r
 681                 // Can I be sure that ReadShort is 2 bytes and ReadLong is 4 bytes?\r
 682                 // Because then this could be optimized to first get all 4-byte-groups,\r
 683                 // then the remaining 2, then the remaining 1\r
 684                 for(i = 0; i < psize; ++i)\r
 685                         ReadByte();\r
 686         }\r
 687         return img;\r
 688 }\r
 689 \r
 690 void Net_Config()\r
 691 {\r
 692         string key, value;\r
 693         key = ReadString();\r
 694         value = ReadString();\r
 695         db_put(configdb, strcat("/v/", key), value);\r
 696         db_put(configdb, strcat("/s/", key), "1");\r
 697 }\r
 698 \r
 699 void Net_ReadRace()\r
 700 {\r
 701         float b;\r
 702 \r
 703         b = ReadByte();\r
 704 \r
 705         switch(b)\r
 706         {\r
 707                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:\r
 708                         race_checkpoint = ReadByte();\r
 709                         race_time = ReadShort();\r
 710                         race_previousbesttime = ReadShort();\r
 711                         if(race_previousbestname)\r
 712                                 strunzone(race_previousbestname);\r
 713                         race_previousbestname = strzone(ReadString());\r
 714 \r
 715                         race_checkpointtime = time;\r
 716 \r
 717                         if(race_checkpoint == 0)\r
 718                                 race_laptime = time; // valid\r
 719 \r
 720                         break;\r
 721 \r
 722                 case RACE_NET_CHECKPOINT_CLEAR:\r
 723                         race_laptime = 0;\r
 724                         race_checkpointtime = 0;\r
 725                         break;\r
 726 \r
 727                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:\r
 728                         race_laptime = ReadCoord();\r
 729                         race_checkpointtime = -99999;\r
 730                         // fall through\r
 731                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:\r
 732                         race_nextcheckpoint = ReadByte();\r
 733 \r
 734                         race_nextbesttime = ReadShort();\r
 735                         if(race_nextbestname)\r
 736                                 strunzone(race_nextbestname);\r
 737                         race_nextbestname = strzone(ReadString());\r
 738                         break;\r
 739 \r
 740                 case RACE_NET_CHECKPOINT_HIT_RACE:\r
 741                         race_mycheckpoint = ReadByte();\r
 742                         race_mycheckpointtime = time;\r
 743                         race_mycheckpointdelta = ReadShort();\r
 744                         race_mycheckpointlapsdelta = ReadByte();\r
 745                         if(race_mycheckpointlapsdelta >= 128)\r
 746                                 race_mycheckpointlapsdelta -= 256;\r
 747                         if(race_mycheckpointenemy)\r
 748                                 strunzone(race_mycheckpointenemy);\r
 749                         race_mycheckpointenemy = strzone(ReadString());\r
 750                         break;\r
 751 \r
 752                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:\r
 753                         race_othercheckpoint = ReadByte();\r
 754                         race_othercheckpointtime = time;\r
 755                         race_othercheckpointdelta = ReadShort();\r
 756                         race_othercheckpointlapsdelta = ReadByte();\r
 757                         if(race_othercheckpointlapsdelta >= 128)\r
 758                                 race_othercheckpointlapsdelta -= 256;\r
 759                         if(race_othercheckpointenemy)\r
 760                                 strunzone(race_othercheckpointenemy);\r
 761                         race_othercheckpointenemy = strzone(ReadString());\r
 762                         break;\r
 763         }\r
 764 }\r
 765 \r
 766 void Net_ReadForceScoreboard()\r
 767 {\r
 768         sb_showscores_force = ReadByte();\r
 769 }\r
 770 \r
 771 void Net_Reset()\r
 772 {\r
 773         float i;\r
 774         race_laptime = 0;\r
 775         race_checkpointtime = 0;\r
 776         for(i = 0; i < 24; ++i)\r
 777                 angles_held_status[i] = 0;\r
 778 }\r
 779 \r
 780 void Net_ReadSpectating()\r
 781 {\r
 782         float newspectatee_status;\r
 783         newspectatee_status = ReadByte();\r
 784         if(newspectatee_status == player_localentnum)\r
 785                 newspectatee_status = -1; // observing\r
 786         if(newspectatee_status != spectatee_status)\r
 787                 Net_Reset();\r
 788         spectatee_status = newspectatee_status;\r
 789 }\r
 790 \r
 791 void Net_ReadZoomNotify()\r
 792 {\r
 793         spectatorbutton_zoom = ReadByte();\r
 794 }\r
 795 \r
 796 void Net_ReadSpawn()\r
 797 {\r
 798         zoomin_effect = 1;\r
 799         current_viewzoom = 0.6;\r
 800 }\r
 801 \r
 802 void Net_ReadWarmupStage()\r
 803 {\r
 804         warmup_stage = ReadByte();\r
 805 }\r
 806 \r
 807 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.\r
 808 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.\r
 809 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.\r
 810 void Net_ReadHoldAngles();\r
 811 float CSQC_Parse_TempEntity()\r
 812 {\r
 813         local float bHandled;\r
 814                 bHandled  = true;\r
 815         // Acquire TE ID\r
 816         local float nTEID;\r
 817                 nTEID = ReadByte();\r
 818 \r
 819                 // NOTE: Could just do return instead of break...\r
 820         switch(nTEID)\r
 821         {\r
 822                 case TE_CSQC_INIT:\r
 823                         Net_ReadInit();\r
 824                         bHandled = true;\r
 825                         break;\r
 826                 case TE_CSQC_MAPVOTE:\r
 827                         Net_Mapvote();\r
 828                         bHandled = true;\r
 829                         break;\r
 830                 case TE_CSQC_CONFIG:\r
 831                         Net_Config();\r
 832                         bHandled = true;\r
 833                         break;\r
 834                 case TE_CSQC_SCORESINFO:\r
 835                         Net_ReadScoresInfo();\r
 836                         bHandled = true;\r
 837                         break;\r
 838                 case TE_CSQC_RACE:\r
 839                         Net_ReadRace();\r
 840                         bHandled = true;\r
 841                         break;\r
 842                 case TE_CSQC_FORCESCOREBOARD:\r
 843                         Net_ReadForceScoreboard();\r
 844                         bHandled = true;\r
 845                         break;\r
 846                 case TE_CSQC_SPECTATING:\r
 847                         Net_ReadSpectating();\r
 848                         bHandled = true;\r
 849                         break;\r
 850                 case 13: // TE_BEAM\r
 851                         Net_GrapplingHook();\r
 852                         bHandled = true;\r
 853                         break;\r
 854                 case TE_CSQC_SPAWN:\r
 855                         Net_ReadSpawn();\r
 856                         bHandled = true;\r
 857                         break;\r
 858                 case TE_CSQC_ZOOMNOTIFY:\r
 859                         Net_ReadZoomNotify();\r
 860                         bHandled = true;\r
 861                         break;\r
 862                 case TE_CSQC_HOLDANGLES:\r
 863                         Net_ReadHoldAngles();\r
 864                         bHandled = true;\r
 865                         break;\r
 866                 case TE_CSQC_WARMUP:\r
 867                         Net_ReadWarmupStage();\r
 868                         bHandled = true;\r
 869                         break;\r
 870                 case TE_CSQC_FOG:\r
 871                         Net_ReadFog();\r
 872                         bHandled = true;\r
 873                         break;\r
 874                 default:\r
 875                         // No special logic for this temporary entity; return 0 so the engine can handle it\r
 876                         bHandled = false;\r
 877                         break;\r
 878         }\r
 879         \r
 880         if(!postinit)\r
 881                 PostInit();\r
 882                 \r
 883         return bHandled;\r
 884 }\r
 885 \r
 886 // COMMIT-TODO: Update if necessare, before committing\r
 887 void CSQC_CheckRevision()\r
 888 {\r
 889         if(csqc_revision == CSQC_REVISION)\r
 890         {\r
 891                 print("^2SVQC and CSQC revisions are compatible.\n");\r
 892         } else if(csqc_revision < CSQC_REVISION) {\r
 893                 print("^1Your csprogs.dat (CSQC) version is newer than the one on the server.\n");\r
 894         } else if(csqc_revision > CSQC_REVISION) {\r
 895                 print("^1Your csprogs.dat (CSQC) is too old for this server.\n");\r
 896                 print("^1Please update to a newer version.\n");\r
 897         }\r
 898 }\r
 899 \r
 900 string getcommandkey(string text, string command)\r
 901 {\r
 902         string keys;\r
 903         float n, j, k, l;\r
 904 \r
 905         if (!sbar_showbinds)\r
 906                 return text;\r
 907 \r
 908         keys = db_get(binddb, command);\r
 909         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
 910         {\r
 911                 if (!keys) \r
 912                 {\r
 913                         n = tokenize(findkeysforcommand(command));\r
 914                         for(j = 0; j < n; ++j)\r
 915                         {\r
 916                                 k = stof(argv(j));\r
 917                                 if(k != -1) \r
 918                                 {\r
 919                                         if ("" == keys)\r
 920                                                 keys = keynumtostring(k);\r
 921                                         else\r
 922                                                 keys = strcat(keys, ", ", keynumtostring(k));\r
 923 \r
 924                                         ++l;\r
 925                                         if (sbar_showbinds_limit > 0 && sbar_showbinds_limit >= l) break;\r
 926                                 }\r
 927                         \r
 928                         }\r
 929                         db_put(binddb, command, keys);\r
 930                 }\r
 931         }\r
 932         \r
 933         if ("" == keys) {\r
 934                 if (sbar_showbinds > 1)\r
 935                         return strcat(text, " (not bound)");\r
 936                 else\r
 937                         return text;\r
 938         }\r
 939         else if (sbar_showbinds > 1)\r
 940                 return strcat(text, " (", keys, ")");\r
 941         else\r
 942                 return keys;\r
 943 }\r