data/qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------\r
   2 // BEGIN REQUIRED CSQC FUNCTIONS\r
   3 //include "main.qh"\r
   4 \r
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
   6 \r
   7 void cvar_clientsettemp(string cv, string val)\r
   8 {\r
   9         entity e;\r
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  11                 if(e.netname == cv)\r
  12                         goto saved;\r
  13         e = spawn();\r
  14         e.classname = "saved_cvar_value";\r
  15         e.netname = strzone(cv);\r
  16         e.message = strzone(cvar_string(cv));\r
  17 :saved\r
  18         cvar_set(cv, val);\r
  19 }\r
  20 \r
  21 void cvar_clientsettemp_restore()\r
  22 {\r
  23         entity e;\r
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  25                         cvar_set(e.netname, e.message);\r
  26 }\r
  27 \r
  28 void() menu_show_error =\r
  29 {\r
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);\r
  31 };\r
  32 \r
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)\r
  34 // Useful for precaching things\r
  35 \r
  36 void() menu_sub_null =\r
  37 {\r
  38 };\r
  39 \r
  40 #ifdef USE_FTE\r
  41 float __engine_check;\r
  42 #endif\r
  43 \r
  44 string config_get(string key, string defaultvalue)\r
  45 {\r
  46         string s;\r
  47         s = db_get(configdb, strcat("/s/", key));\r
  48         if(s == "")\r
  49                 return defaultvalue;\r
  50         else\r
  51                 return db_get(configdb, strcat("/v/", key));\r
  52 }\r
  53 \r
  54 string forcefog;\r
  55 void WaypointSprite_Load();\r
  56 void CSQC_Init(void)\r
  57 {\r
  58 #ifdef USE_FTE\r
  59 #pragma target ID\r
  60         __engine_check = checkextension("DP_SV_WRITEPICTURE");\r
  61         if(!__engine_check)\r
  62         {\r
  63                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");\r
  64                 localcmd("\ndisconnect\n");\r
  65                 return;\r
  66         }\r
  67 #pragma target FTE\r
  68 #endif\r
  69         \r
  70         float i;\r
  71         CSQC_CheckEngine();\r
  72         dprint_load();\r
  73 \r
  74         configdb = db_create();\r
  75         binddb = db_create();\r
  76         tempdb = db_create();\r
  77         compressShortVector_init();\r
  78 \r
  79         drawfont = 0;\r
  80         menu_visible = FALSE;\r
  81         menu_show = menu_show_error;\r
  82         menu_action = menu_sub_null;\r
  83         maxclients = 255; // we later get the real maxclients to speed up stuff\r
  84         //ctf_temp_1 = "";\r
  85         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used\r
  86         //registercmd("ctf_menu");\r
  87         registercmd("ons_map");\r
  88         //registercmd("menu_action");\r
  89         registercmd("sbar_columns_set");\r
  90         registercmd("sbar_columns_help");\r
  91 \r
  92         registercmd("+button3");\r
  93         registercmd("-button3");\r
  94         registercmd("+button4");\r
  95         registercmd("-button4");\r
  96 \r
  97         registercvar("sbar_usecsqc", "1");\r
  98         registercvar("sbar_columns", "default", CVAR_SAVE);\r
  99 \r
 100         gametype = 0;\r
 101 \r
 102         // sbar_fields uses strunzone on the titles!\r
 103         for(i = 0; i < MAX_SBAR_FIELDS; ++i)\r
 104                 sbar_title[i] = strzone("(null)");\r
 105 \r
 106         postinit = false;\r
 107 \r
 108         teams = Sort_Spawn();\r
 109         players = Sort_Spawn();\r
 110         \r
 111         GetTeam(COLOR_SPECTATOR, true); // add specs first\r
 112 \r
 113         cvar_clientsettemp("_supports_weaponpriority", "1");\r
 114 \r
 115 \r
 116 \r
 117 \r
 118         cs_project_is_b0rked = TRUE;\r
 119         R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');\r
 120         R_SetView(VF_FOV, '90 90 0');\r
 121         R_SetView(VF_ORIGIN, '0 0 0');\r
 122         R_SetView(VF_ANGLES, '0 0 0');\r
 123         R_SetView(VF_PERSPECTIVE, 1);\r
 124         makevectors('0 0 0');\r
 125         vector v;\r
 126         v = cs_project(v_forward);\r
 127         if(v_x - 320 < +1)\r
 128         if(v_x - 320 > -1)\r
 129         if(v_y - 240 < +1)\r
 130         if(v_y - 240 > -1)\r
 131                 cs_project_is_b0rked = FALSE;\r
 132 \r
 133         RegisterWeapons();\r
 134 \r
 135         WaypointSprite_Load();\r
 136 \r
 137         Projectile_Precache();\r
 138         GibSplash_Precache();\r
 139         Casings_Precache();\r
 140         DamageInfo_Precache();\r
 141 \r
 142         get_mi_min_max_texcoords(1); // try the CLEVER way first\r
 143         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");\r
 144         shortmapname = mi_shortname;\r
 145 \r
 146         if(precache_pic(minimapname) == "")\r
 147         {\r
 148                 // but maybe we have a non-clever minimap\r
 149                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");\r
 150                 if(precache_pic(minimapname) == "")\r
 151                         minimapname = ""; // FAIL\r
 152                 else\r
 153                         get_mi_min_max_texcoords(0); // load new texcoords\r
 154         }\r
 155 \r
 156         mi_center = (mi_min + mi_max) * 0.5;\r
 157         mi_scale = mi_max - mi_min;\r
 158         minimapname = strzone(minimapname);\r
 159 }\r
 160 \r
 161 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)\r
 162 void CSQC_Shutdown(void)\r
 163 {\r
 164 #ifdef USE_FTE\r
 165 #pragma TARGET id\r
 166         if(!__engine_check)\r
 167                 return 0;\r
 168 #pragma TARGET fte\r
 169 #endif\r
 170 \r
 171         remove(teams);\r
 172         remove(players);\r
 173         db_close(configdb);\r
 174         db_close(binddb);\r
 175         db_close(tempdb);\r
 176 \r
 177         cvar_clientsettemp_restore();\r
 178 }\r
 179 \r
 180 .float has_team;\r
 181 float SetTeam(entity o, float Team)\r
 182 {\r
 183         entity tm;\r
 184         if(Team == -1) // leave\r
 185         {\r
 186                 if(o.has_team)\r
 187                 {\r
 188                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");\r
 189                         tm = GetTeam(o.team, false);\r
 190                         tm.team_size -= 1;\r
 191                         o.has_team = 0;\r
 192                         return TRUE;\r
 193                 }\r
 194         }\r
 195         else\r
 196         {\r
 197                 if not(o.has_team)\r
 198                 {\r
 199                         //print("(CONNECT) enter team ", ftos(o.team), "\n");\r
 200                         o.team = Team;\r
 201                         tm = GetTeam(Team, true);\r
 202                         tm.team_size += 1;\r
 203                         o.has_team = 1;\r
 204                         return TRUE;\r
 205                 }\r
 206                 else if(Team != o.team)\r
 207                 {\r
 208                         //print("(CHANGE) leave team ", ftos(o.team), "\n");\r
 209                         tm = GetTeam(o.team, false);\r
 210                         tm.team_size -= 1;\r
 211                         o.team = Team;\r
 212                         //print("(CHANGE) enter team ", ftos(o.team), "\n");\r
 213                         tm = GetTeam(Team, true);\r
 214                         tm.team_size += 1;\r
 215                         return TRUE;\r
 216                 }\r
 217         }\r
 218         return FALSE;\r
 219 }\r
 220 \r
 221 void Playerchecker_Think()\r
 222 {\r
 223         float i;\r
 224         entity e;\r
 225         for(i = 0; i < maxclients; ++i)\r
 226         {\r
 227                 e = playerslots[i];\r
 228                 if(GetPlayerName(i) == "")\r
 229                 {\r
 230                         if(e.sort_prev)\r
 231                         {\r
 232                                 //print("playerchecker: KILL KILL KILL\n");\r
 233                                 // player disconnected\r
 234                                 SetTeam(e, -1);\r
 235                                 RemovePlayer(e);\r
 236                                 e.sort_prev = world;\r
 237                                 //e.gotscores = 0;\r
 238                         }\r
 239                 }\r
 240                 else\r
 241                 {\r
 242                         if not(e.sort_prev)\r
 243                         {\r
 244                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");\r
 245                                 // player connected\r
 246                                 if not(e)\r
 247                                         playerslots[i] = e = spawn();\r
 248                                 e.sv_entnum = i;\r
 249                                 //e.gotscores = 0; // we might already have the scores...\r
 250                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with Sbar_UpdatePlayerTeams\r
 251                                 RegisterPlayer(e);\r
 252                                 Sbar_UpdatePlayerPos(e);\r
 253                         }\r
 254                 }\r
 255         }\r
 256         self.nextthink = time + 0.2;\r
 257 }\r
 258 \r
 259 void Porto_Init();\r
 260 void PostInit(void)\r
 261 {\r
 262         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));\r
 263         localcmd(strcat("\nsbar_columns_set ", cvar_string("sbar_columns"), ";\n"));\r
 264 \r
 265         entity playerchecker;\r
 266         playerchecker = spawn();\r
 267         playerchecker.think = Playerchecker_Think;\r
 268         playerchecker.nextthink = time + 0.2;\r
 269 \r
 270         Porto_Init();\r
 271 \r
 272         postinit = true;\r
 273 }\r
 274 \r
 275 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function\r
 276 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.\r
 277 float button_zoom;\r
 278 void Cmd_Sbar_SetFields(float);\r
 279 void Cmd_Sbar_Help(float);\r
 280 float CSQC_ConsoleCommand(string strMessage)\r
 281 {\r
 282         float argc;\r
 283         // Tokenize String\r
 284         //argc = tokenize(strMessage);\r
 285         argc = tokenize_sane(strMessage);\r
 286         \r
 287         // Acquire Command\r
 288         local string strCmd;\r
 289         strCmd = argv(0);\r
 290 \r
 291         if(strCmd == "+button4") { // zoom\r
 292                 // return false, because the message shall be sent to the server anyway (for demos/speccing)\r
 293                 if(ignore_plus_zoom)\r
 294                 {\r
 295                         --ignore_plus_zoom;\r
 296                         return false;\r
 297                 }\r
 298                 button_zoom = 1;\r
 299                 return true;\r
 300         } else if(strCmd == "-button4") { // zoom\r
 301                 if(ignore_minus_zoom)\r
 302                 {\r
 303                         --ignore_minus_zoom;\r
 304                         return false;\r
 305                 }\r
 306                 button_zoom = 0;\r
 307                 return true;\r
 308         } else if(strCmd == "+button3") { // secondary\r
 309                 button_attack2 = 1;\r
 310                 return false;\r
 311         } else if(strCmd == "-button3") { // secondary\r
 312                 button_attack2 = 0;\r
 313                 return false;\r
 314         } else if(strCmd == "+showscores") {\r
 315                 sb_showscores = true;\r
 316                 return true;\r
 317         } else if(strCmd == "-showscores") {\r
 318                 sb_showscores = false;\r
 319                 return true;\r
 320         }\r
 321         \r
 322         return false;\r
 323 }\r
 324 \r
 325 float GameCommand(string msg)\r
 326 {\r
 327         float argc;\r
 328         argc = tokenize_sane(msg);\r
 329         string cmd;\r
 330         cmd = argv(0);\r
 331         if(cmd == "mv_download") {\r
 332                 Cmd_MapVote_MapDownload(argc);\r
 333                 return true;\r
 334         }\r
 335         else if(cmd == "settemp") {\r
 336                 cvar_clientsettemp(argv(1), argv(2));\r
 337         }\r
 338         else if(cmd == "radar") {\r
 339                 ons_showmap = !ons_showmap;\r
 340         }\r
 341         else if(cmd == "sbar_columns_set") {\r
 342                 Cmd_Sbar_SetFields(argc);\r
 343         }\r
 344         else if(cmd == "sbar_columns_help") {\r
 345                 Cmd_Sbar_Help(argc);\r
 346         }\r
 347 #ifdef BLURTEST\r
 348         else if(cmd == "blurtest") {\r
 349                 blurtest_time0 = time;\r
 350                 blurtest_time1 = time + stof(argv(1));\r
 351                 blurtest_radius = stof(argv(2));\r
 352                 blurtest_power = stof(argv(3));\r
 353         }\r
 354 #endif\r
 355         \r
 356         return false;\r
 357 }\r
 358 \r
 359 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.\r
 360 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.\r
 361 // All keys are in ascii.\r
 362 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.\r
 363 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.\r
 364 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.\r
 365 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)\r
 366 {\r
 367         local float bSkipKey;\r
 368         bSkipKey = false;\r
 369         \r
 370         if(menu_visible)\r
 371                 if(menu_action(bInputType, nPrimary, nSecondary))\r
 372                         return TRUE;\r
 373         return bSkipKey;\r
 374 }\r
 375 \r
 376 // END REQUIRED CSQC FUNCTIONS\r
 377 // --------------------------------------------------------------------------\r
 378 \r
 379 // --------------------------------------------------------------------------\r
 380 // BEGIN OPTIONAL CSQC FUNCTIONS\r
 381 void Ent_ReadEntCS()\r
 382 {\r
 383         InterpolateOrigin_Undo();\r
 384 \r
 385         self.classname = "entcs_receiver";\r
 386         self.sv_entnum = ReadByte() - 1;\r
 387         self.origin_x = ReadShort();\r
 388         self.origin_y = ReadShort();\r
 389         self.origin_z = ReadShort();\r
 390         self.angles_y = ReadByte() * 360.0 / 256;\r
 391         self.origin_z = self.angles_x = self.angles_z = 0;\r
 392 \r
 393         InterpolateOrigin_Note();\r
 394 }\r
 395 \r
 396 void Ent_RemoveEntCS()\r
 397 {\r
 398 }\r
 399 \r
 400 void Ent_Remove();\r
 401 void Ent_ReadPlayerScore()\r
 402 {\r
 403         float i, n;\r
 404         float isNew;\r
 405         entity o;\r
 406 \r
 407         // damnit -.- don't want to go change every single .sv_entnum in sbar.qc AGAIN\r
 408         // (no I've never heard of M-x replace-string, sed, or anything like that)\r
 409         isNew = !self.owner; // workaround for DP bug\r
 410         n = ReadByte()-1;\r
 411 \r
 412 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 413         if(!isNew && n != self.sv_entnum)\r
 414         {\r
 415                 print("A CSQC entity changed its owner!\n");\r
 416                 isNew = true;\r
 417                 Ent_Remove();\r
 418                 self.enttype = ENT_CLIENT_SCORES;\r
 419         }\r
 420 #endif\r
 421 \r
 422         self.sv_entnum = n;\r
 423 \r
 424         if not(playerslots[self.sv_entnum])\r
 425                 playerslots[self.sv_entnum] = spawn();\r
 426         o = self.owner = playerslots[self.sv_entnum];\r
 427         o.sv_entnum = self.sv_entnum;\r
 428         o.gotscores = 1;\r
 429 \r
 430         //if not(o.sort_prev)\r
 431         //      RegisterPlayer(o);\r
 432         //playerchecker will do this for us later, if it has not already done so\r
 433 \r
 434 #if MAX_SCORE <= 3\r
 435         for(i = 0; i < MAX_SCORE; ++i)\r
 436                 o.(scores[i]) = ReadShort();\r
 437 #else\r
 438         float sf;\r
 439 #if MAX_SCORE <= 8\r
 440         sf = ReadByte();\r
 441 #else\r
 442         sf = ReadShort();\r
 443 #endif\r
 444         float p;\r
 445         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)\r
 446                 if(sf & p)\r
 447                         o.(scores[i]) = ReadShort();\r
 448 #endif\r
 449 \r
 450         if(o.sort_prev)\r
 451                 Sbar_UpdatePlayerPos(o); // if not registered, we cannot do this yet!\r
 452 }\r
 453 \r
 454 void Ent_ReadTeamScore()\r
 455 {\r
 456         float i;\r
 457         entity o;\r
 458         \r
 459         self.team = ReadByte();\r
 460         o = self.owner = GetTeam(self.team, true);\r
 461 \r
 462 #if MAX_TEAMSCORE <= 3\r
 463         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 464                 o.(teamscores[i]) = ReadShort();\r
 465 #else\r
 466         float sf;\r
 467 #if MAX_TEAMSCORE <= 8\r
 468         sf = ReadByte();\r
 469 #else\r
 470         sf = ReadShort();\r
 471 #endif\r
 472         float p;\r
 473         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)\r
 474                 if(sf & p)\r
 475                         o.(teamscores[i]) = ReadShort();\r
 476 #endif\r
 477 \r
 478         Sbar_UpdateTeamPos(o);\r
 479 }\r
 480 \r
 481 void Ent_Nagger()\r
 482 {\r
 483         float nags;\r
 484 \r
 485         nags = ReadByte();\r
 486 \r
 487         if(nags & 128)\r
 488         {\r
 489                 if(vote_called_vote)\r
 490                         strunzone(vote_called_vote);\r
 491                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));\r
 492         }\r
 493 \r
 494         ready_waiting = (nags & 1);\r
 495         ready_waiting_for_me = (nags & 2);\r
 496         vote_waiting = (nags & 4);\r
 497         vote_waiting_for_me = (nags & 8);\r
 498         warmup_stage = (nags & 16);\r
 499 }\r
 500 \r
 501 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.\r
 502 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.\r
 503 void Ent_RadarLink();\r
 504 void Ent_Init();\r
 505 void Ent_ScoresInfo();\r
 506 void(float bIsNewEntity) CSQC_Ent_Update =\r
 507 {\r
 508         float t;\r
 509         float savetime;\r
 510         t = ReadByte();\r
 511 \r
 512         // set up the "time" global for received entities to be correct for interpolation purposes\r
 513         savetime = time;\r
 514         if(servertime)\r
 515                 time = servertime;\r
 516 \r
 517 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 518         if(self.enttype)\r
 519                 if(t != self.enttype)\r
 520                 {\r
 521                         print("A CSQC entity changed its type!\n");\r
 522                         Ent_Remove();\r
 523                 }\r
 524 #endif\r
 525         self.enttype = t;\r
 526         if(self.enttype == ENT_CLIENT_ENTCS)\r
 527                 Ent_ReadEntCS();\r
 528         else if(self.enttype == ENT_CLIENT_SCORES)\r
 529                 Ent_ReadPlayerScore();\r
 530         else if(self.enttype == ENT_CLIENT_TEAMSCORES)\r
 531                 Ent_ReadTeamScore();\r
 532         else if(self.enttype == ENT_CLIENT_POINTPARTICLES)\r
 533                 Ent_PointParticles();\r
 534         else if(self.enttype == ENT_CLIENT_RAINSNOW)\r
 535                 Ent_RainOrSnow();\r
 536         else if(self.enttype == ENT_CLIENT_LASER)\r
 537                 Ent_Laser();\r
 538         else if(self.enttype == ENT_CLIENT_NAGGER)\r
 539                 Ent_Nagger();\r
 540         else if(self.enttype == ENT_CLIENT_WAYPOINT)\r
 541                 Ent_WaypointSprite();\r
 542         else if(self.enttype == ENT_CLIENT_RADARLINK)\r
 543                 Ent_RadarLink();\r
 544         else if(self.enttype == ENT_CLIENT_PROJECTILE)\r
 545                 Ent_Projectile();\r
 546         else if(self.enttype == ENT_CLIENT_GIBSPLASH)\r
 547                 Ent_GibSplash();\r
 548         else if(self.enttype == ENT_CLIENT_DAMAGEINFO)\r
 549                 Ent_DamageInfo();\r
 550         else if(self.enttype == ENT_CLIENT_CASING)\r
 551                 Ent_Casing();\r
 552         else if(self.enttype == ENT_CLIENT_INIT)\r
 553                 Ent_Init();\r
 554         else if(self.enttype == ENT_CLIENT_SCORES_INFO)\r
 555                 Ent_ScoresInfo();\r
 556         else if(self.enttype == ENT_CLIENT_MAPVOTE)\r
 557                 Ent_MapVote();\r
 558         else\r
 559                 error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));\r
 560         \r
 561         time = savetime;\r
 562 };\r
 563 // Destructor, but does NOT deallocate the entity by calling remove(). Also\r
 564 // used when an entity changes its type. For an entity that someone interacts\r
 565 // with others, make sure it can no longer do so.\r
 566 void Ent_Remove()\r
 567 {\r
 568         float i;\r
 569         if(self.enttype == ENT_CLIENT_ENTCS)\r
 570         {\r
 571                 Ent_RemoveEntCS();\r
 572         } else if(self.enttype == ENT_CLIENT_SCORES)\r
 573         {\r
 574                 if(self.owner)\r
 575                 {\r
 576                         SetTeam(self.owner, -1);\r
 577                         self.owner.gotscores = 0;\r
 578                         for(i = 0; i < MAX_SCORE; ++i)\r
 579                                 self.owner.(scores[i]) = 0; // clear all scores\r
 580                 }\r
 581         } else if(self.enttype == ENT_CLIENT_TEAMSCORES)\r
 582         {\r
 583                 /*\r
 584                 if(self.owner)\r
 585                         RemoveTeam(self.owner);\r
 586                 */\r
 587                 // we don't NEED to remove them... they won't display anyway\r
 588                 // plus, svqc never does this anyway\r
 589         } else if(self.enttype == ENT_CLIENT_POINTPARTICLES)\r
 590         {\r
 591                 Ent_PointParticles_Remove();\r
 592         }\r
 593         else if(self.enttype == ENT_CLIENT_WAYPOINT)\r
 594                 Ent_RemoveWaypointSprite();\r
 595         else if(self.enttype == ENT_CLIENT_PROJECTILE)\r
 596                 Ent_RemoveProjectile();\r
 597 \r
 598         self.enttype = 0;\r
 599         self.classname = "";\r
 600         self.draw = menu_sub_null;\r
 601         // TODO possibly set more stuff to defaults\r
 602 }\r
 603 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.\r
 604 void CSQC_Ent_Remove()\r
 605 {\r
 606         if(self.enttype)\r
 607                 Ent_Remove();\r
 608         remove(self);\r
 609 }\r
 610 \r
 611 void Gamemode_Init()\r
 612 {\r
 613         if(gametype == GAME_ONSLAUGHT) {\r
 614                 print(strcat("Using ", minimapname, " as minimap.\n"));\r
 615                 precache_pic("gfx/ons-cp-neutral.tga");\r
 616                 precache_pic("gfx/ons-cp-red.tga");\r
 617                 precache_pic("gfx/ons-cp-blue.tga");\r
 618                 precache_pic("gfx/ons-frame.tga");\r
 619                 precache_pic("gfx/ons-frame-team.tga");\r
 620         } else if(gametype == GAME_KEYHUNT) {\r
 621                 precache_pic("gfx/sb_key_carrying");\r
 622                 precache_pic("gfx/sb_key_carrying_outline");\r
 623         }\r
 624 }\r
 625 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.\r
 626 void CSQC_Parse_StuffCmd(string strMessage)\r
 627 {\r
 628         localcmd(strMessage);\r
 629 }\r
 630 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.\r
 631 void CSQC_Parse_Print(string strMessage)\r
 632 {\r
 633         print(ColorTranslateRGB(strMessage));\r
 634 }\r
 635 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.  To execute standard behavior, simply execute cprint with the string.\r
 636 void CSQC_Parse_CenterPrint(string strMessage)\r
 637 {\r
 638         cprint(ColorTranslateRGB(strMessage));\r
 639 }\r
 640 \r
 641 void CSQC_CheckRevision();\r
 642 \r
 643 void Fog_Force()\r
 644 {\r
 645         // TODO somehow thwart prvm_globalset client ...\r
 646 \r
 647         if(forcefog != "")\r
 648                 localcmd(strcat("\nfog ", forcefog, "\nr_fog_exp2 0\nr_drawfog 1\n"));\r
 649 }\r
 650 \r
 651 void Net_ReadFog()\r
 652 {\r
 653         if(forcefog)\r
 654                 strunzone(forcefog);\r
 655         ReadCoord(); // ignore fog interval\r
 656         forcefog = strzone(ReadString());\r
 657 }\r
 658 \r
 659 void Gamemode_Init();\r
 660 void Ent_ScoresInfo()\r
 661 {\r
 662         float i;\r
 663         self.classname = "ent_client_scores_info";\r
 664         gametype = ReadByte();\r
 665         for(i = 0; i < MAX_SCORE; ++i)\r
 666         {\r
 667                 scores_label[i] = strzone(ReadString());\r
 668                 scores_flags[i] = ReadByte();\r
 669         }\r
 670         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 671         {\r
 672                 teamscores_label[i] = strzone(ReadString());\r
 673                 teamscores_flags[i] = ReadByte();\r
 674         }\r
 675         Sbar_InitScores();\r
 676         Gamemode_Init();\r
 677 }\r
 678 \r
 679 void Ent_Init()\r
 680 {\r
 681         float i;\r
 682         self.classname = "ent_client_init";\r
 683 \r
 684         csqc_revision = ReadShort();\r
 685 \r
 686         maxclients = ReadByte();\r
 687         for(i = 0; i < 24; ++i)\r
 688                 weaponimpulse[i] = ReadByte() - 1;\r
 689         hook_shotorigin_x = ReadCoord();\r
 690         hook_shotorigin_y = ReadCoord();\r
 691         hook_shotorigin_z = ReadCoord();\r
 692         CSQC_CheckRevision();\r
 693         \r
 694         if(!postinit)\r
 695                 PostInit();\r
 696 }\r
 697 \r
 698 string Net_ReadPicture()\r
 699 {\r
 700         string img;\r
 701         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
 702         {\r
 703                 img = ReadPicture();\r
 704                 print(strcat("Got Picture: ", img, "\n"));\r
 705         } else {\r
 706                 img = ReadString();\r
 707                 print(strcat("^3Warning: ^7Couldn't download ", img, ". This is probably because your engine build is outdated.\n"));\r
 708                 float psize, i;\r
 709                 psize = ReadShort();\r
 710                 // Can I be sure that ReadShort is 2 bytes and ReadLong is 4 bytes?\r
 711                 // Because then this could be optimized to first get all 4-byte-groups,\r
 712                 // then the remaining 2, then the remaining 1\r
 713                 for(i = 0; i < psize; ++i)\r
 714                         ReadByte();\r
 715         }\r
 716         return img;\r
 717 }\r
 718 \r
 719 void Net_Config()\r
 720 {\r
 721         string key, value;\r
 722         key = ReadString();\r
 723         value = ReadString();\r
 724         db_put(configdb, strcat("/v/", key), value);\r
 725         db_put(configdb, strcat("/s/", key), "1");\r
 726 }\r
 727 \r
 728 void Net_ReadRace()\r
 729 {\r
 730         float b;\r
 731 \r
 732         b = ReadByte();\r
 733 \r
 734         switch(b)\r
 735         {\r
 736                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:\r
 737                         race_checkpoint = ReadByte();\r
 738                         race_time = ReadShort();\r
 739                         race_previousbesttime = ReadShort();\r
 740                         if(race_previousbestname)\r
 741                                 strunzone(race_previousbestname);\r
 742                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));\r
 743 \r
 744                         race_checkpointtime = time;\r
 745 \r
 746                         if(race_checkpoint == 0)\r
 747                                 race_laptime = time; // valid\r
 748 \r
 749                         break;\r
 750 \r
 751                 case RACE_NET_CHECKPOINT_CLEAR:\r
 752                         race_laptime = 0;\r
 753                         race_checkpointtime = 0;\r
 754                         break;\r
 755 \r
 756                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:\r
 757                         race_laptime = ReadCoord();\r
 758                         race_checkpointtime = -99999;\r
 759                         // fall through\r
 760                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:\r
 761                         race_nextcheckpoint = ReadByte();\r
 762 \r
 763                         race_nextbesttime = ReadShort();\r
 764                         if(race_nextbestname)\r
 765                                 strunzone(race_nextbestname);\r
 766                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));\r
 767                         break;\r
 768 \r
 769                 case RACE_NET_CHECKPOINT_HIT_RACE:\r
 770                         race_mycheckpoint = ReadByte();\r
 771                         race_mycheckpointtime = time;\r
 772                         race_mycheckpointdelta = ReadShort();\r
 773                         race_mycheckpointlapsdelta = ReadByte();\r
 774                         if(race_mycheckpointlapsdelta >= 128)\r
 775                                 race_mycheckpointlapsdelta -= 256;\r
 776                         if(race_mycheckpointenemy)\r
 777                                 strunzone(race_mycheckpointenemy);\r
 778                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));\r
 779                         break;\r
 780 \r
 781                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:\r
 782                         race_othercheckpoint = ReadByte();\r
 783                         race_othercheckpointtime = time;\r
 784                         race_othercheckpointdelta = ReadShort();\r
 785                         race_othercheckpointlapsdelta = ReadByte();\r
 786                         if(race_othercheckpointlapsdelta >= 128)\r
 787                                 race_othercheckpointlapsdelta -= 256;\r
 788                         if(race_othercheckpointenemy)\r
 789                                 strunzone(race_othercheckpointenemy);\r
 790                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));\r
 791                         break;\r
 792         }\r
 793 }\r
 794 \r
 795 void Net_ReadForceScoreboard()\r
 796 {\r
 797         sb_showscores_force = ReadByte();\r
 798 }\r
 799 \r
 800 void Net_Reset()\r
 801 {\r
 802         float i;\r
 803         race_laptime = 0;\r
 804         race_checkpointtime = 0;\r
 805         for(i = 0; i < 24; ++i)\r
 806                 angles_held_status[i] = 0;\r
 807 }\r
 808 \r
 809 void Net_ReadSpectating()\r
 810 {\r
 811         float newspectatee_status;\r
 812         newspectatee_status = ReadByte();\r
 813         if(newspectatee_status == player_localentnum)\r
 814                 newspectatee_status = -1; // observing\r
 815         if(newspectatee_status != spectatee_status)\r
 816                 Net_Reset();\r
 817         spectatee_status = newspectatee_status;\r
 818 }\r
 819 \r
 820 void Net_ReadZoomNotify()\r
 821 {\r
 822         spectatorbutton_zoom = ReadByte();\r
 823 }\r
 824 \r
 825 void Net_ReadSpawn()\r
 826 {\r
 827         zoomin_effect = 1;\r
 828         current_viewzoom = 0.6;\r
 829 }\r
 830 \r
 831 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.\r
 832 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.\r
 833 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.\r
 834 void Net_ReadHoldAngles();\r
 835 float CSQC_Parse_TempEntity()\r
 836 {\r
 837         local float bHandled;\r
 838                 bHandled  = true;\r
 839         // Acquire TE ID\r
 840         local float nTEID;\r
 841                 nTEID = ReadByte();\r
 842 \r
 843                 // NOTE: Could just do return instead of break...\r
 844         switch(nTEID)\r
 845         {\r
 846                 case TE_CSQC_PICTURE:\r
 847                         Net_MapVote_Picture();\r
 848                         bHandled = true;\r
 849                         break;\r
 850                 case TE_CSQC_CONFIG:\r
 851                         Net_Config();\r
 852                         bHandled = true;\r
 853                         break;\r
 854                 case TE_CSQC_RACE:\r
 855                         Net_ReadRace();\r
 856                         bHandled = true;\r
 857                         break;\r
 858                 case TE_CSQC_FORCESCOREBOARD:\r
 859                         Net_ReadForceScoreboard();\r
 860                         bHandled = true;\r
 861                         break;\r
 862                 case TE_CSQC_SPECTATING:\r
 863                         Net_ReadSpectating();\r
 864                         bHandled = true;\r
 865                         break;\r
 866                 case 13: // TE_BEAM\r
 867                         Net_GrapplingHook();\r
 868                         bHandled = true;\r
 869                         break;\r
 870                 case TE_CSQC_SPAWN:\r
 871                         Net_ReadSpawn();\r
 872                         bHandled = true;\r
 873                         break;\r
 874                 case TE_CSQC_ZOOMNOTIFY:\r
 875                         Net_ReadZoomNotify();\r
 876                         bHandled = true;\r
 877                         break;\r
 878                 case TE_CSQC_HOLDANGLES:\r
 879                         Net_ReadHoldAngles();\r
 880                         bHandled = true;\r
 881                         break;\r
 882                 case TE_CSQC_FOG:\r
 883                         Net_ReadFog();\r
 884                         bHandled = true;\r
 885                         break;\r
 886                 default:\r
 887                         // No special logic for this temporary entity; return 0 so the engine can handle it\r
 888                         bHandled = false;\r
 889                         break;\r
 890         }\r
 891                 \r
 892         return bHandled;\r
 893 }\r
 894 \r
 895 // COMMIT-TODO: Update if necessare, before committing\r
 896 void CSQC_CheckRevision()\r
 897 {\r
 898         if(csqc_revision == CSQC_REVISION)\r
 899         {\r
 900                 print("^2SVQC and CSQC revisions are compatible.\n");\r
 901         } else if(csqc_revision < CSQC_REVISION) {\r
 902                 print("^1Your csprogs.dat (CSQC) version is newer than the one on the server.\n");\r
 903         } else if(csqc_revision > CSQC_REVISION) {\r
 904                 print("^1Your csprogs.dat (CSQC) is too old for this server.\n");\r
 905                 print("^1Please update to a newer version.\n");\r
 906         }\r
 907 }\r
 908 \r
 909 string getcommandkey(string text, string command)\r
 910 {\r
 911         string keys;\r
 912         float n, j, k, l;\r
 913 \r
 914         if (!sbar_showbinds)\r
 915                 return text;\r
 916 \r
 917         keys = db_get(binddb, command);\r
 918         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
 919         {\r
 920                 if (!keys) \r
 921                 {\r
 922                         n = tokenize_insane(findkeysforcommand(command)); // uses '...' strings\r
 923                         for(j = 0; j < n; ++j)\r
 924                         {\r
 925                                 k = stof(argv(j));\r
 926                                 if(k != -1) \r
 927                                 {\r
 928                                         if ("" == keys)\r
 929                                                 keys = keynumtostring(k);\r
 930                                         else\r
 931                                                 keys = strcat(keys, ", ", keynumtostring(k));\r
 932 \r
 933                                         ++l;\r
 934                                         if (sbar_showbinds_limit > 0 && sbar_showbinds_limit >= l) break;\r
 935                                 }\r
 936                         \r
 937                         }\r
 938                         db_put(binddb, command, keys);\r
 939                 }\r
 940         }\r
 941         \r
 942         if ("" == keys) {\r
 943                 if (sbar_showbinds > 1)\r
 944                         return strcat(text, " (not bound)");\r
 945                 else\r
 946                         return text;\r
 947         }\r
 948         else if (sbar_showbinds > 1)\r
 949                 return strcat(text, " (", keys, ")");\r
 950         else\r
 951                 return keys;\r
 952 }\r