configure.ac

   1 AC_PREREQ([2.54])
   2 AC_INIT([openbox], [3.5.0], [http://bugzilla.icculus.org])
   3 AC_CONFIG_SRCDIR([openbox/openbox.c])
   4
   5 AM_INIT_AUTOMAKE([foreign])
   6 AM_SILENT_RULES([yes])
   7
   8 OB_VERSION=$PACKAGE_VERSION
   9 AC_SUBST(OB_VERSION)
  10
  11 dnl Making releases:
  12 dnl   RR_MICRO_VERSION += 1;
  13 dnl   RR_INTERFACE_AGE += 1;
  14 dnl   R_BINARY_AGE += 1;
  15 dnl if any functions have been added, set RR_INTERFACE_AGE to 0.
  16 dnl if backwards compatibility has been broken,
  17 dnl set RR_BINARY_AGE and RR_INTERFACE_AGE to 0.
  18 dnl
  19 dnl if MAJOR or MINOR version changes, be sure to change AC_INIT above to match
  20 dnl
  21 RR_MAJOR_VERSION=3
  22 RR_MINOR_VERSION=5
  23 RR_MICRO_VERSION=28
  24 RR_INTERFACE_AGE=1
  25 RR_BINARY_AGE=1
  26 RR_VERSION=$RR_MAJOR_VERSION.$RR_MINOR_VERSION
  27
  28 OBT_MAJOR_VERSION=3
  29 OBT_MINOR_VERSION=5
  30 OBT_MICRO_VERSION=1
  31 OBT_INTERFACE_AGE=1
  32 OBT_BINARY_AGE=1
  33 OBT_VERSION=$OBT_MAJOR_VERSION.$OBT_MINOR_VERSION
  34
  35 AC_SUBST(RR_MAJOR_VERSION)
  36 AC_SUBST(RR_MINOR_VERSION)
  37 AC_SUBST(RR_MICRO_VERSION)
  38 AC_SUBST(RR_INTERFACE_AGE)
  39 AC_SUBST(RR_BINARY_AGE)
  40 AC_SUBST(RR_VERSION)
  41 AC_SUBST(OBT_MAJOR_VERSION)
  42 AC_SUBST(OBT_MINOR_VERSION)
  43 AC_SUBST(OBT_MICRO_VERSION)
  44 AC_SUBST(OBT_INTERFACE_AGE)
  45 AC_SUBST(OBT_BINARY_AGE)
  46 AC_SUBST(OBT_VERSION)
  47
  48 dnl Libtool versioning
  49 RR_RELEASE=$RR_MAJOR_VERSION.$RR_MINOR_VERSION
  50 RR_CURRENT=`expr $RR_MICRO_VERSION - $RR_INTERFACE_AGE`
  51 RR_REVISION=$RR_INTERFACE_AGE
  52 RR_AGE=`expr $RR_BINARY_AGE - $RR_INTERFACE_AGE`
  53 RR_CURRENT_MINUS_AGE=`expr $RR_CURRENT - $RR_AGE`
  54
  55 OBT_RELEASE=$OBT_MAJOR_VERSION.$OBT_MINOR_VERSION
  56 OBT_CURRENT=`expr $OBT_MICRO_VERSION - $OBT_INTERFACE_AGE`
  57 OBT_REVISION=$OBT_INTERFACE_AGE
  58 OBT_AGE=`expr $OBT_BINARY_AGE - $OBT_INTERFACE_AGE`
  59 OBT_CURRENT_MINUS_AGE=`expr $OBT_CURRENT - $OBT_AGE`
  60
  61 AC_SUBST(RR_RELEASE)
  62 AC_SUBST(RR_CURRENT)
  63 AC_SUBST(RR_REVISION)
  64 AC_SUBST(RR_AGE)
  65 AC_SUBST(RR_CURRENT_MINUS_AGE)
  66 AC_SUBST(OBT_RELEASE)
  67 AC_SUBST(OBT_CURRENT)
  68 AC_SUBST(OBT_REVISION)
  69 AC_SUBST(OBT_AGE)
  70 AC_SUBST(OBT_CURRENT_MINUS_AGE)
  71
  72 AC_PREFIX_DEFAULT([/usr/local])
  73 test "$prefix" = "NONE" && prefix=$ac_default_prefix
  74
  75 dnl Determine build target
  76 OB_DEBUG
  77 dnl Pick compiler specific/build target flags, and set $CVS
  78 AM_PROG_CC_C_O
  79 OB_COMPILER_FLAGS
  80 AC_C_CONST
  81 AC_C_INLINE
  82
  83 AC_PROG_LIBTOOL
  84 AC_SUBST(LIBTOOL_DEPS)
  85 LIBTOOL="$LIBTOOL --silent"
  86
  87 AC_PROG_INSTALL
  88
  89 AM_GNU_GETTEXT_VERSION(0.15)
  90 AM_GNU_GETTEXT([external])
  91
  92 AC_CHECK_HEADERS(ctype.h dirent.h errno.h fcntl.h grp.h locale.h pwd.h)
  93 AC_CHECK_HEADERS(signal.h string.h stdio.h stdlib.h unistd.h sys/stat.h)
  94 AC_CHECK_HEADERS(sys/select.h sys/socket.h sys/time.h sys/types.h sys/wait.h)
  95 AC_CHECK_HEADERS(sys/inotify.h)
  96
  97 AC_PATH_PROG([SED], [sed], [no])
  98 if test "$SED" = "no"; then
  99   AC_MSG_ERROR([The program "sed" is not available. This program is required to build Openbox.])
 100 fi
 101
 102 AC_PATH_PROG([DIRNAME], [dirname], [no])
 103 if test "$DIRNAME" = "no"; then
 104   AC_MSG_ERROR([The program "dirname" is not available. This program is required to build Openbox.])
 105 fi
 106
 107 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.14.0])
 108 AC_SUBST(GLIB_CFLAGS)
 109 AC_SUBST(GLIB_LIBS)
 110
 111 PKG_CHECK_MODULES(PANGO, [pango >= 1.8.0 pangoxft >= 1.8.0])
 112 AC_SUBST(PANGO_CFLAGS)
 113 AC_SUBST(PANGO_LIBS)
 114
 115 PKG_CHECK_MODULES(XML, [libxml-2.0 >= 2.6.0])
 116 AC_SUBST(XML_CFLAGS)
 117 AC_SUBST(XML_LIBS)
 118
 119 AC_ARG_ENABLE(startup-notification,
 120   AC_HELP_STRING(
 121     [--disable-startup-notification],
 122     [disable the startup notification library. [default=enabled]]
 123   ),
 124   [enable_sn=$enableval],
 125   [enable_sn=yes]
 126 )
 127
 128 if test "$enable_sn" = yes; then
 129 PKG_CHECK_MODULES(LIBSN, [libstartup-notification-1.0 >= 0.8],
 130   [
 131     AC_DEFINE(USE_LIBSN, [1], [Use startup-notification])
 132     AC_SUBST(LIBSN_CFLAGS)
 133     AC_SUBST(LIBSN_LIBS)
 134     sn_found=yes
 135   ],
 136   [
 137     sn_found=no
 138   ]
 139 )
 140 else
 141   sn_found=no
 142 fi
 143
 144 AC_ARG_ENABLE(xcursor,
 145   AC_HELP_STRING(
 146     [--disable-xcursor],
 147     [disable use of the X Cursor library. [default=enabled]]
 148   ),
 149   [enable_xcursor=$enableval],
 150   [enable_xcursor=yes]
 151 )
 152
 153 if test "$enable_xcursor" = yes; then
 154 PKG_CHECK_MODULES(XCURSOR, [xcursor],
 155   [
 156     AC_DEFINE(USE_XCURSOR, [1], [Use X Cursor library])
 157     AC_SUBST(XCURSOR_CFLAGS)
 158     AC_SUBST(XCURSOR_LIBS)
 159     xcursor_found=yes
 160   ],
 161   [
 162     xcursor_found=no
 163   ]
 164 )
 165 else
 166   xcursor_found=no
 167 fi
 168
 169 AC_ARG_ENABLE(imlib2,
 170   AC_HELP_STRING(
 171     [--disable-imlib2],
 172     [disable use of Imlib2 image library for loading icons. [default=enabled]]
 173   ),
 174   [enable_imlib2=$enableval],
 175   [enable_imlib2=yes]
 176 )
 177
 178 if test "$enable_imlib2" = yes; then
 179 PKG_CHECK_MODULES(IMLIB2, [imlib2],
 180   [
 181     AC_DEFINE(USE_IMLIB2, [1], [Use Imlib2 image library])
 182     AC_SUBST(IMLIB2_CFLAGS)
 183     AC_SUBST(IMLIB2_LIBS)
 184     # export it for the pkg-config file
 185     PKG_CONFIG_IMLIB=imlib2
 186     AC_SUBST(PKG_CONFIG_IMLIB)
 187     imlib2_found=yes
 188   ],
 189   [
 190     imlib2_found=no
 191   ]
 192 )
 193 else
 194   imlib2_found=no
 195 fi
 196
 197 AM_CONDITIONAL(USE_IMLIB2, [test $imlib2_found = yes])
 198
 199 dnl Check for session management
 200 X11_SM
 201
 202 #EFENCE_LIBS=-lefence
 203 EFENCE_LIBS=""
 204 AC_SUBST(EFENCE_LIBS)
 205
 206 dnl Check for X11 extensions
 207 X11_EXT_XKB
 208 X11_EXT_XRANDR
 209 X11_EXT_SHAPE
 210 X11_EXT_XINERAMA
 211 X11_EXT_SYNC
 212 X11_EXT_AUTH
 213
 214 AC_CONFIG_FILES([
 215   Makefile
 216   m4/Makefile
 217   po/Makefile.in
 218   obrender/obrender-3.5.pc
 219   obt/obt-3.5.pc
 220   obrender/version.h
 221   obt/version.h
 222   version.h
 223 ])
 224 AC_CONFIG_COMMANDS([doc],
 225                    [test -d doc || mkdir doc])
 226 AC_CONFIG_COMMANDS([data],
 227                    [test -d data || mkdir data])
 228 AC_CONFIG_COMMANDS([data/xsession],
 229                    [test -d data/xsession || mkdir data/xsession])
 230 AC_OUTPUT
 231
 232 AC_MSG_RESULT
 233 AC_MSG_RESULT([Compiling with these options:
 234                Startup Notification... $sn_found
 235                X Cursor Library... $xcursor_found
 236                Session Management... $SM
 237                Imlib2 library... $imlib2_found
 238                ])
 239 AC_MSG_RESULT([configure complete, now type "make"])