cmake/FindSDL2.cmake

   1 # - Locate SDL2 library (modified from CMake's FindSDL.cmake)
   2 # This module defines
   3 #  SDL2_LIBRARY, the name of the library to link against
   4 #  SDL2_FOUND, if false, do not try to link to SDL
   5 #  SDL2_INCLUDE_DIR, where to find SDL.h
   6 #  SDL2_VERSION_STRING, human-readable string containing the version of SDL2
   7 #
   8 # This module responds to the the flag:
   9 #  SDL2_BUILDING_LIBRARY
  10 #    If this is defined, then no SDL_main will be linked in because
  11 #    only applications need main().
  12 #    Otherwise, it is assumed you are building an application and this
  13 #    module will attempt to locate and set the the proper link flags
  14 #    as part of the returned SDL2_LIBRARY variable.
  15 #
  16 # Additional Note: If you see an empty SDL2_LIBRARY_TEMP in your configuration
  17 # and no SDL2_LIBRARY, it means CMake did not find your SDL2 library
  18 # (SDL2.dll, libsdl2.so, SDL2.framework, etc).
  19 # Set SDL2_LIBRARY_TEMP to point to your SDL2 library, and configure again.
  20 # Similarly, if you see an empty SDL2MAIN_LIBRARY, you should set this value
  21 # as appropriate. These values are used to generate the final SDL2_LIBRARY
  22 # variable, but when these values are unset, SDL2_LIBRARY does not get created.
  23 #
  24 #
  25 # $SDL2DIR is an environment variable that would
  26 # correspond to the ./configure --prefix=$SDL2DIR
  27 # used in building SDL.
  28 #
  29
  30 #=============================================================================
  31 # Copyright 2014 Justin Jacobs
  32 #
  33 # Distributed under the OSI-approved BSD License (the "License");
  34 # see accompanying file Copyright.txt for details.
  35 #
  36 # This software is distributed WITHOUT ANY WARRANTY; without even the
  37 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  38 # See the License for more information.
  39 #=============================================================================
  40
  41 find_path(SDL2_INCLUDE_DIR SDL.h
  42   HINTS
  43     "${SDL2DIR}"
  44         ENV SDL2DIR
  45         PATH_SUFFIXES include/SDL2 include
  46 )
  47
  48 if(CMAKE_SIZEOF_VOID_P EQUAL 8)
  49   set(VC_LIB_PATH_SUFFIX lib/x64)
  50 else()
  51   set(VC_LIB_PATH_SUFFIX lib/x86)
  52 endif()
  53
  54 find_library(SDL2_LIBRARY_TEMP
  55   NAMES SDL2
  56   HINTS
  57     "${SDL2DIR}"
  58         ENV SDL2DIR
  59   PATH_SUFFIXES lib "${VC_LIB_PATH_SUFFIX}"
  60 )
  61
  62 if(NOT SDL2_BUILDING_LIBRARY)
  63   if(NOT ${SDL2_INCLUDE_DIR} MATCHES ".framework")
  64         # Non-OS X framework versions expect you to also dynamically link to
  65         # SDLmain. This is mainly for Windows and OS X. Other (Unix) platforms
  66         # seem to provide SDLmain for compatibility even though they don't
  67         # necessarily need it.
  68         find_library(SDL2MAIN_LIBRARY
  69           NAMES SDL2main
  70           HINTS
  71             "${SDL2DIR}"
  72                 ENV SDL2DIR
  73           PATH_SUFFIXES lib "${VC_LIB_PATH_SUFFIX}"
  74           PATHS
  75           /sw
  76           /opt/local
  77           /opt/csw
  78           /opt
  79         )
  80   endif()
  81 endif()
  82
  83 # SDL2 may require threads on your system.
  84 # The Apple build may not need an explicit flag because one of the
  85 # frameworks may already provide it.
  86 # But for non-OSX systems, I will use the CMake Threads package.
  87 if(NOT APPLE)
  88   find_package(Threads)
  89 endif()
  90
  91 # MinGW needs an additional library, mwindows
  92 # It's total link flags should look like -lmingw32 -lSDLmain -lSDL -lmwindows
  93 # (Actually on second look, I think it only needs one of the m* libraries.)
  94 if(MINGW)
  95   set(MINGW32_LIBRARY mingw32 CACHE STRING "mwindows for MinGW")
  96 endif()
  97
  98 if(SDL2_LIBRARY_TEMP)
  99   # For SDLmain
 100   if(SDL2MAIN_LIBRARY AND NOT SDL2_BUILDING_LIBRARY)
 101         list(FIND SDL2_LIBRARY_TEMP "${SDL2MAIN_LIBRARY}" _SDL2_MAIN_INDEX)
 102         if(_SDL2_MAIN_INDEX EQUAL -1)
 103           set(SDL2_LIBRARY_TEMP "${SDL2MAIN_LIBRARY}" ${SDL2_LIBRARY_TEMP})
 104         endif()
 105         unset(_SDL2_MAIN_INDEX)
 106   endif()
 107
 108   # For OS X, SDL uses Cocoa as a backend so it must link to Cocoa.
 109   # CMake doesn't display the -framework Cocoa string in the UI even
 110   # though it actually is there if I modify a pre-used variable.
 111   # I think it has something to do with the CACHE STRING.
 112   # So I use a temporary variable until the end so I can set the
 113   # "real" variable in one-shot.
 114   if(APPLE)
 115         set(SDL2_LIBRARY_TEMP ${SDL2_LIBRARY_TEMP} "-framework Cocoa")
 116   endif()
 117
 118   # For threads, as mentioned Apple doesn't need this.
 119   # In fact, there seems to be a problem if I used the Threads package
 120   # and try using this line, so I'm just skipping it entirely for OS X.
 121   if(NOT APPLE)
 122         set(SDL2_LIBRARY_TEMP ${SDL2_LIBRARY_TEMP} ${CMAKE_THREAD_LIBS_INIT})
 123   endif()
 124
 125   # For MinGW library
 126   if(MINGW)
 127         set(SDL2_LIBRARY_TEMP ${MINGW32_LIBRARY} ${SDL2_LIBRARY_TEMP})
 128   endif()
 129
 130   # Set the final string here so the GUI reflects the final state.
 131   set(SDL2_LIBRARY ${SDL2_LIBRARY_TEMP} CACHE STRING "Where the SDL2 Library can be found")
 132   # Set the temp variable to INTERNAL so it is not seen in the CMake GUI
 133   set(SDL2_LIBRARY_TEMP "${SDL2_LIBRARY_TEMP}" CACHE INTERNAL "")
 134 endif()
 135
 136 if(SDL2_INCLUDE_DIR AND EXISTS "${SDL2_INCLUDE_DIR}/SDL_version.h")
 137   file(STRINGS "${SDL2_INCLUDE_DIR}/SDL_version.h" SDL2_VERSION_MAJOR_LINE REGEX "^#define[ \t]+SDL_MAJOR_VERSION[ \t]+[0-9]+$")
 138   file(STRINGS "${SDL2_INCLUDE_DIR}/SDL_version.h" SDL2_VERSION_MINOR_LINE REGEX "^#define[ \t]+SDL_MINOR_VERSION[ \t]+[0-9]+$")
 139   file(STRINGS "${SDL2_INCLUDE_DIR}/SDL_version.h" SDL2_VERSION_PATCH_LINE REGEX "^#define[ \t]+SDL_PATCHLEVEL[ \t]+[0-9]+$")
 140   string(REGEX REPLACE "^#define[ \t]+SDL_MAJOR_VERSION[ \t]+([0-9]+)$" "\\1" SDL2_VERSION_MAJOR "${SDL2_VERSION_MAJOR_LINE}")
 141   string(REGEX REPLACE "^#define[ \t]+SDL_MINOR_VERSION[ \t]+([0-9]+)$" "\\1" SDL2_VERSION_MINOR "${SDL2_VERSION_MINOR_LINE}")
 142   string(REGEX REPLACE "^#define[ \t]+SDL_PATCHLEVEL[ \t]+([0-9]+)$" "\\1" SDL2_VERSION_PATCH "${SDL2_VERSION_PATCH_LINE}")
 143   set(SDL2_VERSION_STRING ${SDL2_VERSION_MAJOR}.${SDL2_VERSION_MINOR}.${SDL2_VERSION_PATCH})
 144   unset(SDL2_VERSION_MAJOR_LINE)
 145   unset(SDL2_VERSION_MINOR_LINE)
 146   unset(SDL2_VERSION_PATCH_LINE)
 147   unset(SDL2_VERSION_MAJOR)
 148   unset(SDL2_VERSION_MINOR)
 149   unset(SDL2_VERSION_PATCH)
 150 endif()
 151
 152 include(FindPackageHandleStandardArgs)
 153
 154 FIND_PACKAGE_HANDLE_STANDARD_ARGS(SDL2
 155                                                                   REQUIRED_VARS SDL2_LIBRARY SDL2_INCLUDE_DIR
 156                                                                   VERSION_VAR SDL2_VERSION_STRING)
 157