configure.in

   1 dnl configure.in for Openbox
   2 dnl Initialize autoconf and automake
   3 AC_INIT(src/blackbox.cc)
   4 AM_INIT_AUTOMAKE(openbox,2.0.0,no-define)
   5
   6 dnl Determine default prefix
   7 test x$prefix = "xNONE" && prefix="$ac_default_prefix"
   8
   9 dnl Check for various flavors of UNIX(r)
  10 dnl AC_AIX
  11 dnl AC_ISC_POSIX
  12
  13 dnl Locate required external software
  14 AC_PROG_CC
  15 AC_PROG_CXX
  16 AC_PROG_INSTALL
  17
  18 AC_CHECK_PROGS(regex_cmd, sed)
  19 if test x$regex_cmd = "x"; then
  20   AC_MSG_ERROR([error. sed is required to build the default menu file.])
  21 fi
  22
  23 dnl Check for system header files
  24 AC_CHECK_HEADERS(ctype.h dirent.h fcntl.h libgen.h locale.h nl_types.h process.h signal.h stdarg.h stdio.h string.h stdlib.h time.h unistd.h sys/param.h sys/select.h sys/signal.h sys/stat.h sys/time.h sys/types.h sys/wait.h)
  25 AC_HEADER_TIME
  26
  27 dnl Check for existance of basename(), setlocale() and strftime()
  28 AC_CHECK_FUNCS(basename, , AC_CHECK_LIB(gen, basename,
  29                           AC_DEFINE(HAVE_BASENAME) LIBS="$LIBS -lgen"))
  30 AC_CHECK_FUNCS(getpid setlocale sigaction strftime strcasestr snprintf vsnprintf catopen catgets catclose)
  31 AC_CHECK_LIB(nsl, t_open, LIBS="$LIBS -lnsl")
  32 AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
  33
  34 dnl Check for X headers and libraries
  35 AC_PATH_X
  36 AC_PATH_XTRA
  37
  38 test x$no_x = "xyes" && AC_MSG_ERROR([Openbox requires the X Window System libraries and headers.])
  39
  40 test x$x_includes = "x" && x_includes="/usr/include"
  41 test x$x_libraries = "x" && x_libraries="/usr/lib"
  42
  43 CFLAGS="$CFLAGS $X_CFLAGS"
  44 CXXFLAGS="$CXXFLAGS $X_CFLAGS"
  45 LIBS="$LIBS $X_LIBS"
  46 LDFLAGS="$LDFLAGS $LIBS $X_PRE_LIBS"
  47
  48 dnl Check for required functions in -lX11
  49 AC_CHECK_LIB(X11, XOpenDisplay,
  50   LIBS="$LIBS -lX11",
  51   AC_MSG_ERROR([Could not find XOpenDisplay in -lX11.])
  52 )
  53
  54 LIBS="$LIBS $X_EXTRA_LIBS"
  55
  56 dnl Check for XShape extension support and proper library files.
  57 SHAPE=""
  58 AC_MSG_CHECKING([whether to build support for the XShape extension])
  59 AC_ARG_ENABLE(
  60   shape, [  --enable-shape          enable support of the XShape extension [default=yes]])
  61
  62 : ${enableval="yes"}
  63 if test x$enableval = "xyes"; then
  64   AC_MSG_RESULT([yes])
  65   AC_CHECK_LIB(Xext, XShapeCombineShape,
  66         AC_MSG_CHECKING([for X11/extensions/shape.h])
  67         AC_TRY_LINK(
  68 #include <X11/Xlib.h>
  69 #include <X11/Xutil.h>
  70 #include <X11/extensions/shape.h>
  71 , long foo = ShapeSet,
  72           AC_MSG_RESULT([yes])
  73           SHAPE="yes",
  74           AC_MSG_RESULT([no])
  75         )
  76   )
  77 else
  78   AC_MSG_RESULT([no])
  79 fi
  80 if test x$SHAPE = "xyes"; then
  81   LIBS="$LIBS -lXext"
  82   AC_DEFINE(SHAPE,1,Enable support of the XShape extension)
  83 fi
  84
  85 dnl Check for Xft extension support and proper library files.
  86 XFT=""
  87 AC_MSG_CHECKING([whether to build support for the Xft extension])
  88 AC_ARG_ENABLE(
  89   xft, [  --enable-xft            enable support of the Xft extension [default=no]],
  90   if test x$enableval = "xyes"; then
  91         AC_MSG_RESULT([yes])
  92
  93         AC_CHECK_LIB(Xft, XftFontOpenXlfd,
  94           AC_MSG_CHECKING([for X11/Xft/Xft.h])
  95           AC_TRY_LINK(
  96 #include <X11/Xlib.h>
  97 #include <X11/Xft/Xft.h>
  98 , XftFont foo,
  99         AC_MSG_RESULT([yes])
 100             XFT="yes"
 101                 LIBS="$LIBS -lXft",
 102         AC_MSG_RESULT([no])
 103           )
 104     )
 105
 106   else
 107         AC_MSG_RESULT([no])
 108   fi,
 109   AC_MSG_RESULT([no])
 110 )
 111 if test x$XFT = "xyes"; then
 112   AC_DEFINE(XFT,1,Enable support of the Xft extension)
 113 fi
 114
 115 dnl Check for ordered 8bpp dithering
 116 ORDEREDPSEUDO=""
 117 AC_MSG_CHECKING([whether to include Pseudocolor ordered dithering code])
 118 AC_ARG_ENABLE(ordered-pseudo,
 119 [  --enable-ordered-pseudo include code for ordered pseudocolor (8bpp)
 120                           dithering [default=no]],
 121   if test x$enableval = "xyes"; then
 122     AC_MSG_RESULT([yes])
 123     ORDEREDPSEUDO="yes"
 124   else
 125     AC_MSG_RESULT([no])
 126   fi,
 127   AC_MSG_RESULT([no])
 128 )
 129 if test x$ORDEREDPSEUDO = "xyes"; then
 130   AC_DEFINE(ORDEREDPSEUDO,1,Enable pseudocolor ordered dithering)
 131 fi
 132
 133 dnl Check whether to include debugging code
 134 DEBUG=""
 135 AC_MSG_CHECKING([whether to include verbose debugging code])
 136 AC_ARG_ENABLE(debug,
 137   [  --enable-debug          include verbose debugging code [default=no]],
 138   if test x$enableval = "xyes"; then
 139     AC_MSG_RESULT([yes])
 140     DEBUG="-DDEBUG -Wall -W -fno-inline"
 141   else
 142     AC_MSG_RESULT([no])
 143     DEBUG="-DNDEBUG"
 144   fi,
 145   AC_MSG_RESULT([no])
 146   DEBUG="-DNDEBUG"
 147 )
 148 AC_SUBST(DEBUG)
 149
 150 dnl Check whether to include natural language support (i18n)
 151 NLS=""
 152 AC_MSG_CHECKING([whether to include NLS support])
 153 AC_ARG_ENABLE(nls,
 154   [  --enable-nls            include natural language support [default=yes]],
 155   if test x$enableval = "xyes"; then
 156     AC_MSG_RESULT([yes])
 157     NLS="yes"
 158   else
 159     AC_MSG_RESULT([no])
 160   fi,
 161   AC_MSG_RESULT([yes])
 162   NLS="yes"
 163 )
 164
 165 AC_CHECK_LIB(xpg4, setlocale, LIBS="$LIBS -lxpg4")
 166
 167 AC_CHECK_PROGS(gencat_cmd, gencat)
 168 if test x$gencat_cmd = "x"; then
 169   NLS=""
 170 fi
 171
 172 if test x$NLS = "xyes"; then
 173   AC_DEFINE(NLS,1,Include natural language support)
 174   AC_SUBST(NLS)
 175 fi
 176
 177 dnl Check for new timed pixmap cache
 178 TIMEDCACHE=""
 179 AC_MSG_CHECKING([whether to use the timed pixmap cache])
 180 AC_ARG_ENABLE(
 181   timed-cache,
 182 [  --enable-timed-cache    use timed pixmap cache [default=yes]],
 183   if test x$enableval = "xyes"; then
 184     AC_MSG_RESULT([yes])
 185     TIMEDCACHE="yes"
 186   else
 187     AC_MSG_RESULT([no])
 188   fi,
 189   AC_MSG_RESULT([yes])
 190   TIMEDCACHE="yes"
 191 )
 192 if test x$TIMEDCACHE = "xyes"; then
 193   AC_DEFINE(TIMEDCACHE,1,Use timed pixmap cache)
 194 fi
 195
 196 dnl Determine the return type of signal handlers
 197 AC_TYPE_SIGNAL
 198
 199 dnl Determine if maintainer portions of the Makefiles should be included.
 200 AM_MAINTAINER_MODE
 201
 202 dnl Print results
 203 AC_MSG_RESULT([])
 204 AC_MSG_RESULT([ $PACKAGE version $VERSION configured successfully.])
 205 AC_MSG_RESULT([])
 206 AC_MSG_RESULT([Using '$prefix' for installation.])
 207 AC_MSG_RESULT([Using '$CXX' for C++ compiler.])
 208 AC_MSG_RESULT([Building with '$CXXFLAGS' for C++ compiler flags.])
 209 AC_MSG_RESULT([Building with '$LIBS' for linker flags.])
 210 AC_MSG_RESULT([])
 211
 212 dnl Output files
 213 AM_CONFIG_HEADER(config.h)
 214 AC_OUTPUT(Makefile
 215 src/Makefile
 216 util/Makefile
 217 util/epist/Makefile
 218 data/Makefile
 219 data/styles/Makefile
 220 doc/Makefile
 221 nls/Makefile
 222 nls/C/Makefile
 223 nls/da_DK/Makefile
 224 nls/de_DE/Makefile
 225 nls/es_ES/Makefile
 226 nls/et_EE/Makefile
 227 nls/fr_FR/Makefile
 228 nls/hu_HU/Makefile
 229 nls/it_IT/Makefile
 230 nls/ja_JP/Makefile
 231 nls/ko_KR/Makefile
 232 nls/no_NO/Makefile
 233 nls/nl_NL/Makefile
 234 nls/pt_BR/Makefile
 235 nls/ro_RO/Makefile
 236 nls/ru_RU/Makefile
 237 nls/sl_SI/Makefile
 238 nls/sv_SE/Makefile
 239 nls/tr_TR/Makefile
 240 nls/uk_UA/Makefile
 241 nls/zh_CN/Makefile
 242 nls/zh_TW/Makefile
 243 version.h)