configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 ###############################################################################
   5 #
   6 #   Copyright (C) 2007 Lasse Collin
   7 #
   8 #   This library is free software; you can redistribute it and/or
   9 #   modify it under the terms of the GNU Lesser General Public
  10 #   License as published by the Free Software Foundation; either
  11 #   version 2.1 of the License, or (at your option) any later version.
  12 #
  13 #   This library is distributed in the hope that it will be useful,
  14 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 #   Lesser General Public License for more details.
  17 #
  18 ###############################################################################
  19
  20 # NOTE: Don't add useless checks. autoscan detects this and that, but don't
  21 # let it confuse you. For example, we don't care about checking for behavior
  22 # of malloc(), stat(), or lstat(), since we don't use those functions in
  23 # a way that would cause the problems the autoconf macros check.
  24
  25 AC_PREREQ(2.61)
  26
  27 # [LZMA] instead of [LZMA utils] since I prefer to have lzma-version.tar.gz
  28 # instead of lzma-utils-version.tar.gz.
  29 AC_INIT([LZMA], [4.42.3alpha], [lasse.collin@tukaani.org])
  30
  31 AC_CONFIG_SRCDIR([src/liblzma/common/common.h])
  32 AC_CONFIG_HEADER([config.h])
  33
  34 echo
  35 echo "LZMA Utils $PACKAGE_VERSION"
  36
  37 echo
  38 echo "System type:"
  39 # This is needed to know if assembler optimizations can be used.
  40 AC_CANONICAL_HOST
  41
  42 echo
  43 echo "Configure options:"
  44
  45 # Enable/disable debugging code:
  46 AC_MSG_CHECKING([if debugging code should be compiled])
  47 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [Enable debugging code.]),
  48         [], enable_debug=no)
  49 if test "x$enable_debug" = xyes; then
  50         CFLAGS="-g $CFLAGS"
  51         AC_MSG_RESULT([yes])
  52 else
  53         AC_DEFINE(NDEBUG, 1, [Define to disable debugging code.])
  54         AC_MSG_RESULT([no])
  55 fi
  56
  57 # Enable/disable the encoder components:
  58 AC_MSG_CHECKING([if encoder components should be built])
  59 AC_ARG_ENABLE(encoder, AC_HELP_STRING([--disable-encoder],
  60                 [Do not build the encoder components.]),
  61         [], enable_encoder=yes)
  62 if test "x$enable_encoder" = xyes; then
  63         AC_DEFINE([HAVE_ENCODER], 1,
  64                 [Define to 1 if encoder components are enabled.])
  65         AC_MSG_RESULT([yes])
  66 else
  67         AC_MSG_RESULT([no])
  68 fi
  69 AM_CONDITIONAL(COND_MAIN_ENCODER, test "x$enable_encoder" = xyes)
  70
  71 # Enable/disable the decoder components:
  72 AC_MSG_CHECKING([if decoder components should be built])
  73 AC_ARG_ENABLE(decoder, AC_HELP_STRING([--disable-decoder],
  74                 [Do not build the decoder components.]),
  75         [], enable_decoder=yes)
  76 if test "x$enable_decoder" = xyes; then
  77         AC_DEFINE([HAVE_DECODER], 1,
  78                 [Define to 1 if decoder components are enabled.])
  79         AC_MSG_RESULT([yes])
  80 else
  81         AC_MSG_RESULT([no])
  82         if test "x$enable_encoder" = xno; then
  83                 AC_MSG_ERROR([Do not disable both encoder and decoder.])
  84         fi
  85 fi
  86 AM_CONDITIONAL(COND_MAIN_DECODER, test "x$enable_decoder" = xyes)
  87
  88 # Filters
  89 AC_MSG_CHECKING([which filters to build])
  90 AC_ARG_ENABLE(filters, AC_HELP_STRING([--enable-filters=],
  91                 [Comma-separated list of filters to build. Default=all.
  92                 Filters used in encoding are needed also in decoding.
  93                 Available filters: copy subblock x86 powerpc ia64
  94                 arm armthumb sparc delta lzma]),
  95                 [], [enable_filters=copy,subblock,x86,powerpc,ia64,arm,armthumb,sparc,delta,lzma])
  96 enable_filters=`echo "$enable_filters" | sed 's/,/ /g'`
  97 enable_filters_copy=no
  98 enable_filters_subblock=no
  99 enable_filters_x86=no
 100 enable_filters_powerpc=no
 101 enable_filters_ia64=no
 102 enable_filters_arm=no
 103 enable_filters_armthumb=no
 104 enable_filters_sparc=no
 105 enable_filters_delta=no
 106 enable_filters_lzma=no
 107 enable_simple_filters=no
 108 if test "x$enable_filters" = xno || test "x$enable_filters" = x; then
 109         AC_MSG_RESULT([])
 110         AC_MSG_ERROR([Please enable at least one filter.])
 111 else
 112         for arg in $enable_filters
 113         do
 114                 case $arg in
 115                         copy)
 116                                 enable_filters_copy=yes
 117                                 AC_DEFINE([HAVE_FILTER_COPY], 1,
 118                                         [Define to 1 if support for the
 119                                         Copy filter is enabled.])
 120                                 ;;
 121                         subblock)
 122                                 enable_filters_subblock=yes
 123                                 AC_DEFINE([HAVE_FILTER_SUBBLOCK], 1,
 124                                         [Define to 1 if support for the
 125                                         Subblock filter is enabled.])
 126                                 ;;
 127                         x86)
 128                                 enable_filters_x86=yes
 129                                 enable_simple_filters=yes
 130                                 AC_DEFINE([HAVE_FILTER_X86], 1,
 131                                         [Define to 1 if support for the
 132                                         x86 (BCJ) filter is enabled.])
 133                                 ;;
 134                         powerpc)
 135                                 enable_filters_powerpc=yes
 136                                 enable_simple_filters=yes
 137                                 AC_DEFINE([HAVE_FILTER_POWERPC], 1,
 138                                         [Define to 1 if support for the
 139                                         PowerPC filter is enabled.])
 140                                 ;;
 141                         ia64)
 142                                 enable_filters_ia64=yes
 143                                 enable_simple_filters=yes
 144                                 AC_DEFINE([HAVE_FILTER_IA64], 1,
 145                                         [Define to 1 if support for the
 146                                         IA64 filter is enabled.])
 147                                 ;;
 148                         arm)
 149                                 enable_filters_arm=yes
 150                                 enable_simple_filters=yes
 151                                 AC_DEFINE([HAVE_FILTER_ARM], 1,
 152                                         [Define to 1 if support for the
 153                                         ARM filter is enabled.])
 154                                 ;;
 155                         armthumb)
 156                                 enable_filters_armthumb=yes
 157                                 enable_simple_filters=yes
 158                                 AC_DEFINE([HAVE_FILTER_ARMTHUMB], 1,
 159                                         [Define to 1 if support for the
 160                                         ARMThumb filter is enabled.])
 161                                 ;;
 162                         sparc)
 163                                 enable_filters_sparc=yes
 164                                 enable_simple_filters=yes
 165                                 AC_DEFINE([HAVE_FILTER_SPARC], 1,
 166                                         [Define to 1 if support for the
 167                                         SPARC filter is enabled.])
 168                                 ;;
 169                         delta)
 170                                 enable_filters_delta=yes
 171                                 AC_DEFINE([HAVE_FILTER_DELTA], 1,
 172                                         [Define to 1 if support for the
 173                                         Delta filter is enabled.])
 174                                 ;;
 175                         lzma)
 176                                 enable_filters_lzma=yes
 177                                 AC_DEFINE([HAVE_FILTER_LZMA], 1,
 178                                         [Define to 1 if support for the
 179                                         LZMA filter is enabled.])
 180                                 ;;
 181                         *)
 182                                 AC_MSG_RESULT([])
 183                                 AC_MSG_ERROR([unknown filter: $arg])
 184                                 ;;
 185                 esac
 186         done
 187         AC_MSG_RESULT([$enable_filters])
 188 fi
 189 if test "x$enable_simple_filters" = xyes ; then
 190         AC_DEFINE([HAVE_FILTER_SIMPLE], 1, [Define to 1 if support for any
 191                 of the so called simple filters is enabled.])
 192 fi
 193 AM_CONDITIONAL(COND_FILTER_COPY, test "x$enable_filters_copy" = xyes)
 194 AM_CONDITIONAL(COND_FILTER_SUBBLOCK, test "x$enable_filters_subblock" = xyes)
 195 AM_CONDITIONAL(COND_FILTER_X86, test "x$enable_filters_x86" = xyes)
 196 AM_CONDITIONAL(COND_FILTER_POWERPC, test "x$enable_filters_powerpc" = xyes)
 197 AM_CONDITIONAL(COND_FILTER_IA64, test "x$enable_filters_ia64" = xyes)
 198 AM_CONDITIONAL(COND_FILTER_ARM, test "x$enable_filters_arm" = xyes)
 199 AM_CONDITIONAL(COND_FILTER_ARMTHUMB, test "x$enable_filters_armthumb" = xyes)
 200 AM_CONDITIONAL(COND_FILTER_SPARC, test "x$enable_filters_sparc" = xyes)
 201 AM_CONDITIONAL(COND_FILTER_DELTA, test "x$enable_filters_delta" = xyes)
 202 AM_CONDITIONAL(COND_FILTER_LZMA, test "x$enable_filters_lzma" = xyes)
 203 AM_CONDITIONAL(COND_MAIN_SIMPLE, test "x$enable_simple_filters" = xyes)
 204
 205 # Which match finders should be enabled:
 206 AC_MSG_CHECKING([which match finders to build])
 207 AC_ARG_ENABLE(match-finders, AC_HELP_STRING([--enable-match-finders=],
 208                 [Comma-separated list of match finders to build. Default=all.
 209                 At least one match finder is required for encoding with
 210                 the LZMA filter.
 211                 Available match finders: hc3 hc4 bt2 bt3 bt4]), [],
 212         [enable_match_finders=hc3,hc4,bt2,bt3,bt4])
 213 enable_match_finders=`echo "$enable_match_finders" | sed 's/,/ /g'`
 214 enable_match_finders_hc3=no
 215 enable_match_finders_hc4=no
 216 enable_match_finders_bt2=no
 217 enable_match_finders_bt3=no
 218 enable_match_finders_bt4=no
 219 if test "x$enable_encoder" = xyes && test "x$enable_filters_lzma" = xyes ; then
 220         for arg in $enable_match_finders
 221                 do
 222                 case $arg in
 223                         hc3) enable_match_finders_hc3=yes ;;
 224                         hc4) enable_match_finders_hc4=yes ;;
 225                         bt2) enable_match_finders_bt2=yes ;;
 226                         bt3) enable_match_finders_bt3=yes ;;
 227                         bt4) enable_match_finders_bt4=yes ;;
 228                         *)
 229                                 AC_MSG_RESULT([])
 230                                 AC_MSG_ERROR([unknown match finder: $arg])
 231                                 ;;
 232                 esac
 233         done
 234         AC_MSG_RESULT([$enable_match_finders])
 235 else
 236         AC_MSG_RESULT([(none because not building the LZMA encoder)])
 237 fi
 238 AM_CONDITIONAL(COND_MF_HC3, test "x$enable_match_finders_hc3" = xyes)
 239 AM_CONDITIONAL(COND_MF_HC4, test "x$enable_match_finders_hc4" = xyes)
 240 AM_CONDITIONAL(COND_MF_BT2, test "x$enable_match_finders_bt2" = xyes)
 241 AM_CONDITIONAL(COND_MF_BT3, test "x$enable_match_finders_bt3" = xyes)
 242 AM_CONDITIONAL(COND_MF_BT4, test "x$enable_match_finders_bt4" = xyes)
 243
 244 # Which integrity checks to build
 245 AC_MSG_CHECKING([which integrity checks to build])
 246 AC_ARG_ENABLE(checks, AC_HELP_STRING([--enable-checks=],
 247                 [Comma-separated list of integrity checks to build.
 248                 Default=all. Available integrity checks: crc32 crc64 sha256]),
 249                 [], [enable_checks=crc32,crc64,sha256])
 250 enable_checks=`echo "$enable_checks" | sed 's/,/ /g'`
 251 enable_checks_crc32=no
 252 enable_checks_crc64=no
 253 enable_checks_sha256=no
 254 if test "x$enable_checks" = xno || test "x$enable_checks" = x; then
 255         AC_MSG_RESULT([(none)])
 256 else
 257         for arg in $enable_checks
 258         do
 259                 case $arg in
 260                         crc32)
 261                                 enable_checks_crc32=yes
 262                                 AC_DEFINE([HAVE_CHECK_CRC32], 1,
 263                                         [Define to 1 if CRC32 support
 264                                         is enabled.])
 265                                 ;;
 266                         crc64)
 267                                 enable_checks_crc64=yes
 268                                 AC_DEFINE([HAVE_CHECK_CRC64], 1,
 269                                         [Define to 1 if CRC64 support
 270                                         is enabled.])
 271                                 ;;
 272                         sha256)
 273                                 enable_checks_sha256=yes
 274                                 AC_DEFINE([HAVE_CHECK_SHA256], 1,
 275                                         [Define to 1 if SHA256 support
 276                                         is enabled.])
 277                                 ;;
 278                         *)
 279                                 AC_MSG_RESULT([])
 280                                 AC_MSG_ERROR([unknown integrity check: $arg])
 281                                 ;;
 282                 esac
 283         done
 284         AC_MSG_RESULT([$enable_checks])
 285 fi
 286 if test "x$enable_checks_crc32" = xno ; then
 287         AC_MSG_ERROR([For now, the CRC32 check must always be enabled.])
 288 fi
 289 AM_CONDITIONAL(COND_CHECK_CRC32, test "x$enable_checks_crc32" = xyes)
 290 AM_CONDITIONAL(COND_CHECK_CRC64, test "x$enable_checks_crc64" = xyes)
 291 AM_CONDITIONAL(COND_CHECK_SHA256, test "x$enable_checks_sha256" = xyes)
 292
 293 # Assembler optimizations
 294 AC_MSG_CHECKING([if assembler optimizations should be used])
 295 AC_ARG_ENABLE(assembler, AC_HELP_STRING([--disable-assembler],
 296                 [Do not use assembler optimizations even if such exist
 297                 for the architecture.]),
 298                 [], [enable_assembler=yes])
 299 if test "x$enable_assembler" = xyes; then
 300         case $host_cpu in
 301                 i?86)   enable_assembler=x86 ;;
 302                 *)      enable_assembler=no ;;
 303         esac
 304 fi
 305 case $enable_assembler in
 306         x86|no) ;;
 307         *)
 308                 AC_MSG_RESULT([])
 309                 AC_MSG_ERROR([--enable-assembler accepts only \`yes', \`no', or \`x86'.])
 310                 ;;
 311 esac
 312 AC_MSG_RESULT([$enable_assembler])
 313 AM_CONDITIONAL(COND_ASM_X86, test "x$enable_assembler" = xx86)
 314
 315 # Size optimization
 316 AC_MSG_CHECKING([if small size is preferred over speed])
 317 AC_ARG_ENABLE(small, AC_HELP_STRING([--enable-small],
 318                 [Omit precomputed tables to make liblzma a few kilobytes
 319                 smaller. This will increase startup time of applications
 320                 slightly, because the tables need to be computed first.]),
 321                 [], [enable_small=no])
 322 if test "x$enable_small" = xyes; then
 323         AC_DEFINE([HAVE_SMALL], 1, [Define to 1 if optimizing for size.])
 324 elif test "x$enable_small" != xno; then
 325         AC_MSG_RESULT([])
 326         AC_MSG_ERROR([--enable-small accepts only \`yes' or \`no'])
 327 fi
 328 AC_MSG_RESULT([$enable_small])
 329 AM_CONDITIONAL(COND_SMALL, test "x$enable_small" = xyes)
 330
 331 echo
 332 echo "Initializing Automake:"
 333
 334 # There's no C++ or Fortran in LZMA Utils:
 335 CXX=no
 336 F77=no
 337
 338 AM_INIT_AUTOMAKE
 339
 340 AC_USE_SYSTEM_EXTENSIONS
 341
 342 ###############################################################################
 343 # Checks for programs.
 344 ###############################################################################
 345
 346 AM_PROG_CC_C_O
 347 AM_PROG_AS
 348 AC_PROG_LN_S
 349
 350 echo
 351 echo "Threading support:"
 352 ACX_PTHREAD
 353 CC="$PTHREAD_CC"
 354
 355 echo
 356 echo "Initializing Libtool:"
 357 AC_PROG_LIBTOOL
 358
 359
 360 ###############################################################################
 361 # Checks for libraries.
 362 ###############################################################################
 363
 364 echo
 365 echo "Initializing gettext:"
 366 AM_GNU_GETTEXT_VERSION([0.16.1])
 367 AM_GNU_GETTEXT([external])
 368
 369 ###############################################################################
 370 # Checks for header files.
 371 ###############################################################################
 372
 373 echo
 374 echo "System headers and functions:"
 375
 376 # There is currently no workarounds in this package if some of
 377 # these headers are missing.
 378 AC_CHECK_HEADERS([fcntl.h limits.h sys/time.h],
 379         [],
 380         [AC_MSG_ERROR([Required header file(s) are missing.])])
 381
 382 # If any of these headers are missing, things should still work correctly:
 383 AC_CHECK_HEADERS([assert.h errno.h byteswap.h sys/param.h sys/sysctl.h],
 384         [], [], [
 385 #ifdef HAVE_SYS_PARAM_H
 386 #       include <sys/param.h>
 387 #endif
 388 ])
 389
 390
 391 ###############################################################################
 392 # Checks for typedefs, structures, and compiler characteristics.
 393 ###############################################################################
 394
 395 AC_HEADER_STDBOOL
 396 AC_C_INLINE
 397 AC_C_RESTRICT
 398
 399 # The command line tool can copy high resolution timestamps if such
 400 # information is availabe in struct stat. Otherwise one second accuracy
 401 # is used. Most systems seem to have st_xtim but BSDs have st_xtimespec.
 402 AC_CHECK_MEMBERS([struct stat.st_atim.tv_nsec, struct stat.st_mtim.tv_nsec,
 403         struct stat.st_atimespec.tv_nsec, struct stat.st_mtimespec.tv_nsec])
 404
 405 # It is very unlikely that you want to build liblzma without
 406 # large file support.
 407 AC_SYS_LARGEFILE
 408
 409 # At the moment, the only endian-dependent part should be the integrity checks.
 410 AC_C_BIGENDIAN
 411
 412
 413 ###############################################################################
 414 # Checks for library functions.
 415 ###############################################################################
 416
 417 # Gnulib replacements as needed
 418 gl_GETOPT
 419
 420 # Functions that are not mandatory i.e. we have alternatives for them
 421 # or we can just drop some functionality:
 422 AC_CHECK_FUNCS([memcpy memmove memset futimes futimesat])
 423
 424 # Check how to find out the amount of physical memory in the system. The
 425 # lzma command line tool uses this to automatically limits its memory usage.
 426 # - sysconf() gives all the needed info on GNU+Linux and Solaris.
 427 # - BSDs use sysctl().
 428 AC_MSG_CHECKING([how to detect the amount of physical memory])
 429 AC_COMPILE_IFELSE([
 430 #include <unistd.h>
 431 int
 432 main()
 433 {
 434         long i;
 435         i = sysconf(_SC_PAGESIZE);
 436         i = sysconf(_SC_PHYS_PAGES);
 437         return 0;
 438 }
 439 ], [
 440         AC_DEFINE([HAVE_PHYSMEM_SYSCONF], 1,
 441                 [Define to 1 if the amount of physical memory can be detected
 442                 with sysconf(_SC_PAGESIZE) and sysconf(_SC_PHYS_PAGES).])
 443         AC_MSG_RESULT([sysconf])
 444 ], [
 445 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 446 #include <sys/types.h>
 447 #ifdef HAVE_SYS_PARAM_H
 448 #       include <sys/param.h>
 449 #endif
 450 #include <sys/sysctl.h>
 451 int
 452 main()
 453 {
 454         int name[2] = { CTL_HW, HW_PHYSMEM };
 455         unsigned long mem;
 456         size_t mem_ptr_size = sizeof(mem);
 457         sysctl(name, 2, &mem, &mem_ptr_size, NULL, NULL);
 458         return 0;
 459 }
 460 ]])], [
 461         AC_DEFINE([HAVE_PHYSMEM_SYSCTL], 1,
 462                 [Define to 1 if the amount of physical memory can be detected
 463                 with sysctl().])
 464         AC_MSG_RESULT([sysctl])
 465 ], [
 466         AC_MSG_RESULT([unknown])
 467 ])])
 468
 469 # Check how to find out the number of available CPU cores in the system.
 470 # sysconf(_SC_NPROCESSORS_ONLN) works on most systems, except that BSDs
 471 # use sysctl().
 472 AC_MSG_CHECKING([how to detect the number of available CPU cores])
 473 AC_COMPILE_IFELSE([
 474 #include <unistd.h>
 475 int
 476 main()
 477 {
 478         long i;
 479         i = sysconf(_SC_NPROCESSORS_ONLN);
 480         return 0;
 481 }
 482 ], [
 483         AC_DEFINE([HAVE_NCPU_SYSCONF], 1,
 484                 [Define to 1 if the number of available CPU cores can be
 485                 detected with sysconf(_SC_NPROCESSORS_ONLN).])
 486         AC_MSG_RESULT([sysconf])
 487 ], [
 488 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 489 #include <sys/types.h>
 490 #ifdef HAVE_SYS_PARAM_H
 491 #       include <sys/param.h>
 492 #endif
 493 #include <sys/sysctl.h>
 494 int
 495 main()
 496 {
 497         int name[2] = { CTL_HW, HW_NCPU };
 498         int cpus;
 499         size_t cpus_size = sizeof(cpus);
 500         sysctl(name, 2, &cpus, &cpus_size, NULL, NULL);
 501         return 0;
 502 }
 503 ]])], [
 504         AC_DEFINE([HAVE_NCPU_SYSCTL], 1,
 505                 [Define to 1 if the number of available CPU cores can be
 506                 detected with sysctl().])
 507         AC_MSG_RESULT([sysctl])
 508 ], [
 509         AC_MSG_RESULT([unknown])
 510 ])])
 511
 512
 513 ###############################################################################
 514 # If using GCC, set some additional CFLAGS:
 515 ###############################################################################
 516
 517 Wno_uninitialized=no
 518
 519 if test -n "$GCC" ; then
 520         echo
 521         echo "GCC extensions:"
 522         gl_VISIBILITY
 523         if test -n "$CFLAG_VISIBILITY" ; then
 524                 CFLAGS="$CFLAG_VISIBILITY $CFLAGS"
 525         fi
 526
 527         # -Wno-uninitialized is needed with -Werror with SHA256 code
 528         # to omit a bogus warning.
 529         AC_MSG_CHECKING([if $CC accepts -Wno-uninitialized])
 530         OLD_CFLAGS="$CFLAGS"
 531         CFLAGS="$CFLAGS -Wno-uninitialized"
 532         AC_COMPILE_IFELSE([void foo(void) { }], [Wno_uninitialized=yes])
 533         CFLAGS="$OLD_CFLAGS"
 534         AC_MSG_RESULT([$Wno_uninitialized])
 535
 536         # Enable as much warnings as possible. These commented warnings won't
 537         # work for LZMA Utils though:
 538         #   * -Wunreachable-code breaks several assert(0) cases, which are
 539         #     backed up with "return LZMA_PROG_ERROR".
 540         #   * -Wcast-qual would break various things where we need a non-const
 541         #     pointer although we don't modify anything through it.
 542         #   * -Wcast-align breaks optimized CRC32 and CRC64 implementation
 543         #     on some architectures (not on x86), where this warning is bogus,
 544         #     because we take care of correct alignment.
 545         #   * -Winline, -Wdisabled-optimization, -Wunsafe-loop-optimizations
 546         #     don't seem so useful here; at least the last one gives some
 547         #     warnings which are not bugs.
 548         for NEW_FLAG in -Wextra -Wformat=2 -Winit-self -Wstrict-aliasing=2 \
 549                         -Wfloat-equal -Wshadow  -Wpointer-arith \
 550                         -Wbad-function-cast -Wwrite-strings \
 551                         -Waggregate-return -Wstrict-prototypes \
 552                         -Wold-style-definition -Wmissing-prototypes \
 553                         -Wmissing-declarations -Wmissing-noreturn \
 554                         -Wredundant-decls
 555         do
 556                 AC_MSG_CHECKING([if $CC accepts $NEW_FLAG])
 557                 OLD_CFLAGS="$CFLAGS"
 558                 CFLAGS="$NEW_FLAG $CFLAGS"
 559                 AC_COMPILE_IFELSE([void foo(void) { }], [
 560                         AC_MSG_RESULT([yes])
 561                 ], [
 562                         CFLAGS="$OLD_CFLAGS"
 563                         AC_MSG_RESULT([no])
 564                 ])
 565         done
 566
 567         AC_ARG_ENABLE([werror],
 568                 AC_HELP_STRING([--enable-werror], [Enable -Werror to abort
 569                         compilation on all compiler warnings.]),
 570                 [], [enable_werror=no])
 571         if test "x$enable_werror" = "xyes"; then
 572                 CFLAGS="-Werror $CFLAGS"
 573         fi
 574
 575         # IIRC these work with all GCC versions that support -std=c99:
 576         CFLAGS="-std=c99 -pedantic -Wall $CFLAGS"
 577 fi
 578
 579 AM_CONDITIONAL([COND_WNO_UNINITIALIZED], test "x$Wno_uninitialized" = "xyes")
 580
 581
 582 ###############################################################################
 583 # Create the makefiles and config.h
 584 ###############################################################################
 585
 586 echo
 587
 588 # Don't build the lib directory at all if we don't need any replacement
 589 # functions.
 590 AM_CONDITIONAL([COND_GNULIB], test -n "$LIBOBJS")
 591
 592 AC_CONFIG_FILES([
 593         Doxyfile
 594         Makefile
 595         po/Makefile.in
 596         lib/Makefile
 597         src/Makefile
 598         src/liblzma/lzma.pc
 599         src/liblzma/Makefile
 600         src/liblzma/api/Makefile
 601         src/liblzma/common/Makefile
 602         src/liblzma/check/Makefile
 603         src/liblzma/lz/Makefile
 604         src/liblzma/lzma/Makefile
 605         src/liblzma/simple/Makefile
 606         src/liblzma/subblock/Makefile
 607         src/liblzma/rangecoder/Makefile
 608         src/lzma/Makefile
 609         src/lzmadec/Makefile
 610         src/scripts/Makefile
 611         tests/Makefile
 612 ])
 613
 614 AC_OUTPUT