configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 ###############################################################################
   5 #
   6 # Author: Lasse Collin
   7 #
   8 # This file has been put into the public domain.
   9 # You can do whatever you want with this file.
  10 #
  11 ###############################################################################
  12
  13 # NOTE: Don't add useless checks. autoscan detects this and that, but don't
  14 # let it confuse you. For example, we don't care about checking for behavior
  15 # of malloc(), stat(), or lstat(), since we don't use those functions in
  16 # a way that would cause the problems the autoconf macros check.
  17
  18 AC_PREREQ([2.61])
  19
  20 AC_INIT([XZ Utils], m4_esyscmd([/bin/sh version.sh]),
  21         [lasse.collin@tukaani.org], [xz])
  22 AC_CONFIG_SRCDIR([src/liblzma/common/common.h])
  23 AC_CONFIG_HEADER([config.h])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 echo
  27 echo "$PACKAGE_STRING"
  28
  29 echo
  30 echo "System type:"
  31 # This is needed to know if assembler optimizations can be used.
  32 AC_CANONICAL_HOST
  33
  34
  35 echo
  36 echo "Configure options:"
  37 AM_CFLAGS=
  38
  39
  40 #############
  41 # Debugging #
  42 #############
  43
  44 AC_MSG_CHECKING([if debugging code should be compiled])
  45 AC_ARG_ENABLE([debug], AC_HELP_STRING([--enable-debug], [Enable debugging code.]),
  46         [], enable_debug=no)
  47 if test "x$enable_debug" = xyes; then
  48         AC_MSG_RESULT([yes])
  49 else
  50         AC_DEFINE([NDEBUG], [1], [Define to 1 to disable debugging code.])
  51         AC_MSG_RESULT([no])
  52 fi
  53
  54
  55 ###########
  56 # Filters #
  57 ###########
  58
  59 m4_define([SUPPORTED_FILTERS], [lzma1,lzma2,subblock,delta,x86,powerpc,ia64,arm,armthumb,sparc])dnl
  60 m4_define([SIMPLE_FILTERS], [x86,powerpc,ia64,arm,armthumb,sparc])
  61 m4_define([LZ_FILTERS], [lzma1,lzma2])
  62
  63 m4_foreach([NAME], [SUPPORTED_FILTERS],
  64 [enable_filter_[]NAME=no
  65 enable_encoder_[]NAME=no
  66 enable_decoder_[]NAME=no
  67 ])dnl
  68
  69 AC_MSG_CHECKING([which encoders to build])
  70 AC_ARG_ENABLE([encoders], AC_HELP_STRING([--enable-encoders=LIST],
  71                 [Comma-separated list of encoders to build. Default=all.
  72                 Available encoders:]
  73                         m4_translit(m4_defn([SUPPORTED_FILTERS]), [,], [ ])),
  74         [], [enable_encoders=SUPPORTED_FILTERS])
  75 enable_encoders=`echo "$enable_encoders" | sed 's/,subblock//; s/,/ /g'`
  76 if test "x$enable_encoders" = xno || test "x$enable_encoders" = x; then
  77         AC_MSG_RESULT([(none)])
  78 else
  79         AC_DEFINE([HAVE_ENCODER], [1],
  80                 [Define to 1 if encoder components are enabled.])
  81         for arg in $enable_encoders
  82         do
  83                 case $arg in m4_foreach([NAME], [SUPPORTED_FILTERS], [
  84                         NAME)
  85                                 enable_filter_[]NAME=yes
  86                                 enable_encoder_[]NAME=yes
  87                                 AC_DEFINE(HAVE_ENCODER_[]m4_toupper(NAME), [1],
  88                                 [Define to 1 if] NAME [encoder is enabled.])
  89                                 ;;])
  90                         *)
  91                                 AC_MSG_RESULT([])
  92                                 AC_MSG_ERROR([unknown filter: $arg])
  93                                 ;;
  94                 esac
  95         done
  96         AC_MSG_RESULT([$enable_encoders])
  97 fi
  98
  99 AC_MSG_CHECKING([which decoders to build])
 100 AC_ARG_ENABLE([decoders], AC_HELP_STRING([--enable-decoders=LIST],
 101                 [Comma-separated list of decoders to build. Default=all.
 102                 Available decoders are the same as available encoders.]),
 103         [], [enable_decoders=SUPPORTED_FILTERS])
 104 enable_decoders=`echo "$enable_decoders" | sed 's/,subblock//; s/,/ /g'`
 105 if test "x$enable_decoders" = xno || test "x$enable_decoders" = x; then
 106         AC_MSG_RESULT([(none)])
 107 else
 108         AC_DEFINE([HAVE_DECODER], [1],
 109                 [Define to 1 if decoder components are enabled.])
 110         for arg in $enable_decoders
 111         do
 112                 case $arg in m4_foreach([NAME], [SUPPORTED_FILTERS], [
 113                         NAME)
 114                                 enable_filter_[]NAME=yes
 115                                 enable_decoder_[]NAME=yes
 116                                 AC_DEFINE(HAVE_DECODER_[]m4_toupper(NAME), [1],
 117                                 [Define to 1 if] NAME [decoder is enabled.])
 118                                 ;;])
 119                         *)
 120                                 AC_MSG_RESULT([])
 121                                 AC_MSG_ERROR([unknown filter: $arg])
 122                                 ;;
 123                 esac
 124         done
 125
 126         # LZMA2 requires that LZMA1 is enabled.
 127         test "x$enable_encoder_lzma2" = xyes && enable_encoder_lzma1=yes
 128         test "x$enable_decoder_lzma2" = xyes && enable_decoder_lzma1=yes
 129
 130         AC_MSG_RESULT([$enable_decoders])
 131 fi
 132
 133 if test "x$enable_encoder_lzma2$enable_encoder_lzma1" = xyesno \
 134                 || test "x$enable_decoder_lzma2$enable_decoder_lzma1" = xyesno; then
 135         AC_MSG_ERROR([LZMA2 requires that LZMA1 is also enabled.])
 136 fi
 137
 138 AM_CONDITIONAL(COND_MAIN_ENCODER, test "x$enable_encoders" != xno && test "x$enable_encoders" != x)
 139 AM_CONDITIONAL(COND_MAIN_DECODER, test "x$enable_decoders" != xno && test "x$enable_decoders" != x)
 140
 141 m4_foreach([NAME], [SUPPORTED_FILTERS],
 142 [AM_CONDITIONAL(COND_FILTER_[]m4_toupper(NAME), test "x$enable_filter_[]NAME" = xyes)
 143 AM_CONDITIONAL(COND_ENCODER_[]m4_toupper(NAME), test "x$enable_encoder_[]NAME" = xyes)
 144 AM_CONDITIONAL(COND_DECODER_[]m4_toupper(NAME), test "x$enable_decoder_[]NAME" = xyes)
 145 ])dnl
 146
 147 # The so called "simple filters" share common code.
 148 enable_filter_simple=no
 149 enable_encoder_simple=no
 150 enable_decoder_simple=no
 151 m4_foreach([NAME], [SIMPLE_FILTERS],
 152 [test "x$enable_filter_[]NAME" = xyes && enable_filter_simple=yes
 153 test "x$enable_encoder_[]NAME" = xyes && enable_encoder_simple=yes
 154 test "x$enable_decoder_[]NAME" = xyes && enable_decoder_simple=yes
 155 ])dnl
 156 AM_CONDITIONAL(COND_FILTER_SIMPLE, test "x$enable_filter_simple" = xyes)
 157 AM_CONDITIONAL(COND_ENCODER_SIMPLE, test "x$enable_encoder_simple" = xyes)
 158 AM_CONDITIONAL(COND_DECODER_SIMPLE, test "x$enable_decoder_simple" = xyes)
 159
 160 # LZ-based filters share common code.
 161 enable_filter_lz=no
 162 enable_encoder_lz=no
 163 enable_decoder_lz=no
 164 m4_foreach([NAME], [LZ_FILTERS],
 165 [test "x$enable_filter_[]NAME" = xyes && enable_filter_lz=yes
 166 test "x$enable_encoder_[]NAME" = xyes && enable_encoder_lz=yes
 167 test "x$enable_decoder_[]NAME" = xyes && enable_decoder_lz=yes
 168 ])dnl
 169 AM_CONDITIONAL(COND_FILTER_LZ, test "x$enable_filter_lz" = xyes)
 170 AM_CONDITIONAL(COND_ENCODER_LZ, test "x$enable_encoder_lz" = xyes)
 171 AM_CONDITIONAL(COND_DECODER_LZ, test "x$enable_decoder_lz" = xyes)
 172
 173
 174 #################
 175 # Match finders #
 176 #################
 177
 178 m4_define([SUPPORTED_MATCH_FINDERS], [hc3,hc4,bt2,bt3,bt4])
 179
 180 m4_foreach([NAME], [SUPPORTED_MATCH_FINDERS],
 181 [enable_match_finder_[]NAME=no
 182 ])
 183
 184 AC_MSG_CHECKING([which match finders to build])
 185 AC_ARG_ENABLE([match-finders], AC_HELP_STRING([--enable-match-finders=LIST],
 186                 [Comma-separated list of match finders to build. Default=all.
 187                 At least one match finder is required for encoding with
 188                 the LZMA1 and LZMA2 filters. Available match finders:]
 189                 m4_translit(m4_defn([SUPPORTED_MATCH_FINDERS]), [,], [ ])), [],
 190         [enable_match_finders=SUPPORTED_MATCH_FINDERS])
 191 enable_match_finders=`echo "$enable_match_finders" | sed 's/,/ /g'`
 192 if test "x$enable_encoder_lz" = xyes ; then
 193         for arg in $enable_match_finders
 194                 do
 195                 case $arg in m4_foreach([NAME], [SUPPORTED_MATCH_FINDERS], [
 196                         NAME)
 197                                 enable_match_finder_[]NAME=yes
 198                                 AC_DEFINE(HAVE_MF_[]m4_toupper(NAME), [1],
 199                                 [Define to 1 to enable] NAME [match finder.])
 200                                 ;;])
 201                         *)
 202                                 AC_MSG_RESULT([])
 203                                 AC_MSG_ERROR([unknown match finder: $arg])
 204                                 ;;
 205                 esac
 206         done
 207         AC_MSG_RESULT([$enable_match_finders])
 208 else
 209         AC_MSG_RESULT([(none because not building any LZ-based encoder)])
 210 fi
 211
 212
 213 ####################
 214 # Integrity checks #
 215 ####################
 216
 217 m4_define([SUPPORTED_CHECKS], [crc32,crc64,sha256])
 218
 219 m4_foreach([NAME], [SUPPORTED_FILTERS],
 220 [enable_check_[]NAME=no
 221 ])dnl
 222
 223 AC_MSG_CHECKING([which integrity checks to build])
 224 AC_ARG_ENABLE([checks], AC_HELP_STRING([--enable-checks=LIST],
 225                 [Comma-separated list of integrity checks to build.
 226                 Default=all. Available integrity checks:]
 227                 m4_translit(m4_defn([SUPPORTED_CHECKS]), [,], [ ])),
 228         [], [enable_checks=SUPPORTED_CHECKS])
 229 enable_checks=`echo "$enable_checks" | sed 's/,/ /g'`
 230 if test "x$enable_checks" = xno || test "x$enable_checks" = x; then
 231         AC_MSG_RESULT([(none)])
 232 else
 233         for arg in $enable_checks
 234         do
 235                 case $arg in m4_foreach([NAME], [SUPPORTED_CHECKS], [
 236                         NAME)
 237                                 enable_check_[]NAME=yes
 238                                 AC_DEFINE(HAVE_CHECK_[]m4_toupper(NAME), [1],
 239                                 [Define to 1 if] NAME
 240                                 [integrity check is enabled.])
 241                                 ;;])
 242                         *)
 243                                 AC_MSG_RESULT([])
 244                                 AC_MSG_ERROR([unknown integrity check: $arg])
 245                                 ;;
 246                 esac
 247         done
 248         AC_MSG_RESULT([$enable_checks])
 249 fi
 250 if test "x$enable_checks_crc32" = xno ; then
 251         AC_MSG_ERROR([For now, the CRC32 check must always be enabled.])
 252 fi
 253
 254 m4_foreach([NAME], [SUPPORTED_CHECKS],
 255 [AM_CONDITIONAL(COND_CHECK_[]m4_toupper(NAME), test "x$enable_check_[]NAME" = xyes)
 256 ])dnl
 257
 258
 259 ###########################
 260 # Assembler optimizations #
 261 ###########################
 262
 263 AC_MSG_CHECKING([if assembler optimizations should be used])
 264 AC_ARG_ENABLE([assembler], AC_HELP_STRING([--disable-assembler],
 265                 [Do not use assembler optimizations even if such exist
 266                 for the architecture.]),
 267         [], [enable_assembler=yes])
 268 if test "x$enable_assembler" = xyes; then
 269         case $host_cpu in
 270                 i?86)   enable_assembler=x86 ;;
 271                 x86_64) enable_assembler=x86_64 ;;
 272                 *)      enable_assembler=no ;;
 273         esac
 274 fi
 275 case $enable_assembler in
 276         x86)
 277                 AC_DEFINE([HAVE_ASM_X86], [1],
 278                         [Define to 1 if using x86 assembler optimizations.])
 279                 ;;
 280         x86_64)
 281                 AC_DEFINE([HAVE_ASM_X86_64], [1],
 282                         [Define to 1 if using x86_64 assembler optimizations.])
 283                 ;;
 284         no)
 285                 ;;
 286         *)
 287                 AC_MSG_RESULT([])
 288                 AC_MSG_ERROR([--enable-assembler accepts only \`yes', \`no', \`x86', or \`x86_64'.])
 289                 ;;
 290 esac
 291 AC_MSG_RESULT([$enable_assembler])
 292 AM_CONDITIONAL(COND_ASM_X86, test "x$enable_assembler" = xx86)
 293 AM_CONDITIONAL(COND_ASM_X86_64, test "x$enable_assembler" = xx86_64)
 294
 295
 296 ################################
 297 # Fast unaligned memory access #
 298 ################################
 299
 300 AC_MSG_CHECKING([if unaligned memory access should be used])
 301 AC_ARG_ENABLE([unaligned-access], AC_HELP_STRING([--enable-unaligned-access],
 302                 [Enable if the system supports *fast* unaligned memory access
 303                 with 16-bit and 32-bit integers. By default, this is enabled
 304                 only on x86, x86_64, and big endian PowerPC.]),
 305         [], [enable_unaligned_access=auto])
 306 if test "x$enable_unaligned_access" = xauto ; then
 307         case $host_cpu in
 308                 i?86|x86_64|powerpc|powerpc64)
 309                         enable_unaligned_access=yes
 310                         ;;
 311                 *)
 312                         enable_unaligned_access=no
 313                         ;;
 314         esac
 315 fi
 316 if test "x$enable_unaligned_access" = xyes ; then
 317         AC_DEFINE([HAVE_FAST_UNALIGNED_ACCESS], [1], [Define to 1 if
 318                 the system supports fast unaligned memory access.])
 319         AC_MSG_RESULT([yes])
 320 else
 321         AC_MSG_RESULT([no])
 322 fi
 323
 324
 325 #####################
 326 # Size optimization #
 327 #####################
 328
 329 AC_MSG_CHECKING([if small size is preferred over speed])
 330 AC_ARG_ENABLE([small], AC_HELP_STRING([--enable-small],
 331                 [Make liblzma smaller and a little slower.
 332                 This is disabled by default to optimize for speed.]),
 333         [], [enable_small=no])
 334 if test "x$enable_small" = xyes; then
 335         AC_DEFINE([HAVE_SMALL], [1], [Define to 1 if optimizing for size.])
 336 elif test "x$enable_small" != xno; then
 337         AC_MSG_RESULT([])
 338         AC_MSG_ERROR([--enable-small accepts only \`yes' or \`no'])
 339 fi
 340 AC_MSG_RESULT([$enable_small])
 341 AM_CONDITIONAL(COND_SMALL, test "x$enable_small" = xyes)
 342
 343
 344 #############
 345 # Threading #
 346 #############
 347
 348 AC_MSG_CHECKING([if threading support is wanted])
 349 AC_ARG_ENABLE([threads], AC_HELP_STRING([--disable-threads],
 350                 [Disable threading support.
 351                 This makes some things thread-unsafe.]),
 352         [], [enable_threads=yes])
 353 if test "x$enable_threads" != xyes && test "x$enable_threads" != xno; then
 354         AC_MSG_RESULT([])
 355         AC_MSG_ERROR([--enable-threads accepts only \`yes' or \`no'])
 356 fi
 357 AC_MSG_RESULT([$enable_threads])
 358 # We use the actual result a little later.
 359
 360
 361 ############################################
 362 # xz/xzdec/lzmadec linkage against liblzma #
 363 ############################################
 364
 365 # Link the command line tool statically against liblzma unless using
 366 # --enable-dynamic. Using static liblzma gives a little bit faster executable
 367 # on x86, because no register is wasted for PIC. We also have one dependency
 368 # less, which allows users to more freely copy the xz binary to other boxes.
 369 # However, I wouldn't be surprised if distro maintainers still prefer dynamic
 370 # linking, so let's make it easy for them.
 371
 372 AC_MSG_CHECKING([how command line tools should be linked against liblzma])
 373 AC_ARG_ENABLE([dynamic], [AC_HELP_STRING([--enable-dynamic],
 374                         [Link command line tools dynamically against liblzma.
 375                         The default is to use static liblzma if it was
 376                         built.])],
 377                 [], [enable_dynamic=no])
 378 case $enable_dynamic in
 379         yes)
 380                 STATIC_CPPFLAGS=
 381                 STATIC_LDFLAGS=
 382                 AC_MSG_RESULT([dynamically])
 383                 ;;
 384         no)
 385                 STATIC_CPPFLAGS="-DLZMA_API_STATIC"
 386                 STATIC_LDFLAGS="-static"
 387                 AC_MSG_RESULT([statically])
 388                 ;;
 389         *)
 390                 AC_MSG_RESULT([])
 391                 AC_MSG_ERROR([--enable-dynamic accepts only \`yes' or \`no'])
 392                 ;;
 393 esac
 394 AC_SUBST([STATIC_CPPFLAGS])
 395 AC_SUBST([STATIC_LDFLAGS])
 396
 397
 398 ###############################################################################
 399 # Checks for programs.
 400 ###############################################################################
 401
 402 echo
 403 echo "Initializing Automake:"
 404
 405 AM_INIT_AUTOMAKE([1.10 foreign tar-v7 filename-length-max=99])
 406 AC_PROG_LN_S
 407
 408 AC_PROG_CC_C99
 409 if test x$ac_cv_prog_cc_c99 = xno ; then
 410         AC_MSG_ERROR([No C99 compiler was found.])
 411 fi
 412
 413 AM_PROG_CC_C_O
 414 AM_PROG_AS
 415 AC_USE_SYSTEM_EXTENSIONS
 416
 417 if test "x$enable_threads" = xyes; then
 418         echo
 419         echo "Threading support:"
 420         ACX_PTHREAD
 421         LIBS="$LIBS $PTHREAD_LIBS"
 422         AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS"
 423         CC="$PTHREAD_CC"
 424 fi
 425
 426 echo
 427 echo "Initializing Libtool:"
 428 CXX=no
 429 F77=no
 430 AC_PROG_LIBTOOL
 431
 432
 433 ###############################################################################
 434 # Checks for libraries.
 435 ###############################################################################
 436
 437 echo
 438 echo "Initializing gettext:"
 439 AM_GNU_GETTEXT_VERSION([0.16.1])
 440 AM_GNU_GETTEXT([external])
 441
 442 ###############################################################################
 443 # Checks for header files.
 444 ###############################################################################
 445
 446 echo
 447 echo "System headers and functions:"
 448
 449 # There is currently no workarounds in this package if some of
 450 # these headers are missing.
 451 AC_CHECK_HEADERS([fcntl.h limits.h sys/time.h],
 452         [],
 453         [AC_MSG_ERROR([Required header file(s) are missing.])])
 454
 455 # If any of these headers are missing, things should still work correctly:
 456 AC_CHECK_HEADERS([sys/param.h sys/sysctl.h byteswap.h],
 457         [], [], [
 458 #ifdef HAVE_SYS_PARAM_H
 459 #       include <sys/param.h>
 460 #endif
 461 ])
 462
 463 # Even if we have byteswap.h, we may lack the specific macros/functions.
 464 if test x$ac_cv_header_byteswap_h = xyes ; then
 465         m4_foreach([FUNC], [bswap_16,bswap_32,bswap_64], [
 466                 AC_MSG_CHECKING([if FUNC is available])
 467                 AC_LINK_IFELSE([AC_LANG_SOURCE([
 468 #include <byteswap.h>
 469 int
 470 main(void)
 471 {
 472         FUNC[](42);
 473         return 0;
 474 }
 475                 ])], [
 476                         AC_DEFINE(HAVE_[]m4_toupper(FUNC), [1],
 477                                         [Define to 1 if] FUNC [is available.])
 478                         AC_MSG_RESULT([yes])
 479                 ], [AC_MSG_RESULT([no])])
 480
 481         ])dnl
 482 fi
 483
 484
 485 ###############################################################################
 486 # Checks for typedefs, structures, and compiler characteristics.
 487 ###############################################################################
 488
 489 dnl We don't need these as long as we need a C99 compiler anyway.
 490 dnl AC_C_INLINE
 491 dnl AC_C_RESTRICT
 492
 493 AC_HEADER_STDBOOL
 494
 495 AC_TYPE_UINT8_T
 496 AC_TYPE_UINT16_T
 497 AC_TYPE_INT32_T
 498 AC_TYPE_UINT32_T
 499 AC_TYPE_INT64_T
 500 AC_TYPE_UINT64_T
 501 AC_TYPE_UINTPTR_T
 502
 503 AC_CHECK_SIZEOF([size_t])
 504
 505 # The command line tool can copy high resolution timestamps if such
 506 # information is availabe in struct stat. Otherwise one second accuracy
 507 # is used.
 508 AC_CHECK_MEMBERS([
 509         struct stat.st_atim.tv_nsec,
 510         struct stat.st_atimespec.tv_nsec,
 511         struct stat.st_atimensec,
 512         struct stat.st_uatime,
 513         struct stat.st_atim.st__tim.tv_nsec])
 514
 515 AC_SYS_LARGEFILE
 516 AC_C_BIGENDIAN
 517
 518
 519 ###############################################################################
 520 # Checks for library functions.
 521 ###############################################################################
 522
 523 # Gnulib replacements as needed
 524 gl_GETOPT
 525
 526 # Find the best function to set timestamps.
 527 AC_CHECK_FUNCS([futimens futimes futimesat utimes utime], [break])
 528
 529 lc_PHYSMEM
 530 lc_CPUCORES
 531
 532
 533 ###############################################################################
 534 # If using GCC, set some additional AM_CFLAGS:
 535 ###############################################################################
 536
 537 if test "x$GCC" = xyes ; then
 538         echo
 539         echo "GCC extensions:"
 540         gl_VISIBILITY
 541         if test -n "$CFLAG_VISIBILITY" ; then
 542                 AM_CFLAGS="$AM_CFLAGS $CFLAG_VISIBILITY"
 543         fi
 544
 545         # Enable as much warnings as possible. These commented warnings won't
 546         # work for this package though:
 547         #   * -Wunreachable-code breaks several assert(0) cases, which are
 548         #     backed up with "return LZMA_PROG_ERROR".
 549         #   * -Wcast-qual would break various things where we need a non-const
 550         #     pointer although we don't modify anything through it.
 551         #   * -Wcast-align breaks optimized CRC32 and CRC64 implementation
 552         #     on some architectures (not on x86), where this warning is bogus,
 553         #     because we take care of correct alignment.
 554         #   * -Winline, -Wdisabled-optimization, -Wunsafe-loop-optimizations
 555         #     don't seem so useful here; at least the last one gives some
 556         #     warnings which are not bugs.
 557         for NEW_FLAG in \
 558                         -Wall \
 559                         -Wextra \
 560                         -Wformat=2 \
 561                         -Winit-self \
 562                         -Wmissing-include-dirs \
 563                         -Wstrict-aliasing \
 564                         -Wfloat-equal \
 565                         -Wundef \
 566                         -Wshadow \
 567                         -Wpointer-arith \
 568                         -Wbad-function-cast \
 569                         -Wwrite-strings \
 570                         -Wlogical-op \
 571                         -Waggregate-return \
 572                         -Wstrict-prototypes \
 573                         -Wold-style-definition \
 574                         -Wmissing-prototypes \
 575                         -Wmissing-declarations \
 576                         -Wmissing-noreturn \
 577                         -Wredundant-decls
 578         do
 579                 AC_MSG_CHECKING([if $CC accepts $NEW_FLAG])
 580                 OLD_CFLAGS="$CFLAGS"
 581                 CFLAGS="$CFLAGS $NEW_FLAG"
 582                 AC_COMPILE_IFELSE([void foo(void) { }], [
 583                         AM_CFLAGS="$AM_CFLAGS $NEW_FLAG"
 584                         AC_MSG_RESULT([yes])
 585                 ], [
 586                         AC_MSG_RESULT([no])
 587                 ])
 588                 CFLAGS="$OLD_CFLAGS"
 589         done
 590
 591         AC_ARG_ENABLE([werror],
 592                 AC_HELP_STRING([--enable-werror], [Enable -Werror to abort
 593                         compilation on all compiler warnings.]),
 594                 [], [enable_werror=no])
 595         if test "x$enable_werror" = "xyes"; then
 596                 AM_CFLAGS="$AM_CFLAGS -Werror"
 597         fi
 598 fi
 599
 600
 601 ###############################################################################
 602 # Create the makefiles and config.h
 603 ###############################################################################
 604
 605 echo
 606
 607 # Don't build the lib directory at all if we don't need any replacement
 608 # functions.
 609 AM_CONDITIONAL([COND_GNULIB], test -n "$LIBOBJS")
 610
 611 # Add default AM_CFLAGS.
 612 AC_SUBST([AM_CFLAGS])
 613
 614 AC_CONFIG_FILES([
 615         Doxyfile
 616         Makefile
 617         po/Makefile.in
 618         lib/Makefile
 619         src/Makefile
 620         src/liblzma/liblzma.pc
 621         src/liblzma/Makefile
 622         src/liblzma/api/Makefile
 623         src/liblzma/common/Makefile
 624         src/liblzma/check/Makefile
 625         src/liblzma/rangecoder/Makefile
 626         src/liblzma/lz/Makefile
 627         src/liblzma/lzma/Makefile
 628         src/liblzma/subblock/Makefile
 629         src/liblzma/delta/Makefile
 630         src/liblzma/simple/Makefile
 631         src/xz/Makefile
 632         src/xzdec/Makefile
 633         src/scripts/Makefile
 634         tests/Makefile
 635         debug/Makefile
 636 ])
 637
 638 AC_OUTPUT