data/qcsrc/server/w_tuba.qc

   1 #define TUBA_NOTE(n) strcat("weapons/tuba_note", ftos(n), ".wav")
   2 .float tuba_notecount;
   3
   4 float Tuba_GetNote(entity pl, float hittype)
   5 {
   6         float note;
   7         float movestate;
   8         movestate = 5;
   9         if(pl.movement_x < 0) movestate -= 3;
  10         if(pl.movement_x > 0) movestate += 3;
  11         if(pl.movement_y < 0) movestate -= 1;
  12         if(pl.movement_y > 0) movestate += 1;
  13         switch(movestate)
  14         {
  15         // layout: originally I wanted
  16         //   eb e  e#=f
  17         //   B  c  d
  18         //   Gb G  G#
  19         // but then you only use forward and right key. So to make things more
  20         // interesting, I swapped B with e#. Har har har...
  21         //   eb e  B
  22         // f=e# c  d
  23         //   Gb G  G#
  24                 case 1: note = -6; break; // Gb
  25                 case 2: note = -5; break; // G
  26                 case 3: note = -4; break; // G#
  27                 case 4: note = +5; break; // e#
  28                 case 5: note =  0; break; // c
  29                 case 6: note = +2; break; // d
  30                 case 7: note = +3; break; // eb
  31                 case 8: note = +4; break; // e
  32                 case 9: note = -1; break; // B
  33         }
  34         if(pl.BUTTON_CROUCH)
  35                 note -= 12;
  36         if(hittype & HITTYPE_SECONDARY)
  37                 note += 7;
  38
  39         // we support two kinds of tubas, those tuned in Eb and those tuned in C
  40         // kind of tuba currently is player slot number, or team number if in
  41         // teamplay
  42         // that way, holes in the range of notes are "plugged"
  43         if(teams_matter)
  44         {
  45                 if(pl.team == COLOR_TEAM2 || pl.team == COLOR_TEAM4)
  46                         note += 3;
  47         }
  48         else
  49         {
  50                 if(mod(num_for_edict(pl), 2) == 0)
  51                         note += 3;
  52         }
  53
  54         // total range of notes:
  55         //                       0
  56         //                 ***  ** ****
  57         //                        ***  ** ****
  58         //     ***  ** ****
  59         //            ***  ** ****
  60         //     ***  ********************* ****
  61         //     -18.........................+12
  62         //        ***  ********************* ****
  63         //     -18............................+15
  64         return note;
  65 }
  66
  67 void W_Tuba_Attack(float hittype)
  68 {
  69         W_SetupShot(self, FALSE, 2, "");
  70         self.tuba_notecount = !self.tuba_notecount;
  71         if(self.tuba_notecount)
  72                 sound(self, CHAN_WEAPON, TUBA_NOTE(Tuba_GetNote(self, hittype)), VOL_BASE, cvar("g_balance_tuba_attenuation"));
  73         else
  74                 sound(self, CHAN_WEAPON2, TUBA_NOTE(Tuba_GetNote(self, hittype)), VOL_BASE, cvar("g_balance_tuba_attenuation"));
  75         RadiusDamage(self, self, cvar("g_balance_tuba_damage"), cvar("g_balance_tuba_edgedamage"), cvar("g_balance_tuba_radius"), world, cvar("g_balance_tuba_force"), hittype | WEP_TUBA, world);
  76 }
  77
  78 void spawnfunc_weapon_tuba (void)
  79 {
  80         weapon_defaultspawnfunc(WEP_TUBA);
  81 }
  82
  83 float w_tuba(float req)
  84 {
  85         if (req == WR_AIM)
  86         {
  87                 // bots cannot play the Tuba yet
  88                 // I think they should start with the recorder first
  89         }
  90         else if (req == WR_THINK)
  91         {
  92                 if (self.BUTTON_ATCK)
  93                 if (weapon_prepareattack(0, cvar("g_balance_tuba_refire")))
  94                 {
  95                         W_Tuba_Attack(0);
  96                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_tuba_animtime"), w_ready);
  97                 }
  98                 if (self.BUTTON_ATCK2)
  99                 if (weapon_prepareattack(1, cvar("g_balance_tuba_refire")))
 100                 {
 101                         W_Tuba_Attack(HITTYPE_SECONDARY);
 102                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_tuba_animtime"), w_ready);
 103                 }
 104         }
 105         else if (req == WR_PRECACHE)
 106         {
 107                 precache_model ("models/weapons/g_tuba.md3");
 108                 precache_model ("models/weapons/v_tuba.md3");
 109                 precache_model ("models/weapons/h_tuba.dpm");
 110
 111                 float i;
 112                 for(i = -18; i <= +15; ++i)
 113                         precache_sound(TUBA_NOTE(i));
 114         }
 115         else if (req == WR_SETUP)
 116                 weapon_setup(WEP_TUBA);
 117         else if (req == WR_CHECKAMMO1)
 118                 return TRUE; // TODO use fuel?
 119         else if (req == WR_CHECKAMMO2)
 120                 return TRUE; // TODO use fuel?
 121         else if (req == WR_SUICIDEMESSAGE)
 122         {
 123                 w_deathtypestring = "hurt his own ears with the @!#%'n Tuba";
 124         }
 125         else if (req == WR_KILLMESSAGE)
 126         {
 127                 w_deathtypestring = "died of #'s great playing on the @!#%'n Tuba";
 128         }
 129         return TRUE;
 130 };