data/qcsrc/server/t_items.qc

   1 floatfield Item_CounterField(float it)
   2 {
   3         switch(it)
   4         {
   5                 case IT_SHELLS:      return ammo_shells;
   6                 case IT_NAILS:       return ammo_nails;
   7                 case IT_ROCKETS:     return ammo_rockets;
   8                 case IT_CELLS:       return ammo_cells;
   9                 case IT_5HP:         return health;
  10                 case IT_25HP:        return health;
  11                 case IT_HEALTH:      return health;
  12                 case IT_ARMOR_SHARD: return armorvalue;
  13                 case IT_ARMOR:       return armorvalue;
  14                 // add more things here (health, armor)
  15                 default:             error("requested item has no counter field");
  16         }
  17 }
  18
  19 string Item_CounterFieldName(float it)
  20 {
  21         switch(it)
  22         {
  23                 case IT_SHELLS:      return "shells";
  24                 case IT_NAILS:       return "nails";
  25                 case IT_ROCKETS:     return "rockets";
  26                 case IT_CELLS:       return "cells";
  27
  28                 // add more things here (health, armor)
  29                 default:             error("requested item has no counter field name");
  30         }
  31 }
  32
  33 .float max_armorvalue;
  34
  35 void Item_Respawn (void)
  36 {
  37         self.model = self.mdl;          // restore original model
  38         self.solid = SOLID_TRIGGER;     // allow it to be touched again
  39         sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);        // play respawn sound
  40         setorigin (self, self.origin);
  41
  42         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
  43         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
  44 }
  45
  46 float Item_GiveTo(entity item, entity player)
  47 {
  48         float _switchweapon;
  49         float pickedup;
  50         float it;
  51         float i;
  52         entity e;
  53
  54         // if nothing happens to player, just return without taking the item
  55         pickedup = FALSE;
  56         _switchweapon = FALSE;
  57
  58         if (g_minstagib)
  59         {
  60                 _switchweapon = TRUE;
  61                 if (item.ammo_cells)
  62                 {
  63                         pickedup = TRUE;
  64                         // play some cool sounds ;)
  65                         centerprint(player, "\n");
  66                         if(player.health <= 5)
  67                                 announce(player, "announcer/robotic/lastsecond.ogg");
  68                         else if(player.health < 50)
  69                                 announce(player, "announcer/robotic/narrowly.ogg");
  70                         // sound not available
  71                         // else if(item.items == IT_CELLS)
  72                         //      play2(player, "announce/robotic/ammo.ogg");
  73
  74                         if (item.weapons & WEPBIT_MINSTANEX)
  75                                 W_GiveWeapon (player, WEP_MINSTANEX, "Nex");
  76                         if (item.ammo_cells)
  77                                 player.ammo_cells = min (player.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
  78                         player.health = 100;
  79                 }
  80
  81                 // extralife powerup
  82                 if (item.max_health)
  83                 {
  84                         pickedup = TRUE;
  85                         // sound not available
  86                         // play2(player, "announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.ogg");
  87                         player.armorvalue = player.armorvalue + cvar("g_minstagib_extralives");
  88                         sprint(player, "^3You picked up some extra lives\n");
  89                 }
  90
  91                 // invis powerup
  92                 if (item.strength_finished)
  93                 {
  94                         pickedup = TRUE;
  95                         // sound not available
  96                         // play2(player, "announce/robotic/invisible.ogg");
  97                         player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
  98                 }
  99
 100                 // speed powerup
 101                 if (item.invincible_finished)
 102                 {
 103                         pickedup = TRUE;
 104                         // sound not available
 105                         // play2(player, "announce/robotic/speed.ogg");
 106                         player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
 107                 }
 108         }
 109         else
 110         {
 111                 if (cvar("deathmatch") == 2 || cvar("g_weapon_stay"))
 112                 {
 113                         if (item.flags & FL_WEAPON && player.weapons & item.weapons && item.classname != "droppedweapon")
 114                                 return 0;
 115                         if (player.weapons & item.weapons && item.flags & FL_TOSSED)    // don't let players stack ammo by tossing weapons
 116                                 return 0;
 117                 }
 118
 119                 // in case the player has autoswitch enabled do the following:
 120                 // if the player is using their best weapon before items are given, they
 121                 // probably want to switch to an even better weapon after items are given
 122                 if (player.autoswitch)
 123                 if (player.switchweapon == w_getbestweapon(player))
 124                         _switchweapon = TRUE;
 125
 126                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 127                         _switchweapon = TRUE;
 128
 129                 if (item.ammo_shells)
 130                 if (player.ammo_shells < g_pickup_shells_max)
 131                 {
 132                         pickedup = TRUE;
 133                         player.ammo_shells = min (player.ammo_shells + item.ammo_shells, g_pickup_shells_max);
 134                 }
 135                 if (item.ammo_nails)
 136                 if (player.ammo_nails < g_pickup_nails_max)
 137                 {
 138                         pickedup = TRUE;
 139                         player.ammo_nails = min (player.ammo_nails + item.ammo_nails, g_pickup_nails_max);
 140                 }
 141                 if (item.ammo_rockets)
 142                 if (player.ammo_rockets < g_pickup_rockets_max)
 143                 {
 144                         pickedup = TRUE;
 145                         player.ammo_rockets = min (player.ammo_rockets + item.ammo_rockets, g_pickup_rockets_max);
 146                 }
 147                 if (item.ammo_cells)
 148                 if (player.ammo_cells < g_pickup_cells_max)
 149                 {
 150                         pickedup = TRUE;
 151                         player.ammo_cells = min (player.ammo_cells + item.ammo_cells, g_pickup_cells_max);
 152                 }
 153
 154                 if (item.flags & FL_WEAPON)
 155                 if ((it = item.weapons - (item.weapons & player.weapons)))
 156                 {
 157                         pickedup = TRUE;
 158                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 159                         {
 160                                 e = get_weaponinfo(i);
 161                                 if(it & e.weapons)
 162                                         W_GiveWeapon (player, e.weapon, item.netname);
 163                         }
 164                 }
 165
 166                 if (item.strength_finished)
 167                 {
 168                         pickedup = TRUE;
 169                         player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 170                 }
 171                 if (item.invincible_finished)
 172                 {
 173                         pickedup = TRUE;
 174                         player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 175                 }
 176                 //if (item.speed_finished)
 177                 //{
 178                 //      pickedup = TRUE;
 179                 //      player.speed_finished = max(player.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 180                 //}
 181                 //if (item.slowmo_finished)
 182                 //{
 183                 //      pickedup = TRUE;
 184                 //      player.slowmo_finished = max(player.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 185                 //}
 186
 187                 if (item.health)
 188                 if (player.health < item.max_health)
 189                 {
 190                         pickedup = TRUE;
 191                         player.health = min(player.health + item.health, item.max_health);
 192                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 193                 }
 194                 if (item.armorvalue)
 195                 if (player.armorvalue < item.max_armorvalue)
 196                 {
 197                         pickedup = TRUE;
 198                         player.armorvalue = min(player.armorvalue + item.armorvalue, item.max_armorvalue);
 199                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 200                 }
 201         }
 202
 203         // always eat teamed entities
 204         if(item.team)
 205                 pickedup = TRUE;
 206
 207         if (!pickedup)
 208                 return 0;
 209
 210         sound (player, CHAN_AUTO, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 211         if (_switchweapon)
 212                 W_SwitchWeapon_Force(player, w_getbestweapon(player));
 213
 214         return 1;
 215 }
 216
 217 void Item_Touch (void)
 218 {
 219         entity e, head;
 220
 221         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 222         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 223         {
 224                 remove(self);
 225                 return;
 226         }
 227         if (other.classname != "player")
 228                 return;
 229         if (other.deadflag)
 230                 return;
 231         if (self.solid != SOLID_TRIGGER)
 232                 return;
 233         if (self.owner == other)
 234                 return;
 235
 236         if(!Item_GiveTo(self, other))
 237                 return;
 238
 239         if (self.classname == "droppedweapon")
 240                 remove (self);
 241         else if((self.flags & FL_WEAPON) && !self.team && (cvar("deathmatch") == 2 || cvar("g_weapon_stay")))
 242                 return;
 243         else
 244         {
 245                 self.solid = SOLID_NOT;
 246                 self.model = string_null;
 247                 if(self.team)
 248                 {
 249                         RandomSelection_Init();
 250                         for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 251                                 RandomSelection_Add(head, 0, 1, 0);
 252                         e = RandomSelection_chosen_ent;
 253                 }
 254                 else
 255                         e = self;
 256                 e.nextthink = time + self.respawntime;
 257                 e.think = Item_Respawn;
 258         }
 259 }
 260
 261 void Item_FindTeam()
 262 {
 263         entity head, e;
 264
 265         if(self.effects & EF_NODRAW)
 266         {
 267                 // marker for item team search
 268                 dprint("Initializing item team ", ftos(self.team), "\n");
 269                 RandomSelection_Init();
 270                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 271                         RandomSelection_Add(head, 0, 1, 0);
 272                 e = RandomSelection_chosen_ent;
 273                 e.cnt = 0;
 274
 275                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 276                 {
 277                         if(head != e)
 278                         {
 279                                 // make it a non-spawned item
 280                                 head.solid = SOLID_NOT;
 281                                 head.model = string_null;
 282                                 head.cnt = 1; // cnt 1 = initially hidden item
 283                         }
 284                         head.effects = head.effects - (head.effects & EF_NODRAW);
 285                 }
 286         }
 287 }
 288
 289 // Savage: used for item garbage-collection
 290 // TODO: perhaps nice special effect?
 291 void RemoveItem(void) /*FIXDECL*/
 292 {
 293         remove(self);
 294 }
 295
 296 // pickup evaluation functions
 297 // these functions decide how desirable an item is to the bots
 298
 299 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};
 300
 301 float weapon_pickupevalfunc(entity player, entity item)
 302 {
 303         // if we already have the weapon, rate it 1/5th normal value
 304         if ((player.weapons & item.weapons) == item.weapons)
 305                 return item.bot_pickupbasevalue * 0.2;
 306         return item.bot_pickupbasevalue;
 307 };
 308
 309 float commodity_pickupevalfunc(entity player, entity item)
 310 {
 311         float c;
 312         c = 0;
 313         // TODO: figure out if the player even has the weapon this ammo is for?
 314         // may not affect strategy much though...
 315         // find out how much more ammo/armor/health the player can hold
 316         if (item.ammo_shells)
 317         if (player.ammo_shells < g_pickup_shells_max)
 318                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 319         if (item.ammo_nails)
 320         if (player.ammo_nails < g_pickup_nails_max)
 321                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 322         if (item.ammo_rockets)
 323         if (player.ammo_rockets < g_pickup_rockets_max)
 324                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 325         if (item.ammo_cells)
 326         if (player.ammo_cells < g_pickup_cells_max)
 327                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 328         if (item.armorvalue)
 329         if (player.armorvalue < item.max_armorvalue)
 330                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 331         if (item.health)
 332         if (player.health < item.max_health)
 333                 c = c + max(0, 1 - player.health / item.max_health);
 334
 335         return item.bot_pickupbasevalue * c;
 336 };
 337
 338
 339 .float is_item;
 340 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 341 {
 342         startitem_failed = FALSE;
 343
 344         // is it a dropped weapon?
 345         if (self.classname == "droppedweapon")
 346         {
 347                 // it's a dropped weapon
 348                 self.movetype = MOVETYPE_TOSS;
 349                 self.solid = SOLID_TRIGGER;
 350                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 351                 self.think = RemoveItem;
 352                 self.nextthink = time + 60;
 353                 // don't drop if in a NODROP zone (such as lava)
 354                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 355                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 356                 {
 357                         startitem_failed = TRUE;
 358                         remove(self);
 359                         return;
 360                 }
 361         }
 362         else
 363         {
 364                 // it's a level item
 365                 if(self.spawnflags & 1)
 366                         self.noalign = 1;
 367                 if (self.noalign)
 368                         self.movetype = MOVETYPE_NONE;
 369                 else
 370                         self.movetype = MOVETYPE_TOSS;
 371                 self.solid = SOLID_TRIGGER;
 372                 // do item filtering according to game mode and other things
 373                 if (!self.noalign)
 374                 {
 375                         // first nudge it off the floor a little bit to avoid math errors
 376                         setorigin(self, self.origin + '0 0 1');
 377                         // set item size before we spawn a spawnfunc_waypoint
 378                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 379                                 setsize (self, '-16 -16 0', '16 16 48');
 380                         else
 381                                 setsize (self, '-16 -16 0', '16 16 32');
 382                         // note droptofloor returns FALSE if stuck/or would fall too far
 383                         droptofloor();
 384                         waypoint_spawnforitem(self);
 385                 }
 386
 387                 if(teams_matter)
 388                 {
 389                         if(self.notteam)
 390                         {
 391                                 print("removed non-teamplay ", self.classname, "\n");
 392                                 startitem_failed = TRUE;
 393                                 remove (self);
 394                                 return;
 395                         }
 396                 }
 397                 else
 398                 {
 399                         if(self.notfree)
 400                         {
 401                                 print("removed non-FFA ", self.classname, "\n");
 402                                 startitem_failed = TRUE;
 403                                 remove (self);
 404                                 return;
 405                         }
 406                 }
 407
 408                 if(self.notq3a)
 409                 {
 410                         // We aren't TA or something like that, so we keep the Q3A entities
 411                         print("removed non-Q3A ", self.classname, "\n");
 412                         startitem_failed = TRUE;
 413                         remove (self);
 414                         return;
 415                 }
 416
 417                 /*
 418                  * can't do it that way, as it would break maps
 419                  * TODO make a target_give like entity another way, that perhaps has
 420                  * the weapon name in a key
 421                 if(self.targetname)
 422                 {
 423                         // target_give not yet supported; maybe later
 424                         print("removed targeted ", self.classname, "\n");
 425                         startitem_failed = TRUE;
 426                         remove (self);
 427                         return;
 428                 }
 429                 */
 430
 431                 if(cvar("spawn_debug") >= 2)
 432                 {
 433                         entity otheritem;
 434                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 435                         {
 436                                 if(otheritem.is_item)
 437                                 {
 438                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 439                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 440                                         error("Mapper sucks.");
 441                                 }
 442                         }
 443                         self.is_item = TRUE;
 444                 }
 445
 446                 weaponsInMap |= weaponid;
 447
 448                 if(g_lms || g_rocketarena)
 449                 {
 450                         startitem_failed = TRUE;
 451                         remove(self);
 452                         return;
 453                 }
 454                 else if (g_minstagib)
 455                 {
 456                         // don't remove dropped items and powerups
 457                         if (self.classname != "minstagib")
 458                         {
 459                                 startitem_failed = TRUE;
 460                                 remove (self);
 461                                 return;
 462                         }
 463                 }
 464                 else if ((!cvar("g_pickup_items") || g_nixnex) && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 465                 {
 466                         startitem_failed = TRUE;
 467                         remove (self);
 468                         return;
 469                 }
 470
 471                 precache_model (itemmodel);
 472                 precache_sound (pickupsound);
 473                 precache_sound ("misc/itemrespawn.wav");
 474
 475                 if((itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)) || (weaponid & WEPBIT_ALL))
 476                         self.target = "###item###"; // for finding the nearest item using find()
 477         }
 478
 479         self.bot_pickup = TRUE;
 480         self.bot_pickupevalfunc = pickupevalfunc;
 481         self.bot_pickupbasevalue = pickupbasevalue;
 482         self.mdl = itemmodel;
 483         self.item_pickupsound = pickupsound;
 484         // let mappers override respawntime
 485         if (!self.respawntime)
 486                 self.respawntime = defaultrespawntime;
 487         self.netname = itemname;
 488         self.items = itemid;
 489         self.weapons = weaponid;
 490         self.flags = FL_ITEM | itemflags;
 491         self.touch = Item_Touch;
 492         setmodel (self, self.mdl); // precision set below
 493         self.effects |= EF_LOWPRECISION;
 494         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 495                 setsize (self, '-16 -16 0', '16 16 48');
 496         else
 497                 setsize (self, '-16 -16 0', '16 16 32');
 498         if (itemflags & FL_WEAPON)
 499         {
 500                 // neutral team color for pickup weapons
 501                 self.colormap = 160 * 1024 + 160;
 502         }
 503
 504         if (cvar("g_fullbrightitems"))
 505                 self.effects = self.effects | EF_FULLBRIGHT;
 506
 507         if(self.team)
 508         {
 509                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 510                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 511         }
 512 }
 513
 514 /* replace items in minstagib
 515  * IT_STRENGTH   = invisibility
 516  * IT_NAILS      = extra lives
 517  * IT_INVINCIBLE = speed
 518  */
 519 void minstagib_items (float itemid)
 520 {
 521         // we don't want to replace dropped weapons ;)
 522         if (self.classname == "droppedweapon")
 523         {
 524                 self.ammo_cells = 25;
 525                 StartItem ("models/weapons/g_nex.md3",
 526                         "weapons/weaponpickup.wav", 15,
 527                         "MinstaNex", 0, WEPBIT_MINSTANEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 528                 return;
 529         }
 530
 531         local float rnd;
 532         self.classname = "minstagib";
 533
 534         // replace rocket launchers and nex guns with ammo cells
 535         if (itemid == IT_CELLS)
 536         {
 537                 self.ammo_cells = 1;
 538                 StartItem ("models/items/a_cells.md3",
 539                         "misc/itempickup.wav", 45,
 540                         "Nex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 541                 return;
 542         }
 543
 544         // randomize
 545         rnd = random() * 3;
 546         if (rnd <= 1)
 547                 itemid = IT_STRENGTH;
 548         else if (rnd <= 2)
 549                 itemid = IT_NAILS;
 550         else
 551                 itemid = IT_INVINCIBLE;
 552
 553         // replace with invis
 554         if (itemid == IT_STRENGTH)
 555         {
 556                 self.effects = EF_ADDITIVE;
 557                 self.strength_finished = 30;
 558                 StartItem ("models/items/g_strength.md3",
 559                         "misc/powerup.wav", g_pickup_respawntime_powerup,
 560                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 1000);
 561         }
 562         // replace with extra lives
 563         if (itemid == IT_NAILS)
 564         {
 565                 self.max_health = 1;
 566                 StartItem ("models/items/g_h100.md3",
 567                         "misc/megahealth.wav", g_pickup_respawntime_powerup,
 568                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, 1000);
 569
 570         }
 571         // replace with speed
 572         if (itemid == IT_INVINCIBLE)
 573         {
 574                 self.effects = EF_ADDITIVE;
 575                 self.invincible_finished = 30;
 576                 StartItem ("models/items/g_invincible.md3",
 577                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup,
 578                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 1000);
 579         }
 580
 581 }
 582
 583 float minst_no_auto_cells;
 584 void minst_remove_item (void) {
 585         if(minst_no_auto_cells)
 586                 remove(self);
 587 }
 588
 589 float weaponswapping;
 590 float internalteam;
 591
 592 void weapon_defaultspawnfunc(float wpn)
 593 {
 594         entity e;
 595         float t;
 596         var .float ammofield;
 597         string s;
 598         entity oldself;
 599         float i;
 600
 601         // set the respawntime in advance (so replaced weapons can copy it)
 602         if(!self.respawntime)
 603         {
 604                 e = get_weaponinfo(wpn);
 605                 if(e.items == IT_SUPERWEAPON)
 606                         self.respawntime = g_pickup_respawntime_powerup;
 607                 else
 608                         self.respawntime = g_pickup_respawntime_short;
 609         }
 610
 611         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 612         {
 613                 s = cvar_string(strcat("g_weaponreplace_", ftos(wpn)));
 614                 t = tokenize(s);
 615                 if(t >= 2)
 616                 {
 617                         self.team = --internalteam;
 618                         for(i = 1; i < t; ++i)
 619                         {
 620                                 oldself = self;
 621                                 self = spawn();
 622                                 copyentity(oldself, self);
 623                                 self.classname = "replacedweapon";
 624                                 weapon_defaultspawnfunc(stof(argv(i)));
 625                                 self = oldself;
 626                         }
 627                 }
 628                 if(t >= 1)
 629                         wpn = stof(argv(0));
 630         }
 631
 632         e = get_weaponinfo(wpn);
 633
 634         if(e.items && e.items != IT_SUPERWEAPON)
 635         {
 636                 ammofield = Item_CounterField(e.items);
 637                 if(!self.ammofield)
 638                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(e.items)));
 639         }
 640
 641         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
 642         if (self.modelindex) // don't precache if self was removed
 643                 weapon_action(e.weapon, WR_PRECACHE);
 644 }
 645
 646 void spawnfunc_weapon_shotgun (void);
 647 void spawnfunc_weapon_uzi (void) {
 648         if(q3acompat_machineshotgunswap)
 649         if(self.classname != "droppedweapon")
 650         {
 651                 weapon_defaultspawnfunc(WEP_SHOTGUN);
 652                 return;
 653         }
 654         weapon_defaultspawnfunc(WEP_UZI);
 655 }
 656
 657 void spawnfunc_weapon_shotgun (void) {
 658         if(q3acompat_machineshotgunswap)
 659         if(self.classname != "droppedweapon")
 660         {
 661                 weapon_defaultspawnfunc(WEP_UZI);
 662                 return;
 663         }
 664         weapon_defaultspawnfunc(WEP_SHOTGUN);
 665 }
 666
 667 void spawnfunc_weapon_nex (void)
 668 {
 669         if (g_minstagib)
 670         {
 671                 minstagib_items(IT_CELLS);
 672                 self.think = minst_remove_item;
 673                 self.nextthink = time + cvar("sys_ticrate");
 674                 return;
 675         }
 676         weapon_defaultspawnfunc(WEP_NEX);
 677 }
 678
 679 void spawnfunc_weapon_minstanex (void)
 680 {
 681         if (g_minstagib)
 682         {
 683                 minstagib_items(IT_CELLS);
 684                 self.think = minst_remove_item;
 685                 self.nextthink = time + cvar("sys_ticrate");
 686                 return;
 687         }
 688         weapon_defaultspawnfunc(WEP_MINSTANEX);
 689 }
 690
 691 void spawnfunc_weapon_rocketlauncher (void)
 692 {
 693         if (g_minstagib)
 694         {
 695                 minstagib_items(IT_CELLS);
 696                 self.think = minst_remove_item;
 697                 self.nextthink = time + cvar("sys_ticrate");
 698                 return;
 699         }
 700         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
 701 }
 702
 703 void spawnfunc_item_rockets (void) {
 704         if(!self.ammo_rockets)
 705                 self.ammo_rockets = g_pickup_rockets;
 706         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_short, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
 707 }
 708
 709 void spawnfunc_item_shells (void);
 710 void spawnfunc_item_bullets (void) {
 711         if(!weaponswapping)
 712         if(q3acompat_machineshotgunswap)
 713         if(self.classname != "droppedweapon")
 714         {
 715                 weaponswapping = TRUE;
 716                 spawnfunc_item_shells();
 717                 weaponswapping = FALSE;
 718                 return;
 719         }
 720
 721         if(!self.ammo_nails)
 722                 self.ammo_nails = g_pickup_nails;
 723         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_short, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
 724 }
 725
 726 void spawnfunc_item_cells (void) {
 727         if(!self.ammo_cells)
 728                 self.ammo_cells = g_pickup_cells;
 729         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_short, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
 730 }
 731
 732 void spawnfunc_item_shells (void) {
 733         if(!weaponswapping)
 734         if(q3acompat_machineshotgunswap)
 735         if(self.classname != "droppedweapon")
 736         {
 737                 weaponswapping = TRUE;
 738                 spawnfunc_item_bullets();
 739                 weaponswapping = FALSE;
 740                 return;
 741         }
 742
 743         if(!self.ammo_shells)
 744                 self.ammo_shells = g_pickup_shells;
 745         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_short, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
 746 }
 747
 748 void spawnfunc_item_armor_small (void) {
 749         if(!self.armorvalue)
 750                 self.armorvalue = g_pickup_armorsmall;
 751         if(!self.max_armorvalue)
 752                 self.max_armorvalue = g_pickup_armorsmall_max;
 753         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", g_pickup_respawntime_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, 1000);
 754 }
 755
 756 void spawnfunc_item_armor_medium (void) {
 757         if(!self.armorvalue)
 758                 self.armorvalue = g_pickup_armormedium;
 759         if(!self.max_armorvalue)
 760                 self.max_armorvalue = g_pickup_armormedium_max;
 761         StartItem ("models/items/g_armormedium.md3", "misc/armor1.wav", g_pickup_respawntime_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
 762 }
 763
 764 void spawnfunc_item_armor_large (void) {
 765         if(!self.armorvalue)
 766                 self.armorvalue = g_pickup_armorlarge;
 767         if(!self.max_armorvalue)
 768                 self.max_armorvalue = g_pickup_armorlarge_max;
 769         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", g_pickup_respawntime_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
 770 }
 771
 772 void spawnfunc_item_health_small (void) {
 773         if(!self.max_health)
 774                 self.max_health = g_pickup_healthsmall_max;
 775         if(!self.health)
 776                 self.health = g_pickup_healthsmall;
 777         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, 20000);
 778 }
 779
 780 void spawnfunc_item_health_medium (void) {
 781         if(!self.max_health)
 782                 self.max_health = g_pickup_healthmedium_max;
 783         if(!self.health)
 784                 self.health = g_pickup_healthmedium;
 785         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, 20000);
 786 }
 787
 788 void spawnfunc_item_health_large (void) {
 789         if(!self.max_health)
 790                 self.max_health = g_pickup_healthlarge_max;
 791         if(!self.health)
 792                 self.health = g_pickup_healthlarge;
 793         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, 20000);
 794 }
 795
 796 void spawnfunc_item_health_mega (void) {
 797         if(!cvar("g_powerup_superhealth"))
 798                 return;
 799
 800         if(g_arena && !cvar("g_arena_powerups"))
 801                 return;
 802
 803         if(g_minstagib) {
 804                 minstagib_items(IT_NAILS);
 805         } else {
 806                 if(!self.max_health)
 807                         self.max_health = g_pickup_healthmega_max;
 808                 if(!self.health)
 809                         self.health = g_pickup_healthmega;
 810                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, 20000);
 811         }
 812 }
 813
 814 // support old misnamed entities
 815 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Nexuiz maps it is an armor shard
 816 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
 817 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
 818 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
 819 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
 820
 821 void spawnfunc_item_strength (void) {
 822         if(!cvar("g_powerup_strength"))
 823                 return;
 824
 825         if(g_arena && !cvar("g_arena_powerups"))
 826                 return;
 827
 828         if(g_minstagib) {
 829                 minstagib_items(IT_STRENGTH);
 830         } else {
 831                 precache_sound("weapons/strength_fire.wav");
 832                 self.strength_finished = 30;
 833                 self.effects = EF_ADDITIVE;
 834                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
 835         }
 836 }
 837
 838 void spawnfunc_item_invincible (void) {
 839         if(!cvar("g_powerup_shield"))
 840                 return;
 841
 842         if(g_arena && !cvar("g_arena_powerups"))
 843                 return;
 844
 845         if(g_minstagib) {
 846                 minstagib_items(IT_INVINCIBLE);
 847         } else {
 848                 self.invincible_finished = 30;
 849                 self.effects = EF_ADDITIVE;
 850                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, "Invulnerability", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
 851         }
 852 }
 853
 854 void spawnfunc_item_minst_cells (void) {
 855         if (g_minstagib)
 856         {
 857                 minst_no_auto_cells = 1;
 858                 minstagib_items(IT_CELLS);
 859         }
 860         else
 861                 remove(self);
 862 }
 863
 864 // compatibility:
 865 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
 866
 867 void spawnfunc_misc_models (void)
 868 {
 869         SetBrushEntityModel();
 870 }
 871
 872 void func_wall_use (void)
 873 {
 874         if(teams_matter)
 875         {
 876                 if(activator.team)
 877                         self.colormap = (activator.team - 1) * 0x11;
 878                 else
 879                         self.colormap = 0x00;
 880         }
 881         else
 882                 self.colormap = ceil(random() * 256) - 1;
 883         self.colormap |= 1024; // RENDER_COLORMAPPED
 884 }
 885
 886 void spawnfunc_func_wall (void)
 887 {
 888         SetBrushEntityModel();
 889         self.solid = SOLID_BSP;
 890         self.use = func_wall_use;
 891 }
 892
 893 float target_item_func_set(float a, float b)
 894 {
 895         if(b == 0)
 896                 return a;
 897         else if(b < 0)
 898                 return 0;
 899         else
 900                 return b;
 901 }
 902
 903 float target_item_func_min(float a, float b)
 904 {
 905         if(b == 0)
 906                 return a;
 907         else if(b < 0)
 908                 return 0;
 909         else
 910                 return min(a, b);
 911 }
 912
 913 float target_item_func_max(float a, float b)
 914 {
 915         return max(a, b);
 916 }
 917
 918 float target_item_func_bitset(float a, float b)
 919 {
 920         return b;
 921 }
 922
 923 float target_item_func_and(float a, float b)
 924 {
 925         return a & b;
 926 }
 927
 928 float target_item_func_itembitset(float a, float b)
 929 {
 930         return (a - (a & (IT_UNLIMITED_AMMO | IT_STRENGTH | IT_INVINCIBLE))) | b;
 931 }
 932
 933 float target_item_func_itemand(float a, float b)
 934 {
 935         return (a - (a & (IT_UNLIMITED_AMMO | IT_STRENGTH | IT_INVINCIBLE))) | (a & b);
 936 }
 937
 938 float target_item_func_or(float a, float b)
 939 {
 940         return a | b;
 941 }
 942
 943 float target_item_func_andnot(float a, float b)
 944 {
 945         return a - (a & b);
 946 }
 947
 948 float target_item_changed;
 949 void target_item_change(float binary, .float field, float(float a, float b) func, string sound_increase, string sound_decrease)
 950 {
 951         float n, d;
 952         n = func(activator.field, self.field);
 953
 954         if(binary)
 955         {
 956                 d = n & activator.field;
 957                 if(d != n) // bits added?
 958                         d = +1;
 959                 else if(d != activator.field) // bits removed?
 960                         d = -1;
 961                 else
 962                         d = 0;
 963         }
 964         else
 965                 d = n - activator.field;
 966
 967         if(d < 0)
 968         {
 969                 if(sound_decrease != "")
 970                         sound (activator, CHAN_AUTO, sound_decrease, VOL_BASE, ATTN_NORM);
 971                 target_item_changed = 1;
 972         }
 973         else if(d > 0)
 974         {
 975                 if(sound_increase != "")
 976                         sound (activator, CHAN_AUTO, sound_increase, VOL_BASE, ATTN_NORM);
 977                 target_item_changed = 1;
 978         }
 979         activator.field = n;
 980 }
 981
 982 void target_items_use (void)
 983 {
 984         float h0, a0;
 985         if(activator.classname != "player")
 986                 return;
 987         if(activator.deadflag != DEAD_NO)
 988                 return;
 989         EXACTTRIGGER_TOUCH;
 990
 991         entity e;
 992         for(e = world; (e = find(e, classname, "droppedweapon")); )
 993                 if(e.enemy == activator)
 994                         remove(e);
 995
 996         float _switchweapon;
 997         _switchweapon = FALSE;
 998         if (activator.autoswitch)
 999                 if (activator.switchweapon == w_getbestweapon(activator))
1000                         _switchweapon = TRUE;
1001
1002         a0 = activator.armorvalue;
1003         h0 = activator.health;
1004         target_item_changed = 0;
1005
1006         if(self.spawnflags == 0) // SET
1007         {
1008                 target_item_change(0, ammo_shells, target_item_func_set, "misc/itempickup.wav", "");
1009                 target_item_change(0, ammo_nails, target_item_func_set, "misc/itempickup.wav", "");
1010                 target_item_change(0, ammo_rockets, target_item_func_set, "misc/itempickup.wav", "");
1011                 target_item_change(0, ammo_cells, target_item_func_set, "misc/itempickup.wav", "");
1012                 target_item_change(0, health, target_item_func_set, "misc/megahealth.wav", "");
1013                 target_item_change(0, armorvalue, target_item_func_set, "misc/armor25.wav", "");
1014                 target_item_change(1, items, target_item_func_itembitset, "misc/powerup.wav", "");
1015                 target_item_change(1, weapons, target_item_func_bitset, "weapons/weaponpickup.wav", "");
1016
1017                 if((self.items & activator.items) & IT_STRENGTH)
1018                         activator.strength_finished = time + self.strength_finished;
1019                 if((self.items & activator.items) & IT_INVINCIBLE)
1020                         activator.invincible_finished = time + self.invincible_finished;
1021         }
1022         else if(self.spawnflags == 1) // AND/MIN
1023         {
1024                 target_item_change(0, ammo_shells, target_item_func_min, "misc/itempickup.wav", "");
1025                 target_item_change(0, ammo_nails, target_item_func_min, "misc/itempickup.wav", "");
1026                 target_item_change(0, ammo_rockets, target_item_func_min, "misc/itempickup.wav", "");
1027                 target_item_change(0, ammo_cells, target_item_func_min, "misc/itempickup.wav", "");
1028                 target_item_change(0, health, target_item_func_min, "misc/megahealth.wav", "");
1029                 target_item_change(0, armorvalue, target_item_func_min, "misc/armor25.wav", "");
1030                 target_item_change(1, items, target_item_func_itemand, "misc/powerup.wav", "");
1031                 target_item_change(1, weapons, target_item_func_and, "weapons/weaponpickup.wav", "");
1032
1033                 if((self.items & activator.items) & IT_STRENGTH)
1034                         activator.strength_finished = min(activator.strength_finished, time + self.strength_finished);
1035                 if((self.items & activator.items) & IT_INVINCIBLE)
1036                         activator.invincible_finished = min(activator.invincible_finished, time + self.invincible_finished);
1037         }
1038         else if(self.spawnflags == 2) // OR/MAX
1039         {
1040                 target_item_change(0, ammo_shells, target_item_func_max, "misc/itempickup.wav", "");
1041                 target_item_change(0, ammo_nails, target_item_func_max, "misc/itempickup.wav", "");
1042                 target_item_change(0, ammo_rockets, target_item_func_max, "misc/itempickup.wav", "");
1043                 target_item_change(0, ammo_cells, target_item_func_max, "misc/itempickup.wav", "");
1044                 target_item_change(0, health, target_item_func_max, "misc/megahealth.wav", "");
1045                 target_item_change(0, armorvalue, target_item_func_max, "misc/armor25.wav", "");
1046                 target_item_change(1, items, target_item_func_or, "misc/powerup.wav", "");
1047                 target_item_change(1, weapons, target_item_func_or, "weapons/weaponpickup.wav", "");
1048
1049                 if((self.items & activator.items) & IT_STRENGTH)
1050                         activator.strength_finished = max(activator.strength_finished, time + self.strength_finished);
1051                 if((self.items & activator.items) & IT_INVINCIBLE)
1052                         activator.invincible_finished = max(activator.invincible_finished, time + self.invincible_finished);
1053         }
1054         else if(self.spawnflags == 4) // ANDNOT/MIN
1055         {
1056                 target_item_change(0, ammo_shells, target_item_func_min, "misc/itempickup.wav", "");
1057                 target_item_change(0, ammo_nails, target_item_func_min, "misc/itempickup.wav", "");
1058                 target_item_change(0, ammo_rockets, target_item_func_min, "misc/itempickup.wav", "");
1059                 target_item_change(0, ammo_cells, target_item_func_min, "misc/itempickup.wav", "");
1060                 target_item_change(0, health, target_item_func_min, "misc/megahealth.wav", "");
1061                 target_item_change(0, armorvalue, target_item_func_min, "misc/armor25.wav", "");
1062                 target_item_change(1, items, target_item_func_andnot, "misc/powerup.wav", "");
1063                 target_item_change(1, weapons, target_item_func_andnot, "weapons/weaponpickup.wav", "");
1064
1065                 if((self.items & activator.items) & IT_STRENGTH)
1066                         activator.strength_finished = min(activator.strength_finished, time + self.strength_finished);
1067                 if((self.items & activator.items) & IT_INVINCIBLE)
1068                         activator.invincible_finished = min(activator.invincible_finished, time + self.invincible_finished);
1069         }
1070
1071         if not(activator.items & IT_STRENGTH)
1072                 activator.strength_finished = 0;
1073         if not(activator.items & IT_INVINCIBLE)
1074                 activator.invincible_finished = 0;
1075
1076         if(activator.health > h0)
1077                 activator.pauserothealth_finished = max(activator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
1078         else if(activator.health < h0)
1079                 activator.pauseregen_finished = max(activator.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
1080
1081         if(activator.armorvalue > a0)
1082                 activator.pauserotarmor_finished = max(activator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
1083
1084         if not(activator.weapons & W_WeaponBit(activator.switchweapon))
1085                 _switchweapon = TRUE;
1086         if(_switchweapon)
1087                 W_SwitchWeapon_Force(activator, w_getbestweapon(activator));
1088
1089         if(target_item_changed)
1090                 centerprint(activator, self.message);
1091 }
1092
1093 void spawnfunc_target_items (void)
1094 {
1095         float n, i, j;
1096         entity e;
1097         self.use = target_items_use;
1098         if(!self.strength_finished)
1099                 self.strength_finished = cvar("g_balance_powerup_strength_time");
1100         if(!self.invincible_finished)
1101                 self.invincible_finished = cvar("g_balance_powerup_invincible_time");
1102
1103         precache_sound("misc/itempickup.wav");
1104         precache_sound("misc/itempickup.wav");
1105         precache_sound("misc/itempickup.wav");
1106         precache_sound("misc/itempickup.wav");
1107         precache_sound("misc/megahealth.wav");
1108         precache_sound("misc/armor25.wav");
1109         precache_sound("misc/powerup.wav");
1110         precache_sound("weapons/weaponpickup.wav");
1111
1112         n = tokenize(self.netname);
1113         for(i = 0; i < n; ++i)
1114         {
1115                 if(argv(i) == "unlimited_ammo") self.items |= IT_UNLIMITED_AMMO;
1116                 if(argv(i) == "strength")       self.items |= IT_STRENGTH;
1117                 if(argv(i) == "invincible")     self.items |= IT_INVINCIBLE;
1118                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1119                 {
1120                         e = get_weaponinfo(j);
1121                         if(argv(i) == e.netname)
1122                         {
1123                                 self.weapons |= e.weapons;
1124                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1125                                         weapon_action(e.weapon, WR_PRECACHE);
1126                         }
1127                 }
1128         }
1129 }