data/qcsrc/server/t_items.qc

   1 //void Item_ClearRespawnEffect (void) {
   2 //      self.effects = self.effects - (self.effects & EF_STARDUST);
   3 //}
   4
   5 void Item_Respawn (void)
   6 {
   7         self.model = self.mdl;          // restore original model
   8         self.solid = SOLID_TRIGGER;     // allow it to be touched again
   9         sound (self, CHAN_VOICE, "misc/itemrespawn.ogg", 1, ATTN_NORM); // play respawn sound
  10         setorigin (self, self.origin);
  11
  12         // LordHavoc: replaced respawn stardust effect with a custom te_wizspike
  13         te_wizspike(self.origin + self.mins_z * '0 0 1' + '0 0 48');
  14         //// Savage: Add simple Respawn effect and make sure it gets removed
  15         //self.effects = self.effects | EF_STARDUST;
  16         //self.think = Item_ClearRespawnEffect;
  17         //self.nextthink = time + 0.1;
  18 }
  19
  20 void Item_Touch (void)
  21 {
  22         local entity oldself;
  23         local float _switchweapon;
  24
  25         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
  26         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
  27         {
  28                 remove(self);
  29                 return;
  30         }
  31         if (other.classname != "player")
  32                 return;
  33         if (other.deadflag)
  34                 return;
  35         if (self.solid != SOLID_TRIGGER)
  36                 return;
  37         if (self.health && other.health >= other.max_health)
  38                 return;
  39         if (self.owner == other)
  40                 return;
  41         // Savage: Remove the respawn effect if still present
  42         self.effects = self.effects - (self.effects & EF_STARDUST);
  43
  44         sound (self, CHAN_BODY, self.noise, 1, ATTN_NORM);
  45
  46         // in case the player has autoswitch enabled do the following:
  47         // if the player is using their best weapon before items are given, they
  48         // probably want to switch to an even better weapon after items are given
  49         _switchweapon = (other.autoswitch && (other.switchweapon == w_getbestweapon(other)) || cvar("g_minstagib"));
  50
  51         if (cvar("g_minstagib"))
  52         {
  53                 if (self.ammo_cells)
  54                 {
  55                         // play some cool sounds ;)
  56                         centerprint(other, "\n");
  57                         if(other.health <= 5)
  58                                 stuffcmd(other, "play2 announcer/robotic/lastsecond.ogg\n");
  59                         else if(other.health < 50)
  60                                 stuffcmd(other, "play2 announcer/robotic/narrowly.ogg\n");
  61                         // sound not available
  62                         // else if(self.items == IT_CELLS)
  63                         //      stuffcmd(other, "play2 announce/robotic/ammo.ogg\n");
  64
  65                         if (self.items & IT_NEX)
  66                                 W_GiveWeapon (other, IT_NEX, "Nex");
  67                         if (self.ammo_cells)
  68                                 other.ammo_cells = min (other.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
  69                         other.health = 100;
  70                 }
  71
  72                 // extralife powerup
  73                 if (self.max_health)
  74                 {
  75                         // sound not available
  76                         // stuffcmd(other, "play2 announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.ogg\n");
  77                         other.armorvalue = other.armorvalue + cvar("g_minstagib_extralives");
  78                         sprint(other, "^3You picked up some extra lives\n");
  79                 }
  80
  81                 // invis powerup
  82                 if (self.strength_finished)
  83                 {
  84                         // sound not available
  85                         // stuffcmd(other, "play2 announce/robotic/invisible.ogg\n");
  86                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
  87                 }
  88
  89                 // speed powerup
  90                 if (self.invincible_finished)
  91                 {
  92                         // sound not available
  93                         // stuffcmd(other, "play2 announce/robotic/speed.ogg\n");
  94                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
  95                 }
  96         }
  97         else
  98         {
  99                 if (cvar("deathmatch") == 2 || cvar("g_weapon_stay"))
 100                 {
 101                         if (self.flags & FL_WEAPON && other.items & self.items && self.classname != "droppedweapon")
 102                                 return;
 103                         if (other.items & self.items && self.flags & FL_TOSSED) // don't let players stack ammo by tossing weapons
 104                                 return;
 105                 }
 106
 107                 if (self.ammo_shells)
 108                         other.ammo_shells = min (other.ammo_shells + self.ammo_shells, 999);
 109                 if (self.ammo_nails)
 110                         other.ammo_nails = min (other.ammo_nails + self.ammo_nails, 999);
 111                 if (self.ammo_rockets)
 112                         other.ammo_rockets = min (other.ammo_rockets + self.ammo_rockets, 999);
 113                 if (self.ammo_cells)
 114                         other.ammo_cells = min (other.ammo_cells + self.ammo_cells, 999);
 115
 116                 if (self.items & IT_UZI)                W_GiveWeapon (other, IT_UZI, self.netname);
 117                 if (self.items & IT_SHOTGUN)            W_GiveWeapon (other, IT_SHOTGUN, self.netname);
 118                 if (self.items & IT_GRENADE_LAUNCHER)   W_GiveWeapon (other, IT_GRENADE_LAUNCHER, self.netname);
 119                 if (self.items & IT_ELECTRO)            W_GiveWeapon (other, IT_ELECTRO, self.netname);
 120                 if (self.items & IT_NEX)                W_GiveWeapon (other, IT_NEX, self.netname);
 121                 if (self.items & IT_HAGAR)              W_GiveWeapon (other, IT_HAGAR, self.netname);
 122                 if (self.items & IT_ROCKET_LAUNCHER)    W_GiveWeapon (other, IT_ROCKET_LAUNCHER, self.netname);
 123                 if (self.items & IT_CRYLINK)            W_GiveWeapon (other, IT_CRYLINK, self.netname);
 124
 125                 if (self.strength_finished)
 126                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 127                 if (self.invincible_finished)
 128                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 129                 //if (self.speed_finished)
 130                 //      other.speed_finished = max(other.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 131                 //if (self.slowmo_finished)
 132                 //      other.slowmo_finished = max(other.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 133
 134                 if (self.max_health)
 135                 {
 136                         other.health = other.health + self.max_health;
 137                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 138                 }
 139                 if (self.health && other.health < other.max_health)
 140                         other.health = min(other.health + self.health, other.max_health);
 141                 if (self.armorvalue)
 142                 {
 143                         other.armorvalue = other.armorvalue + self.armorvalue;
 144                         other.pauserotarmor_finished = max(other.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 145                 }
 146         }
 147
 148         sound (other, CHAN_AUTO, self.item_pickupsound, 1, ATTN_NORM);
 149
 150         oldself = self;
 151         self = other;
 152
 153         if (_switchweapon)
 154                 self.switchweapon = w_getbestweapon(self);
 155         if (self.switchweapon != self.weapon)
 156                 self.cnt = self.weapon;
 157
 158         self = oldself;
 159
 160         if (self.classname == "droppedweapon")
 161                 remove (self);
 162         else if(self.flags & FL_WEAPON && (cvar("deathmatch") == 2 || cvar("g_weapon_stay")))
 163                 return;
 164         else
 165         {
 166                 self.solid = SOLID_NOT;
 167                 self.model = string_null;
 168                 self.nextthink = time + self.respawntime;
 169                 self.think = Item_Respawn;
 170                 setorigin (self, self.origin);
 171         }
 172 }
 173
 174 // Savage: used for item garbage-collection
 175 // TODO: perhaps nice special effect?
 176 void RemoveItem(void) = {
 177         remove(self);
 178 }
 179
 180 // pickup evaluation functions
 181 // these functions decide how desirable an item is to the bots
 182
 183 float(entity player, entity item) generic_pickupevalfunc = {return item.bot_pickupbasevalue;};
 184
 185 float(entity player, entity item) weapon_pickupevalfunc =
 186 {
 187         // if we already have the weapon, rate it 1/5th normal value
 188         if ((player.items & item.items) == item.items)
 189                 return item.bot_pickupbasevalue * 0.2;
 190         return item.bot_pickupbasevalue;
 191 };
 192
 193 float(entity player, entity item) commodity_pickupevalfunc =
 194 {
 195         float c;
 196         c = 0;
 197         // TODO: figure out if the player even has the weapon this ammo is for?
 198         // may not affect strategy much though...
 199         // find out how much ammo the player has, in terms of this ammo pickup
 200         // (how many of these ammo pickups it would take to total the player's
 201         // current ammo)
 202         if (item.ammo_shells)
 203                 c = c + player.ammo_shells / item.ammo_shells;
 204         if (item.ammo_nails)
 205                 c = c + player.ammo_nails / item.ammo_nails;
 206         if (item.ammo_rockets)
 207                 c = c + player.ammo_rockets / item.ammo_rockets;
 208         if (item.ammo_cells)
 209                 c = c + player.ammo_cells / item.ammo_cells;
 210         if (item.armorvalue)
 211                 c = c + player.armorvalue / item.armorvalue;
 212         if (item.health)
 213                 c = c + player.health / item.health / 10;
 214         // the more ammo the player has, the less desirable this pickup becomes
 215         c = 1 / (1 + c);
 216
 217         if (cvar("deathmatch") == 2) // weapon stay is on, so weapons the player already has are of no interest
 218         if (item.flags & FL_WEAPON)
 219         if (self.items & item.items)
 220         if (item.classname != "droppedweapon")
 221                 c = 0;
 222
 223         return item.bot_pickupbasevalue * c;
 224 };
 225
 226
 227 .float is_item;
 228 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, string itemname, float itemid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 229 {
 230         startitem_failed = FALSE;
 231
 232         if (self.classname != "droppedweapon")
 233         {
 234                 if(cvar("spawn_debug") >= 2)
 235                 {
 236                         entity otheritem;
 237                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 238                         {
 239                                 if(otheritem.is_item)
 240                                 {
 241                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 242                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 243                                         error("Mapper sucks.");
 244                                 }
 245                         }
 246                         self.is_item = TRUE;
 247                 }
 248
 249                 waypoint_spawnforitem(self);
 250         }
 251
 252         if (!(cvar("g_pickup_items") && !cvar("g_nixnex")) && !cvar("g_minstagib") &&
 253                         itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 254         {
 255                 startitem_failed = TRUE;
 256                 remove (self);
 257                 return;
 258         }
 259
 260         if (cvar("g_minstagib"))
 261         {
 262                 // don't remove dropped items and powerups
 263                 if (self.classname != "droppedweapon" &&
 264                     self.classname != "minstagib")
 265                 {
 266                         startitem_failed = TRUE;
 267                         remove (self);
 268                         return;
 269                 }
 270         }
 271
 272         if(cvar("g_lms") && (self.classname != "droppedweapon"))
 273         {
 274                 startitem_failed = TRUE;
 275                 remove(self);
 276                 return;
 277         }
 278
 279         if(cvar("g_instagib") || cvar("g_rocketarena"))
 280         {
 281                 startitem_failed = TRUE;
 282                 remove(self);
 283                 return;
 284         }
 285
 286         if (self.classname == "droppedweapon")
 287         {
 288                 // don't drop if in a NODROP zone (such as lava)
 289                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 290                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 291                 {
 292                         startitem_failed = TRUE;
 293                         remove(self);
 294                         return;
 295                 }
 296         }
 297
 298         if(itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2 |
 299                                 IT_ROCKET_LAUNCHER | IT_HAGAR | IT_NEX | IT_CRYLINK | IT_ELECTRO |
 300                                 IT_GRENADE_LAUNCHER | IT_UZI | IT_SHOTGUN | IT_LASER) && self.classname != "droppedweapon")
 301         {
 302                 self.target = "###item###"; // for finding the nearest item using find()
 303         }
 304         self.bot_pickup = TRUE;
 305         self.bot_pickupevalfunc = pickupevalfunc;
 306         self.bot_pickupbasevalue = pickupbasevalue;
 307         self.mdl = itemmodel;
 308         //self.noise = pickupsound;
 309         self.item_pickupsound = pickupsound;
 310         // let mappers override respawntime
 311         if (!self.respawntime)
 312                 self.respawntime = defaultrespawntime;
 313         self.netname = itemname;
 314         self.items = itemid;
 315         self.flags = FL_ITEM | itemflags;
 316         if (self.noalign)
 317                 self.movetype = MOVETYPE_NONE;
 318         else
 319                 self.movetype = MOVETYPE_TOSS;
 320         self.solid = SOLID_TRIGGER;
 321         self.touch = Item_Touch;
 322         setmodel (self, self.mdl);
 323         setsize (self, '-16 -16 0', '16 16 32');
 324         if (itemflags & FL_WEAPON)
 325         {
 326                 // neutral team color for pickup weapons
 327                 self.colormap = 160 * 1024 + 160;
 328         }
 329
 330         // Savage: remove thrown items after a certain period of time ("garbage collection")
 331         if (self.classname == "droppedweapon")
 332         {
 333                 self.think = RemoveItem;
 334                 self.nextthink = time + 60;
 335         }
 336         else if (!self.noalign)
 337         {
 338                 // first nudge it off the floor a little bit to avoid math errors
 339                 setorigin(self, self.origin + '0 0 1');
 340                 // note droptofloor returns FALSE if stuck/or would fall too far
 341                 droptofloor();
 342         }
 343
 344         if (cvar("g_fullbrightitems"))
 345                 self.effects = self.effects | EF_FULLBRIGHT;
 346 }
 347
 348 /* replace items in minstagib
 349  * IT_STRENGTH   = invisibility
 350  * IT_NAILS      = extra lives
 351  * IT_INVINCIBLE = speed
 352  */
 353 void minstagib_items (float itemid)
 354 {
 355         // we don't want to replace dropped weapons ;)
 356         if (self.classname == "droppedweapon")
 357         {
 358                 self.ammo_cells = 25;
 359                 StartItem ("models/weapons/g_nex.md3",
 360                         "weapons/weaponpickup.ogg", 15,
 361                         "Nex Gun", IT_NEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 362                 return;
 363         }
 364
 365         local float rnd;
 366         self.classname = "minstagib";
 367
 368         // replace rocket launchers and nex guns with ammo cells
 369         if (itemid == IT_CELLS)
 370         {
 371                 self.ammo_cells = 1;
 372                 StartItem ("models/items/a_cells.md3",
 373                         "misc/itempickup.ogg", 45,
 374                         "Nex Ammo", IT_CELLS, 0, generic_pickupevalfunc, 100);
 375                 return;
 376         }
 377
 378         // randomize
 379         rnd = random() * 3;
 380         if (rnd <= 1)
 381                 itemid = IT_STRENGTH;
 382         else if (rnd <= 2)
 383                 itemid = IT_NAILS;
 384         else
 385                 itemid = IT_INVINCIBLE;
 386
 387         // replace with invis
 388         if (itemid == IT_STRENGTH)
 389         {
 390                 self.effects = EF_ADDITIVE;
 391                 self.strength_finished = 30;
 392                 StartItem ("models/items/g_strength.md3",
 393                         "misc/powerup.ogg", 120,
 394                         "Invisibility", IT_STRENGTH, FL_POWERUP, generic_pickupevalfunc, 1000);
 395         }
 396         // replace with extra lives
 397         if (itemid == IT_NAILS)
 398         {
 399                 self.max_health = 1;
 400                 StartItem ("models/items/g_h100.md3",
 401                         "misc/megahealth.ogg", 120,
 402                         "Extralife", IT_NAILS, FL_POWERUP, generic_pickupevalfunc, 1000);
 403
 404         }
 405         // replace with speed
 406         if (itemid == IT_INVINCIBLE)
 407         {
 408                 self.effects = EF_ADDITIVE;
 409                 self.invincible_finished = 30;
 410                 StartItem ("models/items/g_invincible.md3",
 411                         "misc/powerup_shield.ogg", 120,
 412                         "Speed", IT_INVINCIBLE, FL_POWERUP, generic_pickupevalfunc, 1000);
 413         }
 414
 415 }
 416
 417 void weapon_uzi (void) {
 418         if(!self.ammo_nails)
 419                 self.ammo_nails = 120;
 420         StartItem ("models/weapons/g_uzi.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_UZI), IT_UZI, FL_WEAPON, weapon_pickupevalfunc, 1000);
 421 }
 422
 423 void weapon_shotgun (void) {
 424         if(!self.ammo_shells)
 425                 self.ammo_shells = 15;
 426         StartItem ("models/weapons/g_shotgun.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_SHOTGUN), IT_SHOTGUN, FL_WEAPON, weapon_pickupevalfunc, 1000);
 427 }
 428
 429 void weapon_grenadelauncher (void) {
 430         if(!self.ammo_rockets)
 431                 self.ammo_rockets = 15;
 432         StartItem ("models/weapons/g_gl.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_GRENADE_LAUNCHER), IT_GRENADE_LAUNCHER, FL_WEAPON, weapon_pickupevalfunc, 1000);
 433 }
 434
 435 void weapon_electro (void) {
 436         if(!self.ammo_cells)
 437                 self.ammo_cells = 25;
 438         StartItem ("models/weapons/g_electro.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_ELECTRO), IT_ELECTRO, FL_WEAPON, weapon_pickupevalfunc, 1000);
 439 }
 440
 441 void weapon_crylink (void) {
 442         if(!self.ammo_cells)
 443                 self.ammo_cells = 25;
 444         StartItem ("models/weapons/g_crylink.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_CRYLINK), IT_CRYLINK, FL_WEAPON, weapon_pickupevalfunc, 1000);
 445 }
 446
 447 void weapon_nex (void) {
 448         if (cvar("g_minstagib")) {
 449                 minstagib_items(IT_CELLS);
 450         } else {
 451                 float nextime;
 452                 if(!self.ammo_cells)
 453                         self.ammo_cells = 25;
 454                 nextime = cvar("g_balance_nex_respawntime_modifier");
 455                 if(nextime)
 456                         nextime = 15 * nextime;
 457                 else
 458                         nextime = 15;
 459                 StartItem ("models/weapons/g_nex.md3", "weapons/weaponpickup.ogg", nextime, W_Name(WEP_NEX), IT_NEX, FL_WEAPON, weapon_pickupevalfunc, 1000);
 460         }
 461 }
 462
 463 void weapon_hagar (void) {
 464         if(!self.ammo_rockets)
 465                 self.ammo_rockets = 15;
 466         StartItem ("models/weapons/g_hagar.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_HAGAR), IT_HAGAR, FL_WEAPON, weapon_pickupevalfunc, 1000);
 467 }
 468
 469 void weapon_rocketlauncher (void) {
 470         if (cvar("g_minstagib")) {
 471                 minstagib_items(IT_CELLS);
 472         } else {
 473                 if(!self.ammo_rockets)
 474                         self.ammo_rockets = 15;
 475                 StartItem ("models/weapons/g_rl.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_ROCKET_LAUNCHER), IT_ROCKET_LAUNCHER, FL_WEAPON, weapon_pickupevalfunc, 1000);
 476         }
 477 }
 478
 479 void item_rockets (void) {
 480         if(!self.ammo_rockets)
 481                 self.ammo_rockets = 15;
 482         StartItem ("models/items/a_rockets.md3", "misc/itempickup.ogg", 15, "rockets", IT_ROCKETS, 0, commodity_pickupevalfunc, 100);
 483 }
 484
 485 void item_bullets (void) {
 486         if(!self.ammo_nails)
 487                 self.ammo_nails = 120;
 488         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.ogg", 15, "bullets", IT_NAILS, 0, commodity_pickupevalfunc, 100);
 489 }
 490
 491 void item_cells (void) {
 492         if(!self.ammo_cells)
 493                 self.ammo_cells = 25;
 494         StartItem ("models/items/a_cells.md3", "misc/itempickup.ogg", 15, "cells", IT_CELLS, 0, commodity_pickupevalfunc, 100);
 495 }
 496
 497 void item_shells (void) {
 498         if(!self.ammo_shells)
 499                 self.ammo_shells = 15;
 500         StartItem ("models/items/a_shells.md3", "misc/itempickup.ogg", 15, "shells", IT_SHELLS, 0, commodity_pickupevalfunc, 100);
 501 }
 502
 503 void item_armor1 (void) {
 504         if(!self.armorvalue)
 505                 self.armorvalue = 5;
 506         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", 15, "Armor Shard", IT_ARMOR_SHARD, 0, commodity_pickupevalfunc, 100);
 507 }
 508
 509 void item_armor25 (void) {
 510         if(!self.armorvalue)
 511                 self.armorvalue = 100;
 512         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", 30, "Armor", IT_ARMOR, 0, commodity_pickupevalfunc, 2000);
 513 }
 514
 515 void item_health1 (void) {
 516         if(!self.max_health)
 517                 self.max_health = 5;
 518         StartItem ("models/items/g_h1.md3", "misc/minihealth.ogg", 15, "5 Health", IT_5HP, 0, commodity_pickupevalfunc, 100);
 519 }
 520
 521 void item_health25 (void) {
 522         if(!self.max_health)
 523                 self.max_health = 25;
 524         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.ogg", 15, "25 Health", IT_25HP, 0, commodity_pickupevalfunc, 500);
 525 }
 526
 527 void item_health100 (void) {
 528         if(!cvar("g_powerup_superhealth"))
 529                 return;
 530
 531         if(cvar("g_arena") && !cvar("g_arena_powerups"))
 532                 return;
 533
 534         if(cvar("g_minstagib")) {
 535                 minstagib_items(IT_NAILS);
 536         } else {
 537                 if(!self.max_health)
 538                         self.max_health = 100;
 539                 StartItem ("models/items/g_h100.md3", "misc/megahealth.ogg", 30, "100 Health", IT_HEALTH, 0, commodity_pickupevalfunc, 2000);
 540         }
 541 }
 542
 543 void item_strength (void) {
 544         if(!cvar("g_powerup_strength"))
 545                 return;
 546
 547         if(cvar("g_arena") && !cvar("g_arena_powerups"))
 548                 return;
 549
 550         if(cvar("g_minstagib")) {
 551                 minstagib_items(IT_STRENGTH);
 552         } else {
 553                 self.strength_finished = 30;
 554                 self.effects = EF_ADDITIVE;StartItem ("models/items/g_strength.md3", "misc/powerup.ogg", 120, "Strength Powerup", IT_STRENGTH, FL_POWERUP, generic_pickupevalfunc, 10000);
 555         }
 556 }
 557
 558 void item_invincible (void) {
 559         if(!cvar("g_powerup_shield"))
 560                 return;
 561
 562         if(cvar("g_arena") && !cvar("g_arena_powerups"))
 563                 return;
 564
 565         if(cvar("g_minstagib")) {
 566                 minstagib_items(IT_INVINCIBLE);
 567         } else {
 568                 self.invincible_finished = 30;
 569                 self.effects = EF_ADDITIVE;
 570                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.ogg", 120, "Invulnerability", IT_INVINCIBLE, FL_POWERUP, generic_pickupevalfunc, 10000);
 571         }
 572 }
 573 //void item_speed (void) {self.speed_finished = 30;StartItem ("models/items/g_speed.md3", "misc/powerup.wav", 120, "Speed Powerup", IT_SPEED, FL_POWERUP, generic_pickupevalfunc, 10000);}
 574 //void item_slowmo (void) {self.slowmo_finished = 30;StartItem ("models/items/g_slowmo.md3", "misc/powerup.wav", 120, "Slow Motion", IT_SLOWMO, FL_POWERUP, generic_pickupevalfunc, 10000);}
 575
 576 // compatibility:
 577 void item_quad (void) {self.classname = "item_strength";item_strength();}
 578
 579 void misc_models (void)
 580 {
 581         precache_model (self.model);
 582         setmodel (self, self.model);
 583         setsize (self, self.mins, self.maxs);
 584 }
 585
 586
 587
 588
 589
 590 floatfield Item_CounterField(float it)
 591 {
 592         switch(it)
 593         {
 594                 case IT_SHELLS:      return ammo_shells;
 595                 case IT_NAILS:       return ammo_nails;
 596                 case IT_ROCKETS:     return ammo_rockets;
 597                 case IT_CELLS:       return ammo_cells;
 598                 case IT_5HP:         return health;
 599                 case IT_25HP:        return health;
 600                 case IT_HEALTH:      return health;
 601                 case IT_ARMOR_SHARD: return armorvalue;
 602                 case IT_ARMOR:       return armorvalue;
 603                 // add more things here (health, armor)
 604                 default:             error("requested item has no counter field");
 605         }
 606 }
 607
 608 float Item_WeaponCode(float it)
 609 {
 610         switch(it)
 611         {
 612                 case IT_LASER:            return WEP_LASER;
 613                 case IT_SHOTGUN:          return WEP_SHOTGUN;
 614                 case IT_UZI:              return WEP_UZI;
 615                 case IT_GRENADE_LAUNCHER: return WEP_GRENADE_LAUNCHER;
 616                 case IT_ELECTRO:          return WEP_ELECTRO;
 617                 case IT_CRYLINK:          return WEP_CRYLINK;
 618                 case IT_NEX:              return WEP_NEX;
 619                 case IT_HAGAR:            return WEP_HAGAR;
 620                 case IT_ROCKET_LAUNCHER:  return WEP_ROCKET_LAUNCHER;
 621                 default:                  return 0;
 622         }
 623 }
 624
 625 spawnfunc Item_SpawnFunc(float it)
 626 {
 627         switch(it)
 628         {
 629                 case IT_SHOTGUN:          return weapon_shotgun;
 630                 case IT_UZI:              return weapon_uzi;
 631                 case IT_GRENADE_LAUNCHER: return weapon_grenadelauncher;
 632                 case IT_ELECTRO:          return weapon_electro;
 633                 case IT_CRYLINK:          return weapon_crylink;
 634                 case IT_NEX:              return weapon_nex;
 635                 case IT_HAGAR:            return weapon_hagar;
 636                 case IT_ROCKET_LAUNCHER:  return weapon_rocketlauncher;
 637                 // add all other item spawn functions here
 638                 default:                  error("requested item can't be spawned");
 639         }
 640 }