data/qcsrc/server/t_items.qc

   1 //void Item_ClearRespawnEffect (void) {
   2 //      self.effects = self.effects - (self.effects & EF_STARDUST);
   3 //}
   4
   5 .float max_armorvalue;
   6
   7 void Item_Respawn (void)
   8 {
   9         self.model = self.mdl;          // restore original model
  10         self.solid = SOLID_TRIGGER;     // allow it to be touched again
  11         sound (self, CHAN_VOICE, "misc/itemrespawn.wav", 1, ATTN_NORM); // play respawn sound
  12         setorigin (self, self.origin);
  13
  14         // LordHavoc: replaced respawn stardust effect with a custom te_wizspike
  15         te_wizspike(self.origin + self.mins_z * '0 0 1' + '0 0 48');
  16         //// Savage: Add simple Respawn effect and make sure it gets removed
  17         //self.effects = self.effects | EF_STARDUST;
  18         //self.think = Item_ClearRespawnEffect;
  19         //self.nextthink = time + 0.1;
  20 }
  21
  22 void Item_Touch (void)
  23 {
  24         local entity oldself;
  25         local float _switchweapon;
  26         local float pickedup;
  27         local float it;
  28
  29         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
  30         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
  31         {
  32                 remove(self);
  33                 return;
  34         }
  35         if (other.classname != "player")
  36                 return;
  37         if (other.deadflag)
  38                 return;
  39         if (self.solid != SOLID_TRIGGER)
  40                 return;
  41         if (self.owner == other)
  42                 return;
  43
  44         // if nothing happens to other, just return without taking the item
  45         pickedup = FALSE;
  46         _switchweapon = FALSE;
  47
  48         if (cvar("g_minstagib"))
  49         {
  50                 _switchweapon = TRUE;
  51                 if (self.ammo_cells)
  52                 {
  53                         pickedup = TRUE;
  54                         // play some cool sounds ;)
  55                         centerprint(other, "\n");
  56                         if(other.health <= 5)
  57                                 play2(other, "announcer/robotic/lastsecond.ogg");
  58                         else if(other.health < 50)
  59                                 play2(other, "announcer/robotic/narrowly.ogg");
  60                         // sound not available
  61                         // else if(self.items == IT_CELLS)
  62                         //      play2(other, "announce/robotic/ammo.ogg");
  63
  64                         if (self.items & IT_NEX)
  65                                 W_GiveWeapon (other, IT_NEX, "Nex");
  66                         if (self.ammo_cells)
  67                                 other.ammo_cells = min (other.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
  68                         other.health = 100;
  69                 }
  70
  71                 // extralife powerup
  72                 if (self.max_health)
  73                 {
  74                         pickedup = TRUE;
  75                         // sound not available
  76                         // play2(other, "announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.ogg");
  77                         other.armorvalue = other.armorvalue + cvar("g_minstagib_extralives");
  78                         sprint(other, "^3You picked up some extra lives\n");
  79                 }
  80
  81                 // invis powerup
  82                 if (self.strength_finished)
  83                 {
  84                         pickedup = TRUE;
  85                         // sound not available
  86                         // play2(other, "announce/robotic/invisible.ogg");
  87                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
  88                 }
  89
  90                 // speed powerup
  91                 if (self.invincible_finished)
  92                 {
  93                         pickedup = TRUE;
  94                         // sound not available
  95                         // play2(other, "announce/robotic/speed.ogg");
  96                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
  97                 }
  98         }
  99         else
 100         {
 101                 if (cvar("deathmatch") == 2 || cvar("g_weapon_stay"))
 102                 {
 103                         if (self.flags & FL_WEAPON && other.items & self.items && self.classname != "droppedweapon")
 104                                 return;
 105                         if (other.items & self.items && self.flags & FL_TOSSED) // don't let players stack ammo by tossing weapons
 106                                 return;
 107                 }
 108
 109                 // in case the player has autoswitch enabled do the following:
 110                 // if the player is using their best weapon before items are given, they
 111                 // probably want to switch to an even better weapon after items are given
 112                 if (other.autoswitch)
 113                 if (other.switchweapon == w_getbestweapon(other))
 114                         _switchweapon = TRUE;
 115
 116                 if (self.ammo_shells)
 117                 if (other.ammo_shells < g_pickup_shells_max)
 118                 {
 119                         pickedup = TRUE;
 120                         other.ammo_shells = min (other.ammo_shells + self.ammo_shells, g_pickup_shells_max);
 121                 }
 122                 if (self.ammo_nails)
 123                 if (other.ammo_nails < g_pickup_nails_max)
 124                 {
 125                         pickedup = TRUE;
 126                         other.ammo_nails = min (other.ammo_nails + self.ammo_nails, g_pickup_nails_max);
 127                 }
 128                 if (self.ammo_rockets)
 129                 if (other.ammo_rockets < g_pickup_rockets_max)
 130                 {
 131                         pickedup = TRUE;
 132                         other.ammo_rockets = min (other.ammo_rockets + self.ammo_rockets, g_pickup_rockets_max);
 133                 }
 134                 if (self.ammo_cells)
 135                 if (other.ammo_cells < g_pickup_cells_max)
 136                 {
 137                         pickedup = TRUE;
 138                         other.ammo_cells = min (other.ammo_cells + self.ammo_cells, g_pickup_cells_max);
 139                 }
 140
 141                 if (self.flags & FL_WEAPON)
 142                 if ((it = self.items - (self.items & other.items)))
 143                 {
 144                         pickedup = TRUE;
 145                         if (it & IT_UZI)                W_GiveWeapon (other, IT_UZI, self.netname);
 146                         if (it & IT_SHOTGUN)            W_GiveWeapon (other, IT_SHOTGUN, self.netname);
 147                         if (it & IT_GRENADE_LAUNCHER)   W_GiveWeapon (other, IT_GRENADE_LAUNCHER, self.netname);
 148                         if (it & IT_ELECTRO)            W_GiveWeapon (other, IT_ELECTRO, self.netname);
 149                         if (it & IT_NEX)                W_GiveWeapon (other, IT_NEX, self.netname);
 150                         if (it & IT_HAGAR)              W_GiveWeapon (other, IT_HAGAR, self.netname);
 151                         if (it & IT_ROCKET_LAUNCHER)    W_GiveWeapon (other, IT_ROCKET_LAUNCHER, self.netname);
 152                         if (it & IT_CRYLINK)            W_GiveWeapon (other, IT_CRYLINK, self.netname);
 153                 }
 154
 155                 if (self.strength_finished)
 156                 {
 157                         pickedup = TRUE;
 158                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 159                 }
 160                 if (self.invincible_finished)
 161                 {
 162                         pickedup = TRUE;
 163                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 164                 }
 165                 //if (self.speed_finished)
 166                 //{
 167                 //      pickedup = TRUE;
 168                 //      other.speed_finished = max(other.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 169                 //}
 170                 //if (self.slowmo_finished)
 171                 //{
 172                 //      pickedup = TRUE;
 173                 //      other.slowmo_finished = max(other.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 174                 //}
 175
 176                 if (self.health)
 177                 if (other.health < self.max_health)
 178                 {
 179                         pickedup = TRUE;
 180                         other.health = min(other.health + self.health, self.max_health);
 181                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 182                 }
 183                 if (self.armorvalue)
 184                 if (other.armorvalue < self.max_armorvalue)
 185                 {
 186                         pickedup = TRUE;
 187                         other.armorvalue = min(other.armorvalue + self.armorvalue, self.max_armorvalue);
 188                         other.pauserotarmor_finished = max(other.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 189                 }
 190         }
 191
 192         if (!pickedup)
 193                 return;
 194
 195         // Savage: Remove the respawn effect if still present
 196         self.effects = self.effects - (self.effects & EF_STARDUST);
 197
 198         sound (self, CHAN_BODY, self.noise, 1, ATTN_NORM);
 199         sound (other, CHAN_AUTO, self.item_pickupsound, 1, ATTN_NORM);
 200
 201         oldself = self;
 202         self = other;
 203
 204         if (_switchweapon)
 205                 self.switchweapon = w_getbestweapon(self);
 206         if (self.switchweapon != self.weapon)
 207                 self.cnt = self.weapon;
 208
 209         self = oldself;
 210
 211         if (self.classname == "droppedweapon")
 212                 remove (self);
 213         else if(self.flags & FL_WEAPON && (cvar("deathmatch") == 2 || cvar("g_weapon_stay")))
 214                 return;
 215         else
 216         {
 217                 self.solid = SOLID_NOT;
 218                 self.model = string_null;
 219                 self.nextthink = time + self.respawntime;
 220                 self.think = Item_Respawn;
 221                 setorigin (self, self.origin);
 222         }
 223 }
 224
 225 // Savage: used for item garbage-collection
 226 // TODO: perhaps nice special effect?
 227 void RemoveItem(void) = {
 228         remove(self);
 229 }
 230
 231 // pickup evaluation functions
 232 // these functions decide how desirable an item is to the bots
 233
 234 float(entity player, entity item) generic_pickupevalfunc = {return item.bot_pickupbasevalue;};
 235
 236 float(entity player, entity item) weapon_pickupevalfunc =
 237 {
 238         // if we already have the weapon, rate it 1/5th normal value
 239         if ((player.items & item.items) == item.items)
 240                 return item.bot_pickupbasevalue * 0.2;
 241         return item.bot_pickupbasevalue;
 242 };
 243
 244 float(entity player, entity item) commodity_pickupevalfunc =
 245 {
 246         float c;
 247         c = 0;
 248         // TODO: figure out if the player even has the weapon this ammo is for?
 249         // may not affect strategy much though...
 250         // find out how much more ammo/armor/health the player can hold
 251         if (item.ammo_shells)
 252         if (player.ammo_shells < g_pickup_shells_max)
 253                 c = c + 1 - min(player.ammo_shells / g_pickup_shells_max, 1);
 254         if (item.ammo_nails)
 255         if (player.ammo_nails < g_pickup_nails_max)
 256                 c = c + 1 - min(player.ammo_nails / g_pickup_nails_max, 1);
 257         if (item.ammo_rockets)
 258         if (player.ammo_rockets < g_pickup_rockets_max)
 259                 c = c + 1 - min(player.ammo_rockets / g_pickup_rockets_max, 1);
 260         if (item.ammo_cells)
 261         if (player.ammo_cells < g_pickup_cells_max)
 262                 c = c + 1 - min(player.ammo_cells / g_pickup_cells_max, 1);
 263         if (item.armorvalue)
 264         if (player.armorvalue < item.max_armorvalue)
 265                 c = c + 1 - min(player.armorvalue / item.max_armorvalue, 1);
 266         if (item.health)
 267         if (player.health < item.max_health)
 268                 c = c + 1 - min(player.health / item.max_health, 1);
 269
 270         if (cvar("deathmatch") == 2) // weapon stay is on, so weapons the player already has are of no interest
 271         if (item.flags & FL_WEAPON)
 272         if (self.items & item.items)
 273         if (item.classname != "droppedweapon")
 274                 c = 0;
 275
 276         return item.bot_pickupbasevalue * c;
 277 };
 278
 279
 280 .float is_item;
 281 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, string itemname, float itemid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 282 {
 283         startitem_failed = FALSE;
 284
 285         if (self.classname != "droppedweapon")
 286         {
 287                 if(cvar("spawn_debug") >= 2)
 288                 {
 289                         entity otheritem;
 290                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 291                         {
 292                                 if(otheritem.is_item)
 293                                 {
 294                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 295                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 296                                         error("Mapper sucks.");
 297                                 }
 298                         }
 299                         self.is_item = TRUE;
 300                 }
 301
 302                 waypoint_spawnforitem(self);
 303
 304                 itemsInMap |= itemid;
 305         }
 306
 307         if (!(cvar("g_pickup_items") && !cvar("g_nixnex")) && !cvar("g_minstagib") &&
 308                         itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 309         {
 310                 startitem_failed = TRUE;
 311                 remove (self);
 312                 return;
 313         }
 314
 315         if (cvar("g_minstagib"))
 316         {
 317                 // don't remove dropped items and powerups
 318                 if (self.classname != "droppedweapon" &&
 319                     self.classname != "minstagib")
 320                 {
 321                         startitem_failed = TRUE;
 322                         remove (self);
 323                         return;
 324                 }
 325         }
 326
 327         if(cvar("g_lms") && (self.classname != "droppedweapon"))
 328         {
 329                 startitem_failed = TRUE;
 330                 remove(self);
 331                 return;
 332         }
 333
 334         if(cvar("g_instagib") || cvar("g_rocketarena"))
 335         {
 336                 startitem_failed = TRUE;
 337                 remove(self);
 338                 return;
 339         }
 340
 341         if (self.classname == "droppedweapon")
 342         {
 343                 // don't drop if in a NODROP zone (such as lava)
 344                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 345                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 346                 {
 347                         startitem_failed = TRUE;
 348                         remove(self);
 349                         return;
 350                 }
 351         }
 352
 353         if (self.classname != "droppedweapon")
 354         {
 355                 precache_model (itemmodel);
 356                 precache_sound (pickupsound);
 357                 precache_sound ("misc/itemrespawn.wav");
 358         }
 359
 360         if(itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2 |
 361                                 IT_ROCKET_LAUNCHER | IT_HAGAR | IT_NEX | IT_CRYLINK | IT_ELECTRO |
 362                                 IT_GRENADE_LAUNCHER | IT_UZI | IT_SHOTGUN | IT_LASER) && self.classname != "droppedweapon")
 363         {
 364                 self.target = "###item###"; // for finding the nearest item using find()
 365         }
 366         self.bot_pickup = TRUE;
 367         self.bot_pickupevalfunc = pickupevalfunc;
 368         self.bot_pickupbasevalue = pickupbasevalue;
 369         self.mdl = itemmodel;
 370         //self.noise = pickupsound;
 371         self.item_pickupsound = pickupsound;
 372         // let mappers override respawntime
 373         if (!self.respawntime)
 374                 self.respawntime = defaultrespawntime;
 375         self.netname = itemname;
 376         self.items = itemid;
 377         self.flags = FL_ITEM | itemflags;
 378         if(self.spawnflags & 1)
 379                 self.noalign = 1;
 380         if (self.noalign)
 381                 self.movetype = MOVETYPE_NONE;
 382         else
 383                 self.movetype = MOVETYPE_TOSS;
 384         self.solid = SOLID_TRIGGER;
 385         self.touch = Item_Touch;
 386         setmodel (self, self.mdl); // precision set below
 387         self.effects |= EF_LOWPRECISION;
 388         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 389                 setsize (self, '-16 -16 0', '16 16 48');
 390         else
 391                 setsize (self, '-16 -16 0', '16 16 32');
 392         if (itemflags & FL_WEAPON)
 393         {
 394                 // neutral team color for pickup weapons
 395                 self.colormap = 160 * 1024 + 160;
 396         }
 397
 398         // Savage: remove thrown items after a certain period of time ("garbage collection")
 399         if (self.classname == "droppedweapon")
 400         {
 401                 self.think = RemoveItem;
 402                 self.nextthink = time + 60;
 403         }
 404         else if (!self.noalign)
 405         {
 406                 // first nudge it off the floor a little bit to avoid math errors
 407                 setorigin(self, self.origin + '0 0 1');
 408                 // note droptofloor returns FALSE if stuck/or would fall too far
 409                 droptofloor();
 410         }
 411
 412         if (cvar("g_fullbrightitems"))
 413                 self.effects = self.effects | EF_FULLBRIGHT;
 414 }
 415
 416 /* replace items in minstagib
 417  * IT_STRENGTH   = invisibility
 418  * IT_NAILS      = extra lives
 419  * IT_INVINCIBLE = speed
 420  */
 421 void minstagib_items (float itemid)
 422 {
 423         // we don't want to replace dropped weapons ;)
 424         if (self.classname == "droppedweapon")
 425         {
 426                 self.ammo_cells = 25;
 427                 StartItem ("models/weapons/g_nex.md3",
 428                         "weapons/weaponpickup.wav", 15,
 429                         "Nex Gun", IT_NEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 430                 return;
 431         }
 432
 433         local float rnd;
 434         self.classname = "minstagib";
 435
 436         // replace rocket launchers and nex guns with ammo cells
 437         if (itemid == IT_CELLS)
 438         {
 439                 self.ammo_cells = 1;
 440                 StartItem ("models/items/a_cells.md3",
 441                         "misc/itempickup.wav", 45,
 442                         "Nex Ammo", IT_CELLS, 0, generic_pickupevalfunc, 100);
 443                 return;
 444         }
 445
 446         // randomize
 447         rnd = random() * 3;
 448         if (rnd <= 1)
 449                 itemid = IT_STRENGTH;
 450         else if (rnd <= 2)
 451                 itemid = IT_NAILS;
 452         else
 453                 itemid = IT_INVINCIBLE;
 454
 455         // replace with invis
 456         if (itemid == IT_STRENGTH)
 457         {
 458                 self.effects = EF_ADDITIVE;
 459                 self.strength_finished = 30;
 460                 StartItem ("models/items/g_strength.md3",
 461                         "misc/powerup.wav", 120,
 462                         "Invisibility", IT_STRENGTH, FL_POWERUP, generic_pickupevalfunc, 1000);
 463         }
 464         // replace with extra lives
 465         if (itemid == IT_NAILS)
 466         {
 467                 self.max_health = 1;
 468                 StartItem ("models/items/g_h100.md3",
 469                         "misc/megahealth.wav", 120,
 470                         "Extralife", IT_NAILS, FL_POWERUP, generic_pickupevalfunc, 1000);
 471
 472         }
 473         // replace with speed
 474         if (itemid == IT_INVINCIBLE)
 475         {
 476                 self.effects = EF_ADDITIVE;
 477                 self.invincible_finished = 30;
 478                 StartItem ("models/items/g_invincible.md3",
 479                         "misc/powerup_shield.wav", 120,
 480                         "Speed", IT_INVINCIBLE, FL_POWERUP, generic_pickupevalfunc, 1000);
 481         }
 482
 483 }
 484
 485 void weapon_uzi (void) {
 486         if(!self.ammo_nails)
 487                 self.ammo_nails = cvar("g_pickup_nails");
 488         StartItem ("models/weapons/g_uzi.md3", "weapons/weaponpickup.wav", 15, W_Name(WEP_UZI), IT_UZI, FL_WEAPON, weapon_pickupevalfunc, 1000);
 489         if (self.modelindex) // don't precache if self was removed
 490                 weapon_action(WEP_UZI, WR_PRECACHE);
 491 }
 492
 493 void weapon_shotgun (void) {
 494         if(!self.ammo_shells)
 495                 self.ammo_shells = cvar("g_pickup_shells");
 496         StartItem ("models/weapons/g_shotgun.md3", "weapons/weaponpickup.wav", 15, W_Name(WEP_SHOTGUN), IT_SHOTGUN, FL_WEAPON, weapon_pickupevalfunc, 1000);
 497         if (self.modelindex) // don't precache if self was removed
 498                 weapon_action(WEP_SHOTGUN, WR_PRECACHE);
 499 }
 500
 501 void weapon_grenadelauncher (void)
 502 {
 503         if(!self.ammo_rockets)
 504                 self.ammo_rockets = cvar("g_pickup_rockets");
 505         StartItem ("models/weapons/g_gl.md3", "weapons/weaponpickup.wav", 15, W_Name(WEP_GRENADE_LAUNCHER), IT_GRENADE_LAUNCHER, FL_WEAPON, weapon_pickupevalfunc, 1000);
 506         if (self.modelindex) // don't precache if self was removed
 507                 weapon_action(WEP_GRENADE_LAUNCHER, WR_PRECACHE);
 508 }
 509
 510 void weapon_electro (void)
 511 {
 512         if(!self.ammo_cells)
 513                 self.ammo_cells = cvar("g_pickup_cells");
 514         StartItem ("models/weapons/g_electro.md3", "weapons/weaponpickup.wav", 15, W_Name(WEP_ELECTRO), IT_ELECTRO, FL_WEAPON, weapon_pickupevalfunc, 1000);
 515         if (self.modelindex) // don't precache if self was removed
 516                 weapon_action(WEP_ELECTRO, WR_PRECACHE);
 517 }
 518
 519 void weapon_crylink (void)
 520 {
 521         if(!self.ammo_cells)
 522                 self.ammo_cells = cvar("g_pickup_cells");
 523         StartItem ("models/weapons/g_crylink.md3", "weapons/weaponpickup.wav", 15, W_Name(WEP_CRYLINK), IT_CRYLINK, FL_WEAPON, weapon_pickupevalfunc, 1000);
 524         if (self.modelindex) // don't precache if self was removed
 525                 weapon_action(WEP_CRYLINK, WR_PRECACHE);
 526 }
 527
 528 void weapon_nex (void)
 529 {
 530         float nextime;
 531         if (cvar("g_minstagib"))
 532         {
 533                 minstagib_items(IT_CELLS);
 534                 return;
 535         }
 536         if(!self.ammo_cells)
 537                 self.ammo_cells = cvar("g_pickup_cells");
 538         nextime = cvar("g_balance_nex_respawntime_modifier");
 539         if(nextime)
 540                 nextime = 15 * nextime;
 541         else
 542                 nextime = 15;
 543         StartItem ("models/weapons/g_nex.md3", "weapons/weaponpickup.wav", nextime, W_Name(WEP_NEX), IT_NEX, FL_WEAPON, weapon_pickupevalfunc, 1000);
 544         if (self.modelindex) // don't precache if self was removed
 545                 weapon_action(WEP_NEX, WR_PRECACHE);
 546 }
 547
 548 void weapon_hagar (void)
 549 {
 550         if(!self.ammo_rockets)
 551                 self.ammo_rockets = cvar("g_pickup_rockets");
 552         StartItem ("models/weapons/g_hagar.md3", "weapons/weaponpickup.wav", 15, W_Name(WEP_HAGAR), IT_HAGAR, FL_WEAPON, weapon_pickupevalfunc, 1000);
 553         if (self.modelindex) // don't precache if self was removed
 554                 weapon_action(WEP_HAGAR, WR_PRECACHE);
 555 }
 556
 557 void weapon_rocketlauncher (void)
 558 {
 559         if (cvar("g_minstagib"))
 560         {
 561                 minstagib_items(IT_CELLS);
 562                 return;
 563         }
 564         if(!self.ammo_rockets)
 565                 self.ammo_rockets = g_pickup_rockets;
 566         StartItem ("models/weapons/g_rl.md3", "weapons/weaponpickup.wav", 15, W_Name(WEP_ROCKET_LAUNCHER), IT_ROCKET_LAUNCHER, FL_WEAPON, weapon_pickupevalfunc, 1000);
 567         if (self.modelindex) // don't precache if self was removed
 568                 weapon_action(WEP_ROCKET_LAUNCHER, WR_PRECACHE);
 569 }
 570
 571 void item_rockets (void) {
 572         if(!self.ammo_rockets)
 573                 self.ammo_rockets = g_pickup_rockets;
 574         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", 15, "rockets", IT_ROCKETS, 0, commodity_pickupevalfunc, 100);
 575 }
 576
 577 void item_bullets (void) {
 578         if(!self.ammo_nails)
 579                 self.ammo_nails = g_pickup_nails;
 580         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", 15, "bullets", IT_NAILS, 0, commodity_pickupevalfunc, 100);
 581 }
 582
 583 void item_cells (void) {
 584         if(!self.ammo_cells)
 585                 self.ammo_cells = g_pickup_cells;
 586         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", 15, "cells", IT_CELLS, 0, commodity_pickupevalfunc, 100);
 587 }
 588
 589 void item_shells (void) {
 590         if(!self.ammo_shells)
 591                 self.ammo_shells = g_pickup_shells;
 592         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", 15, "shells", IT_SHELLS, 0, commodity_pickupevalfunc, 100);
 593 }
 594
 595 void item_armor1 (void) {
 596         if(!self.armorvalue)
 597                 self.armorvalue = g_pickup_armorshard;
 598         if(!self.max_armorvalue)
 599                 self.max_armorvalue = g_pickup_armorshard_max;
 600         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", 15, "Armor Shard", IT_ARMOR_SHARD, 0, commodity_pickupevalfunc, 100);
 601 }
 602
 603 void item_armor25 (void) {
 604         if(!self.armorvalue)
 605                 self.armorvalue = g_pickup_armor;
 606         if(!self.max_armorvalue)
 607                 self.max_armorvalue = g_pickup_armor_max;
 608         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", 30, "Armor", IT_ARMOR, 0, commodity_pickupevalfunc, 2000);
 609 }
 610
 611 void item_health1 (void) {
 612         if(!self.max_health)
 613                 self.max_health = g_pickup_healthshard_max;
 614         if(!self.health)
 615                 self.health = g_pickup_healthshard;
 616         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", 15, "5 Health", IT_5HP, 0, commodity_pickupevalfunc, 100);
 617 }
 618
 619 void item_health25 (void) {
 620         if(!self.max_health)
 621                 self.max_health = g_pickup_health_max;
 622         if(!self.health)
 623                 self.health = g_pickup_health;
 624         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", 15, "25 Health", IT_25HP, 0, commodity_pickupevalfunc, 500);
 625 }
 626
 627 void item_health100 (void) {
 628         if(!cvar("g_powerup_superhealth"))
 629                 return;
 630
 631         if(cvar("g_arena") && !cvar("g_arena_powerups"))
 632                 return;
 633
 634         if(cvar("g_minstagib")) {
 635                 minstagib_items(IT_NAILS);
 636         } else {
 637                 if(!self.max_health)
 638                         self.max_health = g_pickup_healthmega_max;
 639                 if(!self.health)
 640                         self.health = g_pickup_healthmega;
 641                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", 30, "100 Health", IT_HEALTH, 0, commodity_pickupevalfunc, 2000);
 642         }
 643 }
 644
 645 void item_strength (void) {
 646         if(!cvar("g_powerup_strength"))
 647                 return;
 648
 649         if(cvar("g_arena") && !cvar("g_arena_powerups"))
 650                 return;
 651
 652         if(cvar("g_minstagib")) {
 653                 minstagib_items(IT_STRENGTH);
 654         } else {
 655                 precache_sound("weapons/strength_fire.wav");
 656                 self.strength_finished = 30;
 657                 self.effects = EF_ADDITIVE;StartItem ("models/items/g_strength.md3", "misc/powerup.wav", 120, "Strength Powerup", IT_STRENGTH, FL_POWERUP, generic_pickupevalfunc, 10000);
 658         }
 659 }
 660
 661 void item_invincible (void) {
 662         if(!cvar("g_powerup_shield"))
 663                 return;
 664
 665         if(cvar("g_arena") && !cvar("g_arena_powerups"))
 666                 return;
 667
 668         if(cvar("g_minstagib")) {
 669                 minstagib_items(IT_INVINCIBLE);
 670         } else {
 671                 self.invincible_finished = 30;
 672                 self.effects = EF_ADDITIVE;
 673                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", 120, "Invulnerability", IT_INVINCIBLE, FL_POWERUP, generic_pickupevalfunc, 10000);
 674         }
 675 }
 676 //void item_speed (void) {self.speed_finished = 30;StartItem ("models/items/g_speed.md3", "misc/powerup.wav", 120, "Speed Powerup", IT_SPEED, FL_POWERUP, generic_pickupevalfunc, 10000);}
 677 //void item_slowmo (void) {self.slowmo_finished = 30;StartItem ("models/items/g_slowmo.md3", "misc/powerup.wav", 120, "Slow Motion", IT_SLOWMO, FL_POWERUP, generic_pickupevalfunc, 10000);}
 678
 679 // compatibility:
 680 void item_quad (void) {self.classname = "item_strength";item_strength();}
 681
 682 void misc_models (void)
 683 {
 684         precache_model (self.model);
 685         setmodel (self, self.model); // precision set by mapper
 686         setsize (self, self.mins, self.maxs);
 687 }
 688
 689
 690
 691
 692
 693 floatfield Item_CounterField(float it)
 694 {
 695         switch(it)
 696         {
 697                 case IT_SHELLS:      return ammo_shells;
 698                 case IT_NAILS:       return ammo_nails;
 699                 case IT_ROCKETS:     return ammo_rockets;
 700                 case IT_CELLS:       return ammo_cells;
 701                 case IT_5HP:         return health;
 702                 case IT_25HP:        return health;
 703                 case IT_HEALTH:      return health;
 704                 case IT_ARMOR_SHARD: return armorvalue;
 705                 case IT_ARMOR:       return armorvalue;
 706                 // add more things here (health, armor)
 707                 default:             error("requested item has no counter field");
 708         }
 709 }
 710
 711 float Item_WeaponCode(float it)
 712 {
 713         switch(it)
 714         {
 715                 case IT_LASER:            return WEP_LASER;
 716                 case IT_SHOTGUN:          return WEP_SHOTGUN;
 717                 case IT_UZI:              return WEP_UZI;
 718                 case IT_GRENADE_LAUNCHER: return WEP_GRENADE_LAUNCHER;
 719                 case IT_ELECTRO:          return WEP_ELECTRO;
 720                 case IT_CRYLINK:          return WEP_CRYLINK;
 721                 case IT_NEX:              return WEP_NEX;
 722                 case IT_HAGAR:            return WEP_HAGAR;
 723                 case IT_ROCKET_LAUNCHER:  return WEP_ROCKET_LAUNCHER;
 724                 default:                  return 0;
 725         }
 726 }
 727
 728 void Item_SpawnByItemCode(float it)
 729 {
 730         switch(it)
 731         {
 732                 case IT_SHOTGUN:          weapon_shotgun(); break;
 733                 case IT_UZI:              weapon_uzi(); break;
 734                 case IT_GRENADE_LAUNCHER: weapon_grenadelauncher(); break;
 735                 case IT_ELECTRO:          weapon_electro(); break;
 736                 case IT_CRYLINK:          weapon_crylink(); break;
 737                 case IT_NEX:              weapon_nex(); break;
 738                 case IT_HAGAR:            weapon_hagar(); break;
 739                 case IT_ROCKET_LAUNCHER:  weapon_rocketlauncher(); break;
 740                 // add all other item spawn functions here
 741                 default:
 742                         error("requested item can't be spawned");
 743         }
 744 }