data/qcsrc/server/t_items.qc

   1 //void Item_ClearRespawnEffect (void) {
   2 //      self.effects = self.effects - (self.effects & EF_STARDUST);
   3 //}
   4
   5 void Item_Respawn (void)
   6 {
   7         self.model = self.mdl;          // restore original model
   8         self.solid = SOLID_TRIGGER;     // allow it to be touched again
   9         sound (self, CHAN_VOICE, "misc/itemrespawn.ogg", 1, ATTN_NORM); // play respawn sound
  10         setorigin (self, self.origin);
  11
  12         // LordHavoc: replaced respawn stardust effect with a custom te_wizspike
  13         te_wizspike(self.origin + self.mins_z * '0 0 1' + '0 0 48');
  14         //// Savage: Add simple Respawn effect and make sure it gets removed
  15         //self.effects = self.effects | EF_STARDUST;
  16         //self.think = Item_ClearRespawnEffect;
  17         //self.nextthink = time + 0.1;
  18 }
  19
  20 void Item_Touch (void)
  21 {
  22         local entity oldself;
  23         local float _switchweapon;
  24
  25         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
  26         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
  27         {
  28                 remove(self);
  29                 return;
  30         }
  31         if (other.classname != "player")
  32                 return;
  33         if (other.deadflag)
  34                 return;
  35         if (self.solid != SOLID_TRIGGER)
  36                 return;
  37         if (self.health && other.health >= other.max_health)
  38                 return;
  39         if (self.owner == other)
  40                 return;
  41         // Savage: Remove the respawn effect if still present
  42         self.effects = self.effects - (self.effects & EF_STARDUST);
  43
  44         sound (self, CHAN_BODY, self.noise, 1, ATTN_NORM);
  45
  46         // in case the player has autoswitch enabled do the following:
  47         // if the player is using their best weapon before items are given, they
  48         // probably want to switch to an even better weapon after items are given
  49         _switchweapon = (other.autoswitch && (other.switchweapon == w_getbestweapon(other)) || cvar("g_minstagib"));
  50
  51         if (cvar("g_minstagib"))
  52         {
  53                 if (self.ammo_cells)
  54                 {
  55                         // play some cool sounds ;)
  56                         centerprint(other, "\n");
  57                         if(other.health <= 5)
  58                                 stuffcmd(other, "play2 announcer/robotic/lastsecond.ogg\n");
  59                         else if(other.health < 50)
  60                                 stuffcmd(other, "play2 announcer/robotic/narrowly.ogg\n");
  61                         // sound not available
  62                         // else if(self.items == IT_CELLS)
  63                         //      stuffcmd(other, "play2 announce/robotic/ammo.ogg\n");
  64
  65                         if (self.items & IT_NEX)
  66                                 W_GiveWeapon (other, IT_NEX, "Nex");
  67                         if (self.ammo_cells)
  68                                 other.ammo_cells = min (other.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
  69                         other.health = 100;
  70                 }
  71
  72                 // extralife powerup
  73                 if (self.max_health)
  74                 {
  75                         // sound not available
  76                         // stuffcmd(other, "play2 announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.ogg\n");
  77                         other.armorvalue = other.armorvalue + cvar("g_minstagib_extralives");
  78                         sprint(other, "^3You picked up some extra lives\n");
  79                 }
  80
  81                 // invis powerup
  82                 if (self.strength_finished)
  83                 {
  84                         // sound not available
  85                         // stuffcmd(other, "play2 announce/robotic/invisible.ogg\n");
  86                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
  87                 }
  88
  89                 // speed powerup
  90                 if (self.invincible_finished)
  91                 {
  92                         // sound not available
  93                         // stuffcmd(other, "play2 announce/robotic/speed.ogg\n");
  94                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
  95                 }
  96         }
  97         else
  98         {
  99                 if (cvar("deathmatch") == 2 || cvar("g_weapon_stay"))
 100                 {
 101                         if (self.flags & FL_WEAPON && other.items & self.items && self.classname != "droppedweapon")
 102                                 return;
 103                         if (other.items & self.items && self.flags & FL_TOSSED) // don't let players stack ammo by tossing weapons
 104                                 return;
 105                 }
 106
 107                 if (self.ammo_shells)
 108                         other.ammo_shells = min (other.ammo_shells + self.ammo_shells, 999);
 109                 if (self.ammo_nails)
 110                         other.ammo_nails = min (other.ammo_nails + self.ammo_nails, 999);
 111                 if (self.ammo_rockets)
 112                         other.ammo_rockets = min (other.ammo_rockets + self.ammo_rockets, 999);
 113                 if (self.ammo_cells)
 114                         other.ammo_cells = min (other.ammo_cells + self.ammo_cells, 999);
 115
 116                 if (self.items & IT_UZI)                W_GiveWeapon (other, IT_UZI, self.netname);
 117                 if (self.items & IT_SHOTGUN)            W_GiveWeapon (other, IT_SHOTGUN, self.netname);
 118                 if (self.items & IT_GRENADE_LAUNCHER)   W_GiveWeapon (other, IT_GRENADE_LAUNCHER, self.netname);
 119                 if (self.items & IT_ELECTRO)            W_GiveWeapon (other, IT_ELECTRO, self.netname);
 120                 if (self.items & IT_NEX)                W_GiveWeapon (other, IT_NEX, self.netname);
 121                 if (self.items & IT_HAGAR)              W_GiveWeapon (other, IT_HAGAR, self.netname);
 122                 if (self.items & IT_ROCKET_LAUNCHER)    W_GiveWeapon (other, IT_ROCKET_LAUNCHER, self.netname);
 123                 if (self.items & IT_CRYLINK)            W_GiveWeapon (other, IT_CRYLINK, self.netname);
 124
 125                 if (self.strength_finished)
 126                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 127                 if (self.invincible_finished)
 128                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 129                 //if (self.speed_finished)
 130                 //      other.speed_finished = max(other.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 131                 //if (self.slowmo_finished)
 132                 //      other.slowmo_finished = max(other.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 133
 134                 if (self.max_health)
 135                 {
 136                         other.health = other.health + self.max_health;
 137                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 138                 }
 139                 if (self.health && other.health < other.max_health)
 140                         other.health = min(other.health + self.health, other.max_health);
 141                 if (self.armorvalue)
 142                 {
 143                         other.armorvalue = other.armorvalue + self.armorvalue;
 144                         other.pauserotarmor_finished = max(other.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 145                 }
 146         }
 147
 148         sound (other, CHAN_AUTO, self.item_pickupsound, 1, ATTN_NORM);
 149
 150         oldself = self;
 151         self = other;
 152
 153         if (_switchweapon)
 154                 self.switchweapon = w_getbestweapon(self);
 155         if (self.switchweapon != self.weapon)
 156                 self.cnt = self.weapon;
 157
 158         self = oldself;
 159
 160         if (self.classname == "droppedweapon")
 161                 remove (self);
 162         else if(self.flags & FL_WEAPON && (cvar("deathmatch") == 2 || cvar("g_weapon_stay")))
 163                 return;
 164         else
 165         {
 166                 self.solid = SOLID_NOT;
 167                 self.model = string_null;
 168                 self.nextthink = time + self.respawntime;
 169                 self.think = Item_Respawn;
 170                 setorigin (self, self.origin);
 171         }
 172 }
 173
 174 // Savage: used for item garbage-collection
 175 // TODO: perhaps nice special effect?
 176 void RemoveItem(void) = {
 177         remove(self);
 178 }
 179
 180 // pickup evaluation functions
 181 // these functions decide how desirable an item is to the bots
 182
 183 float(entity player, entity item) generic_pickupevalfunc = {return item.bot_pickupbasevalue;};
 184
 185 float(entity player, entity item) weapon_pickupevalfunc =
 186 {
 187         // if we already have the weapon, rate it 1/5th normal value
 188         if ((player.items & item.items) == item.items)
 189                 return item.bot_pickupbasevalue * 0.2;
 190         return item.bot_pickupbasevalue;
 191 };
 192
 193 float(entity player, entity item) commodity_pickupevalfunc =
 194 {
 195         float c;
 196         c = 0;
 197         // TODO: figure out if the player even has the weapon this ammo is for?
 198         // may not affect strategy much though...
 199         // find out how much ammo the player has, in terms of this ammo pickup
 200         // (how many of these ammo pickups it would take to total the player's
 201         // current ammo)
 202         if (item.ammo_shells)
 203                 c = c + player.ammo_shells / item.ammo_shells;
 204         if (item.ammo_nails)
 205                 c = c + player.ammo_nails / item.ammo_nails;
 206         if (item.ammo_rockets)
 207                 c = c + player.ammo_rockets / item.ammo_rockets;
 208         if (item.ammo_cells)
 209                 c = c + player.ammo_cells / item.ammo_cells;
 210         if (item.armorvalue)
 211                 c = c + player.armorvalue / item.armorvalue;
 212         if (item.health)
 213                 c = c + player.health / item.health / 10;
 214         // the more ammo the player has, the less desirable this pickup becomes
 215         c = 1 / (1 + c);
 216
 217         if (cvar("deathmatch") == 2) // weapon stay is on, so weapons the player already has are of no interest
 218         if (item.flags & FL_WEAPON)
 219         if (self.items & item.items)
 220         if (item.classname != "droppedweapon")
 221                 c = 0;
 222
 223         return item.bot_pickupbasevalue * c;
 224 };
 225
 226
 227 .float is_item;
 228 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, string itemname, float itemid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 229 {
 230         vector org;
 231         org = self.origin;
 232
 233         startitem_failed = FALSE;
 234
 235         if (self.classname != "droppedweapon" && !self.noalign)
 236         {
 237                 vector z_offset;
 238
 239                 z_offset = '0 0 1';
 240
 241                 if (itemid == IT_SHELLS)
 242                         z_offset = '0 0 4';
 243                 else if (itemid == IT_ROCKETS)
 244                         z_offset = '0 0 4';
 245                 else if (itemid == IT_NAILS)
 246                         z_offset = '0 0 0';
 247                 else if (itemid == IT_25HP)
 248                         z_offset = '0 0 5';
 249                 else if (itemid == IT_ARMOR)
 250                         z_offset = '0 0 3';
 251                 else if (itemid == IT_SHOTGUN)
 252                         z_offset = '0 0 10';
 253
 254                 org = find_floor(org) + z_offset;
 255                 setorigin(self, org);
 256         }
 257
 258         if(cvar("spawn_debug") >= 2)
 259         {
 260                 if(self.classname != "droppedweapon")
 261                 {
 262                         entity otheritem;
 263                         for(otheritem = findradius(org, 3); otheritem; otheritem = otheritem.chain)
 264                         {
 265                                 if(otheritem.is_item)
 266                                 {
 267                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 268                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 269                                         error("Mapper sucks.");
 270                                 }
 271                         }
 272                         self.is_item = TRUE;
 273                 }
 274         }
 275
 276         if (self.classname != "droppedweapon")
 277                 waypoint_spawnforitem(self);
 278
 279         if (!(cvar("g_pickup_items") && !cvar("g_nixnex")) && !cvar("g_minstagib") &&
 280                         itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 281         {
 282                 startitem_failed = TRUE;
 283                 remove (self);
 284                 return;
 285         }
 286
 287         if (cvar("g_minstagib"))
 288         {
 289                 // don't remove dropped items and powerups
 290                 if (self.classname != "droppedweapon" &&
 291                     self.classname != "minstagib")
 292                 {
 293                         startitem_failed = TRUE;
 294                         remove (self);
 295                         return;
 296                 }
 297         }
 298
 299         if(cvar("g_lms") && (self.classname != "droppedweapon"))
 300         {
 301                 startitem_failed = TRUE;
 302                 remove(self);
 303                 return;
 304         }
 305
 306         if(cvar("g_instagib") || cvar("g_rocketarena"))
 307         {
 308                 startitem_failed = TRUE;
 309                 remove(self);
 310                 return;
 311         }
 312
 313         if (self.classname == "droppedweapon")
 314         {
 315                 // don't drop if in a NODROP zone (such as lava)
 316                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 317                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 318                 {
 319                         startitem_failed = TRUE;
 320                         remove(self);
 321                         return;
 322                 }
 323         }
 324
 325         if(itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2 |
 326                                 IT_ROCKET_LAUNCHER | IT_HAGAR | IT_NEX | IT_CRYLINK | IT_ELECTRO |
 327                                 IT_GRENADE_LAUNCHER | IT_UZI | IT_SHOTGUN | IT_LASER) && self.classname != "droppedweapon")
 328         {
 329                 self.target = "###item###"; // for finding the nearest item using find()
 330         }
 331         self.bot_pickup = TRUE;
 332         self.bot_pickupevalfunc = pickupevalfunc;
 333         self.bot_pickupbasevalue = pickupbasevalue;
 334         self.mdl = itemmodel;
 335         //self.noise = pickupsound;
 336         self.item_pickupsound = pickupsound;
 337         // let mappers override respawntime
 338         if (!self.respawntime)
 339                 self.respawntime = defaultrespawntime;
 340         self.netname = itemname;
 341         self.items = itemid;
 342         self.flags = FL_ITEM | itemflags;
 343         setmodel (self, self.mdl);
 344         if (itemflags & FL_WEAPON)
 345         {
 346                 setorigin (self, self.origin + '0 0 23');
 347                 setsize (self, '-12 -12 -12', '12 12 12');
 348
 349                 // neutral team color for pickup weapons
 350                 self.colormap = 160 * 1024 + 160;
 351         }
 352         else
 353         {
 354                 setorigin (self, self.origin + '0 0 25');
 355         //      setsize (self, '-8 -8 -5', '8 8 8');
 356         }
 357         self.movetype = MOVETYPE_TOSS;
 358         self.solid = SOLID_TRIGGER;
 359         self.touch = Item_Touch;
 360
 361         // Savage: remove thrown items after a certain period of time ("garbage collection")
 362         if (self.classname == "droppedweapon")
 363         {
 364                 self.think = RemoveItem;
 365                 self.nextthink = time + 60;
 366         }
 367         else
 368         {
 369                 self.movetype = MOVETYPE_NONE;
 370                 setorigin(self, org);
 371         }
 372
 373         if (cvar("g_fullbrightitems"))
 374                 self.effects = self.effects | EF_FULLBRIGHT;
 375 }
 376
 377 /* replace items in minstagib
 378  * IT_STRENGTH   = invisibility
 379  * IT_NAILS      = extra lives
 380  * IT_INVINCIBLE = speed
 381  */
 382 void minstagib_items (float itemid)
 383 {
 384         // we don't want to replace dropped weapons ;)
 385         if (self.classname == "droppedweapon")
 386         {
 387                 self.ammo_cells = 25;
 388                 StartItem ("models/weapons/g_nex.md3",
 389                         "weapons/weaponpickup.ogg", 15,
 390                         "Nex Gun", IT_NEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 391                 return;
 392         }
 393
 394         local float rnd;
 395         self.classname = "minstagib";
 396
 397         // replace rocket launchers and nex guns with ammo cells
 398         if (itemid == IT_CELLS)
 399         {
 400                 self.ammo_cells = 1;
 401                 StartItem ("models/items/a_cells.md3",
 402                         "misc/itempickup.ogg", 45,
 403                         "Nex Ammo", IT_CELLS, 0, generic_pickupevalfunc, 100);
 404                 return;
 405         }
 406
 407         // randomize
 408         rnd = random() * 3;
 409         if (rnd <= 1)
 410                 itemid = IT_STRENGTH;
 411         else if (rnd <= 2)
 412                 itemid = IT_NAILS;
 413         else
 414                 itemid = IT_INVINCIBLE;
 415
 416         // replace with invis
 417         if (itemid == IT_STRENGTH)
 418         {
 419                 self.effects = EF_ADDITIVE;
 420                 self.strength_finished = 30;
 421                 StartItem ("models/items/g_strength.md3",
 422                         "misc/powerup.ogg", 120,
 423                         "Invisibility", IT_STRENGTH, FL_POWERUP, generic_pickupevalfunc, 1000);
 424         }
 425         // replace with extra lives
 426         if (itemid == IT_NAILS)
 427         {
 428                 self.max_health = 1;
 429                 StartItem ("models/items/g_h100.md3",
 430                         "misc/megahealth.ogg", 120,
 431                         "Extralife", IT_NAILS, FL_POWERUP, generic_pickupevalfunc, 1000);
 432
 433         }
 434         // replace with speed
 435         if (itemid == IT_INVINCIBLE)
 436         {
 437                 self.effects = EF_ADDITIVE;
 438                 self.invincible_finished = 30;
 439                 StartItem ("models/items/g_invincible.md3",
 440                         "misc/powerup_shield.ogg", 120,
 441                         "Speed", IT_INVINCIBLE, FL_POWERUP, generic_pickupevalfunc, 1000);
 442         }
 443
 444 }
 445
 446 void weapon_uzi (void) {
 447         if(!self.ammo_nails)
 448                 self.ammo_nails = 120;
 449         StartItem ("models/weapons/g_uzi.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_UZI), IT_UZI, FL_WEAPON, weapon_pickupevalfunc, 1000);
 450 }
 451
 452 void weapon_shotgun (void) {
 453         if(!self.ammo_shells)
 454                 self.ammo_shells = 15;
 455         StartItem ("models/weapons/g_shotgun.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_SHOTGUN), IT_SHOTGUN, FL_WEAPON, weapon_pickupevalfunc, 1000);
 456 }
 457
 458 void weapon_grenadelauncher (void) {
 459         if(!self.ammo_rockets)
 460                 self.ammo_rockets = 15;
 461         StartItem ("models/weapons/g_gl.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_GRENADE_LAUNCHER), IT_GRENADE_LAUNCHER, FL_WEAPON, weapon_pickupevalfunc, 1000);
 462 }
 463
 464 void weapon_electro (void) {
 465         if(!self.ammo_cells)
 466                 self.ammo_cells = 25;
 467         StartItem ("models/weapons/g_electro.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_ELECTRO), IT_ELECTRO, FL_WEAPON, weapon_pickupevalfunc, 1000);
 468 }
 469
 470 void weapon_crylink (void) {
 471         if(!self.ammo_cells)
 472                 self.ammo_cells = 25;
 473         StartItem ("models/weapons/g_crylink.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_CRYLINK), IT_CRYLINK, FL_WEAPON, weapon_pickupevalfunc, 1000);
 474 }
 475
 476 void weapon_nex (void) {
 477         if (cvar("g_minstagib")) {
 478                 minstagib_items(IT_CELLS);
 479         } else {
 480                 float nextime;
 481                 if(!self.ammo_cells)
 482                         self.ammo_cells = 25;
 483                 nextime = cvar("g_balance_nex_respawntime_modifier");
 484                 if(nextime)
 485                         nextime = 15 * nextime;
 486                 else
 487                         nextime = 15;
 488                 StartItem ("models/weapons/g_nex.md3", "weapons/weaponpickup.ogg", nextime, W_Name(WEP_NEX), IT_NEX, FL_WEAPON, weapon_pickupevalfunc, 1000);
 489         }
 490 }
 491
 492 void weapon_hagar (void) {
 493         if(!self.ammo_rockets)
 494                 self.ammo_rockets = 15;
 495         StartItem ("models/weapons/g_hagar.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_HAGAR), IT_HAGAR, FL_WEAPON, weapon_pickupevalfunc, 1000);
 496 }
 497
 498 void weapon_rocketlauncher (void) {
 499         if (cvar("g_minstagib")) {
 500                 minstagib_items(IT_CELLS);
 501         } else {
 502                 if(!self.ammo_rockets)
 503                         self.ammo_rockets = 15;
 504                 StartItem ("models/weapons/g_rl.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_ROCKET_LAUNCHER), IT_ROCKET_LAUNCHER, FL_WEAPON, weapon_pickupevalfunc, 1000);
 505         }
 506 }
 507
 508 void item_rockets (void) {
 509         if(!self.ammo_rockets)
 510                 self.ammo_rockets = 15;
 511         StartItem ("models/items/a_rockets.md3", "misc/itempickup.ogg", 15, "rockets", IT_ROCKETS, 0, commodity_pickupevalfunc, 100);
 512 }
 513
 514 void item_bullets (void) {
 515         if(!self.ammo_nails)
 516                 self.ammo_nails = 120;
 517         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.ogg", 15, "bullets", IT_NAILS, 0, commodity_pickupevalfunc, 100);
 518 }
 519
 520 void item_cells (void) {
 521         if(!self.ammo_cells)
 522                 self.ammo_cells = 25;
 523         StartItem ("models/items/a_cells.md3", "misc/itempickup.ogg", 15, "cells", IT_CELLS, 0, commodity_pickupevalfunc, 100);
 524 }
 525
 526 void item_shells (void) {
 527         if(!self.ammo_shells)
 528                 self.ammo_shells = 15;
 529         StartItem ("models/items/a_shells.md3", "misc/itempickup.ogg", 15, "shells", IT_SHELLS, 0, commodity_pickupevalfunc, 100);
 530 }
 531
 532 void item_armor1 (void) {
 533         if(!self.armorvalue)
 534                 self.armorvalue = 5;
 535         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", 15, "Armor Shard", IT_ARMOR_SHARD, 0, commodity_pickupevalfunc, 100);
 536 }
 537
 538 void item_armor25 (void) {
 539         if(!self.armorvalue)
 540                 self.armorvalue = 100;
 541         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", 30, "Armor", IT_ARMOR, 0, commodity_pickupevalfunc, 2000);
 542 }
 543
 544 void item_health1 (void) {
 545         if(!self.max_health)
 546                 self.max_health = 5;
 547         StartItem ("models/items/g_h1.md3", "misc/minihealth.ogg", 15, "5 Health", IT_5HP, 0, commodity_pickupevalfunc, 100);
 548 }
 549
 550 void item_health25 (void) {
 551         if(!self.max_health)
 552                 self.max_health = 25;
 553         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.ogg", 15, "25 Health", IT_25HP, 0, commodity_pickupevalfunc, 500);
 554 }
 555
 556 void item_health100 (void) {
 557         if(!cvar("g_powerup_superhealth"))
 558                 return;
 559
 560         if(cvar("g_arena") && !cvar("g_arena_powerups"))
 561                 return;
 562
 563         if(cvar("g_minstagib")) {
 564                 minstagib_items(IT_NAILS);
 565         } else {
 566                 if(!self.max_health)
 567                         self.max_health = 100;
 568                 StartItem ("models/items/g_h100.md3", "misc/megahealth.ogg", 30, "100 Health", IT_HEALTH, 0, commodity_pickupevalfunc, 2000);
 569         }
 570 }
 571
 572 void item_strength (void) {
 573         if(!cvar("g_powerup_strength"))
 574                 return;
 575
 576         if(cvar("g_arena") && !cvar("g_arena_powerups"))
 577                 return;
 578
 579         if(cvar("g_minstagib")) {
 580                 minstagib_items(IT_STRENGTH);
 581         } else {
 582                 self.strength_finished = 30;
 583                 self.effects = EF_ADDITIVE;StartItem ("models/items/g_strength.md3", "misc/powerup.ogg", 120, "Strength Powerup", IT_STRENGTH, FL_POWERUP, generic_pickupevalfunc, 10000);
 584         }
 585 }
 586
 587 void item_invincible (void) {
 588         if(!cvar("g_powerup_shield"))
 589                 return;
 590
 591         if(cvar("g_arena") && !cvar("g_arena_powerups"))
 592                 return;
 593
 594         if(cvar("g_minstagib")) {
 595                 minstagib_items(IT_INVINCIBLE);
 596         } else {
 597                 self.invincible_finished = 30;
 598                 self.effects = EF_ADDITIVE;
 599                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.ogg", 120, "Invulnerability", IT_INVINCIBLE, FL_POWERUP, generic_pickupevalfunc, 10000);
 600         }
 601 }
 602 //void item_speed (void) {self.speed_finished = 30;StartItem ("models/items/g_speed.md3", "misc/powerup.wav", 120, "Speed Powerup", IT_SPEED, FL_POWERUP, generic_pickupevalfunc, 10000);}
 603 //void item_slowmo (void) {self.slowmo_finished = 30;StartItem ("models/items/g_slowmo.md3", "misc/powerup.wav", 120, "Slow Motion", IT_SLOWMO, FL_POWERUP, generic_pickupevalfunc, 10000);}
 604
 605 // compatibility:
 606 void item_quad (void) {self.classname = "item_strength";item_strength();}
 607
 608 void misc_models (void)
 609 {
 610         precache_model (self.model);
 611         setmodel (self, self.model);
 612         setsize (self, self.mins, self.maxs);
 613 }
 614
 615
 616
 617
 618
 619 floatfield Item_CounterField(float it)
 620 {
 621         switch(it)
 622         {
 623                 case IT_SHELLS:      return ammo_shells;
 624                 case IT_NAILS:       return ammo_nails;
 625                 case IT_ROCKETS:     return ammo_rockets;
 626                 case IT_CELLS:       return ammo_cells;
 627                 case IT_5HP:         return health;
 628                 case IT_25HP:        return health;
 629                 case IT_HEALTH:      return health;
 630                 case IT_ARMOR_SHARD: return armorvalue;
 631                 case IT_ARMOR:       return armorvalue;
 632                 // add more things here (health, armor)
 633                 default:             error("requested item has no counter field");
 634         }
 635 }
 636
 637 float Item_WeaponCode(float it)
 638 {
 639         switch(it)
 640         {
 641                 case IT_LASER:            return WEP_LASER;
 642                 case IT_SHOTGUN:          return WEP_SHOTGUN;
 643                 case IT_UZI:              return WEP_UZI;
 644                 case IT_GRENADE_LAUNCHER: return WEP_GRENADE_LAUNCHER;
 645                 case IT_ELECTRO:          return WEP_ELECTRO;
 646                 case IT_CRYLINK:          return WEP_CRYLINK;
 647                 case IT_NEX:              return WEP_NEX;
 648                 case IT_HAGAR:            return WEP_HAGAR;
 649                 case IT_ROCKET_LAUNCHER:  return WEP_ROCKET_LAUNCHER;
 650                 default:                  return 0;
 651         }
 652 }
 653
 654 spawnfunc Item_SpawnFunc(float it)
 655 {
 656         switch(it)
 657         {
 658                 case IT_SHOTGUN:          return weapon_shotgun;
 659                 case IT_UZI:              return weapon_uzi;
 660                 case IT_GRENADE_LAUNCHER: return weapon_grenadelauncher;
 661                 case IT_ELECTRO:          return weapon_electro;
 662                 case IT_CRYLINK:          return weapon_crylink;
 663                 case IT_NEX:              return weapon_nex;
 664                 case IT_HAGAR:            return weapon_hagar;
 665                 case IT_ROCKET_LAUNCHER:  return weapon_rocketlauncher;
 666                 // add all other item spawn functions here
 667                 default:                  error("requested item can't be spawned");
 668         }
 669 }