data/qcsrc/server/t_items.qc

   1 floatfield Item_CounterField(float it)
   2 {
   3         switch(it)
   4         {
   5                 case IT_SHELLS:      return ammo_shells;
   6                 case IT_NAILS:       return ammo_nails;
   7                 case IT_ROCKETS:     return ammo_rockets;
   8                 case IT_CELLS:       return ammo_cells;
   9                 case IT_5HP:         return health;
  10                 case IT_25HP:        return health;
  11                 case IT_HEALTH:      return health;
  12                 case IT_ARMOR_SHARD: return armorvalue;
  13                 case IT_ARMOR:       return armorvalue;
  14                 // add more things here (health, armor)
  15                 default:             error("requested item has no counter field");
  16         }
  17 }
  18
  19 string Item_CounterFieldName(float it)
  20 {
  21         switch(it)
  22         {
  23                 case IT_SHELLS:      return "shells";
  24                 case IT_NAILS:       return "nails";
  25                 case IT_ROCKETS:     return "rockets";
  26                 case IT_CELLS:       return "cells";
  27
  28                 // add more things here (health, armor)
  29                 default:             error("requested item has no counter field name");
  30         }
  31 }
  32
  33 .float max_armorvalue;
  34
  35 void Item_Respawn (void)
  36 {
  37         self.model = self.mdl;          // restore original model
  38         self.solid = SOLID_TRIGGER;     // allow it to be touched again
  39         sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);        // play respawn sound
  40         setorigin (self, self.origin);
  41
  42         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
  43         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
  44 }
  45
  46 float Item_GiveTo(entity item, entity player)
  47 {
  48         float _switchweapon;
  49         float pickedup;
  50         float it;
  51         float i;
  52         entity e;
  53
  54         // if nothing happens to player, just return without taking the item
  55         pickedup = FALSE;
  56         _switchweapon = FALSE;
  57
  58         if (g_minstagib)
  59         {
  60                 _switchweapon = TRUE;
  61                 if (item.ammo_cells)
  62                 {
  63                         pickedup = TRUE;
  64                         // play some cool sounds ;)
  65                         centerprint(player, "\n");
  66                         if(player.health <= 5)
  67                                 announce(player, "announcer/robotic/lastsecond.ogg");
  68                         else if(player.health < 50)
  69                                 announce(player, "announcer/robotic/narrowly.ogg");
  70                         // sound not available
  71                         // else if(item.items == IT_CELLS)
  72                         //      play2(player, "announce/robotic/ammo.ogg");
  73
  74                         if (item.weapons & WEPBIT_MINSTANEX)
  75                                 W_GiveWeapon (player, WEP_MINSTANEX, "Nex");
  76                         if (item.ammo_cells)
  77                                 player.ammo_cells = min (player.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
  78                         player.health = 100;
  79                 }
  80
  81                 // extralife powerup
  82                 if (item.max_health)
  83                 {
  84                         pickedup = TRUE;
  85                         // sound not available
  86                         // play2(player, "announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.ogg");
  87                         player.armorvalue = player.armorvalue + cvar("g_minstagib_extralives");
  88                         sprint(player, "^3You picked up some extra lives\n");
  89                 }
  90
  91                 // invis powerup
  92                 if (item.strength_finished)
  93                 {
  94                         pickedup = TRUE;
  95                         // sound not available
  96                         // play2(player, "announce/robotic/invisible.ogg");
  97                         player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
  98                 }
  99
 100                 // speed powerup
 101                 if (item.invincible_finished)
 102                 {
 103                         pickedup = TRUE;
 104                         // sound not available
 105                         // play2(player, "announce/robotic/speed.ogg");
 106                         player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
 107                 }
 108         }
 109         else
 110         {
 111                 if (cvar("deathmatch") == 2 || cvar("g_weapon_stay"))
 112                 {
 113                         if (item.flags & FL_WEAPON && player.weapons & item.weapons && item.classname != "droppedweapon")
 114                                 return 0;
 115                         if (player.weapons & item.weapons && item.flags & FL_TOSSED)    // don't let players stack ammo by tossing weapons
 116                                 return 0;
 117                 }
 118
 119                 // in case the player has autoswitch enabled do the following:
 120                 // if the player is using their best weapon before items are given, they
 121                 // probably want to switch to an even better weapon after items are given
 122                 if (player.autoswitch)
 123                 if (player.switchweapon == w_getbestweapon(player))
 124                         _switchweapon = TRUE;
 125
 126                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 127                         _switchweapon = TRUE;
 128
 129                 if (item.ammo_shells)
 130                 if (player.ammo_shells < g_pickup_shells_max)
 131                 {
 132                         pickedup = TRUE;
 133                         player.ammo_shells = min (player.ammo_shells + item.ammo_shells, g_pickup_shells_max);
 134                 }
 135                 if (item.ammo_nails)
 136                 if (player.ammo_nails < g_pickup_nails_max)
 137                 {
 138                         pickedup = TRUE;
 139                         player.ammo_nails = min (player.ammo_nails + item.ammo_nails, g_pickup_nails_max);
 140                 }
 141                 if (item.ammo_rockets)
 142                 if (player.ammo_rockets < g_pickup_rockets_max)
 143                 {
 144                         pickedup = TRUE;
 145                         player.ammo_rockets = min (player.ammo_rockets + item.ammo_rockets, g_pickup_rockets_max);
 146                 }
 147                 if (item.ammo_cells)
 148                 if (player.ammo_cells < g_pickup_cells_max)
 149                 {
 150                         pickedup = TRUE;
 151                         player.ammo_cells = min (player.ammo_cells + item.ammo_cells, g_pickup_cells_max);
 152                 }
 153
 154                 if (item.flags & FL_WEAPON)
 155                 if ((it = item.weapons - (item.weapons & player.weapons)))
 156                 {
 157                         pickedup = TRUE;
 158                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 159                         {
 160                                 e = get_weaponinfo(i);
 161                                 if(it & e.weapons)
 162                                         W_GiveWeapon (player, e.weapon, item.netname);
 163                         }
 164                 }
 165
 166                 if (item.strength_finished)
 167                 {
 168                         pickedup = TRUE;
 169                         player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 170                 }
 171                 if (item.invincible_finished)
 172                 {
 173                         pickedup = TRUE;
 174                         player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 175                 }
 176                 //if (item.speed_finished)
 177                 //{
 178                 //      pickedup = TRUE;
 179                 //      player.speed_finished = max(player.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 180                 //}
 181                 //if (item.slowmo_finished)
 182                 //{
 183                 //      pickedup = TRUE;
 184                 //      player.slowmo_finished = max(player.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 185                 //}
 186
 187                 if (item.health)
 188                 if (player.health < item.max_health)
 189                 {
 190                         pickedup = TRUE;
 191                         player.health = min(player.health + item.health, item.max_health);
 192                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 193                 }
 194                 if (item.armorvalue)
 195                 if (player.armorvalue < item.max_armorvalue)
 196                 {
 197                         pickedup = TRUE;
 198                         player.armorvalue = min(player.armorvalue + item.armorvalue, item.max_armorvalue);
 199                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 200                 }
 201         }
 202
 203         // always eat teamed entities
 204         if(item.team)
 205                 pickedup = TRUE;
 206
 207         if (!pickedup)
 208                 return 0;
 209
 210         sound (player, CHAN_AUTO, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 211         if (_switchweapon)
 212                 W_SwitchWeapon_Force(player, w_getbestweapon(player));
 213
 214         return 1;
 215 }
 216
 217 void Item_Touch (void)
 218 {
 219         entity e, head;
 220
 221         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 222         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 223         {
 224                 remove(self);
 225                 return;
 226         }
 227         if (other.classname != "player")
 228                 return;
 229         if (other.deadflag)
 230                 return;
 231         if (self.solid != SOLID_TRIGGER)
 232                 return;
 233         if (self.owner == other)
 234                 return;
 235
 236         if(!Item_GiveTo(self, other))
 237                 return;
 238
 239         if (self.classname == "droppedweapon")
 240                 remove (self);
 241         else if((self.flags & FL_WEAPON) && !self.team && (cvar("deathmatch") == 2 || cvar("g_weapon_stay")))
 242                 return;
 243         else
 244         {
 245                 self.solid = SOLID_NOT;
 246                 self.model = string_null;
 247                 if(self.team)
 248                 {
 249                         RandomSelection_Init();
 250                         for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 251                                 RandomSelection_Add(head, 0, 1, 0);
 252                         e = RandomSelection_chosen_ent;
 253                 }
 254                 else
 255                         e = self;
 256                 e.nextthink = time + self.respawntime;
 257                 e.think = Item_Respawn;
 258         }
 259 }
 260
 261 void Item_FindTeam()
 262 {
 263         entity head, e;
 264
 265         if(self.effects & EF_NODRAW)
 266         {
 267                 // marker for item team search
 268                 dprint("Initializing item team ", ftos(self.team), "\n");
 269                 RandomSelection_Init();
 270                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 271                         RandomSelection_Add(head, 0, 1, 0);
 272                 e = RandomSelection_chosen_ent;
 273
 274                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 275                 {
 276                         if(head != e)
 277                         {
 278                                 // make it a non-spawned item
 279                                 head.solid = SOLID_NOT;
 280                                 head.model = string_null;
 281                         }
 282                         head.effects = head.effects - (head.effects & EF_NODRAW);
 283                 }
 284         }
 285 }
 286
 287 // Savage: used for item garbage-collection
 288 // TODO: perhaps nice special effect?
 289 void RemoveItem(void) /*FIXDECL*/
 290 {
 291         remove(self);
 292 }
 293
 294 // pickup evaluation functions
 295 // these functions decide how desirable an item is to the bots
 296
 297 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};
 298
 299 float weapon_pickupevalfunc(entity player, entity item)
 300 {
 301         // if we already have the weapon, rate it 1/5th normal value
 302         if ((player.weapons & item.weapons) == item.weapons)
 303                 return item.bot_pickupbasevalue * 0.2;
 304         return item.bot_pickupbasevalue;
 305 };
 306
 307 float commodity_pickupevalfunc(entity player, entity item)
 308 {
 309         float c;
 310         c = 0;
 311         // TODO: figure out if the player even has the weapon this ammo is for?
 312         // may not affect strategy much though...
 313         // find out how much more ammo/armor/health the player can hold
 314         if (item.ammo_shells)
 315         if (player.ammo_shells < g_pickup_shells_max)
 316                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 317         if (item.ammo_nails)
 318         if (player.ammo_nails < g_pickup_nails_max)
 319                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 320         if (item.ammo_rockets)
 321         if (player.ammo_rockets < g_pickup_rockets_max)
 322                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 323         if (item.ammo_cells)
 324         if (player.ammo_cells < g_pickup_cells_max)
 325                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 326         if (item.armorvalue)
 327         if (player.armorvalue < item.max_armorvalue)
 328                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 329         if (item.health)
 330         if (player.health < item.max_health)
 331                 c = c + max(0, 1 - player.health / item.max_health);
 332
 333         return item.bot_pickupbasevalue * c;
 334 };
 335
 336
 337 .float is_item;
 338 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 339 {
 340         startitem_failed = FALSE;
 341
 342         // is it a dropped weapon?
 343         if (self.classname == "droppedweapon")
 344         {
 345                 // it's a dropped weapon
 346                 self.movetype = MOVETYPE_TOSS;
 347                 self.solid = SOLID_TRIGGER;
 348                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 349                 self.think = RemoveItem;
 350                 self.nextthink = time + 60;
 351                 // don't drop if in a NODROP zone (such as lava)
 352                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 353                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 354                 {
 355                         startitem_failed = TRUE;
 356                         remove(self);
 357                         return;
 358                 }
 359         }
 360         else
 361         {
 362                 // it's a level item
 363                 if(self.spawnflags & 1)
 364                         self.noalign = 1;
 365                 if (self.noalign)
 366                         self.movetype = MOVETYPE_NONE;
 367                 else
 368                         self.movetype = MOVETYPE_TOSS;
 369                 self.solid = SOLID_TRIGGER;
 370                 // do item filtering according to game mode and other things
 371                 if (!self.noalign)
 372                 {
 373                         // first nudge it off the floor a little bit to avoid math errors
 374                         setorigin(self, self.origin + '0 0 1');
 375                         // set item size before we spawn a spawnfunc_waypoint
 376                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 377                                 setsize (self, '-16 -16 0', '16 16 48');
 378                         else
 379                                 setsize (self, '-16 -16 0', '16 16 32');
 380                         // note droptofloor returns FALSE if stuck/or would fall too far
 381                         droptofloor();
 382                         waypoint_spawnforitem(self);
 383                 }
 384
 385                 if(teams_matter)
 386                 {
 387                         if(self.notteam)
 388                         {
 389                                 print("removed non-teamplay ", self.classname, "\n");
 390                                 startitem_failed = TRUE;
 391                                 remove (self);
 392                                 return;
 393                         }
 394                 }
 395                 else
 396                 {
 397                         if(self.notfree)
 398                         {
 399                                 print("removed non-FFA ", self.classname, "\n");
 400                                 startitem_failed = TRUE;
 401                                 remove (self);
 402                                 return;
 403                         }
 404                 }
 405
 406                 if(self.notq3a)
 407                 {
 408                         // We aren't TA or something like that, so we keep the Q3A entities
 409                         print("removed non-Q3A ", self.classname, "\n");
 410                         startitem_failed = TRUE;
 411                         remove (self);
 412                         return;
 413                 }
 414
 415                 /*
 416                  * can't do it that way, as it would break maps
 417                  * TODO make a target_give like entity another way, that perhaps has
 418                  * the weapon name in a key
 419                 if(self.targetname)
 420                 {
 421                         // target_give not yet supported; maybe later
 422                         print("removed targeted ", self.classname, "\n");
 423                         startitem_failed = TRUE;
 424                         remove (self);
 425                         return;
 426                 }
 427                 */
 428
 429                 if(cvar("spawn_debug") >= 2)
 430                 {
 431                         entity otheritem;
 432                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 433                         {
 434                                 if(otheritem.is_item)
 435                                 {
 436                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 437                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 438                                         error("Mapper sucks.");
 439                                 }
 440                         }
 441                         self.is_item = TRUE;
 442                 }
 443
 444                 weaponsInMap |= weaponid;
 445
 446                 if(g_lms || g_rocketarena)
 447                 {
 448                         startitem_failed = TRUE;
 449                         remove(self);
 450                         return;
 451                 }
 452                 else if (g_minstagib)
 453                 {
 454                         // don't remove dropped items and powerups
 455                         if (self.classname != "minstagib")
 456                         {
 457                                 startitem_failed = TRUE;
 458                                 remove (self);
 459                                 return;
 460                         }
 461                 }
 462                 else if ((!cvar("g_pickup_items") || g_nixnex) && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 463                 {
 464                         startitem_failed = TRUE;
 465                         remove (self);
 466                         return;
 467                 }
 468
 469                 precache_model (itemmodel);
 470                 precache_sound (pickupsound);
 471                 precache_sound ("misc/itemrespawn.wav");
 472
 473                 if((itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)) || (weaponid & WEPBIT_ALL))
 474                         self.target = "###item###"; // for finding the nearest item using find()
 475         }
 476
 477         self.bot_pickup = TRUE;
 478         self.bot_pickupevalfunc = pickupevalfunc;
 479         self.bot_pickupbasevalue = pickupbasevalue;
 480         self.mdl = itemmodel;
 481         self.item_pickupsound = pickupsound;
 482         // let mappers override respawntime
 483         if (!self.respawntime)
 484                 self.respawntime = defaultrespawntime;
 485         self.netname = itemname;
 486         self.items = itemid;
 487         self.weapons = weaponid;
 488         self.flags = FL_ITEM | itemflags;
 489         self.touch = Item_Touch;
 490         setmodel (self, self.mdl); // precision set below
 491         self.effects |= EF_LOWPRECISION;
 492         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 493                 setsize (self, '-16 -16 0', '16 16 48');
 494         else
 495                 setsize (self, '-16 -16 0', '16 16 32');
 496         if (itemflags & FL_WEAPON)
 497         {
 498                 // neutral team color for pickup weapons
 499                 self.colormap = 160 * 1024 + 160;
 500         }
 501
 502         if (cvar("g_fullbrightitems"))
 503                 self.effects = self.effects | EF_FULLBRIGHT;
 504
 505         if(self.team)
 506         {
 507                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 508                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 509         }
 510 }
 511
 512 /* replace items in minstagib
 513  * IT_STRENGTH   = invisibility
 514  * IT_NAILS      = extra lives
 515  * IT_INVINCIBLE = speed
 516  */
 517 void minstagib_items (float itemid)
 518 {
 519         // we don't want to replace dropped weapons ;)
 520         if (self.classname == "droppedweapon")
 521         {
 522                 self.ammo_cells = 25;
 523                 StartItem ("models/weapons/g_nex.md3",
 524                         "weapons/weaponpickup.wav", 15,
 525                         "MinstaNex", 0, WEPBIT_MINSTANEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 526                 return;
 527         }
 528
 529         local float rnd;
 530         self.classname = "minstagib";
 531
 532         // replace rocket launchers and nex guns with ammo cells
 533         if (itemid == IT_CELLS)
 534         {
 535                 self.ammo_cells = 1;
 536                 StartItem ("models/items/a_cells.md3",
 537                         "misc/itempickup.wav", 45,
 538                         "Nex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 539                 return;
 540         }
 541
 542         // randomize
 543         rnd = random() * 3;
 544         if (rnd <= 1)
 545                 itemid = IT_STRENGTH;
 546         else if (rnd <= 2)
 547                 itemid = IT_NAILS;
 548         else
 549                 itemid = IT_INVINCIBLE;
 550
 551         // replace with invis
 552         if (itemid == IT_STRENGTH)
 553         {
 554                 self.effects = EF_ADDITIVE;
 555                 self.strength_finished = 30;
 556                 StartItem ("models/items/g_strength.md3",
 557                         "misc/powerup.wav", g_pickup_respawntime_powerup,
 558                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 1000);
 559         }
 560         // replace with extra lives
 561         if (itemid == IT_NAILS)
 562         {
 563                 self.max_health = 1;
 564                 StartItem ("models/items/g_h100.md3",
 565                         "misc/megahealth.wav", g_pickup_respawntime_powerup,
 566                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, 1000);
 567
 568         }
 569         // replace with speed
 570         if (itemid == IT_INVINCIBLE)
 571         {
 572                 self.effects = EF_ADDITIVE;
 573                 self.invincible_finished = 30;
 574                 StartItem ("models/items/g_invincible.md3",
 575                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup,
 576                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 1000);
 577         }
 578
 579 }
 580
 581 float minst_no_auto_cells;
 582 void minst_remove_item (void) {
 583         if(minst_no_auto_cells)
 584                 remove(self);
 585 }
 586
 587 float weaponswapping;
 588 float internalteam;
 589
 590 void weapon_defaultspawnfunc(float wpn)
 591 {
 592         entity e;
 593         float t;
 594         var .float ammofield;
 595         string s;
 596         entity oldself;
 597         float i;
 598
 599         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 600         {
 601                 s = cvar_string(strcat("g_weaponreplace_", ftos(wpn)));
 602                 t = tokenize(s);
 603                 if(t >= 2)
 604                 {
 605                         self.team = --internalteam;
 606                         for(i = 1; i < t; ++i)
 607                         {
 608                                 oldself = self;
 609                                 self = spawn();
 610                                 copyentity(oldself, self);
 611                                 self.classname = "replacedweapon";
 612                                 weapon_defaultspawnfunc(stof(argv(i)));
 613                                 self = oldself;
 614                                 print("replaced by ", argv(i), "\n");
 615                         }
 616                 }
 617                 if(t >= 1)
 618                         wpn = stof(argv(0));
 619         }
 620
 621         e = get_weaponinfo(wpn);
 622
 623         t = g_pickup_respawntime_short;
 624
 625         if(e.items && e.items != IT_SUPERWEAPON)
 626         {
 627                 ammofield = Item_CounterField(e.items);
 628                 if(!self.ammofield)
 629                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(e.items)));
 630         }
 631
 632         if(e.items == IT_SUPERWEAPON)
 633                 t = g_pickup_respawntime_powerup;
 634
 635         StartItem(e.model, "weapons/weaponpickup.wav", t, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
 636         if (self.modelindex) // don't precache if self was removed
 637                 weapon_action(e.weapon, WR_PRECACHE);
 638 }
 639
 640 void spawnfunc_weapon_shotgun (void);
 641 void spawnfunc_weapon_uzi (void) {
 642         if(q3acompat_machineshotgunswap)
 643         if(self.classname != "droppedweapon")
 644         {
 645                 weapon_defaultspawnfunc(WEP_SHOTGUN);
 646                 return;
 647         }
 648         weapon_defaultspawnfunc(WEP_UZI);
 649 }
 650
 651 void spawnfunc_weapon_shotgun (void) {
 652         if(q3acompat_machineshotgunswap)
 653         if(self.classname != "droppedweapon")
 654         {
 655                 weapon_defaultspawnfunc(WEP_UZI);
 656                 return;
 657         }
 658         weapon_defaultspawnfunc(WEP_SHOTGUN);
 659 }
 660
 661 void spawnfunc_weapon_nex (void)
 662 {
 663         if (g_minstagib)
 664         {
 665                 minstagib_items(IT_CELLS);
 666                 self.think = minst_remove_item;
 667                 self.nextthink = time + cvar("sys_ticrate");
 668                 return;
 669         }
 670         weapon_defaultspawnfunc(WEP_NEX);
 671 }
 672
 673 void spawnfunc_weapon_minstanex (void)
 674 {
 675         if (g_minstagib)
 676         {
 677                 minstagib_items(IT_CELLS);
 678                 self.think = minst_remove_item;
 679                 self.nextthink = time + cvar("sys_ticrate");
 680                 return;
 681         }
 682         weapon_defaultspawnfunc(WEP_MINSTANEX);
 683 }
 684
 685 void spawnfunc_weapon_rocketlauncher (void)
 686 {
 687         if (g_minstagib)
 688         {
 689                 minstagib_items(IT_CELLS);
 690                 self.think = minst_remove_item;
 691                 self.nextthink = time + cvar("sys_ticrate");
 692                 return;
 693         }
 694         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
 695 }
 696
 697 void spawnfunc_item_rockets (void) {
 698         if(!self.ammo_rockets)
 699                 self.ammo_rockets = g_pickup_rockets;
 700         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_short, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
 701 }
 702
 703 void spawnfunc_item_shells (void);
 704 void spawnfunc_item_bullets (void) {
 705         if(!weaponswapping)
 706         if(q3acompat_machineshotgunswap)
 707         if(self.classname != "droppedweapon")
 708         {
 709                 weaponswapping = TRUE;
 710                 spawnfunc_item_shells();
 711                 weaponswapping = FALSE;
 712                 return;
 713         }
 714
 715         if(!self.ammo_nails)
 716                 self.ammo_nails = g_pickup_nails;
 717         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_short, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
 718 }
 719
 720 void spawnfunc_item_cells (void) {
 721         if(!self.ammo_cells)
 722                 self.ammo_cells = g_pickup_cells;
 723         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_short, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
 724 }
 725
 726 void spawnfunc_item_shells (void) {
 727         if(!weaponswapping)
 728         if(q3acompat_machineshotgunswap)
 729         if(self.classname != "droppedweapon")
 730         {
 731                 weaponswapping = TRUE;
 732                 spawnfunc_item_bullets();
 733                 weaponswapping = FALSE;
 734                 return;
 735         }
 736
 737         if(!self.ammo_shells)
 738                 self.ammo_shells = g_pickup_shells;
 739         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_short, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
 740 }
 741
 742 void spawnfunc_item_armor_small (void) {
 743         if(!self.armorvalue)
 744                 self.armorvalue = g_pickup_armorsmall;
 745         if(!self.max_armorvalue)
 746                 self.max_armorvalue = g_pickup_armorsmall_max;
 747         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", g_pickup_respawntime_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, 1000);
 748 }
 749
 750 void spawnfunc_item_armor_medium (void) {
 751         if(!self.armorvalue)
 752                 self.armorvalue = g_pickup_armormedium;
 753         if(!self.max_armorvalue)
 754                 self.max_armorvalue = g_pickup_armormedium_max;
 755         StartItem ("models/items/g_armormedium.md3", "misc/armor1.wav", g_pickup_respawntime_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
 756 }
 757
 758 void spawnfunc_item_armor_large (void) {
 759         if(!self.armorvalue)
 760                 self.armorvalue = g_pickup_armorlarge;
 761         if(!self.max_armorvalue)
 762                 self.max_armorvalue = g_pickup_armorlarge_max;
 763         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", g_pickup_respawntime_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
 764 }
 765
 766 void spawnfunc_item_health_small (void) {
 767         if(!self.max_health)
 768                 self.max_health = g_pickup_healthsmall_max;
 769         if(!self.health)
 770                 self.health = g_pickup_healthsmall;
 771         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, 20000);
 772 }
 773
 774 void spawnfunc_item_health_medium (void) {
 775         if(!self.max_health)
 776                 self.max_health = g_pickup_healthmedium_max;
 777         if(!self.health)
 778                 self.health = g_pickup_healthmedium;
 779         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, 20000);
 780 }
 781
 782 void spawnfunc_item_health_large (void) {
 783         if(!self.max_health)
 784                 self.max_health = g_pickup_healthlarge_max;
 785         if(!self.health)
 786                 self.health = g_pickup_healthlarge;
 787         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, 20000);
 788 }
 789
 790 void spawnfunc_item_health_mega (void) {
 791         if(!cvar("g_powerup_superhealth"))
 792                 return;
 793
 794         if(g_arena && !cvar("g_arena_powerups"))
 795                 return;
 796
 797         if(g_minstagib) {
 798                 minstagib_items(IT_NAILS);
 799         } else {
 800                 if(!self.max_health)
 801                         self.max_health = g_pickup_healthmega_max;
 802                 if(!self.health)
 803                         self.health = g_pickup_healthmega;
 804                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, 20000);
 805         }
 806 }
 807
 808 // support old misnamed entities
 809 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Nexuiz maps it is an armor shard
 810 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
 811 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
 812 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
 813 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
 814
 815 void spawnfunc_item_strength (void) {
 816         if(!cvar("g_powerup_strength"))
 817                 return;
 818
 819         if(g_arena && !cvar("g_arena_powerups"))
 820                 return;
 821
 822         if(g_minstagib) {
 823                 minstagib_items(IT_STRENGTH);
 824         } else {
 825                 precache_sound("weapons/strength_fire.wav");
 826                 self.strength_finished = 30;
 827                 self.effects = EF_ADDITIVE;
 828                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
 829         }
 830 }
 831
 832 void spawnfunc_item_invincible (void) {
 833         if(!cvar("g_powerup_shield"))
 834                 return;
 835
 836         if(g_arena && !cvar("g_arena_powerups"))
 837                 return;
 838
 839         if(g_minstagib) {
 840                 minstagib_items(IT_INVINCIBLE);
 841         } else {
 842                 self.invincible_finished = 30;
 843                 self.effects = EF_ADDITIVE;
 844                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, "Invulnerability", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
 845         }
 846 }
 847
 848 void spawnfunc_item_minst_cells (void) {
 849         if (g_minstagib)
 850         {
 851                 minst_no_auto_cells = 1;
 852                 minstagib_items(IT_CELLS);
 853         }
 854         else
 855                 remove(self);
 856 }
 857
 858 // compatibility:
 859 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
 860
 861 void spawnfunc_misc_models (void)
 862 {
 863         SetBrushEntityModel();
 864 }
 865
 866 void func_wall_use (void)
 867 {
 868         if(teams_matter)
 869         {
 870                 if(activator.team)
 871                         self.colormap = (activator.team - 1) * 0x11;
 872                 else
 873                         self.colormap = 0x00;
 874         }
 875         else
 876                 self.colormap = ceil(random() * 256) - 1;
 877         self.colormap |= 1024; // RENDER_COLORMAPPED
 878 }
 879
 880 void spawnfunc_func_wall (void)
 881 {
 882         SetBrushEntityModel();
 883         self.solid = SOLID_BSP;
 884         self.use = func_wall_use;
 885 }
 886
 887 float trigger_item_func_set(float a, float b)
 888 {
 889         if(b == 0)
 890                 return a;
 891         else if(b < 0)
 892                 return 0;
 893         else
 894                 return b;
 895 }
 896
 897 float trigger_item_func_min(float a, float b)
 898 {
 899         if(b == 0)
 900                 return a;
 901         else if(b < 0)
 902                 return 0;
 903         else
 904                 return min(a, b);
 905 }
 906
 907 float trigger_item_func_max(float a, float b)
 908 {
 909         return max(a, b);
 910 }
 911
 912 float trigger_item_func_bitset(float a, float b)
 913 {
 914         return b;
 915 }
 916
 917 float trigger_item_func_and(float a, float b)
 918 {
 919         return a & b;
 920 }
 921
 922 float trigger_item_func_or(float a, float b)
 923 {
 924         return a | b;
 925 }
 926
 927 float trigger_item_func_andnot(float a, float b)
 928 {
 929         return a - (a & b);
 930 }
 931
 932 float trigger_item_changed;
 933 void trigger_item_change(float binary, .float field, float(float a, float b) func, string sound_increase, string sound_decrease)
 934 {
 935         float n, d;
 936         n = func(activator.field, self.field);
 937
 938         if(binary)
 939         {
 940                 d = n & activator.field;
 941                 if(d != n) // bits added?
 942                         d = +1;
 943                 else if(d != activator.field) // bits removed?
 944                         d = -1;
 945                 else
 946                         d = 0;
 947         }
 948         else
 949                 d = n - activator.field;
 950
 951         if(d < 0)
 952         {
 953                 if(sound_decrease != "")
 954                         sound (activator, CHAN_AUTO, sound_decrease, VOL_BASE, ATTN_NORM);
 955                 trigger_item_changed = 1;
 956         }
 957         else if(d > 0)
 958         {
 959                 if(sound_increase != "")
 960                         sound (activator, CHAN_AUTO, sound_increase, VOL_BASE, ATTN_NORM);
 961                 trigger_item_changed = 1;
 962         }
 963         activator.field = n;
 964 }
 965
 966 void trigger_items_use (void)
 967 {
 968         float h0, a0;
 969         if(activator.classname != "player")
 970                 return;
 971         if(activator.deadflag != DEAD_NO)
 972                 return;
 973         EXACTTRIGGER_TOUCH;
 974
 975         entity e;
 976         for(e = world; (e = find(e, classname, "droppedweapon")); )
 977                 if(e.enemy == activator)
 978                         remove(e);
 979
 980         float _switchweapon;
 981         _switchweapon = FALSE;
 982         if (activator.autoswitch)
 983                 if (activator.switchweapon == w_getbestweapon(activator))
 984                         _switchweapon = TRUE;
 985
 986         a0 = activator.armorvalue;
 987         h0 = activator.health;
 988         trigger_item_changed = 0;
 989
 990         if(self.spawnflags == 0) // SET
 991         {
 992                 trigger_item_change(0, ammo_shells, trigger_item_func_set, "misc/itempickup.wav", "");
 993                 trigger_item_change(0, ammo_nails, trigger_item_func_set, "misc/itempickup.wav", "");
 994                 trigger_item_change(0, ammo_rockets, trigger_item_func_set, "misc/itempickup.wav", "");
 995                 trigger_item_change(0, ammo_cells, trigger_item_func_set, "misc/itempickup.wav", "");
 996                 trigger_item_change(0, health, trigger_item_func_set, "misc/megahealth.wav", "");
 997                 trigger_item_change(0, armorvalue, trigger_item_func_set, "misc/armor25.wav", "");
 998                 trigger_item_change(1, items, trigger_item_func_bitset, "misc/powerup.wav", "");
 999                 trigger_item_change(1, weapons, trigger_item_func_bitset, "weapons/weaponpickup.wav", "");
1000
1001                 if((self.items & activator.items) & IT_STRENGTH)
1002                         activator.strength_finished = time + self.strength_finished;
1003                 if((self.items & activator.items) & IT_INVINCIBLE)
1004                         activator.invincible_finished = time + self.invincible_finished;
1005         }
1006         else if(self.spawnflags == 1) // AND/MIN
1007         {
1008                 trigger_item_change(0, ammo_shells, trigger_item_func_min, "misc/itempickup.wav", "");
1009                 trigger_item_change(0, ammo_nails, trigger_item_func_min, "misc/itempickup.wav", "");
1010                 trigger_item_change(0, ammo_rockets, trigger_item_func_min, "misc/itempickup.wav", "");
1011                 trigger_item_change(0, ammo_cells, trigger_item_func_min, "misc/itempickup.wav", "");
1012                 trigger_item_change(0, health, trigger_item_func_min, "misc/megahealth.wav", "");
1013                 trigger_item_change(0, armorvalue, trigger_item_func_min, "misc/armor25.wav", "");
1014                 trigger_item_change(1, items, trigger_item_func_and, "misc/powerup.wav", "");
1015                 trigger_item_change(1, weapons, trigger_item_func_and, "weapons/weaponpickup.wav", "");
1016
1017                 if((self.items & activator.items) & IT_STRENGTH)
1018                         activator.strength_finished = min(activator.strength_finished, time + self.strength_finished);
1019                 if((self.items & activator.items) & IT_INVINCIBLE)
1020                         activator.invincible_finished = min(activator.invincible_finished, time + self.invincible_finished);
1021         }
1022         else if(self.spawnflags == 2) // OR/MAX
1023         {
1024                 trigger_item_change(0, ammo_shells, trigger_item_func_max, "misc/itempickup.wav", "");
1025                 trigger_item_change(0, ammo_nails, trigger_item_func_max, "misc/itempickup.wav", "");
1026                 trigger_item_change(0, ammo_rockets, trigger_item_func_max, "misc/itempickup.wav", "");
1027                 trigger_item_change(0, ammo_cells, trigger_item_func_max, "misc/itempickup.wav", "");
1028                 trigger_item_change(0, health, trigger_item_func_max, "misc/megahealth.wav", "");
1029                 trigger_item_change(0, armorvalue, trigger_item_func_max, "misc/armor25.wav", "");
1030                 trigger_item_change(1, items, trigger_item_func_or, "misc/powerup.wav", "");
1031                 trigger_item_change(1, weapons, trigger_item_func_or, "weapons/weaponpickup.wav", "");
1032
1033                 if((self.items & activator.items) & IT_STRENGTH)
1034                         activator.strength_finished = max(activator.strength_finished, time + self.strength_finished);
1035                 if((self.items & activator.items) & IT_INVINCIBLE)
1036                         activator.invincible_finished = max(activator.invincible_finished, time + self.invincible_finished);
1037         }
1038         else if(self.spawnflags == 4) // ANDNOT/MIN
1039         {
1040                 trigger_item_change(0, ammo_shells, trigger_item_func_min, "misc/itempickup.wav", "");
1041                 trigger_item_change(0, ammo_nails, trigger_item_func_min, "misc/itempickup.wav", "");
1042                 trigger_item_change(0, ammo_rockets, trigger_item_func_min, "misc/itempickup.wav", "");
1043                 trigger_item_change(0, ammo_cells, trigger_item_func_min, "misc/itempickup.wav", "");
1044                 trigger_item_change(0, health, trigger_item_func_min, "misc/megahealth.wav", "");
1045                 trigger_item_change(0, armorvalue, trigger_item_func_min, "misc/armor25.wav", "");
1046                 trigger_item_change(1, items, trigger_item_func_andnot, "misc/powerup.wav", "");
1047                 trigger_item_change(1, weapons, trigger_item_func_andnot, "weapons/weaponpickup.wav", "");
1048
1049                 if((self.items & activator.items) & IT_STRENGTH)
1050                         activator.strength_finished = min(activator.strength_finished, time + self.strength_finished);
1051                 if((self.items & activator.items) & IT_INVINCIBLE)
1052                         activator.invincible_finished = min(activator.invincible_finished, time + self.invincible_finished);
1053         }
1054
1055         if not(activator.items & IT_STRENGTH)
1056                 activator.strength_finished = 0;
1057         if not(activator.items & IT_INVINCIBLE)
1058                 activator.invincible_finished = 0;
1059
1060         if(activator.health > h0)
1061                 activator.pauserothealth_finished = max(activator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
1062         else if(activator.health < h0)
1063                 activator.pauseregen_finished = max(activator.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
1064
1065         if(activator.armorvalue > a0)
1066                 activator.pauserotarmor_finished = max(activator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
1067
1068         if not(activator.weapons & W_WeaponBit(activator.switchweapon))
1069                 _switchweapon = TRUE;
1070         if(_switchweapon)
1071                 W_SwitchWeapon_Force(activator, w_getbestweapon(activator));
1072
1073         if(trigger_item_changed)
1074                 centerprint(activator, self.message);
1075 }
1076
1077 void spawnfunc_trigger_items (void)
1078 {
1079         float n, i, j;
1080         entity e;
1081         EXACTTRIGGER_INIT;
1082         self.use = trigger_items_use;
1083         if(!self.strength_finished)
1084                 self.strength_finished = cvar("g_balance_powerup_strength_time");
1085         if(!self.invincible_finished)
1086                 self.invincible_finished = cvar("g_balance_powerup_invincible_time");
1087
1088         n = tokenize(self.netname);
1089         for(i = 0; i < n; ++i)
1090         {
1091                 if(argv(i) == "unlimited_ammo") self.items |= IT_UNLIMITED_AMMO;
1092                 if(argv(i) == "strength")       self.items |= IT_STRENGTH;
1093                 if(argv(i) == "invincible")     self.items |= IT_INVINCIBLE;
1094                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1095                 {
1096                         e = get_weaponinfo(j);
1097                         if(argv(i) == e.netname)
1098                                 self.weapons |= e.weapons;
1099                 }
1100         }
1101 }