data/qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
   7 void() spawnpoint_use;
   8 string ColoredTeamName(float t);
   9
  10 float RandomSelection_totalweight;
  11 float RandomSelection_best_priority;
  12 entity RandomSelection_chosen_ent;
  13 float RandomSelection_chosen_float;
  14 void RandomSelection_Init()
  15 {
  16         RandomSelection_totalweight = 0;
  17         RandomSelection_chosen_ent = world;
  18         RandomSelection_chosen_float = 0;
  19         RandomSelection_best_priority = -1;
  20 }
  21 void RandomSelection_Add(entity e, float f, float weight, float priority)
  22 {
  23         if(priority > RandomSelection_best_priority)
  24         {
  25                 RandomSelection_best_priority = priority;
  26                 RandomSelection_chosen_ent = e;
  27                 RandomSelection_chosen_float = f;
  28                 RandomSelection_totalweight = weight;
  29         }
  30         else if(priority == RandomSelection_best_priority)
  31         {
  32                 RandomSelection_totalweight += weight;
  33                 if(random() * RandomSelection_totalweight <= weight)
  34                 {
  35                         RandomSelection_chosen_ent = e;
  36                         RandomSelection_chosen_float = f;
  37                 }
  38         }
  39 }
  40
  41 float DistributeEvenly_amount;
  42 float DistributeEvenly_totalweight;
  43 void DistributeEvenly_Init(float amount, float totalweight)
  44 {
  45         if(DistributeEvenly_amount)
  46         {
  47                 dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  48                 dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  49         }
  50         if(totalweight == 0)
  51                 DistributeEvenly_amount = 0;
  52         else
  53                 DistributeEvenly_amount = amount;
  54         DistributeEvenly_totalweight = totalweight;
  55 }
  56 float DistributeEvenly_Get(float weight)
  57 {
  58         float f;
  59         if(weight <= 0)
  60                 return 0;
  61         f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  62         DistributeEvenly_totalweight -= weight;
  63         DistributeEvenly_amount -= f;
  64         return f;
  65 }
  66
  67 void move_out_of_solid_expand(entity e, vector by)
  68 {
  69         float eps = 0.0625;
  70         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
  71         if(trace_startsolid)
  72                 return;
  73         if(trace_fraction < 1)
  74         {
  75                 // hit something
  76                 // adjust origin in the other direction...
  77                 e.origin = e.origin - by * (1 - trace_fraction);
  78         }
  79 }
  80
  81 float move_out_of_solid(entity e)
  82 {
  83         vector o, m0, m1;
  84
  85         o = e.origin;
  86         traceline(o, o, MOVE_WORLDONLY, e);
  87         if(trace_startsolid)
  88                 return 0;
  89
  90         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
  91         if(!trace_startsolid)
  92                 return 1;
  93
  94         m0 = e.mins;
  95         m1 = e.maxs;
  96         e.mins = '0 0 0';
  97         e.maxs = '0 0 0';
  98         move_out_of_solid_expand(e, '1 0 0' * m0_x); e.mins_x = m0_x;
  99         move_out_of_solid_expand(e, '1 0 0' * m1_x); e.maxs_x = m1_x;
 100         move_out_of_solid_expand(e, '0 1 0' * m0_y); e.mins_y = m0_y;
 101         move_out_of_solid_expand(e, '0 1 0' * m1_y); e.maxs_y = m1_y;
 102         move_out_of_solid_expand(e, '0 0 1' * m0_z); e.mins_z = m0_z;
 103         move_out_of_solid_expand(e, '0 0 1' * m1_z); e.maxs_z = m1_z;
 104         setorigin(e, e.origin);
 105
 106         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
 107         if(trace_startsolid)
 108         {
 109                 setorigin(e, o);
 110                 return 0;
 111         }
 112
 113         return 1;
 114 }
 115
 116 string STR_PLAYER = "player";
 117 string STR_SPECTATOR = "spectator";
 118 string STR_OBSERVER = "observer";
 119
 120 #if 0
 121 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
 122 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
 123 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
 124 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
 125 #else
 126 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
 127 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
 128 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
 129 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
 130 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
 131 #endif
 132
 133 // copies a string to a tempstring (so one can strunzone it)
 134 string strcat1(string s) = #115; // FRIK_FILE
 135
 136 float logfile_open;
 137 float logfile;
 138
 139 void bcenterprint(string s)
 140 {
 141         // TODO replace by MSG_ALL (would show it to spectators too, though)?
 142         entity head;
 143         FOR_EACH_PLAYER(head)
 144                 if(clienttype(head) == CLIENTTYPE_REAL)
 145                         centerprint(head, s);
 146 }
 147
 148 void GameLogEcho(string s)
 149 {
 150         string fn;
 151         float matches;
 152
 153         if(cvar("sv_eventlog_files"))
 154         {
 155                 if(!logfile_open)
 156                 {
 157                         logfile_open = TRUE;
 158                         matches = cvar("sv_eventlog_files_counter") + 1;
 159                         cvar_set("sv_eventlog_files_counter", ftos(matches));
 160                         fn = ftos(matches);
 161                         if(strlen(fn) < 8)
 162                                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 163                         fn = strcat(cvar_string("sv_eventlog_files_nameprefix"), fn, cvar_string("sv_eventlog_files_namesuffix"));
 164                         logfile = fopen(fn, FILE_APPEND);
 165                         fputs(logfile, ":logversion:3\n");
 166                 }
 167                 if(logfile >= 0)
 168                 {
 169                         if(cvar("sv_eventlog_files_timestamps"))
 170                                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 171                         else
 172                                 fputs(logfile, strcat(s, "\n"));
 173                 }
 174         }
 175         if(cvar("sv_eventlog_console"))
 176         {
 177                 print(s, "\n");
 178         }
 179 }
 180
 181 void GameLogInit()
 182 {
 183         logfile_open = 0;
 184         // will be opened later
 185 }
 186
 187 void GameLogClose()
 188 {
 189         if(logfile_open && logfile >= 0)
 190         {
 191                 fclose(logfile);
 192                 logfile = -1;
 193         }
 194 }
 195
 196 float spawnpoint_nag;
 197 void relocate_spawnpoint()
 198 {
 199         // nudge off the floor
 200         setorigin(self, self.origin + '0 0 1');
 201
 202         tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 203         if (trace_startsolid)
 204         {
 205                 vector o;
 206                 o = self.origin;
 207                 self.mins = PL_MIN;
 208                 self.maxs = PL_MAX;
 209                 if(!move_out_of_solid(self))
 210                         objerror("could not get out of solid at all!");
 211                 print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 212                 print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 213                 print(" ", ftos(self.origin_y - o_y));
 214                 print(" ", ftos(self.origin_z - o_z), "'\n");
 215                 if(cvar("g_spawnpoints_auto_move_out_of_solid"))
 216                 {
 217                         if(!spawnpoint_nag)
 218                                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 219                         spawnpoint_nag = 1;
 220                 }
 221                 else
 222                 {
 223                         self.origin = o;
 224                         self.mins = self.maxs = '0 0 0';
 225                         objerror("player spawn point in solid, mapper sucks!\n");
 226                         return;
 227                 }
 228         }
 229
 230         if(cvar("g_spawnpoints_autodrop"))
 231         {
 232                 setsize(self, PL_MIN, PL_MAX);
 233                 droptofloor();
 234         }
 235
 236         self.use = spawnpoint_use;
 237         self.team_saved = self.team;
 238         if(!self.cnt)
 239                 self.cnt = 1;
 240
 241         if(g_ctf || g_assault || g_onslaught || g_domination)
 242         if(self.team)
 243                 have_team_spawns = 1;
 244
 245         if(cvar("r_showbboxes"))
 246         {
 247                 // show where spawnpoints point at too
 248                 makevectors(self.angles);
 249                 entity e;
 250                 e = spawn();
 251                 e.classname = "info_player_foo";
 252                 setorigin(e, self.origin + v_forward * 24);
 253                 setsize(e, '-8 -8 -8', '8 8 8');
 254                 e.solid = SOLID_TRIGGER;
 255         }
 256 }
 257
 258 #define strstr strstrofs
 259 /*
 260 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 261 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 262 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 263 // BE CONSTANT OR strzoneD!
 264 float strstr(string haystack, string needle, float offset)
 265 {
 266         float len, endpos;
 267         string found;
 268         len = strlen(needle);
 269         endpos = strlen(haystack) - len;
 270         while(offset <= endpos)
 271         {
 272                 found = substring(haystack, offset, len);
 273                 if(found == needle)
 274                         return offset;
 275                 offset = offset + 1;
 276         }
 277         return -1;
 278 }
 279 */
 280
 281 float NUM_NEAREST_ENTITIES = 4;
 282 entity nearest_entity[NUM_NEAREST_ENTITIES];
 283 float nearest_length[NUM_NEAREST_ENTITIES];
 284 entity findnearest(vector point, .string field, string value, vector axismod)
 285 {
 286         entity localhead;
 287         float i;
 288         float j;
 289         float len;
 290         vector dist;
 291
 292         float num_nearest;
 293         num_nearest = 0;
 294
 295         localhead = find(world, field, value);
 296         while(localhead)
 297         {
 298                 if((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 299                         dist = localhead.oldorigin;
 300                 else
 301                         dist = localhead.origin;
 302                 dist = dist - point;
 303                 dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 304                 len = vlen(dist);
 305
 306                 for(i = 0; i < num_nearest; ++i)
 307                 {
 308                         if(len < nearest_length[i])
 309                                 break;
 310                 }
 311
 312                 // now i tells us where to insert at
 313                 //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 314                 if(i < NUM_NEAREST_ENTITIES)
 315                 {
 316                         for(j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 317                         {
 318                                 nearest_length[j + 1] = nearest_length[j];
 319                                 nearest_entity[j + 1] = nearest_entity[j];
 320                         }
 321                         nearest_length[i] = len;
 322                         nearest_entity[i] = localhead;
 323                         if(num_nearest < NUM_NEAREST_ENTITIES)
 324                                 num_nearest = num_nearest + 1;
 325                 }
 326
 327                 localhead = find(localhead, field, value);
 328         }
 329
 330         // now use the first one from our list that we can see
 331         for(i = 0; i < num_nearest; ++i)
 332         {
 333                 traceline(point, nearest_entity[i].origin, TRUE, world);
 334                 if(trace_fraction == 1)
 335                 {
 336                         if(i != 0)
 337                         {
 338                                 dprint("Nearest point (");
 339                                 dprint(nearest_entity[0].netname);
 340                                 dprint(") is not visible, using a visible one.\n");
 341                         }
 342                         return nearest_entity[i];
 343                 }
 344         }
 345
 346         if(num_nearest == 0)
 347                 return world;
 348
 349         dprint("Not seeing any location point, using nearest as fallback.\n");
 350         /* DEBUGGING CODE:
 351         dprint("Candidates were: ");
 352         for(j = 0; j < num_nearest; ++j)
 353         {
 354                 if(j != 0)
 355                         dprint(", ");
 356                 dprint(nearest_entity[j].netname);
 357         }
 358         dprint("\n");
 359         */
 360
 361         return nearest_entity[0];
 362 }
 363
 364 void spawnfunc_target_location()
 365 {
 366         self.classname = "target_location";
 367         // location name in netname
 368         // eventually support: count, teamgame selectors, line of sight?
 369 };
 370
 371 void spawnfunc_info_location()
 372 {
 373         self.classname = "target_location";
 374         self.message = self.netname;
 375 };
 376
 377 string NearestLocation(vector p)
 378 {
 379         entity loc;
 380         string ret;
 381         ret = "somewhere";
 382         loc = findnearest(p, classname, "target_location", '1 1 1');
 383         if(loc)
 384         {
 385                 ret = loc.message;
 386         }
 387         else
 388         {
 389                 loc = findnearest(p, target, "###item###", '1 1 4');
 390                 if(loc)
 391                         ret = loc.netname;
 392         }
 393         return ret;
 394 }
 395
 396 string formatmessage(string msg)
 397 {
 398         float p, p1, p2;
 399         float n;
 400         string escape;
 401         string replacement;
 402         p = 0;
 403         n = 7;
 404         while(1)
 405         {
 406                 if(n < 1)
 407                         break; // too many replacements
 408                 n = n - 1;
 409                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 410                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 411
 412                 if(p1 < 0)
 413                         p1 = p2;
 414                 if(p2 < 0)
 415                         p2 = p1;
 416                 p = min(p1, p2);
 417
 418                 if(p < 0)
 419                         break;
 420                 replacement = substring(msg, p, 2);
 421                 escape = substring(msg, p + 1, 1);
 422                 if(escape == "%")
 423                         replacement = "%";
 424                 else if(escape == "\\")
 425                         replacement = "\\";
 426                 else if(escape == "n")
 427                         replacement = "\n";
 428                 else if(escape == "a")
 429                         replacement = ftos(floor(self.armorvalue));
 430                 else if(escape == "h")
 431                         replacement = ftos(floor(self.health));
 432                 else if(escape == "l")
 433                         replacement = NearestLocation(self.origin);
 434                 else if(escape == "y")
 435                         replacement = NearestLocation(self.cursor_trace_endpos);
 436                 else if(escape == "d")
 437                         replacement = NearestLocation(self.death_origin);
 438                 else if(escape == "w")
 439                 {
 440                         float wep;
 441                         wep = self.weapon;
 442                         if(!wep)
 443                                 wep = self.switchweapon;
 444                         if(!wep)
 445                                 wep = self.cnt;
 446                         replacement = W_Name(wep);
 447                 }
 448                 else if(escape == "W")
 449                 {
 450                         if(self.items & IT_SHELLS) replacement = "shells";
 451                         else if(self.items & IT_NAILS) replacement = "bullets";
 452                         else if(self.items & IT_ROCKETS) replacement = "rockets";
 453                         else if(self.items & IT_CELLS) replacement = "cells";
 454                         else replacement = "batteries"; // ;)
 455                 }
 456                 else if(escape == "x")
 457                 {
 458                         replacement = self.cursor_trace_ent.netname;
 459                         if(!replacement || !self.cursor_trace_ent)
 460                                 replacement = "nothing";
 461                 }
 462                 else if(escape == "p")
 463                 {
 464                         if(self.last_selected_player)
 465                                 replacement = self.last_selected_player.netname;
 466                         else
 467                                 replacement = "(nobody)";
 468                 }
 469                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 470                 p = p + strlen(replacement);
 471         }
 472         return msg;
 473 }
 474
 475 /*
 476 =============
 477 GetCvars
 478 =============
 479 Called with:
 480   0:  sends the request
 481   >0: receives a cvar from name=argv(f) value=argv(f+1)
 482 */
 483 void GetCvars_handleString(string thisname, float f, .string field, string name)
 484 {
 485         if(f < 0)
 486         {
 487                 if(self.field)
 488                         strunzone(self.field);
 489                 self.field = string_null;
 490         }
 491         else if(f > 0)
 492         {
 493                 if(thisname == name)
 494                 {
 495                         if(self.field)
 496                                 strunzone(self.field);
 497                         self.field = strzone(argv(f + 1));
 498                 }
 499         }
 500         else
 501                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 502 }
 503 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 504 {
 505         GetCvars_handleString(thisname, f, field, name);
 506         if(f >= 0) // also initialize to the fitting value for "" when sending cvars out
 507         if(thisname == name)
 508         {
 509                 string s;
 510                 s = func(strcat1(self.field));
 511                 if(s != self.field)
 512                 {
 513                         strunzone(self.field);
 514                         self.field = strzone(s);
 515                 }
 516         }
 517 }
 518 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 519 {
 520         if(f < 0)
 521         {
 522         }
 523         else if(f > 0)
 524         {
 525                 if(thisname == name)
 526                         self.field = stof(argv(f + 1));
 527         }
 528         else
 529                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 530 }
 531 string W_FixWeaponOrder_ForceComplete(string s);
 532 string W_FixWeaponOrder_AllowIncomplete(string s);
 533 float w_getbestweapon(entity e);
 534 void GetCvars(float f)
 535 {
 536         string s;
 537         if(f > 0)
 538                 s = strcat1(argv(f));
 539         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 540         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 541         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 542         GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
 543         GetCvars_handleString(s, f, cvar_g_nexuizversion, "g_nexuizversion");
 544         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 545         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete);
 546         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 547         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 548         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 549         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 550         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 551         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 552         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 553         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 554         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 555         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 556         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 557         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 558         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 559         GetCvars_handleFloat(s, f, cvar_cl_hitsound, "cl_hitsound");
 560
 561         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 562         if(f > 0)
 563         {
 564                 if(s == "cl_weaponpriority")
 565                         self.switchweapon = w_getbestweapon(self);
 566         }
 567 }
 568
 569 float fexists(string f)
 570 {
 571         float fh;
 572         fh = fopen(f, FILE_READ);
 573         if(fh < 0)
 574                 return FALSE;
 575         fclose(fh);
 576         return TRUE;
 577 }
 578
 579 void backtrace(string msg)
 580 {
 581         float dev;
 582         dev = cvar("developer");
 583         cvar_set("developer", "1");
 584         dprint("\n");
 585         dprint("--- CUT HERE ---\nWARNING: ");
 586         dprint(msg);
 587         dprint("\n");
 588         remove(world); // isn't there any better way to cause a backtrace?
 589         dprint("\n--- CUT UNTIL HERE ---\n");
 590         cvar_set("developer", ftos(dev));
 591 }
 592
 593 string Team_ColorCode(float teamid)
 594 {
 595         if(teamid == COLOR_TEAM1)
 596                 return "^1";
 597         else if(teamid == COLOR_TEAM2)
 598                 return "^4";
 599         else if(teamid == COLOR_TEAM3)
 600                 return "^3";
 601         else if(teamid == COLOR_TEAM4)
 602                 return "^6";
 603         else
 604                 return "^7";
 605 }
 606 string Team_ColorName(float t)
 607 {
 608         // fixme: Search for team entities and get their .netname's!
 609         if(t == COLOR_TEAM1)
 610                 return "Red";
 611         if(t == COLOR_TEAM2)
 612                 return "Blue";
 613         if(t == COLOR_TEAM3)
 614                 return "Yellow";
 615         if(t == COLOR_TEAM4)
 616                 return "Pink";
 617         return "Neutral";
 618 }
 619 string Team_ColorNameLowerCase(float t)
 620 {
 621         // fixme: Search for team entities and get their .netname's!
 622         if(t == COLOR_TEAM1)
 623                 return "red";
 624         if(t == COLOR_TEAM2)
 625                 return "blue";
 626         if(t == COLOR_TEAM3)
 627                 return "yellow";
 628         if(t == COLOR_TEAM4)
 629                 return "pink";
 630         return "neutral";
 631 }
 632
 633 #define CENTERPRIO_POINT 1
 634 #define CENTERPRIO_SPAM 2
 635 #define CENTERPRIO_VOTE 4
 636 #define CENTERPRIO_NORMAL 5
 637 #define CENTERPRIO_SHIELDING 7
 638 #define CENTERPRIO_MAPVOTE 9
 639 #define CENTERPRIO_IDLEKICK 50
 640 #define CENTERPRIO_ADMIN 99
 641 .float centerprint_priority;
 642 .float centerprint_expires;
 643 void centerprint_atprio(entity e, float prio, string s)
 644 {
 645         if(intermission_running)
 646                 if(prio < CENTERPRIO_MAPVOTE)
 647                         return;
 648         if(time > e.centerprint_expires)
 649                 e.centerprint_priority = 0;
 650         if(prio >= e.centerprint_priority)
 651         {
 652                 e.centerprint_priority = prio;
 653                 if(timeoutStatus == 2)
 654                         e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 655                 else
 656                         e.centerprint_expires = time + e.cvar_scr_centertime;
 657                 centerprint_builtin(e, s);
 658         }
 659 }
 660 void centerprint_expire(entity e, float prio)
 661 {
 662         if(prio == e.centerprint_priority)
 663         {
 664                 e.centerprint_priority = 0;
 665                 centerprint_builtin(e, "");
 666         }
 667 }
 668 void centerprint(entity e, string s)
 669 {
 670         centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 671 }
 672
 673 // decolorizes and team colors the player name when needed
 674 string playername(entity p)
 675 {
 676         string t;
 677         if(teams_matter && !intermission_running && p.classname == "player")
 678         {
 679                 t = Team_ColorCode(p.team);
 680                 return strcat(t, strdecolorize(p.netname));
 681         }
 682         else
 683                 return p.netname;
 684 }
 685
 686 vector randompos(vector m1, vector m2)
 687 {
 688         local vector v;
 689         m2 = m2 - m1;
 690         v_x = m2_x * random() + m1_x;
 691         v_y = m2_y * random() + m1_y;
 692         v_z = m2_z * random() + m1_z;
 693         return  v;
 694 };
 695
 696 float g_pickup_shells;
 697 float g_pickup_shells_max;
 698 float g_pickup_nails;
 699 float g_pickup_nails_max;
 700 float g_pickup_rockets;
 701 float g_pickup_rockets_max;
 702 float g_pickup_cells;
 703 float g_pickup_cells_max;
 704 float g_pickup_armorsmall;
 705 float g_pickup_armorsmall_max;
 706 float g_pickup_armormedium;
 707 float g_pickup_armormedium_max;
 708 float g_pickup_armorbig;
 709 float g_pickup_armorbig_max;
 710 float g_pickup_armorlarge;
 711 float g_pickup_armorlarge_max;
 712 float g_pickup_healthsmall;
 713 float g_pickup_healthsmall_max;
 714 float g_pickup_healthmedium;
 715 float g_pickup_healthmedium_max;
 716 float g_pickup_healthlarge;
 717 float g_pickup_healthlarge_max;
 718 float g_pickup_healthmega;
 719 float g_pickup_healthmega_max;
 720 float g_weaponarena;
 721 string g_weaponarena_list;
 722
 723 float start_weapons;
 724 float start_items;
 725 float start_ammo_shells;
 726 float start_ammo_nails;
 727 float start_ammo_rockets;
 728 float start_ammo_cells;
 729 float start_health;
 730 float start_armorvalue;
 731 float warmup_start_weapons;
 732 float warmup_start_ammo_shells;
 733 float warmup_start_ammo_nails;
 734 float warmup_start_ammo_rockets;
 735 float warmup_start_ammo_cells;
 736 float warmup_start_health;
 737 float warmup_start_armorvalue;
 738 float start_fuel;
 739 float g_weapon_stay;
 740
 741 entity get_weaponinfo(float w);
 742
 743 void readplayerstartcvars()
 744 {
 745         entity e;
 746         float i, j, t;
 747         string s;
 748
 749         // initialize starting values for players
 750         start_weapons = 0;
 751         start_items = 0;
 752         start_ammo_shells = 0;
 753         start_ammo_nails = 0;
 754         start_ammo_rockets = 0;
 755         start_ammo_cells = 0;
 756         start_health = cvar("g_balance_health_start");
 757         start_fuel = cvar("g_balance_fuel_start");
 758         start_armorvalue = cvar("g_balance_armor_start");
 759
 760         g_weaponarena = 0;
 761         s = cvar_string("g_weaponarena");
 762         if(s == "0")
 763         {
 764         }
 765         else if(s == "all")
 766         {
 767                 g_weaponarena_list = "All Weapons";
 768                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 769                 {
 770                         e = get_weaponinfo(j);
 771                         g_weaponarena |= e.weapons;
 772                         weapon_action(e.weapon, WR_PRECACHE);
 773                 }
 774         }
 775         else if(s == "most")
 776         {
 777                 g_weaponarena_list = "Most Weapons";
 778                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 779                 {
 780                         e = get_weaponinfo(j);
 781                         if(e.spawnflags & WEPSPAWNFLAG_NORMAL)
 782                         {
 783                                 g_weaponarena |= e.weapons;
 784                                 weapon_action(e.weapon, WR_PRECACHE);
 785                         }
 786                 }
 787         }
 788         else
 789         {
 790                 t = tokenize_sane(s);
 791                 g_weaponarena_list = "";
 792                 for(i = 0; i < t; ++i)
 793                 {
 794                         s = argv(i);
 795                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 796                         {
 797                                 e = get_weaponinfo(j);
 798                                 if(e.netname == s)
 799                                 {
 800                                         g_weaponarena |= e.weapons;
 801                                         weapon_action(e.weapon, WR_PRECACHE);
 802                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 803                                         break;
 804                                 }
 805                         }
 806                         if(j > WEP_LAST)
 807                         {
 808                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 809                         }
 810                 }
 811                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 812         }
 813
 814         if(g_weaponarena)
 815         {
 816                 start_weapons = g_weaponarena;
 817                 start_ammo_rockets = 999;
 818                 start_ammo_shells = 999;
 819                 start_ammo_cells = 999;
 820                 start_ammo_nails = 999;
 821                 start_items |= IT_UNLIMITED_AMMO;
 822         }
 823         else if(g_nixnex)
 824         {
 825                 start_weapons = 0;
 826                 // will be done later
 827                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 828                 {
 829                         e = get_weaponinfo(i);
 830                         if(!(e.weapon))
 831                                 continue;
 832                         weapon_action(e.weapon, WR_PRECACHE);
 833                 }
 834         }
 835         else if(g_minstagib)
 836         {
 837                 start_health = 100;
 838                 start_armorvalue = 0;
 839                 start_weapons = WEPBIT_MINSTANEX;
 840                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
 841                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 842                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 843
 844                 if(g_minstagib_invis_alpha <= 0)
 845                         g_minstagib_invis_alpha = -1;
 846         }
 847         else
 848         {
 849                 if(g_lms)
 850                 {
 851                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 852                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 853                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 854                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 855                         start_health = cvar("g_lms_start_health");
 856                         start_armorvalue = cvar("g_lms_start_armor");
 857                 } else if (cvar("g_use_ammunition")) {
 858                         start_ammo_shells = cvar("g_start_ammo_shells");
 859                         start_ammo_nails = cvar("g_start_ammo_nails");
 860                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 861                         start_ammo_cells = cvar("g_start_ammo_cells");
 862                 } else {
 863                         start_ammo_shells = cvar("g_pickup_shells_max");
 864                         start_ammo_nails = cvar("g_pickup_nails_max");
 865                         start_ammo_rockets = cvar("g_pickup_rockets_max");
 866                         start_ammo_cells = cvar("g_pickup_cells_max");
 867                         start_items |= IT_UNLIMITED_AMMO;
 868                 }
 869
 870                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 871                 {
 872                         e = get_weaponinfo(i);
 873                         if(!(e.weapon))
 874                                 continue;
 875
 876                         t = cvar(strcat("g_start_weapon_", e.netname));
 877
 878                         if(t < 0) // "default" weapon selection
 879                         {
 880                                 if(g_lms)
 881                                         t = (e.spawnflags & WEPSPAWNFLAG_NORMAL);
 882                                 else if(g_race)
 883                                         t = (i == WEP_LASER);
 884                                 else
 885                                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 886                                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 887                                         t += (i == WEP_HOOK);
 888                         }
 889
 890                         if(t)
 891                         {
 892                                 start_weapons |= e.weapons;
 893                                 weapon_action(e.weapon, WR_PRECACHE);
 894                         }
 895                 }
 896         }
 897
 898         if(inWarmupStage)
 899         {
 900                 warmup_start_ammo_shells = start_ammo_shells;
 901                 warmup_start_ammo_nails = start_ammo_nails;
 902                 warmup_start_ammo_rockets = start_ammo_rockets;
 903                 warmup_start_ammo_cells = start_ammo_cells;
 904                 warmup_start_health = start_health;
 905                 warmup_start_armorvalue = start_armorvalue;
 906                 warmup_start_weapons = start_weapons;
 907
 908                 if(!g_weaponarena && !g_nixnex && !g_minstagib)
 909                 {
 910                         if(cvar("g_use_ammunition"))
 911                         {
 912                                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 913                                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 914                                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 915                                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 916                         }
 917                         warmup_start_health = cvar("g_warmup_start_health");
 918                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 919                         if(cvar("g_warmup_allguns"))
 920                         {
 921                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 922                                 {
 923                                         e = get_weaponinfo(i);
 924                                         if(!(e.weapon))
 925                                                 continue;
 926                                         if(e.spawnflags & WEPSPAWNFLAG_NORMAL)
 927                                         {
 928                                                 warmup_start_weapons |= e.weapons;
 929                                                 weapon_action(e.weapon, WR_PRECACHE);
 930                                         }
 931                                 }
 932                         }
 933                 }
 934         }
 935
 936         if(start_weapons & WEPBIT_HOOK)
 937         {
 938                 // can't have off-hand hook, if hook weapon is enabled
 939
 940                 // note: if g_grappling_hook is 1, also give some initial cells
 941                 if(g_grappling_hook)
 942                 {
 943                         if(!start_ammo_cells)
 944                                 start_ammo_cells = g_pickup_cells;
 945                         if(!warmup_start_ammo_cells)
 946                                 warmup_start_ammo_cells = g_pickup_cells;
 947                 }
 948
 949                 g_grappling_hook = 0;
 950         }
 951
 952         if(g_jetpack)
 953         {
 954                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 955                 start_items |= IT_JETPACK;
 956                 start_items |= IT_FUEL_REGEN;
 957                 start_fuel = max(start_fuel, cvar("g_balance_fuel_stable"));
 958         }
 959
 960         if(g_weapon_stay == 2)
 961         {
 962                 if(!start_ammo_shells) start_ammo_shells = g_pickup_shells;
 963                 if(!start_ammo_nails) start_ammo_nails = g_pickup_nails;
 964                 if(!start_ammo_cells) start_ammo_cells = g_pickup_cells;
 965                 if(!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
 966                 if(!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
 967                 if(!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
 968                 if(!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
 969                 if(!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
 970         }
 971
 972         start_ammo_shells = max(0, start_ammo_shells);
 973         start_ammo_nails = max(0, start_ammo_nails);
 974         start_ammo_cells = max(0, start_ammo_cells);
 975         start_ammo_rockets = max(0, start_ammo_rockets);
 976
 977         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 978         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 979         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 980         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 981 }
 982
 983 float g_bugrigs;
 984 float g_bugrigs_planar_movement;
 985 float g_bugrigs_planar_movement_car_jumping;
 986 float g_bugrigs_reverse_spinning;
 987 float g_bugrigs_reverse_speeding;
 988 float g_bugrigs_reverse_stopping;
 989 float g_bugrigs_air_steering;
 990 float g_bugrigs_angle_smoothing;
 991 float g_bugrigs_friction_floor;
 992 float g_bugrigs_friction_brake;
 993 float g_bugrigs_friction_air;
 994 float g_bugrigs_accel;
 995 float g_bugrigs_speed_ref;
 996 float g_bugrigs_speed_pow;
 997 float g_bugrigs_steer;
 998
 999 float g_touchexplode;
1000 float g_touchexplode_radius;
1001 float g_touchexplode_damage;
1002 float g_touchexplode_edgedamage;
1003 float g_touchexplode_force;
1004
1005 void readlevelcvars(void)
1006 {
1007         g_bugrigs = cvar("g_bugrigs");
1008         g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1009         g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1010         g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1011         g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1012         g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1013         g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1014         g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1015         g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1016         g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1017         g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1018         g_bugrigs_accel = cvar("g_bugrigs_accel");
1019         g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1020         g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1021         g_bugrigs_steer = cvar("g_bugrigs_steer");
1022
1023         g_touchexplode = cvar("g_touchexplode");
1024         g_touchexplode_radius = cvar("g_touchexplode_radius");
1025         g_touchexplode_damage = cvar("g_touchexplode_damage");
1026         g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1027         g_touchexplode_force = cvar("g_touchexplode_force");
1028
1029         sv_clones = cvar("sv_clones");
1030         sv_cheats = cvar("sv_cheats");
1031         sv_gentle = cvar("sv_gentle");
1032         sv_foginterval = cvar("sv_foginterval");
1033         g_cloaked = cvar("g_cloaked");
1034         g_jump_grunt = cvar("g_jump_grunt");
1035         g_footsteps = cvar("g_footsteps");
1036         g_grappling_hook = cvar("g_grappling_hook");
1037         g_jetpack = cvar("g_jetpack");
1038         g_laserguided_missile = cvar("g_laserguided_missile");
1039         g_midair = cvar("g_midair");
1040         g_minstagib = cvar("g_minstagib");
1041         g_nixnex = cvar("g_nixnex");
1042         g_nixnex_with_laser = cvar("g_nixnex_with_laser");
1043         g_norecoil = cvar("g_norecoil");
1044         g_vampire = cvar("g_vampire");
1045         g_bloodloss = cvar("g_bloodloss");
1046         sv_maxidle = cvar("sv_maxidle");
1047         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1048         sv_pogostick = cvar("sv_pogostick");
1049         sv_doublejump = cvar("sv_doublejump");
1050         g_maplist_allow_hidden = cvar("g_maplist_allow_hidden");
1051         g_ctf_reverse = cvar("g_ctf_reverse");
1052
1053         inWarmupStage = cvar("g_warmup");
1054         g_warmup_limit = cvar("g_warmup_limit");
1055         g_warmup_allguns = cvar("g_warmup_allguns");
1056         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1057
1058         if(g_race && g_race_qualifying == 2 || g_arena || g_assault || cvar("g_campaign"))
1059                 inWarmupStage = 0; // these modes cannot work together, sorry
1060
1061         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1062         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1063         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1064         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1065         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1066         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1067
1068         if(g_minstagib) g_nixnex = g_weaponarena = 0;
1069         if(g_nixnex) g_weaponarena = 0;
1070         g_weaponarena = 0;
1071
1072         g_pickup_shells                    = cvar("g_pickup_shells");
1073         g_pickup_shells_max                = cvar("g_pickup_shells_max");
1074         g_pickup_nails                     = cvar("g_pickup_nails");
1075         g_pickup_nails_max                 = cvar("g_pickup_nails_max");
1076         g_pickup_rockets                   = cvar("g_pickup_rockets");
1077         g_pickup_rockets_max               = cvar("g_pickup_rockets_max");
1078         g_pickup_cells                     = cvar("g_pickup_cells");
1079         g_pickup_cells_max                 = cvar("g_pickup_cells_max");
1080         g_pickup_armorsmall                = cvar("g_pickup_armorsmall");
1081         g_pickup_armorsmall_max            = cvar("g_pickup_armorsmall_max");
1082         g_pickup_armormedium               = cvar("g_pickup_armormedium");
1083         g_pickup_armormedium_max           = cvar("g_pickup_armormedium_max");
1084         g_pickup_armorbig                  = cvar("g_pickup_armorbig");
1085         g_pickup_armorbig_max              = cvar("g_pickup_armorbig_max");
1086         g_pickup_armorlarge                = cvar("g_pickup_armorlarge");
1087         g_pickup_armorlarge_max            = cvar("g_pickup_armorlarge_max");
1088         g_pickup_healthsmall               = cvar("g_pickup_healthsmall");
1089         g_pickup_healthsmall_max           = cvar("g_pickup_healthsmall_max");
1090         g_pickup_healthmedium              = cvar("g_pickup_healthmedium");
1091         g_pickup_healthmedium_max          = cvar("g_pickup_healthmedium_max");
1092         g_pickup_healthlarge               = cvar("g_pickup_healthlarge");
1093         g_pickup_healthlarge_max           = cvar("g_pickup_healthlarge_max");
1094         g_pickup_healthmega                = cvar("g_pickup_healthmega");
1095         g_pickup_healthmega_max            = cvar("g_pickup_healthmega_max");
1096
1097         g_pinata = cvar("g_pinata");
1098
1099         g_weapon_stay = cvar("g_weapon_stay");
1100         if(!g_weapon_stay && (cvar("deathmatch") == 2))
1101                 g_weapon_stay = 1;
1102
1103         if not(inWarmupStage)
1104                 game_starttime                 = cvar("g_start_delay");
1105
1106         readplayerstartcvars();
1107 }
1108
1109 /*
1110 // TODO sound pack system
1111 string soundpack;
1112
1113 string precache_sound_builtin (string s) = #19;
1114 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1115 string precache_sound(string s)
1116 {
1117         return precache_sound_builtin(strcat(soundpack, s));
1118 }
1119 void play2(entity e, string filename)
1120 {
1121         stuffcmd(e, strcat("play2 ", soundpack, filename, "\n"));
1122 }
1123 void sound(entity e, float chan, string samp, float vol, float atten)
1124 {
1125         sound_builtin(e, chan, strcat(soundpack, samp), vol, atten);
1126 }
1127 */
1128
1129 // Sound functions
1130 string precache_sound (string s) = #19;
1131 void(entity e, float chan, string samp, float vol, float atten) sound = #8;
1132 float precache_sound_index (string s) = #19;
1133
1134 #define SND_VOLUME      1
1135 #define SND_ATTENUATION 2
1136 #define SND_LARGEENTITY 8
1137 #define SND_LARGESOUND  16
1138
1139 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1140 {
1141         float entno, idx;
1142         entno = num_for_edict(e);
1143         idx = precache_sound_index(samp);
1144
1145         float sflags;
1146         sflags = 0;
1147
1148         atten = floor(atten * 64);
1149         vol = floor(vol * 255);
1150
1151         if(vol != 255)
1152                 sflags |= SND_VOLUME;
1153         if(atten != 64)
1154                 sflags |= SND_ATTENUATION;
1155         if(entno >= 8192)
1156                 sflags |= SND_LARGEENTITY;
1157         if(idx >= 256)
1158                 sflags |= SND_LARGESOUND;
1159
1160         WriteByte(dest, SVC_SOUND);
1161         WriteByte(dest, sflags);
1162         if(sflags & SND_VOLUME)
1163                 WriteByte(dest, vol * 255);
1164         if(sflags & SND_ATTENUATION)
1165                 WriteByte(dest, atten);
1166         if(sflags & SND_LARGEENTITY)
1167         {
1168                 WriteShort(dest, entno);
1169                 WriteByte(dest, chan);
1170         }
1171         else
1172         {
1173                 WriteShort(dest, entno * 8 + chan);
1174         }
1175         if(sflags & SND_LARGESOUND)
1176                 WriteShort(dest, idx);
1177         else
1178                 WriteByte(dest, idx);
1179
1180         WriteCoord(dest, o_x);
1181         WriteCoord(dest, o_y);
1182         WriteCoord(dest, o_z);
1183 }
1184 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1185 {
1186         vector o;
1187         o = e.origin + 0.5 * (e.mins + e.maxs);
1188         soundtoat(dest, e, o, chan, samp, vol, atten);
1189 }
1190 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1191 {
1192         soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1193 }
1194 void stopsoundto(float dest, entity e, float chan)
1195 {
1196         float entno;
1197         entno = num_for_edict(e);
1198
1199         if(entno >= 8192)
1200         {
1201                 float idx, sflags;
1202                 idx = precache_sound_index("misc/null.wav");
1203                 sflags = SND_LARGEENTITY;
1204                 if(idx >= 256)
1205                         sflags |= SND_LARGESOUND;
1206                 WriteByte(dest, SVC_SOUND);
1207                 WriteByte(dest, sflags);
1208                 WriteShort(dest, entno);
1209                 WriteByte(dest, chan);
1210                 if(sflags & SND_LARGESOUND)
1211                         WriteShort(dest, idx);
1212                 else
1213                         WriteByte(dest, idx);
1214                 WriteCoord(dest, e.origin_x);
1215                 WriteCoord(dest, e.origin_y);
1216                 WriteCoord(dest, e.origin_z);
1217         }
1218         else
1219         {
1220                 WriteByte(dest, SVC_STOPSOUND);
1221                 WriteShort(dest, entno * 8 + chan);
1222         }
1223 }
1224 void stopsound(entity e, float chan)
1225 {
1226         stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1227         stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1228 }
1229
1230 void play2(entity e, string filename)
1231 {
1232         //stuffcmd(e, strcat("play2 ", filename, "\n"));
1233         msg_entity = e;
1234         soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1235 }
1236
1237 .float announcetime;
1238 float announce(entity player, string msg)
1239 {
1240         if(time > player.announcetime)
1241         if(clienttype(player) == CLIENTTYPE_REAL)
1242         {
1243                 player.announcetime = time + 0.8;
1244                 play2(player, msg);
1245                 return TRUE;
1246         }
1247         return FALSE;
1248 }
1249
1250 void play2team(float t, string filename)
1251 {
1252         local entity head;
1253         FOR_EACH_REALPLAYER(head)
1254         {
1255                 if (head.team == t)
1256                         play2(head, filename);
1257         }
1258 }
1259
1260 void play2all(string samp)
1261 {
1262         sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1263 }
1264
1265 void PrecachePlayerSounds(string f);
1266 void precache_all_models(string pattern)
1267 {
1268         float globhandle, i, n;
1269         string f;
1270
1271         globhandle = search_begin(pattern, TRUE, FALSE);
1272         if(globhandle < 0)
1273                 return;
1274         n = search_getsize(globhandle);
1275         for(i = 0; i < n; ++i)
1276         {
1277                 //print(search_getfilename(globhandle, i), "\n");
1278                 f = search_getfilename(globhandle, i);
1279                 precache_model(f);
1280                 PrecachePlayerSounds(strcat(f, ".sounds"));
1281         }
1282         search_end(globhandle);
1283 }
1284
1285 void precache()
1286 {
1287         // gamemode related things
1288         precache_model ("models/misc/chatbubble.spr");
1289         precache_model ("models/misc/teambubble.spr");
1290         if (g_runematch)
1291         {
1292                 precache_model ("models/runematch/curse.mdl");
1293                 precache_model ("models/runematch/rune.mdl");
1294         }
1295
1296 #ifdef TTURRETS_ENABLED
1297     if(cvar("g_turrets"))
1298         turrets_precash();
1299 #endif
1300
1301         // Precache all player models if desired
1302         if (cvar("sv_precacheplayermodels"))
1303         {
1304                 PrecachePlayerSounds("sound/player/default.sounds");
1305                 precache_all_models("models/player/*.zym");
1306                 precache_all_models("models/player/*.dpm");
1307                 precache_all_models("models/player/*.md3");
1308                 precache_all_models("models/player/*.psk");
1309                 //precache_model("models/player/carni.zym");
1310                 //precache_model("models/player/crash.zym");
1311                 //precache_model("models/player/grunt.zym");
1312                 //precache_model("models/player/headhunter.zym");
1313                 //precache_model("models/player/insurrectionist.zym");
1314                 //precache_model("models/player/jeandarc.zym");
1315                 //precache_model("models/player/lurk.zym");
1316                 //precache_model("models/player/lycanthrope.zym");
1317                 //precache_model("models/player/marine.zym");
1318                 //precache_model("models/player/nexus.zym");
1319                 //precache_model("models/player/pyria.zym");
1320                 //precache_model("models/player/shock.zym");
1321                 //precache_model("models/player/skadi.zym");
1322                 //precache_model("models/player/specop.zym");
1323                 //precache_model("models/player/visitant.zym");
1324         }
1325
1326         if(cvar("sv_defaultcharacter"))
1327         {
1328                 string s;
1329                 s = cvar_string("sv_defaultplayermodel_red");
1330                 if(s != "")
1331                 {
1332                         precache_model(s);
1333                         PrecachePlayerSounds(strcat(s, ".sounds"));
1334                 }
1335                 s = cvar_string("sv_defaultplayermodel_blue");
1336                 if(s != "")
1337                 {
1338                         precache_model(s);
1339                         PrecachePlayerSounds(strcat(s, ".sounds"));
1340                 }
1341                 s = cvar_string("sv_defaultplayermodel_yellow");
1342                 if(s != "")
1343                 {
1344                         precache_model(s);
1345                         PrecachePlayerSounds(strcat(s, ".sounds"));
1346                 }
1347                 s = cvar_string("sv_defaultplayermodel_pink");
1348                 if(s != "")
1349                 {
1350                         precache_model(s);
1351                         PrecachePlayerSounds(strcat(s, ".sounds"));
1352                 }
1353                 s = cvar_string("sv_defaultplayermodel");
1354                 if(s != "")
1355                 {
1356                         precache_model(s);
1357                         PrecachePlayerSounds(strcat(s, ".sounds"));
1358                 }
1359         }
1360
1361         if (g_footsteps)
1362         {
1363                 PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1364                 PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1365         }
1366
1367         // gore and miscellaneous sounds
1368         //precache_sound ("misc/h2ohit.wav");
1369         precache_model ("models/hook.md3");
1370         precache_sound ("misc/armorimpact.wav");
1371         precache_sound ("misc/bodyimpact1.wav");
1372         precache_sound ("misc/bodyimpact2.wav");
1373         precache_sound ("misc/gib.wav");
1374         precache_sound ("misc/gib_splat01.wav");
1375         precache_sound ("misc/gib_splat02.wav");
1376         precache_sound ("misc/gib_splat03.wav");
1377         precache_sound ("misc/gib_splat04.wav");
1378         precache_sound ("misc/hit.wav");
1379         PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1380         PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1381         precache_sound ("misc/null.wav");
1382         precache_sound ("misc/spawn.wav");
1383         precache_sound ("misc/talk.wav");
1384         precache_sound ("misc/teleport.wav");
1385         precache_sound ("player/lava.wav");
1386         precache_sound ("player/slime.wav");
1387
1388         if(g_jetpack)
1389                 precache_sound ("misc/jetpack_fly.wav");
1390
1391         // announcer sounds - male
1392         precache_sound ("announcer/male/electrobitch.wav");
1393         precache_sound ("announcer/male/airshot.wav");
1394         precache_sound ("announcer/male/03kills.wav");
1395         precache_sound ("announcer/male/05kills.wav");
1396         precache_sound ("announcer/male/10kills.wav");
1397         precache_sound ("announcer/male/15kills.wav");
1398         precache_sound ("announcer/male/20kills.wav");
1399         precache_sound ("announcer/male/25kills.wav");
1400         precache_sound ("announcer/male/30kills.wav");
1401         precache_sound ("announcer/male/botlike.wav");
1402         precache_sound ("announcer/male/yoda.wav");
1403         precache_sound ("announcer/male/headshot.wav");
1404         precache_sound ("announcer/male/impressive.wav");
1405
1406         // announcer sounds - robotic
1407         precache_sound ("announcer/robotic/prepareforbattle.wav");
1408         precache_sound ("announcer/robotic/begin.wav");
1409         precache_sound ("announcer/robotic/timeoutcalled.wav");
1410         precache_sound ("announcer/robotic/1fragleft.wav");
1411         precache_sound ("announcer/robotic/1minuteremains.wav");
1412         precache_sound ("announcer/robotic/2fragsleft.wav");
1413         precache_sound ("announcer/robotic/3fragsleft.wav");
1414         if (g_minstagib)
1415         {
1416                 precache_sound ("announcer/robotic/lastsecond.wav");
1417                 precache_sound ("announcer/robotic/narrowly.wav");
1418         }
1419
1420         precache_model ("models/sprites/1.spr32");
1421         precache_model ("models/sprites/2.spr32");
1422         precache_model ("models/sprites/3.spr32");
1423         precache_model ("models/sprites/4.spr32");
1424         precache_model ("models/sprites/5.spr32");
1425         precache_model ("models/sprites/6.spr32");
1426         precache_model ("models/sprites/7.spr32");
1427         precache_model ("models/sprites/8.spr32");
1428         precache_model ("models/sprites/9.spr32");
1429         precache_model ("models/sprites/10.spr32");
1430         precache_sound ("announcer/robotic/1.wav");
1431         precache_sound ("announcer/robotic/2.wav");
1432         precache_sound ("announcer/robotic/3.wav");
1433         precache_sound ("announcer/robotic/4.wav");
1434         precache_sound ("announcer/robotic/5.wav");
1435         precache_sound ("announcer/robotic/6.wav");
1436         precache_sound ("announcer/robotic/7.wav");
1437         precache_sound ("announcer/robotic/8.wav");
1438         precache_sound ("announcer/robotic/9.wav");
1439         precache_sound ("announcer/robotic/10.wav");
1440
1441         // common weapon precaches
1442         precache_sound ("weapons/weapon_switch.wav");
1443         precache_sound ("weapons/weaponpickup.wav");
1444         if(g_grappling_hook)
1445         {
1446                 precache_sound ("weapons/hook_fire.wav"); // hook
1447                 precache_sound ("weapons/hook_impact.wav"); // hook
1448         }
1449
1450         if (cvar("sv_precacheweapons") || g_nixnex)
1451         {
1452                 //precache weapon models/sounds
1453                 local float wep;
1454                 wep = WEP_FIRST;
1455                 while (wep <= WEP_LAST)
1456                 {
1457                         weapon_action(wep, WR_PRECACHE);
1458                         wep = wep + 1;
1459                 }
1460         }
1461
1462         precache_model("models/elaser.mdl");
1463         precache_model("models/laser.mdl");
1464         precache_model("models/ebomb.mdl");
1465
1466 #if 0
1467         // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1468
1469         if (!self.noise && self.music) // quake 3 uses the music field
1470                 self.noise = self.music;
1471
1472         // plays music for the level if there is any
1473         if (self.noise)
1474         {
1475                 precache_sound (self.noise);
1476                 ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1477         }
1478 #endif
1479 }
1480
1481 // sorry, but using \ in macros breaks line numbers
1482 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1483 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1484 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1485
1486 vector ExactTriggerHit_mins;
1487 vector ExactTriggerHit_maxs;
1488 float ExactTriggerHit_Recurse()
1489 {
1490         float s;
1491         entity se;
1492         float f;
1493
1494         tracebox('0 0 0', ExactTriggerHit_mins, ExactTriggerHit_maxs, '0 0 0', MOVE_NORMAL, other);
1495         if not(trace_ent)
1496                 return 0;
1497         if(trace_ent == self)
1498                 return 1;
1499
1500         se = trace_ent;
1501         s = se.solid;
1502         se.solid = SOLID_NOT;
1503         f = ExactTriggerHit_Recurse();
1504         se.solid = s;
1505
1506         return f;
1507 }
1508
1509 float ExactTriggerHit()
1510 {
1511         float f, s;
1512
1513         if not(self.modelindex)
1514                 return 1;
1515
1516         s = self.solid;
1517         self.solid = SOLID_BSP;
1518         ExactTriggerHit_mins = other.absmin;
1519         ExactTriggerHit_maxs = other.absmax;
1520         f = ExactTriggerHit_Recurse();
1521         self.solid = s;
1522
1523         return f;
1524 }
1525
1526 // WARNING: this kills the trace globals
1527 #define EXACTTRIGGER_TOUCH if not(ExactTriggerHit()) return
1528 #define EXACTTRIGGER_INIT  InitSolidBSPTrigger(); self.solid = SOLID_TRIGGER
1529
1530 #define INITPRIO_FIRST              0
1531 #define INITPRIO_GAMETYPE           0
1532 #define INITPRIO_GAMETYPE_FALLBACK  1
1533 #define INITPRIO_CVARS              5
1534 #define INITPRIO_FINDTARGET        10
1535 #define INITPRIO_DROPTOFLOOR       20
1536 #define INITPRIO_SETLOCATION       90
1537 #define INITPRIO_LINKDOORS         91
1538 #define INITPRIO_LAST              99
1539
1540 .void(void) initialize_entity;
1541 .float initialize_entity_order;
1542 .entity initialize_entity_next;
1543 entity initialize_entity_first;
1544
1545 void make_safe_for_remove(entity e)
1546 {
1547         if(e.initialize_entity)
1548         {
1549                 entity ent, prev;
1550                 for(ent = initialize_entity_first; ent; )
1551                 {
1552                         if((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1553                         {
1554                                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1555                                 // skip it in linked list
1556                                 if(prev)
1557                                 {
1558                                         prev.initialize_entity_next = ent.initialize_entity_next;
1559                                         ent = prev.initialize_entity_next;
1560                                 }
1561                                 else
1562                                 {
1563                                         initialize_entity_first = ent.initialize_entity_next;
1564                                         ent = initialize_entity_first;
1565                                 }
1566                         }
1567                         else
1568                         {
1569                                 prev = ent;
1570                                 ent = ent.initialize_entity_next;
1571                         }
1572                 }
1573         }
1574 }
1575
1576 void objerror(string s)
1577 {
1578         make_safe_for_remove(self);
1579         objerror_builtin(s);
1580 }
1581
1582 void remove_unsafely(entity e)
1583 {
1584         remove_builtin(e);
1585 }
1586
1587 void remove_safely(entity e)
1588 {
1589         make_safe_for_remove(e);
1590         remove_builtin(e);
1591 }
1592
1593 void InitializeEntity(entity e, void(void) func, float order)
1594 {
1595         entity prev, cur;
1596
1597         if(!e || e.initialize_entity)
1598         {
1599                 // make a proxy initializer entity
1600                 entity e_old;
1601                 e_old = e;
1602                 e = spawn();
1603                 e.classname = "initialize_entity";
1604                 e.enemy = e_old;
1605         }
1606
1607         e.initialize_entity = func;
1608         e.initialize_entity_order = order;
1609
1610         cur = initialize_entity_first;
1611         for(;;)
1612         {
1613                 if(!cur || cur.initialize_entity_order > order)
1614                 {
1615                         // insert between prev and cur
1616                         if(prev)
1617                                 prev.initialize_entity_next = e;
1618                         else
1619                                 initialize_entity_first = e;
1620                         e.initialize_entity_next = cur;
1621                         return;
1622                 }
1623                 prev = cur;
1624                 cur = cur.initialize_entity_next;
1625         }
1626 }
1627 void InitializeEntitiesRun()
1628 {
1629         entity startoflist;
1630         startoflist = initialize_entity_first;
1631         initialize_entity_first = world;
1632         for(self = startoflist; self; )
1633         {
1634                 entity e;
1635                 var void(void) func;
1636                 e = self.initialize_entity_next;
1637                 func = self.initialize_entity;
1638                 self.initialize_entity_order = 0;
1639                 self.initialize_entity = func_null;
1640                 self.initialize_entity_next = world;
1641                 if(self.classname == "initialize_entity")
1642                 {
1643                         entity e_old;
1644                         e_old = self.enemy;
1645                         remove_builtin(self);
1646                         self = e_old;
1647                 }
1648                 //dprint("Delayed initialization: ", self.classname, "\n");
1649                 func();
1650                 self = e;
1651         }
1652 }
1653
1654 .float uncustomizeentityforclient_set;
1655 .void(void) uncustomizeentityforclient;
1656 void(void) SUB_Nullpointer = #0;
1657 void UncustomizeEntitiesRun()
1658 {
1659         entity oldself;
1660         oldself = self;
1661         for(self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1662                 self.uncustomizeentityforclient();
1663         self = oldself;
1664 }
1665 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1666 {
1667         e.customizeentityforclient = customizer;
1668         e.uncustomizeentityforclient = uncustomizer;
1669         e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1670 }
1671
1672 .float nottargeted;
1673 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1674
1675 void() SUB_Remove;
1676 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1677 {
1678         vector mi, ma;
1679
1680         if(e.classname == "")
1681                 e.classname = "net_linked";
1682
1683         if(e.model == "" || self.modelindex == 0)
1684         {
1685                 mi = e.mins;
1686                 ma = e.maxs;
1687                 setmodel(e, "null");
1688                 setsize(e, mi, ma);
1689         }
1690
1691         e.SendEntity = sendfunc;
1692         e.SendFlags = 0xFFFFFF;
1693
1694         if(!docull)
1695                 e.effects |= EF_NODEPTHTEST;
1696
1697         if(dt)
1698         {
1699                 e.nextthink = time + dt;
1700                 e.think = SUB_Remove;
1701         }
1702 }
1703
1704 void adaptor_think2touch()
1705 {
1706         entity o;
1707         o = other;
1708         other = world;
1709         self.touch();
1710         other = o;
1711 }
1712
1713 void adaptor_think2use()
1714 {
1715         entity o, a;
1716         o = other;
1717         a = activator;
1718         activator = world;
1719         other = world;
1720         self.use();
1721         other = o;
1722         activator = a;
1723 }
1724
1725 // deferred dropping
1726 void DropToFloor_Handler()
1727 {
1728         droptofloor_builtin();
1729         self.dropped_origin = self.origin;
1730 }
1731
1732 void droptofloor()
1733 {
1734         InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1735 }
1736
1737
1738
1739 float trace_hits_box_a0, trace_hits_box_a1;
1740
1741 float trace_hits_box_1d(float end, float thmi, float thma)
1742 {
1743         if(end == 0)
1744         {
1745                 // just check if x is in range
1746                 if(0 < thmi)
1747                         return FALSE;
1748                 if(0 > thma)
1749                         return FALSE;
1750         }
1751         else
1752         {
1753                 // do the trace with respect to x
1754                 // 0 -> end has to stay in thmi -> thma
1755                 trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1756                 trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1757                 if(trace_hits_box_a0 > trace_hits_box_a1)
1758                         return FALSE;
1759         }
1760         return TRUE;
1761 }
1762
1763 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1764 {
1765         end -= start;
1766         thmi -= start;
1767         thma -= start;
1768         // now it is a trace from 0 to end
1769
1770         trace_hits_box_a0 = 0;
1771         trace_hits_box_a1 = 1;
1772
1773         if(!trace_hits_box_1d(end_x, thmi_x, thma_x))
1774                 return FALSE;
1775         if(!trace_hits_box_1d(end_y, thmi_y, thma_y))
1776                 return FALSE;
1777         if(!trace_hits_box_1d(end_z, thmi_z, thma_z))
1778                 return FALSE;
1779
1780         return TRUE;
1781 }
1782
1783 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1784 {
1785         return trace_hits_box(start, end, thmi - ma, thma - mi);
1786 }
1787
1788 float SUB_NoImpactCheck()
1789 {
1790         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1791                 return 1;
1792         if(other == world && self.size != '0 0 0')
1793         {
1794                 vector tic;
1795                 tic = self.velocity * sys_ticrate;
1796                 tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1797                 traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1798                 if(trace_fraction >= 1)
1799                 {
1800                         dprint("Odd... did not hit...?\n");
1801                 }
1802                 else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1803                 {
1804                         dprint("Detected and prevented the sky-grapple bug.\n");
1805                         return 1;
1806                 }
1807         }
1808
1809         return 0;
1810 }
1811
1812 #define SUB_OwnerCheck() (other && (other == self.owner))
1813
1814 #define PROJECTILE_TOUCH do { if(SUB_OwnerCheck()) return; if(SUB_NoImpactCheck()) { remove(self); return; } if(trace_ent && trace_ent.solid > SOLID_TRIGGER) UpdateCSQCProjectileNextFrame(self); } while(0)
1815
1816 float MAX_IPBAN_URIS = 16;
1817
1818 float URI_GET_DISCARD   = 0;
1819 float URI_GET_IPBAN     = 1;
1820 float URI_GET_IPBAN_END = 16;
1821
1822 void URI_Get_Callback(float id, float status, string data)
1823 {
1824         dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is\n:");
1825         dprint(data);
1826         dprint("\nEnd of data.\n");
1827
1828         if(id == URI_GET_DISCARD)
1829         {
1830                 // discard
1831         }
1832         else if(id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1833         {
1834                 // online ban list
1835                 OnlineBanList_URI_Get_Callback(id, status, data);
1836         }
1837         else
1838         {
1839                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1840         }
1841 }
1842
1843 void print_to(entity e, string s)
1844 {
1845         if(e)
1846                 sprint(e, strcat(s, "\n"));
1847         else
1848                 print(s, "\n");
1849 }
1850
1851 string getrecords()
1852 {
1853         float rec;
1854         string h;
1855         float r;
1856         float i;
1857         string s;
1858
1859         rec = 0;
1860
1861         s = "";
1862
1863         if(g_ctf)
1864         {
1865                 for(i = 0; i < MapInfo_count; ++i)
1866                 {
1867                         if(MapInfo_Get_ByID(i))
1868                         {
1869                                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
1870                                 if(r == 0)
1871                                         continue;
1872                                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
1873                                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
1874                                 ++rec;
1875                         }
1876                 }
1877         }
1878
1879         if(g_race)
1880         {
1881                 for(i = 0; i < MapInfo_count; ++i)
1882                 {
1883                         if(MapInfo_Get_ByID(i))
1884                         {
1885                                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/racerecord/time")));
1886                                 if(r == 0)
1887                                         continue;
1888                                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/racerecord/netname"));
1889                                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, mmsss(r)), " ", h, "\n");
1890                                 ++rec;
1891                         }
1892                 }
1893         }
1894         MapInfo_ClearTemps();
1895
1896         if(s == "")
1897                 return "No records are available on this server.\n";
1898         else
1899                 return strcat("Records on this server:\n", s);
1900 }
1901
1902 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1903 {
1904         float m, i;
1905         vector start, org, delta, end, enddown, mstart;
1906
1907         m = e.dphitcontentsmask;
1908         e.dphitcontentsmask = goodcontents | badcontents;
1909
1910         org = world.mins;
1911         delta = world.maxs - world.mins;
1912
1913         for(i = 0; i < attempts; ++i)
1914         {
1915                 start_x = org_x + random() * delta_x;
1916                 start_y = org_y + random() * delta_y;
1917                 start_z = org_z + random() * delta_z;
1918
1919                 // rule 1: start inside world bounds, and outside
1920                 // solid, and don't start from somewhere where you can
1921                 // fall down to evil
1922                 tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1923                 if(trace_fraction >= 1)
1924                         continue;
1925                 if(trace_startsolid)
1926                         continue;
1927                 if(trace_dphitcontents & badcontents)
1928                         continue;
1929                 if(trace_dphitq3surfaceflags & badsurfaceflags)
1930                         continue;
1931
1932                 // rule 2: if we are too high, lower the point
1933                 if(trace_fraction * delta_z > maxaboveground)
1934                         start = trace_endpos + '0 0 1' * maxaboveground;
1935                 enddown = trace_endpos;
1936
1937                 // rule 3: make sure we aren't outside the map. This only works
1938                 // for somewhat well formed maps. A good rule of thumb is that
1939                 // the map should have a convex outside hull.
1940                 // these can be traceLINES as we already verified the starting box
1941                 mstart = start + 0.5 * (e.mins + e.maxs);
1942                 traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1943                 if(trace_fraction >= 1)
1944                         continue;
1945                 traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1946                 if(trace_fraction >= 1)
1947                         continue;
1948                 traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1949                 if(trace_fraction >= 1)
1950                         continue;
1951                 traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1952                 if(trace_fraction >= 1)
1953                         continue;
1954                 traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1955                 if(trace_fraction >= 1)
1956                         continue;
1957
1958                 // find a random vector to "look at"
1959                 end_x = org_x + random() * delta_x;
1960                 end_y = org_y + random() * delta_y;
1961                 end_z = org_z + random() * delta_z;
1962                 end = start + normalize(end - start) * vlen(delta);
1963
1964                 // rule 4: start TO end must not be too short
1965                 tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1966                 if(trace_startsolid)
1967                         continue;
1968                 if(trace_fraction < minviewdistance / vlen(delta))
1969                         continue;
1970
1971                 // rule 5: don't want to look at sky
1972                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1973                         continue;
1974
1975                 // rule 6: we must not end up in trigger_hurt
1976                 if(tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1977                 {
1978                         dprint("trigger_hurt! ouch! and nothing else could find it!\n");
1979                         continue;
1980                 }
1981
1982                 break;
1983         }
1984
1985         e.dphitcontentsmask = m;
1986
1987         if(i < attempts)
1988         {
1989                 setorigin(e, start);
1990                 e.angles = vectoangles(end - start);
1991                 dprint("Needed ", ftos(i + 1), " attempts\n");
1992                 return TRUE;
1993         }
1994         else
1995                 return FALSE;
1996 }
1997
1998 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
1999 {
2000         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
2001         WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
2002         WriteShort(MSG_BROADCAST, effectno);
2003         WriteCoord(MSG_BROADCAST, start_x);
2004         WriteCoord(MSG_BROADCAST, start_y);
2005         WriteCoord(MSG_BROADCAST, start_z);
2006         WriteCoord(MSG_BROADCAST, end_x);
2007         WriteCoord(MSG_BROADCAST, end_y);
2008         WriteCoord(MSG_BROADCAST, end_z);
2009         WriteCoord(MSG_BROADCAST, end_dz);
2010         WriteShort(MSG_BROADCAST, spd / 16);
2011 }
2012
2013 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2014 {
2015         float end_dz;
2016         vector vecxy, velxy;
2017
2018         vecxy = end - start; vecxy_z = 0;
2019         velxy = vel;         velxy_z = 0;
2020
2021         if(vlen(velxy) < 0.000001 * fabs(vel_z))
2022         {
2023                 trailparticles(world, effectno, start, end);
2024                 return;
2025         }
2026
2027         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2028         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2029 }
2030
2031 string GetGametype(); // g_world.qc
2032 void write_recordmarker(entity pl, float tstart, float dt)
2033 {
2034         GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt / 10)));
2035
2036         // also write a marker into demo files for demotc-race-record-extractor to find
2037         stuffcmd(pl,
2038                 strcat(
2039                         strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", mmsss(dt * 10)),
2040                         " ", ftos(tstart), " ", ftos(dt), "\n"));
2041 }
2042
2043 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2044 {
2045         string s;
2046         vector v;
2047         if (cvar("g_shootfromeye"))
2048         {
2049                 if(visual)
2050                 {
2051                         vecs_y = 0;
2052                         vecs_z -= 4;
2053                 }
2054                 else
2055                 {
2056                         vecs_y = 0;
2057                         vecs_z = 0;
2058                 }
2059         }
2060         else if (cvar("g_shootfromcenter"))
2061         {
2062                 vecs_y = 0;
2063                 vecs_z -= 4;
2064         }
2065         else if((s = cvar_string("g_shootfromfixedorigin")) != "")
2066         {
2067                 v = stov(s);
2068                 if(y_is_right)
2069                         v_y = -v_y;
2070                 if(v_x != 0)
2071                         vecs_x = v_x;
2072                 vecs_y = v_y;
2073                 vecs_z = v_z;
2074         }
2075         return vecs;
2076 }
2077
2078
2079
2080 void attach_sameorigin(entity e, entity to, string tag)
2081 {
2082         vector org, t_forward, t_left, t_up, e_forward, e_up;
2083         vector org0, ang0;
2084         float tagscale;
2085
2086         ang0 = e.angles;
2087         org0 = e.origin;
2088
2089         org = e.origin - gettaginfo(to, gettagindex(to, tag));
2090         tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2091         t_forward = v_forward * tagscale;
2092         t_left = v_right * -tagscale;
2093         t_up = v_up * tagscale;
2094
2095         e.origin_x = org * t_forward;
2096         e.origin_y = org * t_left;
2097         e.origin_z = org * t_up;
2098
2099         // current forward and up directions
2100         if(substring(e.model, 0, 1) == "*") // bmodels have their own rules
2101                 e.angles_x = -e.angles_x;
2102         fixedmakevectors(e.angles);
2103
2104         // untransform forward, up!
2105         e_forward_x = v_forward * t_forward;
2106         e_forward_y = v_forward * t_left;
2107         e_forward_z = v_forward * t_up;
2108         e_up_x = v_up * t_forward;
2109         e_up_y = v_up * t_left;
2110         e_up_z = v_up * t_up;
2111
2112         e.angles = fixedvectoangles2(e_forward, e_up);
2113         if(substring(e.model, 0, 1) == "*") // bmodels have their own rules
2114                 e.angles_x = -e.angles_x;
2115
2116         setattachment(e, to, tag);
2117         setorigin(e, e.origin);
2118 }
2119
2120 void detach_sameorigin(entity e)
2121 {
2122         vector org;
2123         org = gettaginfo(e, 0);
2124         e.angles = fixedvectoangles2(v_forward, v_up);
2125         if(substring(e.model, 0, 1) == "*") // bmodels have their own rules
2126                 e.angles_x = -e.angles_x;
2127         e.origin = org;
2128         setattachment(e, world, "");
2129         setorigin(e, e.origin);
2130 }
2131
2132 void follow_sameorigin(entity e, entity to)
2133 {
2134         e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2135         e.aiment = to; // make the hole follow bmodel
2136         e.punchangle = to.angles; // the original angles of bmodel
2137         e.view_ofs = e.origin - to.origin; // relative origin
2138         e.v_angle = e.angles - to.angles; // relative angles
2139 }
2140
2141 void unfollow_sameorigin(entity e)
2142 {
2143         e.movetype = MOVETYPE_NONE;
2144 }
2145
2146 entity gettaginfo_relative_ent;
2147 vector gettaginfo_relative(entity e, float tag)
2148 {
2149         if(!gettaginfo_relative_ent)
2150         {
2151                 gettaginfo_relative_ent = spawn();
2152                 gettaginfo_relative_ent.effects = EF_NODRAW;
2153         }
2154         gettaginfo_relative_ent.model = e.model;
2155         gettaginfo_relative_ent.modelindex = e.modelindex;
2156         gettaginfo_relative_ent.frame = e.frame;
2157         return gettaginfo(gettaginfo_relative_ent, tag);
2158 }
2159
2160 void SoundEntity_StartSound(entity pl, float chan, string samp, float vol, float attn)
2161 {
2162         float p;
2163         p = pow(2, chan);
2164         if(pl.soundentity.cnt & p)
2165                 return;
2166         soundtoat(MSG_ALL, pl.soundentity, gettaginfo(pl.soundentity, 0), chan, samp, vol, attn);
2167         pl.soundentity.cnt |= p;
2168 }
2169
2170 void SoundEntity_StopSound(entity pl, float chan)
2171 {
2172         float p;
2173         p = pow(2, chan);
2174         if(pl.soundentity.cnt & p)
2175         {
2176                 stopsoundto(MSG_ALL, pl.soundentity, chan);
2177                 pl.soundentity.cnt &~= p;
2178         }
2179 }
2180
2181 void SoundEntity_Attach(entity pl)
2182 {
2183         pl.soundentity = spawn();
2184         pl.soundentity.classname = "soundentity";
2185         setattachment(pl.soundentity, pl, "");
2186         setmodel(pl.soundentity, "null");
2187 }
2188
2189 void SoundEntity_Detach(entity pl)
2190 {
2191         float i;
2192         for(i = 0; i <= 7; ++i)
2193                 SoundEntity_StopSound(pl, i);
2194 }