Make bots use the #~½¬&<hr>·@!Tuba if available ;)
[divverent/nexuiz.git] / data / qcsrc / server / havocbot.qc
1 .void() havocbot_role;
2 void() havocbot_chooserole;
3 .float havocbot_keyboardskill;
4 .float facingwalltime, ignoregoaltime;
5 .entity ignoregoal;
6 .float lastfiredweapon;
7 .float lastcombotime;
8 .float havocbot_blockhead;
9
10 #ifdef DEBUG_BOT_GOALSTACK
11 void debuggoalstack();
12 #endif
13
14 vector havocbot_dodge()
15 {
16         // LordHavoc: disabled because this is too expensive
17         return '0 0 0';
18         /*
19         local entity head;
20         local vector dodge, v, n;
21         local float danger, bestdanger, vl, d;
22         dodge = '0 0 0';
23         bestdanger = -20;
24         // check for dangerous objects near bot or approaching bot
25         head = findchainfloat(bot_dodge, TRUE);
26         while(head)
27         {
28                 if (head.owner != self)
29                 {
30                         vl = vlen(head.velocity);
31                         if (vl > sv_maxspeed * 0.3)
32                         {
33                                 n = normalize(head.velocity);
34                                 v = self.origin - head.origin;
35                                 d = v * n;
36                                 if (d > (0 - head.bot_dodgerating))
37                                 if (d < (vl * 0.2 + head.bot_dodgerating))
38                                 {
39                                         // calculate direction and distance from the flight path, by removing the forward axis
40                                         v = v - (n * (v * n));
41                                         danger = head.bot_dodgerating - vlen(v);
42                                         if (bestdanger < danger)
43                                         {
44                                                 bestdanger = danger;
45                                                 // dodge to the side of the object
46                                                 dodge = normalize(v);
47                                         }
48                                 }
49                         }
50                         else
51                         {
52                                 danger = head.bot_dodgerating - vlen(head.origin - self.origin);
53                                 if (bestdanger < danger)
54                                 {
55                                         bestdanger = danger;
56                                         dodge = normalize(self.origin - head.origin);
57                                 }
58                         }
59                 }
60                 head = head.chain;
61         }
62         return dodge;
63         */
64 };
65
66 .float havocbot_keyboardtime;
67 .float havocbot_ducktime;
68 .vector havocbot_keyboard;
69 void havocbot_keyboard_movement(vector destorg)
70 {
71         local vector keyboard;
72         local float blend, maxspeed;
73
74         maxspeed = cvar("sv_maxspeed");
75
76         if (time < self.havocbot_keyboardtime)
77                 return;
78
79         self.havocbot_keyboardtime =
80                 max(
81                         self.havocbot_keyboardtime
82                                 + bound(0,0.05/(skill+self.havocbot_keyboardskill),0.05)
83                                 +random()*bound(0,0.025/(skill+self.havocbot_keyboardskill),100)
84                 , time);
85         keyboard = self.movement * (1.0 / maxspeed);
86
87         local float trigger, trigger1;
88         blend = bound(0,skill*0.1,1);
89         trigger = cvar("bot_ai_keyboard_treshold");
90         trigger1 = 0 - trigger;
91
92         // categorize forward movement
93         // at skill < 1.5 only forward
94         // at skill < 2.5 only individual directions
95         // at skill < 4.5 only individual directions, and forward diagonals
96         // at skill >= 4.5, all cases allowed
97         if (keyboard_x > trigger)
98         {
99                 keyboard_x = 1;
100                 if (skill < 2.5)
101                         keyboard_y = 0;
102         }
103         else if (keyboard_x < trigger1 && skill > 1.5)
104         {
105                 keyboard_x = -1;
106                 if (skill < 4.5)
107                         keyboard_y = 0;
108         }
109         else
110         {
111                 keyboard_x = 0;
112                 if (skill < 1.5)
113                         keyboard_y = 0;
114         }
115         if (skill < 4.5)
116                 keyboard_z = 0;
117
118         if (keyboard_y > trigger)
119                 keyboard_y = 1;
120         else if (keyboard_y < trigger1)
121                 keyboard_y = -1;
122         else
123                 keyboard_y = 0;
124
125         if (keyboard_z > trigger)
126                 keyboard_z = 1;
127         else if (keyboard_z < trigger1)
128                 keyboard_z = -1;
129         else
130                 keyboard_z = 0;
131
132         self.havocbot_keyboard = keyboard * maxspeed;
133         if (self.havocbot_ducktime>time) self.BUTTON_CROUCH=TRUE;
134
135         keyboard = self.havocbot_keyboard;
136         blend = bound(0,vlen(destorg-self.origin)/cvar("bot_ai_keyboard_distance"),1); // When getting close move with 360 degree
137         //dprint("movement ", vtos(self.movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
138         self.movement = self.movement + (keyboard - self.movement) * blend;
139 };
140
141 .entity bot_lastseengoal;
142 .float bot_timelastseengoal;
143 .float bot_canruntogoal;
144 void havocbot_bunnyhop(vector dir)
145 {
146         local float bunnyhopdistance;
147         local vector deviation;
148         local float maxspeed;
149
150         if(cvar("g_midair"))
151                 return;
152
153         if(self.goalcurrent.classname == "player")
154                 return;
155
156         maxspeed = cvar("sv_maxspeed");
157
158         if(self.aistatus & AI_STATUS_DANGER_AHEAD)
159         {
160                 self.aistatus &~= AI_STATUS_RUNNING;
161                 self.BUTTON_JUMP = FALSE;
162                 self.bot_canruntogoal = 0;
163                 self.bot_timelastseengoal = 0;
164                 return;
165         }
166
167         if(self.waterlevel > WATERLEVEL_WETFEET)
168         {
169                 self.aistatus &~= AI_STATUS_RUNNING;
170                 return;
171         }
172
173         if(self.bot_lastseengoal != self.goalcurrent && !(self.aistatus & AI_STATUS_RUNNING))
174         {
175                 self.bot_canruntogoal = 0;
176                 self.bot_timelastseengoal = 0;
177         }
178
179         bunnyhopdistance = vlen(self.origin - self.goalcurrent.origin);
180
181         // Run only to visible goals
182         if(self.flags & FL_ONGROUND)
183         if(self.speed==maxspeed)
184         if(checkpvs(self.origin + self.view_ofs, self.goalcurrent))
185         {
186                         self.bot_lastseengoal = self.goalcurrent;
187
188                         // seen it before
189                         if(self.bot_timelastseengoal)
190                         {
191                                 // for a period of time
192                                 if(time - self.bot_timelastseengoal > cvar("bot_ai_bunnyhop_firstjumpdelay"))
193                                 {
194                                         local float checkdistance;
195                                         checkdistance = TRUE;
196
197                                         // don't run if it is too close
198                                         if(self.bot_canruntogoal==0)
199                                         {
200                                                 if(bunnyhopdistance > cvar("bot_ai_bunnyhop_startdistance"))
201                                                         self.bot_canruntogoal = 1;
202                                                 else
203                                                         self.bot_canruntogoal = -1;
204                                         }
205
206                                         if(self.bot_canruntogoal != 1)
207                                                 return;
208
209                                         if(self.aistatus & AI_STATUS_ROAMING)
210                                         if(self.goalcurrent.classname=="waypoint")
211                                         if not(self.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL)
212                                         if(fabs(self.goalcurrent.origin_z - self.origin_z) < self.maxs_z - self.mins_z)
213                                         if(self.goalstack01!=world)
214                                         {
215                                                 deviation = vectoangles(self.goalstack01.origin - self.origin) - vectoangles(self.goalcurrent.origin - self.origin);
216                                                 while (deviation_y < -180) deviation_y = deviation_y + 360;
217                                                 while (deviation_y > 180) deviation_y = deviation_y - 360;
218
219                                                 if(fabs(deviation_y) < 20)
220                                                 if(bunnyhopdistance < vlen(self.origin - self.goalstack01.origin))
221                                                 if(fabs(self.goalstack01.origin_z - self.goalcurrent.origin_z) < self.maxs_z - self.mins_z)
222                                                 {
223                                                         if(vlen(self.goalcurrent.origin - self.goalstack01.origin) > cvar("bot_ai_bunnyhop_startdistance"))
224                                                         if(checkpvs(self.origin + self.view_ofs, self.goalstack01))
225                                                         {
226                                                                 checkdistance = FALSE;
227                                                         }
228                                                 }
229                                         }
230
231                                         if(checkdistance)
232                                         {
233                                                 self.aistatus &~= AI_STATUS_RUNNING;
234                                                 if(bunnyhopdistance > cvar("bot_ai_bunnyhop_stopdistance"))
235                                                         self.BUTTON_JUMP = TRUE;
236                                         }
237                                         else
238                                         {
239                                                 self.aistatus |= AI_STATUS_RUNNING;
240                                                 self.BUTTON_JUMP = TRUE;
241                                         }
242                                 }
243                         }
244                         else
245                         {
246                                 self.bot_timelastseengoal = time;
247                         }
248         }
249         else
250         {
251                 self.bot_timelastseengoal = 0;
252         }
253
254         // Release jump button
255         if(self.flags & FL_ONGROUND == 0)
256         {
257                 if(self.velocity_z < 0 || vlen(self.velocity)<maxspeed)
258                         self.BUTTON_JUMP = FALSE;
259
260                 // Strafe
261                 if(self.aistatus & AI_STATUS_RUNNING)
262                 if(vlen(self.velocity)>maxspeed)
263                 {
264                         deviation = vectoangles(dir) - vectoangles(self.velocity);
265                         while (deviation_y < -180) deviation_y = deviation_y + 360;
266                         while (deviation_y > 180) deviation_y = deviation_y - 360;
267
268                         if(fabs(deviation_y)>10)
269                                 self.movement_x = 0;
270
271                         if(deviation_y>10)
272                                 self.movement_y = maxspeed * -1;
273                         else if(deviation_y<10)
274                                 self.movement_y = maxspeed;
275
276                 }
277         }
278 };
279
280 //.float havocbotignoretime;
281 //.vector bot_dodgevector;
282 //.float bot_dodgevector_time;
283 //.float bot_dodgevector_jumpbutton;
284 .float ladder_time;
285 .entity ladder_entity;
286 .float rocketjumptime;
287 void havocbot_movetogoal()
288 {
289         local vector destorg;
290         local vector diff;
291         local vector dir;
292         local vector flatdir;
293         local vector m1;
294         local vector m2;
295         local vector evadeobstacle;
296         local vector evadelava;
297         local float s;
298         local float maxspeed;
299         //local float dist;
300         local vector dodge;
301         //if (self.goalentity)
302         //      te_lightning2(self, self.origin, (self.goalentity.absmin + self.goalentity.absmax) * 0.5);
303         self.movement = '0 0 0';
304         maxspeed = cvar("sv_maxspeed");
305
306         if(self.jumppadcount)
307         {
308                 if(self.flags & FL_ONGROUND)
309                 {
310                         self.jumppadcount = FALSE;
311                         if(self.aistatus & AI_STATUS_OUT_JUMPPAD)
312                                 self.aistatus &~= AI_STATUS_OUT_JUMPPAD;
313                 }
314
315                 // If got stuck on the jump pad try to reach the farther visible item
316                 if(self.aistatus & AI_STATUS_OUT_JUMPPAD)
317                 {
318                         if(fabs(self.velocity_z)<50)
319                         {
320                                 local entity head, newgoal;
321                                 local float distance, bestdistance;
322
323                                 for (head = findchainfloat(bot_pickup, TRUE); head; head = head.chain)
324                                 {
325                                         if(head.classname=="worldspawn")
326                                                 continue;
327
328                                         distance = vlen(head.origin - self.origin);
329                                         if(distance>1000)
330                                                 continue;
331
332                                         traceline(self.origin + self.view_ofs , head.origin, TRUE, world);
333
334                                         if(trace_fraction<1)
335                                                 continue;
336
337                                         if(distance>bestdistance)
338                                         {
339                                                 newgoal = head;
340                                                 bestdistance = distance;
341                                         }
342                                 }
343
344                                 if(newgoal)
345                                 {
346                                         self.ignoregoal = self.goalcurrent;
347                                         self.ignoregoaltime = time + cvar("bot_ai_ignoregoal_timeout");
348                                         navigation_clearroute();
349                                         navigation_routetogoal(newgoal, self.origin);
350                                         self.aistatus &~= AI_STATUS_OUT_JUMPPAD;
351                                 }
352                         }
353                         else
354                                 return;
355                 }
356                 else
357                 {
358                         if(self.velocity_z>0)
359                         {
360                                 local float threshold;
361                                 threshold = maxspeed * 0.2;
362                                 if(fabs(self.velocity_x) < threshold  &&  fabs(self.velocity_y) < threshold)
363                                         self.aistatus |= AI_STATUS_OUT_JUMPPAD;
364                                 return;
365                         }
366                 }
367         }
368
369         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
370         if(skill>6)
371         if not(self.flags & FL_ONGROUND)
372         {
373                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 -65536', MOVE_NOMONSTERS, self);
374                 if(tracebox_hits_trigger_hurt(self.origin, self.mins, self.maxs, trace_endpos ))
375                 if(self.items & IT_JETPACK)
376                 {
377                         tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 65536', MOVE_NOMONSTERS, self);
378                         if(tracebox_hits_trigger_hurt(self.origin, self.mins, self.maxs, trace_endpos + '0 0 1' ))
379                         {
380                                 if(self.velocity_z<0)
381                                 {
382                                         self.BUTTON_HOOK = TRUE;
383                                 }
384                         }
385                         else
386                                 self.BUTTON_HOOK = TRUE;
387
388                         // If there is no goal try to move forward
389
390                         if(self.goalcurrent==world)
391                                 dir = v_forward;
392                         else
393                                 dir = normalize(self.goalcurrent.origin - self.origin);
394
395                         local vector xyvelocity = self.velocity; xyvelocity_z = 0;
396                         local float xyspeed = xyvelocity * dir;
397
398                         if(xyspeed < (maxspeed / 2))
399                         {
400                                 makevectors(self.v_angle_y * '0 1 0');
401                                 tracebox(self.origin, self.mins, self.maxs, self.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, self);
402                                 if(trace_fraction==1)
403                                 {
404                                         self.movement_x = dir * v_forward * maxspeed;
405                                         self.movement_y = dir * v_right * maxspeed;
406                                         if (skill < 10)
407                                                 havocbot_keyboard_movement(self.origin + dir * 100);
408                                 }
409                         }
410
411                         self.havocbot_blockhead = TRUE;
412
413                         return;
414                 }
415                 else if(self.health>cvar("g_balance_rocketlauncher_damage")*0.5)
416                 {
417                         if(self.velocity_z < 0)
418                         if(client_hasweapon(self, WEP_ROCKET_LAUNCHER, TRUE, FALSE))
419                         {
420                                 self.movement_x = maxspeed;
421
422                                 if(self.rocketjumptime)
423                                 {
424                                         if(time > self.rocketjumptime)
425                                         {
426                                                 self.BUTTON_ATCK2 = TRUE;
427                                                 self.rocketjumptime = 0;
428                                         }
429                                         return;
430                                 }
431
432                                 self.switchweapon = WEP_ROCKET_LAUNCHER;
433                                 self.v_angle_x = 90;
434                                 self.BUTTON_ATCK = TRUE;
435                                 self.rocketjumptime = time + cvar("g_balance_rocketlauncher_detonatedelay");
436                                 return;
437                         }
438                 }
439                 else
440                 {
441                         // If there is no goal try to move forward
442                         if(self.goalcurrent==world)
443                                 self.movement_x = maxspeed;
444                 }
445         }
446
447         // If we are under water with no goals, swim up
448         if(self.waterlevel)
449         if(self.goalcurrent==world)
450         {
451                 dir = '0 0 0';
452                 if(self.waterlevel>WATERLEVEL_SWIMMING)
453                         dir_z = 1;
454                 else if(self.velocity_z >= 0 && !(self.waterlevel == WATERLEVEL_WETFEET && self.watertype == CONTENT_WATER))
455                         self.BUTTON_JUMP = TRUE;
456                 else
457                         self.BUTTON_JUMP = FALSE;
458                 makevectors(self.v_angle_y * '0 1 0');
459                 self.movement_x = dir * v_forward * maxspeed;
460                 self.movement_y = dir * v_right * maxspeed;
461                 self.movement_z = dir * v_up * maxspeed;
462         }
463
464         // if there is nowhere to go, exit
465         if (self.goalcurrent == world)
466                 return;
467
468         if (self.goalcurrent)
469                 navigation_poptouchedgoals();
470
471         // if ran out of goals try to use an alternative goal or get a new strategy asap
472         if(self.goalcurrent == world)
473         {
474                 self.bot_strategytime = 0;
475                 return;
476         }
477
478 #ifdef DEBUG_BOT_GOALSTACK
479         debuggoalstack();
480 #endif
481
482         m1 = self.goalcurrent.origin + self.goalcurrent.mins;
483         m2 = self.goalcurrent.origin + self.goalcurrent.maxs;
484         destorg = self.origin;
485         destorg_x = bound(m1_x, destorg_x, m2_x);
486         destorg_y = bound(m1_y, destorg_y, m2_y);
487         destorg_z = bound(m1_z, destorg_z, m2_z);
488         diff = destorg - self.origin;
489         //dist = vlen(diff);
490         dir = normalize(diff);
491         flatdir = diff;flatdir_z = 0;
492         flatdir = normalize(flatdir);
493
494         //if (self.bot_dodgevector_time < time)
495         {
496         //      self.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
497         //      self.bot_dodgevector_jumpbutton = 1;
498                 evadeobstacle = '0 0 0';
499                 evadelava = '0 0 0';
500
501                 if (self.waterlevel)
502                 {
503                         if(self.waterlevel>WATERLEVEL_SWIMMING)
504                         {
505                         //      flatdir_z = 1;
506                                 self.aistatus |= AI_STATUS_OUT_WATER;
507                         }
508                         else
509                         {
510                                 if(self.velocity_z >= 0 && !(self.watertype == CONTENT_WATER && self.goalcurrent.origin_z < self.origin_z) &&
511                                         ( !(self.waterlevel == WATERLEVEL_WETFEET && self.watertype == CONTENT_WATER) || self.aistatus & AI_STATUS_OUT_WATER))
512                                         self.BUTTON_JUMP = TRUE;
513                                 else
514                                         self.BUTTON_JUMP = FALSE;
515                         }
516                         dir = normalize(flatdir);
517                         makevectors(self.v_angle_y * '0 1 0');
518                 }
519                 else
520                 {
521                         if(self.aistatus & AI_STATUS_OUT_WATER)
522                                 self.aistatus &~= AI_STATUS_OUT_WATER;
523
524                         // jump if going toward an obstacle that doesn't look like stairs we
525                         // can walk up directly
526                         tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 0.2, FALSE, self);
527                         if (trace_fraction < 1)
528                         if (trace_plane_normal_z < 0.7)
529                         {
530                                 s = trace_fraction;
531                                 tracebox(self.origin + '0 0 16', self.mins, self.maxs, self.origin + self.velocity * 0.2 + '0 0 16', FALSE, self);
532                                 if (trace_fraction < s + 0.01)
533                                 if (trace_plane_normal_z < 0.7)
534                                 {
535                                         s = trace_fraction;
536                                         tracebox(self.origin + '0 0 48', self.mins, self.maxs, self.origin + self.velocity * 0.2 + '0 0 48', FALSE, self);
537                                         if (trace_fraction > s)
538                                                 self.BUTTON_JUMP = 1;
539                                 }
540                         }
541
542                         // avoiding dangers and obstacles
543                         local vector dst_ahead, dst_down;
544                         makevectors(self.v_angle_y * '0 1 0');
545                         dst_ahead = self.origin + self.view_ofs + (self.velocity * 0.4) + (v_forward * 32 * 3);
546                         dst_down = dst_ahead + '0 0 -1500';
547
548                         // Look ahead
549                         traceline(self.origin + self.view_ofs , dst_ahead, TRUE, world);
550
551                         // Check head-banging against walls
552                         if(vlen(self.origin + self.view_ofs - trace_endpos) < 25 && !(self.aistatus & AI_STATUS_OUT_WATER))
553                         {
554                                 self.BUTTON_JUMP = TRUE;
555                                 if(self.facingwalltime && time > self.facingwalltime)
556                                 {
557                                         self.ignoregoal = self.goalcurrent;
558                                         self.ignoregoaltime = time + cvar("bot_ai_ignoregoal_timeout");
559                                         self.bot_strategytime = 0;
560                                         return;
561                                 }
562                                 else
563                                 {
564                                         self.facingwalltime = time + 0.05;
565                                 }
566                         }
567                         else
568                         {
569                                 self.facingwalltime = 0;
570
571                                 if(self.ignoregoal != world && time > self.ignoregoaltime)
572                                 {
573                                         self.ignoregoal = world;
574                                         self.ignoregoaltime = 0;
575                                 }
576                         }
577
578                         // Check for water/slime/lava and dangerous edges
579                         // (only when the bot is on the ground or jumping intentionally)
580                         self.aistatus &~= AI_STATUS_DANGER_AHEAD;
581
582                         if(trace_fraction == 1)
583                         if(self.flags & FL_ONGROUND || self.aistatus & AI_STATUS_RUNNING || self.BUTTON_JUMP == TRUE)
584                         {
585                                 // Look downwards
586                                 traceline(dst_ahead , dst_down, TRUE, world);
587                         //      te_lightning2(world, self.origin, dst_ahead);   // Draw "ahead" look
588                         //      te_lightning2(world, dst_ahead, dst_down);              // Draw "downwards" look
589                                 if(trace_endpos_z < self.origin_z + self.mins_z)
590                                 {
591                                         s = pointcontents(trace_endpos + '0 0 1');
592                                         if (s != CONTENT_SOLID)
593                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
594                                                 evadelava = normalize(self.velocity) * -1;
595                                         else if (s == CONTENT_SKY)
596                                                 evadeobstacle = normalize(self.velocity) * -1;
597                                         else if (!boxesoverlap(dst_ahead - self.view_ofs + self.mins, dst_ahead - self.view_ofs + self.maxs,
598                                                                 self.goalcurrent.absmin, self.goalcurrent.absmax))
599                                         {
600                                                 // if ain't a safe goal with "holes" (like the jumpad on soylent)
601                                                 // and there is a trigger_hurt below
602                                                 if(tracebox_hits_trigger_hurt(dst_ahead, self.mins, self.maxs, trace_endpos))
603                                                 {
604                                                         // Remove dangerous dynamic goals from stack
605                                                         if (self.goalcurrent.classname == "player" || self.goalcurrent.classname == "droppedweapon")
606                                                                 navigation_poproute();
607                                                         // try to stop
608                                                         flatdir = '0 0 0';
609                                                         evadeobstacle = normalize(self.velocity) * -1;
610                                                 }
611                                         }
612                                 }
613                         }
614
615                         dir = flatdir;
616                         evadeobstacle_z = 0;
617                         evadelava_z = 0;
618                         makevectors(self.v_angle_y * '0 1 0');
619
620                         if(evadeobstacle!='0 0 0'||evadelava!='0 0 0')
621                                 self.aistatus |= AI_STATUS_DANGER_AHEAD;
622                 }
623
624                 dodge = havocbot_dodge();
625                 dodge = dodge * bound(0,3+skill*0.1,1);
626                 evadelava = evadelava * bound(1,3-skill,3); //Noobs fear lava a lot and take more distance from it
627                 traceline(self.origin, self.enemy.origin, TRUE, world);
628                 if(trace_ent.classname == "player")
629                         dir = dir * bound(0,skill/7,1);
630
631                 dir = normalize(dir + dodge + evadeobstacle + evadelava);
632         //      self.bot_dodgevector = dir;
633         //      self.bot_dodgevector_jumpbutton = self.BUTTON_JUMP;
634         }
635
636         if(time < self.ladder_time)
637         {
638                 if(self.goalcurrent.origin_z + self.goalcurrent.mins_z > self.origin_z + self.mins_z)
639                 {
640                         if(self.origin_z + self.mins_z  < self.ladder_entity.origin_z + self.ladder_entity.maxs_z)
641                                 dir = '0 0 1';
642                 }
643                 else
644                 {
645                         if(self.origin_z + self.mins_z  > self.ladder_entity.origin_z + self.ladder_entity.mins_z)
646                                 dir = '0 0 -1';
647                 }
648         }
649
650         //dir = self.bot_dodgevector;
651         //if (self.bot_dodgevector_jumpbutton)
652         //      self.BUTTON_JUMP = 1;
653         self.movement_x = dir * v_forward * maxspeed;
654         self.movement_y = dir * v_right * maxspeed;
655         self.movement_z = dir * v_up * maxspeed;
656
657         // Emulate keyboard interface
658         if (skill < 10)
659                 havocbot_keyboard_movement(destorg);
660
661         // Bunnyhop!
662 //      if(self.aistatus & AI_STATUS_ROAMING)
663         if(skill >= cvar("bot_ai_bunnyhop_skilloffset"))
664                 havocbot_bunnyhop(dir);
665
666         if ((dir * v_up) >= cvar("sv_jumpvelocity")*0.5 && (self.flags & FL_ONGROUND)) self.BUTTON_JUMP=1;
667         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill)*0.1,1)) self.BUTTON_JUMP=TRUE;
668         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill)*0.1,1)) self.havocbot_ducktime=time+0.3/bound(0.1,skill,10);
669 };
670
671 .float havocbot_chooseenemy_finished;
672 .float havocbot_stickenemy;
673 void havocbot_chooseenemy()
674 {
675         local entity head, best;
676         local float rating, bestrating;
677         local vector eye, v;
678         if (cvar("bot_nofire") || IS_INDEPENDENT_PLAYER(self))
679         {
680                 self.enemy = world;
681                 return;
682         }
683         if (self.enemy)
684         {
685                 if (!bot_shouldattack(self.enemy))
686                 {
687                         // enemy died or something, find a new target
688                         self.enemy = world;
689                         self.havocbot_chooseenemy_finished = time;
690                 }
691                 else if (self.havocbot_stickenemy)
692                 {
693                         // tracking last chosen enemy
694                         // if enemy is visible
695                         // and not really really far away
696                         // and we're not severely injured
697                         // then keep tracking for a half second into the future
698                         traceline(self.origin+self.view_ofs, self.enemy.origin+self.enemy.view_ofs*0.5,FALSE,world);
699                         if (trace_ent == self.enemy || trace_fraction == 1)
700                         if (vlen(self.enemy.origin - self.origin) < 1000)
701                         if (self.health > 30)
702                         {
703                                 // remain tracking him for a shot while (case he went after a small corner or pilar
704                                 self.havocbot_chooseenemy_finished = time + cvar("bot_ai_enemydetectioninterval");
705                                 return;
706                         }
707                         // enemy isn't visible, or is far away, or we're injured severely
708                         // so stop preferring this enemy
709                         // (it will still take a half second until a new one is chosen)
710                         self.havocbot_stickenemy = 0;
711                 }
712         }
713         if (time < self.havocbot_chooseenemy_finished)
714                 return;
715         self.havocbot_chooseenemy_finished = time + cvar("bot_ai_enemydetectioninterval");
716         eye = self.origin + self.view_ofs;
717         best = world;
718         bestrating = 100000000;
719         head = findchainfloat(bot_attack, TRUE);
720         while (head)
721         {
722                 v = (head.absmin + head.absmax) * 0.5;
723                 rating = vlen(v - eye);
724                 if (bestrating > rating)
725                 if (bot_shouldattack(head))
726                 {
727                         traceline(eye, v, TRUE, self);
728                         if (trace_ent == head || trace_fraction >= 1)
729                         {
730                                 best = head;
731                                 bestrating = rating;
732                         }
733                 }
734                 head = head.chain;
735         }
736         self.enemy = best;
737         self.havocbot_stickenemy = TRUE;
738 };
739
740 .float bot_chooseweapontime;
741 float(entity e) w_getbestweapon;
742 void havocbot_chooseweapon()
743 {
744         local float i;
745
746         // ;)
747         if(g_weaponarena == WEPBIT_TUBA)
748         {
749                 self.switchweapon = WEP_TUBA;
750                 return;
751         }
752
753         // TODO: clean this up by moving it to weapon code
754         if(self.enemy.classname!="player")
755         {
756                 // If no weapon was chosen get the first available weapon
757                 if(self.weapon==0)
758                 for(i=WEP_LASER + 1; i < WEP_COUNT ; ++i)
759                 {
760                         if(client_hasweapon(self, i, TRUE, FALSE))
761                         {
762                                 self.switchweapon = i;
763                                 return;
764                         }
765                 }
766                 return;
767         }
768
769         // Do not change weapon during the next second after a combo
770         i = time - self.lastcombotime;
771         if(i < 1)
772                 return;
773
774         // Workaround for rifle reloading (..)
775         if(self.weapon == WEP_CAMPINGRIFLE)
776         if(i < cvar("g_balance_campingrifle_reloadtime") + 1)
777                 return;
778
779         local float w, s;
780         local float rocket  ; rocket   =-1000;
781         local float nex     ; nex      =-1000;
782         local float hagar   ; hagar    =-1000;
783         local float grenade ; grenade  =-1000;
784         local float electro ; electro  =-1000;
785         local float crylink ; crylink  =-1000;
786         local float uzi     ; uzi      =-1000;
787         local float shotgun ; shotgun  =-1000;
788         local float campingrifle ; campingrifle  =-1000;
789         local float laser   ; laser    =-1000;
790         local float minstanex ; minstanex =-1000;
791         local float currentscore;
792         local float bestscore; bestscore = 0;
793         local float bestweapon; bestweapon=self.switchweapon;
794         local float distance; distance=bound(10,vlen(self.origin-self.enemy.origin)-200,10000);
795         local float maxdelaytime=0.5;
796         local float spreadpenalty=10;
797         local float distancefromfloor;
798
799         // Should it do a weapon combo?
800         local float af, ct, combo_time, combo;
801
802         af = ATTACK_FINISHED(self);
803         ct = cvar("bot_ai_weapon_combo_threshold");
804
805         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
806         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
807         combo_time = time + ct + (ct * ((-0.3*skill)+3));
808
809         combo = FALSE;
810
811         if(cvar("bot_ai_weapon_combo"))
812         if(self.weapon == self.lastfiredweapon)
813         if(af > combo_time)
814         {
815                 combo = TRUE;
816                 self.lastcombotime = time;
817         }
818
819         // Custom weapon list based on distance to the enemy
820         if(bot_custom_weapon){
821
822                 // Choose weapons for far distance
823                 if ( distance > bot_distance_far ) {
824                         for(i=0; i < WEP_COUNT && bot_weapons_far[i] != -1 ; ++i){
825                                 w = bot_weapons_far[i];
826                                 if ( client_hasweapon(self, w, TRUE, FALSE) ){
827                                         if ( self.weapon == w && combo)
828                                                 continue;
829                                         self.switchweapon = w;
830                                         return;
831                                 }
832                         }
833                 }
834
835                 // Choose weapons for mid distance
836                 if ( distance > bot_distance_close ) {
837                         for(i=0; i < WEP_COUNT && bot_weapons_mid[i] != -1 ; ++i){
838                                 w = bot_weapons_mid[i];
839                                 if ( client_hasweapon(self, w, TRUE, FALSE) ){
840                                         if ( self.weapon == w && combo)
841                                                 continue;
842                                         self.switchweapon = w;
843                                         return;
844                                 }
845                         }
846                 }
847
848                 // Choose weapons for close distance
849                 for(i=0; i < WEP_COUNT && bot_weapons_close[i] != -1 ; ++i){
850                         w = bot_weapons_close[i];
851                         if ( client_hasweapon(self, w, TRUE, FALSE) ){
852                                 if ( self.weapon == w && combo)
853                                         continue;
854                                 self.switchweapon = w;
855                                 return;
856                         }
857                 }
858                 // If now weapon was chosen by this system fall back to the previous one
859         }
860
861         // Formula:
862         //      (Damage/Sec * Weapon spefic change to get that damage)
863         //      *(Time to get to target * weapon specfic hitchange bonus) / (in a time of maxdelaytime)
864         //      *(Spread change of hit) // if it applies
865         //      *(Penality for target beeing in air)
866         // %weaponaddpoint
867
868         traceline(self.enemy.origin,self.enemy.origin-'0 0 1000',TRUE,world);
869         distancefromfloor = self.enemy.origin_z - trace_endpos_z;
870
871         if (client_hasweapon(self, WEP_MINSTANEX, TRUE, FALSE))
872                 minstanex = (1000/cvar("g_balance_minstanex_refire")*1.0)
873                         * (0.5);
874
875         if (client_hasweapon(self, WEP_ROCKET_LAUNCHER, TRUE, FALSE)  &&
876                 !(      cvar("bot_ai_weapon_combo") && self.weapon == WEP_ROCKET_LAUNCHER &&
877                         af > combo_time
878                 )
879         )
880                 rocket = (cvar("g_balance_rocketlauncher_damage")/cvar("g_balance_rocketlauncher_refire")*0.75)
881                         * bound(0,(cvar("g_balance_rocketlauncher_speed")/distance*maxdelaytime),1)*1.5;
882
883         if (client_hasweapon(self, WEP_NEX, TRUE, FALSE)  &&
884                 !(      cvar("bot_ai_weapon_combo") && self.weapon == WEP_NEX &&
885                         af > combo_time
886                 )
887         )
888                 nex = (cvar("g_balance_nex_damage")/cvar("g_balance_nex_refire")*1.0)
889                         * (0.5);
890
891         if (client_hasweapon(self, WEP_HAGAR, TRUE, FALSE) ) // &&
892         //      !( cvar("bot_ai_weapon_combo") && self.weapon == WEP_HAGAR &&  time < self.bot_lastshot + cvar("g_balance_hagar_primary_refire") ))
893                 hagar = (cvar("g_balance_hagar_primary_damage")/cvar("g_balance_hagar_primary_refire")*1.0)
894                         * bound(0,(cvar("g_balance_hagar_primary_speed")/distance*maxdelaytime),1)*0.2;
895
896         if (client_hasweapon(self, WEP_GRENADE_LAUNCHER, TRUE, FALSE) &&
897                 !(
898                         cvar("bot_ai_weapon_combo") && self.weapon == WEP_GRENADE_LAUNCHER &&
899                         af > combo_time
900                 )
901         )
902                 grenade = (cvar("g_balance_grenadelauncher_primary_damage")/cvar("g_balance_grenadelauncher_primary_refire")*1.0)
903                         * bound(0,(cvar("g_balance_grenadelauncher_primary_speed")/distance*maxdelaytime),1)*1.1;
904
905         if (client_hasweapon(self, WEP_ELECTRO, TRUE, FALSE) &&
906                 !(      cvar("bot_ai_weapon_combo") && self.weapon == WEP_ELECTRO &&
907                         af > combo_time
908                 )
909         )
910                 electro = (cvar("g_balance_electro_primary_damage")/cvar("g_balance_electro_primary_refire")*0.75)
911                         * bound(0,(cvar("g_balance_electro_primary_speed")/distance*maxdelaytime),1)*1.0;
912
913         if (client_hasweapon(self, WEP_CRYLINK, TRUE, FALSE) ) // &&
914         //      !( self.weapon == WEP_CRYLINK &&  time < self.bot_lastshot + cvar("g_balance_crylink_primary_refire") ))
915                 crylink = (cvar("g_balance_crylink_primary_damage")/cvar("g_balance_crylink_primary_refire")*1.0)
916                         * bound(0,(cvar("g_balance_crylink_primary_speed")/distance*maxdelaytime),1)*(64/(32+cvar("g_balance_crylink_primary_spread")*distance))*1.0;
917
918         if (client_hasweapon(self, WEP_UZI, TRUE, FALSE) ) // &&
919         //      !( self.weapon == WEP_UZI &&  time < self.bot_lastshot + cvar("g_balance_uzi_sustained_refire") ))
920                 uzi = (cvar("g_balance_uzi_sustained_damage")/cvar("g_balance_uzi_sustained_refire")*1.0)
921                         * bound(0,32/(32+cvar("g_balance_uzi_sustained_spread")*distance),1);
922
923         if (client_hasweapon(self, WEP_SHOTGUN, TRUE, FALSE) &&
924                 !(      cvar("bot_ai_weapon_combo") && self.weapon == WEP_SHOTGUN &&
925                         af > combo_time
926                 )
927         )
928                 shotgun = (cvar("g_balance_shotgun_primary_damage")*cvar("g_balance_shotgun_primary_bullets")/cvar("g_balance_shotgun_primary_refire")*1.0)
929                         * bound(0,32/(32+cvar("g_balance_shotgun_primary_spread")*distance),1);
930
931         if (client_hasweapon(self, WEP_LASER, FALSE, FALSE) &&
932                 !(      cvar("bot_ai_weapon_combo") && self.weapon == WEP_LASER &&
933                         af > combo_time
934                 )
935         )
936                 laser = (cvar("g_balance_laser_primary_damage")/cvar("g_balance_laser_primary_refire")*1.0)
937                         * bound(0,cvar("g_balance_laser_primary_speed")/distance*maxdelaytime,1);
938
939         if((self.enemy.flags & FL_ONGROUND)==FALSE){
940                 rocket = rocket   * (1.5-bound(0, distancefromfloor/cvar("g_balance_rocketlauncher_radius"         ),0.9)); //slight bigger change
941                 grenade = grenade * (1.5-bound(0,distancefromfloor/cvar("g_balance_grenadelauncher_primary_radius"),0.95));
942                 electro = electro * (1.5-bound(0,distancefromfloor/cvar("g_balance_electro_primary_radius"        ),0.95));
943                 laser = laser     * (1.5-bound(0,distancefromfloor/cvar("g_balance_laser_primary_radius"                  ),0.95));
944         }
945         /*
946         dprint("Floor distance: ",ftos(distancefromfloor),"\n");
947         dprint("Rocket: " , ftos(rocket  ), "\n");
948         dprint("Nex: "    , ftos(nex     ), "\n");
949         dprint("Hagar: "  , ftos(hagar   ), "\n");
950         dprint("Grenade: ", ftos(grenade ), "\n");
951         dprint("Electro: ", ftos(electro ), "\n");
952         dprint("Crylink: ", ftos(crylink ), "\n");
953         dprint("Uzi: "    , ftos(uzi     ), "\n");
954         dprint("Shotgun :", ftos(shotgun ), "\n");
955         dprint("Laser   :", ftos(laser   ), "\n\n");
956         */
957         currentscore = -1;
958         w = WEP_MINSTANEX        ;s = minstanex;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
959         w = WEP_ROCKET_LAUNCHER  ;s = rocket   ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
960         w = WEP_NEX              ;s = nex      ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
961         w = WEP_HAGAR            ;s = hagar    ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
962         w = WEP_GRENADE_LAUNCHER ;s = grenade  ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
963         w = WEP_ELECTRO          ;s = electro  ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
964         w = WEP_CRYLINK          ;s = crylink  ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
965         w = WEP_UZI              ;s = uzi      ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
966         w = WEP_SHOTGUN          ;s = shotgun  ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
967         w = WEP_LASER            ;s = laser    ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
968
969         // switch if the best weapon would provide a significant damage increase
970         if (bestscore > currentscore*1.5){
971                 self.switchweapon = bestweapon;
972
973                 // buys time for detonating the rocket. not tested yet
974                 if ( cvar("bot_ai_weapon_combo") && bestweapon == WEP_ROCKET_LAUNCHER )
975                         self.bot_chooseweapontime += (distance  / cvar("g_balance_rocketlauncher_speed"));
976         }
977 };
978
979 .float nextaim;
980 void havocbot_aim()
981 {
982         local vector selfvel, enemyvel;
983 //      if(self.flags & FL_INWATER)
984 //              return;
985         if (time < self.nextaim)
986                 return;
987         self.nextaim = time + 0.1;
988         selfvel = self.velocity;
989         if (!self.waterlevel)
990                 selfvel_z = 0;
991         if (self.enemy)
992         {
993                 enemyvel = self.enemy.velocity;
994                 if (!self.enemy.waterlevel)
995                         enemyvel_z = 0;
996                 lag_additem(time + self.ping, 0, 0, self.enemy, self.origin, selfvel, self.enemy.origin, enemyvel);
997         }
998         else
999                 lag_additem(time + self.ping, 0, 0, world, self.origin, selfvel, self.goalcurrent.origin, '0 0 0');
1000 };
1001
1002 void havocbot_ai()
1003 {
1004     if(bot_execute_commands())
1005         return;
1006
1007         if (bot_strategytoken == self)
1008         if (!bot_strategytoken_taken)
1009         {
1010                 if(self.havocbot_blockhead)
1011                 {
1012                         self.havocbot_blockhead = FALSE;
1013                 }
1014                 else
1015                 {
1016                         self.havocbot_role();
1017                 }
1018
1019                 // TODO: tracewalk() should take care of this job (better path finding under water)
1020                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
1021                 if(self.deadflag != DEAD_NO)
1022                 if(self.goalcurrent==world)
1023                 if(self.waterlevel==WATERLEVEL_SWIMMING || self.aistatus & AI_STATUS_OUT_WATER)
1024                 {
1025                         // Look for the closest waypoint out of water
1026                         local entity newgoal, head;
1027                         local float bestdistance, distance;
1028
1029                         newgoal = world;
1030                         bestdistance = 10000;
1031                         for (head = findchain(classname, "waypoint"); head; head = head.chain)
1032                         {
1033                                 distance = vlen(head.origin - self.origin);
1034                                 if(distance>10000)
1035                                         continue;
1036
1037                                 if(head.origin_z < self.origin_z)
1038                                         continue;
1039
1040                                 if(head.origin_z - self.origin_z - self.view_ofs_z > 100)
1041                                         continue;
1042
1043                                 if (pointcontents(head.origin + head.maxs + '0 0 1') != CONTENT_EMPTY)
1044                                         continue;
1045
1046                                 traceline(self.origin + self.view_ofs , head.origin, TRUE, head);
1047
1048                                 if(trace_fraction<1)
1049                                         continue;
1050
1051                                 if(distance<bestdistance)
1052                                 {
1053                                         newgoal = head;
1054                                         bestdistance = distance;
1055                                 }
1056                         }
1057
1058                         if(newgoal)
1059                         {
1060                         //      te_wizspike(newgoal.origin);
1061                                 navigation_pushroute(newgoal);
1062                         }
1063                 }
1064
1065                 // token has been used this frame
1066                 bot_strategytoken_taken = TRUE;
1067         }
1068
1069         if(self.deadflag != DEAD_NO)
1070                 return;
1071
1072         havocbot_chooseenemy();
1073         if (self.bot_chooseweapontime < time )
1074         {
1075                 self.bot_chooseweapontime = time + cvar("bot_ai_chooseweaponinterval");
1076                 havocbot_chooseweapon();
1077         }
1078         havocbot_aim();
1079         lag_update();
1080         if (self.bot_aimtarg)
1081         {
1082                 self.aistatus |= AI_STATUS_ATTACKING;
1083                 self.aistatus &~= AI_STATUS_ROAMING;
1084
1085                 weapon_action(self.weapon, WR_AIM);
1086                 if (cvar("bot_nofire") || IS_INDEPENDENT_PLAYER(self))
1087                 {
1088                         self.BUTTON_ATCK = FALSE;
1089                         self.BUTTON_ATCK2 = FALSE;
1090                 }
1091                 else
1092                 {
1093                         if(self.BUTTON_ATCK||self.BUTTON_ATCK2)
1094                                 self.lastfiredweapon = self.weapon;
1095                 }
1096         }
1097         else if (self.goalcurrent)
1098         {
1099                 self.aistatus |= AI_STATUS_ROAMING;
1100                 self.aistatus &~= AI_STATUS_ATTACKING;
1101
1102                 local vector now,v,next;//,heading;
1103                 local float aimdistance,skillblend,distanceblend,blend;
1104                 next = now = self.goalcurrent.origin - (self.origin + self.view_ofs);
1105                 aimdistance = vlen(now);
1106                 //heading = self.velocity;
1107                 //dprint(self.goalstack01.classname,etos(self.goalstack01),"\n");
1108                 if(
1109                         self.goalstack01 != self && self.goalstack01 != world && self.aistatus & AI_STATUS_RUNNING == 0 &&
1110                         !(self.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
1111                 )
1112                         next = self.goalstack01.origin - (self.origin + self.view_ofs);
1113
1114                 skillblend=bound(0,(skill-2.5)*0.5,1); //lower skill player can't preturn
1115                 distanceblend=bound(0,aimdistance/cvar("bot_ai_keyboard_distance"),1);
1116                 blend = skillblend * (1-distanceblend);
1117                 //v = (now * (distanceblend) + next * (1-distanceblend)) * (skillblend) + now * (1-skillblend);
1118                 //v = now * (distanceblend) * (skillblend) + next * (1-distanceblend) * (skillblend) + now * (1-skillblend);
1119                 //v = now * ((1-skillblend) + (distanceblend) * (skillblend)) + next * (1-distanceblend) * (skillblend);
1120                 v = now + blend * (next - now);
1121                 //dprint(etos(self), " ");
1122                 //dprint(vtos(now), ":", vtos(next), "=", vtos(v), " (blend ", ftos(blend), ")\n");
1123                 //v = now * (distanceblend) + next * (1-distanceblend);
1124                 if (self.waterlevel < WATERLEVEL_SWIMMING)
1125                         v_z = 0;
1126                 //dprint("walk at:", vtos(v), "\n");
1127                 //te_lightning2(world, self.origin, self.goalcurrent.origin);
1128                 bot_aimdir(v, -1);
1129         }
1130         havocbot_movetogoal();
1131 };
1132
1133 .entity havocbot_personal_waypoint;
1134 float havocbot_moveto(vector pos)
1135 {
1136         local entity wp;
1137
1138         if(self.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1139         {
1140                 // Step 4: Move to waypoint
1141                 if(self.havocbot_personal_waypoint==world)
1142                 {
1143                         dprint("Error: ", self.netname, " trying to walk to a non existent personal waypoint\n");
1144                         self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1145                         return CMD_STATUS_ERROR;
1146                 }
1147
1148                 if (!bot_strategytoken_taken)
1149                 if(self.bot_strategytime<time)
1150                 {
1151                         // Refresh path to goal if necessary
1152                         wp = self.havocbot_personal_waypoint;
1153                         navigation_goalrating_start();
1154                         navigation_routerating(wp, 10000, 10000);
1155                         navigation_goalrating_end();
1156
1157                         if(self.navigation_hasgoals)
1158                                 dprint(self.netname, " walking to its personal waypoint\n");
1159                         else
1160                         {
1161                                 dprint("Warning: can't walk to the personal waypoint located at ", vtos(wp.origin),"\n");
1162                                 self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1163                                 return CMD_STATUS_ERROR;
1164                         }
1165
1166                         bot_strategytoken_taken = TRUE;
1167                         self.bot_strategytime = time + 10;
1168                 }
1169
1170                 #ifdef DEBUG_BOT_GOALSTACK
1171                         debuggoalstack();
1172                 #endif
1173
1174                 // Heading
1175                 local vector dir = self.goalcurrent.origin - (self.origin + self.view_ofs);
1176                 dir_z = 0;
1177                 bot_aimdir(dir, -1);
1178
1179                 // Go!
1180                 havocbot_movetogoal();
1181
1182                 if(self.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1183                 {
1184                         // Step 5: Waypoint reached
1185                         dprint(self.netname, "'s personal waypoint reached\n");
1186                         remove(self.havocbot_personal_waypoint);
1187                         self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1188                         return CMD_STATUS_FINISHED;
1189                 }
1190
1191                 return CMD_STATUS_EXECUTING;
1192         }
1193
1194         // Step 2: Linking waypoint
1195         if(self.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1196         {
1197                 // Wait until it is linked
1198                 if(!self.havocbot_personal_waypoint.wplinked)
1199                 {
1200                         dprint(self.netname, " waiting for personal waypoint to be linked\n");
1201                         return CMD_STATUS_EXECUTING;
1202                 }
1203
1204                 // Step 3: Route to waypoint
1205                 wp = self.havocbot_personal_waypoint;
1206                 navigation_goalrating_start();
1207                 navigation_routerating(wp, 10000, 10000);
1208                 navigation_goalrating_end();
1209
1210                 if(!self.navigation_hasgoals)
1211                 {
1212                         dprint("Warning: can't walk to the personal waypoint located at ", vtos(wp.origin),"\n");
1213                         self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1214                         remove(wp);
1215                         return CMD_STATUS_ERROR;
1216                 }
1217
1218                 bot_strategytoken_taken = TRUE;
1219                 self.bot_strategytime = time + 10;
1220
1221                 self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1222                 self.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1223
1224                 dprint(self.netname, " walking to its personal waypoint\n");
1225
1226                 return CMD_STATUS_EXECUTING;
1227         }
1228
1229         // Step 1: Spawning waypoint
1230         wp = waypoint_spawnpersonal(pos);
1231         if(wp==world)
1232         {
1233                 dprint("Error: Can't spawn personal waypoint at ",vtos(pos),"\n");
1234                 return CMD_STATUS_ERROR;
1235         }
1236
1237         self.havocbot_personal_waypoint = wp;
1238         self.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1239
1240         return CMD_STATUS_EXECUTING;
1241 }
1242
1243 float havocbot_resetgoal()
1244 {
1245         navigation_clearroute();
1246         return CMD_STATUS_FINISHED;
1247 }
1248
1249 void havocbot_setupbot()
1250 {
1251         self.bot_ai = havocbot_ai;
1252         self.cmd_moveto = havocbot_moveto;
1253         self.cmd_resetgoal = havocbot_resetgoal;
1254
1255         // will be updated by think code
1256         //Generate some random skill levels
1257         self.havocbot_keyboardskill=random()-0.5;
1258         havocbot_chooserole();
1259 }
1260
1261
1262 #ifdef DEBUG_BOT_GOALSTACK
1263
1264 .float goalcounter;
1265 .vector lastposition;
1266
1267 // Debug the goal stack visually
1268 void debuggoalstack()
1269 {
1270         local entity target;
1271         local vector org;
1272
1273         if(self.goalcounter==0)target=self.goalcurrent;
1274         else if(self.goalcounter==1)target=self.goalstack01;
1275         else if(self.goalcounter==2)target=self.goalstack02;
1276         else if(self.goalcounter==3)target=self.goalstack03;
1277         else if(self.goalcounter==4)target=self.goalstack04;
1278         else if(self.goalcounter==5)target=self.goalstack05;
1279         else if(self.goalcounter==6)target=self.goalstack06;
1280         else if(self.goalcounter==7)target=self.goalstack07;
1281         else if(self.goalcounter==8)target=self.goalstack08;
1282         else if(self.goalcounter==9)target=self.goalstack09;
1283         else if(self.goalcounter==10)target=self.goalstack10;
1284         else if(self.goalcounter==11)target=self.goalstack11;
1285         else if(self.goalcounter==12)target=self.goalstack12;
1286         else if(self.goalcounter==13)target=self.goalstack13;
1287         else if(self.goalcounter==14)target=self.goalstack14;
1288         else if(self.goalcounter==15)target=self.goalstack15;
1289         else if(self.goalcounter==16)target=self.goalstack16;
1290         else if(self.goalcounter==17)target=self.goalstack17;
1291         else if(self.goalcounter==18)target=self.goalstack18;
1292         else if(self.goalcounter==19)target=self.goalstack19;
1293         else if(self.goalcounter==20)target=self.goalstack20;
1294         else if(self.goalcounter==21)target=self.goalstack21;
1295         else if(self.goalcounter==22)target=self.goalstack22;
1296         else if(self.goalcounter==23)target=self.goalstack23;
1297         else if(self.goalcounter==24)target=self.goalstack24;
1298         else if(self.goalcounter==25)target=self.goalstack25;
1299         else if(self.goalcounter==26)target=self.goalstack26;
1300         else if(self.goalcounter==27)target=self.goalstack27;
1301         else if(self.goalcounter==28)target=self.goalstack28;
1302         else if(self.goalcounter==29)target=self.goalstack29;
1303         else if(self.goalcounter==30)target=self.goalstack30;
1304         else if(self.goalcounter==31)target=self.goalstack31;
1305
1306         if(target==world)
1307         {
1308                 self.goalcounter = 0;
1309                 self.lastposition='0 0 0';
1310                 return;
1311         }
1312
1313         if(self.lastposition=='0 0 0')
1314                 org = self.origin;
1315         else
1316                 org = self.lastposition;
1317
1318
1319         te_lightning2(world, org, target.origin);
1320         self.lastposition = target.origin;
1321
1322         self.goalcounter++;
1323 }
1324
1325 #endif