data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 void SetDefaultAlpha()
  12 {
  13         if(cvar("g_running_guns"))
  14         {
  15                 default_player_alpha = -1;
  16                 default_weapon_alpha = +1;
  17         }
  18         else if(g_cloaked)
  19         {
  20                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23         else
  24         {
  25                 default_player_alpha = cvar("g_player_alpha");
  26                 if(default_player_alpha == 0)
  27                         default_player_alpha = 1;
  28                 default_weapon_alpha = default_player_alpha;
  29         }
  30 }
  31
  32 void fteqcc_testbugs()
  33 {
  34         float a, b;
  35
  36         if(!cvar("developer_fteqccbugs"))
  37                 return;
  38
  39         dprint("*** fteqcc test: checking for bugs...\n");
  40
  41         a = 1;
  42         b = 5;
  43         if(sqrt(a) - sqrt(b - a) == 0)
  44                 dprint("*** fteqcc test: found same-function-twice bug\n");
  45         else
  46                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  47
  48         world.cnt = -10;
  49         world.enemy = world;
  50         world.enemy.cnt += 10;
  51         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  52                 dprint("*** fteqcc test: found += bug\n");
  53         else
  54                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  55         world.cnt = 0;
  56 }
  57
  58 /**
  59  * Takes care of pausing and unpausing the game.
  60  * Centerprints the information about an upcoming or active timeout to all active
  61  * players. Also plays reminder sounds.
  62  */
  63 void timeoutHandler_Think() {
  64         local string timeStr;
  65         local entity plr;
  66         if (timeoutStatus == 1) {
  67                 if (remainingLeadTime > 0) {
  68                         //centerprint the information to every player
  69                         timeStr = getTimeoutText(0);
  70                         FOR_EACH_REALCLIENT(plr) {
  71                                 if(plr.classname == "player") {
  72                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  73                                 }
  74                         }
  75                         remainingLeadTime -= 1;
  76                         //think again in 1 second:
  77                         self.nextthink = time + 1;
  78                 }
  79                 else {
  80                         //now pause the game:
  81                         timeoutStatus = 2;
  82                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  83                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  84                         FOR_EACH_REALPLAYER(plr) {
  85                                 plr.lastV_angle = plr.v_angle;
  86                         }
  87                         self.nextthink = time;
  88                 }
  89         }
  90         else if (timeoutStatus == 2) {
  91                 if (remainingTimeoutTime > 0) {
  92                         timeStr = getTimeoutText(0);
  93                         FOR_EACH_REALCLIENT(plr) {
  94                                 if(plr.classname == "player") {
  95                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  96                                 }
  97                         }
  98                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
  99                                 play2all("announcer/robotic/prepareforbattle.wav");
 100                         }
 101                         remainingTimeoutTime -= 1;
 102                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 103                 }
 104                 else {
 105                         //unpause the game again
 106                         remainingTimeoutTime = timeoutStatus = 0;
 107                         cvar_set("slowmo", ftos(orig_slowmo));
 108                         //and unlock the fixed view again once there is no timeout active anymore
 109                         FOR_EACH_REALPLAYER(plr) {
 110                                 plr.fixangle = FALSE;
 111                         }
 112                         //get rid of the countdown message
 113                         FOR_EACH_REALCLIENT(plr) {
 114                                 if(plr.classname == "player") {
 115                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 116                                 }
 117                         }
 118                         remove(self);
 119                         return;
 120                 }
 121
 122         }
 123         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 124                 FOR_EACH_REALCLIENT(plr) {
 125                         if(plr.classname == "player") {
 126                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 127                         }
 128                 }
 129                 remove(self);
 130                 return;
 131         }
 132 }
 133
 134 float GotoFirstMap()
 135 {
 136         if(cvar("_sv_init"))
 137         {
 138                 cvar_set("_sv_init", "0");
 139                 if(cvar("g_maplist_shuffle"))
 140                         ShuffleMaplist();
 141                 tokenizebyseparator(cvar_string("g_maplist"), " ");
 142                 {
 143                         cvar_set("nextmap", argv(0));
 144
 145                         MapInfo_Enumerate();
 146                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 0);
 147
 148                         if(!DoNextMapOverride())
 149                                 GotoNextMap();
 150
 151                         return 1;
 152                 }
 153         }
 154         return 0;
 155 }
 156
 157 void cvar_changes_init()
 158 {
 159         float h;
 160         string k, v, d;
 161         float n, i;
 162
 163         if(cvar_changes)
 164                 strunzone(cvar_changes);
 165         cvar_changes = string_null;
 166
 167         h = buf_create();
 168         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 169         n = buf_getsize(h);
 170
 171         for(i = 0; i < n; ++i)
 172         {
 173                 k = bufstr_get(h, i);
 174
 175 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 176 #define BADCVAR(p) if(k == p) continue
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184
 185                 // client
 186                 BADPREFIX("cl_");
 187                 BADPREFIX("con_");
 188                 BADPREFIX("g_campaign");
 189                 BADPREFIX("gl_");
 190                 BADPREFIX("joy");
 191                 BADPREFIX("menu_");
 192                 BADPREFIX("net_slist_");
 193                 BADPREFIX("r_");
 194                 BADPREFIX("sbar_");
 195                 BADPREFIX("scr_");
 196                 BADPREFIX("userbind");
 197                 BADPREFIX("v_");
 198                 BADPREFIX("vid_");
 199                 BADCVAR("mod_q3bsp_lightmapmergepower");
 200                 BADCVAR("mod_q3bsp_nolightmaps");
 201
 202                 // private
 203                 BADPREFIX("g_ban_");
 204                 BADPREFIX("g_chat_flood_");
 205                 BADPREFIX("rcon_");
 206                 BADPREFIX("settemp_");
 207                 BADPREFIX("sv_allowdownloads_");
 208                 BADPREFIX("sv_autodemo");
 209                 BADPREFIX("sv_curl_");
 210                 BADPREFIX("sv_eventlog");
 211                 BADPREFIX("sv_logscores_");
 212                 BADPREFIX("sv_master");
 213                 BADCVAR("g_banned_list");
 214                 BADCVAR("log_dest_udp");
 215                 BADCVAR("log_file");
 216                 BADCVAR("net_address");
 217                 BADCVAR("port");
 218                 BADCVAR("savedgamecfg");
 219                 BADCVAR("sv_heartbeatperoid");
 220                 BADCVAR("sv_vote_master_password");
 221                 BADCVAR("sys_colortranslation");
 222                 BADCVAR("sys_specialcharactertranslation");
 223                 BADCVAR("timestamps");
 224
 225                 // mapinfo
 226                 BADCVAR("timelimit");
 227                 BADCVAR("fraglimit");
 228                 BADCVAR("g_arena");
 229                 BADCVAR("g_assault");
 230                 BADCVAR("g_ctf");
 231                 BADCVAR("g_dm");
 232                 BADCVAR("g_domination");
 233                 BADCVAR("g_keyhunt");
 234                 BADCVAR("g_keyhunt_teams");
 235                 BADCVAR("g_onslaught");
 236                 BADCVAR("g_race");
 237                 BADCVAR("g_runematch");
 238                 BADCVAR("g_tdm");
 239                 BADCVAR("teamplay");
 240
 241                 // long
 242                 BADCVAR("hostname");
 243                 BADCVAR("g_maplist");
 244                 BADCVAR("g_maplist_mostrecent");
 245                 BADCVAR("sv_motd");
 246 #undef BADPREFIX
 247 #undef BADCVAR
 248
 249                 v = cvar_string(k);
 250                 d = cvar_defstring(k);
 251                 if(v != d)
 252                 {
 253                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 254                         if(strlen(cvar_changes) > 16384)
 255                         {
 256                                 cvar_changes = "// too many settings have been changed to show them here\n";
 257                                 break;
 258                         }
 259                 }
 260         }
 261         buf_del(h);
 262         if(cvar_changes == "")
 263                 cvar_changes = "// this server runs at default settings\n";
 264         else
 265                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 266         cvar_changes = strzone(cvar_changes);
 267 }
 268
 269 void detect_maptype()
 270 {
 271 #if 0
 272         vector o, v;
 273         float i;
 274
 275         for(;;)
 276         {
 277                 o = world.mins;
 278                 o_x += random() * (world.maxs_x - world.mins_x);
 279                 o_y += random() * (world.maxs_y - world.mins_y);
 280                 o_z += random() * (world.maxs_z - world.mins_z);
 281
 282                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 283                 if(trace_fraction == 1)
 284                         continue;
 285
 286                 v = trace_endpos;
 287
 288                 for(i = 0; i < 64; i += 4)
 289                 {
 290                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 291         if(trace_fraction == 1)
 292                 continue;
 293                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 294                 }
 295
 296                 break;
 297         }
 298 #endif
 299 }
 300
 301 entity randomseed;
 302 float RandomSeed_Send(entity to, float sf)
 303 {
 304         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 305         WriteShort(MSG_ENTITY, self.cnt);
 306         return TRUE;
 307 }
 308 void RandomSeed_Think()
 309 {
 310         self.cnt = bound(0, floor(random() * 65536), 65535);
 311         self.nextthink = time + 5;
 312
 313         self.SendFlags |= 1;
 314 }
 315 void RandomSeed_Spawn()
 316 {
 317         randomseed = spawn();
 318         randomseed.think = RandomSeed_Think;
 319         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 320
 321         entity oldself;
 322         oldself = self;
 323         self = randomseed;
 324         self.think(); // sets random seed and nextthink
 325         self = oldself;
 326 }
 327
 328 void Map_MarkAsRecent(string m);
 329 float world_already_spawned;
 330 void RegisterWeapons();
 331 void Nagger_Init();
 332 void ClientInit_Spawn();
 333 void spawnfunc_worldspawn (void)
 334 {
 335         float fd, l, i, j, n;
 336         string s, col;
 337
 338         dprint_load(); // load dprint status from cvar
 339
 340         if(world_already_spawned)
 341                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 342         world_already_spawned = TRUE;
 343
 344         remove = remove_safely; // during spawning, watch what you remove!
 345
 346         if(cvar_string("cvar_check_default") != "bypass")
 347         {
 348                 if(cvar_string("cvar_check_default") != CVAR_CHECK_DEFAULT)
 349                         error("Config file mismatch! Please update defaultNexuiz.cfg to match the QuakeC code!");
 350
 351                 if(cvar_string("cvar_check_weapons") != CVAR_CHECK_WEAPONS)
 352                         error("Config file mismatch! Please update weapons.cfg and weaponsPro.cfg to match the QuakeC code!");
 353         }
 354
 355         compressShortVector_init();
 356
 357         local entity head;
 358         head = nextent(world);
 359         maxclients = 0;
 360         while(head)
 361         {
 362                 ++maxclients;
 363                 head = nextent(head);
 364         }
 365
 366         // needs to be done so early as they would still spawn
 367         RegisterWeapons();
 368
 369         if(GotoFirstMap())
 370         {
 371                 world_initialized = -1; // don't complain
 372                 return;
 373         }
 374
 375         if(sv_cheats)
 376                 ServerProgsDB = db_create();
 377         else
 378                 ServerProgsDB = db_load("server.db");
 379
 380         TemporaryDB = db_create();
 381
 382         /*
 383         TODO sound pack system
 384         // initialize sound pack system
 385         soundpack = cvar_string("g_soundpack");
 386         if(soundpack != "")
 387                 soundpack = strcat(soundpack, "/");
 388         soundpack = strzone(soundpack);
 389         */
 390
 391         // 0 normal
 392         lightstyle(0, "m");
 393
 394         // 1 FLICKER (first variety)
 395         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 396
 397         // 2 SLOW STRONG PULSE
 398         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 399
 400         // 3 CANDLE (first variety)
 401         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 402
 403         // 4 FAST STROBE
 404         lightstyle(4, "mamamamamama");
 405
 406         // 5 GENTLE PULSE 1
 407         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 408
 409         // 6 FLICKER (second variety)
 410         lightstyle(6, "nmonqnmomnmomomno");
 411
 412         // 7 CANDLE (second variety)
 413         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 414
 415         // 8 CANDLE (third variety)
 416         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 417
 418         // 9 SLOW STROBE (fourth variety)
 419         lightstyle(9, "aaaaaaaazzzzzzzz");
 420
 421         // 10 FLUORESCENT FLICKER
 422         lightstyle(10, "mmamammmmammamamaaamammma");
 423
 424         // 11 SLOW PULSE NOT FADE TO BLACK
 425         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 426
 427         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 428
 429         // 63 testing
 430         lightstyle(63, "a");
 431
 432         if(cvar("g_campaign"))
 433                 CampaignPreInit();
 434
 435         Map_MarkAsRecent(mapname);
 436
 437         precache_model ("null"); // we need this one before InitGameplayMode
 438         InitGameplayMode();
 439         readlevelcvars();
 440         GrappleHookInit();
 441
 442         player_count = 0;
 443         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 444         if(bot_waypoints_for_items == 1)
 445                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 446                         bot_waypoints_for_items = 0;
 447
 448         // for setting by mapinfo
 449         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 450         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 451
 452         precache();
 453
 454         WaypointSprite_Init();
 455
 456         //if (g_domination)
 457         //      dom_init();
 458
 459         GameLogInit(); // prepare everything
 460         if(cvar("sv_eventlog"))
 461         {
 462                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 463                 s = strcat(s, ftos(random()));
 464                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 465                 s = ":gameinfo:mutators:LIST";
 466                 if(cvar("g_grappling_hook"))
 467                         s = strcat(s, ":grappling_hook");
 468                 if(!cvar("g_use_ammunition"))
 469                         s = strcat(s, ":no_use_ammunition");
 470                 if(!cvar("g_pickup_items"))
 471                         s = strcat(s, ":no_pickup_items");
 472                 if(cvar("g_instagib"))
 473                         s = strcat(s, ":instagib");
 474                 if(cvar_string("g_weaponarena") != "0")
 475                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 476                 if(cvar("g_nixnex"))
 477                         s = strcat(s, ":nixnex");
 478                 if(cvar("g_vampire"))
 479                         s = strcat(s, ":vampire");
 480                 if(cvar("g_laserguided_missile"))
 481                         s = strcat(s, ":laserguided_missile");
 482                 if(cvar("g_norecoil"))
 483                         s = strcat(s, ":norecoil");
 484                 if(cvar("g_midair"))
 485                         s = strcat(s, ":midair");
 486                 if(cvar("g_minstagib"))
 487                         s = strcat(s, ":minstagib");
 488                 GameLogEcho(s);
 489                 GameLogEcho(":gameinfo:end");
 490         }
 491
 492         cvar_set("nextmap", "");
 493
 494         SetDefaultAlpha();
 495
 496         if(cvar("g_campaign"))
 497                 CampaignPostInit();
 498
 499         fteqcc_testbugs();
 500
 501         Ban_LoadBans();
 502
 503         //initialise globals related to sv_timeout
 504         sys_ticrate = cvar("sys_ticrate");
 505         orig_slowmo = cvar("slowmo");
 506
 507         MapInfo_Enumerate();
 508         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 1);
 509
 510         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 511         {
 512                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 513                 if(fd != -1)
 514                 {
 515                         while((s = fgets(fd)))
 516                         {
 517                                 l = tokenize_sane(s);
 518                                 if(l < 2)
 519                                         continue;
 520                                 if(argv(0) == "cd")
 521                                 {
 522                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 523                                         print("  cdtrack ", argv(2), "\n");
 524                                 }
 525                                 else if(argv(0) == "fog")
 526                                 {
 527                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 528                                         print("  \"fog\" \"", s, "\"\n");
 529                                 }
 530                                 else if(argv(0) == "set")
 531                                 {
 532                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 533                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 534                                 }
 535                                 else if(argv(0) != "//")
 536                                 {
 537                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 538                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 539                                 }
 540                         }
 541                         fclose(fd);
 542                 }
 543         }
 544
 545         addstat(STAT_SYS_TICRATE, AS_FLOAT, stat_sys_ticrate);
 546         addstat(STAT_WEAPONS, AS_INT, weapons);
 547         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 548         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 549         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 550         Nagger_Init();
 551
 552         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 553         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 554
 555         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 556
 557         next_pingtime = time + 5;
 558         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 559
 560         detect_maptype();
 561
 562         lsmaps_reply = "^7Maps available: ";
 563         for(i = 0, j = 0; i < MapInfo_count; ++i)
 564         {
 565                 if(MapInfo_Get_ByID(i))
 566                         if not(MapInfo_Map_flags & MAPINFO_FLAG_HIDDEN)
 567                         {
 568                                 if(mod(i, 2))
 569                                         col = "^2";
 570                                 else
 571                                         col = "^3";
 572                                 ++j;
 573                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 574                         }
 575         }
 576         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 577
 578         maplist_reply = "^7Maps in list: ";
 579         n = tokenize_sane(cvar_string("g_maplist"));
 580         for(i = 0, j = 0; i < n; ++i)
 581         {
 582                 if(MapInfo_CheckMap(argv(i)))
 583                 {
 584                         if(mod(j, 2))
 585                                 col = "^2";
 586                         else
 587                                 col = "^3";
 588                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 589                         ++j;
 590                 }
 591         }
 592         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 593
 594         records_reply = strzone(getrecords());
 595
 596         ClientInit_Spawn();
 597         RandomSeed_Spawn();
 598
 599         world_initialized = 1;
 600 }
 601
 602 void spawnfunc_light (void)
 603 {
 604         //makestatic (self); // Who the f___ did that?
 605         remove(self);
 606 }
 607
 608 float TryFile( string pFilename )
 609 {
 610         local float lHandle;
 611         dprint("TryFile(\"", pFilename, "\")\n");
 612         lHandle = fopen( pFilename, FILE_READ );
 613         if( lHandle != -1 ) {
 614                 fclose( lHandle );
 615                 return TRUE;
 616         } else {
 617                 return FALSE;
 618         }
 619 };
 620
 621 string GetGametype()
 622 {
 623         return GametypeNameFromType(game);
 624 }
 625
 626 string getmapname_stored;
 627 string GetMapname()
 628 {
 629         return mapname;
 630 }
 631
 632 float Map_Count, Map_Current;
 633 string Map_Current_Name;
 634
 635 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 636 float GetMaplistPosition()
 637 {
 638         float pos, idx;
 639         string map;
 640
 641         map = GetMapname();
 642         idx = cvar("g_maplist_index");
 643
 644         if(idx >= 0)
 645                 if(idx < Map_Count)
 646                         if(map == argv(idx))
 647                                 return idx;
 648
 649         for(pos = 0; pos < Map_Count; ++pos)
 650                 if(map == argv(pos))
 651                         return pos;
 652
 653         // resume normal maplist rotation if current map is not in g_maplist
 654         return idx;
 655 }
 656
 657 float MapHasRightSize(string map)
 658 {
 659         float fh;
 660         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 661         if(cvar("g_maplist_check_waypoints"))
 662         {
 663                 dprint("checkwp "); dprint(map);
 664                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 665                 if(fh < 0)
 666                 {
 667                         dprint(": no waypoints\n");
 668                         return FALSE;
 669                 }
 670                 dprint(": has waypoints\n");
 671                 fclose(fh);
 672         }
 673
 674         // open map size restriction file
 675         dprint("opensize "); dprint(map);
 676         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 677         if(fh >= 0)
 678         {
 679                 float mapmin, mapmax;
 680                 dprint(": ok, ");
 681                 mapmin = stof(fgets(fh));
 682                 mapmax = stof(fgets(fh));
 683                 fclose(fh);
 684                 if(player_count < mapmin)
 685                 {
 686                         dprint("not enough\n");
 687                         return FALSE;
 688                 }
 689                 if(player_count > mapmax)
 690                 {
 691                         dprint("too many\n");
 692                         return FALSE;
 693                 }
 694                 dprint("right size\n");
 695                 return TRUE;
 696         }
 697         dprint(": not found\n");
 698         return TRUE;
 699 }
 700
 701 string Map_Filename(float position)
 702 {
 703         return strcat("maps/", argv(position), ".bsp");
 704 }
 705
 706 string strwords(string s, float w)
 707 {
 708         float endpos;
 709         for(endpos = 0; w && endpos >= 0; --w)
 710                 endpos = strstrofs(s, " ", endpos + 1);
 711         if(endpos < 0)
 712                 return s;
 713         else
 714                 return substring(s, 0, endpos);
 715 }
 716
 717 float strhasword(string s, string w)
 718 {
 719         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 720 }
 721
 722 void Map_MarkAsRecent(string m)
 723 {
 724         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
 725 }
 726
 727 float Map_IsRecent(string m)
 728 {
 729         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 730 }
 731
 732 float Map_Check(float position, float pass)
 733 {
 734         string filename;
 735         string map_next;
 736         map_next = argv(position);
 737         if(pass <= 1)
 738         {
 739                 if(Map_IsRecent(map_next))
 740                         return 0;
 741         }
 742         filename = Map_Filename(position);
 743         if(MapInfo_CheckMap(map_next))
 744         {
 745                 if(pass == 2)
 746                         return 1;
 747                 if(MapHasRightSize(map_next))
 748                         return 1;
 749                 return 0;
 750         }
 751         else
 752                 dprint( "Couldn't select '", filename, "'..\n" );
 753
 754         return 0;
 755 }
 756
 757 void Map_Goto_SetStr(string nextmapname)
 758 {
 759         if(getmapname_stored != "")
 760                 strunzone(getmapname_stored);
 761         if(nextmapname == "")
 762                 getmapname_stored = "";
 763         else
 764                 getmapname_stored = strzone(nextmapname);
 765 }
 766
 767 void Map_Goto_SetFloat(float position)
 768 {
 769         cvar_set("g_maplist_index", ftos(position));
 770         Map_Goto_SetStr(argv(position));
 771 }
 772
 773 void GameResetCfg()
 774 {
 775         // settings persist, except...
 776         if(cvar("g_campaign"))
 777                 localcmd("\nexec mutator_reset.cfg\n");
 778         localcmd("\nsettemp_restore\n");
 779 };
 780
 781 void Map_Goto()
 782 {
 783         GameResetCfg();
 784         MapInfo_LoadMap(getmapname_stored);
 785 }
 786
 787 // return codes of map selectors:
 788 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 789 //   -2 = permanent failure
 790 float() MaplistMethod_Iterate = // usual method
 791 {
 792         float pass, i;
 793
 794         for(pass = 1; pass <= 2; ++pass)
 795         {
 796                 for(i = 1; i < Map_Count; ++i)
 797                 {
 798                         float mapindex;
 799                         mapindex = mod(i + Map_Current, Map_Count);
 800                         if(Map_Check(mapindex, pass))
 801                                 return mapindex;
 802                 }
 803         }
 804         return -1;
 805 }
 806
 807 float() MaplistMethod_Repeat = // fallback method
 808 {
 809         if(Map_Check(Map_Current, 2))
 810                 return Map_Current;
 811         return -2;
 812 }
 813
 814 float() MaplistMethod_Random = // random map selection
 815 {
 816         float i, imax;
 817
 818         imax = 42;
 819
 820         for(i = 0; i <= imax; ++i)
 821         {
 822                 float mapindex;
 823                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 824                 if(Map_Check(mapindex, 1))
 825                         return mapindex;
 826         }
 827         return -1;
 828 }
 829
 830 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 831 // the exponent sets a bias on the map selection:
 832 // the higher the exponent, the less likely "shortly repeated" same maps are
 833 {
 834         float i, j, imax, insertpos;
 835
 836         imax = 42;
 837
 838         for(i = 0; i <= imax; ++i)
 839         {
 840                 string newlist;
 841
 842                 // now reinsert this at another position
 843                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 844                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 845                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 846                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 847
 848                 // insert the current map there
 849                 newlist = "";
 850                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 851                         newlist = strcat(newlist, " ", argv(j));
 852                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 853                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 854                         newlist = strcat(newlist, " ", argv(j));
 855                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 856                 cvar_set("g_maplist", newlist);
 857                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 858
 859                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 860                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 861                 if(Map_Check(Map_Current, 1))
 862                         return Map_Current;
 863         }
 864         return -1;
 865 }
 866
 867 void Maplist_Init()
 868 {
 869         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 870         if(Map_Count == 0)
 871         {
 872                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 873                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
 874                 if(cvar("g_maplist_shuffle"))
 875                         ShuffleMaplist();
 876                 localcmd("\nmenu_cmd sync\n");
 877                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 878         }
 879         if(Map_Count == 0)
 880                 error("empty maplist, cannot select a new map");
 881         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 882
 883         if(Map_Current_Name)
 884                 strunzone(Map_Current_Name);
 885         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 886         // this may or may not be correct, but who cares, in the worst case a map
 887         // isn't chosen in the first pass that should have been
 888 }
 889
 890 string GetNextMap()
 891 {
 892         float nextMap;
 893
 894         Maplist_Init();
 895         nextMap = -1;
 896
 897         if(nextMap == -1)
 898                 if(cvar("g_maplist_shuffle") > 0)
 899                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 900
 901         if(nextMap == -1)
 902                 if(cvar("g_maplist_selectrandom"))
 903                         nextMap = MaplistMethod_Random();
 904
 905         if(nextMap == -1)
 906                 nextMap = MaplistMethod_Iterate();
 907
 908         if(nextMap == -1)
 909                 nextMap = MaplistMethod_Repeat();
 910
 911         if(nextMap >= 0)
 912         {
 913                 Map_Goto_SetFloat(nextMap);
 914                 return getmapname_stored;
 915         }
 916
 917         return "";
 918 };
 919
 920 float DoNextMapOverride()
 921 {
 922         if(cvar("g_campaign"))
 923         {
 924                 CampaignPostIntermission();
 925                 alreadychangedlevel = TRUE;
 926                 return TRUE;
 927         }
 928         if(cvar("quit_when_empty"))
 929         {
 930                 if(player_count <= currentbots)
 931                 {
 932                         localcmd("quit\n");
 933                         alreadychangedlevel = TRUE;
 934                         return TRUE;
 935                 }
 936         }
 937         if(cvar_string("quit_and_redirect") != "")
 938         {
 939                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 940                 alreadychangedlevel = TRUE;
 941                 return TRUE;
 942         }
 943         if (cvar("samelevel")) // if samelevel is set, stay on same level
 944         {
 945                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 946                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 947                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 948                 localcmd("restart\n");
 949                 //changelevel (mapname);
 950                 alreadychangedlevel = TRUE;
 951                 return TRUE;
 952         }
 953         if(cvar_string("nextmap") != "")
 954                 if(MapInfo_CheckMap(cvar_string("nextmap")))
 955                 {
 956                         Map_Goto_SetStr(cvar_string("nextmap"));
 957                         Map_Goto();
 958                         alreadychangedlevel = TRUE;
 959                         return TRUE;
 960                 }
 961         if(cvar("lastlevel"))
 962         {
 963                 GameResetCfg();
 964                 localcmd("set lastlevel 0\ntogglemenu\n");
 965                 alreadychangedlevel = TRUE;
 966                 return TRUE;
 967         }
 968         return FALSE;
 969 };
 970
 971 void GotoNextMap()
 972 {
 973         //local string nextmap;
 974         //local float n, nummaps;
 975         //local string s;
 976         if (alreadychangedlevel)
 977                 return;
 978         alreadychangedlevel = TRUE;
 979
 980         {
 981                 string nextMap;
 982                 float allowReset;
 983
 984                 for(allowReset = 1; allowReset >= 0; --allowReset)
 985                 {
 986                         nextMap = GetNextMap();
 987                         if(nextMap != "")
 988                                 break;
 989
 990                         if(allowReset)
 991                         {
 992                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
 993                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
 994                                 if(cvar("g_maplist_shuffle"))
 995                                         ShuffleMaplist();
 996                                 localcmd("\nmenu_cmd sync\n");
 997                         }
 998                         else
 999                         {
1000                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1001                         }
1002                 }
1003                 Map_Goto();
1004         }
1005 };
1006
1007
1008 /*
1009 ============
1010 IntermissionThink
1011
1012 When the player presses attack or jump, change to the next level
1013 ============
1014 */
1015 .float autoscreenshot;
1016 void() MapVote_Start;
1017 void() MapVote_Think;
1018 float mapvote_initialized;
1019 void IntermissionThink()
1020 {
1021         FixIntermissionClient(self);
1022
1023         if(cvar("sv_autoscreenshot"))
1024         if(self.autoscreenshot > 0)
1025         if(time > self.autoscreenshot)
1026         {
1027                 self.autoscreenshot = -1;
1028                 if(clienttype(self) == CLIENTTYPE_REAL)
1029                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1030                 return;
1031         }
1032
1033         if (time < intermission_exittime)
1034                 return;
1035
1036         if(!mapvote_initialized)
1037                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1038                         return;
1039
1040         MapVote_Start();
1041 };
1042
1043 /*
1044 ============
1045 FindIntermission
1046
1047 Returns the entity to view from
1048 ============
1049 */
1050 /*
1051 entity FindIntermission()
1052 {
1053         local   entity spot;
1054         local   float cyc;
1055
1056 // look for info_intermission first
1057         spot = find (world, classname, "info_intermission");
1058         if (spot)
1059         {       // pick a random one
1060                 cyc = random() * 4;
1061                 while (cyc > 1)
1062                 {
1063                         spot = find (spot, classname, "info_intermission");
1064                         if (!spot)
1065                                 spot = find (spot, classname, "info_intermission");
1066                         cyc = cyc - 1;
1067                 }
1068                 return spot;
1069         }
1070
1071 // then look for the start position
1072         spot = find (world, classname, "info_player_start");
1073         if (spot)
1074                 return spot;
1075
1076 // testinfo_player_start is only found in regioned levels
1077         spot = find (world, classname, "testplayerstart");
1078         if (spot)
1079                 return spot;
1080
1081 // then look for the start position
1082         spot = find (world, classname, "info_player_deathmatch");
1083         if (spot)
1084                 return spot;
1085
1086         //objerror ("FindIntermission: no spot");
1087         return world;
1088 };
1089 */
1090
1091 /*
1092 ===============================================================================
1093
1094 RULES
1095
1096 ===============================================================================
1097 */
1098
1099 void DumpStats(float final)
1100 {
1101         local float file;
1102         local string s;
1103         local float to_console;
1104         local float to_eventlog;
1105         local float to_file;
1106         local float i;
1107
1108         to_console = cvar("sv_logscores_console");
1109         to_eventlog = cvar("sv_eventlog");
1110         to_file = cvar("sv_logscores_file");
1111
1112         if(!final)
1113         {
1114                 to_console = TRUE; // always print printstats replies
1115                 to_eventlog = FALSE; // but never print them to the event log
1116         }
1117
1118         if(to_eventlog)
1119                 if(cvar("sv_eventlog_console"))
1120                         to_console = FALSE; // otherwise we get the output twice
1121
1122         if(final)
1123                 s = ":scores:";
1124         else
1125                 s = ":status:";
1126         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1127
1128         if(to_console)
1129                 print(s, "\n");
1130         if(to_eventlog)
1131                 GameLogEcho(s);
1132         if(to_file)
1133         {
1134                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1135                 if(file == -1)
1136                         to_file = FALSE;
1137                 else
1138                         fputs(file, strcat(s, "\n"));
1139         }
1140
1141         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1142         if(to_console)
1143                 print(s, "\n");
1144         if(to_eventlog)
1145                 GameLogEcho(s);
1146         if(to_file)
1147                 fputs(file, strcat(s, "\n"));
1148
1149         FOR_EACH_CLIENT(other)
1150         {
1151                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1152                 {
1153                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1154                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1155                         if(other.classname == "player" || g_arena || g_lms)
1156                                 s = strcat(s, ftos(other.team), ":");
1157                         else
1158                                 s = strcat(s, "spectator:");
1159
1160                         if(to_console)
1161                                 print(s, other.netname, "\n");
1162                         if(to_eventlog)
1163                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1164                         if(to_file)
1165                                 fputs(file, strcat(s, other.netname, "\n"));
1166                 }
1167         }
1168
1169         if(teamplay)
1170         {
1171                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1172                 if(to_console)
1173                         print(s, "\n");
1174                 if(to_eventlog)
1175                         GameLogEcho(s);
1176                 if(to_file)
1177                         fputs(file, strcat(s, "\n"));
1178
1179                 for(i = 1; i < 16; ++i)
1180                 {
1181                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1182                         s = strcat(s, ":", ftos(i));
1183                         if(to_console)
1184                                 print(s, "\n");
1185                         if(to_eventlog)
1186                                 GameLogEcho(s);
1187                         if(to_file)
1188                                 fputs(file, strcat(s, "\n"));
1189                 }
1190         }
1191
1192         if(to_console)
1193                 print(":end\n");
1194         if(to_eventlog)
1195                 GameLogEcho(":end");
1196         if(to_file)
1197         {
1198                 fputs(file, ":end\n");
1199                 fclose(file);
1200         }
1201 }
1202
1203 void FixIntermissionClient(entity e)
1204 {
1205         string s;
1206         if(!e.autoscreenshot) // initial call
1207         {
1208                 e.angles = e.v_angle;
1209                 e.angles_x = -e.angles_x;
1210                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1211                 e.health = -2342;
1212                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1213                 e.solid = SOLID_NOT;
1214                 e.movetype = MOVETYPE_NONE;
1215                 e.takedamage = DAMAGE_NO;
1216                 if(e.weaponentity)
1217                         e.weaponentity.effects = EF_NODRAW;
1218                 if(clienttype(e) == CLIENTTYPE_REAL)
1219                 {
1220                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1221                         s = cvar_string("sv_intermission_cdtrack");
1222                         if(s != "")
1223                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1224                         msg_entity = e;
1225                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1226                 }
1227         }
1228
1229         //e.velocity = '0 0 0';
1230         //e.fixangle = TRUE;
1231
1232         // TODO halt weapon animation
1233 }
1234
1235
1236 /*
1237 go to the next level for deathmatch
1238 only called if a time or frag limit has expired
1239 */
1240 void NextLevel()
1241 {
1242         float minTotalFrags;
1243         float maxTotalFrags;
1244         float score;
1245         float f;
1246
1247         gameover = TRUE;
1248
1249         intermission_running = 1;
1250
1251 // enforce a wait time before allowing changelevel
1252         if(player_count > 0)
1253                 intermission_exittime = time + cvar("sv_mapchange_delay");
1254         else
1255                 intermission_exittime = -1;
1256
1257         /*
1258         WriteByte (MSG_ALL, SVC_CDTRACK);
1259         WriteByte (MSG_ALL, 3);
1260         WriteByte (MSG_ALL, 3);
1261         // done in FixIntermission
1262         */
1263
1264         //pos = FindIntermission ();
1265
1266         VoteReset();
1267
1268         DumpStats(TRUE);
1269
1270         if(cvar("sv_eventlog"))
1271                 GameLogEcho(":gameover");
1272
1273         GameLogClose();
1274
1275         FOR_EACH_CLIENT(other)
1276         {
1277                 FixIntermissionClient(other);
1278
1279                 if(other.winning)
1280                         bprint(other.netname, " ^7wins.\n");
1281         }
1282
1283         minTotalFrags = 0;
1284         maxTotalFrags = 0;
1285         FOR_EACH_PLAYER(other)
1286         {
1287                 if(maxTotalFrags < other.totalfrags)
1288                         maxTotalFrags = other.totalfrags;
1289                 if(minTotalFrags > other.totalfrags)
1290                         minTotalFrags = other.totalfrags;
1291         }
1292
1293         if(!currentbots)
1294         {
1295                 FOR_EACH_PLAYER(other)
1296                 {
1297                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1298                         f = bound(0, other.play_time / max(time, 1), 1);
1299                         // store some statistics?
1300                 }
1301         }
1302
1303         if(cvar("g_campaign"))
1304                 CampaignPreIntermission();
1305
1306         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1307 };
1308
1309 /*
1310 ============
1311 CheckRules_Player
1312
1313 Exit deathmatch games upon conditions
1314 ============
1315 */
1316 void CheckRules_Player()
1317 {
1318         if (gameover)   // someone else quit the game already
1319                 return;
1320
1321         if(self.deadflag == DEAD_NO)
1322                 self.play_time += frametime;
1323
1324         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1325         //   (div0: and that in CheckRules_World please)
1326 };
1327
1328 float checkrules_oneminutewarning;
1329
1330 float checkrules_equality;
1331 float checkrules_suddendeathwarning;
1332 float checkrules_suddendeathend;
1333 float checkrules_overtimesadded; //how many overtimes have been already added
1334 float checkrules_status;
1335
1336 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1337 float WINNING_YES = 1; // winner found
1338 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1339 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1340
1341 void InitiateOvertime()
1342 {
1343         // Check first whether normal overtimes could be added before initiating suddendeath mode
1344         // - for this timelimit_overtime needs to be >0 of course
1345         // - also check the winning condition calculated in the previous frame and only add normal overtime
1346         //   again, if at the point at which timelimit would be extended again, still no winner was found
1347         if ((checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && (checkrules_status == WINNING_NEVER))
1348         {
1349                 ++checkrules_overtimesadded;
1350                 //add one more overtime by simply extending the timelimit
1351                 float tl;
1352                 tl = cvar("timelimit");
1353                 tl += cvar("timelimit_overtime");
1354                 cvar_set("timelimit", ftos(tl));
1355                 string minutesPlural;
1356                 if (cvar("timelimit_overtime") == 1)
1357                         minutesPlural = " ^3minute";
1358                 else
1359                         minutesPlural = " ^3minutes";
1360
1361                 bcenterprint(
1362                         strcat(
1363                                 "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1364                                 ftos(cvar("timelimit_overtime")),
1365                                 minutesPlural,
1366                                 " to the game!"
1367                         )
1368                 );
1369         }
1370         else
1371         {
1372                 if(!checkrules_suddendeathend)
1373                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1374         }
1375 }
1376
1377 float GetWinningCode(float fraglimitreached, float equality)
1378 {
1379         if(equality)
1380                 if(fraglimitreached)
1381                         return WINNING_STARTSUDDENDEATHOVERTIME;
1382                 else
1383                         return WINNING_NEVER;
1384         else
1385                 if(fraglimitreached)
1386                         return WINNING_YES;
1387                 else
1388                         return WINNING_NO;
1389 }
1390
1391 // set the .winning flag for exactly those players with a given field value
1392 void SetWinners(.float field, float value)
1393 {
1394         entity head;
1395         FOR_EACH_PLAYER(head)
1396                 head.winning = (head.field == value);
1397 }
1398
1399 // set the .winning flag for those players with a given field value
1400 void AddWinners(.float field, float value)
1401 {
1402         entity head;
1403         FOR_EACH_PLAYER(head)
1404                 if(head.field == value)
1405                         head.winning = 1;
1406 }
1407
1408 // clear the .winning flags
1409 void ClearWinners(void)
1410 {
1411         entity head;
1412         FOR_EACH_PLAYER(head)
1413                 head.winning = 0;
1414 }
1415
1416 // Onslaught winning condition:
1417 // game terminates if only one team has a working generator (or none)
1418 float WinningCondition_Onslaught()
1419 {
1420         entity head;
1421         local float t1, t2, t3, t4;
1422
1423         WinningConditionHelper(); // set worldstatus
1424
1425         // first check if the game has ended
1426         t1 = t2 = t3 = t4 = 0;
1427         head = find(world, classname, "onslaught_generator");
1428         while (head)
1429         {
1430                 if (head.health > 0)
1431                 {
1432                         if (head.team == COLOR_TEAM1) t1 = 1;
1433                         if (head.team == COLOR_TEAM2) t2 = 1;
1434                         if (head.team == COLOR_TEAM3) t3 = 1;
1435                         if (head.team == COLOR_TEAM4) t4 = 1;
1436                 }
1437                 head = find(head, classname, "onslaught_generator");
1438         }
1439         if (t1 + t2 + t3 + t4 < 2)
1440         {
1441                 // game over, only one team remains (or none)
1442                 ClearWinners();
1443                 if (t1) SetWinners(team, COLOR_TEAM1);
1444                 if (t2) SetWinners(team, COLOR_TEAM2);
1445                 if (t3) SetWinners(team, COLOR_TEAM3);
1446                 if (t4) SetWinners(team, COLOR_TEAM4);
1447                 dprint("Have a winner, ending game.\n");
1448                 return WINNING_YES;
1449         }
1450
1451         // Two or more teams remain
1452         return WINNING_NO;
1453 }
1454
1455 float LMS_NewPlayerLives()
1456 {
1457         float fl;
1458         fl = cvar("fraglimit");
1459         if(fl == 0)
1460                 fl = 999;
1461
1462         // first player has left the game for dying too much? Nobody else can get in.
1463         if(lms_lowest_lives < 1)
1464                 return 0;
1465
1466         if(!cvar("g_lms_join_anytime"))
1467                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1468                         return 0;
1469
1470         return bound(1, lms_lowest_lives, fl);
1471 }
1472
1473 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1474 // they win. Otherwise the defending team wins once the timelimit passes.
1475 void assault_new_round();
1476 float WinningCondition_Assault()
1477 {
1478         local float status;
1479
1480         WinningConditionHelper(); // set worldstatus
1481
1482         status = WINNING_NO;
1483         // as the timelimit has not yet passed just assume the defending team will win
1484         if(assault_attacker_team == COLOR_TEAM1)
1485         {
1486                 SetWinners(team, COLOR_TEAM2);
1487         }
1488         else
1489         {
1490                 SetWinners(team, COLOR_TEAM1);
1491         }
1492
1493         local entity ent;
1494         ent = find(world, classname, "target_assault_roundend");
1495         if(ent)
1496         {
1497                 if(ent.winning) // round end has been triggered by attacking team
1498                 {
1499                         bprint("ASSAULT: round completed...\n");
1500                         SetWinners(team, assault_attacker_team);
1501
1502                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1503
1504                         if(ent.cnt == 1) // this was the second round
1505                         {
1506                                 status = WINNING_YES;
1507                         }
1508                         else
1509                         {
1510                                 local entity oldself;
1511                                 oldself = self;
1512                                 self = ent;
1513                                 assault_new_round();
1514                                 self = oldself;
1515                         }
1516                 }
1517         }
1518
1519         return status;
1520 }
1521
1522 // LMS winning condition: game terminates if and only if there's at most one
1523 // one player who's living lives. Top two scores being equal cancels the time
1524 // limit.
1525 float WinningCondition_LMS()
1526 {
1527         entity head, head2;
1528         float have_player;
1529         float have_players;
1530         float l;
1531
1532         have_player = FALSE;
1533         have_players = FALSE;
1534         l = LMS_NewPlayerLives();
1535
1536         head = find(world, classname, "player");
1537         if(head)
1538                 have_player = TRUE;
1539         head2 = find(head, classname, "player");
1540         if(head2)
1541                 have_players = TRUE;
1542
1543         if(have_player)
1544         {
1545                 // we have at least one player
1546                 if(have_players)
1547                 {
1548                         // two or more active players - continue with the game
1549                 }
1550                 else
1551                 {
1552                         // exactly one player?
1553
1554                         ClearWinners();
1555                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1556
1557                         if(l)
1558                         {
1559                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1560                                 return WINNING_NO;
1561                         }
1562                         else
1563                         {
1564                                 // a winner!
1565                                 // and assign him his first place
1566                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1567                                 return WINNING_YES;
1568                         }
1569                 }
1570         }
1571         else
1572         {
1573                 // nobody is playing at all...
1574                 if(l)
1575                 {
1576                         // wait for players...
1577                 }
1578                 else
1579                 {
1580                         // SNAFU (maybe a draw game?)
1581                         ClearWinners();
1582                         dprint("No players, ending game.\n");
1583                         return WINNING_YES;
1584                 }
1585         }
1586
1587         // When we get here, we have at least two players who are actually LIVING,
1588         // now check if the top two players have equal score.
1589         WinningConditionHelper();
1590
1591         ClearWinners();
1592         if(WinningConditionHelper_winner)
1593                 WinningConditionHelper_winner.winning = TRUE;
1594         if(WinningConditionHelper_equality)
1595                 return WINNING_NEVER;
1596
1597         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1598         return WINNING_NO;
1599 }
1600
1601 void ShuffleMaplist()
1602 {
1603         string result;
1604         float start;
1605         float litems;
1606         float selected;
1607         float i;
1608
1609         result = cvar_string("g_maplist");
1610         litems = tokenizebyseparator(result, " ");
1611
1612         for(start = 0; start < litems - 1; ++start)
1613         {
1614                 result = "";
1615
1616                 // select a random item
1617                 selected = floor(random() * (litems - start) + start);
1618
1619                 // shift this item to the place start
1620                 for(i = 0; i < start; ++i)
1621                         result = strcat(result, " ", argv(i));
1622                 result = strcat(result, " ", argv(selected));
1623                 for(i = start; i < litems; ++i)
1624                         if(i != selected)
1625                                 result = strcat(result, " ", argv(i));
1626                 result = substring(result, 1, strlen(result) - 1);
1627
1628                 litems = tokenizebyseparator(result, " ");
1629
1630                 //dprint(result, "\n");
1631         }
1632
1633         cvar_set("g_maplist", result);
1634 }
1635
1636 float leaderfrags;
1637 float WinningCondition_Scores(float limit)
1638 {
1639         // TODO make everything use THIS winning condition (except LMS)
1640         WinningConditionHelper();
1641
1642         if(teams_matter)
1643         {
1644                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1645                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1646                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1647                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1648         }
1649
1650         ClearWinners();
1651         if(WinningConditionHelper_winner)
1652                 WinningConditionHelper_winner.winning = 1;
1653         if(WinningConditionHelper_winnerteam >= 0)
1654                 SetWinners(team, WinningConditionHelper_winnerteam);
1655
1656         if(WinningConditionHelper_lowerisbetter)
1657         {
1658                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1659                 limit = -limit;
1660         }
1661
1662         if(g_dm || g_tdm || g_arena || (g_race && !g_race_qualifying))
1663         // these modes always score in increments of 1, thus this makes sense
1664         {
1665                 if(leaderfrags != WinningConditionHelper_topscore)
1666                 {
1667                         leaderfrags = WinningConditionHelper_topscore;
1668
1669                         if (limit)
1670                         if (leaderfrags == limit - 1)
1671                                 play2all("announcer/robotic/1fragleft.wav");
1672                         else if (leaderfrags == limit - 2)
1673                                 play2all("announcer/robotic/2fragsleft.wav");
1674                         else if (leaderfrags == limit - 3)
1675                                 play2all("announcer/robotic/3fragsleft.wav");
1676                 }
1677         }
1678
1679         return GetWinningCode(limit && WinningConditionHelper_topscore && (WinningConditionHelper_topscore >= limit), WinningConditionHelper_equality);
1680 }
1681
1682 float WinningCondition_Race(float fraglimit)
1683 {
1684         float wc;
1685         entity p;
1686         wc = WinningCondition_Scores(fraglimit);
1687
1688         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1689         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1690         // do NOT support equality when the laps are all raced!
1691         {
1692                 FOR_EACH_PLAYER(p)
1693                         if not(p.race_completed)
1694                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1695                 return WINNING_YES;
1696         }
1697         return wc;
1698 }
1699
1700 void ReadyRestart();
1701 float WinningCondition_QualifyingThenRace(float limit)
1702 {
1703         float wc;
1704         wc = WinningCondition_Scores(limit);
1705
1706         // NEVER initiate overtime
1707         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1708         {
1709                 return WINNING_YES;
1710         }
1711
1712         return wc;
1713 }
1714
1715 float WinningCondition_RanOutOfSpawns()
1716 {
1717         entity head;
1718
1719         if(!have_team_spawns)
1720                 return WINNING_NO;
1721
1722         if(!some_spawn_has_been_used)
1723                 return WINNING_NO;
1724
1725         team1_score = team2_score = team3_score = team4_score = 0;
1726
1727         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1728         {
1729                 if(head.team == COLOR_TEAM1)
1730                         team1_score = 1;
1731                 else if(head.team == COLOR_TEAM2)
1732                         team2_score = 1;
1733                 else if(head.team == COLOR_TEAM3)
1734                         team3_score = 1;
1735                 else if(head.team == COLOR_TEAM4)
1736                         team4_score = 1;
1737         }
1738
1739         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1740         {
1741                 if(head.team == COLOR_TEAM1)
1742                         team1_score = 1;
1743                 else if(head.team == COLOR_TEAM2)
1744                         team2_score = 1;
1745                 else if(head.team == COLOR_TEAM3)
1746                         team3_score = 1;
1747                 else if(head.team == COLOR_TEAM4)
1748                         team4_score = 1;
1749         }
1750
1751         ClearWinners();
1752         if(team1_score + team2_score + team3_score + team4_score == 0)
1753         {
1754                 checkrules_equality = TRUE;
1755                 return WINNING_YES;
1756         }
1757         else if(team1_score + team2_score + team3_score + team4_score == 1)
1758         {
1759                 float t, i;
1760                 if(team1_score) t = COLOR_TEAM1;
1761                 if(team2_score) t = COLOR_TEAM2;
1762                 if(team3_score) t = COLOR_TEAM3;
1763                 if(team4_score) t = COLOR_TEAM4;
1764                 CheckAllowedTeams(world);
1765                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1766                 {
1767                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1768                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1769                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1770                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1771                 }
1772
1773                 AddWinners(team, t);
1774                 return WINNING_YES;
1775         }
1776         else
1777                 return WINNING_NO;
1778 }
1779
1780 /*
1781 ============
1782 CheckRules_World
1783
1784 Exit deathmatch games upon conditions
1785 ============
1786 */
1787 void CheckRules_World()
1788 {
1789         local float timelimit;
1790         local float fraglimit;
1791
1792         VoteThink();
1793         MapVote_Think();
1794
1795         SetDefaultAlpha();
1796
1797         /*
1798         MapVote_Think should now do that part
1799         if (intermission_running)
1800                 if (time >= intermission_exittime + 60)
1801                 {
1802                         if(!DoNextMapOverride())
1803                                 GotoNextMap();
1804                         return;
1805                 }
1806         */
1807
1808         if (gameover)   // someone else quit the game already
1809         {
1810                 if(player_count == 0) // Nobody there? Then let's go to the next map
1811                         MapVote_Start();
1812                         // this will actually check the player count in the next frame
1813                         // again, but this shouldn't hurt
1814                 return;
1815         }
1816
1817         timelimit = cvar("timelimit") * 60;
1818         fraglimit = cvar("fraglimit");
1819
1820         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1821         {
1822                 if(timelimit > 0)
1823                         timelimit = 0; // timelimit is not made for warmup
1824                 if(fraglimit > 0)
1825                         fraglimit = 0; // no fraglimit for now
1826         }
1827
1828         if(timelimit > 0)
1829         {
1830                 timelimit += game_starttime;
1831         }
1832         else if (timelimit < 0)
1833         {
1834                 // endmatch
1835                 NextLevel();
1836                 return;
1837         }
1838
1839         if(checkrules_suddendeathend)
1840         {
1841                 if(!checkrules_suddendeathwarning)
1842                 {
1843                         checkrules_suddendeathwarning = TRUE;
1844                         if(g_race && !g_race_qualifying)
1845                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1846                         else
1847                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1848                 }
1849         }
1850         else
1851         {
1852                 if (timelimit && time >= timelimit)
1853                 {
1854                         if(g_race && g_race_qualifying == 2 && timelimit > 0)
1855                         {
1856                                 float totalplayers;
1857                                 float playerswithlaps;
1858                                 float readyplayers;
1859                                 entity head;
1860                                 totalplayers = playerswithlaps = readyplayers = 0;
1861                                 FOR_EACH_PLAYER(head)
1862                                 {
1863                                         ++totalplayers;
1864                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1865                                                 ++playerswithlaps;
1866                                         if(head.ready)
1867                                                 ++readyplayers;
1868                                 }
1869
1870                                 // at least 2/3 of the players have completed a lap: start the RACE
1871                                 // otherwise, the players should end the qualifying on their own
1872                                 if(readyplayers || ((totalplayers >= 3) && (playerswithlaps * 3 >= totalplayers * 2)))
1873                                 {
1874                                         checkrules_suddendeathend = 0;
1875                                         ReadyRestart(); // go to race
1876                                 }
1877                                 else
1878                                         InitiateOvertime();
1879                         }
1880                         else
1881                                 InitiateOvertime();
1882                 }
1883         }
1884
1885         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1886         {
1887                 NextLevel();
1888                 return;
1889         }
1890
1891         if (!checkrules_oneminutewarning && timelimit > 0 && time > timelimit - 60)
1892         {
1893                 checkrules_oneminutewarning = TRUE;
1894                 play2all("announcer/robotic/1minuteremains.wav");
1895         }
1896
1897         checkrules_status = WinningCondition_RanOutOfSpawns();
1898         if(checkrules_status == WINNING_YES)
1899         {
1900                 bprint("Hey! Someone ran out of spawns!\n");
1901         }
1902         else if(g_race && !g_race_qualifying && timelimit >= 0)
1903         {
1904                 checkrules_status = WinningCondition_Race(fraglimit);
1905         }
1906         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
1907         {
1908                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
1909         }
1910         else if(g_assault)
1911         {
1912                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
1913         }
1914         else if(g_lms)
1915         {
1916                 checkrules_status = WinningCondition_LMS();
1917         }
1918         else if (g_onslaught)
1919         {
1920                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
1921         }
1922         else
1923         {
1924                 checkrules_status = WinningCondition_Scores(fraglimit);
1925         }
1926
1927         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1928         {
1929                 checkrules_status = WINNING_NEVER;
1930                 InitiateOvertime();
1931         }
1932
1933         if(checkrules_status == WINNING_NEVER)
1934                 // equality cases! Nobody wins if the overtime ends in a draw.
1935                 ClearWinners();
1936
1937         if(checkrules_suddendeathend)
1938                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1939                         checkrules_status = WINNING_YES;
1940
1941         if(checkrules_status == WINNING_YES)
1942                 NextLevel();
1943 };
1944
1945 float mapvote_nextthink;
1946 float mapvote_initialized;
1947 float mapvote_keeptwotime;
1948 float mapvote_timeout;
1949 string mapvote_message;
1950 string mapvote_screenshot_dir;
1951
1952 float mapvote_count;
1953 float mapvote_count_real;
1954 string mapvote_maps[MAPVOTE_COUNT];
1955 float mapvote_maps_suggested[MAPVOTE_COUNT];
1956 string mapvote_suggestions[MAPVOTE_COUNT];
1957 float mapvote_suggestion_ptr;
1958 float mapvote_maxlen;
1959 float mapvote_voters;
1960 float mapvote_votes[MAPVOTE_COUNT];
1961 float mapvote_run;
1962 float mapvote_detail;
1963 float mapvote_abstain;
1964 .float mapvote;
1965
1966 void MapVote_ClearAllVotes()
1967 {
1968         FOR_EACH_CLIENT(other)
1969                 other.mapvote = 0;
1970 }
1971
1972 string MapVote_Suggest(string m)
1973 {
1974         float i;
1975         if(m == "")
1976                 return "That's not how to use this command.";
1977         if(!cvar("g_maplist_votable_suggestions"))
1978                 return "Suggestions are not accepted on this server.";
1979         if(mapvote_initialized)
1980                 return "Can't suggest - voting is already in progress!";
1981         m = MapInfo_FixName(m);
1982         if(!m)
1983                 return "The map you suggested is not available on this server.";
1984         if(!cvar("g_maplist_votable_override_mostrecent"))
1985                 if(Map_IsRecent(m))
1986                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
1987
1988         if(!MapInfo_CheckMap(m))
1989                 return "The map you suggested does not support the current game mode.";
1990         for(i = 0; i < mapvote_suggestion_ptr; ++i)
1991                 if(mapvote_suggestions[i] == m)
1992                         return "This map was already suggested.";
1993         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
1994         {
1995                 i = floor(random() * mapvote_suggestion_ptr);
1996         }
1997         else
1998         {
1999                 i = mapvote_suggestion_ptr;
2000                 mapvote_suggestion_ptr += 1;
2001         }
2002         if(mapvote_suggestions[i] != "")
2003                 strunzone(mapvote_suggestions[i]);
2004         mapvote_suggestions[i] = strzone(m);
2005         if(cvar("sv_eventlog"))
2006                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2007         return strcat("Suggestion of ", m, " accepted.");
2008 }
2009
2010 void MapVote_AddVotable(string nextMap, float isSuggestion)
2011 {
2012         float j;
2013         if(nextMap == "")
2014                 return;
2015         for(j = 0; j < mapvote_count; ++j)
2016                 if(mapvote_maps[j] == nextMap)
2017                         return;
2018         if(strlen(nextMap) > mapvote_maxlen)
2019                 mapvote_maxlen = strlen(nextMap);
2020         mapvote_maps[mapvote_count] = strzone(nextMap);
2021         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2022         mapvote_count += 1;
2023 }
2024
2025 void MapVote_Spawn();
2026 void MapVote_Init()
2027 {
2028         float i;
2029         float nmax, smax;
2030
2031         MapVote_ClearAllVotes();
2032
2033         mapvote_count = 0;
2034         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2035         mapvote_abstain = cvar("g_maplist_votable_abstain");
2036
2037         if(mapvote_abstain)
2038                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2039         else
2040                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2041         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2042
2043         if(mapvote_suggestion_ptr)
2044                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2045                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2046
2047         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2048                 MapVote_AddVotable(GetNextMap(), FALSE);
2049
2050         if(mapvote_count == 0)
2051         {
2052                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2053                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
2054                 if(cvar("g_maplist_shuffle"))
2055                         ShuffleMaplist();
2056                 localcmd("\nmenu_cmd sync\n");
2057                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2058                         MapVote_AddVotable(GetNextMap(), FALSE);
2059         }
2060
2061         mapvote_count_real = mapvote_count;
2062         if(mapvote_abstain)
2063                 MapVote_AddVotable("don't care", 0);
2064
2065         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2066
2067         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2068         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2069         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2070                 mapvote_keeptwotime = 0;
2071         mapvote_message = "Choose a map and press its key!";
2072
2073         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
2074         if(mapvote_screenshot_dir == "")
2075                 mapvote_screenshot_dir = "maps";
2076         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
2077
2078         MapVote_Spawn();
2079 }
2080
2081 void MapVote_SendPicture(float id)
2082 {
2083         msg_entity = self;
2084         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2085         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2086         WriteByte(MSG_ONE, id);
2087         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
2088 }
2089
2090 float GameCommand_MapVote(string cmd)
2091 {
2092         if(!intermission_running)
2093                 return FALSE;
2094
2095         if(cmd == "mv_getpic")
2096         {
2097                 MapVote_SendPicture(stof(argv(1)));
2098                 return TRUE;
2099         }
2100
2101         return FALSE;
2102 }
2103
2104 float MapVote_GetMapMask()
2105 {
2106         float mask, i, power;
2107         mask = 0;
2108         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2109                 if(mapvote_maps[i] != "")
2110                         mask |= power;
2111         return mask;
2112 }
2113
2114 entity mapvote_ent;
2115 float MapVote_SendEntity(entity to, float sf)
2116 {
2117         string mapfile, pakfile;
2118         float i, o;
2119
2120         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2121         WriteByte(MSG_ENTITY, sf);
2122
2123         if(sf & 1)
2124         {
2125                 // flag 1 == initialization
2126                 WriteString(MSG_ENTITY, mapvote_screenshot_dir);
2127                 WriteByte(MSG_ENTITY, mapvote_count);
2128                 WriteByte(MSG_ENTITY, mapvote_abstain);
2129                 WriteByte(MSG_ENTITY, mapvote_detail);
2130                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2131                 if(mapvote_count <= 8)
2132                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2133                 else
2134                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2135                 for(i = 0; i < mapvote_count; ++i)
2136                         if(mapvote_maps[i] != "")
2137                         {
2138                                 WriteString(MSG_ENTITY, mapvote_maps[i]);
2139                                 mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
2140                                 pakfile = whichpack(strcat(mapfile, ".tga"));
2141                                 if(pakfile == "")
2142                                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2143                                 if(pakfile == "")
2144                                         pakfile = whichpack(strcat(mapfile, ".png"));
2145                                 for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2146                                         pakfile = substring(pakfile, o, 999);
2147                                 WriteString(MSG_ENTITY, pakfile);
2148                         }
2149         }
2150
2151         if(sf & 2)
2152         {
2153                 // flag 2 == update of mask
2154                 if(mapvote_count <= 8)
2155                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2156                 else
2157                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2158         }
2159
2160         if(sf & 4)
2161         {
2162                 if(mapvote_detail)
2163                         for(i = 0; i < mapvote_count; ++i)
2164                                 if(mapvote_maps[i] != "")
2165                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2166
2167                 WriteByte(MSG_ENTITY, to.mapvote);
2168         }
2169
2170         return TRUE;
2171 }
2172
2173 void MapVote_Spawn()
2174 {
2175         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2176 }
2177
2178 void MapVote_TouchMask()
2179 {
2180         mapvote_ent.SendFlags |= 2;
2181 }
2182
2183 void MapVote_TouchVotes(entity voter)
2184 {
2185         mapvote_ent.SendFlags |= 4;
2186 }
2187
2188 float MapVote_Finished(float mappos)
2189 {
2190         string result;
2191         float i;
2192         float didntvote;
2193
2194         if(cvar("sv_eventlog"))
2195         {
2196                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2197                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2198                 didntvote = mapvote_voters;
2199                 for(i = 0; i < mapvote_count; ++i)
2200                         if(mapvote_maps[i] != "")
2201                         {
2202                                 didntvote -= mapvote_votes[i];
2203                                 if(i != mappos)
2204                                 {
2205                                         result = strcat(result, ":", mapvote_maps[i]);
2206                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2207                                 }
2208                         }
2209                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2210
2211                 GameLogEcho(result);
2212                 if(mapvote_maps_suggested[mappos])
2213                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2214         }
2215
2216         FOR_EACH_REALCLIENT(other)
2217                 FixClientCvars(other);
2218
2219         Map_Goto_SetStr(mapvote_maps[mappos]);
2220         Map_Goto();
2221         alreadychangedlevel = TRUE;
2222         return TRUE;
2223 }
2224 void MapVote_CheckRules_1()
2225 {
2226         float i;
2227
2228         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2229         {
2230                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2231                 mapvote_votes[i] = 0;
2232         }
2233
2234         mapvote_voters = 0;
2235         FOR_EACH_REALCLIENT(other)
2236         {
2237                 ++mapvote_voters;
2238                 if(other.mapvote)
2239                 {
2240                         i = other.mapvote - 1;
2241                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2242                         mapvote_votes[i] = mapvote_votes[i] + 1;
2243                 }
2244         }
2245 }
2246
2247 float MapVote_CheckRules_2()
2248 {
2249         float i;
2250         float firstPlace, secondPlace;
2251         float firstPlaceVotes, secondPlaceVotes;
2252         float mapvote_voters_real;
2253         string result;
2254
2255         mapvote_voters_real = mapvote_voters;
2256         if(mapvote_abstain)
2257                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2258
2259         RandomSelection_Init();
2260         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2261                 RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2262         firstPlace = RandomSelection_chosen_float;
2263         firstPlaceVotes = RandomSelection_best_priority;
2264         //dprint("First place: ", ftos(firstPlace), "\n");
2265         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2266
2267         RandomSelection_Init();
2268         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2269                 if(i != firstPlace)
2270                         RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2271         secondPlace = RandomSelection_chosen_float;
2272         secondPlaceVotes = RandomSelection_best_priority;
2273         //dprint("Second place: ", ftos(secondPlace), "\n");
2274         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2275
2276         if(firstPlace == -1)
2277                 error("No first place in map vote... WTF?");
2278
2279         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2280                 return MapVote_Finished(firstPlace);
2281
2282         if(mapvote_keeptwotime)
2283                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2284                 {
2285                         float didntvote;
2286                         MapVote_TouchMask();
2287                         mapvote_message = "Now decide between the TOP TWO!";
2288                         mapvote_keeptwotime = 0;
2289                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2290                         result = strcat(result, ":", ftos(firstPlaceVotes));
2291                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2292                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2293                         didntvote = mapvote_voters;
2294                         for(i = 0; i < mapvote_count; ++i)
2295                                 if(mapvote_maps[i] != "")
2296                                 {
2297                                         didntvote -= mapvote_votes[i];
2298                                         if(i != firstPlace)
2299                                                 if(i != secondPlace)
2300                                                 {
2301                                                         result = strcat(result, ":", mapvote_maps[i]);
2302                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2303                                                         if(i < mapvote_count_real)
2304                                                         {
2305                                                                 strunzone(mapvote_maps[i]);
2306                                                                 mapvote_maps[i] = "";
2307                                                         }
2308                                                 }
2309                                 }
2310                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2311                         if(cvar("sv_eventlog"))
2312                                 GameLogEcho(result);
2313                 }
2314
2315         return FALSE;
2316 }
2317 void MapVote_Tick()
2318 {
2319         float keeptwo;
2320         float totalvotes;
2321
2322         keeptwo = mapvote_keeptwotime;
2323         MapVote_CheckRules_1(); // count
2324         if(MapVote_CheckRules_2()) // decide
2325                 return;
2326
2327         totalvotes = 0;
2328         FOR_EACH_REALCLIENT(other)
2329         {
2330                 // hide scoreboard again
2331                 if(other.health != 2342)
2332                 {
2333                         other.health = 2342;
2334                         other.impulse = 0;
2335                         if(clienttype(other) == CLIENTTYPE_REAL)
2336                         {
2337                                 msg_entity = other;
2338                                 WriteByte(MSG_ONE, SVC_FINALE);
2339                                 WriteString(MSG_ONE, "");
2340                         }
2341                 }
2342
2343                 // notify about keep-two
2344                 if(keeptwo != 0 && mapvote_keeptwotime == 0)
2345                         play2(other, "misc/invshot.wav");
2346
2347                 // clear possibly invalid votes
2348                 if(mapvote_maps[other.mapvote - 1] == "")
2349                         other.mapvote = 0;
2350                 // use impulses as new vote
2351                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2352                         if(mapvote_maps[other.impulse - 1] != "")
2353                         {
2354                                 other.mapvote = other.impulse;
2355                                 MapVote_TouchVotes(other);
2356                         }
2357                 other.impulse = 0;
2358
2359                 if(other.mapvote)
2360                         ++totalvotes;
2361         }
2362
2363         MapVote_CheckRules_1(); // just count
2364 }
2365 void MapVote_Start()
2366 {
2367         if(mapvote_run)
2368                 return;
2369
2370         MapInfo_Enumerate();
2371         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 1))
2372                 mapvote_run = TRUE;
2373 }
2374 void MapVote_Think()
2375 {
2376         if(!mapvote_run)
2377                 return;
2378
2379         if(alreadychangedlevel)
2380                 return;
2381
2382         if(time < mapvote_nextthink)
2383                 return;
2384         //dprint("tick\n");
2385
2386         mapvote_nextthink = time + 0.5;
2387
2388         if(!mapvote_initialized)
2389         {
2390                 mapvote_initialized = TRUE;
2391                 if(DoNextMapOverride())
2392                         return;
2393                 if(!cvar("g_maplist_votable") || player_count <= 0)
2394                 {
2395                         GotoNextMap();
2396                         return;
2397                 }
2398                 MapVote_Init();
2399         }
2400
2401         MapVote_Tick();
2402 };
2403
2404 string GotoMap(string m)
2405 {
2406         if(!MapInfo_CheckMap(m))
2407                 return "The map you chose is not available on this server.";
2408         cvar_set("nextmap", m);
2409         cvar_set("timelimit", "-1");
2410         if(mapvote_initialized || alreadychangedlevel)
2411         {
2412                 if(DoNextMapOverride())
2413                         return "Map switch initiated.";
2414                 else
2415                         return "Hm... no. For some reason I like THIS map more.";
2416         }
2417         else
2418                 return "Map switch will happen after scoreboard.";
2419 }
2420
2421
2422 void EndFrame()
2423 {
2424         FOR_EACH_REALCLIENT(self)
2425         {
2426                 if(self.classname == "spectator")
2427                 {
2428                         if(self.enemy.typehitsound)
2429                                 play2(self, "misc/typehit.wav");
2430                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2431                                 play2(self, "misc/hit.wav");
2432                 }
2433                 else
2434                 {
2435                         if(self.typehitsound)
2436                                 play2(self, "misc/typehit.wav");
2437                         else if(self.hitsound && self.cvar_cl_hitsound)
2438                                 play2(self, "misc/hit.wav");
2439                 }
2440         }
2441         FOR_EACH_CLIENT(self)
2442         {
2443                 self.hitsound = FALSE;
2444                 self.typehitsound = FALSE;
2445         }
2446 }
2447
2448
2449 /*
2450  * RedirectionThink:
2451  * returns TRUE if redirecting
2452  */
2453 float redirection_timeout;
2454 float redirection_nextthink;
2455 float RedirectionThink()
2456 {
2457         float clients_found;
2458
2459         if(redirection_target == "")
2460                 return FALSE;
2461
2462         if(!redirection_timeout)
2463         {
2464                 cvar_set("sv_public", "-2");
2465                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2466                 if(redirection_target == "self")
2467                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2468                 else
2469                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2470         }
2471
2472         if(time < redirection_nextthink)
2473                 return TRUE;
2474
2475         redirection_nextthink = time + 1;
2476
2477         clients_found = 0;
2478         FOR_EACH_REALCLIENT(self)
2479         {
2480                 print("Redirecting: sending connect command to ", self.netname, "\n");
2481                 if(redirection_target == "self")
2482                         stuffcmd(self, "\ndisconnect; reconnect\n");
2483                 else
2484                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2485                 ++clients_found;
2486         }
2487
2488         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2489
2490         if(time > redirection_timeout || clients_found == 0)
2491                 localcmd("\nwait; wait; wait; quit\n");
2492
2493         return TRUE;
2494 }
2495
2496 void RestoreGame()
2497 {
2498         // Loaded from a save game
2499         // some things then break, so let's work around them...
2500
2501         // Progs DB (capture records)
2502         if(sv_cheats)
2503                 ServerProgsDB = db_create();
2504         else
2505                 ServerProgsDB = db_load("server.db");
2506
2507         // Mapinfo
2508         MapInfo_Shutdown();
2509         MapInfo_Enumerate();
2510         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 1);
2511 }
2512
2513 void SV_Shutdown()
2514 {
2515         if(world_initialized > 0)
2516         {
2517                 world_initialized = 0;
2518                 print("Saving persistent data...\n");
2519                 Ban_SaveBans();
2520                 if(!sv_cheats)
2521                         db_save(ServerProgsDB, "server.db");
2522                 if(cvar("developer"))
2523                         db_save(TemporaryDB, "server-temp.db");
2524                 db_close(ServerProgsDB);
2525                 db_close(TemporaryDB);
2526                 print("done!\n");
2527                 // tell the bot system the game is ending now
2528                 bot_endgame();
2529
2530                 MapInfo_Shutdown();
2531         }
2532         else if(world_initialized == 0)
2533         {
2534                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2535         }
2536 }