data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 void SetDefaultAlpha()
  12 {
  13         if(cvar("g_running_guns"))
  14         {
  15                 default_player_alpha = -1;
  16                 default_weapon_alpha = +1;
  17         }
  18         else if(g_cloaked)
  19         {
  20                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23         else
  24         {
  25                 default_player_alpha = cvar("g_player_alpha");
  26                 if(default_player_alpha == 0)
  27                         default_player_alpha = 1;
  28                 default_weapon_alpha = default_player_alpha;
  29         }
  30 }
  31
  32 void fteqcc_testbugs()
  33 {
  34         float a, b;
  35
  36         if(!cvar("developer_fteqccbugs"))
  37                 return;
  38
  39         dprint("*** fteqcc test: checking for bugs...\n");
  40
  41         a = 1;
  42         b = 5;
  43         if(sqrt(a) - sqrt(b - a) == 0)
  44                 dprint("*** fteqcc test: found same-function-twice bug\n");
  45         else
  46                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  47
  48         world.cnt = -10;
  49         world.enemy = world;
  50         world.enemy.cnt += 10;
  51         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  52                 dprint("*** fteqcc test: found += bug\n");
  53         else
  54                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  55         world.cnt = 0;
  56 }
  57
  58 /**
  59  * Takes care of pausing and unpausing the game.
  60  * Centerprints the information about an upcoming or active timeout to all active
  61  * players. Also plays reminder sounds.
  62  */
  63 void timeoutHandler_Think() {
  64         local string timeStr;
  65         local entity plr;
  66         if (timeoutStatus == 1) {
  67                 if (remainingLeadTime > 0) {
  68                         //centerprint the information to every player
  69                         timeStr = getTimeoutText(0);
  70                         FOR_EACH_REALCLIENT(plr) {
  71                                 if(plr.classname == "player") {
  72                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  73                                 }
  74                         }
  75                         remainingLeadTime -= 1;
  76                         //think again in 1 second:
  77                         self.nextthink = time + 1;
  78                 }
  79                 else {
  80                         //now pause the game:
  81                         timeoutStatus = 2;
  82                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  83                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  84                         FOR_EACH_REALPLAYER(plr) {
  85                                 plr.lastV_angle = plr.v_angle;
  86                         }
  87                         self.nextthink = time;
  88                 }
  89         }
  90         else if (timeoutStatus == 2) {
  91                 if (remainingTimeoutTime > 0) {
  92                         timeStr = getTimeoutText(0);
  93                         FOR_EACH_REALCLIENT(plr) {
  94                                 if(plr.classname == "player") {
  95                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  96                                 }
  97                         }
  98                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
  99                                 play2all("announcer/robotic/prepareforbattle.wav");
 100                         }
 101                         remainingTimeoutTime -= 1;
 102                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 103                 }
 104                 else {
 105                         //unpause the game again
 106                         remainingTimeoutTime = timeoutStatus = 0;
 107                         cvar_set("slowmo", ftos(orig_slowmo));
 108                         //and unlock the fixed view again once there is no timeout active anymore
 109                         FOR_EACH_REALPLAYER(plr) {
 110                                 plr.fixangle = FALSE;
 111                         }
 112                         //get rid of the countdown message
 113                         FOR_EACH_REALCLIENT(plr) {
 114                                 if(plr.classname == "player") {
 115                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 116                                 }
 117                         }
 118                         remove(self);
 119                         return;
 120                 }
 121
 122         }
 123         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 124                 FOR_EACH_REALCLIENT(plr) {
 125                         if(plr.classname == "player") {
 126                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 127                         }
 128                 }
 129                 remove(self);
 130                 return;
 131         }
 132 }
 133
 134 void GotoFirstMap()
 135 {
 136         float n;
 137         if(cvar("_sv_init"))
 138         {
 139                 // cvar_set("_sv_init", "0");
 140                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 141                 // to this "init" map on a dedicated server will cause no permanent
 142                 // harm
 143                 if(cvar("g_maplist_shuffle"))
 144                         ShuffleMaplist();
 145                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 146                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 147
 148                 MapInfo_Enumerate();
 149                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 0);
 150
 151                 if(!DoNextMapOverride())
 152                         GotoNextMap();
 153
 154                 return;
 155         }
 156
 157         if(time < 5)
 158         {
 159                 self.nextthink = time;
 160         }
 161         else
 162         {
 163                 self.nextthink = time + 1;
 164                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 165         }
 166 }
 167
 168 void cvar_changes_init()
 169 {
 170         float h;
 171         string k, v, d;
 172         float n, i;
 173
 174         if(cvar_changes)
 175                 strunzone(cvar_changes);
 176         cvar_changes = string_null;
 177
 178         h = buf_create();
 179         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 180         n = buf_getsize(h);
 181
 182         for(i = 0; i < n; ++i)
 183         {
 184                 k = bufstr_get(h, i);
 185
 186 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 187 #define BADCVAR(p) if(k == p) continue
 188                 // internal
 189                 BADPREFIX("csqc_");
 190                 BADPREFIX("cvar_check_");
 191                 BADCVAR("gamecfg");
 192                 BADCVAR("g_configversion");
 193                 BADCVAR("g_maplist_index");
 194                 BADCVAR("halflifebsp");
 195
 196                 // client
 197                 BADPREFIX("cl_");
 198                 BADPREFIX("con_");
 199                 BADPREFIX("g_campaign");
 200                 BADPREFIX("gl_");
 201                 BADPREFIX("joy");
 202                 BADPREFIX("menu_");
 203                 BADPREFIX("net_slist_");
 204                 BADPREFIX("r_");
 205                 BADPREFIX("sbar_");
 206                 BADPREFIX("scr_");
 207                 BADPREFIX("userbind");
 208                 BADPREFIX("v_");
 209                 BADPREFIX("vid_");
 210                 BADPREFIX("crosshair");
 211                 BADCVAR("mod_q3bsp_lightmapmergepower");
 212                 BADCVAR("mod_q3bsp_nolightmaps");
 213
 214                 // private
 215                 BADPREFIX("g_ban_");
 216                 BADPREFIX("g_chat_flood_");
 217                 BADPREFIX("g_voice_flood_");
 218                 BADPREFIX("rcon_");
 219                 BADPREFIX("settemp_");
 220                 BADPREFIX("sv_allowdownloads_");
 221                 BADPREFIX("sv_autodemo");
 222                 BADPREFIX("sv_curl_");
 223                 BADPREFIX("sv_eventlog");
 224                 BADPREFIX("sv_logscores_");
 225                 BADPREFIX("sv_master");
 226                 BADCVAR("g_banned_list");
 227                 BADCVAR("log_dest_udp");
 228                 BADCVAR("log_file");
 229                 BADCVAR("net_address");
 230                 BADCVAR("port");
 231                 BADCVAR("savedgamecfg");
 232                 BADCVAR("sv_heartbeatperoid");
 233                 BADCVAR("sv_vote_master_password");
 234                 BADCVAR("sys_colortranslation");
 235                 BADCVAR("sys_specialcharactertranslation");
 236                 BADCVAR("timestamps");
 237
 238                 // mapinfo
 239                 BADCVAR("timelimit");
 240                 BADCVAR("fraglimit");
 241                 BADCVAR("g_arena");
 242                 BADCVAR("g_assault");
 243                 BADCVAR("g_ctf");
 244                 BADCVAR("g_dm");
 245                 BADCVAR("g_domination");
 246                 BADCVAR("g_keyhunt");
 247                 BADCVAR("g_keyhunt_teams");
 248                 BADCVAR("g_onslaught");
 249                 BADCVAR("g_race");
 250                 BADCVAR("g_runematch");
 251                 BADCVAR("g_tdm");
 252                 BADCVAR("teamplay");
 253
 254                 // long
 255                 BADCVAR("hostname");
 256                 BADCVAR("g_maplist");
 257                 BADCVAR("g_maplist_mostrecent");
 258                 BADCVAR("sv_motd");
 259 #undef BADPREFIX
 260 #undef BADCVAR
 261
 262                 v = cvar_string(k);
 263                 d = cvar_defstring(k);
 264                 if(v != d)
 265                 {
 266                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 267                         if(strlen(cvar_changes) > 16384)
 268                         {
 269                                 cvar_changes = "// too many settings have been changed to show them here\n";
 270                                 break;
 271                         }
 272                 }
 273         }
 274         buf_del(h);
 275         if(cvar_changes == "")
 276                 cvar_changes = "// this server runs at default settings\n";
 277         else
 278                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 279         cvar_changes = strzone(cvar_changes);
 280 }
 281
 282 void detect_maptype()
 283 {
 284 #if 0
 285         vector o, v;
 286         float i;
 287
 288         for(;;)
 289         {
 290                 o = world.mins;
 291                 o_x += random() * (world.maxs_x - world.mins_x);
 292                 o_y += random() * (world.maxs_y - world.mins_y);
 293                 o_z += random() * (world.maxs_z - world.mins_z);
 294
 295                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 296                 if(trace_fraction == 1)
 297                         continue;
 298
 299                 v = trace_endpos;
 300
 301                 for(i = 0; i < 64; i += 4)
 302                 {
 303                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 304         if(trace_fraction == 1)
 305                 continue;
 306                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 307                 }
 308
 309                 break;
 310         }
 311 #endif
 312 }
 313
 314 entity randomseed;
 315 float RandomSeed_Send(entity to, float sf)
 316 {
 317         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 318         WriteShort(MSG_ENTITY, self.cnt);
 319         return TRUE;
 320 }
 321 void RandomSeed_Think()
 322 {
 323         self.cnt = bound(0, floor(random() * 65536), 65535);
 324         self.nextthink = time + 5;
 325
 326         self.SendFlags |= 1;
 327 }
 328 void RandomSeed_Spawn()
 329 {
 330         randomseed = spawn();
 331         randomseed.think = RandomSeed_Think;
 332         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 333
 334         entity oldself;
 335         oldself = self;
 336         self = randomseed;
 337         self.think(); // sets random seed and nextthink
 338         self = oldself;
 339 }
 340
 341 void spawnfunc___init_dedicated_server(void)
 342 {
 343         // handler for _init/_init map (only for dedicated server initialization)
 344
 345         world_initialized = -1; // don't complain
 346         cvar = cvar_builtin;
 347         cvar_string = cvar_string_builtin;
 348         cvar_set = cvar_set_builtin;
 349         dprint_load(); // load dprint status from cvar
 350
 351         remove = remove_unsafely;
 352
 353         entity e;
 354         e = spawn();
 355         e.think = GotoFirstMap;
 356         e.nextthink = time; // this is usually 1 at this point
 357
 358         e = spawn();
 359         e.classname = "info_player_deathmatch"; // safeguard against player joining
 360
 361         self.classname = "worldspawn"; // safeguard against various stuff ;)
 362
 363         g_maplist_allow_hidden = cvar("g_maplist_allow_hidden");
 364         MapInfo_Enumerate();
 365         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 0);
 366 }
 367
 368 void Map_MarkAsRecent(string m);
 369 float world_already_spawned;
 370 void RegisterWeapons();
 371 void Nagger_Init();
 372 void ClientInit_Spawn();
 373 void spawnfunc_worldspawn (void)
 374 {
 375         float fd, l, i, j, n;
 376         string s, col;
 377
 378         cvar = cvar_builtin;
 379         cvar_string = cvar_string_builtin;
 380         cvar_set = cvar_set_builtin;
 381         dprint_load(); // load dprint status from cvar
 382
 383         if(world_already_spawned)
 384                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 385         world_already_spawned = TRUE;
 386
 387         remove = remove_safely; // during spawning, watch what you remove!
 388
 389         if(cvar_string("cvar_check_default") != "bypass")
 390         {
 391                 if(cvar_string("cvar_check_default") != CVAR_CHECK_DEFAULT)
 392                         error("Config file mismatch! Please update defaultNexuiz.cfg to match the QuakeC code, and restart the engine!");
 393
 394                 if(cvar_string("cvar_check_weapons") != CVAR_CHECK_WEAPONS)
 395                         error("Config file mismatch! Please update weapons.cfg and weaponsHavoc.cfg to match the QuakeC code, and restart the engine!");
 396         }
 397
 398         compressShortVector_init();
 399
 400         local entity head;
 401         head = nextent(world);
 402         maxclients = 0;
 403         while(head)
 404         {
 405                 ++maxclients;
 406                 head = nextent(head);
 407         }
 408
 409         // needs to be done so early as they would still spawn
 410         RegisterWeapons();
 411
 412         if(sv_cheats)
 413                 ServerProgsDB = db_create();
 414         else
 415                 ServerProgsDB = db_load("server.db");
 416
 417         TemporaryDB = db_create();
 418
 419         /*
 420         TODO sound pack system
 421         // initialize sound pack system
 422         soundpack = cvar_string("g_soundpack");
 423         if(soundpack != "")
 424                 soundpack = strcat(soundpack, "/");
 425         soundpack = strzone(soundpack);
 426         */
 427
 428         // 0 normal
 429         lightstyle(0, "m");
 430
 431         // 1 FLICKER (first variety)
 432         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 433
 434         // 2 SLOW STRONG PULSE
 435         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 436
 437         // 3 CANDLE (first variety)
 438         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 439
 440         // 4 FAST STROBE
 441         lightstyle(4, "mamamamamama");
 442
 443         // 5 GENTLE PULSE 1
 444         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 445
 446         // 6 FLICKER (second variety)
 447         lightstyle(6, "nmonqnmomnmomomno");
 448
 449         // 7 CANDLE (second variety)
 450         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 451
 452         // 8 CANDLE (third variety)
 453         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 454
 455         // 9 SLOW STROBE (fourth variety)
 456         lightstyle(9, "aaaaaaaazzzzzzzz");
 457
 458         // 10 FLUORESCENT FLICKER
 459         lightstyle(10, "mmamammmmammamamaaamammma");
 460
 461         // 11 SLOW PULSE NOT FADE TO BLACK
 462         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 463
 464         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 465
 466         // 63 testing
 467         lightstyle(63, "a");
 468
 469         if(cvar("g_campaign"))
 470                 CampaignPreInit();
 471
 472         Map_MarkAsRecent(mapname);
 473
 474         precache_model ("null"); // we need this one before InitGameplayMode
 475         InitGameplayMode();
 476         readlevelcvars();
 477         GrappleHookInit();
 478
 479         player_count = 0;
 480         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 481         if(bot_waypoints_for_items == 1)
 482                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 483                         bot_waypoints_for_items = 0;
 484
 485         // for setting by mapinfo
 486         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 487         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 488
 489         precache();
 490
 491         WaypointSprite_Init();
 492
 493         //if (g_domination)
 494         //      dom_init();
 495
 496         GameLogInit(); // prepare everything
 497         if(cvar("sv_eventlog"))
 498         {
 499                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 500                 s = strcat(s, ftos(random()));
 501                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 502                 s = ":gameinfo:mutators:LIST";
 503                 if(cvar("g_grappling_hook"))
 504                         s = strcat(s, ":grappling_hook");
 505                 if(!cvar("g_use_ammunition"))
 506                         s = strcat(s, ":no_use_ammunition");
 507                 if(!cvar("g_pickup_items"))
 508                         s = strcat(s, ":no_pickup_items");
 509                 if(cvar("g_instagib"))
 510                         s = strcat(s, ":instagib");
 511                 if(cvar_string("g_weaponarena") != "0")
 512                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 513                 if(cvar("g_nixnex"))
 514                         s = strcat(s, ":nixnex");
 515                 if(cvar("g_vampire"))
 516                         s = strcat(s, ":vampire");
 517                 if(cvar("g_laserguided_missile"))
 518                         s = strcat(s, ":laserguided_missile");
 519                 if(cvar("g_norecoil"))
 520                         s = strcat(s, ":norecoil");
 521                 if(cvar("g_midair"))
 522                         s = strcat(s, ":midair");
 523                 if(cvar("g_minstagib"))
 524                         s = strcat(s, ":minstagib");
 525                 GameLogEcho(s);
 526                 GameLogEcho(":gameinfo:end");
 527         }
 528
 529         cvar_set("nextmap", "");
 530
 531         SetDefaultAlpha();
 532
 533         if(cvar("g_campaign"))
 534                 CampaignPostInit();
 535
 536         fteqcc_testbugs();
 537
 538         Ban_LoadBans();
 539
 540         //initialise globals related to sv_timeout
 541         sys_ticrate = cvar("sys_ticrate");
 542         orig_slowmo = cvar("slowmo");
 543
 544         MapInfo_Enumerate();
 545         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 1);
 546
 547         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 548         {
 549                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 550                 if(fd != -1)
 551                 {
 552                         while((s = fgets(fd)))
 553                         {
 554                                 l = tokenize_sane(s);
 555                                 if(l < 2)
 556                                         continue;
 557                                 if(argv(0) == "cd")
 558                                 {
 559                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 560                                         print("  cdtrack ", argv(2), "\n");
 561                                 }
 562                                 else if(argv(0) == "fog")
 563                                 {
 564                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 565                                         print("  \"fog\" \"", s, "\"\n");
 566                                 }
 567                                 else if(argv(0) == "set")
 568                                 {
 569                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 570                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 571                                 }
 572                                 else if(argv(0) != "//")
 573                                 {
 574                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 575                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 576                                 }
 577                         }
 578                         fclose(fd);
 579                 }
 580         }
 581
 582         addstat(STAT_SYS_TICRATE, AS_FLOAT, stat_sys_ticrate);
 583         addstat(STAT_WEAPONS, AS_INT, weapons);
 584         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 585         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 586         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 587         Nagger_Init();
 588
 589         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 590         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 591         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 592         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 593
 594         next_pingtime = time + 5;
 595         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 596
 597         detect_maptype();
 598
 599         lsmaps_reply = "^7Maps available: ";
 600         for(i = 0, j = 0; i < MapInfo_count; ++i)
 601         {
 602                 if(MapInfo_Get_ByID(i))
 603                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 604                         {
 605                                 if(mod(i, 2))
 606                                         col = "^2";
 607                                 else
 608                                         col = "^3";
 609                                 ++j;
 610                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 611                         }
 612         }
 613         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 614
 615         maplist_reply = "^7Maps in list: ";
 616         n = tokenize_sane(cvar_string("g_maplist"));
 617         for(i = 0, j = 0; i < n; ++i)
 618         {
 619                 if(MapInfo_CheckMap(argv(i)))
 620                 {
 621                         if(mod(j, 2))
 622                                 col = "^2";
 623                         else
 624                                 col = "^3";
 625                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 626                         ++j;
 627                 }
 628         }
 629         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 630         MapInfo_ClearTemps();
 631
 632         records_reply = strzone(getrecords());
 633
 634         ClientInit_Spawn();
 635         RandomSeed_Spawn();
 636
 637         world_initialized = 1;
 638 }
 639
 640 void spawnfunc_light (void)
 641 {
 642         //makestatic (self); // Who the f___ did that?
 643         remove(self);
 644 }
 645
 646 float TryFile( string pFilename )
 647 {
 648         local float lHandle;
 649         dprint("TryFile(\"", pFilename, "\")\n");
 650         lHandle = fopen( pFilename, FILE_READ );
 651         if( lHandle != -1 ) {
 652                 fclose( lHandle );
 653                 return TRUE;
 654         } else {
 655                 return FALSE;
 656         }
 657 };
 658
 659 string GetGametype()
 660 {
 661         return GametypeNameFromType(game);
 662 }
 663
 664 string getmapname_stored;
 665 string GetMapname()
 666 {
 667         return mapname;
 668 }
 669
 670 float Map_Count, Map_Current;
 671 string Map_Current_Name;
 672
 673 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 674 float GetMaplistPosition()
 675 {
 676         float pos, idx;
 677         string map;
 678
 679         map = GetMapname();
 680         idx = cvar("g_maplist_index");
 681
 682         if(idx >= 0)
 683                 if(idx < Map_Count)
 684                         if(map == argv(idx))
 685                                 return idx;
 686
 687         for(pos = 0; pos < Map_Count; ++pos)
 688                 if(map == argv(pos))
 689                         return pos;
 690
 691         // resume normal maplist rotation if current map is not in g_maplist
 692         return idx;
 693 }
 694
 695 float MapHasRightSize(string map)
 696 {
 697         float fh;
 698         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 699         if(cvar("g_maplist_check_waypoints"))
 700         {
 701                 dprint("checkwp "); dprint(map);
 702                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 703                 if(fh < 0)
 704                 {
 705                         dprint(": no waypoints\n");
 706                         return FALSE;
 707                 }
 708                 dprint(": has waypoints\n");
 709                 fclose(fh);
 710         }
 711
 712         // open map size restriction file
 713         dprint("opensize "); dprint(map);
 714         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 715         if(fh >= 0)
 716         {
 717                 float mapmin, mapmax;
 718                 dprint(": ok, ");
 719                 mapmin = stof(fgets(fh));
 720                 mapmax = stof(fgets(fh));
 721                 fclose(fh);
 722                 if(player_count < mapmin)
 723                 {
 724                         dprint("not enough\n");
 725                         return FALSE;
 726                 }
 727                 if(player_count > mapmax)
 728                 {
 729                         dprint("too many\n");
 730                         return FALSE;
 731                 }
 732                 dprint("right size\n");
 733                 return TRUE;
 734         }
 735         dprint(": not found\n");
 736         return TRUE;
 737 }
 738
 739 string Map_Filename(float position)
 740 {
 741         return strcat("maps/", argv(position), ".bsp");
 742 }
 743
 744 string strwords(string s, float w)
 745 {
 746         float endpos;
 747         for(endpos = 0; w && endpos >= 0; --w)
 748                 endpos = strstrofs(s, " ", endpos + 1);
 749         if(endpos < 0)
 750                 return s;
 751         else
 752                 return substring(s, 0, endpos);
 753 }
 754
 755 float strhasword(string s, string w)
 756 {
 757         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 758 }
 759
 760 void Map_MarkAsRecent(string m)
 761 {
 762         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
 763 }
 764
 765 float Map_IsRecent(string m)
 766 {
 767         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 768 }
 769
 770 float Map_Check(float position, float pass)
 771 {
 772         string filename;
 773         string map_next;
 774         map_next = argv(position);
 775         if(pass <= 1)
 776         {
 777                 if(Map_IsRecent(map_next))
 778                         return 0;
 779         }
 780         filename = Map_Filename(position);
 781         if(MapInfo_CheckMap(map_next))
 782         {
 783                 if(pass == 2)
 784                         return 1;
 785                 if(MapHasRightSize(map_next))
 786                         return 1;
 787                 return 0;
 788         }
 789         else
 790                 dprint( "Couldn't select '", filename, "'..\n" );
 791
 792         return 0;
 793 }
 794
 795 void Map_Goto_SetStr(string nextmapname)
 796 {
 797         if(getmapname_stored != "")
 798                 strunzone(getmapname_stored);
 799         if(nextmapname == "")
 800                 getmapname_stored = "";
 801         else
 802                 getmapname_stored = strzone(nextmapname);
 803 }
 804
 805 void Map_Goto_SetFloat(float position)
 806 {
 807         cvar_set("g_maplist_index", ftos(position));
 808         Map_Goto_SetStr(argv(position));
 809 }
 810
 811 void GameResetCfg()
 812 {
 813         // settings persist, except...
 814         localcmd("\nsettemp_restore\n");
 815 };
 816
 817 void Map_Goto()
 818 {
 819         GameResetCfg();
 820         MapInfo_LoadMap(getmapname_stored);
 821 }
 822
 823 // return codes of map selectors:
 824 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 825 //   -2 = permanent failure
 826 float() MaplistMethod_Iterate = // usual method
 827 {
 828         float pass, i;
 829
 830         for(pass = 1; pass <= 2; ++pass)
 831         {
 832                 for(i = 1; i < Map_Count; ++i)
 833                 {
 834                         float mapindex;
 835                         mapindex = mod(i + Map_Current, Map_Count);
 836                         if(Map_Check(mapindex, pass))
 837                                 return mapindex;
 838                 }
 839         }
 840         return -1;
 841 }
 842
 843 float() MaplistMethod_Repeat = // fallback method
 844 {
 845         if(Map_Check(Map_Current, 2))
 846                 return Map_Current;
 847         return -2;
 848 }
 849
 850 float() MaplistMethod_Random = // random map selection
 851 {
 852         float i, imax;
 853
 854         imax = 42;
 855
 856         for(i = 0; i <= imax; ++i)
 857         {
 858                 float mapindex;
 859                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 860                 if(Map_Check(mapindex, 1))
 861                         return mapindex;
 862         }
 863         return -1;
 864 }
 865
 866 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 867 // the exponent sets a bias on the map selection:
 868 // the higher the exponent, the less likely "shortly repeated" same maps are
 869 {
 870         float i, j, imax, insertpos;
 871
 872         imax = 42;
 873
 874         for(i = 0; i <= imax; ++i)
 875         {
 876                 string newlist;
 877
 878                 // now reinsert this at another position
 879                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 880                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 881                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 882                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 883
 884                 // insert the current map there
 885                 newlist = "";
 886                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 887                         newlist = strcat(newlist, " ", argv(j));
 888                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 889                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 890                         newlist = strcat(newlist, " ", argv(j));
 891                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 892                 cvar_set("g_maplist", newlist);
 893                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 894
 895                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 896                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 897                 if(Map_Check(Map_Current, 1))
 898                         return Map_Current;
 899         }
 900         return -1;
 901 }
 902
 903 void Maplist_Init()
 904 {
 905         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 906         if(Map_Count == 0)
 907         {
 908                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 909                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN));
 910                 if(cvar("g_maplist_shuffle"))
 911                         ShuffleMaplist();
 912                 localcmd("\nmenu_cmd sync\n");
 913                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 914         }
 915         if(Map_Count == 0)
 916                 error("empty maplist, cannot select a new map");
 917         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 918
 919         if(Map_Current_Name)
 920                 strunzone(Map_Current_Name);
 921         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 922         // this may or may not be correct, but who cares, in the worst case a map
 923         // isn't chosen in the first pass that should have been
 924 }
 925
 926 string GetNextMap()
 927 {
 928         float nextMap;
 929
 930         Maplist_Init();
 931         nextMap = -1;
 932
 933         if(nextMap == -1)
 934                 if(cvar("g_maplist_shuffle") > 0)
 935                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 936
 937         if(nextMap == -1)
 938                 if(cvar("g_maplist_selectrandom"))
 939                         nextMap = MaplistMethod_Random();
 940
 941         if(nextMap == -1)
 942                 nextMap = MaplistMethod_Iterate();
 943
 944         if(nextMap == -1)
 945                 nextMap = MaplistMethod_Repeat();
 946
 947         if(nextMap >= 0)
 948         {
 949                 Map_Goto_SetFloat(nextMap);
 950                 return getmapname_stored;
 951         }
 952
 953         return "";
 954 };
 955
 956 float DoNextMapOverride()
 957 {
 958         if(cvar("g_campaign"))
 959         {
 960                 CampaignPostIntermission();
 961                 alreadychangedlevel = TRUE;
 962                 return TRUE;
 963         }
 964         if(cvar("quit_when_empty"))
 965         {
 966                 if(player_count <= currentbots)
 967                 {
 968                         localcmd("quit\n");
 969                         alreadychangedlevel = TRUE;
 970                         return TRUE;
 971                 }
 972         }
 973         if(cvar_string("quit_and_redirect") != "")
 974         {
 975                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 976                 alreadychangedlevel = TRUE;
 977                 return TRUE;
 978         }
 979         if (cvar("samelevel")) // if samelevel is set, stay on same level
 980         {
 981                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 982                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 983                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 984                 localcmd("restart\n");
 985                 //changelevel (mapname);
 986                 alreadychangedlevel = TRUE;
 987                 return TRUE;
 988         }
 989         if(cvar_string("nextmap") != "")
 990                 if(MapInfo_CheckMap(cvar_string("nextmap")))
 991                 {
 992                         Map_Goto_SetStr(cvar_string("nextmap"));
 993                         Map_Goto();
 994                         alreadychangedlevel = TRUE;
 995                         return TRUE;
 996                 }
 997         if(cvar("lastlevel"))
 998         {
 999                 GameResetCfg();
1000                 localcmd("set lastlevel 0\ntogglemenu\n");
1001                 alreadychangedlevel = TRUE;
1002                 return TRUE;
1003         }
1004         return FALSE;
1005 };
1006
1007 void GotoNextMap()
1008 {
1009         //local string nextmap;
1010         //local float n, nummaps;
1011         //local string s;
1012         if (alreadychangedlevel)
1013                 return;
1014         alreadychangedlevel = TRUE;
1015
1016         {
1017                 string nextMap;
1018                 float allowReset;
1019
1020                 for(allowReset = 1; allowReset >= 0; --allowReset)
1021                 {
1022                         nextMap = GetNextMap();
1023                         if(nextMap != "")
1024                                 break;
1025
1026                         if(allowReset)
1027                         {
1028                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1029                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN));
1030                                 if(cvar("g_maplist_shuffle"))
1031                                         ShuffleMaplist();
1032                                 localcmd("\nmenu_cmd sync\n");
1033                         }
1034                         else
1035                         {
1036                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1037                         }
1038                 }
1039                 Map_Goto();
1040         }
1041 };
1042
1043
1044 /*
1045 ============
1046 IntermissionThink
1047
1048 When the player presses attack or jump, change to the next level
1049 ============
1050 */
1051 .float autoscreenshot;
1052 void() MapVote_Start;
1053 void() MapVote_Think;
1054 float mapvote_initialized;
1055 void IntermissionThink()
1056 {
1057         FixIntermissionClient(self);
1058
1059         if(cvar("sv_autoscreenshot"))
1060         if(self.autoscreenshot > 0)
1061         if(time > self.autoscreenshot)
1062         {
1063                 self.autoscreenshot = -1;
1064                 if(clienttype(self) == CLIENTTYPE_REAL)
1065                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1066                 return;
1067         }
1068
1069         if (time < intermission_exittime)
1070                 return;
1071
1072         if(!mapvote_initialized)
1073                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1074                         return;
1075
1076         MapVote_Start();
1077 };
1078
1079 /*
1080 ============
1081 FindIntermission
1082
1083 Returns the entity to view from
1084 ============
1085 */
1086 /*
1087 entity FindIntermission()
1088 {
1089         local   entity spot;
1090         local   float cyc;
1091
1092 // look for info_intermission first
1093         spot = find (world, classname, "info_intermission");
1094         if (spot)
1095         {       // pick a random one
1096                 cyc = random() * 4;
1097                 while (cyc > 1)
1098                 {
1099                         spot = find (spot, classname, "info_intermission");
1100                         if (!spot)
1101                                 spot = find (spot, classname, "info_intermission");
1102                         cyc = cyc - 1;
1103                 }
1104                 return spot;
1105         }
1106
1107 // then look for the start position
1108         spot = find (world, classname, "info_player_start");
1109         if (spot)
1110                 return spot;
1111
1112 // testinfo_player_start is only found in regioned levels
1113         spot = find (world, classname, "testplayerstart");
1114         if (spot)
1115                 return spot;
1116
1117 // then look for the start position
1118         spot = find (world, classname, "info_player_deathmatch");
1119         if (spot)
1120                 return spot;
1121
1122         //objerror ("FindIntermission: no spot");
1123         return world;
1124 };
1125 */
1126
1127 /*
1128 ===============================================================================
1129
1130 RULES
1131
1132 ===============================================================================
1133 */
1134
1135 void DumpStats(float final)
1136 {
1137         local float file;
1138         local string s;
1139         local float to_console;
1140         local float to_eventlog;
1141         local float to_file;
1142         local float i;
1143
1144         to_console = cvar("sv_logscores_console");
1145         to_eventlog = cvar("sv_eventlog");
1146         to_file = cvar("sv_logscores_file");
1147
1148         if(!final)
1149         {
1150                 to_console = TRUE; // always print printstats replies
1151                 to_eventlog = FALSE; // but never print them to the event log
1152         }
1153
1154         if(to_eventlog)
1155                 if(cvar("sv_eventlog_console"))
1156                         to_console = FALSE; // otherwise we get the output twice
1157
1158         if(final)
1159                 s = ":scores:";
1160         else
1161                 s = ":status:";
1162         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1163
1164         if(to_console)
1165                 print(s, "\n");
1166         if(to_eventlog)
1167                 GameLogEcho(s);
1168         if(to_file)
1169         {
1170                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1171                 if(file == -1)
1172                         to_file = FALSE;
1173                 else
1174                         fputs(file, strcat(s, "\n"));
1175         }
1176
1177         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1178         if(to_console)
1179                 print(s, "\n");
1180         if(to_eventlog)
1181                 GameLogEcho(s);
1182         if(to_file)
1183                 fputs(file, strcat(s, "\n"));
1184
1185         FOR_EACH_CLIENT(other)
1186         {
1187                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1188                 {
1189                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1190                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1191                         if(other.classname == "player" || g_arena || g_lms)
1192                                 s = strcat(s, ftos(other.team), ":");
1193                         else
1194                                 s = strcat(s, "spectator:");
1195
1196                         if(to_console)
1197                                 print(s, other.netname, "\n");
1198                         if(to_eventlog)
1199                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1200                         if(to_file)
1201                                 fputs(file, strcat(s, other.netname, "\n"));
1202                 }
1203         }
1204
1205         if(teams_matter)
1206         {
1207                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1208                 if(to_console)
1209                         print(s, "\n");
1210                 if(to_eventlog)
1211                         GameLogEcho(s);
1212                 if(to_file)
1213                         fputs(file, strcat(s, "\n"));
1214
1215                 for(i = 1; i < 16; ++i)
1216                 {
1217                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1218                         s = strcat(s, ":", ftos(i));
1219                         if(to_console)
1220                                 print(s, "\n");
1221                         if(to_eventlog)
1222                                 GameLogEcho(s);
1223                         if(to_file)
1224                                 fputs(file, strcat(s, "\n"));
1225                 }
1226         }
1227
1228         if(to_console)
1229                 print(":end\n");
1230         if(to_eventlog)
1231                 GameLogEcho(":end");
1232         if(to_file)
1233         {
1234                 fputs(file, ":end\n");
1235                 fclose(file);
1236         }
1237 }
1238
1239 void FixIntermissionClient(entity e)
1240 {
1241         string s;
1242         if(!e.autoscreenshot) // initial call
1243         {
1244                 e.angles = e.v_angle;
1245                 e.angles_x = -e.angles_x;
1246                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1247                 e.health = -2342;
1248                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1249                 e.solid = SOLID_NOT;
1250                 e.movetype = MOVETYPE_NONE;
1251                 e.takedamage = DAMAGE_NO;
1252                 if(e.weaponentity)
1253                 {
1254                         e.weaponentity.effects = EF_NODRAW;
1255                         if (e.weaponentity.weaponentity)
1256                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1257                 }
1258                 if(clienttype(e) == CLIENTTYPE_REAL)
1259                 {
1260                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1261                         s = cvar_string("sv_intermission_cdtrack");
1262                         if(s != "")
1263                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1264                         msg_entity = e;
1265                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1266                 }
1267         }
1268
1269         //e.velocity = '0 0 0';
1270         //e.fixangle = TRUE;
1271
1272         // TODO halt weapon animation
1273 }
1274
1275
1276 /*
1277 go to the next level for deathmatch
1278 only called if a time or frag limit has expired
1279 */
1280 void NextLevel()
1281 {
1282         float minTotalFrags;
1283         float maxTotalFrags;
1284         float score;
1285         float f;
1286
1287         gameover = TRUE;
1288
1289         intermission_running = 1;
1290
1291 // enforce a wait time before allowing changelevel
1292         if(player_count > 0)
1293                 intermission_exittime = time + cvar("sv_mapchange_delay");
1294         else
1295                 intermission_exittime = -1;
1296
1297         /*
1298         WriteByte (MSG_ALL, SVC_CDTRACK);
1299         WriteByte (MSG_ALL, 3);
1300         WriteByte (MSG_ALL, 3);
1301         // done in FixIntermission
1302         */
1303
1304         //pos = FindIntermission ();
1305
1306         VoteReset();
1307
1308         DumpStats(TRUE);
1309
1310         if(cvar("sv_eventlog"))
1311                 GameLogEcho(":gameover");
1312
1313         GameLogClose();
1314
1315         FOR_EACH_CLIENT(other)
1316         {
1317                 FixIntermissionClient(other);
1318
1319                 if(other.winning)
1320                         bprint(other.netname, " ^7wins.\n");
1321         }
1322
1323         minTotalFrags = 0;
1324         maxTotalFrags = 0;
1325         FOR_EACH_PLAYER(other)
1326         {
1327                 if(maxTotalFrags < other.totalfrags)
1328                         maxTotalFrags = other.totalfrags;
1329                 if(minTotalFrags > other.totalfrags)
1330                         minTotalFrags = other.totalfrags;
1331         }
1332
1333         if(!currentbots)
1334         {
1335                 FOR_EACH_PLAYER(other)
1336                 {
1337                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1338                         f = bound(0, other.play_time / max(time, 1), 1);
1339                         // store some statistics?
1340                 }
1341         }
1342
1343         if(cvar("g_campaign"))
1344                 CampaignPreIntermission();
1345
1346         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1347 };
1348
1349 /*
1350 ============
1351 CheckRules_Player
1352
1353 Exit deathmatch games upon conditions
1354 ============
1355 */
1356 void CheckRules_Player()
1357 {
1358         if (gameover)   // someone else quit the game already
1359                 return;
1360
1361         if(self.deadflag == DEAD_NO)
1362                 self.play_time += frametime;
1363
1364         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1365         //   (div0: and that in CheckRules_World please)
1366 };
1367
1368 float checkrules_oneminutewarning;
1369
1370 float checkrules_equality;
1371 float checkrules_suddendeathwarning;
1372 float checkrules_suddendeathend;
1373 float checkrules_overtimesadded; //how many overtimes have been already added
1374 float checkrules_status;
1375
1376 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1377 float WINNING_YES = 1; // winner found
1378 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1379 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1380
1381 void InitiateOvertime()
1382 {
1383         // Check first whether normal overtimes could be added before initiating suddendeath mode
1384         // - for this timelimit_overtime needs to be >0 of course
1385         // - also check the winning condition calculated in the previous frame and only add normal overtime
1386         //   again, if at the point at which timelimit would be extended again, still no winner was found
1387         if ((checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && (checkrules_status == WINNING_NEVER))
1388         {
1389                 ++checkrules_overtimesadded;
1390                 //add one more overtime by simply extending the timelimit
1391                 float tl;
1392                 tl = cvar("timelimit");
1393                 tl += cvar("timelimit_overtime");
1394                 cvar_set("timelimit", ftos(tl));
1395                 string minutesPlural;
1396                 if (cvar("timelimit_overtime") == 1)
1397                         minutesPlural = " ^3minute";
1398                 else
1399                         minutesPlural = " ^3minutes";
1400
1401                 bcenterprint(
1402                         strcat(
1403                                 "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1404                                 ftos(cvar("timelimit_overtime")),
1405                                 minutesPlural,
1406                                 " to the game!"
1407                         )
1408                 );
1409         }
1410         else
1411         {
1412                 if(!checkrules_suddendeathend)
1413                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1414         }
1415 }
1416
1417 float GetWinningCode(float fraglimitreached, float equality)
1418 {
1419         if(equality)
1420                 if(fraglimitreached)
1421                         return WINNING_STARTSUDDENDEATHOVERTIME;
1422                 else
1423                         return WINNING_NEVER;
1424         else
1425                 if(fraglimitreached)
1426                         return WINNING_YES;
1427                 else
1428                         return WINNING_NO;
1429 }
1430
1431 // set the .winning flag for exactly those players with a given field value
1432 void SetWinners(.float field, float value)
1433 {
1434         entity head;
1435         FOR_EACH_PLAYER(head)
1436                 head.winning = (head.field == value);
1437 }
1438
1439 // set the .winning flag for those players with a given field value
1440 void AddWinners(.float field, float value)
1441 {
1442         entity head;
1443         FOR_EACH_PLAYER(head)
1444                 if(head.field == value)
1445                         head.winning = 1;
1446 }
1447
1448 // clear the .winning flags
1449 void ClearWinners(void)
1450 {
1451         entity head;
1452         FOR_EACH_PLAYER(head)
1453                 head.winning = 0;
1454 }
1455
1456 // Onslaught winning condition:
1457 // game terminates if only one team has a working generator (or none)
1458 float WinningCondition_Onslaught()
1459 {
1460         entity head;
1461         local float t1, t2, t3, t4;
1462
1463         WinningConditionHelper(); // set worldstatus
1464
1465         // first check if the game has ended
1466         t1 = t2 = t3 = t4 = 0;
1467         head = find(world, classname, "onslaught_generator");
1468         while (head)
1469         {
1470                 if (head.health > 0)
1471                 {
1472                         if (head.team == COLOR_TEAM1) t1 = 1;
1473                         if (head.team == COLOR_TEAM2) t2 = 1;
1474                         if (head.team == COLOR_TEAM3) t3 = 1;
1475                         if (head.team == COLOR_TEAM4) t4 = 1;
1476                 }
1477                 head = find(head, classname, "onslaught_generator");
1478         }
1479         if (t1 + t2 + t3 + t4 < 2)
1480         {
1481                 // game over, only one team remains (or none)
1482                 ClearWinners();
1483                 if (t1) SetWinners(team, COLOR_TEAM1);
1484                 if (t2) SetWinners(team, COLOR_TEAM2);
1485                 if (t3) SetWinners(team, COLOR_TEAM3);
1486                 if (t4) SetWinners(team, COLOR_TEAM4);
1487                 dprint("Have a winner, ending game.\n");
1488                 return WINNING_YES;
1489         }
1490
1491         // Two or more teams remain
1492         return WINNING_NO;
1493 }
1494
1495 float LMS_NewPlayerLives()
1496 {
1497         float fl;
1498         fl = cvar("fraglimit");
1499         if(fl == 0)
1500                 fl = 999;
1501
1502         // first player has left the game for dying too much? Nobody else can get in.
1503         if(lms_lowest_lives < 1)
1504                 return 0;
1505
1506         if(!cvar("g_lms_join_anytime"))
1507                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1508                         return 0;
1509
1510         return bound(1, lms_lowest_lives, fl);
1511 }
1512
1513 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1514 // they win. Otherwise the defending team wins once the timelimit passes.
1515 void assault_new_round();
1516 float WinningCondition_Assault()
1517 {
1518         local float status;
1519
1520         WinningConditionHelper(); // set worldstatus
1521
1522         status = WINNING_NO;
1523         // as the timelimit has not yet passed just assume the defending team will win
1524         if(assault_attacker_team == COLOR_TEAM1)
1525         {
1526                 SetWinners(team, COLOR_TEAM2);
1527         }
1528         else
1529         {
1530                 SetWinners(team, COLOR_TEAM1);
1531         }
1532
1533         local entity ent;
1534         ent = find(world, classname, "target_assault_roundend");
1535         if(ent)
1536         {
1537                 if(ent.winning) // round end has been triggered by attacking team
1538                 {
1539                         bprint("ASSAULT: round completed...\n");
1540                         SetWinners(team, assault_attacker_team);
1541
1542                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1543
1544                         if(ent.cnt == 1) // this was the second round
1545                         {
1546                                 status = WINNING_YES;
1547                         }
1548                         else
1549                         {
1550                                 local entity oldself;
1551                                 oldself = self;
1552                                 self = ent;
1553                                 assault_new_round();
1554                                 self = oldself;
1555                         }
1556                 }
1557         }
1558
1559         return status;
1560 }
1561
1562 // LMS winning condition: game terminates if and only if there's at most one
1563 // one player who's living lives. Top two scores being equal cancels the time
1564 // limit.
1565 float WinningCondition_LMS()
1566 {
1567         entity head, head2;
1568         float have_player;
1569         float have_players;
1570         float l;
1571
1572         have_player = FALSE;
1573         have_players = FALSE;
1574         l = LMS_NewPlayerLives();
1575
1576         head = find(world, classname, "player");
1577         if(head)
1578                 have_player = TRUE;
1579         head2 = find(head, classname, "player");
1580         if(head2)
1581                 have_players = TRUE;
1582
1583         if(have_player)
1584         {
1585                 // we have at least one player
1586                 if(have_players)
1587                 {
1588                         // two or more active players - continue with the game
1589                 }
1590                 else
1591                 {
1592                         // exactly one player?
1593
1594                         ClearWinners();
1595                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1596
1597                         if(l)
1598                         {
1599                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1600                                 return WINNING_NO;
1601                         }
1602                         else
1603                         {
1604                                 // a winner!
1605                                 // and assign him his first place
1606                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1607                                 return WINNING_YES;
1608                         }
1609                 }
1610         }
1611         else
1612         {
1613                 // nobody is playing at all...
1614                 if(l)
1615                 {
1616                         // wait for players...
1617                 }
1618                 else
1619                 {
1620                         // SNAFU (maybe a draw game?)
1621                         ClearWinners();
1622                         dprint("No players, ending game.\n");
1623                         return WINNING_YES;
1624                 }
1625         }
1626
1627         // When we get here, we have at least two players who are actually LIVING,
1628         // now check if the top two players have equal score.
1629         WinningConditionHelper();
1630
1631         ClearWinners();
1632         if(WinningConditionHelper_winner)
1633                 WinningConditionHelper_winner.winning = TRUE;
1634         if(WinningConditionHelper_equality)
1635                 return WINNING_NEVER;
1636
1637         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1638         return WINNING_NO;
1639 }
1640
1641 void ShuffleMaplist()
1642 {
1643         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1644 }
1645
1646 float leaderfrags;
1647 float WinningCondition_Scores(float limit)
1648 {
1649         // TODO make everything use THIS winning condition (except LMS)
1650         WinningConditionHelper();
1651
1652         if(teams_matter)
1653         {
1654                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1655                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1656                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1657                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1658         }
1659
1660         ClearWinners();
1661         if(WinningConditionHelper_winner)
1662                 WinningConditionHelper_winner.winning = 1;
1663         if(WinningConditionHelper_winnerteam >= 0)
1664                 SetWinners(team, WinningConditionHelper_winnerteam);
1665
1666         if(WinningConditionHelper_lowerisbetter)
1667         {
1668                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1669                 limit = -limit;
1670         }
1671
1672         if(g_dm || g_tdm || g_arena || (g_race && !g_race_qualifying) || g_nexball)
1673         // these modes always score in increments of 1, thus this makes sense
1674         {
1675                 if(leaderfrags != WinningConditionHelper_topscore)
1676                 {
1677                         leaderfrags = WinningConditionHelper_topscore;
1678
1679                         if (limit)
1680                         if (leaderfrags == limit - 1)
1681                                 play2all("announcer/robotic/1fragleft.wav");
1682                         else if (leaderfrags == limit - 2)
1683                                 play2all("announcer/robotic/2fragsleft.wav");
1684                         else if (leaderfrags == limit - 3)
1685                                 play2all("announcer/robotic/3fragsleft.wav");
1686                 }
1687         }
1688
1689         return GetWinningCode(limit && WinningConditionHelper_topscore && (WinningConditionHelper_topscore >= limit), WinningConditionHelper_equality);
1690 }
1691
1692 float WinningCondition_Race(float fraglimit)
1693 {
1694         float wc;
1695         entity p;
1696         wc = WinningCondition_Scores(fraglimit);
1697
1698         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1699         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1700         // do NOT support equality when the laps are all raced!
1701         {
1702                 FOR_EACH_PLAYER(p)
1703                         if not(p.race_completed)
1704                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1705                 return WINNING_YES;
1706         }
1707         return wc;
1708 }
1709
1710 void ReadyRestart();
1711 float WinningCondition_QualifyingThenRace(float limit)
1712 {
1713         float wc;
1714         wc = WinningCondition_Scores(limit);
1715
1716         // NEVER initiate overtime
1717         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1718         {
1719                 return WINNING_YES;
1720         }
1721
1722         return wc;
1723 }
1724
1725 float WinningCondition_RanOutOfSpawns()
1726 {
1727         entity head;
1728
1729         if(!have_team_spawns)
1730                 return WINNING_NO;
1731
1732         if(!some_spawn_has_been_used)
1733                 return WINNING_NO;
1734
1735         team1_score = team2_score = team3_score = team4_score = 0;
1736
1737         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1738         {
1739                 if(head.team == COLOR_TEAM1)
1740                         team1_score = 1;
1741                 else if(head.team == COLOR_TEAM2)
1742                         team2_score = 1;
1743                 else if(head.team == COLOR_TEAM3)
1744                         team3_score = 1;
1745                 else if(head.team == COLOR_TEAM4)
1746                         team4_score = 1;
1747         }
1748
1749         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1750         {
1751                 if(head.team == COLOR_TEAM1)
1752                         team1_score = 1;
1753                 else if(head.team == COLOR_TEAM2)
1754                         team2_score = 1;
1755                 else if(head.team == COLOR_TEAM3)
1756                         team3_score = 1;
1757                 else if(head.team == COLOR_TEAM4)
1758                         team4_score = 1;
1759         }
1760
1761         ClearWinners();
1762         if(team1_score + team2_score + team3_score + team4_score == 0)
1763         {
1764                 checkrules_equality = TRUE;
1765                 return WINNING_YES;
1766         }
1767         else if(team1_score + team2_score + team3_score + team4_score == 1)
1768         {
1769                 float t, i;
1770                 if(team1_score) t = COLOR_TEAM1;
1771                 if(team2_score) t = COLOR_TEAM2;
1772                 if(team3_score) t = COLOR_TEAM3;
1773                 if(team4_score) t = COLOR_TEAM4;
1774                 CheckAllowedTeams(world);
1775                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1776                 {
1777                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1778                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1779                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1780                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1781                 }
1782
1783                 AddWinners(team, t);
1784                 return WINNING_YES;
1785         }
1786         else
1787                 return WINNING_NO;
1788 }
1789
1790 /*
1791 ============
1792 CheckRules_World
1793
1794 Exit deathmatch games upon conditions
1795 ============
1796 */
1797 void CheckRules_World()
1798 {
1799         local float timelimit;
1800         local float fraglimit;
1801
1802         VoteThink();
1803         MapVote_Think();
1804
1805         SetDefaultAlpha();
1806
1807         /*
1808         MapVote_Think should now do that part
1809         if (intermission_running)
1810                 if (time >= intermission_exittime + 60)
1811                 {
1812                         if(!DoNextMapOverride())
1813                                 GotoNextMap();
1814                         return;
1815                 }
1816         */
1817
1818         if (gameover)   // someone else quit the game already
1819         {
1820                 if(player_count == 0) // Nobody there? Then let's go to the next map
1821                         MapVote_Start();
1822                         // this will actually check the player count in the next frame
1823                         // again, but this shouldn't hurt
1824                 return;
1825         }
1826
1827         timelimit = cvar("timelimit") * 60;
1828         fraglimit = cvar("fraglimit");
1829
1830         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1831         {
1832                 if(timelimit > 0)
1833                         timelimit = 0; // timelimit is not made for warmup
1834                 if(fraglimit > 0)
1835                         fraglimit = 0; // no fraglimit for now
1836         }
1837
1838         if(timelimit > 0)
1839         {
1840                 timelimit += game_starttime;
1841         }
1842         else if (timelimit < 0)
1843         {
1844                 // endmatch
1845                 NextLevel();
1846                 return;
1847         }
1848
1849         if(checkrules_suddendeathend)
1850         {
1851                 if(!checkrules_suddendeathwarning)
1852                 {
1853                         checkrules_suddendeathwarning = TRUE;
1854                         if(g_race && !g_race_qualifying)
1855                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1856                         else
1857                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1858                 }
1859         }
1860         else
1861         {
1862                 if (timelimit && time >= timelimit)
1863                 {
1864                         if(g_race && g_race_qualifying == 2 && timelimit > 0)
1865                         {
1866                                 float totalplayers;
1867                                 float playerswithlaps;
1868                                 float readyplayers;
1869                                 entity head;
1870                                 totalplayers = playerswithlaps = readyplayers = 0;
1871                                 FOR_EACH_PLAYER(head)
1872                                 {
1873                                         ++totalplayers;
1874                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1875                                                 ++playerswithlaps;
1876                                         if(head.ready)
1877                                                 ++readyplayers;
1878                                 }
1879
1880                                 // at least 2/3 of the players have completed a lap: start the RACE
1881                                 // otherwise, the players should end the qualifying on their own
1882                                 if(readyplayers || ((totalplayers >= 3) && (playerswithlaps * 3 >= totalplayers * 2)))
1883                                 {
1884                                         checkrules_suddendeathend = 0;
1885                                         ReadyRestart(); // go to race
1886                                 }
1887                                 else
1888                                         InitiateOvertime();
1889                         }
1890                         else
1891                                 InitiateOvertime();
1892                 }
1893         }
1894
1895         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1896         {
1897                 NextLevel();
1898                 return;
1899         }
1900
1901         if (!checkrules_oneminutewarning && timelimit > 0 && time > timelimit - 60)
1902         {
1903                 checkrules_oneminutewarning = TRUE;
1904                 play2all("announcer/robotic/1minuteremains.wav");
1905         }
1906
1907         checkrules_status = WinningCondition_RanOutOfSpawns();
1908         if(checkrules_status == WINNING_YES)
1909         {
1910                 bprint("Hey! Someone ran out of spawns!\n");
1911         }
1912         else if(g_race && !g_race_qualifying && timelimit >= 0)
1913         {
1914                 checkrules_status = WinningCondition_Race(fraglimit);
1915         }
1916         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
1917         {
1918                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
1919         }
1920         else if(g_assault)
1921         {
1922                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
1923         }
1924         else if(g_lms)
1925         {
1926                 checkrules_status = WinningCondition_LMS();
1927         }
1928         else if (g_onslaught)
1929         {
1930                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
1931         }
1932         else
1933         {
1934                 checkrules_status = WinningCondition_Scores(fraglimit);
1935         }
1936
1937         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1938         {
1939                 checkrules_status = WINNING_NEVER;
1940                 InitiateOvertime();
1941         }
1942
1943         if(checkrules_status == WINNING_NEVER)
1944                 // equality cases! Nobody wins if the overtime ends in a draw.
1945                 ClearWinners();
1946
1947         if(checkrules_suddendeathend)
1948                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1949                         checkrules_status = WINNING_YES;
1950
1951         if(checkrules_status == WINNING_YES)
1952                 NextLevel();
1953 };
1954
1955 float mapvote_nextthink;
1956 float mapvote_initialized;
1957 float mapvote_keeptwotime;
1958 float mapvote_timeout;
1959 string mapvote_message;
1960 string mapvote_screenshot_dir;
1961
1962 float mapvote_count;
1963 float mapvote_count_real;
1964 string mapvote_maps[MAPVOTE_COUNT];
1965 float mapvote_maps_suggested[MAPVOTE_COUNT];
1966 string mapvote_suggestions[MAPVOTE_COUNT];
1967 float mapvote_suggestion_ptr;
1968 float mapvote_maxlen;
1969 float mapvote_voters;
1970 float mapvote_votes[MAPVOTE_COUNT];
1971 float mapvote_run;
1972 float mapvote_detail;
1973 float mapvote_abstain;
1974 .float mapvote;
1975
1976 void MapVote_ClearAllVotes()
1977 {
1978         FOR_EACH_CLIENT(other)
1979                 other.mapvote = 0;
1980 }
1981
1982 string MapVote_Suggest(string m)
1983 {
1984         float i;
1985         if(m == "")
1986                 return "That's not how to use this command.";
1987         if(!cvar("g_maplist_votable_suggestions"))
1988                 return "Suggestions are not accepted on this server.";
1989         if(mapvote_initialized)
1990                 return "Can't suggest - voting is already in progress!";
1991         m = MapInfo_FixName(m);
1992         if(!m)
1993                 return "The map you suggested is not available on this server.";
1994         if(!cvar("g_maplist_votable_override_mostrecent"))
1995                 if(Map_IsRecent(m))
1996                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
1997
1998         if(!MapInfo_CheckMap(m))
1999                 return "The map you suggested does not support the current game mode.";
2000         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2001                 if(mapvote_suggestions[i] == m)
2002                         return "This map was already suggested.";
2003         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2004         {
2005                 i = floor(random() * mapvote_suggestion_ptr);
2006         }
2007         else
2008         {
2009                 i = mapvote_suggestion_ptr;
2010                 mapvote_suggestion_ptr += 1;
2011         }
2012         if(mapvote_suggestions[i] != "")
2013                 strunzone(mapvote_suggestions[i]);
2014         mapvote_suggestions[i] = strzone(m);
2015         if(cvar("sv_eventlog"))
2016                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2017         return strcat("Suggestion of ", m, " accepted.");
2018 }
2019
2020 void MapVote_AddVotable(string nextMap, float isSuggestion)
2021 {
2022         float j;
2023         if(nextMap == "")
2024                 return;
2025         for(j = 0; j < mapvote_count; ++j)
2026                 if(mapvote_maps[j] == nextMap)
2027                         return;
2028         if(strlen(nextMap) > mapvote_maxlen)
2029                 mapvote_maxlen = strlen(nextMap);
2030         mapvote_maps[mapvote_count] = strzone(nextMap);
2031         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2032         mapvote_count += 1;
2033 }
2034
2035 void MapVote_Spawn();
2036 void MapVote_Init()
2037 {
2038         float i;
2039         float nmax, smax;
2040
2041         MapVote_ClearAllVotes();
2042
2043         mapvote_count = 0;
2044         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2045         mapvote_abstain = cvar("g_maplist_votable_abstain");
2046
2047         if(mapvote_abstain)
2048                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2049         else
2050                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2051         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2052
2053         if(mapvote_suggestion_ptr)
2054                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2055                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2056
2057         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2058                 MapVote_AddVotable(GetNextMap(), FALSE);
2059
2060         if(mapvote_count == 0)
2061         {
2062                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2063                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN));
2064                 if(cvar("g_maplist_shuffle"))
2065                         ShuffleMaplist();
2066                 localcmd("\nmenu_cmd sync\n");
2067                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2068                         MapVote_AddVotable(GetNextMap(), FALSE);
2069         }
2070
2071         mapvote_count_real = mapvote_count;
2072         if(mapvote_abstain)
2073                 MapVote_AddVotable("don't care", 0);
2074
2075         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2076
2077         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2078         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2079         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2080                 mapvote_keeptwotime = 0;
2081         mapvote_message = "Choose a map and press its key!";
2082
2083         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
2084         if(mapvote_screenshot_dir == "")
2085                 mapvote_screenshot_dir = "maps";
2086         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
2087
2088         MapVote_Spawn();
2089 }
2090
2091 void MapVote_SendPicture(float id)
2092 {
2093         msg_entity = self;
2094         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2095         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2096         WriteByte(MSG_ONE, id);
2097         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
2098 }
2099
2100 float GameCommand_MapVote(string cmd)
2101 {
2102         if(!intermission_running)
2103                 return FALSE;
2104
2105         if(cmd == "mv_getpic")
2106         {
2107                 MapVote_SendPicture(stof(argv(1)));
2108                 return TRUE;
2109         }
2110
2111         return FALSE;
2112 }
2113
2114 float MapVote_GetMapMask()
2115 {
2116         float mask, i, power;
2117         mask = 0;
2118         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2119                 if(mapvote_maps[i] != "")
2120                         mask |= power;
2121         return mask;
2122 }
2123
2124 entity mapvote_ent;
2125 float MapVote_SendEntity(entity to, float sf)
2126 {
2127         string mapfile, pakfile;
2128         float i, o;
2129
2130         if(sf & 1)
2131                 sf &~= 2; // if we send 1, we don't need to also send 2
2132
2133         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2134         WriteByte(MSG_ENTITY, sf);
2135
2136         if(sf & 1)
2137         {
2138                 // flag 1 == initialization
2139                 WriteString(MSG_ENTITY, mapvote_screenshot_dir);
2140                 WriteByte(MSG_ENTITY, mapvote_count);
2141                 WriteByte(MSG_ENTITY, mapvote_abstain);
2142                 WriteByte(MSG_ENTITY, mapvote_detail);
2143                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2144                 if(mapvote_count <= 8)
2145                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2146                 else
2147                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2148                 for(i = 0; i < mapvote_count; ++i)
2149                         if(mapvote_maps[i] != "")
2150                         {
2151                                 if(mapvote_abstain && i == mapvote_count - 1)
2152                                 {
2153                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2154                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2155                                 }
2156                                 else
2157                                 {
2158                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2159                                         mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
2160                                         pakfile = whichpack(strcat(mapfile, ".tga"));
2161                                         if(pakfile == "")
2162                                                 pakfile = whichpack(strcat(mapfile, ".jpg"));
2163                                         if(pakfile == "")
2164                                                 pakfile = whichpack(strcat(mapfile, ".png"));
2165                                         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2166                                                 pakfile = substring(pakfile, o, 999);
2167                                         WriteString(MSG_ENTITY, pakfile);
2168                                 }
2169                         }
2170         }
2171
2172         if(sf & 2)
2173         {
2174                 // flag 2 == update of mask
2175                 if(mapvote_count <= 8)
2176                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2177                 else
2178                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2179         }
2180
2181         if(sf & 4)
2182         {
2183                 if(mapvote_detail)
2184                         for(i = 0; i < mapvote_count; ++i)
2185                                 if(mapvote_maps[i] != "")
2186                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2187
2188                 WriteByte(MSG_ENTITY, to.mapvote);
2189         }
2190
2191         return TRUE;
2192 }
2193
2194 void MapVote_Spawn()
2195 {
2196         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2197 }
2198
2199 void MapVote_TouchMask()
2200 {
2201         mapvote_ent.SendFlags |= 2;
2202 }
2203
2204 void MapVote_TouchVotes(entity voter)
2205 {
2206         mapvote_ent.SendFlags |= 4;
2207 }
2208
2209 float MapVote_Finished(float mappos)
2210 {
2211         string result;
2212         float i;
2213         float didntvote;
2214
2215         if(cvar("sv_eventlog"))
2216         {
2217                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2218                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2219                 didntvote = mapvote_voters;
2220                 for(i = 0; i < mapvote_count; ++i)
2221                         if(mapvote_maps[i] != "")
2222                         {
2223                                 didntvote -= mapvote_votes[i];
2224                                 if(i != mappos)
2225                                 {
2226                                         result = strcat(result, ":", mapvote_maps[i]);
2227                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2228                                 }
2229                         }
2230                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2231
2232                 GameLogEcho(result);
2233                 if(mapvote_maps_suggested[mappos])
2234                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2235         }
2236
2237         FOR_EACH_REALCLIENT(other)
2238                 FixClientCvars(other);
2239
2240         Map_Goto_SetStr(mapvote_maps[mappos]);
2241         Map_Goto();
2242         alreadychangedlevel = TRUE;
2243         return TRUE;
2244 }
2245 void MapVote_CheckRules_1()
2246 {
2247         float i;
2248
2249         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2250         {
2251                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2252                 mapvote_votes[i] = 0;
2253         }
2254
2255         mapvote_voters = 0;
2256         FOR_EACH_REALCLIENT(other)
2257         {
2258                 ++mapvote_voters;
2259                 if(other.mapvote)
2260                 {
2261                         i = other.mapvote - 1;
2262                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2263                         mapvote_votes[i] = mapvote_votes[i] + 1;
2264                 }
2265         }
2266 }
2267
2268 float MapVote_CheckRules_2()
2269 {
2270         float i;
2271         float firstPlace, secondPlace;
2272         float firstPlaceVotes, secondPlaceVotes;
2273         float mapvote_voters_real;
2274         string result;
2275
2276         if(mapvote_count_real == 1)
2277                 return MapVote_Finished(0);
2278
2279         mapvote_voters_real = mapvote_voters;
2280         if(mapvote_abstain)
2281                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2282
2283         RandomSelection_Init();
2284         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2285                 RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2286         firstPlace = RandomSelection_chosen_float;
2287         firstPlaceVotes = RandomSelection_best_priority;
2288         //dprint("First place: ", ftos(firstPlace), "\n");
2289         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2290
2291         RandomSelection_Init();
2292         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2293                 if(i != firstPlace)
2294                         RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2295         secondPlace = RandomSelection_chosen_float;
2296         secondPlaceVotes = RandomSelection_best_priority;
2297         //dprint("Second place: ", ftos(secondPlace), "\n");
2298         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2299
2300         if(firstPlace == -1)
2301                 error("No first place in map vote... WTF?");
2302
2303         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2304                 return MapVote_Finished(firstPlace);
2305
2306         if(mapvote_keeptwotime)
2307                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2308                 {
2309                         float didntvote;
2310                         MapVote_TouchMask();
2311                         mapvote_message = "Now decide between the TOP TWO!";
2312                         mapvote_keeptwotime = 0;
2313                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2314                         result = strcat(result, ":", ftos(firstPlaceVotes));
2315                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2316                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2317                         didntvote = mapvote_voters;
2318                         for(i = 0; i < mapvote_count; ++i)
2319                                 if(mapvote_maps[i] != "")
2320                                 {
2321                                         didntvote -= mapvote_votes[i];
2322                                         if(i != firstPlace)
2323                                                 if(i != secondPlace)
2324                                                 {
2325                                                         result = strcat(result, ":", mapvote_maps[i]);
2326                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2327                                                         if(i < mapvote_count_real)
2328                                                         {
2329                                                                 strunzone(mapvote_maps[i]);
2330                                                                 mapvote_maps[i] = "";
2331                                                         }
2332                                                 }
2333                                 }
2334                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2335                         if(cvar("sv_eventlog"))
2336                                 GameLogEcho(result);
2337                 }
2338
2339         return FALSE;
2340 }
2341 void MapVote_Tick()
2342 {
2343         float keeptwo;
2344         float totalvotes;
2345
2346         keeptwo = mapvote_keeptwotime;
2347         MapVote_CheckRules_1(); // count
2348         if(MapVote_CheckRules_2()) // decide
2349                 return;
2350
2351         totalvotes = 0;
2352         FOR_EACH_REALCLIENT(other)
2353         {
2354                 // hide scoreboard again
2355                 if(other.health != 2342)
2356                 {
2357                         other.health = 2342;
2358                         other.impulse = 0;
2359                         if(clienttype(other) == CLIENTTYPE_REAL)
2360                         {
2361                                 msg_entity = other;
2362                                 WriteByte(MSG_ONE, SVC_FINALE);
2363                                 WriteString(MSG_ONE, "");
2364                         }
2365                 }
2366
2367                 // clear possibly invalid votes
2368                 if(mapvote_maps[other.mapvote - 1] == "")
2369                         other.mapvote = 0;
2370                 // use impulses as new vote
2371                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2372                         if(mapvote_maps[other.impulse - 1] != "")
2373                         {
2374                                 other.mapvote = other.impulse;
2375                                 MapVote_TouchVotes(other);
2376                         }
2377                 other.impulse = 0;
2378
2379                 if(other.mapvote)
2380                         ++totalvotes;
2381         }
2382
2383         MapVote_CheckRules_1(); // just count
2384 }
2385 void MapVote_Start()
2386 {
2387         if(mapvote_run)
2388                 return;
2389
2390         MapInfo_Enumerate();
2391         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 1))
2392                 mapvote_run = TRUE;
2393 }
2394 void MapVote_Think()
2395 {
2396         if(!mapvote_run)
2397                 return;
2398
2399         if(alreadychangedlevel)
2400                 return;
2401
2402         if(time < mapvote_nextthink)
2403                 return;
2404         //dprint("tick\n");
2405
2406         mapvote_nextthink = time + 0.5;
2407
2408         if(!mapvote_initialized)
2409         {
2410                 mapvote_initialized = TRUE;
2411                 if(DoNextMapOverride())
2412                         return;
2413                 if(!cvar("g_maplist_votable") || player_count <= 0)
2414                 {
2415                         GotoNextMap();
2416                         return;
2417                 }
2418                 MapVote_Init();
2419         }
2420
2421         MapVote_Tick();
2422 };
2423
2424 string GotoMap(string m)
2425 {
2426         if(!MapInfo_CheckMap(m))
2427                 return "The map you chose is not available on this server.";
2428         cvar_set("nextmap", m);
2429         cvar_set("timelimit", "-1");
2430         if(mapvote_initialized || alreadychangedlevel)
2431         {
2432                 if(DoNextMapOverride())
2433                         return "Map switch initiated.";
2434                 else
2435                         return "Hm... no. For some reason I like THIS map more.";
2436         }
2437         else
2438                 return "Map switch will happen after scoreboard.";
2439 }
2440
2441
2442 void EndFrame()
2443 {
2444         FOR_EACH_REALCLIENT(self)
2445         {
2446                 if(self.classname == "spectator")
2447                 {
2448                         if(self.enemy.typehitsound)
2449                                 play2(self, "misc/typehit.wav");
2450                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2451                                 play2(self, "misc/hit.wav");
2452                 }
2453                 else
2454                 {
2455                         if(self.typehitsound)
2456                                 play2(self, "misc/typehit.wav");
2457                         else if(self.hitsound && self.cvar_cl_hitsound)
2458                                 play2(self, "misc/hit.wav");
2459                 }
2460         }
2461         FOR_EACH_CLIENT(self)
2462         {
2463                 self.hitsound = FALSE;
2464                 self.typehitsound = FALSE;
2465         }
2466 }
2467
2468
2469 /*
2470  * RedirectionThink:
2471  * returns TRUE if redirecting
2472  */
2473 float redirection_timeout;
2474 float redirection_nextthink;
2475 float RedirectionThink()
2476 {
2477         float clients_found;
2478
2479         if(redirection_target == "")
2480                 return FALSE;
2481
2482         if(!redirection_timeout)
2483         {
2484                 cvar_set("sv_public", "-2");
2485                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2486                 if(redirection_target == "self")
2487                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2488                 else
2489                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2490         }
2491
2492         if(time < redirection_nextthink)
2493                 return TRUE;
2494
2495         redirection_nextthink = time + 1;
2496
2497         clients_found = 0;
2498         FOR_EACH_REALCLIENT(self)
2499         {
2500                 print("Redirecting: sending connect command to ", self.netname, "\n");
2501                 if(redirection_target == "self")
2502                         stuffcmd(self, "\ndisconnect; reconnect\n");
2503                 else
2504                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2505                 ++clients_found;
2506         }
2507
2508         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2509
2510         if(time > redirection_timeout || clients_found == 0)
2511                 localcmd("\nwait; wait; wait; quit\n");
2512
2513         return TRUE;
2514 }
2515
2516 void RestoreGame()
2517 {
2518         // Loaded from a save game
2519         // some things then break, so let's work around them...
2520
2521         // Progs DB (capture records)
2522         if(sv_cheats)
2523                 ServerProgsDB = db_create();
2524         else
2525                 ServerProgsDB = db_load("server.db");
2526
2527         // Mapinfo
2528         MapInfo_Shutdown();
2529         MapInfo_Enumerate();
2530         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 1);
2531 }
2532
2533 void SV_Shutdown()
2534 {
2535         if(world_initialized > 0)
2536         {
2537                 world_initialized = 0;
2538                 print("Saving persistent data...\n");
2539                 Ban_SaveBans();
2540                 if(!sv_cheats)
2541                         db_save(ServerProgsDB, "server.db");
2542                 if(cvar("developer"))
2543                         db_save(TemporaryDB, "server-temp.db");
2544                 db_close(ServerProgsDB);
2545                 db_close(TemporaryDB);
2546                 print("done!\n");
2547                 // tell the bot system the game is ending now
2548                 bot_endgame();
2549
2550                 MapInfo_Shutdown();
2551         }
2552         else if(world_initialized == 0)
2553         {
2554                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2555         }
2556 }