data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 void SetDefaultAlpha()
  12 {
  13         if(cvar("g_running_guns"))
  14         {
  15                 default_player_alpha = -1;
  16                 default_weapon_alpha = +1;
  17         }
  18         else if(g_cloaked)
  19         {
  20                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23         else
  24         {
  25                 default_player_alpha = cvar("g_player_alpha");
  26                 if(default_player_alpha == 0)
  27                         default_player_alpha = 1;
  28                 default_weapon_alpha = default_player_alpha;
  29         }
  30 }
  31
  32 void fteqcc_testbugs()
  33 {
  34         float a, b;
  35
  36         if(!cvar("developer_fteqccbugs"))
  37                 return;
  38
  39         dprint("*** fteqcc test: checking for bugs...\n");
  40
  41         a = 1;
  42         b = 5;
  43         if(sqrt(a) - sqrt(b - a) == 0)
  44                 dprint("*** fteqcc test: found same-function-twice bug\n");
  45         else
  46                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  47
  48         world.cnt = -10;
  49         world.enemy = world;
  50         world.enemy.cnt += 10;
  51         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  52                 dprint("*** fteqcc test: found += bug\n");
  53         else
  54                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  55         world.cnt = 0;
  56 }
  57
  58 /**
  59  * Takes care of pausing and unpausing the game.
  60  * Centerprints the information about an upcoming or active timeout to all active
  61  * players. Also plays reminder sounds.
  62  */
  63 void timeoutHandler_Think() {
  64         local string timeStr;
  65         local entity plr;
  66         if (timeoutStatus == 1) {
  67                 if (remainingLeadTime > 0) {
  68                         //centerprint the information to every player
  69                         timeStr = getTimeoutText(0);
  70                         FOR_EACH_REALCLIENT(plr) {
  71                                 if(plr.classname == "player") {
  72                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  73                                 }
  74                         }
  75                         remainingLeadTime -= 1;
  76                         //think again in 1 second:
  77                         self.nextthink = time + 1;
  78                 }
  79                 else {
  80                         //now pause the game:
  81                         timeoutStatus = 2;
  82                         //reset all the flood variables
  83                         FOR_EACH_CLIENT(plr) {
  84                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
  85                         }
  86                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  87                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  88                         FOR_EACH_REALPLAYER(plr) {
  89                                 plr.lastV_angle = plr.v_angle;
  90                         }
  91                         self.nextthink = time;
  92                 }
  93         }
  94         else if (timeoutStatus == 2) {
  95                 if (remainingTimeoutTime > 0) {
  96                         timeStr = getTimeoutText(0);
  97                         FOR_EACH_REALCLIENT(plr) {
  98                                 if(plr.classname == "player") {
  99                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 100                                 }
 101                         }
 102                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 103                                 play2all("announcer/robotic/prepareforbattle.wav");
 104                         }
 105                         remainingTimeoutTime -= 1;
 106                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 107                 }
 108                 else {
 109                         //unpause the game again
 110                         remainingTimeoutTime = timeoutStatus = 0;
 111                         cvar_set("slowmo", ftos(orig_slowmo));
 112                         //and unlock the fixed view again once there is no timeout active anymore
 113                         FOR_EACH_REALPLAYER(plr) {
 114                                 plr.fixangle = FALSE;
 115                         }
 116                         //get rid of the countdown message
 117                         FOR_EACH_REALCLIENT(plr) {
 118                                 if(plr.classname == "player") {
 119                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 120                                 }
 121                         }
 122                         remove(self);
 123                         return;
 124                 }
 125
 126         }
 127         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 128                 FOR_EACH_REALCLIENT(plr) {
 129                         if(plr.classname == "player") {
 130                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 131                         }
 132                 }
 133                 remove(self);
 134                 return;
 135         }
 136 }
 137
 138 void GotoFirstMap()
 139 {
 140         float n;
 141         if(cvar("_sv_init"))
 142         {
 143                 // cvar_set("_sv_init", "0");
 144                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 145                 // to this "init" map on a dedicated server will cause no permanent
 146                 // harm
 147                 if(cvar("g_maplist_shuffle"))
 148                         ShuffleMaplist();
 149                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 150                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 151
 152                 MapInfo_Enumerate();
 153                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 0);
 154
 155                 if(!DoNextMapOverride())
 156                         GotoNextMap();
 157
 158                 return;
 159         }
 160
 161         if(time < 5)
 162         {
 163                 self.nextthink = time;
 164         }
 165         else
 166         {
 167                 self.nextthink = time + 1;
 168                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 169         }
 170 }
 171
 172 void cvar_changes_init()
 173 {
 174         float h;
 175         string k, v, d;
 176         float n, i;
 177
 178         if(cvar_changes)
 179                 strunzone(cvar_changes);
 180         cvar_changes = string_null;
 181
 182         h = buf_create();
 183         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 184         n = buf_getsize(h);
 185
 186         for(i = 0; i < n; ++i)
 187         {
 188                 k = bufstr_get(h, i);
 189
 190 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 191 #define BADCVAR(p) if(k == p) continue
 192                 // internal
 193                 BADPREFIX("csqc_");
 194                 BADPREFIX("cvar_check_");
 195                 BADCVAR("gamecfg");
 196                 BADCVAR("g_configversion");
 197                 BADCVAR("g_maplist_index");
 198                 BADCVAR("halflifebsp");
 199
 200                 // client
 201                 BADPREFIX("cl_");
 202                 BADPREFIX("con_");
 203                 BADPREFIX("g_campaign");
 204                 BADPREFIX("gl_");
 205                 BADPREFIX("joy");
 206                 BADPREFIX("menu_");
 207                 BADPREFIX("net_slist_");
 208                 BADPREFIX("r_");
 209                 BADPREFIX("sbar_");
 210                 BADPREFIX("scr_");
 211                 BADPREFIX("userbind");
 212                 BADPREFIX("v_");
 213                 BADPREFIX("vid_");
 214                 BADPREFIX("crosshair");
 215                 BADCVAR("mod_q3bsp_lightmapmergepower");
 216                 BADCVAR("mod_q3bsp_nolightmaps");
 217
 218                 // private
 219                 BADPREFIX("g_ban_");
 220                 BADPREFIX("g_chat_flood_");
 221                 BADPREFIX("g_voice_flood_");
 222                 BADPREFIX("rcon_");
 223                 BADPREFIX("settemp_");
 224                 BADPREFIX("sv_allowdownloads_");
 225                 BADPREFIX("sv_autodemo");
 226                 BADPREFIX("sv_curl_");
 227                 BADPREFIX("sv_eventlog");
 228                 BADPREFIX("sv_logscores_");
 229                 BADPREFIX("sv_master");
 230                 BADCVAR("g_banned_list");
 231                 BADCVAR("log_dest_udp");
 232                 BADCVAR("log_file");
 233                 BADCVAR("net_address");
 234                 BADCVAR("port");
 235                 BADCVAR("savedgamecfg");
 236                 BADCVAR("sv_heartbeatperoid");
 237                 BADCVAR("sv_vote_master_password");
 238                 BADCVAR("sys_colortranslation");
 239                 BADCVAR("sys_specialcharactertranslation");
 240                 BADCVAR("timestamps");
 241
 242                 // mapinfo
 243                 BADCVAR("timelimit");
 244                 BADCVAR("fraglimit");
 245                 BADCVAR("g_arena");
 246                 BADCVAR("g_assault");
 247                 BADCVAR("g_ctf");
 248                 BADCVAR("g_dm");
 249                 BADCVAR("g_domination");
 250                 BADCVAR("g_keyhunt");
 251                 BADCVAR("g_keyhunt_teams");
 252                 BADCVAR("g_onslaught");
 253                 BADCVAR("g_race");
 254                 BADCVAR("g_runematch");
 255                 BADCVAR("g_tdm");
 256                 BADCVAR("teamplay");
 257
 258                 // long
 259                 BADCVAR("hostname");
 260                 BADCVAR("g_maplist");
 261                 BADCVAR("g_maplist_mostrecent");
 262                 BADCVAR("sv_motd");
 263 #undef BADPREFIX
 264 #undef BADCVAR
 265
 266                 v = cvar_string(k);
 267                 d = cvar_defstring(k);
 268                 if(v != d)
 269                 {
 270                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 271                         if(strlen(cvar_changes) > 16384)
 272                         {
 273                                 cvar_changes = "// too many settings have been changed to show them here\n";
 274                                 break;
 275                         }
 276                 }
 277         }
 278         buf_del(h);
 279         if(cvar_changes == "")
 280                 cvar_changes = "// this server runs at default settings\n";
 281         else
 282                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 283         cvar_changes = strzone(cvar_changes);
 284 }
 285
 286 void detect_maptype()
 287 {
 288 #if 0
 289         vector o, v;
 290         float i;
 291
 292         for(;;)
 293         {
 294                 o = world.mins;
 295                 o_x += random() * (world.maxs_x - world.mins_x);
 296                 o_y += random() * (world.maxs_y - world.mins_y);
 297                 o_z += random() * (world.maxs_z - world.mins_z);
 298
 299                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 300                 if(trace_fraction == 1)
 301                         continue;
 302
 303                 v = trace_endpos;
 304
 305                 for(i = 0; i < 64; i += 4)
 306                 {
 307                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 308         if(trace_fraction == 1)
 309                 continue;
 310                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 311                 }
 312
 313                 break;
 314         }
 315 #endif
 316 }
 317
 318 entity randomseed;
 319 float RandomSeed_Send(entity to, float sf)
 320 {
 321         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 322         WriteShort(MSG_ENTITY, self.cnt);
 323         return TRUE;
 324 }
 325 void RandomSeed_Think()
 326 {
 327         self.cnt = bound(0, floor(random() * 65536), 65535);
 328         self.nextthink = time + 5;
 329
 330         self.SendFlags |= 1;
 331 }
 332 void RandomSeed_Spawn()
 333 {
 334         randomseed = spawn();
 335         randomseed.think = RandomSeed_Think;
 336         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 337
 338         entity oldself;
 339         oldself = self;
 340         self = randomseed;
 341         self.think(); // sets random seed and nextthink
 342         self = oldself;
 343 }
 344
 345 void spawnfunc___init_dedicated_server(void)
 346 {
 347         // handler for _init/_init map (only for dedicated server initialization)
 348
 349         world_initialized = -1; // don't complain
 350         cvar = cvar_builtin;
 351         cvar_string = cvar_string_builtin;
 352         cvar_set = cvar_set_builtin;
 353         dprint_load(); // load dprint status from cvar
 354
 355         remove = remove_unsafely;
 356
 357         entity e;
 358         e = spawn();
 359         e.think = GotoFirstMap;
 360         e.nextthink = time; // this is usually 1 at this point
 361
 362         e = spawn();
 363         e.classname = "info_player_deathmatch"; // safeguard against player joining
 364
 365         self.classname = "worldspawn"; // safeguard against various stuff ;)
 366
 367         g_maplist_allow_hidden = cvar("g_maplist_allow_hidden");
 368         MapInfo_Enumerate();
 369         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 0);
 370 }
 371
 372 void Map_MarkAsRecent(string m);
 373 float world_already_spawned;
 374 void RegisterWeapons();
 375 void Nagger_Init();
 376 void ClientInit_Spawn();
 377 void spawnfunc_worldspawn (void)
 378 {
 379         float fd, l, i, j, n;
 380         string s, col;
 381
 382         cvar = cvar_builtin;
 383         cvar_string = cvar_string_builtin;
 384         cvar_set = cvar_set_builtin;
 385         dprint_load(); // load dprint status from cvar
 386
 387         if(world_already_spawned)
 388                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 389         world_already_spawned = TRUE;
 390
 391         remove = remove_safely; // during spawning, watch what you remove!
 392
 393         check_unacceptable_compiler_bugs();
 394
 395         if(cvar_string("cvar_check_default") != "bypass")
 396         {
 397                 if(cvar_string("cvar_check_default") != CVAR_CHECK_DEFAULT)
 398                         error("Config file mismatch! Please update defaultNexuiz.cfg to match the QuakeC code, and restart the engine!");
 399
 400                 if(cvar_string("cvar_check_weapons") != CVAR_CHECK_WEAPONS)
 401                         error("Config file mismatch! Please update weapons.cfg and weaponsHavoc.cfg to match the QuakeC code, and restart the engine!");
 402         }
 403
 404         compressShortVector_init();
 405
 406         local entity head;
 407         head = nextent(world);
 408         maxclients = 0;
 409         while(head)
 410         {
 411                 ++maxclients;
 412                 head = nextent(head);
 413         }
 414
 415         // needs to be done so early as they would still spawn
 416         RegisterWeapons();
 417
 418         if(sv_cheats)
 419                 ServerProgsDB = db_create();
 420         else
 421                 ServerProgsDB = db_load("server.db");
 422
 423         TemporaryDB = db_create();
 424
 425         /*
 426         TODO sound pack system
 427         // initialize sound pack system
 428         soundpack = cvar_string("g_soundpack");
 429         if(soundpack != "")
 430                 soundpack = strcat(soundpack, "/");
 431         soundpack = strzone(soundpack);
 432         */
 433
 434         // 0 normal
 435         lightstyle(0, "m");
 436
 437         // 1 FLICKER (first variety)
 438         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 439
 440         // 2 SLOW STRONG PULSE
 441         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 442
 443         // 3 CANDLE (first variety)
 444         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 445
 446         // 4 FAST STROBE
 447         lightstyle(4, "mamamamamama");
 448
 449         // 5 GENTLE PULSE 1
 450         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 451
 452         // 6 FLICKER (second variety)
 453         lightstyle(6, "nmonqnmomnmomomno");
 454
 455         // 7 CANDLE (second variety)
 456         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 457
 458         // 8 CANDLE (third variety)
 459         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 460
 461         // 9 SLOW STROBE (fourth variety)
 462         lightstyle(9, "aaaaaaaazzzzzzzz");
 463
 464         // 10 FLUORESCENT FLICKER
 465         lightstyle(10, "mmamammmmammamamaaamammma");
 466
 467         // 11 SLOW PULSE NOT FADE TO BLACK
 468         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 469
 470         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 471
 472         // 63 testing
 473         lightstyle(63, "a");
 474
 475         if(cvar("g_campaign"))
 476                 CampaignPreInit();
 477
 478         Map_MarkAsRecent(mapname);
 479
 480         precache_model ("null"); // we need this one before InitGameplayMode
 481         InitGameplayMode();
 482         readlevelcvars();
 483         GrappleHookInit();
 484
 485         player_count = 0;
 486         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 487         if(bot_waypoints_for_items == 1)
 488                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 489                         bot_waypoints_for_items = 0;
 490
 491         // for setting by mapinfo
 492         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 493         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 494
 495         precache();
 496
 497         WaypointSprite_Init();
 498
 499         //if (g_domination)
 500         //      dom_init();
 501
 502         GameLogInit(); // prepare everything
 503         if(cvar("sv_eventlog"))
 504         {
 505                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 506                 s = strcat(s, ftos(random()));
 507                 matchid = strzone(s);
 508
 509                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 510                 s = ":gameinfo:mutators:LIST";
 511                 if(cvar("g_grappling_hook"))
 512                         s = strcat(s, ":grappling_hook");
 513                 if(!cvar("g_use_ammunition"))
 514                         s = strcat(s, ":no_use_ammunition");
 515                 if(!cvar("g_pickup_items"))
 516                         s = strcat(s, ":no_pickup_items");
 517                 if(cvar("g_instagib"))
 518                         s = strcat(s, ":instagib");
 519                 if(cvar_string("g_weaponarena") != "0")
 520                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 521                 if(cvar("g_nixnex"))
 522                         s = strcat(s, ":nixnex");
 523                 if(cvar("g_vampire"))
 524                         s = strcat(s, ":vampire");
 525                 if(cvar("g_laserguided_missile"))
 526                         s = strcat(s, ":laserguided_missile");
 527                 if(cvar("g_norecoil"))
 528                         s = strcat(s, ":norecoil");
 529                 if(cvar("g_midair"))
 530                         s = strcat(s, ":midair");
 531                 if(cvar("g_minstagib"))
 532                         s = strcat(s, ":minstagib");
 533                 GameLogEcho(s);
 534                 GameLogEcho(":gameinfo:end");
 535         }
 536         else
 537                 matchid = strzone(ftos(random()));
 538
 539         cvar_set("nextmap", "");
 540
 541         SetDefaultAlpha();
 542
 543         if(cvar("g_campaign"))
 544                 CampaignPostInit();
 545
 546         fteqcc_testbugs();
 547
 548         Ban_LoadBans();
 549
 550         //initialise globals related to sv_timeout
 551         orig_slowmo = cvar("slowmo");
 552
 553         MapInfo_Enumerate();
 554         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 1);
 555
 556         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 557         {
 558                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 559                 if(fd != -1)
 560                 {
 561                         while((s = fgets(fd)))
 562                         {
 563                                 l = tokenize_console(s);
 564                                 if(l < 2)
 565                                         continue;
 566                                 if(argv(0) == "cd")
 567                                 {
 568                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 569                                         print("  cdtrack ", argv(2), "\n");
 570                                 }
 571                                 else if(argv(0) == "fog")
 572                                 {
 573                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 574                                         print("  \"fog\" \"", s, "\"\n");
 575                                 }
 576                                 else if(argv(0) == "set")
 577                                 {
 578                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 579                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 580                                 }
 581                                 else if(argv(0) != "//")
 582                                 {
 583                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 584                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 585                                 }
 586                         }
 587                         fclose(fd);
 588                 }
 589         }
 590
 591         addstat(STAT_WEAPONS, AS_INT, weapons);
 592         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 593         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 594         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 595         Nagger_Init();
 596
 597         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 598         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 599         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 600         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 601         addstat(STAT_DAMAGE_HITS, AS_INT, damage_hits);
 602         addstat(STAT_DAMAGE_FIRED, AS_INT, maxdamage_fired);
 603         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 604         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 605
 606         next_pingtime = time + 5;
 607         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 608
 609         detect_maptype();
 610
 611         lsmaps_reply = "^7Maps available: ";
 612         for(i = 0, j = 0; i < MapInfo_count; ++i)
 613         {
 614                 if(MapInfo_Get_ByID(i))
 615                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 616                         {
 617                                 if(mod(i, 2))
 618                                         col = "^2";
 619                                 else
 620                                         col = "^3";
 621                                 ++j;
 622                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 623                         }
 624         }
 625         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 626
 627         maplist_reply = "^7Maps in list: ";
 628         n = tokenize_console(cvar_string("g_maplist"));
 629         for(i = 0, j = 0; i < n; ++i)
 630         {
 631                 if(MapInfo_CheckMap(argv(i)))
 632                 {
 633                         if(mod(j, 2))
 634                                 col = "^2";
 635                         else
 636                                 col = "^3";
 637                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 638                         ++j;
 639                 }
 640         }
 641         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 642         MapInfo_ClearTemps();
 643
 644         records_reply = strzone(getrecords());
 645
 646         ClientInit_Spawn();
 647         RandomSeed_Spawn();
 648
 649         world_initialized = 1;
 650 }
 651
 652 void spawnfunc_light (void)
 653 {
 654         //makestatic (self); // Who the f___ did that?
 655         remove(self);
 656 }
 657
 658 float TryFile( string pFilename )
 659 {
 660         local float lHandle;
 661         dprint("TryFile(\"", pFilename, "\")\n");
 662         lHandle = fopen( pFilename, FILE_READ );
 663         if( lHandle != -1 ) {
 664                 fclose( lHandle );
 665                 return TRUE;
 666         } else {
 667                 return FALSE;
 668         }
 669 };
 670
 671 string GetGametype()
 672 {
 673         return GametypeNameFromType(game);
 674 }
 675
 676 string getmapname_stored;
 677 string GetMapname()
 678 {
 679         return mapname;
 680 }
 681
 682 float Map_Count, Map_Current;
 683 string Map_Current_Name;
 684
 685 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 686 float GetMaplistPosition()
 687 {
 688         float pos, idx;
 689         string map;
 690
 691         map = GetMapname();
 692         idx = cvar("g_maplist_index");
 693
 694         if(idx >= 0)
 695                 if(idx < Map_Count)
 696                         if(map == argv(idx))
 697                                 return idx;
 698
 699         for(pos = 0; pos < Map_Count; ++pos)
 700                 if(map == argv(pos))
 701                         return pos;
 702
 703         // resume normal maplist rotation if current map is not in g_maplist
 704         return idx;
 705 }
 706
 707 float MapHasRightSize(string map)
 708 {
 709         float fh;
 710         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 711         if(cvar("g_maplist_check_waypoints"))
 712         {
 713                 dprint("checkwp "); dprint(map);
 714                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 715                 if(fh < 0)
 716                 {
 717                         dprint(": no waypoints\n");
 718                         return FALSE;
 719                 }
 720                 dprint(": has waypoints\n");
 721                 fclose(fh);
 722         }
 723
 724         // open map size restriction file
 725         dprint("opensize "); dprint(map);
 726         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 727         if(fh >= 0)
 728         {
 729                 float mapmin, mapmax;
 730                 dprint(": ok, ");
 731                 mapmin = stof(fgets(fh));
 732                 mapmax = stof(fgets(fh));
 733                 fclose(fh);
 734                 if(player_count < mapmin)
 735                 {
 736                         dprint("not enough\n");
 737                         return FALSE;
 738                 }
 739                 if(player_count > mapmax)
 740                 {
 741                         dprint("too many\n");
 742                         return FALSE;
 743                 }
 744                 dprint("right size\n");
 745                 return TRUE;
 746         }
 747         dprint(": not found\n");
 748         return TRUE;
 749 }
 750
 751 string Map_Filename(float position)
 752 {
 753         return strcat("maps/", argv(position), ".bsp");
 754 }
 755
 756 string strwords(string s, float w)
 757 {
 758         float endpos;
 759         for(endpos = 0; w && endpos >= 0; --w)
 760                 endpos = strstrofs(s, " ", endpos + 1);
 761         if(endpos < 0)
 762                 return s;
 763         else
 764                 return substring(s, 0, endpos);
 765 }
 766
 767 float strhasword(string s, string w)
 768 {
 769         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 770 }
 771
 772 void Map_MarkAsRecent(string m)
 773 {
 774         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
 775 }
 776
 777 float Map_IsRecent(string m)
 778 {
 779         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 780 }
 781
 782 float Map_Check(float position, float pass)
 783 {
 784         string filename;
 785         string map_next;
 786         map_next = argv(position);
 787         if(pass <= 1)
 788         {
 789                 if(Map_IsRecent(map_next))
 790                         return 0;
 791         }
 792         filename = Map_Filename(position);
 793         if(MapInfo_CheckMap(map_next))
 794         {
 795                 if(pass == 2)
 796                         return 1;
 797                 if(MapHasRightSize(map_next))
 798                         return 1;
 799                 return 0;
 800         }
 801         else
 802                 dprint( "Couldn't select '", filename, "'..\n" );
 803
 804         return 0;
 805 }
 806
 807 void Map_Goto_SetStr(string nextmapname)
 808 {
 809         if(getmapname_stored != "")
 810                 strunzone(getmapname_stored);
 811         if(nextmapname == "")
 812                 getmapname_stored = "";
 813         else
 814                 getmapname_stored = strzone(nextmapname);
 815 }
 816
 817 void Map_Goto_SetFloat(float position)
 818 {
 819         cvar_set("g_maplist_index", ftos(position));
 820         Map_Goto_SetStr(argv(position));
 821 }
 822
 823 void GameResetCfg()
 824 {
 825         // settings persist, except...
 826         localcmd("\nsettemp_restore\n");
 827 };
 828
 829 void Map_Goto()
 830 {
 831         GameResetCfg();
 832         MapInfo_LoadMap(getmapname_stored);
 833 }
 834
 835 // return codes of map selectors:
 836 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 837 //   -2 = permanent failure
 838 float() MaplistMethod_Iterate = // usual method
 839 {
 840         float pass, i;
 841
 842         for(pass = 1; pass <= 2; ++pass)
 843         {
 844                 for(i = 1; i < Map_Count; ++i)
 845                 {
 846                         float mapindex;
 847                         mapindex = mod(i + Map_Current, Map_Count);
 848                         if(Map_Check(mapindex, pass))
 849                                 return mapindex;
 850                 }
 851         }
 852         return -1;
 853 }
 854
 855 float() MaplistMethod_Repeat = // fallback method
 856 {
 857         if(Map_Check(Map_Current, 2))
 858                 return Map_Current;
 859         return -2;
 860 }
 861
 862 float() MaplistMethod_Random = // random map selection
 863 {
 864         float i, imax;
 865
 866         imax = 42;
 867
 868         for(i = 0; i <= imax; ++i)
 869         {
 870                 float mapindex;
 871                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 872                 if(Map_Check(mapindex, 1))
 873                         return mapindex;
 874         }
 875         return -1;
 876 }
 877
 878 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 879 // the exponent sets a bias on the map selection:
 880 // the higher the exponent, the less likely "shortly repeated" same maps are
 881 {
 882         float i, j, imax, insertpos;
 883
 884         imax = 42;
 885
 886         for(i = 0; i <= imax; ++i)
 887         {
 888                 string newlist;
 889
 890                 // now reinsert this at another position
 891                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 892                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 893                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 894                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 895
 896                 // insert the current map there
 897                 newlist = "";
 898                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 899                         newlist = strcat(newlist, " ", argv(j));
 900                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 901                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 902                         newlist = strcat(newlist, " ", argv(j));
 903                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 904                 cvar_set("g_maplist", newlist);
 905                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 906
 907                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 908                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 909                 if(Map_Check(Map_Current, 1))
 910                         return Map_Current;
 911         }
 912         return -1;
 913 }
 914
 915 void Maplist_Init()
 916 {
 917         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 918         if(Map_Count == 0)
 919         {
 920                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 921                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN));
 922                 if(cvar("g_maplist_shuffle"))
 923                         ShuffleMaplist();
 924                 localcmd("\nmenu_cmd sync\n");
 925                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 926         }
 927         if(Map_Count == 0)
 928                 error("empty maplist, cannot select a new map");
 929         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 930
 931         if(Map_Current_Name)
 932                 strunzone(Map_Current_Name);
 933         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 934         // this may or may not be correct, but who cares, in the worst case a map
 935         // isn't chosen in the first pass that should have been
 936 }
 937
 938 string GetNextMap()
 939 {
 940         float nextMap;
 941
 942         Maplist_Init();
 943         nextMap = -1;
 944
 945         if(nextMap == -1)
 946                 if(cvar("g_maplist_shuffle") > 0)
 947                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 948
 949         if(nextMap == -1)
 950                 if(cvar("g_maplist_selectrandom"))
 951                         nextMap = MaplistMethod_Random();
 952
 953         if(nextMap == -1)
 954                 nextMap = MaplistMethod_Iterate();
 955
 956         if(nextMap == -1)
 957                 nextMap = MaplistMethod_Repeat();
 958
 959         if(nextMap >= 0)
 960         {
 961                 Map_Goto_SetFloat(nextMap);
 962                 return getmapname_stored;
 963         }
 964
 965         return "";
 966 };
 967
 968 float DoNextMapOverride()
 969 {
 970         if(cvar("g_campaign"))
 971         {
 972                 CampaignPostIntermission();
 973                 alreadychangedlevel = TRUE;
 974                 return TRUE;
 975         }
 976         if(cvar("quit_when_empty"))
 977         {
 978                 if(player_count <= currentbots)
 979                 {
 980                         localcmd("quit\n");
 981                         alreadychangedlevel = TRUE;
 982                         return TRUE;
 983                 }
 984         }
 985         if(cvar_string("quit_and_redirect") != "")
 986         {
 987                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 988                 alreadychangedlevel = TRUE;
 989                 return TRUE;
 990         }
 991         if (cvar("samelevel")) // if samelevel is set, stay on same level
 992         {
 993                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 994                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 995                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 996                 localcmd("restart\n");
 997                 //changelevel (mapname);
 998                 alreadychangedlevel = TRUE;
 999                 return TRUE;
1000         }
1001         if(cvar_string("nextmap") != "")
1002                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1003                 {
1004                         Map_Goto_SetStr(cvar_string("nextmap"));
1005                         Map_Goto();
1006                         alreadychangedlevel = TRUE;
1007                         return TRUE;
1008                 }
1009         if(cvar("lastlevel"))
1010         {
1011                 GameResetCfg();
1012                 localcmd("set lastlevel 0\ntogglemenu\n");
1013                 alreadychangedlevel = TRUE;
1014                 return TRUE;
1015         }
1016         return FALSE;
1017 };
1018
1019 void GotoNextMap()
1020 {
1021         //local string nextmap;
1022         //local float n, nummaps;
1023         //local string s;
1024         if (alreadychangedlevel)
1025                 return;
1026         alreadychangedlevel = TRUE;
1027
1028         {
1029                 string nextMap;
1030                 float allowReset;
1031
1032                 for(allowReset = 1; allowReset >= 0; --allowReset)
1033                 {
1034                         nextMap = GetNextMap();
1035                         if(nextMap != "")
1036                                 break;
1037
1038                         if(allowReset)
1039                         {
1040                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1041                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN));
1042                                 if(cvar("g_maplist_shuffle"))
1043                                         ShuffleMaplist();
1044                                 localcmd("\nmenu_cmd sync\n");
1045                         }
1046                         else
1047                         {
1048                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1049                         }
1050                 }
1051                 Map_Goto();
1052         }
1053 };
1054
1055
1056 /*
1057 ============
1058 IntermissionThink
1059
1060 When the player presses attack or jump, change to the next level
1061 ============
1062 */
1063 .float autoscreenshot;
1064 void() MapVote_Start;
1065 void() MapVote_Think;
1066 float mapvote_initialized;
1067 void IntermissionThink()
1068 {
1069         FixIntermissionClient(self);
1070
1071         if(cvar("sv_autoscreenshot"))
1072         if(self.autoscreenshot > 0)
1073         if(time > self.autoscreenshot)
1074         {
1075                 self.autoscreenshot = -1;
1076                 if(clienttype(self) == CLIENTTYPE_REAL)
1077                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1078                 return;
1079         }
1080
1081         if (time < intermission_exittime)
1082                 return;
1083
1084         if(!mapvote_initialized)
1085                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1086                         return;
1087
1088         MapVote_Start();
1089 };
1090
1091 /*
1092 ============
1093 FindIntermission
1094
1095 Returns the entity to view from
1096 ============
1097 */
1098 /*
1099 entity FindIntermission()
1100 {
1101         local   entity spot;
1102         local   float cyc;
1103
1104 // look for info_intermission first
1105         spot = find (world, classname, "info_intermission");
1106         if (spot)
1107         {       // pick a random one
1108                 cyc = random() * 4;
1109                 while (cyc > 1)
1110                 {
1111                         spot = find (spot, classname, "info_intermission");
1112                         if (!spot)
1113                                 spot = find (spot, classname, "info_intermission");
1114                         cyc = cyc - 1;
1115                 }
1116                 return spot;
1117         }
1118
1119 // then look for the start position
1120         spot = find (world, classname, "info_player_start");
1121         if (spot)
1122                 return spot;
1123
1124 // testinfo_player_start is only found in regioned levels
1125         spot = find (world, classname, "testplayerstart");
1126         if (spot)
1127                 return spot;
1128
1129 // then look for the start position
1130         spot = find (world, classname, "info_player_deathmatch");
1131         if (spot)
1132                 return spot;
1133
1134         //objerror ("FindIntermission: no spot");
1135         return world;
1136 };
1137 */
1138
1139 /*
1140 ===============================================================================
1141
1142 RULES
1143
1144 ===============================================================================
1145 */
1146
1147 void DumpStats(float final)
1148 {
1149         local float file;
1150         local string s;
1151         local float to_console;
1152         local float to_eventlog;
1153         local float to_file;
1154         local float i;
1155
1156         to_console = cvar("sv_logscores_console");
1157         to_eventlog = cvar("sv_eventlog");
1158         to_file = cvar("sv_logscores_file");
1159
1160         if(!final)
1161         {
1162                 to_console = TRUE; // always print printstats replies
1163                 to_eventlog = FALSE; // but never print them to the event log
1164         }
1165
1166         if(to_eventlog)
1167                 if(cvar("sv_eventlog_console"))
1168                         to_console = FALSE; // otherwise we get the output twice
1169
1170         if(final)
1171                 s = ":scores:";
1172         else
1173                 s = ":status:";
1174         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1175
1176         if(to_console)
1177                 print(s, "\n");
1178         if(to_eventlog)
1179                 GameLogEcho(s);
1180         if(to_file)
1181         {
1182                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1183                 if(file == -1)
1184                         to_file = FALSE;
1185                 else
1186                         fputs(file, strcat(s, "\n"));
1187         }
1188
1189         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1190         if(to_console)
1191                 print(s, "\n");
1192         if(to_eventlog)
1193                 GameLogEcho(s);
1194         if(to_file)
1195                 fputs(file, strcat(s, "\n"));
1196
1197         FOR_EACH_CLIENT(other)
1198         {
1199                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1200                 {
1201                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1202                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1203                         if(other.classname == "player" || g_arena || g_lms)
1204                                 s = strcat(s, ftos(other.team), ":");
1205                         else
1206                                 s = strcat(s, "spectator:");
1207
1208                         if(to_console)
1209                                 print(s, other.netname, "\n");
1210                         if(to_eventlog)
1211                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1212                         if(to_file)
1213                                 fputs(file, strcat(s, other.netname, "\n"));
1214                 }
1215         }
1216
1217         if(teams_matter)
1218         {
1219                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1220                 if(to_console)
1221                         print(s, "\n");
1222                 if(to_eventlog)
1223                         GameLogEcho(s);
1224                 if(to_file)
1225                         fputs(file, strcat(s, "\n"));
1226
1227                 for(i = 1; i < 16; ++i)
1228                 {
1229                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1230                         s = strcat(s, ":", ftos(i));
1231                         if(to_console)
1232                                 print(s, "\n");
1233                         if(to_eventlog)
1234                                 GameLogEcho(s);
1235                         if(to_file)
1236                                 fputs(file, strcat(s, "\n"));
1237                 }
1238         }
1239
1240         if(to_console)
1241                 print(":end\n");
1242         if(to_eventlog)
1243                 GameLogEcho(":end");
1244         if(to_file)
1245         {
1246                 fputs(file, ":end\n");
1247                 fclose(file);
1248         }
1249 }
1250
1251 void FixIntermissionClient(entity e)
1252 {
1253         string s;
1254         if(!e.autoscreenshot) // initial call
1255         {
1256                 e.angles = e.v_angle;
1257                 e.angles_x = -e.angles_x;
1258                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1259                 e.health = -2342;
1260                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1261                 e.solid = SOLID_NOT;
1262                 e.movetype = MOVETYPE_NONE;
1263                 e.takedamage = DAMAGE_NO;
1264                 if(e.weaponentity)
1265                 {
1266                         e.weaponentity.effects = EF_NODRAW;
1267                         if (e.weaponentity.weaponentity)
1268                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1269                 }
1270                 if(clienttype(e) == CLIENTTYPE_REAL)
1271                 {
1272                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1273                         s = cvar_string("sv_intermission_cdtrack");
1274                         if(s != "")
1275                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1276                         msg_entity = e;
1277                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1278                 }
1279         }
1280
1281         //e.velocity = '0 0 0';
1282         //e.fixangle = TRUE;
1283
1284         // TODO halt weapon animation
1285 }
1286
1287
1288 /*
1289 go to the next level for deathmatch
1290 only called if a time or frag limit has expired
1291 */
1292 void NextLevel()
1293 {
1294         float minTotalFrags;
1295         float maxTotalFrags;
1296         float score;
1297         float f;
1298
1299         gameover = TRUE;
1300
1301         intermission_running = 1;
1302
1303 // enforce a wait time before allowing changelevel
1304         if(player_count > 0)
1305                 intermission_exittime = time + cvar("sv_mapchange_delay");
1306         else
1307                 intermission_exittime = -1;
1308
1309         /*
1310         WriteByte (MSG_ALL, SVC_CDTRACK);
1311         WriteByte (MSG_ALL, 3);
1312         WriteByte (MSG_ALL, 3);
1313         // done in FixIntermission
1314         */
1315
1316         //pos = FindIntermission ();
1317
1318         VoteReset();
1319
1320         DumpStats(TRUE);
1321
1322         if(cvar("sv_eventlog"))
1323                 GameLogEcho(":gameover");
1324
1325         GameLogClose();
1326
1327         FOR_EACH_CLIENT(other)
1328         {
1329                 FixIntermissionClient(other);
1330
1331                 if(other.winning)
1332                         bprint(other.netname, " ^7wins.\n");
1333         }
1334
1335         minTotalFrags = 0;
1336         maxTotalFrags = 0;
1337         FOR_EACH_PLAYER(other)
1338         {
1339                 if(maxTotalFrags < other.totalfrags)
1340                         maxTotalFrags = other.totalfrags;
1341                 if(minTotalFrags > other.totalfrags)
1342                         minTotalFrags = other.totalfrags;
1343         }
1344
1345         if(!currentbots)
1346         {
1347                 FOR_EACH_PLAYER(other)
1348                 {
1349                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1350                         f = bound(0, other.play_time / max(time, 1), 1);
1351                         // store some statistics?
1352                 }
1353         }
1354
1355         if(cvar("g_campaign"))
1356                 CampaignPreIntermission();
1357
1358         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1359 };
1360
1361 /*
1362 ============
1363 CheckRules_Player
1364
1365 Exit deathmatch games upon conditions
1366 ============
1367 */
1368 void CheckRules_Player()
1369 {
1370         if (gameover)   // someone else quit the game already
1371                 return;
1372
1373         if(self.deadflag == DEAD_NO)
1374                 self.play_time += frametime;
1375
1376         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1377         //   (div0: and that in CheckRules_World please)
1378 };
1379
1380 float checkrules_equality;
1381 float checkrules_suddendeathwarning;
1382 float checkrules_suddendeathend;
1383 float checkrules_overtimesadded; //how many overtimes have been already added
1384 float checkrules_status;
1385
1386 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1387 float WINNING_YES = 1; // winner found
1388 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1389 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1390
1391 void InitiateOvertime()
1392 {
1393         // Check first whether normal overtimes could be added before initiating suddendeath mode
1394         // - for this timelimit_overtime needs to be >0 of course
1395         // - also check the winning condition calculated in the previous frame and only add normal overtime
1396         //   again, if at the point at which timelimit would be extended again, still no winner was found
1397         if ((checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && (checkrules_status == WINNING_NEVER))
1398         {
1399                 ++checkrules_overtimesadded;
1400                 //add one more overtime by simply extending the timelimit
1401                 float tl;
1402                 tl = cvar("timelimit");
1403                 tl += cvar("timelimit_overtime");
1404                 cvar_set("timelimit", ftos(tl));
1405                 string minutesPlural;
1406                 if (cvar("timelimit_overtime") == 1)
1407                         minutesPlural = " ^3minute";
1408                 else
1409                         minutesPlural = " ^3minutes";
1410
1411                 bcenterprint(
1412                         strcat(
1413                                 "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1414                                 ftos(cvar("timelimit_overtime")),
1415                                 minutesPlural,
1416                                 " to the game!"
1417                         )
1418                 );
1419         }
1420         else
1421         {
1422                 if(!checkrules_suddendeathend)
1423                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1424         }
1425 }
1426
1427 float GetWinningCode(float fraglimitreached, float equality)
1428 {
1429         if(equality)
1430                 if(fraglimitreached)
1431                         return WINNING_STARTSUDDENDEATHOVERTIME;
1432                 else
1433                         return WINNING_NEVER;
1434         else
1435                 if(fraglimitreached)
1436                         return WINNING_YES;
1437                 else
1438                         return WINNING_NO;
1439 }
1440
1441 // set the .winning flag for exactly those players with a given field value
1442 void SetWinners(.float field, float value)
1443 {
1444         entity head;
1445         FOR_EACH_PLAYER(head)
1446                 head.winning = (head.field == value);
1447 }
1448
1449 // set the .winning flag for those players with a given field value
1450 void AddWinners(.float field, float value)
1451 {
1452         entity head;
1453         FOR_EACH_PLAYER(head)
1454                 if(head.field == value)
1455                         head.winning = 1;
1456 }
1457
1458 // clear the .winning flags
1459 void ClearWinners(void)
1460 {
1461         entity head;
1462         FOR_EACH_PLAYER(head)
1463                 head.winning = 0;
1464 }
1465
1466 // Onslaught winning condition:
1467 // game terminates if only one team has a working generator (or none)
1468 float WinningCondition_Onslaught()
1469 {
1470         entity head;
1471         local float t1, t2, t3, t4;
1472
1473         WinningConditionHelper(); // set worldstatus
1474
1475         // first check if the game has ended
1476         t1 = t2 = t3 = t4 = 0;
1477         head = find(world, classname, "onslaught_generator");
1478         while (head)
1479         {
1480                 if (head.health > 0)
1481                 {
1482                         if (head.team == COLOR_TEAM1) t1 = 1;
1483                         if (head.team == COLOR_TEAM2) t2 = 1;
1484                         if (head.team == COLOR_TEAM3) t3 = 1;
1485                         if (head.team == COLOR_TEAM4) t4 = 1;
1486                 }
1487                 head = find(head, classname, "onslaught_generator");
1488         }
1489         if (t1 + t2 + t3 + t4 < 2)
1490         {
1491                 // game over, only one team remains (or none)
1492                 ClearWinners();
1493                 if (t1) SetWinners(team, COLOR_TEAM1);
1494                 if (t2) SetWinners(team, COLOR_TEAM2);
1495                 if (t3) SetWinners(team, COLOR_TEAM3);
1496                 if (t4) SetWinners(team, COLOR_TEAM4);
1497                 dprint("Have a winner, ending game.\n");
1498                 return WINNING_YES;
1499         }
1500
1501         // Two or more teams remain
1502         return WINNING_NO;
1503 }
1504
1505 float LMS_NewPlayerLives()
1506 {
1507         float fl;
1508         fl = cvar("fraglimit");
1509         if(fl == 0)
1510                 fl = 999;
1511
1512         // first player has left the game for dying too much? Nobody else can get in.
1513         if(lms_lowest_lives < 1)
1514                 return 0;
1515
1516         if(!cvar("g_lms_join_anytime"))
1517                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1518                         return 0;
1519
1520         return bound(1, lms_lowest_lives, fl);
1521 }
1522
1523 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1524 // they win. Otherwise the defending team wins once the timelimit passes.
1525 void assault_new_round();
1526 float WinningCondition_Assault()
1527 {
1528         local float status;
1529
1530         WinningConditionHelper(); // set worldstatus
1531
1532         status = WINNING_NO;
1533         // as the timelimit has not yet passed just assume the defending team will win
1534         if(assault_attacker_team == COLOR_TEAM1)
1535         {
1536                 SetWinners(team, COLOR_TEAM2);
1537         }
1538         else
1539         {
1540                 SetWinners(team, COLOR_TEAM1);
1541         }
1542
1543         local entity ent;
1544         ent = find(world, classname, "target_assault_roundend");
1545         if(ent)
1546         {
1547                 if(ent.winning) // round end has been triggered by attacking team
1548                 {
1549                         bprint("ASSAULT: round completed...\n");
1550                         SetWinners(team, assault_attacker_team);
1551
1552                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1553
1554                         if(ent.cnt == 1) // this was the second round
1555                         {
1556                                 status = WINNING_YES;
1557                         }
1558                         else
1559                         {
1560                                 local entity oldself;
1561                                 oldself = self;
1562                                 self = ent;
1563                                 assault_new_round();
1564                                 self = oldself;
1565                         }
1566                 }
1567         }
1568
1569         return status;
1570 }
1571
1572 // LMS winning condition: game terminates if and only if there's at most one
1573 // one player who's living lives. Top two scores being equal cancels the time
1574 // limit.
1575 float WinningCondition_LMS()
1576 {
1577         entity head, head2;
1578         float have_player;
1579         float have_players;
1580         float l;
1581
1582         have_player = FALSE;
1583         have_players = FALSE;
1584         l = LMS_NewPlayerLives();
1585
1586         head = find(world, classname, "player");
1587         if(head)
1588                 have_player = TRUE;
1589         head2 = find(head, classname, "player");
1590         if(head2)
1591                 have_players = TRUE;
1592
1593         if(have_player)
1594         {
1595                 // we have at least one player
1596                 if(have_players)
1597                 {
1598                         // two or more active players - continue with the game
1599                 }
1600                 else
1601                 {
1602                         // exactly one player?
1603
1604                         ClearWinners();
1605                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1606
1607                         if(l)
1608                         {
1609                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1610                                 return WINNING_NO;
1611                         }
1612                         else
1613                         {
1614                                 // a winner!
1615                                 // and assign him his first place
1616                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1617                                 return WINNING_YES;
1618                         }
1619                 }
1620         }
1621         else
1622         {
1623                 // nobody is playing at all...
1624                 if(l)
1625                 {
1626                         // wait for players...
1627                 }
1628                 else
1629                 {
1630                         // SNAFU (maybe a draw game?)
1631                         ClearWinners();
1632                         dprint("No players, ending game.\n");
1633                         return WINNING_YES;
1634                 }
1635         }
1636
1637         // When we get here, we have at least two players who are actually LIVING,
1638         // now check if the top two players have equal score.
1639         WinningConditionHelper();
1640
1641         ClearWinners();
1642         if(WinningConditionHelper_winner)
1643                 WinningConditionHelper_winner.winning = TRUE;
1644         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1645                 return WINNING_NEVER;
1646
1647         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1648         return WINNING_NO;
1649 }
1650
1651 void ShuffleMaplist()
1652 {
1653         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1654 }
1655
1656 float leaderfrags;
1657 float WinningCondition_Scores(float limit, float leadlimit)
1658 {
1659         // TODO make everything use THIS winning condition (except LMS)
1660         WinningConditionHelper();
1661
1662         if(teams_matter)
1663         {
1664                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1665                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1666                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1667                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1668         }
1669
1670         ClearWinners();
1671         if(WinningConditionHelper_winner)
1672                 WinningConditionHelper_winner.winning = 1;
1673         if(WinningConditionHelper_winnerteam >= 0)
1674                 SetWinners(team, WinningConditionHelper_winnerteam);
1675
1676         if(WinningConditionHelper_lowerisbetter)
1677         {
1678                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1679                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1680                 limit = -limit;
1681         }
1682
1683         if(WinningConditionHelper_zeroisworst)
1684                 leadlimit = 0; // not supported in this mode
1685
1686         if(g_dm || g_tdm || g_arena || (g_race && !g_race_qualifying) || g_nexball)
1687         // these modes always score in increments of 1, thus this makes sense
1688         {
1689                 if(leaderfrags != WinningConditionHelper_topscore)
1690                 {
1691                         leaderfrags = WinningConditionHelper_topscore;
1692
1693                         if (limit)
1694                         if (leaderfrags == limit - 1)
1695                                 play2all("announcer/robotic/1fragleft.wav");
1696                         else if (leaderfrags == limit - 2)
1697                                 play2all("announcer/robotic/2fragsleft.wav");
1698                         else if (leaderfrags == limit - 3)
1699                                 play2all("announcer/robotic/3fragsleft.wav");
1700                 }
1701         }
1702
1703         return GetWinningCode(
1704                 WinningConditionHelper_topscore &&
1705                 (
1706                         (limit && (WinningConditionHelper_topscore >= limit))
1707                         ||
1708                         (leadlimit && (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit))
1709                 ),
1710                 WinningConditionHelper_equality
1711         );
1712 }
1713
1714 float WinningCondition_Race(float fraglimit)
1715 {
1716         float wc;
1717         entity p;
1718         wc = WinningCondition_Scores(fraglimit, 0);
1719
1720         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1721         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1722         // do NOT support equality when the laps are all raced!
1723         {
1724                 FOR_EACH_PLAYER(p)
1725                         if not(p.race_completed)
1726                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1727                 return WINNING_YES;
1728         }
1729         return wc;
1730 }
1731
1732 void ReadyRestart();
1733 float WinningCondition_QualifyingThenRace(float limit)
1734 {
1735         float wc;
1736         wc = WinningCondition_Scores(limit, 0);
1737
1738         // NEVER initiate overtime
1739         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1740         {
1741                 return WINNING_YES;
1742         }
1743
1744         return wc;
1745 }
1746
1747 float WinningCondition_RanOutOfSpawns()
1748 {
1749         entity head;
1750
1751         if(!have_team_spawns)
1752                 return WINNING_NO;
1753
1754         if(!some_spawn_has_been_used)
1755                 return WINNING_NO;
1756
1757         team1_score = team2_score = team3_score = team4_score = 0;
1758
1759         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1760         {
1761                 if(head.team == COLOR_TEAM1)
1762                         team1_score = 1;
1763                 else if(head.team == COLOR_TEAM2)
1764                         team2_score = 1;
1765                 else if(head.team == COLOR_TEAM3)
1766                         team3_score = 1;
1767                 else if(head.team == COLOR_TEAM4)
1768                         team4_score = 1;
1769         }
1770
1771         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1772         {
1773                 if(head.team == COLOR_TEAM1)
1774                         team1_score = 1;
1775                 else if(head.team == COLOR_TEAM2)
1776                         team2_score = 1;
1777                 else if(head.team == COLOR_TEAM3)
1778                         team3_score = 1;
1779                 else if(head.team == COLOR_TEAM4)
1780                         team4_score = 1;
1781         }
1782
1783         ClearWinners();
1784         if(team1_score + team2_score + team3_score + team4_score == 0)
1785         {
1786                 checkrules_equality = TRUE;
1787                 return WINNING_YES;
1788         }
1789         else if(team1_score + team2_score + team3_score + team4_score == 1)
1790         {
1791                 float t, i;
1792                 if(team1_score) t = COLOR_TEAM1;
1793                 if(team2_score) t = COLOR_TEAM2;
1794                 if(team3_score) t = COLOR_TEAM3;
1795                 if(team4_score) t = COLOR_TEAM4;
1796                 CheckAllowedTeams(world);
1797                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1798                 {
1799                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1800                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1801                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1802                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1803                 }
1804
1805                 AddWinners(team, t);
1806                 return WINNING_YES;
1807         }
1808         else
1809                 return WINNING_NO;
1810 }
1811
1812 /*
1813 ============
1814 CheckRules_World
1815
1816 Exit deathmatch games upon conditions
1817 ============
1818 */
1819 void CheckRules_World()
1820 {
1821         float timelimit;
1822         float fraglimit;
1823         float leadlimit;
1824
1825         VoteThink();
1826         MapVote_Think();
1827
1828         SetDefaultAlpha();
1829
1830         /*
1831         MapVote_Think should now do that part
1832         if (intermission_running)
1833                 if (time >= intermission_exittime + 60)
1834                 {
1835                         if(!DoNextMapOverride())
1836                                 GotoNextMap();
1837                         return;
1838                 }
1839         */
1840
1841         if (gameover)   // someone else quit the game already
1842         {
1843                 if(player_count == 0) // Nobody there? Then let's go to the next map
1844                         MapVote_Start();
1845                         // this will actually check the player count in the next frame
1846                         // again, but this shouldn't hurt
1847                 return;
1848         }
1849
1850         timelimit = cvar("timelimit") * 60;
1851         fraglimit = cvar("fraglimit");
1852         leadlimit = cvar("leadlimit");
1853
1854         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1855         {
1856                 if(timelimit > 0)
1857                         timelimit = 0; // timelimit is not made for warmup
1858                 if(fraglimit > 0)
1859                         fraglimit = 0; // no fraglimit for now
1860                 leadlimit = 0; // no leadlimit for now
1861         }
1862
1863         if(timelimit > 0)
1864         {
1865                 timelimit += game_starttime;
1866         }
1867         else if (timelimit < 0)
1868         {
1869                 // endmatch
1870                 NextLevel();
1871                 return;
1872         }
1873
1874         if(checkrules_suddendeathend)
1875         {
1876                 if(!checkrules_suddendeathwarning)
1877                 {
1878                         checkrules_suddendeathwarning = TRUE;
1879                         if(g_race && !g_race_qualifying)
1880                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1881                         else
1882                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1883                 }
1884         }
1885         else
1886         {
1887                 if (timelimit && time >= timelimit)
1888                 {
1889                         if(g_race && g_race_qualifying == 2 && timelimit > 0)
1890                         {
1891                                 float totalplayers;
1892                                 float playerswithlaps;
1893                                 float readyplayers;
1894                                 entity head;
1895                                 totalplayers = playerswithlaps = readyplayers = 0;
1896                                 FOR_EACH_PLAYER(head)
1897                                 {
1898                                         ++totalplayers;
1899                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1900                                                 ++playerswithlaps;
1901                                         if(head.ready)
1902                                                 ++readyplayers;
1903                                 }
1904
1905                                 // at least 2/3 of the players have completed a lap: start the RACE
1906                                 // otherwise, the players should end the qualifying on their own
1907                                 if(readyplayers || ((totalplayers >= 3) && (playerswithlaps * 3 >= totalplayers * 2)))
1908                                 {
1909                                         checkrules_suddendeathend = 0;
1910                                         ReadyRestart(); // go to race
1911                                 }
1912                                 else
1913                                         InitiateOvertime();
1914                         }
1915                         else
1916                                 InitiateOvertime();
1917                 }
1918         }
1919
1920         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1921         {
1922                 NextLevel();
1923                 return;
1924         }
1925
1926         checkrules_status = WinningCondition_RanOutOfSpawns();
1927         if(checkrules_status == WINNING_YES)
1928         {
1929                 bprint("Hey! Someone ran out of spawns!\n");
1930         }
1931         else if(g_race && !g_race_qualifying && timelimit >= 0)
1932         {
1933                 checkrules_status = WinningCondition_Race(fraglimit);
1934         }
1935         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
1936         {
1937                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
1938         }
1939         else if(g_assault)
1940         {
1941                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
1942         }
1943         else if(g_lms)
1944         {
1945                 checkrules_status = WinningCondition_LMS();
1946         }
1947         else if (g_onslaught)
1948         {
1949                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
1950         }
1951         else
1952         {
1953                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1954         }
1955
1956         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1957         {
1958                 checkrules_status = WINNING_NEVER;
1959                 InitiateOvertime();
1960         }
1961
1962         if(checkrules_status == WINNING_NEVER)
1963                 // equality cases! Nobody wins if the overtime ends in a draw.
1964                 ClearWinners();
1965
1966         if(checkrules_suddendeathend)
1967                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1968                         checkrules_status = WINNING_YES;
1969
1970         if(checkrules_status == WINNING_YES)
1971                 NextLevel();
1972 };
1973
1974 float mapvote_nextthink;
1975 float mapvote_initialized;
1976 float mapvote_keeptwotime;
1977 float mapvote_timeout;
1978 string mapvote_message;
1979 string mapvote_screenshot_dir;
1980
1981 float mapvote_count;
1982 float mapvote_count_real;
1983 string mapvote_maps[MAPVOTE_COUNT];
1984 float mapvote_maps_suggested[MAPVOTE_COUNT];
1985 string mapvote_suggestions[MAPVOTE_COUNT];
1986 float mapvote_suggestion_ptr;
1987 float mapvote_maxlen;
1988 float mapvote_voters;
1989 float mapvote_votes[MAPVOTE_COUNT];
1990 float mapvote_run;
1991 float mapvote_detail;
1992 float mapvote_abstain;
1993 .float mapvote;
1994
1995 void MapVote_ClearAllVotes()
1996 {
1997         FOR_EACH_CLIENT(other)
1998                 other.mapvote = 0;
1999 }
2000
2001 string MapVote_Suggest(string m)
2002 {
2003         float i;
2004         if(m == "")
2005                 return "That's not how to use this command.";
2006         if(!cvar("g_maplist_votable_suggestions"))
2007                 return "Suggestions are not accepted on this server.";
2008         if(mapvote_initialized)
2009                 return "Can't suggest - voting is already in progress!";
2010         m = MapInfo_FixName(m);
2011         if(!m)
2012                 return "The map you suggested is not available on this server.";
2013         if(!cvar("g_maplist_votable_override_mostrecent"))
2014                 if(Map_IsRecent(m))
2015                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2016
2017         if(!MapInfo_CheckMap(m))
2018                 return "The map you suggested does not support the current game mode.";
2019         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2020                 if(mapvote_suggestions[i] == m)
2021                         return "This map was already suggested.";
2022         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2023         {
2024                 i = floor(random() * mapvote_suggestion_ptr);
2025         }
2026         else
2027         {
2028                 i = mapvote_suggestion_ptr;
2029                 mapvote_suggestion_ptr += 1;
2030         }
2031         if(mapvote_suggestions[i] != "")
2032                 strunzone(mapvote_suggestions[i]);
2033         mapvote_suggestions[i] = strzone(m);
2034         if(cvar("sv_eventlog"))
2035                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2036         return strcat("Suggestion of ", m, " accepted.");
2037 }
2038
2039 void MapVote_AddVotable(string nextMap, float isSuggestion)
2040 {
2041         float j;
2042         if(nextMap == "")
2043                 return;
2044         for(j = 0; j < mapvote_count; ++j)
2045                 if(mapvote_maps[j] == nextMap)
2046                         return;
2047         if(strlen(nextMap) > mapvote_maxlen)
2048                 mapvote_maxlen = strlen(nextMap);
2049         mapvote_maps[mapvote_count] = strzone(nextMap);
2050         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2051         mapvote_count += 1;
2052 }
2053
2054 void MapVote_Spawn();
2055 void MapVote_Init()
2056 {
2057         float i;
2058         float nmax, smax;
2059
2060         MapVote_ClearAllVotes();
2061
2062         mapvote_count = 0;
2063         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2064         mapvote_abstain = cvar("g_maplist_votable_abstain");
2065
2066         if(mapvote_abstain)
2067                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2068         else
2069                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2070         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2071
2072         if(mapvote_suggestion_ptr)
2073                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2074                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2075
2076         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2077                 MapVote_AddVotable(GetNextMap(), FALSE);
2078
2079         if(mapvote_count == 0)
2080         {
2081                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2082                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN));
2083                 if(cvar("g_maplist_shuffle"))
2084                         ShuffleMaplist();
2085                 localcmd("\nmenu_cmd sync\n");
2086                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2087                         MapVote_AddVotable(GetNextMap(), FALSE);
2088         }
2089
2090         mapvote_count_real = mapvote_count;
2091         if(mapvote_abstain)
2092                 MapVote_AddVotable("don't care", 0);
2093
2094         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2095
2096         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2097         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2098         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2099                 mapvote_keeptwotime = 0;
2100         mapvote_message = "Choose a map and press its key!";
2101
2102         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
2103         if(mapvote_screenshot_dir == "")
2104                 mapvote_screenshot_dir = "maps";
2105         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
2106
2107         MapVote_Spawn();
2108 }
2109
2110 void MapVote_SendPicture(float id)
2111 {
2112         msg_entity = self;
2113         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2114         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2115         WriteByte(MSG_ONE, id);
2116         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
2117 }
2118
2119 float GameCommand_MapVote(string cmd)
2120 {
2121         if(!intermission_running)
2122                 return FALSE;
2123
2124         if(cmd == "mv_getpic")
2125         {
2126                 MapVote_SendPicture(stof(argv(1)));
2127                 return TRUE;
2128         }
2129
2130         return FALSE;
2131 }
2132
2133 float MapVote_GetMapMask()
2134 {
2135         float mask, i, power;
2136         mask = 0;
2137         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2138                 if(mapvote_maps[i] != "")
2139                         mask |= power;
2140         return mask;
2141 }
2142
2143 entity mapvote_ent;
2144 float MapVote_SendEntity(entity to, float sf)
2145 {
2146         string mapfile, pakfile;
2147         float i, o;
2148
2149         if(sf & 1)
2150                 sf &~= 2; // if we send 1, we don't need to also send 2
2151
2152         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2153         WriteByte(MSG_ENTITY, sf);
2154
2155         if(sf & 1)
2156         {
2157                 // flag 1 == initialization
2158                 WriteString(MSG_ENTITY, mapvote_screenshot_dir);
2159                 WriteByte(MSG_ENTITY, mapvote_count);
2160                 WriteByte(MSG_ENTITY, mapvote_abstain);
2161                 WriteByte(MSG_ENTITY, mapvote_detail);
2162                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2163                 if(mapvote_count <= 8)
2164                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2165                 else
2166                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2167                 for(i = 0; i < mapvote_count; ++i)
2168                         if(mapvote_maps[i] != "")
2169                         {
2170                                 if(mapvote_abstain && i == mapvote_count - 1)
2171                                 {
2172                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2173                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2174                                 }
2175                                 else
2176                                 {
2177                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2178                                         mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
2179                                         pakfile = whichpack(strcat(mapfile, ".tga"));
2180                                         if(pakfile == "")
2181                                                 pakfile = whichpack(strcat(mapfile, ".jpg"));
2182                                         if(pakfile == "")
2183                                                 pakfile = whichpack(strcat(mapfile, ".png"));
2184                                         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2185                                                 pakfile = substring(pakfile, o, 999);
2186                                         WriteString(MSG_ENTITY, pakfile);
2187                                 }
2188                         }
2189         }
2190
2191         if(sf & 2)
2192         {
2193                 // flag 2 == update of mask
2194                 if(mapvote_count <= 8)
2195                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2196                 else
2197                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2198         }
2199
2200         if(sf & 4)
2201         {
2202                 if(mapvote_detail)
2203                         for(i = 0; i < mapvote_count; ++i)
2204                                 if(mapvote_maps[i] != "")
2205                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2206
2207                 WriteByte(MSG_ENTITY, to.mapvote);
2208         }
2209
2210         return TRUE;
2211 }
2212
2213 void MapVote_Spawn()
2214 {
2215         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2216 }
2217
2218 void MapVote_TouchMask()
2219 {
2220         mapvote_ent.SendFlags |= 2;
2221 }
2222
2223 void MapVote_TouchVotes(entity voter)
2224 {
2225         mapvote_ent.SendFlags |= 4;
2226 }
2227
2228 float MapVote_Finished(float mappos)
2229 {
2230         string result;
2231         float i;
2232         float didntvote;
2233
2234         if(cvar("sv_eventlog"))
2235         {
2236                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2237                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2238                 didntvote = mapvote_voters;
2239                 for(i = 0; i < mapvote_count; ++i)
2240                         if(mapvote_maps[i] != "")
2241                         {
2242                                 didntvote -= mapvote_votes[i];
2243                                 if(i != mappos)
2244                                 {
2245                                         result = strcat(result, ":", mapvote_maps[i]);
2246                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2247                                 }
2248                         }
2249                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2250
2251                 GameLogEcho(result);
2252                 if(mapvote_maps_suggested[mappos])
2253                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2254         }
2255
2256         FOR_EACH_REALCLIENT(other)
2257                 FixClientCvars(other);
2258
2259         Map_Goto_SetStr(mapvote_maps[mappos]);
2260         Map_Goto();
2261         alreadychangedlevel = TRUE;
2262         return TRUE;
2263 }
2264 void MapVote_CheckRules_1()
2265 {
2266         float i;
2267
2268         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2269         {
2270                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2271                 mapvote_votes[i] = 0;
2272         }
2273
2274         mapvote_voters = 0;
2275         FOR_EACH_REALCLIENT(other)
2276         {
2277                 ++mapvote_voters;
2278                 if(other.mapvote)
2279                 {
2280                         i = other.mapvote - 1;
2281                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2282                         mapvote_votes[i] = mapvote_votes[i] + 1;
2283                 }
2284         }
2285 }
2286
2287 float MapVote_CheckRules_2()
2288 {
2289         float i;
2290         float firstPlace, secondPlace;
2291         float firstPlaceVotes, secondPlaceVotes;
2292         float mapvote_voters_real;
2293         string result;
2294
2295         if(mapvote_count_real == 1)
2296                 return MapVote_Finished(0);
2297
2298         mapvote_voters_real = mapvote_voters;
2299         if(mapvote_abstain)
2300                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2301
2302         RandomSelection_Init();
2303         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2304                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2305         firstPlace = RandomSelection_chosen_float;
2306         firstPlaceVotes = RandomSelection_best_priority;
2307         //dprint("First place: ", ftos(firstPlace), "\n");
2308         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2309
2310         RandomSelection_Init();
2311         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2312                 if(i != firstPlace)
2313                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2314         secondPlace = RandomSelection_chosen_float;
2315         secondPlaceVotes = RandomSelection_best_priority;
2316         //dprint("Second place: ", ftos(secondPlace), "\n");
2317         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2318
2319         if(firstPlace == -1)
2320                 error("No first place in map vote... WTF?");
2321
2322         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2323                 return MapVote_Finished(firstPlace);
2324
2325         if(mapvote_keeptwotime)
2326                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2327                 {
2328                         float didntvote;
2329                         MapVote_TouchMask();
2330                         mapvote_message = "Now decide between the TOP TWO!";
2331                         mapvote_keeptwotime = 0;
2332                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2333                         result = strcat(result, ":", ftos(firstPlaceVotes));
2334                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2335                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2336                         didntvote = mapvote_voters;
2337                         for(i = 0; i < mapvote_count; ++i)
2338                                 if(mapvote_maps[i] != "")
2339                                 {
2340                                         didntvote -= mapvote_votes[i];
2341                                         if(i != firstPlace)
2342                                                 if(i != secondPlace)
2343                                                 {
2344                                                         result = strcat(result, ":", mapvote_maps[i]);
2345                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2346                                                         if(i < mapvote_count_real)
2347                                                         {
2348                                                                 strunzone(mapvote_maps[i]);
2349                                                                 mapvote_maps[i] = "";
2350                                                         }
2351                                                 }
2352                                 }
2353                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2354                         if(cvar("sv_eventlog"))
2355                                 GameLogEcho(result);
2356                 }
2357
2358         return FALSE;
2359 }
2360 void MapVote_Tick()
2361 {
2362         float keeptwo;
2363         float totalvotes;
2364
2365         keeptwo = mapvote_keeptwotime;
2366         MapVote_CheckRules_1(); // count
2367         if(MapVote_CheckRules_2()) // decide
2368                 return;
2369
2370         totalvotes = 0;
2371         FOR_EACH_REALCLIENT(other)
2372         {
2373                 // hide scoreboard again
2374                 if(other.health != 2342)
2375                 {
2376                         other.health = 2342;
2377                         other.impulse = 0;
2378                         if(clienttype(other) == CLIENTTYPE_REAL)
2379                         {
2380                                 msg_entity = other;
2381                                 WriteByte(MSG_ONE, SVC_FINALE);
2382                                 WriteString(MSG_ONE, "");
2383                         }
2384                 }
2385
2386                 // clear possibly invalid votes
2387                 if(mapvote_maps[other.mapvote - 1] == "")
2388                         other.mapvote = 0;
2389                 // use impulses as new vote
2390                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2391                         if(mapvote_maps[other.impulse - 1] != "")
2392                         {
2393                                 other.mapvote = other.impulse;
2394                                 MapVote_TouchVotes(other);
2395                         }
2396                 other.impulse = 0;
2397
2398                 if(other.mapvote)
2399                         ++totalvotes;
2400         }
2401
2402         MapVote_CheckRules_1(); // just count
2403 }
2404 void MapVote_Start()
2405 {
2406         if(mapvote_run)
2407                 return;
2408
2409         MapInfo_Enumerate();
2410         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 1))
2411                 mapvote_run = TRUE;
2412 }
2413 void MapVote_Think()
2414 {
2415         if(!mapvote_run)
2416                 return;
2417
2418         if(alreadychangedlevel)
2419                 return;
2420
2421         if(time < mapvote_nextthink)
2422                 return;
2423         //dprint("tick\n");
2424
2425         mapvote_nextthink = time + 0.5;
2426
2427         if(!mapvote_initialized)
2428         {
2429                 mapvote_initialized = TRUE;
2430                 if(DoNextMapOverride())
2431                         return;
2432                 if(!cvar("g_maplist_votable") || player_count <= 0)
2433                 {
2434                         GotoNextMap();
2435                         return;
2436                 }
2437                 MapVote_Init();
2438         }
2439
2440         MapVote_Tick();
2441 };
2442
2443 string GotoMap(string m)
2444 {
2445         if(!MapInfo_CheckMap(m))
2446                 return "The map you chose is not available on this server.";
2447         cvar_set("nextmap", m);
2448         cvar_set("timelimit", "-1");
2449         if(mapvote_initialized || alreadychangedlevel)
2450         {
2451                 if(DoNextMapOverride())
2452                         return "Map switch initiated.";
2453                 else
2454                         return "Hm... no. For some reason I like THIS map more.";
2455         }
2456         else
2457                 return "Map switch will happen after scoreboard.";
2458 }
2459
2460
2461 void EndFrame()
2462 {
2463         FOR_EACH_REALCLIENT(self)
2464         {
2465                 if(self.classname == "spectator")
2466                 {
2467                         if(self.enemy.typehitsound)
2468                                 play2(self, "misc/typehit.wav");
2469                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2470                                 play2(self, "misc/hit.wav");
2471                 }
2472                 else
2473                 {
2474                         if(self.typehitsound)
2475                                 play2(self, "misc/typehit.wav");
2476                         else if(self.hitsound && self.cvar_cl_hitsound)
2477                                 play2(self, "misc/hit.wav");
2478                 }
2479         }
2480         FOR_EACH_CLIENT(self)
2481         {
2482                 self.hitsound = FALSE;
2483                 self.typehitsound = FALSE;
2484         }
2485 }
2486
2487
2488 /*
2489  * RedirectionThink:
2490  * returns TRUE if redirecting
2491  */
2492 float redirection_timeout;
2493 float redirection_nextthink;
2494 float RedirectionThink()
2495 {
2496         float clients_found;
2497
2498         if(redirection_target == "")
2499                 return FALSE;
2500
2501         if(!redirection_timeout)
2502         {
2503                 cvar_set("sv_public", "-2");
2504                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2505                 if(redirection_target == "self")
2506                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2507                 else
2508                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2509         }
2510
2511         if(time < redirection_nextthink)
2512                 return TRUE;
2513
2514         redirection_nextthink = time + 1;
2515
2516         clients_found = 0;
2517         FOR_EACH_REALCLIENT(self)
2518         {
2519                 print("Redirecting: sending connect command to ", self.netname, "\n");
2520                 if(redirection_target == "self")
2521                         stuffcmd(self, "\ndisconnect; reconnect\n");
2522                 else
2523                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2524                 ++clients_found;
2525         }
2526
2527         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2528
2529         if(time > redirection_timeout || clients_found == 0)
2530                 localcmd("\nwait; wait; wait; quit\n");
2531
2532         return TRUE;
2533 }
2534
2535 void RestoreGame()
2536 {
2537         // Loaded from a save game
2538         // some things then break, so let's work around them...
2539
2540         // Progs DB (capture records)
2541         if(sv_cheats)
2542                 ServerProgsDB = db_create();
2543         else
2544                 ServerProgsDB = db_load("server.db");
2545
2546         // Mapinfo
2547         MapInfo_Shutdown();
2548         MapInfo_Enumerate();
2549         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 1);
2550 }
2551
2552 void SV_Shutdown()
2553 {
2554         if(world_initialized > 0)
2555         {
2556                 world_initialized = 0;
2557                 print("Saving persistent data...\n");
2558                 Ban_SaveBans();
2559                 if(!sv_cheats)
2560                         db_save(ServerProgsDB, "server.db");
2561                 if(cvar("developer"))
2562                         db_save(TemporaryDB, "server-temp.db");
2563                 db_close(ServerProgsDB);
2564                 db_close(TemporaryDB);
2565                 print("done!\n");
2566                 // tell the bot system the game is ending now
2567                 bot_endgame();
2568
2569                 MapInfo_Shutdown();
2570         }
2571         else if(world_initialized == 0)
2572         {
2573                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2574         }
2575 }