data/qcsrc/server/cl_physics.qc

   1 float sv_accelerate;
   2 float sv_friction;
   3 float sv_maxspeed;
   4 float sv_airaccelerate;
   5 float sv_maxairspeed;
   6 float sv_stopspeed;
   7 float sv_gravity;
   8 float sv_airaccel_sideways_friction;
   9 float sv_airaccel_qw;
  10 .float ladder_time;
  11 .entity ladder_entity;
  12 .float gravity;
  13 .float swamp_slowdown;
  14 .float lastflags;
  15 .float lastground;
  16
  17 /*
  18 =============
  19 PlayerJump
  20
  21 When you press the jump key
  22 =============
  23 */
  24 void PlayerJump (void)
  25 {
  26         float mjumpheight;
  27
  28         mjumpheight = cvar("sv_jumpvelocity");
  29         if (self.waterlevel >= 2)
  30         {
  31                 if (self.watertype == CONTENT_WATER)
  32                         self.velocity_z = 200;
  33                 else if (self.watertype == CONTENT_SLIME)
  34                         self.velocity_z = 80;
  35                 else
  36                         self.velocity_z = 50;
  37
  38                 return;
  39         }
  40
  41
  42         if (!(self.flags & FL_ONGROUND))
  43                 return;
  44
  45         if (!(self.flags & FL_JUMPRELEASED))
  46                 return;
  47
  48         if(cvar("g_runematch"))
  49         {
  50                 if(self.runes & RUNE_SPEED)
  51                 {
  52                         if(self.runes & CURSE_SLOW)
  53                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
  54                         else
  55                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  56                 }
  57                 else if(self.runes & CURSE_SLOW)
  58                 {
  59                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
  60                 }
  61         }
  62
  63         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
  64         {
  65                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
  66         }
  67
  68         self.velocity_z = self.velocity_z + mjumpheight;
  69         self.oldvelocity_z = self.velocity_z;
  70
  71         self.flags = self.flags - FL_ONGROUND;
  72         self.flags = self.flags - FL_JUMPRELEASED;
  73 }
  74
  75 void() CheckWaterJump =
  76 {
  77         local vector start, end;
  78
  79 // check for a jump-out-of-water
  80         makevectors (self.angles);
  81         start = self.origin;
  82         start_z = start_z + 8;
  83         v_forward_z = 0;
  84         normalize(v_forward);
  85         end = start + v_forward*24;
  86         traceline (start, end, TRUE, self);
  87         if (trace_fraction < 1)
  88         {       // solid at waist
  89                 start_z = start_z + self.maxs_z - 8;
  90                 end = start + v_forward*24;
  91                 self.movedir = trace_plane_normal * -50;
  92                 traceline (start, end, TRUE, self);
  93                 if (trace_fraction == 1)
  94                 {       // open at eye level
  95                         self.flags = self.flags | FL_WATERJUMP;
  96                         self.velocity_z = 225;
  97                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
  98                         self.teleport_time = time + 2;  // safety net
  99                         return;
 100                 }
 101         }
 102 };
 103
 104
 105 void Nixnex_GiveCurrentWeapon();
 106 void SV_PlayerPhysics()
 107 {
 108         local vector wishvel, wishdir, v;
 109         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod;
 110         string temps;
 111
 112         if (clienttype(self) == CLIENTTYPE_BOT)
 113                 bot_think();
 114
 115         if (self.movetype == MOVETYPE_NONE)
 116                 return;
 117
 118         if (self.punchangle != '0 0 0')
 119         {
 120                 f = vlen(self.punchangle) - 10 * frametime;
 121                 if (f > 0)
 122                         self.punchangle = normalize(self.punchangle) * f;
 123                 else
 124                         self.punchangle = '0 0 0';
 125         }
 126
 127         if (self.punchvector != '0 0 0')
 128         {
 129                 f = vlen(self.punchvector) - 30 * frametime;
 130                 if (f > 0)
 131                         self.punchvector = normalize(self.punchvector) * f;
 132                 else
 133                         self.punchvector = '0 0 0';
 134         }
 135
 136         maxspd_mod = 1;
 137
 138         if(cvar("g_runematch"))
 139         {
 140                 if(self.runes & RUNE_SPEED)
 141                 {
 142                         if(self.runes & CURSE_SLOW)
 143                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
 144                         else
 145                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
 146                 }
 147                 else if(self.runes & CURSE_SLOW)
 148                 {
 149                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
 150                 }
 151         }
 152
 153         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 154         {
 155                 maxspd_mod = cvar("g_balance_rune_speed_moverate");
 156         }
 157
 158         swampspd_mod = 1;
 159         if(self.in_swamp) {
 160                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
 161         }
 162
 163         if(self.flags & FL_NOTARGET)
 164                 maxspd_mod = cvar("sv_spectator_speed_multiplier");
 165
 166         spd = sv_maxspeed * maxspd_mod * swampspd_mod;
 167
 168         if(self.speed != spd)
 169         {
 170                 self.speed = spd;
 171                 temps = ftos(spd);
 172                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
 173                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
 174                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
 175                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
 176
 177                 temps = ftos(sv_accelerate * maxspd_mod);
 178                 stuffcmd(self, strcat("cl_movement_accelerate ", temps, "\n"));
 179         }
 180
 181         // if dead, behave differently
 182         if (self.deadflag)
 183                 return;
 184
 185         if (!self.fixangle)
 186         {
 187                 self.angles_x = 0;
 188                 self.angles_y = self.v_angle_y;
 189                 self.angles_z = 0;
 190         }
 191
 192         if(self.classname == "player")
 193         {
 194                 if (self.button2)
 195                         PlayerJump ();
 196                 else
 197                         self.flags = self.flags | FL_JUMPRELEASED;
 198
 199                 if (self.waterlevel == 2)
 200                         CheckWaterJump ();
 201         }
 202
 203         if (self.flags & FL_WATERJUMP )
 204         {
 205                 self.velocity_x = self.movedir_x;
 206                 self.velocity_y = self.movedir_y;
 207                 if (time > self.teleport_time || self.waterlevel == 0)
 208                 {
 209                         self.flags = self.flags - (self.flags & FL_WATERJUMP);
 210                         self.teleport_time = 0;
 211                 }
 212         }
 213         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 214         {
 215                 // noclipping or flying
 216                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 217
 218                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 219                 makevectors(self.v_angle);
 220                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 221                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 222                 // acceleration
 223                 wishdir = normalize(wishvel);
 224                 wishspeed = vlen(wishvel);
 225                 if (wishspeed > sv_maxspeed*maxspd_mod)
 226                         wishspeed = sv_maxspeed*maxspd_mod;
 227                 if (time >= self.teleport_time)
 228                 {
 229                         f = wishspeed - (self.velocity * wishdir);
 230                         if (f > 0)
 231                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 232                 }
 233         }
 234         else if (self.waterlevel >= 2)
 235         {
 236                 // swimming
 237                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 238
 239                 makevectors(self.v_angle);
 240                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 241                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 242                 if (wishvel == '0 0 0')
 243                         wishvel = '0 0 -60'; // drift towards bottom
 244
 245                 wishdir = normalize(wishvel);
 246                 wishspeed = vlen(wishvel);
 247                 if (wishspeed > sv_maxspeed*maxspd_mod)
 248                         wishspeed = sv_maxspeed*maxspd_mod;
 249                 wishspeed = wishspeed * 0.7;
 250
 251                 // water friction
 252                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 253
 254                 // water acceleration
 255                 f = wishspeed - (self.velocity * wishdir);
 256                 if (f > 0)
 257                         self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 258         }
 259         else if (time < self.ladder_time)
 260         {
 261                 // on a func_ladder or swimming in func_water
 262                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 263
 264                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 265                 makevectors(self.v_angle);
 266                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 267                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 268                 if (self.gravity)
 269                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 270                 else
 271                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 272                 if (self.ladder_entity.classname == "func_water")
 273                 {
 274                         f = vlen(wishvel);
 275                         if (f > self.ladder_entity.speed)
 276                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 277
 278                         self.watertype = self.ladder_entity.skin;
 279                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 280                         if ((self.origin_z + self.view_ofs_z) < f)
 281                                 self.waterlevel = 3;
 282                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 283                                 self.waterlevel = 2;
 284                         else if ((self.origin_z + self.mins_z + 1) < f)
 285                                 self.waterlevel = 1;
 286                         else
 287                         {
 288                                 self.waterlevel = 0;
 289                                 self.watertype = CONTENT_EMPTY;
 290                         }
 291                 }
 292                 // acceleration
 293                 wishdir = normalize(wishvel);
 294                 wishspeed = vlen(wishvel);
 295                 if (wishspeed > sv_maxspeed)
 296                         wishspeed = sv_maxspeed;
 297                 if (time >= self.teleport_time)
 298                 {
 299                         f = wishspeed - (self.velocity * wishdir);
 300                         if (f > 0)
 301                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 302                 }
 303         }
 304         else if (self.flags & FL_ONGROUND)
 305         {
 306                 // walking
 307                 makevectors(self.v_angle_y * '0 1 0');
 308                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 309
 310                 if(!(self.lastflags & FL_ONGROUND))
 311                 {
 312                         if(cvar("speedmeter"))
 313                                 dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 314                         if(self.lastground < time - 0.3)
 315                                 self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 316                         if(self.jumppadcount > 1)
 317                                 dprint(strcat(ftos(self.jumppadcount), "x jumppad combo\n"));
 318                         self.jumppadcount = 0;
 319                 }
 320
 321                 if (self.velocity_x || self.velocity_y)
 322                 if (!(self.flags & FL_JUMPRELEASED) || !self.button2)
 323                 {
 324                         v = self.velocity;
 325                         v_z = 0;
 326                         f = vlen(v);
 327                         if (f < sv_stopspeed)
 328                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 329                         else
 330                                 f = 1 - frametime * sv_friction;
 331                         if (f > 0)
 332                                 self.velocity = self.velocity * f;
 333                         else
 334                                 self.velocity = '0 0 0';
 335                 }
 336                 // acceleration
 337                 wishdir = normalize(wishvel);
 338                 wishspeed = vlen(wishvel);
 339                 if (wishspeed > sv_maxspeed*maxspd_mod)
 340                         wishspeed = sv_maxspeed*maxspd_mod;
 341                 if (self.crouch)
 342                         wishspeed = wishspeed * 0.5;
 343                 if (time >= self.teleport_time)
 344                 {
 345                         f = wishspeed - (self.velocity * wishdir);
 346                         if (f > 0)
 347                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 348                 }
 349         }
 350         else
 351         {
 352                 if(maxspd_mod < 1)
 353                 {
 354                         maxairspd = sv_maxairspeed*maxspd_mod;
 355                         airaccel = sv_airaccelerate*maxspd_mod;
 356                 }
 357                 else
 358                 {
 359                         maxairspd = sv_maxairspeed;
 360                         airaccel = sv_airaccelerate;
 361                 }
 362                 // airborn
 363                 makevectors(self.v_angle_y * '0 1 0');
 364                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 365                 // acceleration
 366                 wishdir = normalize(wishvel);
 367                 wishspeed = vlen(wishvel);
 368                 if (wishspeed > maxairspd)
 369                         wishspeed = maxairspd;
 370                 if (self.crouch)
 371                         wishspeed = wishspeed * 0.5;
 372                 if (time >= self.teleport_time)
 373                 {
 374                         // NOTE: this does the same as the commented out old code if:
 375                         //   sv_airaccel_qw 0
 376                         //   sv_airaccel_sideways_friction 0
 377
 378                         float vel_straight;
 379                         float vel_z;
 380                         vector vel_perpend;
 381                         vel_straight = self.velocity * wishdir;
 382                         vel_z = self.velocity_z;
 383                         vel_perpend = self.velocity - vel_straight * wishdir - vel_z * '0 0 1';
 384
 385                         f = wishspeed - vel_straight;
 386                         if(f > 0)
 387                                 vel_straight = vel_straight + min(f, airaccel * frametime * wishspeed) * sv_airaccel_qw;
 388                         if(wishspeed > 0)
 389                                 vel_straight = vel_straight + min(wishspeed, airaccel * frametime * wishspeed) * (1 - sv_airaccel_qw);
 390
 391                         // anti-sideways friction to fix QW-style bunnyhopping
 392                         vel_perpend = vel_perpend * (1 - frametime * (wishspeed / maxairspd) * sv_airaccel_sideways_friction);
 393
 394                         self.velocity = vel_straight * wishdir + vel_z * '0 0 1' + vel_perpend;
 395
 396                         /*
 397                         f = wishspeed;// - (self.velocity * wishdir);
 398                         if (f > 0)
 399                                 self.velocity = self.velocity + wishdir * min(f, airaccel * frametime * wishspeed);
 400                         */
 401                 }
 402         }
 403
 404         if(self.flags & FL_ONGROUND)
 405                 self.lastground = time;
 406
 407         self.lastflags = self.flags;
 408 };