data/qcsrc/server/cl_client.qc

   1 .float spectatee_status;
   2 .float zoomstate;
   3 .float bloodloss_timer;
   4
   5 .entity clientdata;
   6 float ClientData_Send(entity to, float sf)
   7 {
   8         if(to != self.owner)
   9         {
  10                 error("wtf");
  11                 return FALSE;
  12         }
  13
  14         entity e;
  15
  16         e = to;
  17         if(to.classname == "spectator")
  18                 e = to.enemy;
  19
  20         sf = 0;
  21
  22         if(e.race_completed)
  23                 sf |= 1; // forced scoreboard
  24         if(to.spectatee_status)
  25                 sf |= 2; // spectator ent number follows
  26         if(e.zoomstate)
  27                 sf |= 4; // zoomed
  28         if(e.porto_v_angle_held)
  29                 sf |= 8; // angles held
  30
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  32         WriteByte(MSG_ENTITY, sf);
  33
  34         if(sf & 2)
  35                 WriteByte(MSG_ENTITY, to.spectatee_status);
  36
  37         if(sf & 8)
  38         {
  39                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  40                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  41         }
  42
  43         return TRUE;
  44 }
  45
  46 void ClientData_Attach()
  47 {
  48         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  49         self.clientdata.drawonlytoclient = self;
  50         self.clientdata.owner = self;
  51 }
  52
  53 void ClientData_Detach()
  54 {
  55         remove(self.clientdata);
  56         self.clientdata = world;
  57 }
  58
  59 void ClientData_Touch(entity e)
  60 {
  61         e.clientdata.SendFlags = 1;
  62
  63         // make it spectatable
  64         entity e2;
  65         FOR_EACH_REALCLIENT(e2)
  66         {
  67                 if(e2 != e)
  68                         if(e2.classname == "spectator")
  69                                 if(e2.enemy == e)
  70                                         e2.clientdata.SendFlags = 1;
  71         }
  72 }
  73
  74
  75 #define SPAWNPOINT_SCORE frags
  76
  77 .string netname_previous;
  78
  79 void spawnfunc_info_player_survivor (void)
  80 {
  81         spawnfunc_info_player_deathmatch();
  82 }
  83
  84 void spawnfunc_info_player_start (void)
  85 {
  86         spawnfunc_info_player_deathmatch();
  87 }
  88
  89 void spawnfunc_info_player_deathmatch (void)
  90 {
  91         self.classname = "info_player_deathmatch";
  92         relocate_spawnpoint();
  93 }
  94
  95 void spawnpoint_use()
  96 {
  97         if(teams_matter)
  98         if(have_team_spawns)
  99         {
 100                 self.team = activator.team;
 101                 some_spawn_has_been_used = 1;
 102         }
 103 };
 104
 105 // Returns:
 106 //   -1 if a spawn can't be used
 107 //   otherwise, a weight of the spawnpoint
 108 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
 109 {
 110         float shortest, thisdist;
 111         entity player;
 112
 113         // filter out spots for the wrong team
 114         if(teamcheck)
 115         if(spot.team != teamcheck)
 116                 return -1;
 117
 118         if(race_spawns)
 119                 if(spot.target == "")
 120                         return -1;
 121
 122         // filter out spots for assault
 123         if(spot.target != "") {
 124                 local entity ent;
 125                 float good, found;
 126                 ent = find(world, targetname, spot.target);
 127                 while(ent) {
 128                         found = 1;
 129                         if(ent.classname == "target_objective")
 130                         {
 131                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 132                                         return -1;
 133                                 good = 1;
 134                         }
 135                         else if(ent.classname == "trigger_race_checkpoint")
 136                         {
 137                                 if(self.classname == "player") // spectators may spawn everywhere
 138                                 {
 139                                         if(g_race_qualifying)
 140                                         {
 141                                                 // spawn at first
 142                                                 if(ent.race_checkpoint != 0)
 143                                                         return -1;
 144                                                 if(spot.race_place != race_lowest_place_spawn)
 145                                                         return -1;
 146                                         }
 147                                         else
 148                                         {
 149                                                 if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
 150                                                         return -1;
 151                                                 float pl;
 152                                                 pl = self.race_place;
 153                                                 if(pl > race_highest_place_spawn)
 154                                                         pl = 0;
 155                                                 if(spot.race_place != pl)
 156                                                         return -1;
 157                                         }
 158                                 }
 159                                 good = 1;
 160                         }
 161                         else
 162                         {
 163                         }
 164                         ent = find(ent, targetname, spot.target);
 165                 }
 166
 167                 if(found && !good)
 168                         return -1;
 169         }
 170
 171         player = playerlist;
 172         shortest = vlen(world.maxs - world.mins);
 173         for(player = playerlist; player; player = player.chain)
 174                 if (player != self)
 175                 {
 176                         thisdist = vlen(player.origin - spot.origin);
 177                         if (thisdist < shortest)
 178                                 shortest = thisdist;
 179                 }
 180         return shortest;
 181 }
 182
 183 float spawn_allbad;
 184 float spawn_allgood;
 185 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 186 {
 187         local entity spot, spotlist, spotlistend;
 188         spawn_allgood = TRUE;
 189         spawn_allbad = TRUE;
 190
 191         spotlist = world;
 192         spotlistend = world;
 193
 194         for(spot = firstspot; spot; spot = spot.chain)
 195         {
 196                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 197
 198                 if(cvar("spawn_debugview"))
 199                 {
 200                         setmodel(spot, "models/runematch/rune.mdl");
 201                         if(spot.SPAWNPOINT_SCORE < mindist)
 202                         {
 203                                 spot.colormod = '1 0 0';
 204                                 spot.scale = 1;
 205                         }
 206                         else
 207                         {
 208                                 spot.colormod = '0 1 0';
 209                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 210                         }
 211                 }
 212
 213                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 214                 {
 215                         if(spot.SPAWNPOINT_SCORE < mindist)
 216                         {
 217                                 // too short distance
 218                                 spawn_allgood = FALSE;
 219                         }
 220                         else
 221                         {
 222                                 // perfect
 223                                 spawn_allbad = FALSE;
 224
 225                                 if(spotlistend)
 226                                         spotlistend.chain = spot;
 227                                 spotlistend = spot;
 228                                 if(!spotlist)
 229                                         spotlist = spot;
 230
 231                                 /*
 232                                 if(teamcheck)
 233                                 if(spot.team != teamcheck)
 234                                         error("invalid spawn added");
 235
 236                                 print("added ", etos(spot), "\n");
 237                                 */
 238                         }
 239                 }
 240         }
 241         if(spotlistend)
 242                 spotlistend.chain = world;
 243
 244         /*
 245                 entity e;
 246                 if(teamcheck)
 247                         for(e = spotlist; e; e = e.chain)
 248                         {
 249                                 print("seen ", etos(e), "\n");
 250                                 if(e.team != teamcheck)
 251                                         error("invalid spawn found");
 252                         }
 253         */
 254
 255         return spotlist;
 256 }
 257
 258 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 259 {
 260         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 261         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 262         local entity spot;
 263
 264         RandomSelection_Init();
 265         for(spot = firstspot; spot; spot = spot.chain)
 266                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 267
 268         return RandomSelection_chosen_ent;
 269 }
 270
 271 /*
 272 =============
 273 SelectSpawnPoint
 274
 275 Finds a point to respawn
 276 =============
 277 */
 278 entity SelectSpawnPoint (float anypoint)
 279 {
 280         local float teamcheck;
 281         local entity firstspot_new;
 282         local entity spot, firstspot, playerlist;
 283
 284         spot = find (world, classname, "testplayerstart");
 285         if (spot)
 286                 return spot;
 287
 288         teamcheck = 0;
 289
 290         if(!anypoint && have_team_spawns)
 291                 teamcheck = self.team;
 292
 293         // get the list of players
 294         playerlist = findchain(classname, "player");
 295         // get the entire list of spots
 296         firstspot = findchain(classname, "info_player_deathmatch");
 297         // filter out the bad ones
 298         // (note this returns the original list if none survived)
 299         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 300         if(!firstspot_new)
 301                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 302         firstspot = firstspot_new;
 303
 304         // there is 50/50 chance of choosing a random spot or the furthest spot
 305         // (this means that roughly every other spawn will be furthest, so you
 306         // usually won't get fragged at spawn twice in a row)
 307         if (arena_roundbased)
 308         {
 309                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 310                 if(firstspot_new)
 311                         firstspot = firstspot_new;
 312                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 313         }
 314         else if (random() > cvar("g_spawn_furthest"))
 315                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 316         else
 317                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 318
 319         if(cvar("spawn_debugview"))
 320         {
 321                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 322
 323                 entity e;
 324                 if(teamcheck)
 325                         for(e = firstspot; e; e = e.chain)
 326                                 if(e.team != teamcheck)
 327                                         error("invalid spawn found");
 328         }
 329
 330         if (!spot)
 331         {
 332                 if(cvar("spawn_debug"))
 333                         GotoNextMap();
 334                 else
 335                 {
 336                         if(some_spawn_has_been_used)
 337                                 return world; // team can't spawn any more, because of actions of other team
 338                         else
 339                                 error("Cannot find a spawn point - please fix the map!");
 340                 }
 341         }
 342
 343         return spot;
 344 }
 345
 346 /*
 347 =============
 348 CheckPlayerModel
 349
 350 Checks if the argument string can be a valid playermodel.
 351 Returns a valid one in doubt.
 352 =============
 353 */
 354 string FallbackPlayerModel = "models/player/marine.zym";
 355 string CheckPlayerModel(string plyermodel) {
 356         if(strlen(plyermodel) < 4)
 357                 return FallbackPlayerModel;
 358         if( substring(plyermodel,0,14) != "models/player/")
 359                 return FallbackPlayerModel;
 360         else if(cvar("sv_servermodelsonly"))
 361         {
 362                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 363                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 364                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 365                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 366                         return FallbackPlayerModel;
 367                 if(plyermodel != strtolower(plyermodel))
 368                         return FallbackPlayerModel;
 369                 if(!fexists(plyermodel))
 370                         return FallbackPlayerModel;
 371         }
 372         return plyermodel;
 373 }
 374
 375 /*
 376 =============
 377 Client_customizeentityforclient
 378
 379 LOD reduction
 380 =============
 381 */
 382 float Client_customizeentityforclient()
 383 {
 384 #ifdef ALLOW_VARIABLE_LOD
 385         // self: me
 386         // other: the player viewing me
 387         float distance;
 388         float f;
 389
 390         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 391                 return TRUE;
 392
 393         if(other.cvar_cl_playerdetailreduction <= 0)
 394         {
 395                 if(other.cvar_cl_playerdetailreduction <= -2)
 396                         self.modelindex = self.modelindex_lod2;
 397                 else if(other.cvar_cl_playerdetailreduction <= -1)
 398                         self.modelindex = self.modelindex_lod1;
 399                 else
 400                         self.modelindex = self.modelindex_lod0;
 401         }
 402         else
 403         {
 404                 distance = vlen(self.origin - other.origin);
 405                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 406                 if(f > 10000)
 407                         self.modelindex = self.modelindex_lod2;
 408                 else if(f > 5000)
 409                         self.modelindex = self.modelindex_lod1;
 410                 else
 411                         self.modelindex = self.modelindex_lod0;
 412         }
 413 #endif
 414
 415         return TRUE;
 416 }
 417
 418 void UpdatePlayerSounds();
 419 void setmodel_lod(entity e, string modelname)
 420 {
 421 #ifdef ALLOW_VARIABLE_LOD
 422         string s;
 423
 424         // FIXME: this only supports 3-letter extensions
 425         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 426         if(fexists(s))
 427         {
 428                 precache_model(s);
 429                 setmodel(e, s); // players have high precision
 430                 self.modelindex_lod1 = self.modelindex;
 431         }
 432         else
 433                 self.modelindex_lod1 = -1;
 434
 435         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 436         if(fexists(s))
 437         {
 438                 precache_model(s);
 439                 setmodel(e, s); // players have high precision
 440                 self.modelindex_lod2 = self.modelindex;
 441         }
 442         else
 443                 self.modelindex_lod2 = -1;
 444
 445         precache_model(modelname);
 446         setmodel(e, modelname); // players have high precision
 447         self.modelindex_lod0 = self.modelindex;
 448
 449         if(self.modelindex_lod1 < 0)
 450                 self.modelindex_lod1 = self.modelindex;
 451
 452         if(self.modelindex_lod2 < 0)
 453                 self.modelindex_lod2 = self.modelindex;
 454 #else
 455         precache_model(modelname);
 456         setmodel(e, modelname); // players have high precision
 457 #endif
 458         player_setupanimsformodel();
 459         UpdatePlayerSounds();
 460 }
 461
 462 /*
 463 =============
 464 PutObserverInServer
 465
 466 putting a client as observer in the server
 467 =============
 468 */
 469 void PutObserverInServer (void)
 470 {
 471         entity  spot;
 472
 473         race_PreSpawnObserver();
 474
 475         spot = SelectSpawnPoint (TRUE);
 476         if(!spot)
 477                 error("No spawnpoints for observers?!?\n");
 478         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 479
 480         if(clienttype(self) == CLIENTTYPE_REAL)
 481         {
 482                 msg_entity = self;
 483                 WriteByte(MSG_ONE, SVC_SETVIEW);
 484                 WriteEntity(MSG_ONE, self);
 485         }
 486
 487         DropAllRunes(self);
 488         kh_Key_DropAll(self, TRUE);
 489
 490         Portal_ClearAll(self);
 491
 492         if(self.flagcarried)
 493                 DropFlag(self.flagcarried, world, world);
 494
 495         WaypointSprite_PlayerDead();
 496
 497         if(self.killcount != -666)
 498         {
 499                 if(g_lms)
 500                 {
 501                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 502                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 503                         else
 504                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 505                 }
 506                 else
 507                         bprint ("^4", self.netname, "^4 is spectating now\n");
 508         }
 509
 510         PlayerScore_Clear(self); // clear scores when needed
 511
 512         self.spectatortime = time;
 513
 514         self.classname = "observer";
 515         self.iscreature = FALSE;
 516         self.health = -666;
 517         self.takedamage = DAMAGE_NO;
 518         self.solid = SOLID_NOT;
 519         self.movetype = MOVETYPE_NOCLIP;
 520         self.flags = FL_CLIENT | FL_NOTARGET;
 521         self.armorvalue = 666;
 522         self.effects = 0;
 523         self.armorvalue = cvar("g_balance_armor_start");
 524         self.pauserotarmor_finished = 0;
 525         self.pauserothealth_finished = 0;
 526         self.pauseregen_finished = 0;
 527         self.damageforcescale = 0;
 528         self.death_time = 0;
 529         self.dead_frame = 0;
 530         self.alpha = 0;
 531         self.scale = 0;
 532         self.fade_time = 0;
 533         self.pain_frame = 0;
 534         self.pain_finished = 0;
 535         self.strength_finished = 0;
 536         self.invincible_finished = 0;
 537         self.pushltime = 0;
 538         self.think = SUB_Null;
 539         self.nextthink = 0;
 540         self.hook_time = 0;
 541         self.runes = 0;
 542         self.deadflag = DEAD_NO;
 543         self.angles = spot.angles;
 544         self.angles_z = 0;
 545         self.fixangle = TRUE;
 546         self.crouch = FALSE;
 547
 548         self.view_ofs = PL_VIEW_OFS;
 549         setorigin (self, spot.origin);
 550         setsize (self, '0 0 0', '0 0 0');
 551         self.oldorigin = self.origin;
 552         self.items = 0;
 553         self.weapons = 0;
 554         self.model = "";
 555         self.modelindex = 0;
 556         self.weapon = 0;
 557         self.weaponmodel = "";
 558         self.weaponentity = world;
 559         self.killcount = -666;
 560         self.velocity = '0 0 0';
 561         self.avelocity = '0 0 0';
 562         self.punchangle = '0 0 0';
 563         self.punchvector = '0 0 0';
 564         self.oldvelocity = self.velocity;
 565         self.customizeentityforclient = Client_customizeentityforclient;
 566
 567         if(g_arena)
 568         {
 569                 if(self.version_mismatch)
 570                 {
 571                         Spawnqueue_Unmark(self);
 572                         Spawnqueue_Remove(self);
 573                 }
 574                 else
 575                 {
 576                         Spawnqueue_Insert(self);
 577                 }
 578         }
 579         else if(g_lms)
 580         {
 581                 // Only if the player cannot play at all
 582                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 583                         self.frags = FRAGS_SPECTATOR;
 584                 else
 585                         self.frags = FRAGS_LMS_LOSER;
 586         }
 587         else
 588                 self.frags = FRAGS_SPECTATOR;
 589 }
 590
 591 float RestrictSkin(float s)
 592 {
 593         if(!teams_matter)
 594                 return s;
 595         if(s == 6)
 596                 return 6;
 597         return mod(s, 3);
 598 }
 599
 600 void FixPlayermodel()
 601 {
 602         local string defaultmodel;
 603         local float defaultskin;
 604         local vector m1, m2;
 605
 606         defaultmodel = "";
 607
 608         if(cvar("sv_defaultcharacter") == 1) {
 609                 defaultskin = 0;
 610
 611                 if(teams_matter)
 612                 {
 613                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 614                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 615                 }
 616
 617                 if(defaultmodel == "")
 618                 {
 619                         defaultmodel = cvar_string("sv_defaultplayermodel");
 620                         defaultskin = cvar("sv_defaultplayerskin");
 621                 }
 622         }
 623
 624         if(self.modelindex == 0)
 625         {
 626                 if(self.model != "")
 627                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 628                 self.model = ""; // force the != checks to return true
 629         }
 630
 631         if(defaultmodel != "")
 632         {
 633                 if (defaultmodel != self.model)
 634                 {
 635                         m1 = self.mins;
 636                         m2 = self.maxs;
 637                         setmodel_lod (self, defaultmodel);
 638                         setsize (self, m1, m2);
 639                 }
 640
 641                 self.skin = defaultskin;
 642         } else {
 643                 if (self.playermodel != self.model)
 644                 {
 645                         self.playermodel = CheckPlayerModel(self.playermodel);
 646                         m1 = self.mins;
 647                         m2 = self.maxs;
 648                         setmodel_lod (self, self.playermodel);
 649                         setsize (self, m1, m2);
 650                 }
 651
 652                 self.skin = RestrictSkin(stof(self.playerskin));
 653         }
 654
 655         if(!teams_matter)
 656                 if(strlen(cvar_string("sv_defaultplayercolors")))
 657                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 658                                 setcolor(self, cvar("sv_defaultplayercolors"));
 659 }
 660
 661 void PlayerTouchExplode(entity p1, entity p2)
 662 {
 663         vector org;
 664         org = (p1.origin + p2.origin) * 0.5;
 665         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 666
 667         te_explosion(org);
 668
 669         entity e;
 670         e = spawn();
 671         setorigin(e, org);
 672         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 673         remove(e);
 674 }
 675
 676 /*
 677 =============
 678 PutClientInServer
 679
 680 Called when a client spawns in the server
 681 =============
 682 */
 683 //void() ctf_playerchanged;
 684 void PutClientInServer (void)
 685 {
 686         if(clienttype(self) == CLIENTTYPE_BOT)
 687         {
 688                 self.classname = "player";
 689         }
 690         else if(clienttype(self) == CLIENTTYPE_REAL)
 691         {
 692                 msg_entity = self;
 693                 WriteByte(MSG_ONE, SVC_SETVIEW);
 694                 WriteEntity(MSG_ONE, self);
 695         }
 696
 697         // player is dead and becomes observer
 698         // FIXME fix LMS scoring for new system
 699         if(g_lms)
 700         {
 701                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 702                         self.classname = "observer";
 703         }
 704
 705         if(g_arena)
 706         if(!self.spawned)
 707                 self.classname = "observer";
 708
 709         if(self.classname == "player") {
 710                 entity spot, oldself;
 711
 712                 race_PreSpawn();
 713
 714                 spot = SelectSpawnPoint (FALSE);
 715                 if(!spot)
 716                 {
 717                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 718                         return; // spawn failed
 719                 }
 720
 721                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 722                 self.campingrifle_bulletcounter = 0;
 723
 724                 self.classname = "player";
 725                 self.iscreature = TRUE;
 726                 self.movetype = MOVETYPE_WALK;
 727                 self.solid = SOLID_SLIDEBOX;
 728                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 729                 self.frags = FRAGS_PLAYER;
 730                 if(independent_players)
 731                         MAKE_INDEPENDENT_PLAYER(self);
 732                 self.flags = FL_CLIENT;
 733                 self.takedamage = DAMAGE_AIM;
 734                 if(g_minstagib)
 735                         self.effects = EF_FULLBRIGHT;
 736                 else
 737                         self.effects = 0;
 738                 self.air_finished = time + 12;
 739                 self.dmg = 2;
 740
 741                 if(inWarmupStage)
 742                 {
 743                         self.ammo_shells = warmup_start_ammo_shells;
 744                         self.ammo_nails = warmup_start_ammo_nails;
 745                         self.ammo_rockets = warmup_start_ammo_rockets;
 746                         self.ammo_cells = warmup_start_ammo_cells;
 747                         self.health = warmup_start_health;
 748                         self.armorvalue = warmup_start_armorvalue;
 749                         self.weapons = warmup_start_weapons;
 750                 }
 751                 else
 752                 {
 753                         self.ammo_shells = start_ammo_shells;
 754                         self.ammo_nails = start_ammo_nails;
 755                         self.ammo_rockets = start_ammo_rockets;
 756                         self.ammo_cells = start_ammo_cells;
 757                         self.health = start_health;
 758                         self.armorvalue = start_armorvalue;
 759                         self.weapons = start_weapons;
 760                 }
 761                 self.items = start_items;
 762                 self.switchweapon = w_getbestweapon(self);
 763                 self.cnt = self.switchweapon;
 764                 self.weapon = 0;
 765                 self.jump_interval = time;
 766
 767                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 768                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 769                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 770                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 771                 //extend the pause of rotting if client was reset at the beginning of the countdown
 772                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 773                         self.spawnshieldtime += game_starttime - time;
 774                         self.pauserotarmor_finished += game_starttime - time;
 775                         self.pauserothealth_finished += game_starttime - time;
 776                         self.pauseregen_finished += game_starttime - time;
 777                 }
 778                 self.damageforcescale = 2;
 779                 self.death_time = 0;
 780                 self.dead_frame = 0;
 781                 self.alpha = 0;
 782                 self.scale = 0;
 783                 self.fade_time = 0;
 784                 self.pain_frame = 0;
 785                 self.pain_finished = 0;
 786                 self.strength_finished = 0;
 787                 self.invincible_finished = 0;
 788                 self.pushltime = 0;
 789                 //self.speed_finished = 0;
 790                 //self.slowmo_finished = 0;
 791                 // players have no think function
 792                 self.think = SUB_Null;
 793                 self.nextthink = 0;
 794                 self.hook_time = 0;
 795                 self.dmg_team = 0;
 796
 797                 self.runes = 0;
 798
 799                 self.deadflag = DEAD_NO;
 800
 801                 self.angles = spot.angles;
 802
 803                 self.angles_z = 0; // never spawn tilted even if the spot says to
 804                 self.fixangle = TRUE; // turn this way immediately
 805                 self.velocity = '0 0 0';
 806                 self.avelocity = '0 0 0';
 807                 self.punchangle = '0 0 0';
 808                 self.punchvector = '0 0 0';
 809                 self.oldvelocity = self.velocity;
 810
 811                 msg_entity = self;
 812                 WRITESPECTATABLE_MSG_ONE({
 813                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 814                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 815                 });
 816
 817                 self.customizeentityforclient = Client_customizeentityforclient;
 818
 819                 self.model = "";
 820                 FixPlayermodel();
 821
 822                 self.crouch = FALSE;
 823                 self.view_ofs = PL_VIEW_OFS;
 824                 setsize (self, PL_MIN, PL_MAX);
 825                 self.spawnorigin = spot.origin;
 826                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 827                 // don't reset back to last position, even if new position is stuck in solid
 828                 self.oldorigin = self.origin;
 829
 830                 if(g_arena)
 831                 {
 832                         Spawnqueue_Remove(self);
 833                         Spawnqueue_Mark(self);
 834                 }
 835
 836                 self.event_damage = PlayerDamage;
 837
 838                 self.bot_attack = TRUE;
 839
 840                 self.statdraintime = time + 5;
 841                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 842
 843                 if(self.killcount == -666) {
 844                         PlayerScore_Clear(self);
 845                         self.killcount = 0;
 846                 }
 847
 848                 self.cnt = WEP_LASER;
 849                 self.nixnex_lastchange_id = -1;
 850
 851                 CL_SpawnWeaponentity();
 852                 self.alpha = default_player_alpha;
 853                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 854                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 855
 856                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 857                 self.lms_traveled_distance = 0;
 858                 self.speedrunning = FALSE;
 859
 860                 race_PostSpawn(spot);
 861
 862                 if(cvar("spawn_debug"))
 863                 {
 864                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 865                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 866                 }
 867
 868                 //stuffcmd(self, "chase_active 0");
 869                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 870
 871                 if (cvar("g_spawnsound"))
 872                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 873
 874                 if(g_assault) {
 875                         if(self.team == assault_attacker_team)
 876                                 centerprint(self, "You are attacking!");
 877                         else
 878                                 centerprint(self, "You are defending!");
 879                 }
 880
 881                 target_voicescript_clear(self);
 882
 883                 oldself = self;
 884                 self = spot;
 885                         activator = oldself;
 886                                 SUB_UseTargets();
 887                         activator = world;
 888                 self = oldself;
 889
 890         } else if(self.classname == "observer") {
 891                 PutObserverInServer ();
 892         }
 893
 894         //if(g_ctf)
 895         //      ctf_playerchanged();
 896 }
 897
 898 float ClientInit_SendEntity(entity to, float sf)
 899 {
 900         float i;
 901         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 902         WriteShort(MSG_ENTITY, CSQC_REVISION);
 903         for(i = 1; i <= 24; ++i)
 904                 WriteByte(MSG_ENTITY, (get_weaponinfo(i)).impulse + 1);
 905         WriteCoord(MSG_ENTITY, hook_shotorigin_x);
 906         WriteCoord(MSG_ENTITY, hook_shotorigin_y);
 907         WriteCoord(MSG_ENTITY, hook_shotorigin_z);
 908
 909         if(sv_foginterval && world.fog != "")
 910                 WriteString(MSG_ENTITY, world.fog);
 911         else
 912                 WriteString(MSG_ENTITY, "");
 913
 914         return TRUE;
 915 }
 916
 917 void ClientInit_Spawn()
 918 {
 919         Net_LinkEntity(spawn(), FALSE, 0, ClientInit_SendEntity);
 920 }
 921
 922 /*
 923 =============
 924 SetNewParms
 925 =============
 926 */
 927 void SetNewParms (void)
 928 {
 929         // initialize parms for a new player
 930         parm1 = -(86400 * 366);
 931 }
 932
 933 /*
 934 =============
 935 SetChangeParms
 936 =============
 937 */
 938 void SetChangeParms (void)
 939 {
 940         // save parms for level change
 941         parm1 = self.parm_idlesince - time;
 942 }
 943
 944 /*
 945 =============
 946 DecodeLevelParms
 947 =============
 948 */
 949 void DecodeLevelParms (void)
 950 {
 951         // load parms
 952         self.parm_idlesince = parm1;
 953         if(self.parm_idlesince == -(86400 * 366))
 954                 self.parm_idlesince = time;
 955
 956         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 957         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 958 }
 959
 960 /*
 961 =============
 962 ClientKill
 963
 964 Called when a client types 'kill' in the console
 965 =============
 966 */
 967
 968 void ClientKill_Now_TeamChange()
 969 {
 970         if(self.killindicator_teamchange == -1)
 971         {
 972                 self.team = -1;
 973                 JoinBestTeam( self, FALSE, FALSE );
 974         }
 975         else
 976         {
 977                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 978         }
 979 }
 980
 981 void ClientKill_Now()
 982 {
 983         if(self.killindicator_teamchange)
 984                 ClientKill_Now_TeamChange();
 985
 986         // in any case:
 987         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 988
 989         if(self.killindicator)
 990         {
 991                 dprint("Cleaned up after a leaked kill indicator.\n");
 992                 remove(self.killindicator);
 993                 self.killindicator = world;
 994         }
 995 }
 996 void KillIndicator_Think()
 997 {
 998         if (!self.owner.modelindex)
 999         {
1000                 self.owner.killindicator = world;
1001                 remove(self);
1002                 return;
1003         }
1004
1005         if(self.cnt <= 0)
1006         {
1007                 self = self.owner;
1008                 ClientKill_Now(); // no oldself needed
1009                 return;
1010         }
1011         else
1012         {
1013                 if(self.cnt <= 10)
1014                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1015                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1016                 {
1017                         if(self.cnt <= 10)
1018                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".wav"));
1019                         if(self.owner.killindicator_teamchange)
1020                         {
1021                                 if(self.owner.killindicator_teamchange == -1)
1022                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1023                                 else
1024                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1025                         }
1026                         else
1027                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1028                 }
1029                 self.nextthink = time + 1;
1030                 self.cnt -= 1;
1031         }
1032 }
1033
1034 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1035 {
1036         float killtime;
1037         entity e;
1038         killtime = cvar("g_balance_kill_delay");
1039
1040         self.killindicator_teamchange = targetteam;
1041
1042         if(!self.killindicator)
1043         {
1044                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1045                 {
1046                         ClientKill_Now();
1047                 }
1048                 else
1049                 {
1050                         self.killindicator = spawn();
1051                         self.killindicator.owner = self;
1052                         self.killindicator.scale = 0.5;
1053                         setattachment(self.killindicator, self, "");
1054                         setorigin(self.killindicator, '0 0 52');
1055                         self.killindicator.think = KillIndicator_Think;
1056                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1057                         self.killindicator.cnt = ceil(killtime);
1058                         self.killindicator.count = bound(0, ceil(killtime), 10);
1059                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1060
1061                         for(e = world; (e = find(e, classname, "body")) != world; )
1062                         {
1063                                 if(e.enemy != self)
1064                                         continue;
1065                                 e.killindicator = spawn();
1066                                 e.killindicator.owner = e;
1067                                 e.killindicator.scale = 0.5;
1068                                 setattachment(e.killindicator, e, "");
1069                                 setorigin(e.killindicator, '0 0 52');
1070                                 e.killindicator.think = KillIndicator_Think;
1071                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1072                                 e.killindicator.cnt = ceil(killtime);
1073                         }
1074                         self.lip = 0;
1075                 }
1076         }
1077         if(self.killindicator)
1078         {
1079                 if(targetteam)
1080                         self.killindicator.colormod = TeamColor(targetteam);
1081                 else
1082                         self.killindicator.colormod = '0 0 0';
1083         }
1084 }
1085
1086 void ClientKill (void)
1087 {
1088         ClientKill_TeamChange(0);
1089 }
1090
1091 void DoTeamChange(float destteam)
1092 {
1093         float t, c0;
1094         if(!teams_matter)
1095         {
1096                 if(destteam >= 0)
1097                         SetPlayerColors(self, destteam);
1098                 return;
1099         }
1100         if(self.classname == "player")
1101         if(destteam == -1)
1102         {
1103                 CheckAllowedTeams(self);
1104                 t = FindSmallestTeam(self, TRUE);
1105                 switch(self.team)
1106                 {
1107                         case COLOR_TEAM1: c0 = c1; break;
1108                         case COLOR_TEAM2: c0 = c2; break;
1109                         case COLOR_TEAM3: c0 = c3; break;
1110                         case COLOR_TEAM4: c0 = c4; break;
1111                         default:          c0 = 999;
1112                 }
1113                 switch(t)
1114                 {
1115                         case 1:
1116                                 if(c0 > c1)
1117                                         destteam = COLOR_TEAM1;
1118                                 break;
1119                         case 2:
1120                                 if(c0 > c2)
1121                                         destteam = COLOR_TEAM2;
1122                                 break;
1123                         case 3:
1124                                 if(c0 > c3)
1125                                         destteam = COLOR_TEAM3;
1126                                 break;
1127                         case 4:
1128                                 if(c0 > c4)
1129                                         destteam = COLOR_TEAM4;
1130                                 break;
1131                 }
1132                 if(destteam == -1)
1133                         return;
1134         }
1135         if(destteam == self.team && !self.killindicator)
1136                 return;
1137         ClientKill_TeamChange(destteam);
1138 }
1139
1140 void FixClientCvars(entity e)
1141 {
1142         // send prediction settings to the client
1143         stuffcmd(e, "\nin_bindmap 0 0\n");
1144         /*
1145          * we no longer need to stuff this. Remove this comment block if you feel
1146          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1147         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1148         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1149         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1150         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1151         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1152         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1153         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1154         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1155         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1156         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1157         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1158         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1159         stuffcmd(e, "cl_movement_edgefriction 1\n");
1160          */
1161 }
1162
1163 /*
1164 =============
1165 ClientConnect
1166
1167 Called when a client connects to the server
1168 =============
1169 */
1170 //void ctf_clientconnect();
1171 string ColoredTeamName(float t);
1172 void DecodeLevelParms (void);
1173 //void dom_player_join_team(entity pl);
1174 void ClientConnect (void)
1175 {
1176         local string s;
1177         float t;
1178
1179         if(self.flags & FL_CLIENT)
1180         {
1181                 print("Warning: ClientConnect, but already connected!\n");
1182                 return;
1183         }
1184
1185         if(Ban_MaybeEnforceBan(self))
1186                 return;
1187
1188         DecodeLevelParms();
1189
1190         self.classname = "player_joining";
1191
1192         self.flags = FL_CLIENT;
1193         self.version_nagtime = time + 10 + random() * 10;
1194
1195         if(player_count<0)
1196         {
1197                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1198                 player_count = 0;
1199         }
1200
1201         PlayerScore_Attach(self);
1202         ClientData_Attach();
1203
1204         bot_clientconnect();
1205
1206         race_PreSpawnObserver();
1207
1208         //if(g_domination)
1209         //      dom_player_join_team(self);
1210
1211         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1212
1213         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1214                 self.classname = "observer";
1215         } else {
1216                 if(teams_matter)
1217                 {
1218                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1219                         {
1220                                 self.classname = "player";
1221                                 campaign_bots_may_start = 1;
1222                         }
1223                         else
1224                         {
1225                                 self.classname = "observer"; // do it anyway
1226                         }
1227                 }
1228                 else
1229                 {
1230                         self.classname = "player";
1231                         campaign_bots_may_start = 1;
1232                 }
1233         }
1234
1235         self.playerid = (playerid_last = playerid_last + 1);
1236         if(cvar("sv_eventlog"))
1237         {
1238                 if(clienttype(self) == CLIENTTYPE_REAL)
1239                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", self.netaddress, ":", self.netname));
1240                 else
1241                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":bot:", self.netname));
1242                 s = strcat(":team:", ftos(self.playerid), ":");
1243                 s = strcat(s, ftos(self.team));
1244                 GameLogEcho(s);
1245         }
1246         self.netname_previous = strzone(self.netname);
1247
1248         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1249
1250         bprint ("^4",self.netname);
1251         bprint ("^4 connected");
1252
1253         if(g_domination || g_ctf)
1254         {
1255                 bprint(" and joined the ");
1256                 bprint(ColoredTeamName(self.team));
1257         }
1258
1259         bprint("\n");
1260
1261         self.welcomemessage_time = 0;
1262
1263         stuffcmd(self, strcat(clientstuff, "\n"));
1264         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1265         stuffcmd(self, "cl_particles_reloadeffects\n");
1266
1267         FixClientCvars(self);
1268
1269         // spawnfunc_waypoint sprites
1270         WaypointSprite_InitClient(self);
1271
1272         // Wazat's grappling hook
1273         SetGrappleHookBindings();
1274
1275         // get autoswitch state from player when he toggles it
1276         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1277
1278         // get version info from player
1279         stuffcmd(self, "cmd clientversion $gameversion\n");
1280
1281         // get other cvars from player
1282         GetCvars(0);
1283
1284         // set cvar for team scoreboard
1285         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1286
1287         // notify about available teams
1288         if(teams_matter)
1289         {
1290                 CheckAllowedTeams(self);
1291                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1292                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1293         }
1294         else
1295                 stuffcmd(self, "set _teams_available 0\n");
1296
1297         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1298
1299         if(g_arena)
1300         {
1301                 self.classname = "observer";
1302                 Spawnqueue_Insert(self);
1303         }
1304         /*else if(g_ctf)
1305         {
1306                 ctf_clientconnect();
1307         }*/
1308
1309         if(teams_matter)
1310                 attach_entcs();
1311
1312         bot_relinkplayerlist();
1313
1314         self.spectatortime = time;
1315         if(blockSpectators)
1316         {
1317                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1318         }
1319
1320         self.jointime = time;
1321         self.allowedTimeouts = cvar("sv_timeout_number");
1322
1323         if(clienttype(self) == CLIENTTYPE_REAL)
1324         {
1325                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1326
1327                 if(cvar("g_bugrigs"))
1328                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1329         }
1330
1331         if(g_lms)
1332         {
1333                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1334                 {
1335                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1336                         self.frags = FRAGS_SPECTATOR;
1337                 }
1338         }
1339
1340         if(!sv_foginterval && world.fog != "")
1341                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1342 }
1343
1344 /*
1345 =============
1346 ClientDisconnect
1347
1348 Called when a client disconnects from the server
1349 =============
1350 */
1351 .entity chatbubbleentity;
1352 .entity teambubbleentity;
1353 void ReadyCount();
1354 void ClientDisconnect (void)
1355 {
1356         if not(self.flags & FL_CLIENT)
1357         {
1358                 print("Warning: ClientDisconnect without ClientConnect\n");
1359                 return;
1360         }
1361
1362         bot_clientdisconnect();
1363
1364         if(teams_matter)
1365                 detach_entcs();
1366
1367         if(cvar("sv_eventlog"))
1368                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1369         bprint ("^4",self.netname);
1370         bprint ("^4 disconnected\n");
1371
1372         DropAllRunes(self);
1373         kh_Key_DropAll(self, TRUE);
1374
1375         Portal_ClearAll(self);
1376
1377         if(self.flagcarried)
1378                 DropFlag(self.flagcarried, world, world);
1379
1380         // Here, everything has been done that requires this player to be a client.
1381
1382         self.flags &~= FL_CLIENT;
1383
1384         if (self.chatbubbleentity)
1385                 remove (self.chatbubbleentity);
1386
1387         if (self.teambubbleentity)
1388                 remove (self.teambubbleentity);
1389
1390         if (self.killindicator)
1391                 remove (self.killindicator);
1392
1393         WaypointSprite_PlayerGone();
1394
1395         bot_relinkplayerlist();
1396
1397         // remove laserdot
1398         if(self.weaponentity)
1399                 if(self.weaponentity.lasertarget)
1400                         remove(self.weaponentity.lasertarget);
1401
1402         if(g_arena)
1403         {
1404                 Spawnqueue_Unmark(self);
1405                 Spawnqueue_Remove(self);
1406         }
1407
1408         ClientData_Detach();
1409         PlayerScore_Detach(self);
1410
1411         if(self.netname_previous)
1412                 strunzone(self.netname_previous);
1413
1414         ClearPlayerSounds();
1415
1416         self.playerid = 0;
1417         ReadyCount();
1418
1419         // free cvars
1420         GetCvars(-1);
1421 }
1422
1423 .float BUTTON_CHAT;
1424 void ChatBubbleThink()
1425 {
1426         self.nextthink = time;
1427         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1428         {
1429                 if(self.owner) // but why can that ever be world?
1430                         self.owner.chatbubbleentity = world;
1431                 remove(self);
1432                 return;
1433         }
1434         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1435                 self.model = self.mdl;
1436         else
1437                 self.model = "";
1438 };
1439
1440 void UpdateChatBubble()
1441 {
1442         if (!self.modelindex)
1443                 return;
1444         // spawn a chatbubble entity if needed
1445         if (!self.chatbubbleentity)
1446         {
1447                 self.chatbubbleentity = spawn();
1448                 self.chatbubbleentity.owner = self;
1449                 self.chatbubbleentity.exteriormodeltoclient = self;
1450                 self.chatbubbleentity.think = ChatBubbleThink;
1451                 self.chatbubbleentity.nextthink = time;
1452                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1453                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1454                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1455                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1456                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1457                 self.chatbubbleentity.model = "";
1458                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1459         }
1460 }
1461
1462
1463 void TeamBubbleThink()
1464 {
1465         self.nextthink = time;
1466         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1467         {
1468                 if(self.owner) // but why can that ever be world?
1469                         self.owner.teambubbleentity = world;
1470                 remove(self);
1471                 return;
1472         }
1473 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1474         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1475                 self.model = "";
1476         else
1477                 self.model = self.mdl;
1478
1479 };
1480
1481 float TeamBubble_customizeentityforclient()
1482 {
1483         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1484 }
1485
1486 void UpdateTeamBubble()
1487 {
1488         if (!self.modelindex || !teams_matter)
1489                 return;
1490         // spawn a teambubble entity if needed
1491         if (!self.teambubbleentity && teams_matter)
1492         {
1493                 self.teambubbleentity = spawn();
1494                 self.teambubbleentity.owner = self;
1495                 self.teambubbleentity.exteriormodeltoclient = self;
1496                 self.teambubbleentity.think = TeamBubbleThink;
1497                 self.teambubbleentity.nextthink = time;
1498                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1499 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1500                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1501                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1502                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1503                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1504                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1505                 self.teambubbleentity.effects = EF_LOWPRECISION;
1506         }
1507 }
1508
1509 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1510 // added to the model skins
1511 /*void UpdateColorModHack()
1512 {
1513         local float c;
1514         c = self.clientcolors & 15;
1515         // LordHavoc: only bothering to support white, green, red, yellow, blue
1516              if (!teams_matter) self.colormod = '0 0 0';
1517         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1518         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1519         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1520         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1521         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1522         else self.colormod = '1 1 1';
1523 };*/
1524
1525 void respawn(void)
1526 {
1527         CopyBody(1);
1528         self.effects |= EF_NODRAW; // prevent another CopyBody
1529         PutClientInServer();
1530 }
1531
1532 /**
1533  * When sv_timeout is used this function returs strings like
1534  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1535  * Called by centerprint functions
1536  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1537  */
1538 string getTimeoutText(float addOneSecond) {
1539         if (!cvar("sv_timeout") || !timeoutStatus)
1540                 return "";
1541
1542         local string retStr;
1543         if (timeoutStatus == 1) {
1544                 if (addOneSecond == 1) {
1545                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1546                 }
1547                 else {
1548                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1549                 }
1550                 return retStr;
1551         }
1552         else if (timeoutStatus == 2) {
1553                 if (addOneSecond) {
1554                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1555                         //don't show messages like "Timeout ends in 0 seconds"...
1556                         if ((remainingTimeoutTime + 1) > 0)
1557                                 return retStr;
1558                         else
1559                                 return "";
1560                 }
1561                 else {
1562                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1563                         //don't show messages like "Timeout ends in 0 seconds"...
1564                         if (remainingTimeoutTime > 0)
1565                                 return retStr;
1566                         else
1567                                 return "";
1568                 }
1569         }
1570         else return "";
1571 }
1572
1573 void player_powerups (void)
1574 {
1575         if (g_minstagib)
1576         {
1577                 if (self.items & IT_STRENGTH)
1578                 {
1579                         if (time > self.strength_finished)
1580                         {
1581                                 self.alpha = default_player_alpha;
1582                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1583                                 self.items &~= IT_STRENGTH;
1584                                 sprint(self, "^3Invisibility has worn off\n");
1585                         }
1586                 }
1587                 else
1588                 {
1589                         if (time < self.strength_finished)
1590                         {
1591                                 self.alpha = g_minstagib_invis_alpha;
1592                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1593                                 self.items |= IT_STRENGTH;
1594                                 sprint(self, "^3You are invisible\n");
1595                         }
1596                 }
1597
1598                 if (self.items & IT_INVINCIBLE)
1599                 {
1600                         if (time > self.invincible_finished)
1601                         {
1602                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1603                                 sprint(self, "^3Speed has worn off\n");
1604                         }
1605                 }
1606                 else
1607                 {
1608                         if (time < self.invincible_finished)
1609                         {
1610                                 self.items = self.items | IT_INVINCIBLE;
1611                                 sprint(self, "^3You are on speed\n");
1612                         }
1613                 }
1614                 return;
1615         }
1616
1617         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1618         if (self.items & IT_STRENGTH)
1619         {
1620                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1621                 if (time > self.strength_finished)
1622                 {
1623                         self.items = self.items - (self.items & IT_STRENGTH);
1624                         sprint(self, "^3Strength has worn off\n");
1625                 }
1626         }
1627         else
1628         {
1629                 if (time < self.strength_finished)
1630                 {
1631                         self.items = self.items | IT_STRENGTH;
1632                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1633                 }
1634         }
1635         if (self.items & IT_INVINCIBLE)
1636         {
1637                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1638                 if (time > self.invincible_finished)
1639                 {
1640                         self.items = self.items - (self.items & IT_INVINCIBLE);
1641                         sprint(self, "^3Shield has worn off\n");
1642                 }
1643         }
1644         else
1645         {
1646                 if (time < self.invincible_finished)
1647                 {
1648                         self.items = self.items | IT_INVINCIBLE;
1649                         sprint(self, "^3Shield surrounds you\n");
1650                 }
1651         }
1652
1653         if (cvar("g_fullbrightplayers"))
1654                 self.effects = self.effects | EF_FULLBRIGHT;
1655
1656         // midair gamemode: damage only while in the air
1657         // if in midair mode, being on ground grants temporary invulnerability
1658         // (this is so that multishot weapon don't clear the ground flag on the
1659         // first damage in the frame, leaving the player vulnerable to the
1660         // remaining hits in the same frame)
1661         if (self.flags & FL_ONGROUND)
1662         if (g_midair)
1663                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1664
1665         if (time >= game_starttime)
1666         if (time < self.spawnshieldtime)
1667                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1668 }
1669
1670 float CalcRegen(float current, float stable, float regenfactor)
1671 {
1672         if(current > stable)
1673                 return current;
1674         else if(current > stable - 0.25) // when close enough, "snap"
1675                 return stable;
1676         else
1677                 return min(stable, current + (stable - current) * regenfactor * frametime);
1678 }
1679
1680 void player_regen (void)
1681 {
1682         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1683         maxh = cvar("g_balance_health_stable");
1684         maxa = cvar("g_balance_armor_stable");
1685         limith = cvar("g_balance_health_limit");
1686         limita = cvar("g_balance_armor_limit");
1687
1688         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1689                 return;
1690
1691         max_mod = regen_mod = rot_mod = limit_mod = 1;
1692
1693         if (self.runes & RUNE_REGEN)
1694         {
1695                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1696                 {
1697                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1698                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1699                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1700                 }
1701                 else
1702                 {
1703                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1704                         max_mod = cvar("g_balance_rune_regen_hpmod");
1705                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1706                 }
1707         }
1708         else if (self.runes & CURSE_VENOM)
1709         {
1710                 max_mod = cvar("g_balance_curse_venom_hpmod");
1711                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1712                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1713                 else
1714                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1715                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1716                 //if (!self.runes & RUNE_REGEN)
1717                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1718         }
1719         maxh = maxh * max_mod;
1720         //maxa = maxa * max_mod;
1721         limith = limith * limit_mod;
1722         limita = limita * limit_mod;
1723
1724         if (self.armorvalue > maxa)
1725         {
1726                 if (time > self.pauserotarmor_finished)
1727                 {
1728                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1729                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1730                 }
1731         }
1732         else if (self.armorvalue < maxa)
1733         {
1734                 if (time > self.pauseregen_finished)
1735                 {
1736                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1737                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1738                 }
1739         }
1740         if (self.health > maxh)
1741         {
1742                 if (time > self.pauserothealth_finished)
1743                 {
1744                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1745                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1746                 }
1747         }
1748         else if (self.health < maxh)
1749         {
1750                 if (time > self.pauseregen_finished)
1751                 {
1752                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1753                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1754                 }
1755         }
1756
1757         if (self.health > limith)
1758                 self.health = limith;
1759         if (self.armorvalue > limita)
1760                 self.armorvalue = limita;
1761
1762         // if player rotted to death...  die!
1763         if(self.health < 1)
1764                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1765 }
1766
1767 float zoomstate_set;
1768 void SetZoomState(float z)
1769 {
1770         if(z != self.zoomstate)
1771                 ClientData_Touch(self);
1772         zoomstate_set = 1;
1773 }
1774
1775 void GetPressedKeys(void) {
1776         if (self.movement_x > 0) // get if movement keys are pressed
1777         {       // forward key pressed
1778                 self.pressedkeys |= KEY_FORWARD;
1779                 self.pressedkeys &~= KEY_BACKWARD;
1780         }
1781         else if (self.movement_x < 0)
1782         {       // backward key pressed
1783                 self.pressedkeys |= KEY_BACKWARD;
1784                 self.pressedkeys &~= KEY_FORWARD;
1785         }
1786         else
1787         {       // no x input
1788                 self.pressedkeys &~= KEY_FORWARD;
1789                 self.pressedkeys &~= KEY_BACKWARD;
1790         }
1791
1792         if (self.movement_y > 0)
1793         {       // right key pressed
1794                 self.pressedkeys |= KEY_RIGHT;
1795                 self.pressedkeys &~= KEY_LEFT;
1796         }
1797         else if (self.movement_y < 0)
1798         {       // left key pressed
1799                 self.pressedkeys |= KEY_LEFT;
1800                 self.pressedkeys &~= KEY_RIGHT;
1801         }
1802         else
1803         {       // no y input
1804                 self.pressedkeys &~= KEY_RIGHT;
1805                 self.pressedkeys &~= KEY_LEFT;
1806         }
1807
1808         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1809                 self.pressedkeys |= KEY_JUMP;
1810         else
1811                 self.pressedkeys &~= KEY_JUMP;
1812         if (self.BUTTON_CROUCH)
1813                 self.pressedkeys |= KEY_CROUCH;
1814         else
1815                 self.pressedkeys &~= KEY_CROUCH;
1816 }
1817
1818 /*
1819 ======================
1820 spectate mode routines
1821 ======================
1822 */
1823 void SpectateCopy(entity spectatee) {
1824         self.armortype = spectatee.armortype;
1825         self.armorvalue = spectatee.armorvalue;
1826         self.currentammo = spectatee.currentammo;
1827         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1828         self.health = spectatee.health;
1829         self.impulse = 0;
1830         self.items = spectatee.items;
1831         self.strength_finished = spectatee.strength_finished;
1832         self.invincible_finished = spectatee.invincible_finished;
1833         self.pressedkeys = spectatee.pressedkeys;
1834         self.weapons = spectatee.weapons;
1835         self.switchweapon = spectatee.switchweapon;
1836         self.weapon = spectatee.weapon;
1837         self.punchangle = spectatee.punchangle;
1838         self.view_ofs = spectatee.view_ofs;
1839         self.v_angle = spectatee.v_angle;
1840         self.velocity = spectatee.velocity;
1841         self.dmg_take = spectatee.dmg_take;
1842         self.dmg_save = spectatee.dmg_save;
1843         self.dmg_inflictor = spectatee.dmg_inflictor;
1844         self.angles = spectatee.v_angle;
1845         self.fixangle = TRUE;
1846         setorigin(self, spectatee.origin);
1847         setsize(self, spectatee.mins, spectatee.maxs);
1848         SetZoomState(spectatee.zoomstate);
1849 }
1850
1851 float SpectateUpdate() {
1852         if(!self.enemy)
1853                 return 0;
1854
1855         if (self == self.enemy)
1856                 return 0;
1857
1858         if(self.enemy.flags & FL_NOTARGET)
1859                 return 0;
1860
1861         SpectateCopy(self.enemy);
1862
1863         return 1;
1864 }
1865
1866 float SpectateNext() {
1867         other = find(self.enemy, classname, "player");
1868         if (!other) {
1869                 other = find(other, classname, "player");
1870         }
1871         if (other) {
1872                 self.enemy = other;
1873         }
1874         if(self.enemy.classname == "player") {
1875                 msg_entity = self;
1876                 WriteByte(MSG_ONE, SVC_SETVIEW);
1877                 WriteEntity(MSG_ONE, self.enemy);
1878                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1879                 if(!SpectateUpdate())
1880                         PutObserverInServer();
1881                 return 1;
1882         } else {
1883                 return 0;
1884         }
1885 }
1886
1887 /*
1888 =============
1889 ShowRespawnCountdown()
1890
1891 Update a respawn countdown display.
1892 =============
1893 */
1894 void ShowRespawnCountdown()
1895 {
1896         float number;
1897         if(self.deadflag == DEAD_NO) // just respawned?
1898                 return;
1899         else
1900         {
1901                 number = ceil(self.death_time - time);
1902                 if(number <= 0)
1903                         return;
1904                 if(number <= self.respawn_countdown)
1905                 {
1906                         self.respawn_countdown = number - 1;
1907                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1908                                 announce(self, strcat("announcer/robotic/", ftos(number), ".wav"));
1909                 }
1910         }
1911 }
1912
1913 void LeaveSpectatorMode()
1914 {
1915         if(isJoinAllowed()) {
1916                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams")) {
1917                         self.classname = "player";
1918                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1919                                 JoinBestTeam(self, FALSE, TRUE);
1920                         if(cvar("g_campaign"))
1921                                 campaign_bots_may_start = 1;
1922                         PutClientInServer();
1923                         if(!(self.flags & FL_NOTARGET))
1924                                 bprint ("^4", self.netname, "^4 is playing now\n");
1925                         centerprint(self,"");
1926                         return;
1927                 } else {
1928                         stuffcmd(self,"menu_showteamselect\n");
1929                         return;
1930                 }
1931         }
1932         else {
1933                 //player may not join because of g_maxplayers is set
1934                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1935         }
1936 }
1937
1938 /**
1939  * Determines whether the player is allowed to join. This depends on cvar
1940  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1941  * it checks whether the number of currently playing players exceeds g_maxplayers.
1942  * @return bool TRUE if the player is allowed to join, false otherwise
1943  */
1944 float isJoinAllowed() {
1945         if (!cvar("g_maxplayers"))
1946                 return TRUE;
1947
1948         local entity e;
1949         local float currentlyPlaying;
1950         FOR_EACH_REALPLAYER(e) {
1951                 if(e.classname == "player")
1952                         currentlyPlaying += 1;
1953         }
1954         if(currentlyPlaying < cvar("g_maxplayers"))
1955                 return TRUE;
1956
1957         return FALSE;
1958 }
1959
1960 /**
1961  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1962  * g_maxplayers_spectator_blocktime seconds
1963  */
1964 void checkSpectatorBlock() {
1965         if(self.classname == "spectator" || self.classname == "observer") {
1966                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1967                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1968                         dropclient(self);
1969                 }
1970         }
1971 }
1972
1973 float vercmp_recursive(string v1, string v2)
1974 {
1975         float dot1, dot2;
1976         string s1, s2;
1977         float r;
1978
1979         dot1 = strstrofs(v1, ".", 0);
1980         dot2 = strstrofs(v2, ".", 0);
1981         if(dot1 == -1)
1982                 s1 = v1;
1983         else
1984                 s1 = substring(v1, 0, dot1);
1985         if(dot2 == -1)
1986                 s2 = v2;
1987         else
1988                 s2 = substring(v2, 0, dot2);
1989
1990         r = stof(s1) - stof(s2);
1991         if(r != 0)
1992                 return r;
1993
1994         r = strcasecmp(s1, s2);
1995         if(r != 0)
1996                 return r;
1997
1998         if(dot1 == -1)
1999                 if(dot2 == -1)
2000                         return 0;
2001                 else
2002                         return -1;
2003         else
2004                 if(dot2 == -1)
2005                         return 1;
2006                 else
2007                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2008 }
2009
2010 float vercmp(string v1, string v2)
2011 {
2012         if(strcasecmp(v1, v2) == 0) // early out check
2013                 return 0;
2014         return vercmp_recursive(v1, v2);
2015 }
2016
2017 void ObserverThink()
2018 {
2019         if (self.flags & FL_JUMPRELEASED) {
2020                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2021                         self.welcomemessage_time = 0;
2022                         self.flags &~= FL_JUMPRELEASED;
2023                         LeaveSpectatorMode();
2024                         return;
2025                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2026                         self.welcomemessage_time = 0;
2027                         self.flags &~= FL_JUMPRELEASED;
2028                         if(SpectateNext() == 1) {
2029                                 self.classname = "spectator";
2030                         }
2031                 }
2032         } else {
2033                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2034                         self.flags |= FL_JUMPRELEASED;
2035                 }
2036         }
2037         PrintWelcomeMessage(self);
2038 }
2039
2040 void SpectatorThink()
2041 {
2042         if (self.flags & FL_JUMPRELEASED) {
2043                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2044                         self.welcomemessage_time = 0;
2045                         self.flags &~= FL_JUMPRELEASED;
2046                         LeaveSpectatorMode();
2047                         return;
2048                 } else if(self.BUTTON_ATCK) {
2049                         self.welcomemessage_time = 0;
2050                         self.flags &~= FL_JUMPRELEASED;
2051                         if(SpectateNext() == 1) {
2052                                 self.classname = "spectator";
2053                         } else {
2054                                 self.classname = "observer";
2055                                 PutClientInServer();
2056                         }
2057                 } else if (self.BUTTON_ATCK2) {
2058                         self.welcomemessage_time = 0;
2059                         self.flags &~= FL_JUMPRELEASED;
2060                         self.classname = "observer";
2061                         PutClientInServer();
2062                 } else {
2063                         if(!SpectateUpdate())
2064                                 PutObserverInServer();
2065                 }
2066         } else {
2067                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2068                         self.flags |= FL_JUMPRELEASED;
2069                 }
2070         }
2071         PrintWelcomeMessage(self);
2072         self.flags |= FL_CLIENT | FL_NOTARGET;
2073 }
2074
2075 .float touchexplode_time;
2076
2077 /*
2078 =============
2079 PlayerPreThink
2080
2081 Called every frame for each client before the physics are run
2082 =============
2083 */
2084 void() ctf_setstatus;
2085 void PlayerPreThink (void)
2086 {
2087         self.stat_sys_ticrate = cvar("sys_ticrate");
2088         self.stat_game_starttime = game_starttime;
2089         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2090
2091         if(blockSpectators && frametime)
2092                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2093                 checkSpectatorBlock();
2094
2095         zoomstate_set = 0;
2096
2097         if(self.netname_previous != self.netname)
2098         {
2099                 if(cvar("sv_eventlog"))
2100                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2101                 if(self.netname_previous)
2102                         strunzone(self.netname_previous);
2103                 self.netname_previous = strzone(self.netname);
2104         }
2105
2106         // version nagging
2107         if(self.version_nagtime)
2108                 if(self.cvar_g_nexuizversion)
2109                         if(time > self.version_nagtime)
2110                         {
2111                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
2112                                 {
2113                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
2114                                         {
2115                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2116                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2117                                         }
2118                                         else
2119                                         {
2120                                                 float r;
2121                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2122                                                 if(r < 0)
2123                                                 {
2124                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
2125                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
2126                                                 }
2127                                                 else if(r > 0)
2128                                                 {
2129                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2130                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2131                                                 }
2132                                         }
2133                                 }
2134                                 self.version_nagtime = 0;
2135                         }
2136
2137         // GOD MODE info
2138         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2139         {
2140                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2141                 self.max_armorvalue = 0;
2142         }
2143
2144         if(frametime)
2145                 antilag_record(self);
2146
2147         if(self.classname == "player") {
2148 //              if(self.netname == "Wazat")
2149 //                      bprint(self.classname, "\n");
2150
2151                 CheckRules_Player();
2152
2153                 PrintWelcomeMessage(self);
2154
2155                 if (intermission_running)
2156                 {
2157                         IntermissionThink ();   // otherwise a button could be missed between
2158                         return;                                 // the think tics
2159                 }
2160
2161                 if(self.teleport_time)
2162                 if(time > self.teleport_time)
2163                 {
2164                         self.teleport_time = 0;
2165                         self.effects = self.effects - (self.effects & EF_NODRAW);
2166                 }
2167
2168                 Nixnex_GiveCurrentWeapon();
2169
2170                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2171                         UpdateSelectedPlayer();
2172
2173                 //don't allow the player to turn around while game is paused!
2174                 if(timeoutStatus == 2) {
2175                         self.v_angle = self.lastV_angle;
2176                         self.angles = self.lastV_angle;
2177                         self.fixangle = TRUE;
2178                 }
2179
2180                 if (self.deadflag != DEAD_NO)
2181                 {
2182                         float button_pressed, force_respawn;
2183                         player_anim();
2184                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2185                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2186                         if (self.deadflag == DEAD_DYING)
2187                         {
2188                                 if(force_respawn)
2189                                         self.deadflag = DEAD_RESPAWNING;
2190                                 else if(!button_pressed)
2191                                         self.deadflag = DEAD_DEAD;
2192                         }
2193                         else if (self.deadflag == DEAD_DEAD)
2194                         {
2195                                 if(button_pressed)
2196                                         self.deadflag = DEAD_RESPAWNABLE;
2197                         }
2198                         else if (self.deadflag == DEAD_RESPAWNABLE)
2199                         {
2200                                 if(!button_pressed)
2201                                         self.deadflag = DEAD_RESPAWNING;
2202                         }
2203                         else if (self.deadflag == DEAD_RESPAWNING)
2204                         {
2205                                 if(time > self.death_time)
2206                                 {
2207                                         self.death_time = time + 1; // only retry once a second
2208                                         respawn();
2209                                 }
2210                         }
2211                         ShowRespawnCountdown();
2212                         return;
2213                 }
2214
2215                 if(g_touchexplode)
2216                 if(time > self.touchexplode_time)
2217                 if(self.classname == "player")
2218                 if(self.deadflag == DEAD_NO)
2219                 if not(IS_INDEPENDENT_PLAYER(self))
2220                 FOR_EACH_PLAYER(other) if(self != other)
2221                 {
2222                         if(time > other.touchexplode_time)
2223                         if(other.classname == "player")
2224                         if(other.deadflag == DEAD_NO)
2225                         if not(IS_INDEPENDENT_PLAYER(other))
2226                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2227                         {
2228                                 PlayerTouchExplode(self, other);
2229                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2230                         }
2231                 }
2232
2233                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2234                 {
2235                         vector dist;
2236
2237                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2238                         dist = self.oldorigin - self.origin;
2239                         dist_z = 0;
2240                         self.lms_traveled_distance += fabs(vlen(dist));
2241
2242                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2243                         {
2244                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2245                                 self.lms_traveled_distance = 0;
2246                         }
2247
2248                         if(time > self.lms_nextcheck)
2249                         {
2250                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2251                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2252                                 {
2253                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2254                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2255                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2256                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2257                                 }
2258                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2259                                 self.lms_traveled_distance = 0;
2260                         }
2261                 }
2262
2263                 self.oldorigin = self.origin;
2264
2265                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2266                 {
2267                         if (!self.crouch)
2268                         {
2269                                 self.crouch = TRUE;
2270                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2271                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2272                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2273                         }
2274                 }
2275                 else
2276                 {
2277                         if (self.crouch)
2278                         {
2279                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2280                                 if (!trace_startsolid)
2281                                 {
2282                                         self.crouch = FALSE;
2283                                         self.view_ofs = PL_VIEW_OFS;
2284                                         setsize (self, PL_MIN, PL_MAX);
2285                                 }
2286                         }
2287                 }
2288
2289                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2290                 {
2291                         if(self.bloodloss_timer < time)
2292                         {
2293                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2294                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2295                         }
2296                 }
2297
2298                 FixPlayermodel();
2299
2300                 GrapplingHookFrame();
2301
2302                 W_WeaponFrame();
2303
2304                 player_powerups();
2305                 player_regen();
2306                 player_anim();
2307
2308                 if (g_minstagib)
2309                         minstagib_ammocheck();
2310
2311                 ctf_setstatus();
2312                 kh_setstatus();
2313
2314                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2315
2316                 //self.angles_y=self.v_angle_y + 90;   // temp
2317
2318                 //if (TetrisPreFrame()) return;
2319         } else if(gameover) {
2320                 if (intermission_running)
2321                         IntermissionThink ();   // otherwise a button could be missed between
2322                 return;
2323         } else if(self.classname == "observer") {
2324                 ObserverThink();
2325         } else if(self.classname == "spectator") {
2326                 SpectatorThink();
2327         }
2328
2329         if(!zoomstate_set)
2330                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2331
2332         float oldspectatee_status;
2333         oldspectatee_status = self.spectatee_status;
2334         if(self.classname == "spectator")
2335                 self.spectatee_status = num_for_edict(self.enemy);
2336         else if(self.classname == "observer")
2337                 self.spectatee_status = num_for_edict(self);
2338         else
2339                 self.spectatee_status = 0;
2340         if(self.spectatee_status != oldspectatee_status)
2341         {
2342                 ClientData_Touch(self);
2343                 if(g_race)
2344                         race_InitSpectator();
2345         }
2346
2347         if(self.teamkill_soundtime)
2348         if(time > self.teamkill_soundtime)
2349         {
2350                 self.teamkill_soundtime = 0;
2351
2352                 entity oldpusher, oldself;
2353
2354                 oldself = self; self = self.teamkill_soundsource;
2355                 oldpusher = self.pusher; self.pusher = oldself;
2356
2357                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2358
2359                 self.pusher = oldpusher;
2360                 self = oldself;
2361         }
2362
2363         if(self.taunt_soundtime)
2364         if(time > self.taunt_soundtime)
2365         {
2366                 self.taunt_soundtime = 0;
2367                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2368         }
2369
2370         target_voicescript_next(self);
2371 }
2372
2373
2374 /*
2375 =============
2376 PlayerPostThink
2377
2378 Called every frame for each client after the physics are run
2379 =============
2380 */
2381 .float idlekick_lasttimeleft;
2382 .float race_penalty;
2383 .float race_penalty_nagged;
2384 .float race_penalty_nagtime;
2385 void PlayerPostThink (void)
2386 {
2387         // Savage: Check for nameless players
2388         if (strlen(self.netname) < 1) {
2389                 self.netname = "Player";
2390                 stuffcmd(self, "seta _cl_name Player\n");
2391         }
2392
2393         if(sv_maxidle && frametime)
2394         {
2395                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2396                 float timeleft;
2397                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2398                 if(timeleft <= 0)
2399                 {
2400                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2401                         announce(self, "announcer/robotic/terminated.wav");
2402                         dropclient(self);
2403                         return;
2404                 }
2405                 else if(timeleft <= 10)
2406                 {
2407                         if(timeleft != self.idlekick_lasttimeleft)
2408                         {
2409                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2410                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".wav"));
2411                         }
2412                 }
2413                 else
2414                 {
2415                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2416                 }
2417                 self.idlekick_lasttimeleft = timeleft;
2418         }
2419
2420         if(self.classname == "player") {
2421                 CheckRules_Player();
2422                 UpdateChatBubble();
2423                 UpdateTeamBubble();
2424                 if (self.impulse)
2425                         ImpulseCommands();
2426                 if (intermission_running)
2427                         return;         // intermission or finale
2428
2429                 //if (TetrisPostFrame()) return;
2430
2431                 // restart countdown
2432                         if(time < game_starttime) {
2433                                 if (!cvar("sv_ready_restart_after_countdown"))
2434                                 {
2435                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2436                                         {
2437                                                 if(time < game_starttime - 2)
2438                                                 {
2439                                                         if(!self.race_penalty_nagged)
2440                                                         {
2441                                                                 // TODO better notification for this!
2442                                                                 self.race_penalty_nagtime = 0;
2443                                                                 self.race_penalty_nagged = 1;
2444                                                         }
2445                                                 }
2446                                                 else if(!self.race_penalty)
2447                                                 {
2448                                                         self.race_penalty_nagtime = 0;
2449                                                         self.race_penalty = time + 5;
2450                                                 }
2451                                         }
2452                                         if(time > self.race_penalty_nagtime)
2453                                         {
2454                                                 if(self.race_penalty > time)
2455                                                 {
2456                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2457                                                 }
2458                                                 else if(self.race_penalty_nagged && time < game_starttime - 2)
2459                                                 {
2460                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2461                                                 }
2462                                                 self.race_penalty_nagtime = time + self.cvar_scr_centertime * 0.6;
2463                                         }
2464                                         self.movetype = MOVETYPE_NONE;
2465                                         self.velocity = '0 0 0';
2466                                         self.avelocity = '0 0 0';
2467                                         self.movement = '0 0 0';
2468                                 }
2469                         }
2470                         else if (time < self.race_penalty)
2471                         {
2472                                 self.movetype = MOVETYPE_NONE;
2473                                 self.velocity = '0 0 0';
2474                                 self.avelocity = '0 0 0';
2475                                 self.movement = '0 0 0';
2476                         }
2477                         else
2478                         {
2479                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2480                                 if (!cvar("sv_ready_restart_after_countdown"))
2481                                 {
2482                                         if(self.movetype == MOVETYPE_NONE)
2483                                         {
2484                                                 self.movetype = MOVETYPE_WALK;
2485                                         }
2486                                         self.race_penalty = 0;
2487                                         self.race_penalty_nagged = 0;
2488                                 }
2489                         }
2490                 GetPressedKeys();
2491         } else if (self.classname == "observer") {
2492                 //do nothing
2493         } else if (self.classname == "spectator") {
2494                 //do nothing
2495         }
2496
2497         /*
2498         float i;
2499         for(i = 0; i < 1000; ++i)
2500         {
2501                 vector end;
2502                 end = self.origin + '0 0 1024' + 512 * randomvec();
2503                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2504                 if(trace_fraction < 1)
2505                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2506                 {
2507                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2508                         break;
2509                 }
2510         }
2511         */
2512
2513         Arena_Warmup();
2514
2515         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2516 }