data/qcsrc/server/cl_client.qc

   1 #define SPAWNPOINT_SCORE frags
   2
   3 .float wantswelcomemessage;
   4 .string netname_previous;
   5
   6 void spawnfunc_info_player_survivor (void)
   7 {
   8         spawnfunc_info_player_deathmatch();
   9 }
  10
  11 void spawnfunc_info_player_start (void)
  12 {
  13         spawnfunc_info_player_deathmatch();
  14 }
  15
  16 void spawnfunc_info_player_deathmatch (void)
  17 {
  18         self.classname = "info_player_deathmatch";
  19         relocate_spawnpoint();
  20 }
  21
  22 void spawnpoint_use()
  23 {
  24         if(teams_matter)
  25         if(have_team_spawns)
  26         {
  27                 self.team = activator.team;
  28                 some_spawn_has_been_used = 1;
  29         }
  30 };
  31
  32 // Returns:
  33 //   -1 if a spawn can't be used
  34 //   otherwise, a weight of the spawnpoint
  35 float Spawn_Score(entity spot, entity playerlist, float teamcheck)
  36 {
  37         float shortest, thisdist;
  38         entity player;
  39
  40         // filter out spots for the wrong team
  41         if(teamcheck)
  42         if(spot.team != teamcheck)
  43                 return -1;
  44
  45         if(race_spawns)
  46                 if(spot.target == "")
  47                         return -1;
  48
  49         // filter out spots for assault
  50         if(spot.target != "") {
  51                 local entity ent;
  52                 float good;
  53                 ent = find(world, targetname, spot.target);
  54                 while(ent) {
  55                         if(ent.classname == "target_objective")
  56                         {
  57                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
  58                                         return -1;
  59                                 good = 1;
  60                         }
  61                         else if(ent.classname == "trigger_race_checkpoint")
  62                         {
  63                                 if(self.classname == "player") // spectators may spawn everywhere
  64                                 {
  65                                         if(g_race_qualifying)
  66                                         {
  67                                                 // spawn at first
  68                                                 if(ent.race_checkpoint != 0)
  69                                                         return -1;
  70                                                 if(spot.race_place != race_lowest_place_spawn)
  71                                                         return -1;
  72                                         }
  73                                         else
  74                                         {
  75                                                 if(ent.race_checkpoint != race_PreviousCheckpoint(self.race_checkpoint))
  76                                                         return -1;
  77                                                 float pl;
  78                                                 pl = self.race_place;
  79                                                 if(pl > race_highest_place_spawn)
  80                                                         pl = 0;
  81                                                 if(spot.race_place != pl)
  82                                                         return -1;
  83                                         }
  84                                 }
  85                                 good = 1;
  86                         }
  87                         else
  88                         {
  89                         }
  90                         ent = find(ent, targetname, spot.target);
  91                 }
  92
  93                 if(!good)
  94                         return -1;
  95         }
  96
  97         player = playerlist;
  98         shortest = vlen(world.maxs - world.mins);
  99         for(player = playerlist; player; player = player.chain)
 100                 if (player != self)
 101                 {
 102                         thisdist = vlen(player.origin - spot.origin);
 103                         if (thisdist < shortest)
 104                                 shortest = thisdist;
 105                 }
 106         return shortest;
 107 }
 108
 109 float spawn_allbad;
 110 float spawn_allgood;
 111 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
 112 {
 113         local entity spot, spotlist, spotlistend;
 114         spawn_allgood = TRUE;
 115         spawn_allbad = TRUE;
 116
 117         spotlist = world;
 118         spotlistend = world;
 119
 120         for(spot = firstspot; spot; spot = spot.chain)
 121         {
 122                 spot.SPAWNPOINT_SCORE = Spawn_Score(spot, playerlist, teamcheck);
 123
 124                 if(cvar("spawn_debugview"))
 125                 {
 126                         setmodel(spot, "models/runematch/rune.mdl");
 127                         if(spot.SPAWNPOINT_SCORE < mindist)
 128                         {
 129                                 spot.colormod = '1 0 0';
 130                                 spot.scale = 1;
 131                         }
 132                         else
 133                         {
 134                                 spot.colormod = '0 1 0';
 135                                 spot.scale = spot.SPAWNPOINT_SCORE / mindist;
 136                         }
 137                 }
 138
 139                 if(spot.SPAWNPOINT_SCORE >= 0) // spawning allowed here
 140                 {
 141                         if(spot.SPAWNPOINT_SCORE < mindist)
 142                         {
 143                                 // too short distance
 144                                 spawn_allgood = FALSE;
 145                         }
 146                         else
 147                         {
 148                                 // perfect
 149                                 spawn_allbad = FALSE;
 150
 151                                 if(spotlistend)
 152                                         spotlistend.chain = spot;
 153                                 spotlistend = spot;
 154                                 if(!spotlist)
 155                                         spotlist = spot;
 156
 157                                 /*
 158                                 if(teamcheck)
 159                                 if(spot.team != teamcheck)
 160                                         error("invalid spawn added");
 161
 162                                 print("added ", etos(spot), "\n");
 163                                 */
 164                         }
 165                 }
 166         }
 167         if(spotlistend)
 168                 spotlistend.chain = world;
 169
 170         /*
 171                 entity e;
 172                 if(teamcheck)
 173                         for(e = spotlist; e; e = e.chain)
 174                         {
 175                                 print("seen ", etos(e), "\n");
 176                                 if(e.team != teamcheck)
 177                                         error("invalid spawn found");
 178                         }
 179         */
 180
 181         return spotlist;
 182 }
 183
 184 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 185 {
 186         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 187         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 188         local entity spot;
 189
 190         RandomSelection_Init();
 191         for(spot = firstspot; spot; spot = spot.chain)
 192                 RandomSelection_Add(spot, 0, pow(bound(lower, spot.SPAWNPOINT_SCORE, upper), exponent) * spot.cnt, spot.SPAWNPOINT_SCORE >= lower);
 193
 194         return RandomSelection_chosen_ent;
 195 }
 196
 197 /*
 198 =============
 199 SelectSpawnPoint
 200
 201 Finds a point to respawn
 202 =============
 203 */
 204 entity SelectSpawnPoint (float anypoint)
 205 {
 206         local float teamcheck;
 207         local entity firstspot_new;
 208         local entity spot, firstspot, playerlist;
 209
 210         spot = find (world, classname, "testplayerstart");
 211         if (spot)
 212                 return spot;
 213
 214         teamcheck = 0;
 215
 216         if(!anypoint && have_team_spawns)
 217                 teamcheck = self.team;
 218
 219         // get the list of players
 220         playerlist = findchain(classname, "player");
 221         // get the entire list of spots
 222         firstspot = findchain(classname, "info_player_deathmatch");
 223         // filter out the bad ones
 224         // (note this returns the original list if none survived)
 225         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 226         if(!firstspot_new)
 227                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck);
 228         firstspot = firstspot_new;
 229
 230         // there is 50/50 chance of choosing a random spot or the furthest spot
 231         // (this means that roughly every other spawn will be furthest, so you
 232         // usually won't get fragged at spawn twice in a row)
 233         if (arena_roundbased)
 234         {
 235                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck);
 236                 if(firstspot_new)
 237                         firstspot = firstspot_new;
 238                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 239         }
 240         else if (random() > cvar("g_spawn_furthest"))
 241                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 242         else
 243                 spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 244
 245         if(cvar("spawn_debugview"))
 246         {
 247                 print("spot mindistance: ", ftos(spot.SPAWNPOINT_SCORE), "\n");
 248
 249                 entity e;
 250                 if(teamcheck)
 251                         for(e = firstspot; e; e = e.chain)
 252                                 if(e.team != teamcheck)
 253                                         error("invalid spawn found");
 254         }
 255
 256         if (!spot)
 257         {
 258                 if(cvar("spawn_debug"))
 259                         GotoNextMap();
 260                 else
 261                 {
 262                         if(some_spawn_has_been_used)
 263                                 return world; // team can't spawn any more, because of actions of other team
 264                         else
 265                                 error("Cannot find a spawn point - please fix the map!");
 266                 }
 267         }
 268
 269         return spot;
 270 }
 271
 272 /*
 273 =============
 274 CheckPlayerModel
 275
 276 Checks if the argument string can be a valid playermodel.
 277 Returns a valid one in doubt.
 278 =============
 279 */
 280 string FallbackPlayerModel = "models/player/marine.zym";
 281 string CheckPlayerModel(string plyermodel) {
 282         if(strlen(plyermodel) < 4)
 283                 return FallbackPlayerModel;
 284         if( substring(plyermodel,0,14) != "models/player/")
 285                 return FallbackPlayerModel;
 286         else if(cvar("sv_servermodelsonly"))
 287         {
 288                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".zym")
 289                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".dpm")
 290                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".md3")
 291                 if(substring(plyermodel,strlen(plyermodel)-4,4) != ".psk")
 292                         return FallbackPlayerModel;
 293                 if(plyermodel != strtolower(plyermodel))
 294                         return FallbackPlayerModel;
 295                 if(!fexists(plyermodel))
 296                         return FallbackPlayerModel;
 297         }
 298         return plyermodel;
 299 }
 300
 301 /*
 302 =============
 303 Client_customizeentityforclient
 304
 305 LOD reduction
 306 =============
 307 */
 308 float Client_customizeentityforclient()
 309 {
 310 #ifdef ALLOW_VARIABLE_LOD
 311         // self: me
 312         // other: the player viewing me
 313         float distance;
 314         float f;
 315
 316         if(self.flags & FL_NOTARGET) // we don't need LOD for spectators
 317                 return TRUE;
 318
 319         if(other.cvar_cl_playerdetailreduction <= 0)
 320         {
 321                 if(other.cvar_cl_playerdetailreduction <= -2)
 322                         self.modelindex = self.modelindex_lod2;
 323                 else if(other.cvar_cl_playerdetailreduction <= -1)
 324                         self.modelindex = self.modelindex_lod1;
 325                 else
 326                         self.modelindex = self.modelindex_lod0;
 327         }
 328         else
 329         {
 330                 distance = vlen(self.origin - other.origin);
 331                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 332                 if(f > 10000)
 333                         self.modelindex = self.modelindex_lod2;
 334                 else if(f > 5000)
 335                         self.modelindex = self.modelindex_lod1;
 336                 else
 337                         self.modelindex = self.modelindex_lod0;
 338         }
 339 #endif
 340
 341         return TRUE;
 342 }
 343
 344 void UpdatePlayerSounds();
 345 void setmodel_lod(entity e, string modelname)
 346 {
 347 #ifdef ALLOW_VARIABLE_LOD
 348         string s;
 349
 350         // FIXME: this only supports 3-letter extensions
 351         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1", substring(modelname, 0, strlen(modelname) - 4));
 352         if(fexists(s))
 353         {
 354                 precache_model(s);
 355                 setmodel(e, s); // players have high precision
 356                 self.modelindex_lod1 = self.modelindex;
 357         }
 358         else
 359                 self.modelindex_lod1 = -1;
 360
 361         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2", substring(modelname, 0, strlen(modelname) - 4));
 362         if(fexists(s))
 363         {
 364                 precache_model(s);
 365                 setmodel(e, s); // players have high precision
 366                 self.modelindex_lod2 = self.modelindex;
 367         }
 368         else
 369                 self.modelindex_lod2 = -1;
 370
 371         precache_model(modelname);
 372         setmodel(e, modelname); // players have high precision
 373         self.modelindex_lod0 = self.modelindex;
 374
 375         if(self.modelindex_lod1 < 0)
 376                 self.modelindex_lod1 = self.modelindex;
 377
 378         if(self.modelindex_lod2 < 0)
 379                 self.modelindex_lod2 = self.modelindex;
 380 #else
 381         precache_model(modelname);
 382         setmodel(e, modelname); // players have high precision
 383 #endif
 384         player_setupanimsformodel();
 385         UpdatePlayerSounds();
 386 }
 387
 388 /*
 389 =============
 390 PutObserverInServer
 391
 392 putting a client as observer in the server
 393 =============
 394 */
 395 void PutObserverInServer (void)
 396 {
 397         entity  spot;
 398
 399         race_PreSpawnObserver();
 400
 401         spot = SelectSpawnPoint (TRUE);
 402         if(!spot)
 403                 error("No spawnpoints for observers?!?\n");
 404         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 405
 406         if(clienttype(self) == CLIENTTYPE_REAL)
 407         {
 408                 msg_entity = self;
 409                 WriteByte(MSG_ONE, SVC_SETVIEW);
 410                 WriteEntity(MSG_ONE, self);
 411         }
 412
 413         DropAllRunes(self);
 414         kh_Key_DropAll(self, TRUE);
 415
 416         Portal_ClearAll(self);
 417
 418         if(self.flagcarried)
 419                 DropFlag(self.flagcarried, world, world);
 420
 421         WaypointSprite_PlayerDead();
 422
 423         if(self.killcount != -666)
 424         {
 425                 if(g_lms)
 426                 {
 427                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 428                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 429                         else
 430                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 431                 }
 432                 else
 433                         bprint ("^4", self.netname, "^4 is spectating now\n");
 434         }
 435
 436         PlayerScore_Clear(self); // clear scores when needed
 437
 438         self.spectatortime = time;
 439
 440         self.classname = "observer";
 441         self.iscreature = FALSE;
 442         self.health = -666;
 443         self.takedamage = DAMAGE_NO;
 444         self.solid = SOLID_NOT;
 445         self.movetype = MOVETYPE_NOCLIP;
 446         self.flags = FL_CLIENT | FL_NOTARGET;
 447         self.armorvalue = 666;
 448         self.effects = 0;
 449         self.armorvalue = cvar("g_balance_armor_start");
 450         self.pauserotarmor_finished = 0;
 451         self.pauserothealth_finished = 0;
 452         self.pauseregen_finished = 0;
 453         self.damageforcescale = 0;
 454         self.death_time = 0;
 455         self.dead_frame = 0;
 456         self.alpha = 0;
 457         self.scale = 0;
 458         self.fade_time = 0;
 459         self.pain_frame = 0;
 460         self.pain_finished = 0;
 461         self.strength_finished = 0;
 462         self.invincible_finished = 0;
 463         self.pushltime = 0;
 464         self.think = SUB_Null;
 465         self.nextthink = 0;
 466         self.hook_time = 0;
 467         self.runes = 0;
 468         self.deadflag = DEAD_NO;
 469         self.angles = spot.angles;
 470         self.angles_z = 0;
 471         self.fixangle = TRUE;
 472         self.crouch = FALSE;
 473
 474         self.view_ofs = PL_VIEW_OFS;
 475         setorigin (self, spot.origin);
 476         setsize (self, '0 0 0', '0 0 0');
 477         self.oldorigin = self.origin;
 478         self.items = 0;
 479         self.weapons = 0;
 480         self.model = "";
 481         self.modelindex = 0;
 482         self.weapon = 0;
 483         self.weaponmodel = "";
 484         self.weaponentity = world;
 485         self.killcount = -666;
 486         self.velocity = '0 0 0';
 487         self.avelocity = '0 0 0';
 488         self.punchangle = '0 0 0';
 489         self.punchvector = '0 0 0';
 490         self.oldvelocity = self.velocity;
 491         self.customizeentityforclient = Client_customizeentityforclient;
 492         self.wantswelcomemessage = 1;
 493
 494         if(g_arena)
 495         {
 496                 if(self.version_mismatch)
 497                 {
 498                         Spawnqueue_Unmark(self);
 499                         Spawnqueue_Remove(self);
 500                 }
 501                 else
 502                 {
 503                         Spawnqueue_Insert(self);
 504                 }
 505         }
 506         else if(g_lms)
 507         {
 508                 // Only if the player cannot play at all
 509                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 510                         self.frags = -666;
 511                 else
 512                         self.frags = -667;
 513         }
 514         else
 515                 self.frags = -666;
 516 }
 517
 518 float RestrictSkin(float s)
 519 {
 520         if(!teams_matter)
 521                 return s;
 522         if(s == 6)
 523                 return 6;
 524         return mod(s, 3);
 525 }
 526
 527 void FixPlayermodel()
 528 {
 529         local string defaultmodel;
 530         local float defaultskin;
 531         local vector m1, m2;
 532
 533         defaultmodel = "";
 534
 535         if(cvar("sv_defaultcharacter") == 1) {
 536                 defaultskin = 0;
 537
 538                 if(teams_matter)
 539                 {
 540                         defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", Team_ColorNameLowerCase(self.team)));
 541                         defaultskin = cvar(strcat("sv_defaultplayerskin_", Team_ColorNameLowerCase(self.team)));
 542                 }
 543
 544                 if(defaultmodel == "")
 545                 {
 546                         defaultmodel = cvar_string("sv_defaultplayermodel");
 547                         defaultskin = cvar("sv_defaultplayerskin");
 548                 }
 549         }
 550
 551         if(self.modelindex == 0)
 552         {
 553                 if(self.model != "")
 554                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 555                 self.model = ""; // force the != checks to return true
 556         }
 557
 558         if(defaultmodel != "")
 559         {
 560                 if (defaultmodel != self.model)
 561                 {
 562                         m1 = self.mins;
 563                         m2 = self.maxs;
 564                         setmodel_lod (self, defaultmodel);
 565                         setsize (self, m1, m2);
 566                 }
 567
 568                 self.skin = defaultskin;
 569         } else {
 570                 if (self.playermodel != self.model)
 571                 {
 572                         self.playermodel = CheckPlayerModel(self.playermodel);
 573                         m1 = self.mins;
 574                         m2 = self.maxs;
 575                         setmodel_lod (self, self.playermodel);
 576                         setsize (self, m1, m2);
 577                 }
 578
 579                 self.skin = RestrictSkin(stof(self.playerskin));
 580         }
 581
 582         if(!teams_matter)
 583                 if(strlen(cvar_string("sv_defaultplayercolors")))
 584                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 585                                 setcolor(self, cvar("sv_defaultplayercolors"));
 586 }
 587
 588 void PlayerTouchExplode(entity p1, entity p2)
 589 {
 590         vector org;
 591         org = (p1.origin + p2.origin) * 0.5;
 592         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 593
 594         te_explosion(org);
 595
 596         entity e;
 597         e = spawn();
 598         setorigin(e, org);
 599         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 600         remove(e);
 601 }
 602
 603 /*
 604 =============
 605 PutClientInServer
 606
 607 Called when a client spawns in the server
 608 =============
 609 */
 610 //void() ctf_playerchanged;
 611 void PutClientInServer (void)
 612 {
 613         if(clienttype(self) == CLIENTTYPE_BOT)
 614         {
 615                 self.classname = "player";
 616         }
 617         else if(clienttype(self) == CLIENTTYPE_REAL)
 618         {
 619                 msg_entity = self;
 620                 WriteByte(MSG_ONE, SVC_SETVIEW);
 621                 WriteEntity(MSG_ONE, self);
 622         }
 623
 624         // player is dead and becomes observer
 625         // FIXME fix LMS scoring for new system
 626         if(g_lms)
 627         {
 628                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 629                         self.classname = "observer";
 630         }
 631
 632         if(g_arena)
 633         if(!self.spawned)
 634                 self.classname = "observer";
 635
 636         if(self.classname == "player") {
 637                 entity spot, oldself;
 638
 639                 race_PreSpawn();
 640
 641                 spot = SelectSpawnPoint (FALSE);
 642                 if(!spot)
 643                 {
 644                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 645                         return; // spawn failed
 646                 }
 647
 648                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 649
 650                 self.classname = "player";
 651                 self.iscreature = TRUE;
 652                 self.movetype = MOVETYPE_WALK;
 653                 self.solid = SOLID_SLIDEBOX;
 654                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 655                 if(independent_players)
 656                         MAKE_INDEPENDENT_PLAYER(self);
 657                 self.flags = FL_CLIENT;
 658                 self.takedamage = DAMAGE_AIM;
 659                 if(g_minstagib)
 660                         self.effects = EF_FULLBRIGHT;
 661                 else
 662                         self.effects = 0;
 663                 self.air_finished = time + 12;
 664                 self.dmg = 2;
 665
 666                 if(inWarmupStage)
 667                 {
 668                         self.ammo_shells = warmup_start_ammo_shells;
 669                         self.ammo_nails = warmup_start_ammo_nails;
 670                         self.ammo_rockets = warmup_start_ammo_rockets;
 671                         self.ammo_cells = warmup_start_ammo_cells;
 672                         self.health = warmup_start_health;
 673                         self.armorvalue = warmup_start_armorvalue;
 674                         self.weapons = warmup_start_weapons;
 675                 }
 676                 else
 677                 {
 678                         self.ammo_shells = start_ammo_shells;
 679                         self.ammo_nails = start_ammo_nails;
 680                         self.ammo_rockets = start_ammo_rockets;
 681                         self.ammo_cells = start_ammo_cells;
 682                         self.health = start_health;
 683                         self.armorvalue = start_armorvalue;
 684                         self.weapons = start_weapons;
 685                 }
 686                 self.items = start_items;
 687                 self.switchweapon = w_getbestweapon(self);
 688                 self.cnt = self.switchweapon;
 689                 self.weapon = 0;
 690                 self.jump_interval = time;
 691
 692                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 693                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 694                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 695                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 696                 //extend the pause of rotting if client was reset at the beginning of the countdown
 697                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 698                         self.spawnshieldtime += game_starttime - time;
 699                         self.pauserotarmor_finished += game_starttime - time;
 700                         self.pauserothealth_finished += game_starttime - time;
 701                         self.pauseregen_finished += game_starttime - time;
 702                 }
 703                 self.damageforcescale = 2;
 704                 self.death_time = 0;
 705                 self.dead_frame = 0;
 706                 self.alpha = 0;
 707                 self.scale = 0;
 708                 self.fade_time = 0;
 709                 self.pain_frame = 0;
 710                 self.pain_finished = 0;
 711                 self.strength_finished = 0;
 712                 self.invincible_finished = 0;
 713                 self.pushltime = 0;
 714                 //self.speed_finished = 0;
 715                 //self.slowmo_finished = 0;
 716                 // players have no think function
 717                 self.think = SUB_Null;
 718                 self.nextthink = 0;
 719                 self.hook_time = 0;
 720
 721                 self.runes = 0;
 722
 723                 self.deadflag = DEAD_NO;
 724
 725                 self.angles = spot.angles;
 726
 727                 self.angles_z = 0; // never spawn tilted even if the spot says to
 728                 self.fixangle = TRUE; // turn this way immediately
 729                 self.velocity = '0 0 0';
 730                 self.avelocity = '0 0 0';
 731                 self.punchangle = '0 0 0';
 732                 self.punchvector = '0 0 0';
 733                 self.oldvelocity = self.velocity;
 734
 735                 msg_entity = self;
 736                 WRITESPECTATABLE_MSG_ONE({
 737                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 738                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 739                 });
 740
 741                 self.customizeentityforclient = Client_customizeentityforclient;
 742
 743                 self.model = "";
 744                 FixPlayermodel();
 745
 746                 self.crouch = FALSE;
 747                 self.view_ofs = PL_VIEW_OFS;
 748                 setsize (self, PL_MIN, PL_MAX);
 749                 self.spawnorigin = spot.origin;
 750                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 751                 // don't reset back to last position, even if new position is stuck in solid
 752                 self.oldorigin = self.origin;
 753
 754                 if(g_arena)
 755                 {
 756                         Spawnqueue_Remove(self);
 757                         Spawnqueue_Mark(self);
 758                 }
 759
 760                 self.event_damage = PlayerDamage;
 761
 762                 self.bot_attack = TRUE;
 763
 764                 self.statdraintime = time + 5;
 765                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 766
 767                 if(self.killcount == -666) {
 768                         PlayerScore_Clear(self);
 769                         self.killcount = 0;
 770                         self.frags = 0;
 771                 }
 772
 773                 self.cnt = WEP_LASER;
 774                 self.nixnex_lastchange_id = -1;
 775
 776                 CL_SpawnWeaponentity();
 777                 self.alpha = default_player_alpha;
 778                 self.colormod = '1 1 1' * cvar("g_player_brightness");
 779                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 780
 781                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 782                 self.lms_traveled_distance = 0;
 783                 self.speedrunning = FALSE;
 784
 785                 race_PostSpawn(spot);
 786
 787                 if(cvar("spawn_debug"))
 788                 {
 789                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 790                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 791                 }
 792
 793                 //stuffcmd(self, "chase_active 0");
 794                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 795
 796                 if (cvar("g_spawnsound"))
 797                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 798
 799                 if(g_assault) {
 800                         if(self.team == assault_attacker_team)
 801                                 centerprint(self, "You are attacking!\n");
 802                         else
 803                                 centerprint(self, "You are defending!\n");
 804                 }
 805
 806                 target_voicescript_clear(self);
 807
 808                 oldself = self;
 809                 self = spot;
 810                         activator = oldself;
 811                                 SUB_UseTargets();
 812                         activator = world;
 813                 self = oldself;
 814
 815         } else if(self.classname == "observer") {
 816                 PutObserverInServer ();
 817         }
 818
 819         //if(g_ctf)
 820         //      ctf_playerchanged();
 821 }
 822
 823 /*
 824 =============
 825 SendCSQCInfo
 826
 827 Send whatever CSQC needs NOW and cannot wait for SendServerInfo to happen...
 828 =============
 829 */
 830 void SendCSQCInfo(void)
 831 {
 832         float i;
 833         if(clienttype(self) != CLIENTTYPE_REAL)
 834                 return;
 835         msg_entity = self;
 836         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 837         WriteByte(MSG_ONE, TE_CSQC_INIT);
 838         WriteShort(MSG_ONE, CSQC_REVISION);
 839         WriteByte(MSG_ONE, maxclients);
 840         for(i = 1; i <= 24; ++i)
 841                 WriteByte(MSG_ONE, (get_weaponinfo(i)).impulse + 1);
 842         WriteCoord(MSG_ONE, hook_shotorigin_x);
 843         WriteCoord(MSG_ONE, hook_shotorigin_y);
 844         WriteCoord(MSG_ONE, hook_shotorigin_z);
 845 }
 846
 847 /*
 848 =============
 849 SetNewParms
 850 =============
 851 */
 852 void SetNewParms (void)
 853 {
 854         // initialize parms for a new player
 855         parm1 = -(86400 * 366);
 856 }
 857
 858 /*
 859 =============
 860 SetChangeParms
 861 =============
 862 */
 863 void SetChangeParms (void)
 864 {
 865         // save parms for level change
 866         parm1 = self.parm_idlesince - time;
 867 }
 868
 869 /*
 870 =============
 871 DecodeLevelParms
 872 =============
 873 */
 874 void DecodeLevelParms (void)
 875 {
 876         // load parms
 877         self.parm_idlesince = parm1;
 878         if(self.parm_idlesince == -(86400 * 366))
 879                 self.parm_idlesince = time;
 880
 881         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 882         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 883 }
 884
 885 /*
 886 =============
 887 ClientKill
 888
 889 Called when a client types 'kill' in the console
 890 =============
 891 */
 892
 893 void ClientKill_Now_TeamChange()
 894 {
 895         if(self.killindicator_teamchange == -1)
 896         {
 897                 self.team = -1;
 898                 JoinBestTeam( self, FALSE, FALSE );
 899         }
 900         else
 901         {
 902                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 903         }
 904 }
 905
 906 void ClientKill_Now()
 907 {
 908         if(self.killindicator_teamchange)
 909                 ClientKill_Now_TeamChange();
 910
 911         // in any case:
 912         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 913
 914         if(self.killindicator)
 915         {
 916                 dprint("Cleaned up after a leaked kill indicator.\n");
 917                 remove(self.killindicator);
 918                 self.killindicator = world;
 919         }
 920 }
 921 void KillIndicator_Think()
 922 {
 923         if (!self.owner.modelindex)
 924         {
 925                 self.owner.killindicator = world;
 926                 remove(self);
 927                 return;
 928         }
 929
 930         if(self.cnt <= 0)
 931         {
 932                 self = self.owner;
 933                 ClientKill_Now(); // no oldself needed
 934                 return;
 935         }
 936         else
 937         {
 938                 if(self.cnt <= 10)
 939                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 940                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
 941                 {
 942                         if(self.cnt <= 10)
 943                                 announce(self.owner, strcat("announcer/robotic/", ftos(self.cnt), ".wav"));
 944                         if(self.owner.killindicator_teamchange)
 945                         {
 946                                 if(self.owner.killindicator_teamchange == -1)
 947                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
 948                                 else
 949                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
 950                         }
 951                         else
 952                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
 953                 }
 954                 self.nextthink = time + 1;
 955                 self.cnt -= 1;
 956         }
 957 }
 958
 959 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
 960 {
 961         float killtime;
 962         entity e;
 963         killtime = cvar("g_balance_kill_delay");
 964
 965         self.killindicator_teamchange = targetteam;
 966
 967         if(!self.killindicator)
 968         {
 969                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
 970                 {
 971                         ClientKill_Now();
 972                 }
 973                 else
 974                 {
 975                         self.killindicator = spawn();
 976                         self.killindicator.owner = self;
 977                         self.killindicator.scale = 0.5;
 978                         setattachment(self.killindicator, self, "");
 979                         setorigin(self.killindicator, '0 0 52');
 980                         self.killindicator.think = KillIndicator_Think;
 981                         self.killindicator.nextthink = time + (self.lip) * 0.05;
 982                         self.killindicator.cnt = ceil(killtime);
 983                         self.killindicator.count = bound(0, ceil(killtime), 10);
 984                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 985
 986                         for(e = world; (e = find(e, classname, "body")) != world; )
 987                         {
 988                                 if(e.enemy != self)
 989                                         continue;
 990                                 e.killindicator = spawn();
 991                                 e.killindicator.owner = e;
 992                                 e.killindicator.scale = 0.5;
 993                                 setattachment(e.killindicator, e, "");
 994                                 setorigin(e.killindicator, '0 0 52');
 995                                 e.killindicator.think = KillIndicator_Think;
 996                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
 997                                 e.killindicator.cnt = ceil(killtime);
 998                         }
 999                         self.lip = 0;
1000                 }
1001         }
1002         if(self.killindicator)
1003         {
1004                 if(targetteam)
1005                         self.killindicator.colormod = TeamColor(targetteam);
1006                 else
1007                         self.killindicator.colormod = '0 0 0';
1008         }
1009 }
1010
1011 void ClientKill (void)
1012 {
1013         ClientKill_TeamChange(0);
1014 }
1015
1016 void DoTeamChange(float destteam)
1017 {
1018         float t, c0;
1019         if(!cvar("teamplay"))
1020         {
1021                 if(destteam >= 0)
1022                         SetPlayerColors(self, destteam);
1023                 return;
1024         }
1025         if(self.classname == "player")
1026         if(destteam == -1)
1027         {
1028                 CheckAllowedTeams(self);
1029                 t = FindSmallestTeam(self, TRUE);
1030                 switch(self.team)
1031                 {
1032                         case COLOR_TEAM1: c0 = c1; break;
1033                         case COLOR_TEAM2: c0 = c2; break;
1034                         case COLOR_TEAM3: c0 = c3; break;
1035                         case COLOR_TEAM4: c0 = c4; break;
1036                         default:          c0 = 999;
1037                 }
1038                 switch(t)
1039                 {
1040                         case 1:
1041                                 if(c0 > c1)
1042                                         destteam = COLOR_TEAM1;
1043                                 break;
1044                         case 2:
1045                                 if(c0 > c2)
1046                                         destteam = COLOR_TEAM2;
1047                                 break;
1048                         case 3:
1049                                 if(c0 > c3)
1050                                         destteam = COLOR_TEAM3;
1051                                 break;
1052                         case 4:
1053                                 if(c0 > c4)
1054                                         destteam = COLOR_TEAM4;
1055                                 break;
1056                 }
1057                 if(destteam == -1)
1058                         return;
1059         }
1060         if(destteam == self.team && !self.killindicator)
1061                 return;
1062         ClientKill_TeamChange(destteam);
1063 }
1064
1065 void FixClientCvars(entity e)
1066 {
1067         // send prediction settings to the client
1068         stuffcmd(e, "\nin_bindmap 0 0\n");
1069         /*
1070          * we no longer need to stuff this. Remove this comment block if you feel
1071          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1072         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1073         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1074         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1075         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1076         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1077         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1078         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1079         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1080         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1081         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1082         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1083         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1084         stuffcmd(e, "cl_movement_edgefriction 1\n");
1085          */
1086 }
1087
1088 .float fog_set;
1089 void SendFog()
1090 {
1091         if(clienttype(self) == CLIENTTYPE_REAL)
1092         if(world.fog) // NOT string_null!
1093         {
1094                 if(!self.fog_set)
1095                 {
1096                         if(sv_foginterval)
1097                         {
1098                                 msg_entity = self;
1099                                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1100                                 WriteByte(MSG_ONE, TE_CSQC_FOG);
1101                                 WriteCoord(MSG_ONE, sv_foginterval);
1102                                 WriteString(MSG_ONE, world.fog);
1103                         }
1104                         else
1105                                 // set it once
1106                                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1107
1108                         self.fog_set = 1;
1109                 }
1110         }
1111 }
1112
1113 /*
1114 =============
1115 ClientConnect
1116
1117 Called when a client connects to the server
1118 =============
1119 */
1120 //void ctf_clientconnect();
1121 string ColoredTeamName(float t);
1122 void DecodeLevelParms (void);
1123 //void dom_player_join_team(entity pl);
1124 void ClientConnect (void)
1125 {
1126         local string s;
1127
1128         if(self.flags & FL_CLIENT)
1129         {
1130                 print("Warning: ClientConnect, but already connected!\n");
1131                 return;
1132         }
1133
1134         if(Ban_MaybeEnforceBan(self))
1135                 return;
1136
1137         DecodeLevelParms();
1138
1139         self.classname = "player_joining";
1140
1141         self.flags = self.flags | FL_CLIENT;
1142         self.version_nagtime = time + 10 + random() * 10;
1143
1144         if(player_count<0)
1145         {
1146                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1147                 player_count = 0;
1148         }
1149
1150         PlayerScore_Attach(self);
1151
1152         bot_clientconnect();
1153
1154         race_PreSpawnObserver();
1155
1156         //if(g_domination)
1157         //      dom_player_join_team(self);
1158
1159         //JoinBestTeam(self, FALSE, FALSE);
1160         //
1161         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1162                 self.classname = "observer";
1163         } else {
1164                 self.classname = "player";
1165                 campaign_bots_may_start = 1;
1166         }
1167
1168         self.playerid = (playerid_last = playerid_last + 1);
1169         if(cvar("sv_eventlog"))
1170         {
1171                 if(clienttype(self) == CLIENTTYPE_REAL)
1172                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", self.netaddress, ":", self.netname));
1173                 else
1174                         GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":bot:", self.netname));
1175                 s = strcat(":team:", ftos(self.playerid), ":");
1176                 s = strcat(s, ftos(self.team));
1177                 GameLogEcho(s);
1178         }
1179         self.netname_previous = strzone(self.netname);
1180
1181         //stuffcmd(self, "set tmpviewsize $viewsize \n");
1182
1183         bprint ("^4",self.netname);
1184         bprint ("^4 connected");
1185
1186         if(g_domination || g_ctf)
1187         {
1188                 bprint(" and joined the ");
1189                 bprint(ColoredTeamName(self.team));
1190         }
1191
1192         bprint("\n");
1193
1194         self.welcomemessage_time = 0;
1195
1196         stuffcmd(self, strcat(clientstuff, "\n"));
1197         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1198         stuffcmd(self, "cl_particles_reloadeffects\n");
1199
1200         FixClientCvars(self);
1201
1202         // spawnfunc_waypoint sprites
1203         WaypointSprite_InitClient(self);
1204
1205         // Wazat's grappling hook
1206         SetGrappleHookBindings();
1207
1208         // get autoswitch state from player when he toggles it
1209         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1210
1211         // get version info from player
1212         stuffcmd(self, "cmd clientversion $gameversion\n");
1213
1214         // get other cvars from player
1215         GetCvars(0);
1216
1217         // set cvar for team scoreboard
1218         if (teams_matter)
1219         {
1220                 local float t;
1221                 t = cvar("teamplay");
1222                 // we have to stuff the correct teamplay value because if this is a listen server, this changes the teamplay mode of the server itself, which is bad
1223                 stuffcmd(self, strcat("set teamplay ", ftos(t), "\n"));
1224         }
1225         else
1226                 stuffcmd(self, "set teamplay 0\n");
1227
1228         // notify about available teams
1229         if(teamplay)
1230         {
1231                 CheckAllowedTeams(self);
1232                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1233                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1234         }
1235         else
1236                 stuffcmd(self, "set _teams_available 0\n");
1237
1238         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1239
1240         if(g_arena)
1241         {
1242                 self.classname = "observer";
1243                 Spawnqueue_Insert(self);
1244         }
1245         /*else if(g_ctf)
1246         {
1247                 ctf_clientconnect();
1248         }*/
1249
1250         if(teams_matter)
1251                 attach_entcs();
1252
1253         bot_relinkplayerlist();
1254
1255         self.spectatortime = time;
1256         if(blockSpectators)
1257         {
1258                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1259         }
1260
1261         self.jointime = time;
1262         self.allowedTimeouts = cvar("sv_timeout_number");
1263
1264         if(clienttype(self) == CLIENTTYPE_REAL)
1265         {
1266                 sprint(self, strcat("nexuiz-csqc protocol ", ftos(CSQC_REVISION), "\n"));
1267                 SendCSQCInfo();
1268                 msg_entity = self;
1269                 if(mapvote_initialized && !cvar("g_maplist_textonly"))
1270                 {
1271                         MapVote_SendData(MSG_ONE);
1272                         MapVote_UpdateData(MSG_ONE);
1273                 }
1274                 ScoreInfo_Write(MSG_ONE);
1275
1276                 if(inWarmupStage)
1277                 {
1278                         msg_entity = self;
1279                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1280                         WriteByte(MSG_ONE, TE_CSQC_WARMUP);
1281                         WriteByte(MSG_ONE, 1);
1282                 }
1283
1284                 if(cvar("g_bugrigs"))
1285                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1286         }
1287
1288         if(g_lms)
1289         {
1290                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1291                 {
1292                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1293                         self.frags = -666; // FIXME do we still need this?
1294                 }
1295         }
1296
1297         SendFog();
1298 }
1299
1300 /*
1301 =============
1302 ClientDisconnect
1303
1304 Called when a client disconnects from the server
1305 =============
1306 */
1307 .entity chatbubbleentity;
1308 .entity teambubbleentity;
1309 void ReadyCount();
1310 void ClientDisconnect (void)
1311 {
1312         if not(self.flags & FL_CLIENT)
1313         {
1314                 print("Warning: ClientDisconnect without ClientConnect\n");
1315                 return;
1316         }
1317
1318         bot_clientdisconnect();
1319
1320         if(teams_matter)
1321                 detach_entcs();
1322
1323         if(cvar("sv_eventlog"))
1324                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1325         bprint ("^4",self.netname);
1326         bprint ("^4 disconnected\n");
1327
1328         DropAllRunes(self);
1329         kh_Key_DropAll(self, TRUE);
1330
1331         Portal_ClearAll(self);
1332
1333         if(self.flagcarried)
1334                 DropFlag(self.flagcarried, world, world);
1335
1336         // Here, everything has been done that requires this player to be a client.
1337
1338         self.flags &~= FL_CLIENT;
1339
1340         if (self.chatbubbleentity)
1341                 remove (self.chatbubbleentity);
1342
1343         if (self.teambubbleentity)
1344                 remove (self.teambubbleentity);
1345
1346         if (self.killindicator)
1347                 remove (self.killindicator);
1348
1349         WaypointSprite_PlayerGone();
1350
1351         bot_relinkplayerlist();
1352
1353         // remove laserdot
1354         if(self.weaponentity)
1355                 if(self.weaponentity.lasertarget)
1356                         remove(self.weaponentity.lasertarget);
1357
1358         if(g_arena)
1359         {
1360                 Spawnqueue_Unmark(self);
1361                 Spawnqueue_Remove(self);
1362         }
1363
1364         PlayerScore_Detach(self);
1365
1366         if(self.netname_previous)
1367                 strunzone(self.netname_previous);
1368
1369         ClearPlayerSounds();
1370
1371         self.playerid = 0;
1372         ReadyCount();
1373
1374         // free cvars
1375         GetCvars(-1);
1376 }
1377
1378 .float BUTTON_CHAT;
1379 void ChatBubbleThink()
1380 {
1381         self.nextthink = time;
1382         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1383         {
1384                 if(self.owner) // but why can that ever be world?
1385                         self.owner.chatbubbleentity = world;
1386                 remove(self);
1387                 return;
1388         }
1389         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
1390         if (self.owner.BUTTON_CHAT && !self.owner.deadflag)
1391                 self.model = self.mdl;
1392         else
1393                 self.model = "";
1394 };
1395
1396 void UpdateChatBubble()
1397 {
1398         if (!self.modelindex)
1399                 return;
1400         // spawn a chatbubble entity if needed
1401         if (!self.chatbubbleentity)
1402         {
1403                 self.chatbubbleentity = spawn();
1404                 self.chatbubbleentity.owner = self;
1405                 self.chatbubbleentity.exteriormodeltoclient = self;
1406                 self.chatbubbleentity.think = ChatBubbleThink;
1407                 self.chatbubbleentity.nextthink = time;
1408                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1409                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1410                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1411                 self.chatbubbleentity.model = "";
1412                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1413         }
1414 }
1415
1416
1417 void TeamBubbleThink()
1418 {
1419         self.nextthink = time;
1420         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1421         {
1422                 if(self.owner) // but why can that ever be world?
1423                         self.owner.teambubbleentity = world;
1424                 remove(self);
1425                 return;
1426         }
1427 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1428         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1429                 self.model = "";
1430         else
1431                 self.model = self.mdl;
1432
1433 };
1434
1435 float TeamBubble_customizeentityforclient()
1436 {
1437         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1438 }
1439
1440 void UpdateTeamBubble()
1441 {
1442         if (!self.modelindex || !cvar("teamplay"))
1443                 return;
1444         // spawn a teambubble entity if needed
1445         if (!self.teambubbleentity && cvar("teamplay"))
1446         {
1447                 self.teambubbleentity = spawn();
1448                 self.teambubbleentity.owner = self;
1449                 self.teambubbleentity.exteriormodeltoclient = self;
1450                 self.teambubbleentity.think = TeamBubbleThink;
1451                 self.teambubbleentity.nextthink = time;
1452                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1453 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1454                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
1455                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1456                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1457                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1458                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1459                 self.teambubbleentity.effects = EF_LOWPRECISION;
1460         }
1461 }
1462
1463 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1464 // added to the model skins
1465 /*void UpdateColorModHack()
1466 {
1467         local float c;
1468         c = self.clientcolors & 15;
1469         // LordHavoc: only bothering to support white, green, red, yellow, blue
1470              if (teamplay == 0) self.colormod = '0 0 0';
1471         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1472         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1473         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1474         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1475         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1476         else self.colormod = '1 1 1';
1477 };*/
1478
1479 void respawn(void)
1480 {
1481         CopyBody(1);
1482         self.effects |= EF_NODRAW; // prevent another CopyBody
1483         PutClientInServer();
1484 }
1485
1486 /**
1487  * When sv_timeout is used this function returs strings like
1488  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1489  * Called by centerprint functions
1490  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1491  */
1492 string getTimeoutText(float addOneSecond) {
1493         if (!cvar("sv_timeout") || !timeoutStatus)
1494                 return "";
1495
1496         local string retStr;
1497         if (timeoutStatus == 1) {
1498                 if (addOneSecond == 1) {
1499                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1500                 }
1501                 else {
1502                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1503                 }
1504                 return retStr;
1505         }
1506         else if (timeoutStatus == 2) {
1507                 if (addOneSecond) {
1508                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1509                         //don't show messages like "Timeout ends in 0 seconds"...
1510                         if ((remainingTimeoutTime + 1) > 0)
1511                                 return retStr;
1512                         else
1513                                 return "";
1514                 }
1515                 else {
1516                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1517                         //don't show messages like "Timeout ends in 0 seconds"...
1518                         if (remainingTimeoutTime > 0)
1519                                 return retStr;
1520                         else
1521                                 return "";
1522                 }
1523         }
1524         else return "";
1525 }
1526
1527 void player_powerups (void)
1528 {
1529         if (g_minstagib)
1530         {
1531                 if (self.items & IT_STRENGTH)
1532                 {
1533                         if (time > self.strength_finished)
1534                         {
1535                                 if (g_minstagib_invis_alpha > 0)
1536                                 {
1537                                         self.alpha = default_player_alpha;
1538                                         self.exteriorweaponentity.alpha = default_weapon_alpha;
1539                                         self.effects = self.effects | EF_FULLBRIGHT;
1540                                 }
1541                                 else
1542                                 {
1543                                         self.effects -= self.effects & EF_NODRAW;
1544                                 }
1545                                 self.items = self.items - (self.items & IT_STRENGTH);
1546                                 sprint(self, "^3Invisibility has worn off\n");
1547                         }
1548                 }
1549                 else
1550                 {
1551                         if (time < self.strength_finished)
1552                         {
1553                                 if (g_minstagib_invis_alpha > 0)
1554                                 {
1555                                         self.alpha = g_minstagib_invis_alpha;
1556                                         self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1557                                         self.effects -= self.effects & EF_FULLBRIGHT;
1558                                 }
1559                                 else
1560                                 {
1561                                         self.effects = self.effects | EF_NODRAW;
1562                                 }
1563                                 self.items = self.items | IT_STRENGTH;
1564                                 sprint(self, "^3You are invisible\n");
1565                         }
1566                 }
1567
1568                 if (self.items & IT_INVINCIBLE)
1569                 {
1570                         if (time > self.invincible_finished)
1571                         {
1572                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1573                                 sprint(self, "^3Speed has worn off\n");
1574                         }
1575                 }
1576                 else
1577                 {
1578                         if (time < self.invincible_finished)
1579                         {
1580                                 self.items = self.items | IT_INVINCIBLE;
1581                                 sprint(self, "^3You are on speed\n");
1582                         }
1583                 }
1584                 return;
1585         }
1586
1587         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1588         if (self.items & IT_STRENGTH)
1589         {
1590                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1591                 if (time > self.strength_finished)
1592                 {
1593                         self.items = self.items - (self.items & IT_STRENGTH);
1594                         sprint(self, "^3Strength has worn off\n");
1595                 }
1596         }
1597         else
1598         {
1599                 if (time < self.strength_finished)
1600                 {
1601                         self.items = self.items | IT_STRENGTH;
1602                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1603                 }
1604         }
1605         if (self.items & IT_INVINCIBLE)
1606         {
1607                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1608                 if (time > self.invincible_finished)
1609                 {
1610                         self.items = self.items - (self.items & IT_INVINCIBLE);
1611                         sprint(self, "^3Shield has worn off\n");
1612                 }
1613         }
1614         else
1615         {
1616                 if (time < self.invincible_finished)
1617                 {
1618                         self.items = self.items | IT_INVINCIBLE;
1619                         sprint(self, "^3Shield surrounds you\n");
1620                 }
1621         }
1622
1623         if (cvar("g_fullbrightplayers"))
1624                 self.effects = self.effects | EF_FULLBRIGHT;
1625
1626         // midair gamemode: damage only while in the air
1627         // if in midair mode, being on ground grants temporary invulnerability
1628         // (this is so that multishot weapon don't clear the ground flag on the
1629         // first damage in the frame, leaving the player vulnerable to the
1630         // remaining hits in the same frame)
1631         if (self.flags & FL_ONGROUND)
1632         if (g_midair)
1633                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1634
1635         if (time >= game_starttime)
1636         if (time < self.spawnshieldtime)
1637                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1638 }
1639
1640 float CalcRegen(float current, float stable, float regenfactor)
1641 {
1642         if(current > stable)
1643                 return current;
1644         else if(current > stable - 0.25) // when close enough, "snap"
1645                 return stable;
1646         else
1647                 return min(stable, current + (stable - current) * regenfactor * frametime);
1648 }
1649
1650 void player_regen (void)
1651 {
1652         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1653         maxh = cvar("g_balance_health_stable");
1654         maxa = cvar("g_balance_armor_stable");
1655         limith = cvar("g_balance_health_limit");
1656         limita = cvar("g_balance_armor_limit");
1657
1658         if (g_minstagib || (g_lms && !cvar("g_lms_regenerate")))
1659                 return;
1660
1661         max_mod = regen_mod = rot_mod = limit_mod = 1;
1662
1663         if (self.runes & RUNE_REGEN)
1664         {
1665                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1666                 {
1667                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1668                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1669                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1670                 }
1671                 else
1672                 {
1673                         regen_mod = cvar("g_balance_rune_regen_regenrate");
1674                         max_mod = cvar("g_balance_rune_regen_hpmod");
1675                         limit_mod = cvar("g_balance_rune_regen_limitmod");
1676                 }
1677         }
1678         else if (self.runes & CURSE_VENOM)
1679         {
1680                 max_mod = cvar("g_balance_curse_venom_hpmod");
1681                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1682                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1683                 else
1684                         rot_mod = cvar("g_balance_curse_venom_rotrate");
1685                 limit_mod = cvar("g_balance_curse_venom_limitmod");
1686                 //if (!self.runes & RUNE_REGEN)
1687                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1688         }
1689         maxh = maxh * max_mod;
1690         //maxa = maxa * max_mod;
1691         limith = limith * limit_mod;
1692         limita = limita * limit_mod;
1693
1694         if (self.armorvalue > maxa)
1695         {
1696                 if (time > self.pauserotarmor_finished)
1697                 {
1698                         self.armorvalue = max(maxa, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime);
1699                         self.armorvalue = max(maxa, self.armorvalue - cvar("g_balance_armor_rotlinear") * frametime);
1700                 }
1701         }
1702         else if (self.armorvalue < maxa)
1703         {
1704                 if (time > self.pauseregen_finished)
1705                 {
1706                         self.armorvalue = CalcRegen(self.armorvalue, maxa, cvar("g_balance_armor_regen"));
1707                         self.armorvalue = min(maxa, self.armorvalue + cvar("g_balance_armor_regenlinear") * frametime);
1708                 }
1709         }
1710         if (self.health > maxh)
1711         {
1712                 if (time > self.pauserothealth_finished)
1713                 {
1714                         self.health = max(maxh, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime);
1715                         self.health = max(maxh, self.health - rot_mod*cvar("g_balance_health_rotlinear") * frametime);
1716                 }
1717         }
1718         else if (self.health < maxh)
1719         {
1720                 if (time > self.pauseregen_finished)
1721                 {
1722                         self.health = CalcRegen(self.health, maxh, regen_mod * cvar("g_balance_health_regen"));
1723                         self.health = min(maxh, self.health + regen_mod*cvar("g_balance_health_regenlinear") * frametime);
1724                 }
1725         }
1726
1727         if (self.health > limith)
1728                 self.health = limith;
1729         if (self.armorvalue > limita)
1730                 self.armorvalue = limita;
1731
1732         // if player rotted to death...  die!
1733         if(self.health < 1)
1734                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1735 }
1736
1737 .float zoomstate;
1738 float zoomstate_set;
1739 void SetZoomState(float z)
1740 {
1741         if(z != self.zoomstate)
1742         {
1743                 msg_entity = self;
1744                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
1745                 WriteByte(MSG_ONE, TE_CSQC_ZOOMNOTIFY);
1746                 WriteByte(MSG_ONE, z);
1747                 self.zoomstate = z;
1748         }
1749         zoomstate_set = 1;
1750 }
1751
1752 /*
1753 ======================
1754 spectate mode routines
1755 ======================
1756 */
1757 void SpectateCopy(entity spectatee) {
1758         self.armortype = spectatee.armortype;
1759         self.armorvalue = spectatee.armorvalue;
1760         self.currentammo = spectatee.currentammo;
1761         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1762         self.health = spectatee.health;
1763         self.impulse = 0;
1764         self.items = spectatee.items;
1765         self.weapons = spectatee.weapons;
1766         self.switchweapon = spectatee.switchweapon;
1767         self.weapon = spectatee.weapon;
1768         self.punchangle = spectatee.punchangle;
1769         self.view_ofs = spectatee.view_ofs;
1770         self.v_angle = spectatee.v_angle;
1771         self.velocity = spectatee.velocity;
1772         self.dmg_take = spectatee.dmg_take;
1773         self.dmg_save = spectatee.dmg_save;
1774         self.dmg_inflictor = spectatee.dmg_inflictor;
1775         self.angles = spectatee.v_angle;
1776         self.fixangle = TRUE;
1777         setorigin(self, spectatee.origin);
1778         setsize(self, spectatee.mins, spectatee.maxs);
1779         SetZoomState(spectatee.zoomstate);
1780 }
1781
1782 float SpectateUpdate() {
1783         if(!self.enemy)
1784                 return 0;
1785
1786         if (self == self.enemy)
1787                 return 0;
1788
1789         if(self.enemy.flags & FL_NOTARGET)
1790                 return 0;
1791
1792         SpectateCopy(self.enemy);
1793
1794         return 1;
1795 }
1796
1797 float SpectateNext() {
1798         other = find(self.enemy, classname, "player");
1799         if (!other) {
1800                 other = find(other, classname, "player");
1801         }
1802         if (other) {
1803                 self.enemy = other;
1804         }
1805         if(self.enemy.classname == "player") {
1806                 msg_entity = self;
1807                 WriteByte(MSG_ONE, SVC_SETVIEW);
1808                 WriteEntity(MSG_ONE, self.enemy);
1809                 self.wantswelcomemessage = 1;
1810                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1811                 if(!SpectateUpdate())
1812                         PutObserverInServer();
1813                 return 1;
1814         } else {
1815                 return 0;
1816         }
1817 }
1818
1819 /*
1820 =============
1821 ShowRespawnCountdown()
1822
1823 Update a respawn countdown display.
1824 =============
1825 */
1826 void ShowRespawnCountdown()
1827 {
1828         float number;
1829         if(self.deadflag == DEAD_NO) // just respawned?
1830                 return;
1831         else
1832         {
1833                 number = ceil(self.death_time - time);
1834                 if(number <= 0)
1835                         return;
1836                 if(number <= self.respawn_countdown)
1837                 {
1838                         self.respawn_countdown = number - 1;
1839                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1840                                 announce(self, strcat("announcer/robotic/", ftos(number), ".wav"));
1841                 }
1842         }
1843 }
1844
1845 void LeaveSpectatorMode()
1846 {
1847         if(isJoinAllowed()) {
1848                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1849                         self.classname = "player";
1850                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1851                                 JoinBestTeam(self, FALSE, TRUE);
1852                         if(cvar("g_campaign"))
1853                                 campaign_bots_may_start = 1;
1854                         PutClientInServer();
1855                         if(!(self.flags & FL_NOTARGET))
1856                                 bprint ("^4", self.netname, "^4 is playing now\n");
1857                         centerprint(self,"");
1858                         return;
1859                 } else {
1860                         stuffcmd(self,"menu_showteamselect\n");
1861                         return;
1862                 }
1863         }
1864         else {
1865                 //player may not join because of g_maxplayers is set
1866                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
1867         }
1868 }
1869
1870 /**
1871  * Determines whether the player is allowed to join. This depends on cvar
1872  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1873  * it checks whether the number of currently playing players exceeds g_maxplayers.
1874  * @return bool TRUE if the player is allowed to join, false otherwise
1875  */
1876 float isJoinAllowed() {
1877         if (!cvar("g_maxplayers"))
1878                 return TRUE;
1879
1880         local entity e;
1881         local float currentlyPlaying;
1882         FOR_EACH_REALPLAYER(e) {
1883                 if(e.classname == "player")
1884                         currentlyPlaying += 1;
1885         }
1886         if(currentlyPlaying < cvar("g_maxplayers"))
1887                 return TRUE;
1888
1889         return FALSE;
1890 }
1891
1892 /**
1893  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1894  * g_maxplayers_spectator_blocktime seconds
1895  */
1896 void checkSpectatorBlock() {
1897         if(self.classname == "spectator" || self.classname == "observer") {
1898                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
1899                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
1900                         dropclient(self);
1901                 }
1902         }
1903 }
1904
1905 float vercmp_recursive(string v1, string v2)
1906 {
1907         float dot1, dot2;
1908         string s1, s2;
1909         float r;
1910
1911         dot1 = strstrofs(v1, ".", 0);
1912         dot2 = strstrofs(v2, ".", 0);
1913         if(dot1 == -1)
1914                 s1 = v1;
1915         else
1916                 s1 = substring(v1, 0, dot1);
1917         if(dot2 == -1)
1918                 s2 = v2;
1919         else
1920                 s2 = substring(v2, 0, dot2);
1921
1922         r = stof(s1) - stof(s2);
1923         if(r != 0)
1924                 return r;
1925
1926         r = strcasecmp(s1, s2);
1927         if(r != 0)
1928                 return r;
1929
1930         if(dot1 == -1)
1931                 if(dot2 == -1)
1932                         return 0;
1933                 else
1934                         return -1;
1935         else
1936                 if(dot2 == -1)
1937                         return 1;
1938                 else
1939                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
1940 }
1941
1942 float vercmp(string v1, string v2)
1943 {
1944         if(strcasecmp(v1, v2) == 0) // early out check
1945                 return 0;
1946         return vercmp_recursive(v1, v2);
1947 }
1948
1949 void ObserverThink()
1950 {
1951         if (self.flags & FL_JUMPRELEASED) {
1952                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1953                         self.welcomemessage_time = 0;
1954                         self.flags = self.flags - FL_JUMPRELEASED;
1955                         LeaveSpectatorMode();
1956                         return;
1957                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
1958                         self.welcomemessage_time = 0;
1959                         self.flags = self.flags - FL_JUMPRELEASED;
1960                         if(SpectateNext() == 1) {
1961                                 self.classname = "spectator";
1962                         }
1963                 }
1964         } else {
1965                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
1966                         self.flags = self.flags | FL_JUMPRELEASED;
1967                 }
1968         }
1969         if(self.BUTTON_ZOOM)
1970                 self.wantswelcomemessage = 0;
1971         if(self.wantswelcomemessage)
1972                 PrintWelcomeMessage(self);
1973 }
1974
1975 void SpectatorThink()
1976 {
1977         if (self.flags & FL_JUMPRELEASED) {
1978                 if (self.BUTTON_JUMP && !self.version_mismatch) {
1979                         self.welcomemessage_time = 0;
1980                         self.flags = self.flags - FL_JUMPRELEASED;
1981                         LeaveSpectatorMode();
1982                         return;
1983                 } else if(self.BUTTON_ATCK) {
1984                         self.welcomemessage_time = 0;
1985                         self.flags = self.flags - FL_JUMPRELEASED;
1986                         if(SpectateNext() == 1) {
1987                                 self.classname = "spectator";
1988                         } else {
1989                                 self.classname = "observer";
1990                                 PutClientInServer();
1991                         }
1992                 } else if (self.BUTTON_ATCK2) {
1993                         self.welcomemessage_time = 0;
1994                         self.flags = self.flags - FL_JUMPRELEASED;
1995                         self.classname = "observer";
1996                         PutClientInServer();
1997                 } else {
1998                         if(!SpectateUpdate())
1999                                 PutObserverInServer();
2000                 }
2001         } else {
2002                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2003                         self.flags = self.flags | FL_JUMPRELEASED;
2004                 }
2005         }
2006         if(self.BUTTON_ZOOM)
2007                 self.wantswelcomemessage = 0;
2008         if(self.wantswelcomemessage)
2009                 PrintWelcomeMessage(self);
2010         self.flags = self.flags | FL_CLIENT | FL_NOTARGET;
2011 }
2012
2013 .float touchexplode_time;
2014
2015 /*
2016 =============
2017 PlayerPreThink
2018
2019 Called every frame for each client before the physics are run
2020 =============
2021 */
2022 void() ctf_setstatus;
2023 .float spectatee_status;
2024 void PlayerPreThink (void)
2025 {
2026         self.stat_sys_ticrate = cvar("sys_ticrate");
2027         self.stat_game_starttime = game_starttime;
2028
2029         if(blockSpectators)
2030                 checkSpectatorBlock();
2031
2032         zoomstate_set = 0;
2033
2034         if(self.netname_previous != self.netname)
2035         {
2036                 if(cvar("sv_eventlog"))
2037                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2038                 if(self.netname_previous)
2039                         strunzone(self.netname_previous);
2040                 self.netname_previous = strzone(self.netname);
2041         }
2042
2043         // version nagging
2044         if(self.version_nagtime)
2045                 if(self.cvar_g_nexuizversion)
2046                         if(time > self.version_nagtime)
2047                         {
2048                                 if(strstr(self.cvar_g_nexuizversion, "svn", 0) < 0)
2049                                 {
2050                                         if(strstr(cvar_string("g_nexuizversion"), "svn", 0) >= 0)
2051                                         {
2052                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2053                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), " (beta)^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2054                                         }
2055                                         else
2056                                         {
2057                                                 float r;
2058                                                 r = vercmp(self.cvar_g_nexuizversion, cvar_string("g_nexuizversion"));
2059                                                 if(r < 0)
2060                                                 {
2061                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n");
2062                                                         sprint(self, strcat("\{1}^1NOTE: ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7 is out, and you still have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1 - get the update from ^4http://www.nexuiz.com/^1!\n"));
2063                                                 }
2064                                                 else if(r > 0)
2065                                                 {
2066                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n");
2067                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Nexuiz ", cvar_string("g_nexuizversion"), "^7, you have ^3Nexuiz ", self.cvar_g_nexuizversion, "^1\n"));
2068                                                 }
2069                                         }
2070                                 }
2071                                 self.version_nagtime = 0;
2072                         }
2073
2074         // GOD MODE info
2075         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2076         {
2077                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2078                 self.max_armorvalue = 0;
2079         }
2080
2081         if(frametime)
2082         {
2083                 SendFog();
2084                 antilag_record(self);
2085         }
2086
2087         if(self.classname == "player") {
2088 //              if(self.netname == "Wazat")
2089 //                      bprint(self.classname, "\n");
2090
2091                 CheckRules_Player();
2092
2093                 if(self.BUTTON_INFO)
2094                         PrintWelcomeMessage(self);
2095
2096                 if(g_lms || !cvar("sv_spectate"))
2097                 if((time - self.jointime) <= cvar("welcome_message_time"))
2098                         PrintWelcomeMessage(self);
2099
2100                 if (intermission_running)
2101                 {
2102                         IntermissionThink ();   // otherwise a button could be missed between
2103                         return;                                 // the think tics
2104                 }
2105
2106                 if(self.teleport_time)
2107                 if(time > self.teleport_time)
2108                 {
2109                         self.teleport_time = 0;
2110                         self.effects = self.effects - (self.effects & EF_NODRAW);
2111                         if(self.weaponentity)
2112                                 self.weaponentity.flags = self.weaponentity.flags - (self.weaponentity.flags & EF_NODRAW);
2113                 }
2114
2115                 Nixnex_GiveCurrentWeapon();
2116
2117                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2118                         UpdateSelectedPlayer();
2119
2120                 //don't allow the player to turn around while game is paused!
2121                 if(timeoutStatus == 2) {
2122                         self.v_angle = self.lastV_angle;
2123                         self.angles = self.lastV_angle;
2124                         self.fixangle = TRUE;
2125                 }
2126
2127                 if (self.deadflag != DEAD_NO)
2128                 {
2129                         float button_pressed, force_respawn;
2130                         player_anim();
2131                         button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2132                         force_respawn = (g_lms || cvar("g_forced_respawn"));
2133                         if (self.deadflag == DEAD_DYING)
2134                         {
2135                                 if(force_respawn)
2136                                         self.deadflag = DEAD_RESPAWNING;
2137                                 else if(!button_pressed)
2138                                         self.deadflag = DEAD_DEAD;
2139                         }
2140                         else if (self.deadflag == DEAD_DEAD)
2141                         {
2142                                 if(button_pressed)
2143                                         self.deadflag = DEAD_RESPAWNABLE;
2144                         }
2145                         else if (self.deadflag == DEAD_RESPAWNABLE)
2146                         {
2147                                 if(!button_pressed)
2148                                         self.deadflag = DEAD_RESPAWNING;
2149                         }
2150                         else if (self.deadflag == DEAD_RESPAWNING)
2151                         {
2152                                 if(time > self.death_time)
2153                                 {
2154                                         self.death_time = time + 1; // only retry once a second
2155                                         respawn();
2156                                 }
2157                         }
2158                         ShowRespawnCountdown();
2159                         return;
2160                 }
2161
2162                 if(g_touchexplode)
2163                 if(time > self.touchexplode_time)
2164                 if(self.classname == "player")
2165                 if(self.deadflag == DEAD_NO)
2166                 if not(IS_INDEPENDENT_PLAYER(self))
2167                 FOR_EACH_PLAYER(other) if(self != other)
2168                 {
2169                         if(time > other.touchexplode_time)
2170                         if(other.classname == "player")
2171                         if(other.deadflag == DEAD_NO)
2172                         if not(IS_INDEPENDENT_PLAYER(other))
2173                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2174                         {
2175                                 PlayerTouchExplode(self, other);
2176                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2177                         }
2178                 }
2179
2180                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2181                 {
2182                         vector dist;
2183
2184                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2185                         dist = self.oldorigin - self.origin;
2186                         dist_z = 0;
2187                         self.lms_traveled_distance += fabs(vlen(dist));
2188
2189                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2190                         {
2191                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2192                                 self.lms_traveled_distance = 0;
2193                         }
2194
2195                         if(time > self.lms_nextcheck)
2196                         {
2197                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2198                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2199                                 {
2200                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2201                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2202                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2203                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2204                                 }
2205                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2206                                 self.lms_traveled_distance = 0;
2207                         }
2208                 }
2209
2210                 self.oldorigin = self.origin;
2211
2212                 if (self.BUTTON_CROUCH && !self.hook.state)
2213                 {
2214                         if (!self.crouch)
2215                         {
2216                                 self.crouch = TRUE;
2217                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2218                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2219                                 player_setanim(self.anim_duck, FALSE, TRUE, TRUE);
2220                         }
2221                 }
2222                 else
2223                 {
2224                         if (self.crouch)
2225                         {
2226                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2227                                 if (!trace_startsolid)
2228                                 {
2229                                         self.crouch = FALSE;
2230                                         self.view_ofs = PL_VIEW_OFS;
2231                                         setsize (self, PL_MIN, PL_MAX);
2232                                 }
2233                         }
2234                 }
2235
2236                 FixPlayermodel();
2237
2238                 GrapplingHookFrame();
2239
2240                 W_WeaponFrame();
2241
2242                 player_powerups();
2243                 player_regen();
2244                 player_anim();
2245
2246                 if (g_minstagib)
2247                         minstagib_ammocheck();
2248
2249                 ctf_setstatus();
2250                 kh_setstatus();
2251
2252                 //self.angles_y=self.v_angle_y + 90;   // temp
2253
2254                 //if (TetrisPreFrame()) return;
2255         } else if(gameover) {
2256                 if (intermission_running)
2257                         IntermissionThink ();   // otherwise a button could be missed between
2258                 return;
2259         } else if(self.classname == "observer") {
2260                 ObserverThink();
2261         } else if(self.classname == "spectator") {
2262                 SpectatorThink();
2263         }
2264
2265         if(!zoomstate_set)
2266                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX));
2267
2268         float oldspectatee_status;
2269         oldspectatee_status = self.spectatee_status;
2270         if(self.classname == "spectator")
2271                 self.spectatee_status = num_for_edict(self.enemy);
2272         else if(self.classname == "observer")
2273                 self.spectatee_status = num_for_edict(self);
2274         else
2275                 self.spectatee_status = 0;
2276         if(self.spectatee_status != oldspectatee_status)
2277         {
2278                 msg_entity = self;
2279                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
2280                 WriteByte(MSG_ONE, TE_CSQC_SPECTATING);
2281                 WriteByte(MSG_ONE, self.spectatee_status);
2282                 if(g_race)
2283                         race_InitSpectator();
2284         }
2285
2286         if(self.teamkill_soundtime)
2287         if(time > self.teamkill_soundtime)
2288         {
2289                 self.teamkill_soundtime = 0;
2290
2291                 entity oldpusher, oldself;
2292
2293                 oldself = self; self = self.teamkill_soundsource;
2294                 oldpusher = self.pusher; self.pusher = oldself;
2295
2296                 VoiceMessage("teamshoot_auto");
2297
2298                 self.pusher = oldpusher;
2299                 self = oldself;
2300         }
2301
2302         target_voicescript_next(self);
2303 }
2304
2305
2306 /*
2307 =============
2308 PlayerPostThink
2309
2310 Called every frame for each client after the physics are run
2311 =============
2312 */
2313 .float idlekick_lasttimeleft;
2314 .float race_penalty;
2315 .float race_penalty_nagged;
2316 .float race_penalty_nagtime;
2317 void PlayerPostThink (void)
2318 {
2319         // Savage: Check for nameless players
2320         if (strlen(self.netname) < 1) {
2321                 self.netname = "Player";
2322                 stuffcmd(self, "seta _cl_name Player\n");
2323         }
2324
2325         if(sv_maxidle)
2326         {
2327                 float timeleft;
2328                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2329                 if(timeleft <= 0)
2330                 {
2331                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2332                         announce(self, "announcer/robotic/terminated.wav");
2333                         dropclient(self);
2334                         return;
2335                 }
2336                 else if(timeleft <= 10)
2337                 {
2338                         if(timeleft != self.idlekick_lasttimeleft)
2339                         {
2340                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2341                                 announce(self, strcat("announcer/robotic/", ftos(timeleft), ".wav"));
2342                         }
2343                 }
2344                 else
2345                 {
2346                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2347                 }
2348                 self.idlekick_lasttimeleft = timeleft;
2349         }
2350
2351         if(self.classname == "player") {
2352                 CheckRules_Player();
2353                 UpdateChatBubble();
2354                 UpdateTeamBubble();
2355                 if (self.impulse)
2356                         ImpulseCommands();
2357                 if (intermission_running)
2358                         return;         // intermission or finale
2359
2360                 //PrintWelcomeMessage(self);
2361                 //if (TetrisPostFrame()) return;
2362
2363                 // restart countdown
2364                         if(time < game_starttime) {
2365                                 if (!cvar("sv_ready_restart_after_countdown"))
2366                                 {
2367                                         if(self.movement != '0 0 0' && g_race && !g_race_qualifying)
2368                                         {
2369                                                 if(time < game_starttime - 2)
2370                                                 {
2371                                                         if(!self.race_penalty_nagged)
2372                                                         {
2373                                                                 // TODO better notification for this!
2374                                                                 self.race_penalty_nagtime = 0;
2375                                                                 self.race_penalty_nagged = 1;
2376                                                         }
2377                                                 }
2378                                                 else if(!self.race_penalty)
2379                                                 {
2380                                                         self.race_penalty_nagtime = 0;
2381                                                         self.race_penalty = time + 5;
2382                                                 }
2383                                         }
2384                                         if(time > self.race_penalty_nagtime)
2385                                         {
2386                                                 if(self.race_penalty > time)
2387                                                 {
2388                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1FIVE SECONDS PENALTY.");
2389                                                 }
2390                                                 else if(self.race_penalty_nagged && time < game_starttime - 2)
2391                                                 {
2392                                                         centerprint_atprio(self, CENTERPRIO_IDLEKICK, "^1DO NOT MOVE DURING THE COUNTDOWN.");
2393                                                 }
2394                                                 self.race_penalty_nagtime = time + self.cvar_scr_centertime * 0.6;
2395                                         }
2396                                         self.movetype = MOVETYPE_NONE;
2397                                         self.velocity = '0 0 0';
2398                                         self.avelocity = '0 0 0';
2399                                         self.movement = '0 0 0';
2400                                 }
2401                         }
2402                         else if (time < self.race_penalty)
2403                         {
2404                                 self.movetype = MOVETYPE_NONE;
2405                                 self.velocity = '0 0 0';
2406                                 self.avelocity = '0 0 0';
2407                                 self.movement = '0 0 0';
2408                         }
2409                         else
2410                         {
2411                                 //allow the player to move again if sv_ready_restart_after_countdown is not used and countdown is over
2412                                 if (!cvar("sv_ready_restart_after_countdown"))
2413                                 {
2414                                         if(self.movetype == MOVETYPE_NONE)
2415                                         {
2416                                                 self.movetype = MOVETYPE_WALK;
2417                                         }
2418                                         self.race_penalty = 0;
2419                                         self.race_penalty_nagged = 0;
2420                                 }
2421                         }
2422
2423         } else if (self.classname == "observer") {
2424                 //do nothing
2425         } else if (self.classname == "spectator") {
2426                 //do nothing
2427         }
2428
2429         /*
2430         float i;
2431         for(i = 0; i < 1000; ++i)
2432         {
2433                 vector end;
2434                 end = self.origin + '0 0 1024' + 512 * randomvec();
2435                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2436                 if(trace_fraction < 1)
2437                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2438                 {
2439                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2440                         break;
2441                 }
2442         }
2443         */
2444
2445         Arena_Warmup();
2446
2447         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2448 }