data/qcsrc/common/mapinfo.qc

   1         // internal toy
   2 void cvar_settemp(string pKey, string pValue)
   3 {
   4         //localcmd(strcat("\nsettemp ", t, " \"", s, "\"\n"));
   5
   6         // duplicate what this alias does:
   7         // alias settemp "settemp_list \"1 $1 $settemp_var $settemp_list\"; set $settemp_var \"${$1}\"; settemp_var ${settemp_var}x; $1 \"$2\""
   8
   9         cvar_set("settemp_list", strcat("1 ", pKey, " ", cvar_string("settemp_var"), " ", cvar_string("settemp_list")));
  10 #ifdef MENUQC
  11         registercvar(cvar_string("settemp_var"), "", 0);
  12 #else
  13         registercvar(cvar_string("settemp_var"), "");
  14 #endif
  15         cvar_set(cvar_string("settemp_var"), cvar_string(pKey));
  16         cvar_set("settemp_var", strcat(cvar_string("settemp_var"), "x"));
  17         cvar_set(pKey, pValue);
  18 }
  19
  20 void cvar_settemp_restore()
  21 {
  22         // undo what cvar_settemp did
  23         float n, i;
  24         n = tokenize(cvar_string("settemp_list"));
  25         for(i = 0; i < n - 3; i += 3)
  26                 cvar_set(argv(i + 1), cvar_string(argv(i + 2)));
  27         cvar_set("settemp_list", "0");
  28 }
  29
  30 #ifdef HSOI
  31 // HUGE SET - stored in a string
  32 string HugeSetOfIntegers_empty()
  33 {
  34         return "";
  35 }
  36 float HugeSetOfIntegers_get(string pArr, float i)
  37 {
  38         return stof(substring(pArr, i * 4, 4));
  39 }
  40 float HugeSetOfIntegers_length(string pArr)
  41 {
  42         return strlen(pArr) / 4;
  43 }
  44 string HugeSetOfIntegers_concat(string a1, string a2)
  45 {
  46         return strcat(a1, a2);
  47 }
  48 string HugeSetOfIntegers_insert(string a1, float n, string a2)
  49         // special concat function to build up large lists in less time by binary concatenation
  50 {
  51         string s;
  52         s = strcat("    ", ftos(n));
  53         return strcat(a1, substring(s, strlen(s) - 4, 4), a2);
  54 }
  55 #endif
  56
  57 // generic string stuff
  58 float startsWith(string haystack, string needle)
  59 {
  60         return substring(haystack, 0, strlen(needle)) == needle;
  61 }
  62 float startsWithNocase(string haystack, string needle)
  63 {
  64         return strcasecmp(substring(haystack, 0, strlen(needle)), needle) == 0;
  65 }
  66 string extractRestOfLine(string haystack, string needle)
  67 {
  68         if(startsWith(haystack, needle))
  69                 return substring(haystack, strlen(needle), strlen(haystack) - strlen(needle));
  70         return string_null;
  71 }
  72 string car(string s)
  73 {
  74         float o;
  75         o = strstrofs(s, " ", 0);
  76         if(o < 0)
  77                 return s;
  78         return substring(s, 0, o);
  79 }
  80 string cdr(string s)
  81 {
  82         float o;
  83         o = strstrofs(s, " ", 0);
  84         if(o < 0)
  85                 return string_null;
  86         return substring(s, o + 1, strlen(s) - (o + 1));
  87 }
  88
  89 float _MapInfo_Cache_Active;
  90 float _MapInfo_Cache_DB_NameToIndex;
  91 float _MapInfo_Cache_Buf_IndexToMapData;
  92
  93 void MapInfo_Cache_Destroy()
  94 {
  95         if(!_MapInfo_Cache_Active)
  96                 return;
  97
  98         db_close(_MapInfo_Cache_DB_NameToIndex);
  99         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
 100         _MapInfo_Cache_Active = 0;
 101 }
 102
 103 void MapInfo_Cache_Create()
 104 {
 105         MapInfo_Cache_Destroy();
 106         _MapInfo_Cache_DB_NameToIndex = db_create();
 107         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
 108         _MapInfo_Cache_Active = 1;
 109 }
 110
 111 void MapInfo_Cache_Invalidate()
 112 {
 113         if(!_MapInfo_Cache_Active)
 114                 return;
 115
 116         MapInfo_Cache_Create();
 117 }
 118
 119 void MapInfo_Cache_Store()
 120 {
 121         float i;
 122         string s;
 123         if(!_MapInfo_Cache_Active)
 124                 return;
 125
 126         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
 127         if(!s) // empty string is NOT valid here!
 128         {
 129                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
 130                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
 131         }
 132         else
 133                 i = stof(s);
 134
 135         // now store all the stuff
 136         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, i++, MapInfo_Map_bspname);
 137         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, i++, MapInfo_Map_title);
 138         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, i++, MapInfo_Map_description);
 139         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, i++, MapInfo_Map_author);
 140         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, i++, ftos(MapInfo_Map_supportedGametypes));
 141         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, i++, ftos(MapInfo_Map_supportedFeatures));
 142 }
 143
 144 float MapInfo_Cache_Retrieve(string map)
 145 {
 146         float i;
 147         string s;
 148         if(!_MapInfo_Cache_Active)
 149                 return 0;
 150
 151         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
 152         if(!s)
 153                 return 0;
 154         i = stof(s);
 155
 156         // now retrieve all the stuff
 157         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i++);
 158         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i++);
 159         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i++);
 160         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i++);
 161         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i++));
 162         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i++));
 163         return 1;
 164 }
 165
 166 // GLOB HANDLING (for all BSP files)
 167 float _MapInfo_globopen;
 168 float _MapInfo_globcount;
 169 float _MapInfo_globhandle;
 170 string _MapInfo_GlobItem(float i)
 171 {
 172         string s;
 173         s = search_getfilename(_MapInfo_globhandle, i);
 174         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
 175 }
 176
 177 void MapInfo_Enumerate()
 178 {
 179         if(_MapInfo_globopen)
 180                 search_end(_MapInfo_globhandle);
 181         MapInfo_Cache_Invalidate();
 182         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
 183         _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 184         _MapInfo_globopen = 1;
 185 }
 186
 187 // filter the info by game type mask (updates MapInfo_count)
 188 //
 189 #ifdef HSOI
 190 string _MapInfo_filtered;
 191 float MapInfo_FilterList_Lookup(float i)
 192 {
 193         return MapInfo_FilterList_Lookup(i);
 194 }
 195
 196 string MapInfo_FilterGametype_Recursive(float pGametype, float pFeatures, float pBegin, float pEnd, float pAbortOnGenerate)
 197 {
 198         float m, valid;
 199         string l, r;
 200
 201         if(pBegin == pEnd)
 202                 return HugeSetOfIntegers_empty();
 203
 204         m = floor((pBegin + pEnd) / 2);
 205
 206         l = MapInfo_FilterGametype_Recursive(pGametype, pFeatures, pBegin, m, pAbortOnGenerate);
 207         if not(l)
 208                 return string_null; // BAIL OUT
 209         if(MapInfo_Get_ByName(_MapInfo_GlobItem(m), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 210                 if(pAbortOnGenerate)
 211                 {
 212                         MapInfo_progress = m / _MapInfo_globcount;
 213                         return string_null; // BAIL OUT
 214                 }
 215         valid = (((MapInfo_Map_supportedGametypes & pGametype) != 0) && ((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures));
 216         r = MapInfo_FilterGametype_Recursive(pGametype, pFeatures, m + 1, pEnd, pAbortOnGenerate);
 217         if not(r)
 218                 return string_null; // BAIL OUT
 219
 220         if(valid)
 221                 return HugeSetOfIntegers_insert(l, m, r);
 222         else
 223                 return HugeSetOfIntegers_concat(l, r);
 224 }
 225
 226 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pAbortOnGenerate)
 227 {
 228         if(_MapInfo_filtered)
 229                 strunzone(_MapInfo_filtered);
 230         _MapInfo_filtered = MapInfo_FilterGametype_Recursive(pGametype, pFeatures, 0, _MapInfo_globcount, pAbortOnGenerate);
 231         if not(_MapInfo_filtered)
 232         {
 233                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 234                 return 0;
 235         }
 236         _MapInfo_filtered = strzone(_MapInfo_filtered);
 237         MapInfo_count = HugeSetOfIntegers_length(_MapInfo_filtered);
 238         MapInfo_ClearTemps();
 239         return 1;
 240 }
 241 #else
 242 float _MapInfo_filtered;
 243 float _MapInfo_filtered_allocated;
 244 float MapInfo_FilterList_Lookup(float i)
 245 {
 246         return stof(bufstr_get(_MapInfo_filtered, i));
 247 }
 248
 249 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pAbortOnGenerate)
 250 {
 251         float i, j;
 252         if not(_MapInfo_filtered_allocated)
 253         {
 254                 _MapInfo_filtered_allocated = 1;
 255                 _MapInfo_filtered = buf_create();
 256         }
 257         MapInfo_count = 0;
 258         for(i = 0, j = 0; i < _MapInfo_globcount; ++i)
 259         {
 260                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 261                         if(pAbortOnGenerate)
 262                         {
 263                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 264                                 MapInfo_progress = i / _MapInfo_globcount;
 265                                 return 0;
 266                         }
 267                 if(((MapInfo_Map_supportedGametypes & pGametype) != 0) && ((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures))
 268                         bufstr_set(_MapInfo_filtered, j++, ftos(i));
 269         }
 270         MapInfo_count = j;
 271         MapInfo_ClearTemps();
 272         return 1;
 273 }
 274 #endif
 275
 276 // load info about the i-th map into the MapInfo_Map_* globals
 277 string MapInfo_BSPName_ByID(float i)
 278 {
 279         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 280 }
 281
 282 string unquote(string s)
 283 {
 284         float i, j, l;
 285         l = strlen(s);
 286         j = -1;
 287         for(i = 0; i < l; ++i)
 288         {
 289                 string ch;
 290                 ch = substring(s, i, 1);
 291                 if(ch != " ") if(ch != "\"")
 292                 {
 293                         for(j = strlen(s) - i - 1; j > 0; --j)
 294                         {
 295                                 ch = substring(s, i+j, 1);
 296                                 if(ch != " ") if(ch != "\"")
 297                                         return substring(s, i, j+1);
 298                         }
 299                         return substring(s, i, 1);
 300                 }
 301         }
 302         return "";
 303 }
 304
 305 float MapInfo_Get_ByID(float i)
 306 {
 307         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 308                 return 1;
 309         return 0;
 310 }
 311
 312 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 313 {
 314         string fn;
 315         float fh;
 316         string s, k, v;
 317         vector o;
 318         float i;
 319         float inWorldspawn;
 320         float r;
 321         float twoBaseModes;
 322         float diameter, spawnpoints;
 323
 324         vector mapMins, mapMaxs;
 325
 326         r = 1;
 327         fn = strcat("maps/", pFilename, ".ent");
 328         fh = fopen(fn, FILE_READ);
 329         if(fh < 0)
 330         {
 331                 r = 2;
 332                 fn = strcat("maps/", pFilename, ".bsp");
 333                 fh = fopen(fn, FILE_READ);
 334         }
 335         if(fh < 0)
 336                 return 0;
 337         print("Analyzing ", fn, " to generate initial mapinfo; please edit that file later\n");
 338
 339         inWorldspawn = 2;
 340         MapInfo_Map_supportedGametypes = 0;
 341         spawnpoints = 0;
 342
 343         for(;;)
 344         {
 345                 if not((s = fgets(fh)))
 346                         break;
 347                 if(inWorldspawn == 1)
 348                         if(startsWith(s, "}"))
 349                                 inWorldspawn = 0;
 350                 k = unquote(car(s));
 351                 v = unquote(cdr(s));
 352                 if(inWorldspawn)
 353                 {
 354                         if(k == "classname" && v == "worldspawn")
 355                                 inWorldspawn = 1;
 356                         else if(k == "author")
 357                                 MapInfo_Map_author = v;
 358                         else if(k == "_description")
 359                                 MapInfo_Map_description = v;
 360                         else if(k == "message")
 361                         {
 362                                 i = strstrofs(v, " by ", 0);
 363                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 364                                 {
 365                                         MapInfo_Map_title = substring(v, 0, i);
 366                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 367                                 }
 368                                 else
 369                                         MapInfo_Map_title = v;
 370                         }
 371                 }
 372                 else
 373                 {
 374                         if(k == "origin")
 375                         {
 376                                 o = stov(strcat("'", v, "'"));
 377                                 mapMins_x = min(mapMins_x, o_x);
 378                                 mapMins_y = min(mapMins_y, o_y);
 379                                 mapMins_z = min(mapMins_z, o_z);
 380                                 mapMaxs_x = max(mapMaxs_x, o_x);
 381                                 mapMaxs_y = max(mapMaxs_y, o_y);
 382                                 mapMaxs_z = max(mapMaxs_z, o_z);
 383                         }
 384                         else if(k == "classname")
 385                         {
 386                                 if(v == "dom_controlpoint")
 387                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 388                                 else if(v == "item_flag_team2")
 389                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 390                                 else if(v == "team_CTF_blueflag")
 391                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 392                                 else if(v == "runematch_spawn_point")
 393                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;
 394                                 else if(v == "target_assault_roundend")
 395                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 396                                 else if(v == "onslaught_generator")
 397                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 398                                 else if(v == "info_player_team1")
 399                                         ++spawnpoints;
 400                                 else if(v == "info_player_team2")
 401                                         ++spawnpoints;
 402                                 else if(v == "info_player_start")
 403                                         ++spawnpoints;
 404                                 else if(v == "info_player_deathmatch")
 405                                         ++spawnpoints;
 406                                 else if(v == "weapon_nex")
 407                                         { }
 408                                 else if(v == "weapon_railgun")
 409                                         { }
 410                                 else if(startsWith(v, "weapon_"))
 411                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 412                         }
 413                 }
 414         }
 415         if(inWorldspawn)
 416         {
 417                 print(fn, " ended still in worldspawn, BUG\n");
 418                 return 0;
 419         }
 420         diameter = vlen(mapMaxs - mapMins);
 421
 422         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT);
 423         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 424         {
 425                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 426                 // as the map is too symmetric for them.
 427         }
 428         else
 429         {
 430                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 431                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 432
 433                 if(spawnpoints >= 8  && diameter > 4096)
 434                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 435                 if(                     diameter < 4096)
 436                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ARENA;
 437                 if(spawnpoints >= 12 && diameter > 5120)
 438                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 439         }
 440
 441         dprint("-> diameter ",    ftos(diameter));
 442         dprint(";  spawnpoints ", ftos(spawnpoints));
 443         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 444
 445         fclose(fh);
 446
 447         return r;
 448 }
 449
 450 void _MapInfo_Map_Reset()
 451 {
 452         MapInfo_Map_title = "<TITLE>";
 453         MapInfo_Map_description = "<DESCRIPTION>";
 454         MapInfo_Map_author = "<AUTHOR>";
 455         MapInfo_Map_supportedGametypes = 0;
 456         MapInfo_Map_supportedFeatures = 0;
 457 }
 458
 459 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType)
 460 {
 461         string sa;
 462         MapInfo_Map_supportedGametypes |= pThisType;
 463         if(!(pThisType & pWantedType))
 464                 return;
 465
 466         cvar_set("fraglimit", car(s));
 467         s = cdr(s);
 468
 469         cvar_set("timelimit", car(s));
 470         s = cdr(s);
 471
 472         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 473         {
 474                 sa = car(s); if(sa == "") sa = "2";
 475                 cvar_set("g_tdm_teams", sa);
 476                 s = cdr(s);
 477         }
 478
 479         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 480         {
 481                 sa = car(s); if(sa == "") sa = "3";
 482                 cvar_set("g_keyhunt_teams", sa);
 483                 s = cdr(s);
 484         }
 485
 486         if(pWantedType == MAPINFO_TYPE_CTF)
 487         {
 488                 sa = car(s); if(sa == "") sa = "10";
 489                 cvar_set("capturelimit", sa);
 490                 s = cdr(s);
 491         }
 492 }
 493
 494 float MapInfo_Type_FromString(string t)
 495 {
 496         if     (t == "dm")    return MAPINFO_TYPE_DEATHMATCH;
 497         else if(t == "tdm")   return MAPINFO_TYPE_TEAM_DEATHMATCH;
 498         else if(t == "dom")   return MAPINFO_TYPE_DOMINATION;
 499         else if(t == "ctf")   return MAPINFO_TYPE_CTF;
 500         else if(t == "rune")  return MAPINFO_TYPE_RUNEMATCH;
 501         else if(t == "lms")   return MAPINFO_TYPE_LMS;
 502         else if(t == "arena") return MAPINFO_TYPE_ARENA;
 503         else if(t == "kh")    return MAPINFO_TYPE_KEYHUNT;
 504         else if(t == "as")    return MAPINFO_TYPE_ASSAULT;
 505         else if(t == "ons")   return MAPINFO_TYPE_ONSLAUGHT;
 506         else if(t == "all")   return MAPINFO_TYPE_ALL;
 507         else                  return 0;
 508 }
 509
 510 // load info about a map by name into the MapInfo_Map_* globals
 511 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
 512 {
 513         string fn;
 514         string s, t;
 515         float fh, fh2;
 516         float r, f;
 517
 518         if(pGametypeToSet == 0)
 519                 if(MapInfo_Cache_Retrieve(pFilename))
 520                         return 1;
 521
 522         r = 1;
 523
 524         MapInfo_Map_bspname = pFilename;
 525
 526         // default all generic fields so they have "good" values in case something fails
 527         fn = strcat("maps/", pFilename, ".mapinfo");
 528         fh = fopen(fn, FILE_READ);
 529         if(fh < 0)
 530         {
 531                 if(!pAllowGenerate)
 532                         return 0;
 533                 _MapInfo_Map_Reset();
 534                 r = _MapInfo_Generate(pFilename);
 535                 if(!r)
 536                         return 0;
 537                 fh = fopen(fn, FILE_WRITE);
 538                 fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 539                 fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 540                 fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 541                 if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)       fputs(fh, "has weapons\n");
 542                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)      fputs(fh, "type dm 30 20\n");
 543                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH) fputs(fh, "type tdm 50 20 2\n");
 544                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DOMINATION)      fputs(fh, "type dom 200 20\n");
 545                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_CTF)             fputs(fh, "type ctf 300 20 10\n");
 546                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RUNEMATCH)       fputs(fh, "type rune 200 20\n");
 547                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_LMS)             fputs(fh, "type lms 9 20\n");
 548                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ARENA)           fputs(fh, "type arena 10 20\n");
 549                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_KEYHUNT)         fputs(fh, "type kh 1000 20 3\n");
 550                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ASSAULT)         fputs(fh, "type as 20\n");
 551                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ONSLAUGHT)       fputs(fh, "type ons 20\n");
 552
 553                 fh2 = fopen(strcat("scripts/", pFilename, ".arena"), FILE_READ);
 554                 if(fh2 >= 0)
 555                 {
 556                         fclose(fh2);
 557                         fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 558                 }
 559
 560                 fclose(fh);
 561                 r = 2;
 562                 // return r;
 563                 fh = fopen(fn, FILE_READ);
 564                 if(fh < 0)
 565                         error("... but I just wrote it!");
 566         }
 567
 568         _MapInfo_Map_Reset();
 569         for(;;)
 570         {
 571                 if not((s = fgets(fh)))
 572                         break;
 573
 574                 // catch different sorts of comments
 575                 if(s == "")                    // empty lines
 576                         continue;
 577                 if(substring(s, 0, 1) == "#")  // UNIX style
 578                         continue;
 579                 if(substring(s, 0, 2) == "//") // C++ style
 580                         continue;
 581                 if(substring(s, 0, 1) == "_")  // q3map style
 582                         continue;
 583
 584                 t = car(s); s = cdr(s);
 585                 if(t == "title")
 586                         MapInfo_Map_title = s;
 587                 else if(t == "description")
 588                         MapInfo_Map_description = s;
 589                 else if(t == "author")
 590                         MapInfo_Map_author = s;
 591                 else if(t == "has")
 592                 {
 593                         t = car(s); s = cdr(s);
 594                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 595                         else
 596                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
 597                 }
 598                 else if(t == "type")
 599                 {
 600                         t = car(s); s = cdr(s);
 601                         f = MapInfo_Type_FromString(t);
 602                         if(f)
 603                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f);
 604                         else
 605                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
 606                 }
 607                 else if(t == "settemp_for_type")
 608                 {
 609                         t = car(s); s = cdr(s);
 610                         if((f = MapInfo_Type_FromString(t)))
 611                         {
 612                                 if(f & pGametypeToSet)
 613                                 {
 614                                         t = car(s); s = cdr(s);
 615                                         if(strstrofs(t, "\"", 0) >= 0)
 616                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 617                                         else if(strstrofs(t, "\\", 0) >= 0)
 618                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 619                                         else if(strstrofs(t, ";", 0) >= 0)
 620                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 621                                         else if(strstrofs(s, "\"", 0) >= 0)
 622                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 623                                         else if(strstrofs(s, "\\", 0) >= 0)
 624                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 625                                         else if(strstrofs(s, ";", 0) >= 0)
 626                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 627                                         else
 628                                         {
 629                                                 dprint("Applying temporary setting ", t, " := ", s, "\n");
 630                                                 cvar_settemp(t, s);
 631                                         }
 632                                 }
 633                         }
 634                         else
 635                         {
 636                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
 637                         }
 638                 }
 639                 else
 640                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
 641         }
 642         fclose(fh);
 643         if(pGametypeToSet)
 644                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
 645                         error("Can't select the requested game type. Bailing out.");
 646         MapInfo_Cache_Store();
 647         if(MapInfo_Map_supportedGametypes != 0)
 648                 return r;
 649         dprint("Map ", pFilename, " supports no game types, ignored\n");
 650         return 0;
 651 }
 652
 653 float MapInfo_FindName(string s)
 654 {
 655         // if there is exactly one map of prefix s, return it
 656         // if not, return the null string
 657         // note that DP sorts glob results... so I can use a binary search
 658         float l, r, m, cmp;
 659         l = 0;
 660         r = MapInfo_count;
 661         // invariants: r is behind s, l-1 is equal or before
 662         while(l != r)
 663         {
 664                 m = floor((l + r) / 2);
 665                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
 666                 cmp = strcasecmp(MapInfo_FindName_match, s);
 667                 if(cmp == 0)
 668                         return m; // found and good
 669                 if(cmp < 0)
 670                         l = m + 1; // l-1 is before s
 671                 else
 672                         r = m; // behind s
 673         }
 674         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
 675         MapInfo_FindName_firstResult = l;
 676         // r == l, so: l is behind s, l-1 is before
 677         // SO: if there is any, l is the one with the right prefix
 678         //     and l+1 may be one too
 679         if(l == MapInfo_count)
 680         {
 681                 MapInfo_FindName_match = string_null;
 682                 MapInfo_FindName_firstResult = -1;
 683                 return -1; // no MapInfo_FindName_match, behind last item
 684         }
 685         if(!startsWithNocase(MapInfo_FindName_match, s))
 686         {
 687                 MapInfo_FindName_match = string_null;
 688                 MapInfo_FindName_firstResult = -1;
 689                 return -1; // wrong prefix
 690         }
 691         if(l == MapInfo_count - 1)
 692                 return l; // last one, nothing can follow => unique
 693         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
 694         {
 695                 MapInfo_FindName_match = string_null;
 696                 return -1; // ambigous MapInfo_FindName_match
 697         }
 698         return l;
 699 }
 700
 701 string MapInfo_FixName(string s)
 702 {
 703         MapInfo_FindName(s);
 704         return MapInfo_FindName_match;
 705 }
 706
 707 float MapInfo_CurrentFeatures()
 708 {
 709         float req;
 710         req = 0;
 711         if(!(cvar("g_lms") || cvar("g_instagib") || cvar("g_minstagib") || cvar("g_nixnex") || cvar("g_rocketarena")))
 712                 req |= MAPINFO_FEATURE_WEAPONS;
 713         return req;
 714 }
 715
 716 float MapInfo_CurrentGametype()
 717 {
 718         if(cvar("g_domination"))
 719                 return MAPINFO_TYPE_DOMINATION;
 720         else if(cvar("g_ctf"))
 721                 return MAPINFO_TYPE_CTF;
 722         else if(cvar("g_runematch"))
 723                 return MAPINFO_TYPE_RUNEMATCH;
 724         else if(cvar("g_tdm"))
 725                 return MAPINFO_TYPE_TEAM_DEATHMATCH;
 726         else if(cvar("g_assault"))
 727                 return MAPINFO_TYPE_ASSAULT;
 728         else if(cvar("g_lms"))
 729                 return MAPINFO_TYPE_LMS;
 730         else if(cvar("g_arena"))
 731                 return MAPINFO_TYPE_ARENA;
 732         else if(cvar("g_keyhunt"))
 733                 return MAPINFO_TYPE_KEYHUNT;
 734         else if(cvar("g_onslaught"))
 735                 return MAPINFO_TYPE_ONSLAUGHT;
 736         else
 737                 return MAPINFO_TYPE_DEATHMATCH;
 738 }
 739
 740 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
 741 {
 742         if(!MapInfo_Get_ByName(s, 1, 0))
 743                 return 0;
 744         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
 745                 return 0;
 746         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
 747                 return 0;
 748         return 1;
 749 }
 750
 751 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
 752 {
 753         float r;
 754         r = _MapInfo_CheckMap(s);
 755         MapInfo_ClearTemps();
 756         return r;
 757 }
 758
 759 void MapInfo_SwitchGameType(float t)
 760 {
 761         cvar_set("gamecfg",      "0");
 762         cvar_set("g_dm",         (t == MAPINFO_TYPE_DEATHMATCH)      ? "1" : "0");
 763         cvar_set("g_tdm",        (t == MAPINFO_TYPE_TEAM_DEATHMATCH) ? "1" : "0");
 764         cvar_set("g_domination", (t == MAPINFO_TYPE_DOMINATION)      ? "1" : "0");
 765         cvar_set("g_ctf",        (t == MAPINFO_TYPE_CTF)             ? "1" : "0");
 766         cvar_set("g_runematch",  (t == MAPINFO_TYPE_RUNEMATCH)       ? "1" : "0");
 767         cvar_set("g_lms",        (t == MAPINFO_TYPE_LMS)             ? "1" : "0");
 768         cvar_set("g_arena",      (t == MAPINFO_TYPE_ARENA)           ? "1" : "0");
 769         cvar_set("g_keyhunt",    (t == MAPINFO_TYPE_KEYHUNT)         ? "1" : "0");
 770         cvar_set("g_assault",    (t == MAPINFO_TYPE_ASSAULT)         ? "1" : "0");
 771         cvar_set("g_onslaught",  (t == MAPINFO_TYPE_ONSLAUGHT)       ? "1" : "0");
 772 }
 773
 774 void MapInfo_LoadMap(string s)
 775 {
 776         MapInfo_Map_supportedGametypes = 0;
 777         if(!MapInfo_CheckMap(s))
 778         {
 779                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
 780                 MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
 781         }
 782         localcmd(strcat("\nsettemp_restore\nchangelevel ", s, "\n"));
 783 }
 784
 785 string MapInfo_ListAllowedMaps()
 786 {
 787         string out;
 788         float i;
 789
 790         // to make absolutely sure:
 791         MapInfo_Enumerate();
 792         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0);
 793
 794         out = "";
 795         for(i = 0; i < MapInfo_count; ++i)
 796                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
 797         return substring(out, 1, strlen(out) - 1);
 798 }
 799
 800 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
 801 {
 802         float t;
 803         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
 804         {
 805                 if(MapInfo_Map_supportedGametypes <= 0)
 806                         error("Mapinfo system is not functional at all. BAILED OUT.\n");
 807
 808                 t = 1;
 809                 while(!(MapInfo_Map_supportedGametypes & 1))
 810                 {
 811                         t *= 2;
 812                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
 813                 }
 814                 // t is now a supported mode!
 815                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
 816                 MapInfo_SwitchGameType(t);
 817         }
 818         cvar_settemp_restore();
 819         MapInfo_Get_ByName(s, 1, MapInfo_CurrentGametype());
 820         MapInfo_ClearTemps();
 821 }
 822
 823 void MapInfo_ClearTemps()
 824 {
 825         MapInfo_Map_bspname = string_null;
 826         MapInfo_Map_title = string_null;
 827         MapInfo_Map_description = string_null;
 828         MapInfo_Map_author = string_null;
 829         MapInfo_Map_supportedGametypes = 0;
 830         MapInfo_Map_supportedFeatures = 0;
 831 }