data/qcsrc/common/mapinfo.qc

   1 #ifdef HSOI
   2 // HUGE SET - stored in a string
   3 string HugeSetOfIntegers_empty()
   4 {
   5         return "";
   6 }
   7 float HugeSetOfIntegers_get(string pArr, float i)
   8 {
   9         return stof(substring(pArr, i * 4, 4));
  10 }
  11 float HugeSetOfIntegers_length(string pArr)
  12 {
  13         return strlen(pArr) / 4;
  14 }
  15 string HugeSetOfIntegers_concat(string a1, string a2)
  16 {
  17         return strcat(a1, a2);
  18 }
  19 string HugeSetOfIntegers_insert(string a1, float n, string a2)
  20         // special concat function to build up large lists in less time by binary concatenation
  21 {
  22         string s;
  23         s = strcat("    ", ftos(n));
  24         return strcat(a1, substring(s, strlen(s) - 4, 4), a2);
  25 }
  26 #endif
  27
  28 // generic string stuff
  29 float startsWith(string haystack, string needle)
  30 {
  31         return substring(haystack, 0, strlen(needle)) == needle;
  32 }
  33 float startsWithNocase(string haystack, string needle)
  34 {
  35         return strcasecmp(substring(haystack, 0, strlen(needle)), needle) == 0;
  36 }
  37 string extractRestOfLine(string haystack, string needle)
  38 {
  39         if(startsWith(haystack, needle))
  40                 return substring(haystack, strlen(needle), strlen(haystack) - strlen(needle));
  41         return string_null;
  42 }
  43 string car(string s)
  44 {
  45         float o;
  46         o = strstrofs(s, " ", 0);
  47         if(o < 0)
  48                 return s;
  49         return substring(s, 0, o);
  50 }
  51 string cdr(string s)
  52 {
  53         float o;
  54         o = strstrofs(s, " ", 0);
  55         if(o < 0)
  56                 return string_null;
  57         return substring(s, o + 1, strlen(s) - (o + 1));
  58 }
  59
  60 float _MapInfo_Cache_Active;
  61 float _MapInfo_Cache_DB_NameToIndex;
  62 float _MapInfo_Cache_Buf_IndexToMapData;
  63
  64 void MapInfo_Cache_Destroy()
  65 {
  66         if(!_MapInfo_Cache_Active)
  67                 return;
  68
  69         db_close(_MapInfo_Cache_DB_NameToIndex);
  70         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  71         _MapInfo_Cache_Active = 0;
  72 }
  73
  74 void MapInfo_Cache_Create()
  75 {
  76         MapInfo_Cache_Destroy();
  77         _MapInfo_Cache_DB_NameToIndex = db_create();
  78         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  79         _MapInfo_Cache_Active = 1;
  80 }
  81
  82 void MapInfo_Cache_Invalidate()
  83 {
  84         if(!_MapInfo_Cache_Active)
  85                 return;
  86
  87         MapInfo_Cache_Create();
  88 }
  89
  90 void MapInfo_Cache_Store()
  91 {
  92         float i;
  93         string s;
  94         if(!_MapInfo_Cache_Active)
  95                 return;
  96
  97         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  98         if(!s) // empty string is NOT valid here!
  99         {
 100                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
 101                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
 102         }
 103         else
 104                 i = stof(s);
 105
 106         // now store all the stuff
 107         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
 108         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
 109         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
 110         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
 111         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
 112         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
 113         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
 114 }
 115
 116 float MapInfo_Cache_Retrieve(string map)
 117 {
 118         float i;
 119         string s;
 120         if(!_MapInfo_Cache_Active)
 121                 return 0;
 122
 123         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
 124         if(!s)
 125                 return 0;
 126         i = stof(s);
 127
 128         // now retrieve all the stuff
 129         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
 130         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
 131         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
 132         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
 133         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
 134         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
 135         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
 136         return 1;
 137 }
 138
 139 // GLOB HANDLING (for all BSP files)
 140 float _MapInfo_globopen;
 141 float _MapInfo_globcount;
 142 float _MapInfo_globhandle;
 143 string _MapInfo_GlobItem(float i)
 144 {
 145         string s;
 146         s = search_getfilename(_MapInfo_globhandle, i);
 147         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
 148 }
 149
 150 void MapInfo_Enumerate()
 151 {
 152         if(_MapInfo_globopen)
 153                 search_end(_MapInfo_globhandle);
 154         MapInfo_Cache_Invalidate();
 155         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
 156         _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 157         _MapInfo_globopen = 1;
 158 }
 159
 160 // filter the info by game type mask (updates MapInfo_count)
 161 //
 162 #ifdef HSOI
 163 string _MapInfo_filtered;
 164 float MapInfo_FilterList_Lookup(float i)
 165 {
 166         return MapInfo_FilterList_Lookup(i);
 167 }
 168
 169 string MapInfo_FilterGametype_Recursive(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pBegin, float pEnd, float pAbortOnGenerate)
 170 {
 171         float m, valid;
 172         string l, r;
 173
 174         if(pBegin == pEnd)
 175                 return HugeSetOfIntegers_empty();
 176
 177         m = floor((pBegin + pEnd) / 2);
 178
 179         l = MapInfo_FilterGametype_Recursive(pGametype, pFeatures, pBegin, m, pAbortOnGenerate);
 180         if not(l)
 181                 return string_null; // BAIL OUT
 182         if(MapInfo_Get_ByName(_MapInfo_GlobItem(m), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 183                 if(pAbortOnGenerate)
 184                 {
 185                         MapInfo_progress = m / _MapInfo_globcount;
 186                         return string_null; // BAIL OUT
 187                 }
 188         valid = (((MapInfo_Map_supportedGametypes & pGametype) != 0);
 189         valid = valid && ((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures));
 190         valid = valid && (MapInfo_Map_flags & pFlagsForbidden == 0);
 191         valid = valid && (MapInfo_Map_flags & pFlagsRequired == pFlagsRequired);
 192         r = MapInfo_FilterGametype_Recursive(pGametype, pFeatures, pFlagsRequired, pFlagsForbidden, m + 1, pEnd, pAbortOnGenerate);
 193         if not(r)
 194                 return string_null; // BAIL OUT
 195
 196         if(valid)
 197                 return HugeSetOfIntegers_insert(l, m, r);
 198         else
 199                 return HugeSetOfIntegers_concat(l, r);
 200 }
 201
 202 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate)
 203 {
 204         if(_MapInfo_filtered)
 205                 strunzone(_MapInfo_filtered);
 206         _MapInfo_filtered = MapInfo_FilterGametype_Recursive(pGametype, pFeatures, pFlagsRequired, pFlagsForbidden, 0, _MapInfo_globcount, pAbortOnGenerate);
 207         if not(_MapInfo_filtered)
 208         {
 209                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 210                 return 0;
 211         }
 212         _MapInfo_filtered = strzone(_MapInfo_filtered);
 213         MapInfo_count = HugeSetOfIntegers_length(_MapInfo_filtered);
 214         MapInfo_ClearTemps();
 215         return 1;
 216 }
 217
 218 void MapInfo_Filter_Free()
 219 {
 220         if(_MapInfo_filtered)
 221         {
 222                 strunzone(_MapInfo_filtered);
 223                 _MapInfo_filtered = string_null;
 224         }
 225 }
 226 #else
 227 float _MapInfo_filtered;
 228 float _MapInfo_filtered_allocated;
 229 float MapInfo_FilterList_Lookup(float i)
 230 {
 231         return stof(bufstr_get(_MapInfo_filtered, i));
 232 }
 233
 234 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate)
 235 {
 236         float i, j;
 237         if not(_MapInfo_filtered_allocated)
 238         {
 239                 _MapInfo_filtered_allocated = 1;
 240                 _MapInfo_filtered = buf_create();
 241         }
 242         MapInfo_count = 0;
 243         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 244         {
 245                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 246                         if(pAbortOnGenerate)
 247                         {
 248                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 249                                 MapInfo_progress = i / _MapInfo_globcount;
 250                                 return 0;
 251                         }
 252                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 253                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 254                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 255                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 256                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 257         }
 258         MapInfo_count = j + 1;
 259         MapInfo_ClearTemps();
 260         return 1;
 261 }
 262
 263 void MapInfo_Filter_Free()
 264 {
 265         if(_MapInfo_filtered_allocated)
 266         {
 267                 buf_del(_MapInfo_filtered);
 268                 _MapInfo_filtered_allocated = 0;
 269         }
 270 }
 271 #endif
 272
 273 // load info about the i-th map into the MapInfo_Map_* globals
 274 string MapInfo_BSPName_ByID(float i)
 275 {
 276         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 277 }
 278
 279 string unquote(string s)
 280 {
 281         float i, j, l;
 282         l = strlen(s);
 283         j = -1;
 284         for(i = 0; i < l; ++i)
 285         {
 286                 string ch;
 287                 ch = substring(s, i, 1);
 288                 if(ch != " ") if(ch != "\"")
 289                 {
 290                         for(j = strlen(s) - i - 1; j > 0; --j)
 291                         {
 292                                 ch = substring(s, i+j, 1);
 293                                 if(ch != " ") if(ch != "\"")
 294                                         return substring(s, i, j+1);
 295                         }
 296                         return substring(s, i, 1);
 297                 }
 298         }
 299         return "";
 300 }
 301
 302 float MapInfo_Get_ByID(float i)
 303 {
 304         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 305                 return 1;
 306         return 0;
 307 }
 308
 309 string _MapInfo_Map_worldspawn_music;
 310
 311 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 312 {
 313         string fn;
 314         float fh;
 315         string s, k, v;
 316         vector o;
 317         float i;
 318         float inWorldspawn;
 319         float r;
 320         float twoBaseModes;
 321         float diameter, spawnpoints;
 322
 323         vector mapMins, mapMaxs;
 324
 325         r = 1;
 326         fn = strcat("maps/", pFilename, ".ent");
 327         fh = fopen(fn, FILE_READ);
 328         if(fh < 0)
 329         {
 330                 r = 2;
 331                 fn = strcat("maps/", pFilename, ".bsp");
 332                 fh = fopen(fn, FILE_READ);
 333         }
 334         if(fh < 0)
 335                 return 0;
 336         print("Analyzing ", fn, " to generate initial mapinfo; please edit that file later\n");
 337
 338         inWorldspawn = 2;
 339         MapInfo_Map_supportedGametypes = 0;
 340         spawnpoints = 0;
 341         _MapInfo_Map_worldspawn_music = "";
 342
 343         for(;;)
 344         {
 345                 if not((s = fgets(fh)))
 346                         break;
 347                 if(inWorldspawn == 1)
 348                         if(startsWith(s, "}"))
 349                                 inWorldspawn = 0;
 350                 k = unquote(car(s));
 351                 v = unquote(cdr(s));
 352                 if(inWorldspawn)
 353                 {
 354                         if(k == "classname" && v == "worldspawn")
 355                                 inWorldspawn = 1;
 356                         else if(k == "author")
 357                                 MapInfo_Map_author = v;
 358                         else if(k == "_description")
 359                                 MapInfo_Map_description = v;
 360                         else if(k == "music")
 361                                 _MapInfo_Map_worldspawn_music = v;
 362                         else if(k == "noise")
 363                                 _MapInfo_Map_worldspawn_music = v;
 364                         else if(k == "message")
 365                         {
 366                                 i = strstrofs(v, " by ", 0);
 367                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 368                                 {
 369                                         MapInfo_Map_title = substring(v, 0, i);
 370                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 371                                 }
 372                                 else
 373                                         MapInfo_Map_title = v;
 374                         }
 375                 }
 376                 else
 377                 {
 378                         if(k == "origin")
 379                         {
 380                                 o = stov(strcat("'", v, "'"));
 381                                 mapMins_x = min(mapMins_x, o_x);
 382                                 mapMins_y = min(mapMins_y, o_y);
 383                                 mapMins_z = min(mapMins_z, o_z);
 384                                 mapMaxs_x = max(mapMaxs_x, o_x);
 385                                 mapMaxs_y = max(mapMaxs_y, o_y);
 386                                 mapMaxs_z = max(mapMaxs_z, o_z);
 387                         }
 388                         else if(k == "classname")
 389                         {
 390                                 if(v == "dom_controlpoint")
 391                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 392                                 else if(v == "item_flag_team2")
 393                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 394                                 else if(v == "team_CTF_blueflag")
 395                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 396                                 else if(v == "runematch_spawn_point")
 397                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;
 398                                 else if(v == "target_assault_roundend")
 399                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 400                                 else if(v == "onslaught_generator")
 401                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 402                                 else if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
 403                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_NEXBALL;
 404                                 else if(v == "info_player_team1")
 405                                         ++spawnpoints;
 406                                 else if(v == "info_player_team2")
 407                                         ++spawnpoints;
 408                                 else if(v == "info_player_start")
 409                                         ++spawnpoints;
 410                                 else if(v == "info_player_deathmatch")
 411                                         ++spawnpoints;
 412                                 else if(v == "trigger_race_checkpoint")
 413                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
 414                                 else if(v == "weapon_nex")
 415                                         { }
 416                                 else if(v == "weapon_railgun")
 417                                         { }
 418                                 else if(startsWith(v, "weapon_"))
 419                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 420                         }
 421                 }
 422         }
 423         if(inWorldspawn)
 424         {
 425                 print(fn, " ended still in worldspawn, BUG\n");
 426                 return 0;
 427         }
 428         diameter = vlen(mapMaxs - mapMins);
 429
 430         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE);
 431         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 432         {
 433                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 434                 // as the map is too symmetric for them.
 435         }
 436         else
 437         {
 438                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 439                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;       // Rune always works
 440                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 441
 442                 if(spawnpoints >= 8  && diameter > 4096)
 443                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 444                 if(                     diameter < 4096)
 445                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ARENA;
 446                 if(spawnpoints >= 12 && diameter > 5120)
 447                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 448         }
 449
 450         dprint("-> diameter ",    ftos(diameter));
 451         dprint(";  spawnpoints ", ftos(spawnpoints));
 452         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 453
 454         fclose(fh);
 455
 456         return r;
 457 }
 458
 459 void _MapInfo_Map_Reset()
 460 {
 461         MapInfo_Map_title = "<TITLE>";
 462         MapInfo_Map_description = "<DESCRIPTION>";
 463         MapInfo_Map_author = "<AUTHOR>";
 464         MapInfo_Map_supportedGametypes = 0;
 465         MapInfo_Map_supportedFeatures = 0;
 466         MapInfo_Map_flags = 0;
 467         MapInfo_Map_clientstuff = "";
 468         MapInfo_Map_fog = "";
 469         MapInfo_Map_mins = '0 0 0';
 470         MapInfo_Map_maxs = '0 0 0';
 471 }
 472
 473 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType)
 474 {
 475         string sa;
 476         MapInfo_Map_supportedGametypes |= pThisType;
 477         if(!(pThisType & pWantedType))
 478                 return;
 479
 480         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT) // these modes don't use fraglimit
 481         {
 482                 cvar_set("fraglimit", "0");
 483         }
 484         else
 485         {
 486                 cvar_set("fraglimit", car(s));
 487                 s = cdr(s);
 488         }
 489
 490         cvar_set("timelimit", car(s));
 491         s = cdr(s);
 492
 493         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 494         {
 495                 sa = car(s); if(sa == "") sa = "2";
 496                 cvar_set("g_tdm_teams", sa);
 497                 s = cdr(s);
 498         }
 499
 500         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 501         {
 502                 sa = car(s); if(sa == "") sa = "3";
 503                 cvar_set("g_keyhunt_teams", sa);
 504                 s = cdr(s);
 505         }
 506
 507         if(pWantedType == MAPINFO_TYPE_CTF)
 508         {
 509                 sa = car(s); if(sa == "") sa = "10";
 510                 if(cvar("g_ctf_win_mode") < 2)
 511                         cvar_set("fraglimit", sa);
 512                 s = cdr(s);
 513         }
 514
 515         if(pWantedType == MAPINFO_TYPE_RACE)
 516         {
 517                 sa = car(s); if(sa == "") sa = cvar_string("fraglimit");
 518                 if(cvar("g_race_teams"))
 519                         cvar_set("fraglimit", sa);
 520                 s = cdr(s);
 521         }
 522 }
 523
 524 float MapInfo_Type_FromString(string t)
 525 {
 526         if     (t == "dm")      return MAPINFO_TYPE_DEATHMATCH;
 527         else if(t == "tdm")     return MAPINFO_TYPE_TEAM_DEATHMATCH;
 528         else if(t == "dom")     return MAPINFO_TYPE_DOMINATION;
 529         else if(t == "ctf")     return MAPINFO_TYPE_CTF;
 530         else if(t == "rune")    return MAPINFO_TYPE_RUNEMATCH;
 531         else if(t == "lms")     return MAPINFO_TYPE_LMS;
 532         else if(t == "arena")   return MAPINFO_TYPE_ARENA;
 533         else if(t == "kh")      return MAPINFO_TYPE_KEYHUNT;
 534         else if(t == "as")      return MAPINFO_TYPE_ASSAULT;
 535         else if(t == "ons")     return MAPINFO_TYPE_ONSLAUGHT;
 536         else if(t == "race")    return MAPINFO_TYPE_RACE;
 537         else if(t == "nexball") return MAPINFO_TYPE_NEXBALL;
 538         else if(t == "all")     return MAPINFO_TYPE_ALL;
 539         else                    return 0;
 540 }
 541
 542 // load info about a map by name into the MapInfo_Map_* globals
 543 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
 544 {
 545         string fn;
 546         string s, t;
 547         float fh, fh2;
 548         float r, f, n, i;
 549
 550         if(strstrofs(pFilename, "/", 0) >= 0)
 551         {
 552                 print("Invalid character in map name, ignored\n");
 553                 return 0;
 554         }
 555
 556         if(pGametypeToSet == 0)
 557                 if(MapInfo_Cache_Retrieve(pFilename))
 558                         return 1;
 559
 560         r = 1;
 561
 562         MapInfo_Map_bspname = pFilename;
 563
 564         // default all generic fields so they have "good" values in case something fails
 565         fn = strcat("maps/", pFilename, ".mapinfo");
 566         fh = fopen(fn, FILE_READ);
 567         if(fh < 0)
 568         {
 569                 if(!pAllowGenerate)
 570                         return 0;
 571                 _MapInfo_Map_Reset();
 572                 r = _MapInfo_Generate(pFilename);
 573                 if(!r)
 574                         return 0;
 575                 fh = fopen(fn, FILE_WRITE);
 576                 fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 577                 fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 578                 fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 579                 if(_MapInfo_Map_worldspawn_music != "")
 580                 {
 581                         if(
 582                                 substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 583                                 ||
 584                                 substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 585                         )
 586                                 fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 587                         else
 588                                 fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 589                 }
 590                 else
 591                 {
 592                         n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
 593                         s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
 594                         for(;;)
 595                         {
 596                                 i = floor(random() * n);
 597                                 if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
 598                                         break;
 599                         }
 600                         fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
 601                 }
 602                 if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
 603                         fputs(fh, "has weapons\n");
 604                 else
 605                         fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
 606                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)      fputs(fh, "type dm 30 20\n");
 607                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH) fputs(fh, "type tdm 50 20 2\n");
 608                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DOMINATION)      fputs(fh, "type dom 200 20\n");
 609                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_CTF)             fputs(fh, "type ctf 300 20 10\n");
 610                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RUNEMATCH)       fputs(fh, "type rune 200 20\n");
 611                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_LMS)             fputs(fh, "type lms 9 20\n");
 612                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ARENA)           fputs(fh, "type arena 10 20\n");
 613                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_KEYHUNT)         fputs(fh, "type kh 1000 20 3\n");
 614                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ASSAULT)         fputs(fh, "type as 20\n");
 615                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)            fputs(fh, "type race 5 20 15\n");
 616                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ONSLAUGHT)       fputs(fh, "type ons 20\n");
 617                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_NEXBALL)         fputs(fh, "type nexball 5 20\n");
 618
 619                 fh2 = fopen(strcat("scripts/", pFilename, ".arena"), FILE_READ);
 620                 if(fh2 >= 0)
 621                 {
 622                         fclose(fh2);
 623                         fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 624                 }
 625
 626                 fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 627                 fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 628                 fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 629                 fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 630                 fputs(fh, "// optional: hidden\n");
 631
 632                 fclose(fh);
 633                 r = 2;
 634                 // return r;
 635                 fh = fopen(fn, FILE_READ);
 636                 if(fh < 0)
 637                         error("... but I just wrote it!");
 638         }
 639
 640         _MapInfo_Map_Reset();
 641         for(;;)
 642         {
 643                 if not((s = fgets(fh)))
 644                         break;
 645
 646                 // catch different sorts of comments
 647                 if(s == "")                    // empty lines
 648                         continue;
 649                 if(substring(s, 0, 1) == "#")  // UNIX style
 650                         continue;
 651                 if(substring(s, 0, 2) == "//") // C++ style
 652                         continue;
 653                 if(substring(s, 0, 1) == "_")  // q3map style
 654                         continue;
 655
 656                 t = car(s); s = cdr(s);
 657                 if(t == "title")
 658                         MapInfo_Map_title = s;
 659                 else if(t == "description")
 660                         MapInfo_Map_description = s;
 661                 else if(t == "author")
 662                         MapInfo_Map_author = s;
 663                 else if(t == "has")
 664                 {
 665                         t = car(s); s = cdr(s);
 666                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 667                         else
 668                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
 669                 }
 670                 else if(t == "hidden")
 671                 {
 672                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
 673                 }
 674                 else if(t == "forbidden")
 675                 {
 676                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
 677                 }
 678                 else if(t == "type")
 679                 {
 680                         t = car(s); s = cdr(s);
 681                         f = MapInfo_Type_FromString(t);
 682                         if(f)
 683                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f);
 684                         else
 685                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
 686                 }
 687                 else if(t == "size")
 688                 {
 689                         float a, b, c, d, e;
 690                         t = car(s); s = cdr(s); a = stof(t);
 691                         t = car(s); s = cdr(s); b = stof(t);
 692                         t = car(s); s = cdr(s); c = stof(t);
 693                         t = car(s); s = cdr(s); d = stof(t);
 694                         t = car(s); s = cdr(s); e = stof(t);
 695                         if(s == "")
 696                                 print("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 697                         else
 698                         {
 699                                 t = car(s); s = cdr(s); f = stof(t);
 700                                 if(s != "")
 701                                         print("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 702                                 else
 703                                 {
 704                                         if(a >= d || b >= e || c >= f)
 705                                                 print("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
 706                                         else
 707                                         {
 708                                                 MapInfo_Map_mins_x = a;
 709                                                 MapInfo_Map_mins_y = b;
 710                                                 MapInfo_Map_mins_z = c;
 711                                                 MapInfo_Map_maxs_x = d;
 712                                                 MapInfo_Map_maxs_y = e;
 713                                                 MapInfo_Map_maxs_z = f;
 714                                         }
 715                                 }
 716                         }
 717                 }
 718                 else if(t == "settemp_for_type")
 719                 {
 720                         t = car(s); s = cdr(s);
 721                         if((f = MapInfo_Type_FromString(t)))
 722                         {
 723                                 if(f & pGametypeToSet)
 724                                 {
 725                                         t = car(s); s = cdr(s);
 726                                         if not(cvar_value_issafe(t))
 727                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 728                                         else if not (cvar_value_issafe(s))
 729                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 730                                         else
 731                                         {
 732                                                 dprint("Applying temporary setting ", t, " := ", s, "\n");
 733                                                 cvar_settemp(t, s);
 734                                         }
 735                                 }
 736                         }
 737                         else
 738                         {
 739                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
 740                         }
 741                 }
 742                 else if(t == "clientsettemp_for_type")
 743                 {
 744                         t = car(s); s = cdr(s);
 745                         if((f = MapInfo_Type_FromString(t)))
 746                         {
 747                                 if(f & pGametypeToSet)
 748                                 {
 749                                         t = car(s); s = cdr(s);
 750                                         if not(cvar_value_issafe(t))
 751                                                 print("Map ", pFilename, " contains a potentially harmful client setting, ignored\n");
 752                                         else if not (cvar_value_issafe(s))
 753                                                 print("Map ", pFilename, " contains a potentially harmful client setting, ignored\n");
 754                                         else
 755                                         {
 756                                                 dprint("Applying temporary client setting ", t, " := ", s, "\n");
 757                                                 MapInfo_Map_clientstuff = strcat(
 758                                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 759                                                 );
 760                                         }
 761                                 }
 762                         }
 763                         else
 764                         {
 765                                 dprint("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
 766                         }
 767                 }
 768                 else if(t == "fog")
 769                 {
 770                         if not(cvar_value_issafe(t))
 771                                 print("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
 772                         else
 773                                 MapInfo_Map_fog = s;
 774                 }
 775                 else if(t == "cdtrack")
 776                 {
 777                         if(pGametypeToSet)
 778                         {
 779                                 if not(cvar_value_issafe(t))
 780                                         print("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
 781                                 else
 782                                         MapInfo_Map_clientstuff = strcat(
 783                                                 MapInfo_Map_clientstuff, "cd loop \"", s, "\"\n"
 784                                         );
 785                         }
 786                 }
 787                 else
 788                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
 789         }
 790         fclose(fh);
 791
 792         if(!MapInfo_Map_supportedGametypes)
 793                 _MapInfo_Map_ApplyGametype("30 20", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
 794
 795         if(pGametypeToSet)
 796                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
 797                         error("Can't select the requested game type. Bailing out.");
 798         MapInfo_Cache_Store();
 799         if(MapInfo_Map_supportedGametypes != 0)
 800                 return r;
 801         dprint("Map ", pFilename, " supports no game types, ignored\n");
 802         return 0;
 803 }
 804
 805 float MapInfo_FindName(string s)
 806 {
 807         // if there is exactly one map of prefix s, return it
 808         // if not, return the null string
 809         // note that DP sorts glob results... so I can use a binary search
 810         float l, r, m, cmp;
 811         l = 0;
 812         r = MapInfo_count;
 813         // invariants: r is behind s, l-1 is equal or before
 814         while(l != r)
 815         {
 816                 m = floor((l + r) / 2);
 817                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
 818                 cmp = strcasecmp(MapInfo_FindName_match, s);
 819                 if(cmp == 0)
 820                         return m; // found and good
 821                 if(cmp < 0)
 822                         l = m + 1; // l-1 is before s
 823                 else
 824                         r = m; // behind s
 825         }
 826         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
 827         MapInfo_FindName_firstResult = l;
 828         // r == l, so: l is behind s, l-1 is before
 829         // SO: if there is any, l is the one with the right prefix
 830         //     and l+1 may be one too
 831         if(l == MapInfo_count)
 832         {
 833                 MapInfo_FindName_match = string_null;
 834                 MapInfo_FindName_firstResult = -1;
 835                 return -1; // no MapInfo_FindName_match, behind last item
 836         }
 837         if(!startsWithNocase(MapInfo_FindName_match, s))
 838         {
 839                 MapInfo_FindName_match = string_null;
 840                 MapInfo_FindName_firstResult = -1;
 841                 return -1; // wrong prefix
 842         }
 843         if(l == MapInfo_count - 1)
 844                 return l; // last one, nothing can follow => unique
 845         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
 846         {
 847                 MapInfo_FindName_match = string_null;
 848                 return -1; // ambigous MapInfo_FindName_match
 849         }
 850         return l;
 851 }
 852
 853 string MapInfo_FixName(string s)
 854 {
 855         MapInfo_FindName(s);
 856         return MapInfo_FindName_match;
 857 }
 858
 859 float MapInfo_CurrentFeatures()
 860 {
 861         float req;
 862         req = 0;
 863         if(!(cvar("g_lms") || cvar("g_instagib") || cvar("g_minstagib") || cvar("g_nixnex") || cvar("g_rocketarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_nexball")))
 864                 req |= MAPINFO_FEATURE_WEAPONS;
 865         return req;
 866 }
 867
 868 float MapInfo_CurrentGametype()
 869 {
 870         if(cvar("g_domination"))
 871                 return MAPINFO_TYPE_DOMINATION;
 872         else if(cvar("g_ctf"))
 873                 return MAPINFO_TYPE_CTF;
 874         else if(cvar("g_runematch"))
 875                 return MAPINFO_TYPE_RUNEMATCH;
 876         else if(cvar("g_tdm"))
 877                 return MAPINFO_TYPE_TEAM_DEATHMATCH;
 878         else if(cvar("g_assault"))
 879                 return MAPINFO_TYPE_ASSAULT;
 880         else if(cvar("g_lms"))
 881                 return MAPINFO_TYPE_LMS;
 882         else if(cvar("g_arena"))
 883                 return MAPINFO_TYPE_ARENA;
 884         else if(cvar("g_keyhunt"))
 885                 return MAPINFO_TYPE_KEYHUNT;
 886         else if(cvar("g_onslaught"))
 887                 return MAPINFO_TYPE_ONSLAUGHT;
 888         else if(cvar("g_race"))
 889                 return MAPINFO_TYPE_RACE;
 890         else if(cvar("g_nexball"))
 891                 return MAPINFO_TYPE_NEXBALL;
 892         else
 893                 return MAPINFO_TYPE_DEATHMATCH;
 894 }
 895
 896 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
 897 {
 898         if(!MapInfo_Get_ByName(s, 1, 0))
 899                 return 0;
 900         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
 901                 return 0;
 902         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
 903                 return 0;
 904         return 1;
 905 }
 906
 907 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
 908 {
 909         float r;
 910         r = _MapInfo_CheckMap(s);
 911         MapInfo_ClearTemps();
 912         return r;
 913 }
 914
 915 string MapInfo_GetGameTypeCvar(float t)
 916 {
 917         switch(t)
 918         {
 919                 case MAPINFO_TYPE_DEATHMATCH: return "g_dm";
 920                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "g_tdm";
 921                 case MAPINFO_TYPE_DOMINATION: return "g_domination";
 922                 case MAPINFO_TYPE_CTF: return "g_ctf";
 923                 case MAPINFO_TYPE_RUNEMATCH: return "g_runematch";
 924                 case MAPINFO_TYPE_LMS: return "g_lms";
 925                 case MAPINFO_TYPE_ARENA: return "g_arena";
 926                 case MAPINFO_TYPE_KEYHUNT: return "g_kh";
 927                 case MAPINFO_TYPE_ASSAULT: return "g_assault";
 928                 case MAPINFO_TYPE_ONSLAUGHT: return "g_onslaught";
 929                 case MAPINFO_TYPE_RACE: return "g_race";
 930                 default: return "";
 931         }
 932 }
 933
 934 void MapInfo_SwitchGameType(float t)
 935 {
 936         cvar_set("gamecfg",      "0");
 937         cvar_set("g_dm",         (t == MAPINFO_TYPE_DEATHMATCH)      ? "1" : "0");
 938         cvar_set("g_tdm",        (t == MAPINFO_TYPE_TEAM_DEATHMATCH) ? "1" : "0");
 939         cvar_set("g_domination", (t == MAPINFO_TYPE_DOMINATION)      ? "1" : "0");
 940         cvar_set("g_ctf",        (t == MAPINFO_TYPE_CTF)             ? "1" : "0");
 941         cvar_set("g_runematch",  (t == MAPINFO_TYPE_RUNEMATCH)       ? "1" : "0");
 942         cvar_set("g_lms",        (t == MAPINFO_TYPE_LMS)             ? "1" : "0");
 943         cvar_set("g_arena",      (t == MAPINFO_TYPE_ARENA)           ? "1" : "0");
 944         cvar_set("g_keyhunt",    (t == MAPINFO_TYPE_KEYHUNT)         ? "1" : "0");
 945         cvar_set("g_assault",    (t == MAPINFO_TYPE_ASSAULT)         ? "1" : "0");
 946         cvar_set("g_onslaught",  (t == MAPINFO_TYPE_ONSLAUGHT)       ? "1" : "0");
 947         cvar_set("g_race",       (t == MAPINFO_TYPE_RACE)            ? "1" : "0");
 948         cvar_set("g_nexball",    (t == MAPINFO_TYPE_NEXBALL)         ? "1" : "0");
 949 }
 950
 951 void MapInfo_LoadMap(string s)
 952 {
 953         MapInfo_Map_supportedGametypes = 0;
 954         if(!MapInfo_CheckMap(s))
 955         {
 956                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
 957                 MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
 958         }
 959         localcmd(strcat("\nsettemp_restore\nchangelevel ", s, "\n"));
 960 }
 961
 962 string MapInfo_ListAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
 963 {
 964         string out;
 965         float i;
 966
 967         // to make absolutely sure:
 968         MapInfo_Enumerate();
 969         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
 970
 971         out = "";
 972         for(i = 0; i < MapInfo_count; ++i)
 973                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
 974         return substring(out, 1, strlen(out) - 1);
 975 }
 976
 977 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
 978 {
 979         float t;
 980         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
 981         {
 982                 if(MapInfo_Map_supportedGametypes <= 0)
 983                         error("Mapinfo system is not functional at all. BAILED OUT.\n");
 984
 985                 t = 1;
 986                 while(!(MapInfo_Map_supportedGametypes & 1))
 987                 {
 988                         t *= 2;
 989                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
 990                 }
 991                 // t is now a supported mode!
 992                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
 993                 MapInfo_SwitchGameType(t);
 994         }
 995         cvar_settemp_restore();
 996         MapInfo_Get_ByName(s, 1, MapInfo_CurrentGametype());
 997 }
 998
 999 void MapInfo_ClearTemps()
1000 {
1001         MapInfo_Map_bspname = string_null;
1002         MapInfo_Map_title = string_null;
1003         MapInfo_Map_description = string_null;
1004         MapInfo_Map_author = string_null;
1005         MapInfo_Map_clientstuff = string_null;
1006         MapInfo_Map_supportedGametypes = 0;
1007         MapInfo_Map_supportedFeatures = 0;
1008 }
1009
1010 void MapInfo_Shutdown()
1011 {
1012         MapInfo_ClearTemps();
1013         MapInfo_Filter_Free();
1014         MapInfo_Cache_Destroy();
1015         if(_MapInfo_globopen)
1016         {
1017                 search_end(_MapInfo_globhandle);
1018                 _MapInfo_globhandle = -1;
1019                 _MapInfo_globopen = FALSE;
1020         }
1021 }