data/qcsrc/client/sbar.qc

   1
   2 float last_weapon;
   3 float weapontime;
   4
   5 float sb_lines; // still don't know what to do with that NOTE: check dp's sbar.c to see what that should be
   6
   7 vector sbar;
   8 float sbar_alpha_fg;
   9 float sbar_hudselector;
  10
  11 float ps_primary, ps_secondary;
  12 float ts_primary, ts_secondary;
  13
  14 void CSQC_kh_hud();
  15 void CSQC_ctf_hud();
  16 void MapVote_Draw();
  17 void Sbar_FinaleOverlay()
  18 {
  19         /*vector pos;
  20         pos_x = (vid_conwidth - 1)/2;
  21         pos_y = 16;
  22         pos_z = 0;*/
  23
  24         //drawpic(pos, "gfx/finale", '0 0 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
  25
  26         //drawstring(pos, "END", sbar_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
  27         MapVote_Draw();
  28 }
  29
  30 float weaponspace[10];
  31 float weapon_first, weapon_last;
  32 void Sbar_DrawWeapon_Clear()
  33 {
  34         float idx;
  35         weapon_first = -2;
  36         weapon_last = -1;
  37         for(idx = 0; idx < 10; ++idx)
  38                 weaponspace[idx] = 0;
  39         for(idx = 0; idx <= 23; ++idx)
  40         {
  41                 if(weaponimpulse[idx] >= 0)
  42                 {
  43                         if(weapon_first < 0)
  44                                 weapon_first = idx;
  45                         weapon_last = idx;
  46                 }
  47         }
  48 }
  49 void Sbar_DrawWeapon(float nr, float fade, float active)
  50 {
  51         vector pos, vsize, color;
  52         float value, idx, imp, sp;
  53
  54         imp = weaponimpulse[nr];
  55         if(imp == 0)
  56                 idx = 9;
  57         else
  58                 idx = imp - 1;
  59
  60         value = (active) ? 1 : 0.6;
  61         color_x = color_y = color_z = value;
  62
  63         if(sbar_hudselector == 1)
  64         {
  65                 // width = 300, height = 100
  66                 const float w_width = 32, w_height = 12, w_space = 2, font_size = 8;
  67
  68                 sp = weaponspace[idx] + 1;
  69                 weaponspace[idx] = sp;
  70
  71                 pos_x = (vid_conwidth - w_width * 9) * 0.5 + w_width * idx;
  72                 pos_y = (vid_conheight - w_height * sp);
  73                 pos_z = 0;
  74                 vsize_x = w_width;
  75                 vsize_y = w_height;
  76                 vsize_z = 0;
  77                 drawpic(pos, strcat("gfx/inv_weapon", ftos(nr)), vsize, color, value * fade * sbar_alpha_fg, 0);
  78                 pos_x += w_space;
  79                 pos_y += w_space;
  80                 vsize_x = font_size;
  81                 vsize_y = font_size;
  82                 vsize_z = 0;
  83                 drawstring(pos, ftos(imp), vsize, '1 1 0', sbar_alpha_fg, 0);
  84         }
  85         else
  86         {
  87                 // width = 300, height = 100
  88                 const float w2_width = 300, w2_height = 100, w2_space = 10;
  89                 const float w2_scale = 0.4;
  90
  91                 float f;
  92                 f = 9 / (weapon_last + 1 - weapon_first);
  93
  94                 pos_x = vid_conwidth - (w2_width + w2_space) * w2_scale * f;
  95                 pos_y = (w2_height + w2_space) * w2_scale * nr * f + w2_space;
  96                 pos_z = 0;
  97                 vsize_x = w2_width * w2_scale * f;
  98                 vsize_y = w2_height * w2_scale * f;
  99                 vsize_z = 0;
 100
 101                 drawpic(pos, strcat("gfx/inv_weapon", ftos(nr)), vsize, color, value * fade * sbar_alpha_fg, 0);
 102         }
 103 }
 104 void Sbar_DrawXNum (vector pos, float num, float digits, float lettersize, vector rgb, float a, float dflags)
 105 {
 106         float l, i;
 107         string str, tmp;
 108         float minus;
 109         vector vsize;
 110
 111         vsize_x = vsize_y = lettersize;
 112         vsize_z = 0;
 113
 114         if(num < 0)
 115         {
 116                 minus = true;
 117                 num = -num;
 118                 pos_x -= lettersize;
 119         } else
 120                 minus = false;
 121
 122         if(digits < 0)
 123         {
 124                 tmp = ftos(num);
 125                 digits = -digits;
 126                 str = strcat(substring("0000000000", 0, digits - strlen(tmp)), tmp);
 127         } else
 128                 str = ftos(num);
 129
 130         l = strlen(str);
 131
 132         if(l > digits)
 133         {
 134                 str = substring(str, l-digits, 999);
 135                 l = strlen(str);
 136         } else if(l < digits)
 137                 pos_x += (digits-l) * lettersize;
 138
 139         if(minus)
 140         {
 141                 drawpic(sbar + pos, "gfx/num_minus", vsize, rgb, a * sbar_alpha_fg, dflags);
 142                 pos_x += lettersize;
 143         }
 144
 145         for(i = 0; i < l; ++i)
 146         {
 147                 drawpic(sbar + pos, strcat("gfx/num_", substring(str, i, 1)), vsize, rgb, a * sbar_alpha_fg, dflags);
 148                 pos_x += lettersize;
 149         }
 150 }
 151
 152 void Cmd_Sbar_SetFields(float argc);
 153 void Sbar_InitScores()
 154 {
 155         float i, f;
 156
 157         ps_primary = ps_secondary = ts_primary = ts_secondary = -1;
 158         for(i = 0; i < MAX_SCORE; ++i)
 159         {
 160                 f = (scores_flags[i] & SFL_SORT_PRIO_MASK);
 161                 if(f == SFL_SORT_PRIO_PRIMARY)
 162                         ps_primary = i;
 163                 if(f == SFL_SORT_PRIO_SECONDARY)
 164                         ps_secondary = i;
 165         }
 166         if(ps_secondary == -1)
 167                 ps_secondary = ps_primary;
 168
 169         for(i = 0; i < MAX_TEAMSCORE; ++i)
 170         {
 171                 f = (teamscores_flags[i] & SFL_SORT_PRIO_MASK);
 172                 if(f == SFL_SORT_PRIO_PRIMARY)
 173                         ts_primary = i;
 174                 if(f == SFL_SORT_PRIO_SECONDARY)
 175                         ts_secondary = i;
 176         }
 177         if(ts_secondary == -1)
 178                 ts_secondary = ts_primary;
 179
 180         Cmd_Sbar_SetFields(0);
 181 }
 182
 183 void Sbar_UpdatePlayerPos(entity pl);
 184 float SetTeam(entity pl, float Team);
 185 //float lastpnum;
 186 void Sbar_UpdatePlayerTeams()
 187 {
 188         float Team;
 189         entity pl, tmp;
 190         float num;
 191
 192         num = 0;
 193         for(pl = players.sort_next; pl; pl = pl.sort_next)
 194         {
 195                 num += 1;
 196                 Team = GetPlayerColor(pl.sv_entnum);
 197                 if(SetTeam(pl, Team))
 198                 {
 199                         tmp = pl.sort_prev;
 200                         Sbar_UpdatePlayerPos(pl);
 201                         if(tmp)
 202                                 pl = tmp;
 203                         else
 204                                 pl = players.sort_next;
 205                 }
 206         }
 207         /*
 208         if(num != lastpnum)
 209                 print(strcat("PNUM: ", ftos(num), "\n"));
 210         lastpnum = num;
 211         */
 212 }
 213
 214 float Sbar_ComparePlayerScores(entity left, entity right)
 215 {
 216         float vl, vr;
 217         vl = GetPlayerColor(left.sv_entnum);
 218         vr = GetPlayerColor(right.sv_entnum);
 219
 220         if(vl > vr)
 221                 return true;
 222         if(vl < vr)
 223                 return false;
 224
 225         if(vl == COLOR_SPECTATOR)
 226         {
 227                 // FIRST the one with scores (spectators), THEN the ones without (downloaders)
 228                 // no other sorting
 229                 if(!left.gotscores && right.gotscores)
 230                         return true;
 231                 return false;
 232         }
 233
 234         vl = left.scores[ps_primary];
 235         vr = right.scores[ps_primary];
 236         if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
 237         {
 238                 if(vl == 0 && vr != 0)
 239                         return 1;
 240                 if(vl != 0 && vr == 0)
 241                         return 0;
 242         }
 243         if(vl > vr)
 244                 return IS_INCREASING(scores_flags[ps_primary]);
 245         if(vl < vr)
 246                 return IS_DECREASING(scores_flags[ps_primary]);
 247
 248         vl = left.scores[ps_secondary];
 249         vr = right.scores[ps_secondary];
 250         if(scores_flags[ps_secondary] & SFL_ZERO_IS_WORST)
 251         {
 252                 if(vl == 0 && vr != 0)
 253                         return 1;
 254                 if(vl != 0 && vr == 0)
 255                         return 0;
 256         }
 257         if(vl > vr)
 258                 return IS_INCREASING(scores_flags[ps_secondary]);
 259         if(vl < vr)
 260                 return IS_DECREASING(scores_flags[ps_secondary]);
 261
 262         return false;
 263 }
 264
 265 void Sbar_UpdatePlayerPos(entity player)
 266 {
 267         for(other = player.sort_next; other && Sbar_ComparePlayerScores(player, other); other = player.sort_next)
 268         {
 269                 SORT_SWAP(player, other);
 270         }
 271         for(other = player.sort_prev; other != players && Sbar_ComparePlayerScores(other, player); other = player.sort_prev)
 272         {
 273                 SORT_SWAP(other, player);
 274         }
 275 }
 276
 277 float Sbar_CompareTeamScores(entity left, entity right)
 278 {
 279         float vl, vr;
 280
 281         if(left.team == COLOR_SPECTATOR)
 282                 return 1;
 283         if(right.team == COLOR_SPECTATOR)
 284                 return 0;
 285
 286         vl = left.teamscores[ts_primary];
 287         vr = right.teamscores[ts_primary];
 288         if(vl > vr)
 289                 return IS_INCREASING(teamscores_flags[ts_primary]);
 290         if(vl < vr)
 291                 return IS_DECREASING(teamscores_flags[ts_primary]);
 292
 293         vl = left.teamscores[ts_secondary];
 294         vr = right.teamscores[ts_secondary];
 295         if(vl > vr)
 296                 return IS_INCREASING(teamscores_flags[ts_secondary]);
 297         if(vl < vr)
 298                 return IS_DECREASING(teamscores_flags[ts_secondary]);
 299
 300         return false;
 301 }
 302
 303 void Sbar_UpdateTeamPos(entity Team)
 304 {
 305         for(other = Team.sort_next; other && Sbar_CompareTeamScores(Team, other); other = Team.sort_next)
 306         {
 307                 SORT_SWAP(Team, other);
 308         }
 309         for(other = Team.sort_prev; other != teams && Sbar_CompareTeamScores(other, Team); other = Team.sort_prev)
 310         {
 311                 SORT_SWAP(other, Team);
 312         }
 313 }
 314
 315 void Cmd_Sbar_Help(float argc)
 316 {
 317         print("You can modify the scoreboard using the\n");
 318         print("^3|---------------------------------------------------------------|\n");
 319         print("^1 TO BE DONE\n");
 320         print("Usage:\n");
 321         print("^2sbar_columns_set default\n");
 322         print("^2sbar_columns_set ^7filed1 field2 ...\n");
 323         print("The following field names are recognized (case INsensitive):\n");
 324         print("You can use a ^3|^7 to start the right-aligned fields.\n");
 325
 326         print("^3name^7 or ^3nick^7             Name of a player\n");
 327         print("^3ping^7                     Ping time\n\n");
 328         print("^3kd^7 or ^3kdr^7 or ^3kdratio^7 or ^3k/d\n");
 329         print("                         The kill-death ratio\n");
 330
 331         print("Before a field you can put a + or - sign, then a comma separated list\n");
 332         print("of game types, then a slash, to make the field show up only in these\n");
 333         print("or in all but these game types.\n");
 334
 335         local float i;
 336         print("Additional columns:\n");
 337         for(i = 0; i < MAX_SCORE; ++i)
 338         {
 339                 if(scores_label[i] != "")
 340                         print(strcat(scores_label[i], "\n"));
 341         }
 342 }
 343
 344 #define MIN_NAMELEN 24
 345 #define MAX_NAMELEN 24
 346
 347 string Sbar_DefaultColumnLayout()
 348 {
 349         return "ping pl name | -ctf,kh/kills -ctf,kh/deaths +lms/lives +lms/rank +kh,ctf/caps +kh/pushes +kh/destroyed -lms/score";
 350 }
 351
 352 void Cmd_Sbar_SetFields(float argc)
 353 {
 354         float i, j, slash;
 355         string str, pattern, subpattern;
 356         float digit;
 357         float have_name, have_primary, have_secondary, have_separator;
 358         float missing;
 359
 360         // TODO: re enable with gametype dependant cvars?
 361         if(argc < 2) // no arguments provided
 362                 argc = tokenizebyseparator(strcat("x ", cvar_string("sbar_columns")), " ");
 363
 364         if(argc < 2)
 365                 argc = tokenizebyseparator(strcat("x ", Sbar_DefaultColumnLayout()), " ");
 366
 367         if(argc == 2)
 368         {
 369                 if(argv(1) == "default")
 370                         argc = tokenizebyseparator(strcat("x ", Sbar_DefaultColumnLayout()), " ");
 371                 else if(argv(1) == "all")
 372                 {
 373                         string s;
 374                         s = "ping pl name |";
 375                         for(i = 0; i < MAX_SCORE; ++i)
 376                         {
 377                                 if(i != ps_primary)
 378                                 if(i != ps_secondary)
 379                                 if(scores_label[i] != "")
 380                                         s = strcat(s, " ", scores_label[i]);
 381                         }
 382                         if(ps_secondary != ps_primary)
 383                                 s = strcat(s, " ", scores_label[ps_secondary]);
 384                         s = strcat(s, " ", scores_label[ps_primary]);
 385                         argc = tokenizebyseparator(strcat("x ", s), " ");
 386                 }
 387         }
 388
 389
 390         argc = min(MAX_SBAR_FIELDS, argc);
 391         sbar_num_fields = 0;
 392
 393         drawfont = sbar_font;
 394         digit = stringwidth("0123456789", FALSE) / 10;
 395
 396         subpattern = strcat(",", GametypeNameFromType(gametype), ",");
 397
 398         argc = min(argc-1, MAX_SBAR_FIELDS-1);
 399         for(i = 0; i < argc; ++i)
 400         {
 401                 str = argv(i+1);
 402
 403                 slash = strstrofs(str, "/", 0);
 404                 if(slash >= 0)
 405                 {
 406                         pattern = substring(str, 0, slash);
 407                         str = substring(str, slash + 1, strlen(str) - (slash + 1));
 408
 409                         if(substring(pattern, 0, 1) == "-")
 410                         {
 411                                 pattern = substring(pattern, 1, strlen(pattern) - 1);
 412                                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) >= 0)
 413                                         continue;
 414                         }
 415                         else
 416                         {
 417                                 if(substring(pattern, 0, 1) == "+")
 418                                         pattern = substring(pattern, 1, strlen(pattern) - 1);
 419                                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) < 0)
 420                                         continue;
 421                         }
 422                 }
 423
 424                 strunzone(sbar_title[sbar_num_fields]);
 425                 sbar_title[sbar_num_fields] = strzone(str);
 426                 sbar_size[sbar_num_fields] = stringwidth(str, FALSE);
 427                 str = strtolower(str);
 428
 429                 if(str == "ping") {
 430                         sbar_field[sbar_num_fields] = SP_PING;
 431                 } else if(str == "pl") {
 432                         sbar_field[sbar_num_fields] = SP_PL;
 433                 } else if(str == "kd" || str == "kdr" || str == "kdratio" || str == "k/d") {
 434                         sbar_field[sbar_num_fields] = SP_KDRATIO;
 435                 } else if(str == "name" || str == "nick") {
 436                         sbar_field[sbar_num_fields] = SP_NAME;
 437                         sbar_size[sbar_num_fields] = MIN_NAMELEN; // minimum size? any use?
 438                         have_name = 1;
 439                 } else if(str == "|") {
 440                         sbar_field[sbar_num_fields] = SP_SEPARATOR;
 441                         have_separator = 1;
 442                 } else {
 443                         for(j = 0; j < MAX_SCORE; ++j)
 444                                 if(str == strtolower(scores_label[j]))
 445                                         goto found; // sorry, but otherwise fteqcc -O3 miscompiles this and warns about "unreachable code"
 446 :notfound
 447                         print(strcat("^1Error:^7 Unknown score field: '", str, "'\n"));
 448                         continue;
 449 :found
 450                         sbar_field[sbar_num_fields] = j;
 451                         if(j == ps_primary)
 452                                 have_primary = 1;
 453                         if(j == ps_secondary)
 454                                 have_secondary = 1;
 455                 }
 456                 ++sbar_num_fields;
 457         }
 458
 459         if(scores_flags[ps_primary] & SFL_ALLOW_HIDE)
 460                 have_primary = 1;
 461         if(scores_flags[ps_secondary] & SFL_ALLOW_HIDE)
 462                 have_secondary = 1;
 463         if(ps_primary == ps_secondary)
 464                 have_secondary = 1;
 465         missing = !have_primary + !have_secondary + !have_separator + !have_name;
 466
 467         if(sbar_num_fields+missing < MAX_SBAR_FIELDS)
 468         {
 469                 if(!have_name)
 470                 {
 471                         strunzone(sbar_title[sbar_num_fields]);
 472                         for(i = sbar_num_fields; i > 0; --i)
 473                         {
 474                                 sbar_title[i] = sbar_title[i-1];
 475                                 sbar_size[i] = sbar_size[i-1];
 476                                 sbar_field[i] = sbar_field[i-1];
 477                         }
 478                         sbar_title[0] = strzone("name");
 479                         sbar_field[0] = SP_NAME;
 480                         sbar_size[0] = MIN_NAMELEN; // minimum size? any use?
 481                         ++sbar_num_fields;
 482                         print("fixed missing field 'name'\n");
 483
 484                         if(!have_separator)
 485                         {
 486                                 strunzone(sbar_title[sbar_num_fields]);
 487                                 for(i = sbar_num_fields; i > 1; --i)
 488                                 {
 489                                         sbar_title[i] = sbar_title[i-1];
 490                                         sbar_size[i] = sbar_size[i-1];
 491                                         sbar_field[i] = sbar_field[i-1];
 492                                 }
 493                                 sbar_title[1] = strzone("|");
 494                                 sbar_field[1] = SP_SEPARATOR;
 495                                 sbar_size[1] = stringwidth("|", FALSE);
 496                                 ++sbar_num_fields;
 497                                 print("fixed missing field '|'\n");
 498                         }
 499                 }
 500                 else if(!have_separator)
 501                 {
 502                         strunzone(sbar_title[sbar_num_fields]);
 503                         sbar_title[sbar_num_fields] = strzone("|");
 504                         sbar_size[sbar_num_fields] = stringwidth("|", FALSE);
 505                         sbar_field[sbar_num_fields] = SP_SEPARATOR;
 506                         ++sbar_num_fields;
 507                         print("fixed missing field '|'\n");
 508                 }
 509
 510                 if(!have_secondary)
 511                 {
 512                         strunzone(sbar_title[sbar_num_fields]);
 513                         sbar_title[sbar_num_fields] = strzone(scores_label[ps_secondary]);
 514                         sbar_size[sbar_num_fields] = stringwidth(sbar_title[sbar_num_fields], FALSE);
 515                         sbar_field[sbar_num_fields] = ps_secondary;
 516                         ++sbar_num_fields;
 517                         print("fixed missing field '", scores_label[ps_secondary], "'\n");
 518                 }
 519
 520                 if(!have_primary)
 521                 {
 522                         strunzone(sbar_title[sbar_num_fields]);
 523                         sbar_title[sbar_num_fields] = strzone(scores_label[ps_primary]);
 524                         sbar_size[sbar_num_fields] = stringwidth(sbar_title[sbar_num_fields], FALSE);
 525                         sbar_field[sbar_num_fields] = ps_primary;
 526                         ++sbar_num_fields;
 527                         print("fixed missing field '", scores_label[ps_primary], "'\n");
 528                 }
 529         }
 530
 531         sbar_field[sbar_num_fields] = SP_END;
 532 }
 533
 534 // MOVEUP::
 535 vector sbar_field_rgb;
 536 string Sbar_GetField(entity pl, float field)
 537 {
 538         float tmp, num, denom, f;
 539         string str;
 540         sbar_field_rgb = '1 1 1';
 541         switch(field)
 542         {
 543                 case SP_PING:
 544                         if not(pl.gotscores)
 545                                 return "\x8D\x8D\x8D"; // >>> sign
 546                         str = getplayerkey(pl.sv_entnum, "ping");
 547                         if(str == "0")
 548                                 return "N/A";
 549                         tmp = max(0, min(220, stof(str)-80)) / 220;
 550                         sbar_field_rgb = '1 1 1' - '0 1 1'*tmp;
 551                         return str;
 552
 553                 case SP_PL:
 554                         if not(pl.gotscores)
 555                                 return "N/A";
 556                         str = getplayerkey(pl.sv_entnum, "pl");
 557                         if(str == "0")
 558                                 return "";
 559                         tmp = bound(0, stof(str), 20) / 20; // 20% is REALLY BAD pl
 560                         sbar_field_rgb = '1 0.5 0.5' - '0 0.5 0.5'*tmp;
 561                         return str;
 562
 563                 case SP_NAME:
 564                         return getplayerkey(pl.sv_entnum, "name");
 565
 566                 case SP_KDRATIO:
 567                         num = pl.(scores[SP_KILLS]);
 568                         denom = pl.(scores[SP_DEATHS]);
 569
 570                         if(denom == 0) {
 571                                 sbar_field_rgb = '0 1 0';
 572                                 str = ftos(num);
 573                         } else if(num <= 0) {
 574                                 sbar_field_rgb = '1 0 0';
 575                                 str = ftos(num/denom);
 576                         } else
 577                                 str = ftos(num/denom);
 578
 579                         tmp = strstrofs(str, ".", 0);
 580                         if(tmp > 0)
 581                                 str = substring(str, 0, tmp+2);
 582                         return str;
 583
 584                 default:
 585                         tmp = pl.(scores[field]);
 586                         f = scores_flags[field];
 587                         if(field == ps_primary)
 588                                 sbar_field_rgb = '1 1 0';
 589                         else if(field == ps_secondary)
 590                                 sbar_field_rgb = '0 1 1';
 591                         else
 592                                 sbar_field_rgb = '1 1 1';
 593                         return ScoreString(f, tmp);
 594         }
 595         //return "error";
 596 }
 597
 598 // shamelessly stolen from menu QC :P <- as if I would steal YOUR code pfft ;)
 599 float textLengthUpToWidth(string theText, float maxWidth, float handleColors)
 600 {
 601         // STOP.
 602         // The following function is SLOW.
 603         // For your safety and for the protection of those around you...
 604         // DO NOT CALL THIS AT HOME.
 605         // No really, don't.
 606         if(stringwidth(theText, handleColors) <= maxWidth)
 607                 return strlen(theText); // yeah!
 608
 609         // binary search for right place to cut string
 610         float left, right, middle; // this always works
 611         left = 0;
 612         right = strlen(theText); // this always fails
 613         do
 614         {
 615                 middle = floor((left + right) / 2);
 616                 if(stringwidth(substring(theText, 0, middle), handleColors) <= maxWidth)
 617                         left = middle;
 618                 else
 619                         right = middle;
 620         }
 621         while(left < right - 1);
 622
 623         // NOTE: when color codes are involved, this binary search is,
 624         // mathematically, BROKEN. However, it is obviously guaranteed to
 625         // terminate, as the range still halves each time - but nevertheless, it is
 626         // guaranteed that it finds ONE valid cutoff place (where "left" is in
 627         // range, and "right" is outside).
 628
 629         return left;
 630 }
 631 string textShortenToWidth(string theText, float maxWidth, float handleColors)
 632 {
 633         if(stringwidth(theText, handleColors) <= maxWidth)
 634                 return theText;
 635         else
 636                 return strcat(substring(theText, 0, textLengthUpToWidth(theText, maxWidth - stringwidth("...", handleColors), handleColors)), "...");
 637 }
 638
 639 float xmin, xmax, ymin, ymax, sbwidth, sbheight;
 640
 641 void Sbar_PrintScoreboardItem(vector pos, entity pl, float is_self)
 642 {
 643         vector tmp;
 644         string str;
 645         float i, field, len;
 646         float is_spec;
 647         is_spec = (GetPlayerColor(pl.sv_entnum) == COLOR_SPECTATOR);
 648
 649         // Layout:
 650         tmp_z = 0;
 651         if(is_self)
 652         {
 653                 tmp_x = sbwidth;
 654                 tmp_y = sbar_fontsize_y;
 655                 drawfill(pos - '1 1 0', tmp + '2 2 0', '1 1 1', 0.3, DRAWFLAG_NORMAL);
 656         }
 657         tmp_y = 0;
 658
 659         for(i = 0; i < sbar_num_fields; ++i)
 660         {
 661                 field = sbar_field[i];
 662                 if(field == SP_SEPARATOR)
 663                         break;
 664
 665                 if(is_spec && field != SP_NAME && field != SP_PING) {
 666                         pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 667                         continue;
 668                 }
 669                 str = Sbar_GetField(pl, field);
 670
 671                 if(field == SP_NAME)
 672                 {
 673                         float realsize;
 674                         float j;
 675                         realsize = sbar_size[i];
 676                         if(i+1 < sbar_num_fields)
 677                                 if(sbar_field[i+1] == SP_SEPARATOR)
 678                                 {
 679                                         realsize = (xmax - xmin) / sbar_fontsize_x;
 680                                         for(j = 0; j < sbar_num_fields; ++j) if(j != i) if(sbar_field[j] != SP_SEPARATOR)
 681                                                 realsize -= sbar_size[j] + 1;
 682                                         realsize += 1;
 683                                 }
 684                         str = textShortenToWidth(str, realsize, TRUE);
 685                 }
 686                 len = stringwidth(str, TRUE);
 687
 688                 if(sbar_size[i] < len)
 689                         sbar_size[i] = len;
 690
 691                 pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 692
 693                 if(field == SP_NAME) {
 694                         tmp_x = sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 695                         drawcolorcodedstring(pos - tmp, str, sbar_fontsize, 1, DRAWFLAG_NORMAL);
 696                 } else {
 697                         tmp_x = len*sbar_fontsize_x + sbar_fontsize_x;
 698                         drawstring(pos - tmp, str, sbar_fontsize, sbar_field_rgb, 1, DRAWFLAG_NORMAL);
 699                 }
 700         }
 701
 702         if(sbar_field[i] == SP_SEPARATOR)
 703         {
 704                 pos_x = xmax;
 705                 for(i = sbar_num_fields-1; i > 0; --i)
 706                 {
 707                         field = sbar_field[i];
 708                         if(field == SP_SEPARATOR)
 709                                 break;
 710
 711                         if(is_spec && field != SP_NAME && field != SP_PING) {
 712                                 pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 713                                 continue;
 714                         }
 715
 716                         str = Sbar_GetField(pl, field);
 717
 718                         if(field == SP_NAME)
 719                                 str = textShortenToWidth(str, sbar_size[i], TRUE);
 720                         len = stringwidth(str, TRUE);
 721
 722                         if(sbar_size[i] < len)
 723                                 sbar_size[i] = len;
 724
 725                         if(field == SP_NAME) {
 726                                 tmp_x = sbar_fontsize_x*len; // left or right aligned? let's put it right...
 727                                 drawcolorcodedstring(pos - tmp, str, sbar_fontsize, 1, DRAWFLAG_NORMAL);
 728                         } else {
 729                                 tmp_x = sbar_fontsize_x*len; //strlen(str);
 730                                 drawstring(pos - tmp, str, sbar_fontsize, sbar_field_rgb, 1, DRAWFLAG_NORMAL);
 731                         }
 732                         pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 733                 }
 734         }
 735 }
 736
 737 float lastpingstime;
 738 void Sbar_DrawScoreboard()
 739 {
 740         //float xmin, ymin, xmax, ymax;
 741         vector rgb, pos, tmp, sbar_save;
 742         entity pl, tm;
 743         float specs, i;
 744         float center_x;
 745
 746         if(time > lastpingstime + 10)
 747         {
 748                 localcmd("pings\n");
 749                 lastpingstime = time;
 750         }
 751
 752         xmin = vid_conwidth / 5;
 753         ymin = 20;
 754
 755         xmax = vid_conwidth - xmin;
 756         ymax = vid_conheight - 0.2*vid_conheight;
 757
 758         sbwidth = xmax - xmin;
 759         sbheight = ymax - ymin;
 760
 761         center_x = xmin + 0.5*sbwidth;
 762
 763         //Sbar_UpdateFields();
 764
 765         // Initializes position
 766         //pos_x = xmin;
 767         pos_y = ymin;
 768         pos_z = 0;
 769
 770         // Heading
 771         drawfont = sbar_bigfont;
 772         pos_x = center_x - stringwidth("Scoreboard", TRUE)*0.5*24;
 773         drawstring(pos, "Scoreboard", '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
 774         pos_x = xmin;
 775         pos_y += 24 + 4;
 776
 777         // Titlebar background:
 778         tmp_x = sbwidth;
 779         tmp_y = sbar_fontsize_y;
 780         drawfill(pos - '1 1 0', tmp + '2 2 0', '0.5 0.5 0.5', 0.5, DRAWFLAG_NORMAL);
 781
 782         drawfont = sbar_font;
 783
 784         for(i = 0; i < sbar_num_fields; ++i)
 785         {
 786                 if(sbar_field[i] == SP_SEPARATOR)
 787                         break;
 788                 drawstring(pos, sbar_title[i], sbar_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 789                 pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 790         }
 791
 792         if(sbar_field[i] == SP_SEPARATOR)
 793         {
 794                 pos_x = xmax + sbar_fontsize_x;
 795                 tmp_y = tmp_z = 0;
 796                 for(i = sbar_num_fields-1; i > 0; --i)
 797                 {
 798                         if(sbar_field[i] == SP_SEPARATOR)
 799                                 break;
 800
 801                         pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 802                         /**
 803                          * FTEQCC BUG!
 804                          * Using the following line will fuck it all up:
 805                          **
 806                          * tmp_x = sbar_size[i] - strlen(sbar_title[i])*8;
 807                          */
 808                         tmp_x = sbar_fontsize_x*sbar_size[i];
 809                         tmp_x -= stringwidth(sbar_title[i], FALSE)*sbar_fontsize_x;
 810                         drawstring(pos + tmp, sbar_title[i], sbar_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 811                 }
 812         }
 813
 814         pos_x = xmin;
 815         pos_y += 1.5 * sbar_fontsize_y;
 816
 817         sbar_save = sbar;
 818         sbar = '0 0 0';
 819
 820         if(teamplay)
 821         {
 822                 //for(tm = sortedTeams.sort_next; tm; tm = tm.sort_next)
 823                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
 824                 {
 825                         if(!tm.team_size || tm.team == COLOR_SPECTATOR)
 826                                 continue;
 827
 828                         rgb = GetTeamRGB(tm.team);
 829
 830                         pos_x = xmin;
 831
 832                         Sbar_DrawXNum(
 833                                 pos - '6.5 0 0' * sbar_fontsize_y,
 834                                 tm.(teamscores[ts_primary]),
 835                                 4, sbar_fontsize_y * 1.5, rgb, 1, DRAWFLAG_NORMAL);
 836
 837                         if(ts_primary != ts_secondary)
 838                         Sbar_DrawXNum(
 839                                 pos - '4.5 0 0' * sbar_fontsize_y + '0 1.5 0' * sbar_fontsize_y,
 840                                 tm.(teamscores[ts_secondary]),
 841                                 4, sbar_fontsize_y * 1, rgb, 1, DRAWFLAG_NORMAL);
 842
 843                         specs = tm.team_size;
 844
 845                         if(specs < 2)
 846                                 specs = 2;
 847
 848                         tmp_x = sbwidth;
 849                         tmp_y = 1.25 * sbar_fontsize_y * specs;
 850                         drawfill(pos - '1 1 0', tmp + '2 0 0', rgb, 0.2, DRAWFLAG_NORMAL);
 851
 852                         for(pl = players.sort_next; pl; pl = pl.sort_next)
 853                         {
 854                                 if(pl.team != tm.team)
 855                                         continue;
 856                                 Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 857                                 pos_y += 1.25 * sbar_fontsize_y;
 858                                 tmp_y -= 1.25 * sbar_fontsize_y;
 859                         }
 860                         pos_y += tmp_y + 1.5 * sbar_fontsize_y;
 861                 }
 862                 // rgb := tempvector :)
 863                 rgb = pos + '0 1.5 0' * sbar_fontsize_y;
 864                 pos_y += 3 * sbar_fontsize_y;
 865                 specs = 0;
 866                 for(pl = players.sort_next; pl; pl = pl.sort_next)
 867                 {
 868                         if(pl.team != COLOR_SPECTATOR)
 869                                 continue;
 870                         //drawcolorcodedstring(pos, getplayerkey(pl.sb_player, "name"), '8 8 0', 1, 0);
 871                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 872                         pos += '0 1.25 0' * sbar_fontsize_y;
 873                         ++specs;
 874                 }
 875
 876                 if(specs)
 877                         drawstring(rgb, "Spectators", sbar_fontsize, '1 1 1', 1, 0);
 878         } else {
 879                 pos_x = xmin;
 880                 for(pl = players.sort_next; pl; pl = pl.sort_next)
 881                 {
 882                         if(pl.team == COLOR_SPECTATOR)
 883                                 continue;
 884                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 885                         pos_y += 1.25 * sbar_fontsize_y;
 886                         tmp_y -= 1.25 * sbar_fontsize_y;
 887                 }
 888
 889                 // rgb := tempvector :)
 890                 rgb = pos + '0 1.5 0' * sbar_fontsize_y;
 891                 pos_y += 3 * sbar_fontsize_y;
 892                 specs = 0;
 893                 for(pl = players.sort_next; pl; pl = pl.sort_next)
 894                 {
 895                         if(pl.team != COLOR_SPECTATOR)
 896                                 continue;
 897                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 898                         pos += '0 1.25 0' * sbar_fontsize_y;
 899                         ++specs;
 900                 }
 901
 902                 if(specs)
 903                         drawstring(rgb, "Spectators", sbar_fontsize, '1 1 1', 1, 0);
 904         }
 905
 906         string str;
 907         float tl, fl;
 908         str = strcat("playing on ^2", shortmapname, "^7");
 909         tl = getstatf(STAT_TIMELIMIT);
 910         fl = getstatf(STAT_FRAGLIMIT);
 911         if(gametype == GAME_LMS)
 912         {
 913                 if(tl > 0)
 914                         str = strcat(str, " for up to ^1", ftos(tl), " minutes^7");
 915         }
 916         else
 917         {
 918                 if(tl > 0)
 919                         str = strcat(str, " for ^1", ftos(tl), " minutes^7");
 920                 if(fl > 0)
 921                 {
 922                         if(tl > 0)
 923                                 str = strcat(str, " or");
 924                         str = strcat(str, " until ^3", ScoreString(scores_flags[ps_primary], fl));
 925                         if(scores_label[ps_primary] == "score")
 926                                 str = strcat(str, " points^7");
 927                         else if(scores_label[ps_primary] == "fastest")
 928                                 str = strcat(str, " is beaten^7");
 929                         else
 930                                 str = strcat(str, " ", scores_label[ps_primary]);
 931                 }
 932         }
 933
 934
 935         pos_y += 1.5 * sbar_fontsize_y;
 936         drawcolorcodedstring(pos + '0.5 0 0' * (sbwidth - sbar_fontsize_x * stringwidth(str, TRUE)), str, sbar_fontsize, 0.8, 0);
 937
 938         sbar = sbar_save;
 939 }
 940
 941 string MakeRaceString(float cp, float mytime, float histime, float lapdelta, string hisname)
 942 {
 943         string col;
 944         string timestr;
 945         string cpname;
 946         string lapstr;
 947         lapstr = "";
 948
 949         if(histime == 0) // goal hit
 950         {
 951                 if(mytime > 0)
 952                 {
 953                         timestr = strcat("+", ftos_decimals(+mytime, 1));
 954                         col = "^1";
 955                 }
 956                 else if(mytime == 0)
 957                 {
 958                         timestr = "+0.0";
 959                         col = "^3";
 960                 }
 961                 else
 962                 {
 963                         timestr = strcat("-", ftos_decimals(-mytime, 1));
 964                         col = "^2";
 965                 }
 966
 967                 if(lapdelta > 0)
 968                 {
 969                         lapstr = strcat(" (-", ftos(lapdelta), "L)");
 970                         col = "^2";
 971                 }
 972                 else if(lapdelta < 0)
 973                 {
 974                         lapstr = strcat(" (+", ftos(-lapdelta), "L)");
 975                         col = "^1";
 976                 }
 977         }
 978         else if(histime > 0) // anticipation
 979         {
 980                 if(mytime >= histime)
 981                         timestr = strcat("+", ftos_decimals(mytime - histime, 1));
 982                 else
 983                         timestr = mmsss(histime * 10);
 984                 col = "^3";
 985         }
 986         else
 987                 col = "^7";
 988
 989         if(cp)
 990                 cpname = strcat("Intermediate ", ftos(cp));
 991         else
 992                 cpname = "Finish line";
 993
 994         if(histime < 0)
 995                 return strcat(col, cpname);
 996         else if(hisname == "")
 997                 return strcat(col, cpname, " (", timestr, ")");
 998         else
 999                 return strcat(col, cpname, " (", timestr, " ", strcat(hisname, col, lapstr), ")");
1000 }
1001
1002 void dummyfunction(float a1, float a2, float a3, float a4, float a5, float a6, float a7, float a8)
1003 {
1004 }
1005
1006 void Sbar_Score(float margin)
1007 {
1008         float timelimit, timeleft, minutes, seconds, distribution, myplace, score;
1009         vector sbar_save, place;
1010         entity tm, pl, me;
1011         sbar_save = sbar;
1012
1013         myteam = GetPlayerColor(player_localentnum - 1);
1014
1015         sbar_y = vid_conheight - (32+12);
1016         sbar_x -= margin;
1017
1018         place = '-48 -12 0';
1019         if(teamplay)
1020         {
1021                 // Layout:
1022                 //
1023                 //   team1 team3 team4
1024                 //
1025                 //         TEAM2
1026                 //for(i = 0; i < 4; ++i)
1027                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
1028                 {
1029                         if(tm.team == COLOR_SPECTATOR || !tm.team_size) // no players? don't display
1030                                 continue;
1031                         // -32*4 = -128
1032                         score = tm.(teamscores[ts_primary]);
1033                         if(tm.team == myteam)
1034                                 Sbar_DrawXNum('-128 0 0', score, 4, 32, GetTeamRGB(tm.team), 1, DRAWFLAG_NORMAL);
1035                         else
1036                         {
1037                                 Sbar_DrawXNum(place, score, 4, 12, GetTeamRGB(tm.team), 1, DRAWFLAG_NORMAL);
1038                                 place_x -= 4*12;
1039                         }
1040                 }
1041         } else {
1042                 // me vector := [team/connected frags id]
1043                 myplace = 0;
1044                 for(me = players.sort_next; me; me = me.sort_next)
1045                 {
1046                         if(me.team != COLOR_SPECTATOR)
1047                                 ++myplace;
1048                         if(me.sv_entnum == player_localentnum - 1)
1049                                 break;
1050                 }
1051                 pl = players;
1052                 if(pl == me)
1053                         pl = pl.sort_next;
1054
1055                 if(pl) {
1056                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
1057                 } else
1058                         distribution = 0;
1059
1060                 if(myplace == 1)
1061                         Sbar_DrawXNum('-36 -12 0', myplace, 3, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
1062                 else if(myplace == 2)
1063                         Sbar_DrawXNum('-36 -12 0', myplace, 3, 12, '1 1 0', 1, DRAWFLAG_NORMAL);
1064                 else
1065                         Sbar_DrawXNum('-36 -12 0', myplace, 3, 12, '1 0 0', 1, DRAWFLAG_NORMAL);
1066
1067                 score = me.(scores[ps_primary]);
1068                 if(distribution >= 0)
1069                 {
1070                         Sbar_DrawXNum('-84 -12 0', distribution, 4, 12, ' 1 1 1', 1, DRAWFLAG_NORMAL);
1071                         Sbar_DrawXNum('-128 0 0', score, 4, 32, '1 1 1', 1, DRAWFLAG_NORMAL);
1072                 } else if(distribution >= -5)
1073                 {
1074                         Sbar_DrawXNum('-84 -12 0', distribution, 4, 12, ' 1 1 0', 1, DRAWFLAG_NORMAL);
1075                         Sbar_DrawXNum('-128 0 0', score, 4, 32, '1 1 0', 1, DRAWFLAG_NORMAL);
1076                 } else {
1077                         Sbar_DrawXNum('-84 -12 0', distribution, 4, 12, ' 1 0 0', 1, DRAWFLAG_NORMAL);
1078                         Sbar_DrawXNum('-128 0 0', score, 4, 32, '1 0 0', 1, DRAWFLAG_NORMAL);
1079                 }
1080         }
1081         timelimit = getstatf(STAT_TIMELIMIT);
1082         if(timelimit)
1083         {
1084                 timeleft = max(0, timelimit * 60 - time);
1085                 minutes = floor(timeleft / 60);
1086                 seconds = floor(timeleft - minutes*60);
1087                 if(minutes >= 5)
1088                 {
1089                         Sbar_DrawXNum('-72 32 0', minutes, 3, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
1090                         drawpic(sbar + '-36 32 0', "gfx/num_colon", '12 12 0', '1 1 1', sbar_alpha_fg, 0);
1091                         Sbar_DrawXNum('-24 32 0', seconds, -2, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
1092                 } else if(minutes >= 1)
1093                 {
1094                         Sbar_DrawXNum('-72 32 0', minutes, 3, 12, '1 1 0', 1, DRAWFLAG_NORMAL);
1095                         drawpic(sbar + '-36 32 0', "gfx/num_colon", '12 12 0', '1 1 0', sbar_alpha_fg, 0);
1096                         Sbar_DrawXNum('-24 32 0', seconds, -2, 12, '1 1 0', 1, DRAWFLAG_NORMAL);
1097                 } else {
1098                         Sbar_DrawXNum('-24 32 0', seconds, -2, 12, '1 0 0', 1, DRAWFLAG_NORMAL);
1099                 }
1100         } else {
1101                 minutes = floor(time / 60);
1102                 seconds = floor(time - minutes*60);
1103                 Sbar_DrawXNum('-72 32 0', minutes, 3, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
1104                 drawpic(sbar + '-36 32 0', "gfx/num_colon", '12 12 0', '1 1 1', sbar_alpha_fg, 0);
1105                 Sbar_DrawXNum('-24 32 0', seconds, -2, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
1106         }
1107
1108         if(gametype == GAME_RACE)
1109         {
1110                 drawfont = sbar_bigfont;
1111                 float a;
1112                 vector m;
1113                 string s, forcetime;
1114
1115                 m = '0.5 0 0' * vid_conwidth + '0 0.25 0' * vid_conheight;
1116
1117                 if(race_checkpointtime)
1118                 {
1119
1120                         a = bound(0, 2 - (time - race_checkpointtime), 1);
1121                         s = "";
1122                         forcetime = "";
1123                         if(a > 0) // just hit a checkpoint?
1124                         {
1125                                 if(race_time && race_previousbesttime)
1126                                         s = MakeRaceString(race_checkpoint, race_time / 10 - race_previousbesttime / 10, 0, 0, race_previousbestname);
1127                                 else
1128                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
1129                                 if(race_time)
1130                                         forcetime = mmsss(race_time);
1131                         }
1132                         else
1133                         {
1134                                 if(race_laptime && race_nextbesttime)
1135                                 {
1136                                         a = bound(0, 2 - ((race_laptime + race_nextbesttime/10) - time), 1);
1137                                         if(a > 0) // next one?
1138                                         {
1139                                                 s = MakeRaceString(race_nextcheckpoint, time - race_laptime, race_nextbesttime / 10, 0, race_nextbestname);
1140                                         }
1141                                 }
1142                         }
1143
1144                         if(s != "" && a > 0)
1145                         {
1146                                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1147                                 drawcolorcodedstring(m - '0 16 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, 0);
1148                         }
1149
1150                         if(forcetime != "")
1151                         {
1152                                 float sz;
1153                                 a = bound(0, 1 - 2 * (time - race_checkpointtime), 1);
1154                                 sz = 1.2 / (a + 0.2);
1155                                 drawstring(m - '0 0 0' - '0 16 0' * (sz - 1) - '16 0 0' * sz * stringwidth(forcetime, FALSE), forcetime, '32 32 0' * sz, '1 1 1', sbar_alpha_fg * a, 0);
1156                                 a = 1 - a;
1157                         }
1158                         else
1159                                 a = 1;
1160
1161                         if(race_laptime)
1162                         {
1163                                 s = mmsss(10*(time - race_laptime));
1164                                 drawstring(m - '0 0 0' - '16 0 0' * stringwidth(s, FALSE), s, '32 32 0', '1 1 1', sbar_alpha_fg * a, 0);
1165                         }
1166                 }
1167                 else
1168                 {
1169                         if(race_mycheckpointtime)
1170                         {
1171                                 a = bound(0, 2 - (time - race_mycheckpointtime), 1);
1172                                 s = MakeRaceString(race_mycheckpoint, race_mycheckpointdelta / 10, -!race_mycheckpointenemy, race_mycheckpointlapsdelta, race_mycheckpointenemy);
1173                                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1174                                 drawcolorcodedstring(m - '0 16 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, 0);
1175                         }
1176                         if(race_othercheckpointtime && race_othercheckpointenemy != "")
1177                         {
1178                                 a = bound(0, 2 - (time - race_othercheckpointtime), 1);
1179                                 s = MakeRaceString(race_othercheckpoint, -race_othercheckpointdelta / 10, -!race_othercheckpointenemy, race_othercheckpointlapsdelta, race_othercheckpointenemy);
1180                                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1181                                 drawcolorcodedstring(m - '0 0 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, 0);
1182                         }
1183                 }
1184
1185                 drawfont = sbar_font;
1186         }
1187
1188         sbar = sbar_save;
1189 }
1190
1191 void Sbar_MiniscoreItem(vector pos, entity pl, float is_self)
1192 {
1193         float x, score;
1194         pos_x += 72;
1195
1196         if(teamplay)
1197                 drawfill(pos + '0 1 0', '40 6 0', GetTeamRGB(pl.team)*0.5, 1, DRAWFLAG_NORMAL);
1198         else
1199                 drawfill(pos + '0 1 0', '40 6 0', '0.5 0.5 0.5', 0.5, DRAWFLAG_NORMAL);
1200         x = pos_x;
1201         pos_x += 5*8;
1202         score = pl.(scores[ps_primary]);
1203         pos_x -= stringwidth(ftos(score), FALSE)*8;
1204         drawstring(pos, ftos(score), '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1205         pos_x = x;
1206         if(is_self)
1207         {
1208                 pos_x += 48;
1209                 drawstring(pos, "\x0D", '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1210                 pos_x += 8;
1211         } else
1212                 pos_x += 56;
1213         drawcolorcodedstring(pos, getplayerkey(pl.sv_entnum, "name"), '8 8 0', 1, 0);
1214 }
1215
1216 void Sbar_MiniscoreTeamItem(vector pos, float color, float frags, float is_self)
1217 {
1218         float x;
1219         pos_x += 72;
1220
1221         if(teamplay)
1222                 drawfill(pos + '0 1 0', '40 6 0', GetTeamRGB(color)*0.5, 1, DRAWFLAG_NORMAL);
1223         else
1224                 drawfill(pos + '0 1 0', '40 6 0', '0.5 0.5 0.5', 0.5, DRAWFLAG_NORMAL);
1225         x = pos_x;
1226         pos_x += 5*8;
1227         pos_x -= stringwidth(ftos(frags), FALSE)*8;
1228         drawstring(pos, ftos(frags), '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1229         pos_x = x;
1230         if(is_self)
1231         {
1232                 pos_x += 48;
1233                 drawstring(pos, "\x0D", '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1234                 pos_x += 8;
1235         } else
1236                 pos_x += 56;
1237         drawstring(pos, GetTeamName(color), '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1238 }
1239
1240 void Sbar_MiniDeathmatchOverlay(vector pos)
1241 {
1242         float numlines, up, down, score;
1243         entity me, tm, pl;
1244         float miniscoreboard_size;
1245         miniscoreboard_size = cvar("sbar_miniscoreboard_size");
1246
1247         if(miniscoreboard_size == 0)
1248                 return;
1249         pos_y = vid_conheight - 8;
1250
1251         if(miniscoreboard_size < 0)
1252                 numlines = (vid_conheight - sbar_y + 7) / 8;
1253         else
1254                 numlines = miniscoreboard_size;
1255
1256         // give up if there isn't enough room
1257         if(pos_x >= vid_conwidth || pos_y >= vid_conheight || numlines < 1)
1258                 return;
1259
1260         // me vector := [team/connected frags id]
1261         for(me = players.sort_next; me; me = me.sort_next)
1262         {
1263                 if(me.sv_entnum == player_localentnum - 1)
1264                         break;
1265         }
1266
1267         if(teamplay)
1268                 numlines -= numteams;
1269
1270         // figure out how many players above and below we can show
1271         up = floor(numlines/2);
1272         down = up;
1273         if((up + down) > numlines)
1274                 down = numlines - up;
1275
1276         // render bottom-up
1277         for(pl = me.sort_next; pl && down > 0; pl = pl.sort_next)
1278         {
1279                 if(pl.team == COLOR_SPECTATOR)
1280                         continue;
1281                 Sbar_MiniscoreItem(pos, pl, false);
1282                 pos_y -= 9;
1283                 --down;
1284         }
1285         Sbar_MiniscoreItem(pos, me, true);
1286         pos_y -= 9;
1287         up += down; // if there weren't enough lines below... add them
1288         for(pl = me.sort_prev; pl && up > 0; pl = pl.sort_prev)
1289         {
1290                 if(pl.team == COLOR_SPECTATOR)
1291                         continue;
1292                 Sbar_MiniscoreItem(pos, pl, false);
1293                 pos_y -= 9;
1294                 --up;
1295         }
1296
1297         if(teamplay)
1298         {
1299                 for(tm = teams.sort_next; tm.sort_next; tm = tm.sort_next);
1300                 for(; tm; tm = tm.sort_prev)
1301                 {
1302                         if(!tm.team_size || tm.team == COLOR_SPECTATOR)
1303                                 continue;
1304                         score = tm.(teamscores[ts_primary]);
1305                         Sbar_MiniscoreTeamItem(pos, tm.team, score, (tm.team == me.team));
1306                         pos_y -= 9;
1307                 }
1308         }
1309 }
1310
1311 float Sbar_WouldDrawScoreboard ()
1312 {
1313         if (sb_showscores)
1314                 return 1;
1315         else if (intermission == 1)
1316                 return 1;
1317         else if (intermission == 2)
1318                 return 1;
1319         else if (getstati(STAT_HEALTH) <= 0 && cvar("cl_deathscoreboard"))
1320                 return 1;
1321         else if(sb_showscores_force)
1322                 return 1;
1323         return 0;
1324 }
1325
1326 void Sbar_Draw (void)
1327 {
1328         float i;
1329         float x, fade;
1330         float stat_items, stat_weapons;
1331         vector o; o = '1 0 0' * vid_conwidth;
1332         string s;
1333
1334         sbar_fontsize = Sbar_GetFontsize();
1335
1336         if(warmup_stage)
1337         {
1338                 s = "^1Press ^3ready^1 to end warmup";
1339                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1340                 drawcolorcodedstring(
1341                         o - sbar_fontsize_x * '2 0 0' * stringwidth(s, TRUE),
1342                         s,
1343                         sbar_fontsize * 2,
1344                         sbar_alpha_fg,
1345                         0
1346                 );
1347                 o += sbar_fontsize_y * '0 2 0';
1348         }
1349
1350         if(spectatee_status)
1351         {
1352                 if(spectatee_status == -1)
1353                         s = "^1Observing";
1354                 else
1355                         s = strcat("^1Spectating ^7", getplayerkey(spectatee_status - 1, "name"));
1356                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1357                 drawcolorcodedstring(
1358                         o - sbar_fontsize_x * '1 0 0' * stringwidth(s, TRUE),
1359                         s,
1360                         sbar_fontsize,
1361                         sbar_alpha_fg,
1362                         0
1363                 );
1364                 o += sbar_fontsize_y * '0 1 0';
1365
1366                 if(spectatee_status == -1)
1367                         s = "^1Press ^3primary fire^1 to spectate";
1368                 else
1369                         s = "^1Press ^3primary fire^1 for another player";
1370                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1371                 drawcolorcodedstring(
1372                         o - sbar_fontsize_x * '1 0 0' * stringwidth(s, TRUE),
1373                         s,
1374                         sbar_fontsize,
1375                         sbar_alpha_fg,
1376                         0
1377                 );
1378                 o += sbar_fontsize_y * '0 1 0';
1379
1380                 if(spectatee_status == -1)
1381                         s = "^1Use ^3weapon switching^1 to change the speed";
1382                 else
1383                         s = "^1Press ^3secondary fire^1 to observe";
1384                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1385                 drawcolorcodedstring(
1386                         o - sbar_fontsize_x * '1 0 0' * stringwidth(s, TRUE),
1387                         s,
1388                         sbar_fontsize,
1389                         sbar_alpha_fg,
1390                         0
1391                 );
1392                 o += sbar_fontsize_y * '0 1 0';
1393
1394                 if(gametype == GAME_ARENA)
1395                         s = "^1Wait for your turn to join";
1396                 else if(gametype == GAME_LMS)
1397                 {
1398                         entity sk;
1399                         sk = playerslots[player_localentnum - 1];
1400                         if(sk.(scores[ps_primary]) >= 666)
1401                                 s = "^1Match has already begun";
1402                         else if(sk.(scores[ps_primary]) > 0)
1403                                 s = "^1You have no more lives left";
1404                         else
1405                                 s = "^1Press ^7jump^1 to join";
1406                 }
1407                 else
1408                         s = "^1Press ^7jump^1 to join";
1409                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1410                 drawcolorcodedstring(
1411                         o - sbar_fontsize_x * '1 0 0' * stringwidth(s, TRUE),
1412                         s,
1413                         sbar_fontsize,
1414                         sbar_alpha_fg,
1415                         0
1416                 );
1417                 o += sbar_fontsize_y * '0 1 0';
1418         }
1419
1420         //Sbar_SortFrags();
1421         Sbar_UpdatePlayerTeams();
1422
1423         sb_lines = 24;
1424
1425         if (sb_showscores)
1426                 Sbar_DrawScoreboard();
1427         else if (intermission == 1)
1428         {
1429                 Sbar_DrawScoreboard();
1430                 return;
1431         }
1432         else if (intermission == 2)
1433                 Sbar_FinaleOverlay();
1434         else
1435         {
1436                 if (sb_showscores || sb_showscores_force || (getstati(STAT_HEALTH) <= 0 && cvar("cl_deathscoreboard")))
1437                 {
1438                         sbar_x = (vid_conwidth - 640.0)*0.5;
1439                         sbar_y = vid_conheight - 47;
1440                         //Sbar_DrawAlphaPic (sbar_x, sbar_y, sb_scorebar, sbar_alpha_bg.value);
1441                         //drawpic('0 0 0', "gfx/scorebar", '0 0 0', '1 1 1', cvar("sbar_alpha_bg"), 0);
1442                         Sbar_DrawScoreboard ();
1443                 }
1444                 else
1445                 {
1446                         if (sb_lines && sbar_hudselector == 1)
1447                         {
1448                                 stat_items = getstati(STAT_ITEMS);
1449                                 stat_weapons = getstati(STAT_WEAPONS);
1450
1451                                 sbar_x = (vid_conwidth - 320.0)*0.5;
1452                                 sbar_y = vid_conheight - 24.0 - 16.0;
1453                                 sbar_z = 0;
1454
1455                                 fade = 3.2 - 2 * (time - weapontime);
1456                                 fade = bound(0.7, fade, 1);
1457
1458                                 x = 1.0;
1459                                 Sbar_DrawWeapon_Clear();
1460                                 for(i = 1; i <= 24; ++i)
1461                                 {
1462                                         if(weaponimpulse[i-1] >= 0)
1463                                         if(stat_weapons & x)
1464                                         {
1465                                                 Sbar_DrawWeapon(i-1, fade, (i == activeweapon));
1466                                         }
1467                                         x *= 2;
1468                                 }
1469
1470                                 // armor
1471                                 x = getstati(STAT_ARMOR);
1472                                 if (x > 0)
1473                                 {
1474                                         // "gfx/sb_armor"
1475                                         //Sbar_DrawStretchPic (72, 0, sb_armor[0], sbar_alpha_fg.value, 24, 24);
1476                                         drawpic(sbar + '72 0 0', "gfx/sb_armor", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1477                                         if(x > 200)
1478                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0 1 0', 1, 0);
1479                                         else if(x > 100)
1480                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0.2 1 0', 1, 0);
1481                                         else if(x > 50)
1482                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1483                                         else if(x > 25)
1484                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '1 1 0.2', 1, 0);
1485                                         else
1486                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0.7 0 0', 1, 0);
1487                                 }
1488
1489                                 // health
1490                                 x = getstati(STAT_HEALTH);
1491                                 if (x != 0)
1492                                 {
1493                                         // "gfx/sb_health"
1494                                         //Sbar_DrawStretchPic (184, 0, sb_health, sbar_alpha_fg.value, 24, 24);
1495                                         drawpic(sbar + '184 0 0', "gfx/sb_health", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1496                                         if(x > 200)
1497                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0 1 0', 1, 0);
1498                                         else if(x > 100)
1499                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0.2 1 0', 1, 0);
1500                                         else if(x > 50)
1501                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1502                                         else if(x > 25)
1503                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '1 1 0.2', 1, 0);
1504                                         else
1505                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0.7 0 0', 1, 0);
1506                                 }
1507
1508                                 // ammo
1509                                 x = getstati(STAT_AMMO);
1510                                 if ((stat_items & IT_AMMO) || x != 0)
1511                                 {
1512                                         if (stat_items & IT_SHELLS)
1513                                                 drawpic(sbar + '296 0 0', "gfx/sb_shells", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1514                                         else if (stat_items & IT_NAILS)
1515                                                 drawpic(sbar + '296 0 0', "gfx/sb_bullets", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1516                                         else if (stat_items & IT_ROCKETS)
1517                                                 drawpic(sbar + '296 0 0', "gfx/sb_rocket", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1518                                         else if (stat_items & IT_CELLS)
1519                                                 drawpic(sbar + '296 0 0', "gfx/sb_cells", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1520                                         if(x > 10)
1521                                                 Sbar_DrawXNum('224 0 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1522                                         else
1523                                                 Sbar_DrawXNum('224 0 0', x, 3, 24, '0.7 0 0', 1, 0);
1524                                 }
1525
1526                                 if (sbar_x + 320 + 160 <= vid_conwidth)
1527                                         Sbar_MiniDeathmatchOverlay(sbar + '320 0 0');
1528                                 if (sbar_x > 0)
1529                                         Sbar_Score(16);
1530                                 // The margin can be at most 8 to support 640x480 console size:
1531                                 //   320 + 2 * (144 + 16) = 640
1532                         }
1533                         else if (sb_lines)
1534                         {
1535
1536                                 stat_items = getstati(STAT_ITEMS);
1537                                 stat_weapons = getstati(STAT_WEAPONS);
1538
1539                                 sbar_x = (vid_conwidth - 640.0)*0.5;
1540                                 sbar_y = vid_conheight - 47;
1541                                 sbar_z = 0;
1542
1543                                 fade = 3 - 2 * (time - weapontime);
1544
1545                                 x = 1.0;
1546                                 Sbar_DrawWeapon_Clear();
1547                                 for(i = 1; i <= 24; ++i)
1548                                 {
1549                                         if(weaponimpulse[i-1] >= 0)
1550                                         if(stat_weapons & x)
1551                                         {
1552                                                 Sbar_DrawWeapon(i-1, fade, (i == activeweapon));
1553                                         }
1554                                         x *= 2;
1555                                 }
1556
1557                                 if (sb_lines > 24)
1558                                         drawpic(sbar, "gfx/sbar", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1559                                 else
1560                                         drawpic(sbar, "gfx/sbar_minimal", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1561
1562                                 // armor
1563                                 // (340-3*24) = 268
1564                                 Sbar_DrawXNum('268 12 0', getstati(STAT_ARMOR), 3, 24, '0.6 0.7 0.8', 1, 0);
1565
1566                                 // health
1567                                 // (154-3*24) = 82
1568                                 x = getstati(STAT_HEALTH);
1569                                 if(x > 100)
1570                                         Sbar_DrawXNum('82 12 0', x, 3, 24, '1 1 1', 1, 0);
1571                                 else if(x <= 25 && time - floor(time) > 0.5)
1572                                         Sbar_DrawXNum('82 12 0', x, 3, 24, '0.7 0 0', 1, 0);
1573                                 else
1574                                         Sbar_DrawXNum('81 12 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1575
1576                                 // AK dont draw ammo for the laser
1577                                 x = getstati(STAT_AMMO);
1578                                 if(activeweapon != 12)
1579                                 {
1580                                         // (519-3*24) = 447
1581                                         if (stat_items & IT_SHELLS)
1582                                                 drawpic(sbar + '519 0 0', "gfx/sb_shells", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1583                                         else if (stat_items & IT_NAILS)
1584                                                 drawpic(sbar + '519 0 0', "gfx/sb_bullets", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1585                                         else if (stat_items & IT_ROCKETS)
1586                                                 drawpic(sbar + '519 0 0', "gfx/sb_rocket", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1587                                         else if (stat_items & IT_CELLS)
1588                                                 drawpic(sbar + '519 0 0', "gfx/sb_cells", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1589                                         if(x > 10)
1590                                                 Sbar_DrawXNum('447 12 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1591                                         else
1592                                                 Sbar_DrawXNum('447 12 0', x, 3, 24, '0.7 0 0', 1, 0);
1593                                 }
1594
1595                                 if (sb_lines > 24)
1596                                         drawpic(sbar, "gfx/sbar_overlay", '0 0 0', '1 1 1', 1, DRAWFLAG_MODULATE);
1597
1598                                 if (sbar_x + 600 + 160 <= vid_conwidth)
1599                                         Sbar_MiniDeathmatchOverlay (sbar + '600 0 0');
1600
1601                                 if (sbar_x > 0)
1602                                         Sbar_Score(-16);
1603                                 // Because:
1604                                 //   Mini scoreboard uses 12*4 per other team, that is, 144
1605                                 //   pixels when there are four teams...
1606                                 //   Nexuiz by default sets vid_conwidth to 800... makes
1607                                 //   sbar_x == 80...
1608                                 //   so we need to shift it by 64 pixels to the right to fit
1609                                 //   BUT: then it overlaps with the image that gets drawn
1610                                 //   for viewsize 100! Therefore, just account for 3 teams,
1611                                 //   that is, 96 pixels mini scoreboard size, needing 16 pixels
1612                                 //   to the right!
1613                         }
1614
1615
1616                         if(gametype == GAME_KEYHUNT)
1617                         {
1618                                 CSQC_kh_hud();
1619                         } else if(gametype == GAME_CTF)
1620                         {
1621                                 CSQC_ctf_hud();
1622                         }
1623                 }
1624         }
1625 }
1626
1627 void CSQC_ctf_hud(void)
1628 {
1629         // cvar("sbar_flagstatus_right") move the flag icons right
1630         // cvar("sbar_flagstatus_pos") pixel position of the nexuiz flagstatus icons
1631         float redflag, blueflag;
1632         float stat_items;
1633         vector pos;
1634
1635         stat_items = getstati(STAT_ITEMS);
1636         redflag = (stat_items/32768) & 3;
1637         blueflag = (stat_items/131072) & 3;
1638
1639         /**
1640          * FTEQCC BUG!
1641          * For some reason now not even THAT works there...
1642          * Maybe the minus' precedence screws it up? The last one there, maybe I should use brackets
1643          **
1644          * pos_x = (cvar("sbar_flagstatus_right")) ? vid_conwidth - 10 - sbar_x - 64 : 10 - sbar_x;
1645          ** Should try those later:
1646          * pos_x = (cvar("sbar_flagstatus_right")) ? (vid_conwidth - 10 - sbar_x - 64) : (10 - sbar_x);
1647          * pos_x = ( (cvar("sbar_flagstatus_right")) ? vid_conwidth - 10 - 64 : 10 ) - sbar_x;
1648          */
1649
1650         if(cvar("sbar_flagstatus_right"))
1651                 pos_x = vid_conwidth - 10 - sbar_x - 64;
1652         else
1653                 pos_x = 10 - sbar_x;
1654
1655         pos_z = 0;
1656
1657         if(sbar_hudselector == 1)
1658                 pos_y = (vid_conheight - sbar_y) - cvar("sbar_flagstatus_pos") - 64;
1659         else
1660                 pos_y = -117;
1661
1662         pos += sbar;
1663
1664         switch(redflag)
1665         {
1666         case 1: drawpic(pos, "gfx/sb_flag_red_taken", '0 0 0', '1 1 1', 1, DRAWFLAG_NORMAL); break;
1667         case 2: drawpic(pos, "gfx/sb_flag_red_lost", '0 0 0', '1 1 1', 1, DRAWFLAG_NORMAL); break;
1668         case 3: drawpic(pos, "gfx/sb_flag_red_carrying", '0 0 0', '1 1 1', 1, DRAWFLAG_NORMAL); break;
1669         }
1670
1671         pos_y -= 64;
1672
1673         switch(blueflag)
1674         {
1675         case 1: drawpic(pos, "gfx/sb_flag_blue_taken", '0 0 0', '1 1 1', 1, 0); break;
1676         case 2: drawpic(pos, "gfx/sb_flag_blue_lost", '0 0 0', '1 1 1', 1, 0); break;
1677         case 3: drawpic(pos, "gfx/sb_flag_blue_carrying", '0 0 0', '1 1 1', 1, 0); break;
1678         }
1679 }