data/qcsrc/client/View.qc

   1 vector angles_held[24];\r
   2 void Net_ReadHoldAngles()\r
   3 {\r
   4         float wpn;\r
   5         vector v;\r
   6         wpn = ReadByte();\r
   7         --wpn;\r
   8         angles_held_status[wpn] = ReadByte();\r
   9         if(angles_held_status[wpn])\r
  10         {\r
  11                 v_x = ReadCoord();\r
  12                 v_y = ReadCoord();\r
  13                 v_z = 0;\r
  14                 angles_held[wpn] = v;\r
  15         }\r
  16 }\r
  17 \r
  18 entity porto;\r
  19 vector polyline[16];\r
  20 float trace_dphitcontents;\r
  21 float Q3SURFACEFLAG_SLICK = 2; // low friction surface\r
  22 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement\r
  23 void Porto_Draw()\r
  24 {\r
  25         vector p, dir, ang, q, nextdir;\r
  26         float idx, portal_number, portal1_idx;\r
  27 \r
  28         if(activeweapon != WEP_PORTO)\r
  29                 return;\r
  30 \r
  31         dir = view_forward;\r
  32 \r
  33         if(angles_held_status[WEP_PORTO-1])\r
  34         {\r
  35                 makevectors(angles_held[WEP_PORTO-1]);\r
  36                 dir = v_forward;\r
  37         }\r
  38 \r
  39         p = view_origin;\r
  40 \r
  41         polyline[0] = p;\r
  42         idx = 1;\r
  43         portal_number = 0;\r
  44         nextdir = dir;\r
  45 \r
  46         for(;;)\r
  47         {\r
  48                 dir = nextdir;\r
  49                 traceline(p, p + 65536 * dir, TRUE, world);\r
  50                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)\r
  51                         return;\r
  52                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal\r
  53                 p = trace_endpos;\r
  54                 polyline[idx] = p;\r
  55                 ++idx;\r
  56                 if(idx >= 16)\r
  57                         return;\r
  58                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)\r
  59                         continue;\r
  60                 ++portal_number;\r
  61                 ang = vectoangles2(trace_plane_normal, dir);\r
  62                 ang_x = -ang_x;\r
  63                 makevectors(ang);\r
  64                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))\r
  65                         return;\r
  66                 if(portal_number == 1)\r
  67                         portal1_idx = idx;\r
  68                 if(portal_number >= 2)\r
  69                         break;\r
  70         }\r
  71 \r
  72         while(idx >= 2)\r
  73         {\r
  74                 p = polyline[idx-2];\r
  75                 q = polyline[idx-1];\r
  76                 if(idx == 2)\r
  77                         p = p - view_up * 16;\r
  78                 if(idx-1 >= portal1_idx)\r
  79                 {\r
  80                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL);\r
  81                 }\r
  82                 else\r
  83                 {\r
  84                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL);\r
  85                 }\r
  86                 --idx;\r
  87         }\r
  88 }\r
  89 \r
  90 float DPCONTENTS_SOLID = 1; // hit a bmodel, not a bounding box\r
  91 float DPCONTENTS_BODY = 32; // hit a bounding box, not a bmodel\r
  92 void Porto_Init()\r
  93 {\r
  94         porto = spawn();\r
  95         porto.classname = "porto";\r
  96         porto.draw = Porto_Draw;\r
  97         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;\r
  98 }\r
  99 \r
 100 float drawtime;\r
 101 \r
 102 float tan(float x)\r
 103 { \r
 104         return sin(x) / cos(x);\r
 105 }\r
 106 float atan2(float y, float x)\r
 107 {\r
 108         vector v;\r
 109         v = '1 0 0' * x + '0 1 0' * y;\r
 110         v = vectoangles(v);\r
 111         return v_y * 0.01745329251994329576;\r
 112 }\r
 113 \r
 114 vector GetCurrentFov(float fov)\r
 115 {\r
 116         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;\r
 117 \r
 118         zoomsensitivity = cvar("cl_zoomsensitivity");\r
 119         zoomfactor = cvar("cl_zoomfactor");\r
 120         if(zoomfactor < 1 || zoomfactor > 16)\r
 121                 zoomfactor = 2.5;\r
 122         zoomspeed = cvar("cl_zoomspeed");\r
 123         if(zoomspeed >= 0)\r
 124                 if(zoomspeed < 0.5 || zoomspeed > 16)\r
 125                         zoomspeed = 3.5;\r
 126 \r
 127         zoomdir = button_zoom;\r
 128         if(getstati(STAT_ACTIVEWEAPON) == WEP_NEX) // do NOT use switchweapon here\r
 129                 zoomdir += button_attack2;\r
 130         if(spectatee_status > 0 || isdemo())\r
 131         {\r
 132                 if(spectatorbutton_zoom)\r
 133                         zoomdir = 0 + !zoomdir;\r
 134                         // do not even THINK about removing this 0\r
 135                         // _I_ know what I am doing\r
 136                         // fteqcc does not\r
 137         }\r
 138 \r
 139         if(zoomdir)\r
 140                 zoomin_effect = 0;\r
 141 \r
 142         if(zoomin_effect)\r
 143         {\r
 144                 current_viewzoom = min(1, current_viewzoom + drawframetime);\r
 145         }\r
 146         else\r
 147         {\r
 148                 if(zoomspeed < 0) // instant zoom\r
 149                 {\r
 150                         if(zoomdir)\r
 151                                 current_viewzoom = 1 / zoomfactor;\r
 152                         else\r
 153                                 current_viewzoom = 1;\r
 154                 }\r
 155                 else\r
 156                 {\r
 157                         if(zoomdir)\r
 158                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);\r
 159                         else\r
 160                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);\r
 161                 }\r
 162         }\r
 163 \r
 164         if(almost_equals(current_viewzoom, 1))\r
 165                 current_zoomfraction = 0;\r
 166         else if(almost_equals(current_viewzoom, 1/zoomfactor))\r
 167                 current_zoomfraction = 1;\r
 168         else\r
 169                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);\r
 170 \r
 171         if(zoomsensitivity < 1)\r
 172                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));\r
 173         else\r
 174                 setsensitivityscale(1);\r
 175 \r
 176         float frustumx, frustumy, fovx, fovy;\r
 177         frustumy = tan(fov * 0.00872664625997164788) * 0.75 * current_viewzoom;\r
 178         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;\r
 179         fovx = atan2(frustumx, 1) / 0.00872664625997164788;\r
 180         fovy = atan2(frustumy, 1) / 0.00872664625997164788;\r
 181 \r
 182         return '1 0 0' * fovx + '0 1 0' * fovy;\r
 183 }\r
 184 \r
 185 void CSQC_common_hud(void);\r
 186 \r
 187 void CSQC_kh_hud(void);\r
 188 void CSQC_ctf_hud(void);\r
 189 void PostInit(void);\r
 190 float Sbar_WouldDrawScoreboard ();\r
 191 float zoomscript_caught;\r
 192 float view_set;\r
 193 void CSQC_UpdateView(float w, float h)\r
 194 {\r
 195         entity e;\r
 196         float fov;\r
 197         float f;\r
 198         vector v1, v2;\r
 199 \r
 200         dprint_load();\r
 201         WaypointSprite_Load();\r
 202 \r
 203         // Render the Scene\r
 204         if(!intermission || !view_set)\r
 205         {\r
 206                 view_origin = pmove_org + '0 0 1' * getstati(STAT_VIEWHEIGHT);\r
 207                 view_angles = input_angles;\r
 208                 makevectors(view_angles);\r
 209                 view_forward = v_forward;\r
 210                 view_right = v_right;\r
 211                 view_up = v_up;\r
 212                 view_set = 1;\r
 213         }\r
 214 \r
 215         f = floor(cvar("v_flipped"));\r
 216         cvar_set("v_flipped", ftos(!f));\r
 217         v1 = cs_unproject('-100 -100 1000');\r
 218         cvar_set("v_flipped", ftos(f));\r
 219         v2 = cs_unproject('-100 -100 1000');\r
 220 \r
 221         if(v1 == v2)\r
 222         {\r
 223                 // non-supporting engine\r
 224                 vid_width = cvar("vid_width");\r
 225                 vid_height = cvar("vid_height");\r
 226         }\r
 227         else\r
 228         {\r
 229                 // supporting engine\r
 230                 vid_width = w;\r
 231                 vid_height = h;\r
 232         }\r
 233 \r
 234         Fog_Force();\r
 235 \r
 236         drawframetime = max(0.000001, time - drawtime);\r
 237         drawtime = time;\r
 238 \r
 239         // watch for gametype changes here...\r
 240         // in ParseStuffCMD the cmd isn't executed yet :/\r
 241         // might even be better to add the gametype to TE_CSQC_INIT...?\r
 242         if(!postinit)\r
 243                 PostInit();\r
 244 \r
 245         fov = cvar("fov");\r
 246         if(button_zoom || fov <= 59.5)\r
 247         {\r
 248                 if(!zoomscript_caught)\r
 249                 {\r
 250                         localcmd("+button4\n");\r
 251                         zoomscript_caught = 1;\r
 252                         ignore_plus_zoom += 1;\r
 253                 }\r
 254         }\r
 255         else\r
 256         {\r
 257                 if(zoomscript_caught)\r
 258                 {\r
 259                         localcmd("-button4\n");\r
 260                         zoomscript_caught = 0;\r
 261                         ignore_minus_zoom += 1;\r
 262                 }\r
 263         }\r
 264         \r
 265         sbar_alpha_fg = cvar("sbar_alpha_fg" );\r
 266         sbar_hudselector = cvar("sbar_hudselector");\r
 267         ColorTranslateMode = cvar("cl_stripcolorcodes");\r
 268         activeweapon = getstati(STAT_SWITCHWEAPON);\r
 269         f = cvar("teamplay");\r
 270         if(f != teamplay)\r
 271         {\r
 272                 teamplay = f;\r
 273                 Sbar_InitScores();\r
 274         }\r
 275 \r
 276         if(last_weapon != activeweapon) {\r
 277                 weapontime = time;\r
 278                 last_weapon = activeweapon;\r
 279         }\r
 280 \r
 281         // ALWAYS Clear Current Scene First\r
 282         R_ClearScene();\r
 283 \r
 284         // Assign Standard Viewflags\r
 285         // Draw the World (and sky)\r
 286         R_SetView(VF_DRAWWORLD, 1);\r
 287 \r
 288         R_SetView(VF_FOV, GetCurrentFov(fov));\r
 289         \r
 290         // Draw the Crosshair\r
 291         float scoreboard_active;\r
 292         scoreboard_active = Sbar_WouldDrawScoreboard();\r
 293         R_SetView(VF_DRAWCROSSHAIR, !scoreboard_active && !ons_showmap);\r
 294         \r
 295         // Draw the Engine Status Bar (the default Quake HUD)\r
 296         R_SetView(VF_DRAWENGINESBAR, 0);\r
 297 \r
 298         // Set the console size vars\r
 299         vid_conwidth = cvar("vid_conwidth");\r
 300         vid_conheight = cvar("vid_conheight");\r
 301         vid_pixelheight = cvar("vid_pixelheight");\r
 302 \r
 303         // fetch this one only once per frame\r
 304         sbar_showbinds = cvar("sbar_showbinds");\r
 305         sbar_showbinds_limit = cvar("sbar_showbinds_limit");\r
 306 \r
 307         // Update the mouse position\r
 308         /*\r
 309         mousepos_x = vid_conwidth;\r
 310         mousepos_y = vid_conheight;\r
 311         mousepos = mousepos*0.5 + getmousepos();\r
 312         */\r
 313 \r
 314         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);\r
 315 \r
 316         e = self;\r
 317         for(self = world; (self = nextent(self)); )\r
 318                 if(self.draw)\r
 319                         self.draw();\r
 320         self = e;\r
 321         R_RenderScene();\r
 322 \r
 323         // now switch to 2D drawing mode by calling a 2D drawing function\r
 324         // then polygon drawing will draw as 2D stuff, and NOT get queued until the\r
 325         // next R_RenderScene call\r
 326         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);\r
 327 \r
 328         // Draw the mouse cursor\r
 329         // NOTE: drawpic must happen after R_RenderScene for some reason\r
 330         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);\r
 331         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);\r
 332         //self = edict_num(player_localnum);\r
 333         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);\r
 334         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);\r
 335         // as long as the ctf part isn't in, this is useless\r
 336         if(menu_visible)\r
 337                 menu_show();\r
 338         \r
 339         /*if(gametype == GAME_CTF)\r
 340         {\r
 341                 ctf_view();\r
 342         } else */\r
 343 \r
 344         // draw 2D entities\r
 345         e = self;\r
 346         for(self = world; (self = nextent(self)); )\r
 347                 if(self.draw2d)\r
 348                         self.draw2d();\r
 349         self = e;\r
 350         \r
 351         // draw radar\r
 352         if(teamplay)\r
 353         {\r
 354                 if((cvar_string("cl_teamradar") != "0" && !scoreboard_active) || ons_showmap)\r
 355                         teamradar_view();\r
 356         }\r
 357 \r
 358         // draw sbar\r
 359         if(cvar("r_letterbox") == 0)\r
 360         if(cvar("viewsize") < 120)\r
 361                 CSQC_common_hud();\r
 362 }\r
 363 \r
 364 void Sbar_Draw();\r
 365 void CSQC_common_hud(void)\r
 366 {\r
 367         // Sbar_SortFrags(); done in Sbar_Draw\r
 368         Sbar_Draw();\r
 369 }\r
 370 \r
 371 // KeyHunt HUD by victim\r
 372 void CSQC_kh_hud(void)\r
 373 {\r
 374         // HUD 0 has the weapons on the right hand side - temporarily shown when needed\r
 375         // HUD 1 has the weapons on the bottom - permanently\r
 376 \r
 377         // use the following two binds to check the icons move correctly\r
 378         // bind g "toggle sbar_flagstatus_right; echo Menu right $sbar_flagstatus_right"  // move the icons\r
 379         // bind h "toggle sbar_hudselector; echo HUD $sbar_hudselector"  // change the HUD\r
 380 \r
 381         float kh_keys, kh_keys_status, kh_teams_set;\r
 382         float kh_margin_x, kh_margin_y, kh_key_box;\r
 383         string kh_carrying, kh_outline;\r
 384         vector red_pos, blue_pos, yellow_pos, pink_pos, kh_size;\r
 385         vector red, blue, yellow, pink;\r
 386 \r
 387         kh_keys = getstati(STAT_KH_KEYS);\r
 388         kh_keys_status = kh_keys / 256;\r
 389         kh_teams_set = cvar("_teams_available");  // set in keyhunt.qc\r
 390 \r
 391         kh_margin_y = 8;\r
 392         kh_margin_x = (cvar("sbar_flagstatus_right") * sbar_hudselector * (vid_conwidth - 67)) + 10;\r
 393 //      sbar_flagstatus_right 0/1; sbar_hudselector 0/1; screen width - key width + margin\r
 394 \r
 395         red_pos_x = blue_pos_x = yellow_pos_x = pink_pos_x = kh_margin_x;\r
 396 \r
 397         kh_key_box = 120;\r
 398 \r
 399         pink_pos_y = kh_margin_y + 0;  // top\r
 400         yellow_pos_y = kh_margin_y + kh_key_box;\r
 401         blue_pos_y = kh_margin_y + kh_key_box * 2;\r
 402         red_pos_y = kh_margin_y + kh_key_box * 3;  //bottom\r
 403 \r
 404         red = '1 0 0';\r
 405         blue = '0 0 1';\r
 406         yellow = '1 1 0';\r
 407         pink = '1 0 1';\r
 408 \r
 409         kh_size = '0 0 0';  // don't resize the image\r
 410 \r
 411         kh_carrying = "gfx/sb_kh_full";\r
 412         kh_outline = "gfx/sb_kh_outline";\r
 413 \r
 414 //      drawpic(vector position, string pic, vector size, vector rgb, float alpha, float flag)\r
 415 //      vector position = '0 0';  // 'x y' 0 0 (the origin) is the top left. X 0 - 799, Y 0 - 599\r
 416 \r
 417 //      vector size = '0 0';  // 'x y' changes the x & y dimensions. '0 0' gives the default pic size\r
 418 //      vector rgb = '0 0 0';  // 'r g b' range 0 - 1\r
 419 \r
 420         if (kh_keys_status & 1)  // red\r
 421                 drawpic (red_pos, kh_carrying, kh_size, red, 0.2, 0);  // show 20% alpha key\r
 422         else\r
 423                 drawpic (red_pos, kh_outline, kh_size, red, 0.4, 0);  // show key outline 40% alpha\r
 424 \r
 425         if (kh_keys & 1)\r
 426                 drawpic (red_pos, kh_carrying, kh_size, red, 1.0, 0);  // show solid key 100% alpha\r
 427 \r
 428 \r
 429         if (kh_keys_status & 2)  // blue\r
 430                 drawpic (blue_pos, kh_carrying, kh_size, blue, 0.2, 0);\r
 431         else\r
 432                 drawpic (blue_pos, kh_outline, kh_size, blue, 0.4, 0);\r
 433 \r
 434         if (kh_keys & 2)\r
 435                 drawpic (blue_pos, kh_carrying, kh_size, blue, 1.0, 0);\r
 436 \r
 437 \r
 438         if (kh_teams_set & 4)  // yellow\r
 439         {\r
 440                 if (kh_keys_status & 4)\r
 441                         drawpic (yellow_pos, kh_carrying, kh_size, yellow, 0.2, 0);\r
 442                 else\r
 443                         drawpic (yellow_pos, kh_outline, kh_size, yellow, 0.4, 0);\r
 444 \r
 445                 if (kh_keys & 4)\r
 446                         drawpic (yellow_pos, kh_carrying, kh_size, yellow, 1.0, 0);\r
 447         }\r
 448 \r
 449 \r
 450         if (kh_teams_set & 8)  // pink\r
 451         {\r
 452                 if (kh_keys_status & 8)\r
 453                         drawpic (pink_pos, kh_carrying, kh_size, pink, 0.2, 0);\r
 454                 else\r
 455                         drawpic (pink_pos, kh_outline, kh_size, pink, 0.4, 0);\r
 456 \r
 457                 if (kh_keys & 8)\r
 458                         drawpic (pink_pos, kh_carrying, kh_size, pink, 1.0, 0);\r
 459         }\r
 460 \r
 461 }\r