data/qcsrc/client/View.qc

   1 entity porto;\r
   2 vector polyline[16];\r
   3 float trace_dphitcontents;\r
   4 float Q3SURFACEFLAG_SLICK = 2; // low friction surface\r
   5 float DPCONTENTS_SOLID = 1; // blocks player movement\r
   6 float DPCONTENTS_BODY = 32; // blocks player movement\r
   7 float DPCONTENTS_CORPSE = 64; // blocks player movement\r
   8 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement\r
   9 void Porto_Draw()\r
  10 {\r
  11         vector p, dir, ang, q, nextdir;\r
  12         float idx, portal_number, portal1_idx;\r
  13 \r
  14         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)\r
  15                 return;\r
  16         if(intermission == 1)\r
  17                 return;\r
  18         if(intermission == 2)\r
  19                 return;\r
  20         if (getstati(STAT_HEALTH) <= 0)\r
  21                 return;\r
  22 \r
  23         dir = view_forward;\r
  24 \r
  25         if(angles_held_status)\r
  26         {\r
  27                 makevectors(angles_held);\r
  28                 dir = v_forward;\r
  29         }\r
  30 \r
  31         p = view_origin;\r
  32 \r
  33         polyline[0] = p;\r
  34         idx = 1;\r
  35         portal_number = 0;\r
  36         nextdir = dir;\r
  37 \r
  38         for(;;)\r
  39         {\r
  40                 dir = nextdir;\r
  41                 traceline(p, p + 65536 * dir, TRUE, porto);\r
  42                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)\r
  43                         return;\r
  44                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal\r
  45                 p = trace_endpos;\r
  46                 polyline[idx] = p;\r
  47                 ++idx;\r
  48                 if(idx >= 16)\r
  49                         return;\r
  50                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)\r
  51                         continue;\r
  52                 ++portal_number;\r
  53                 ang = vectoangles2(trace_plane_normal, dir);\r
  54                 ang_x = -ang_x;\r
  55                 makevectors(ang);\r
  56                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))\r
  57                         return;\r
  58                 if(portal_number == 1)\r
  59                         portal1_idx = idx;\r
  60                 if(portal_number >= 2)\r
  61                         break;\r
  62         }\r
  63 \r
  64         while(idx >= 2)\r
  65         {\r
  66                 p = polyline[idx-2];\r
  67                 q = polyline[idx-1];\r
  68                 if(idx == 2)\r
  69                         p = p - view_up * 16;\r
  70                 if(idx-1 >= portal1_idx)\r
  71                 {\r
  72                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL);\r
  73                 }\r
  74                 else\r
  75                 {\r
  76                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL);\r
  77                 }\r
  78                 --idx;\r
  79         }\r
  80 }\r
  81 \r
  82 /**\r
  83  * Checks whether the server initiated a map restart (stat_game_starttime changed)\r
  84  *\r
  85  * TODO: Use a better solution where a common shared entitiy is used that contains\r
  86  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT\r
  87  * and STAT_FRAGLIMIT to be auto-sent)\r
  88  */\r
  89 void CheckForGamestartChange() {\r
  90         float startTime;\r
  91         startTime = getstatf(STAT_GAMESTARTTIME);\r
  92         if (previous_game_starttime != startTime) {\r
  93                 if ((time + 5.0) < startTime) {\r
  94                         //if connecting to server while restart was active don't always play prepareforbattle\r
  95                         sound(self, CHAN_VOICE, "announcer/robotic/prepareforbattle.wav", VOL_BASEVOICE, ATTN_NONE);\r
  96                 }\r
  97                 if (time < startTime) {\r
  98                         restartAnnouncer = spawn();\r
  99                         restartAnnouncer.think = restartAnnouncer_Think;\r
 100                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime\r
 101                 }\r
 102         }\r
 103         previous_game_starttime = startTime;\r
 104 }\r
 105 \r
 106 void Porto_Init()\r
 107 {\r
 108         porto = spawn();\r
 109         porto.classname = "porto";\r
 110         porto.draw = Porto_Draw;\r
 111         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;\r
 112 }\r
 113 \r
 114 float drawtime;\r
 115 \r
 116 float tan(float x)\r
 117 {\r
 118         return sin(x) / cos(x);\r
 119 }\r
 120 float atan2(float y, float x)\r
 121 {\r
 122         vector v;\r
 123         v = '1 0 0' * x + '0 1 0' * y;\r
 124         v = vectoangles(v);\r
 125         return v_y * 0.01745329251994329576;\r
 126 }\r
 127 \r
 128 vector GetCurrentFov(float fov)\r
 129 {\r
 130         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;\r
 131 \r
 132         zoomsensitivity = cvar("cl_zoomsensitivity");\r
 133         zoomfactor = cvar("cl_zoomfactor");\r
 134         if(zoomfactor < 1 || zoomfactor > 16)\r
 135                 zoomfactor = 2.5;\r
 136         zoomspeed = cvar("cl_zoomspeed");\r
 137         if(zoomspeed >= 0)\r
 138                 if(zoomspeed < 0.5 || zoomspeed > 16)\r
 139                         zoomspeed = 3.5;\r
 140 \r
 141         zoomdir = button_zoom;\r
 142         if(getstati(STAT_ACTIVEWEAPON) == WEP_NEX) // do NOT use switchweapon here\r
 143                 zoomdir += button_attack2;\r
 144         if(spectatee_status > 0 || isdemo())\r
 145         {\r
 146                 if(spectatorbutton_zoom)\r
 147                         zoomdir = 0 + !zoomdir;\r
 148                         // do not even THINK about removing this 0\r
 149                         // _I_ know what I am doing\r
 150                         // fteqcc does not\r
 151         }\r
 152 \r
 153         if(zoomdir)\r
 154                 zoomin_effect = 0;\r
 155 \r
 156         if(zoomin_effect || camera_active)\r
 157         {\r
 158                 current_viewzoom = min(1, current_viewzoom + drawframetime);\r
 159         }\r
 160         else\r
 161         {\r
 162                 if(zoomspeed < 0) // instant zoom\r
 163                 {\r
 164                         if(zoomdir)\r
 165                                 current_viewzoom = 1 / zoomfactor;\r
 166                         else\r
 167                                 current_viewzoom = 1;\r
 168                 }\r
 169                 else\r
 170                 {\r
 171                         if(zoomdir)\r
 172                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);\r
 173                         else\r
 174                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);\r
 175                 }\r
 176         }\r
 177 \r
 178         if(almost_equals(current_viewzoom, 1))\r
 179                 current_zoomfraction = 0;\r
 180         else if(almost_equals(current_viewzoom, 1/zoomfactor))\r
 181                 current_zoomfraction = 1;\r
 182         else\r
 183                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);\r
 184 \r
 185         if(zoomsensitivity < 1)\r
 186                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));\r
 187         else\r
 188                 setsensitivityscale(1);\r
 189 \r
 190         float frustumx, frustumy, fovx, fovy;\r
 191         frustumy = tan(fov * 0.00872664625997164788) * 0.75 * current_viewzoom;\r
 192         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;\r
 193         fovx = atan2(frustumx, 1) / 0.00872664625997164788;\r
 194         fovy = atan2(frustumy, 1) / 0.00872664625997164788;\r
 195 \r
 196         return '1 0 0' * fovx + '0 1 0' * fovy;\r
 197 }\r
 198 \r
 199 // this function must match W_SetupShot!\r
 200 float zoomscript_caught;\r
 201 entity trueaim;\r
 202 void TrueAim_Init()\r
 203 {\r
 204         trueaim = spawn();\r
 205         trueaim.classname = "trueaim";\r
 206         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;\r
 207 }\r
 208 \r
 209 float TrueAimCheck()\r
 210 {\r
 211         float nudge = 1; // added to traceline target and subtracted from result\r
 212         vector vecs, trueaimpoint, w_shotorg;\r
 213         vector mi, ma, dv;\r
 214 \r
 215         mi = ma = '0 0 0';\r
 216 \r
 217         switch(activeweapon)\r
 218         {\r
 219                 case WEP_PORTO: // shoots from eye\r
 220                 case WEP_HOOK: // no trueaim\r
 221                 case WEP_GRENADE_LAUNCHER: // toss curve\r
 222                         return 1;\r
 223                 case WEP_CAMPINGRIFLE:\r
 224                         if(zoomscript_caught)\r
 225                                 return 1; // shoots from eye when zoomed\r
 226                         break;\r
 227                 case WEP_ROCKET_LAUNCHER: // projectile has a size!\r
 228                         mi = '-3 -3 -3';\r
 229                         ma = '3 3 3';\r
 230                         break;\r
 231                 case WEP_SEEKER: // projectile has a size!\r
 232                         mi = '-2 -2 -2';\r
 233                         ma = '2 2 2';\r
 234                         break;\r
 235                 case WEP_ELECTRO: // projectile has a size!\r
 236                         mi = '0 0 -3';\r
 237                         ma = '0 0 -3';\r
 238                         break;\r
 239         }\r
 240 \r
 241         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));\r
 242 \r
 243         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, MOVE_NOMONSTERS, trueaim);\r
 244         trueaimpoint = trace_endpos;\r
 245 \r
 246         if(vecs_x > 0)\r
 247                 vecs_y = -vecs_y;\r
 248         else\r
 249                 vecs = '0 0 0';\r
 250 \r
 251         dv = view_right * vecs_y + view_up * vecs_z;\r
 252         w_shotorg = view_origin + dv;\r
 253 \r
 254         // now move the vecs forward as much as requested if possible\r
 255         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, trueaim); // FIXME this MOVE_NORMAL part will misbehave a little in csqc\r
 256         w_shotorg = trace_endpos - view_forward * nudge;\r
 257         \r
 258         // now test whether we will actually hit the trueaimpoint...\r
 259         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NOMONSTERS, trueaim);\r
 260 \r
 261         return vlen(trace_endpos - trueaimpoint) <= vlen(ma - mi) + 1;\r
 262                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace\r
 263 }\r
 264 \r
 265 void CSQC_common_hud(void);\r
 266 \r
 267 void CSQC_kh_hud(void);\r
 268 void CSQC_ctf_hud(void);\r
 269 void PostInit(void);\r
 270 void CSQC_Demo_Camera();\r
 271 float Sbar_WouldDrawScoreboard ();\r
 272 float view_set;\r
 273 float camera_mode;\r
 274 string NextFrameCommand;\r
 275 void CSQC_UpdateView(float w, float h)\r
 276 {\r
 277         entity e;\r
 278         float fov;\r
 279         float f, i, j;\r
 280 \r
 281         dprint_load();\r
 282         WaypointSprite_Load();\r
 283 \r
 284         ticrate = getstatf(STAT_SYS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);\r
 285 \r
 286         // Render the Scene\r
 287         if(!intermission || !view_set)\r
 288         {\r
 289                 view_origin = pmove_org + '0 0 1' * getstati(STAT_VIEWHEIGHT);\r
 290                 view_angles = input_angles;\r
 291                 makevectors(view_angles);\r
 292                 view_forward = v_forward;\r
 293                 view_right = v_right;\r
 294                 view_up = v_up;\r
 295                 view_set = 1;\r
 296         }\r
 297 \r
 298         vid_width = w;\r
 299         vid_height = h;\r
 300 \r
 301 #ifdef BLURTEST\r
 302         if(time > blurtest_time0 && time < blurtest_time1)\r
 303         {\r
 304                 float r, t;\r
 305 \r
 306                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);\r
 307                 r = t * blurtest_radius;\r
 308                 f = 1 / pow(t, blurtest_power) - 1;\r
 309 \r
 310                 cvar_set("r_glsl_postprocess", "1");\r
 311                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));\r
 312         }\r
 313         else\r
 314         {\r
 315                 cvar_set("r_glsl_postprocess", "0");\r
 316                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");\r
 317         }\r
 318 #endif\r
 319 \r
 320         Fog_Force();\r
 321 \r
 322         drawframetime = max(0.000001, time - drawtime);\r
 323         drawtime = time;\r
 324 \r
 325         // watch for gametype changes here...\r
 326         // in ParseStuffCMD the cmd isn't executed yet :/\r
 327         // might even be better to add the gametype to TE_CSQC_INIT...?\r
 328         if(!postinit)\r
 329                 PostInit();\r
 330 \r
 331         CheckForGamestartChange();\r
 332         maptimeAnnouncer();\r
 333 \r
 334         fov = cvar("fov");\r
 335         if(button_zoom || fov <= 59.5)\r
 336         {\r
 337                 if(!zoomscript_caught)\r
 338                 {\r
 339                         localcmd("+button4\n");\r
 340                         zoomscript_caught = 1;\r
 341                         ignore_plus_zoom += 1;\r
 342                 }\r
 343         }\r
 344         else\r
 345         {\r
 346                 if(zoomscript_caught)\r
 347                 {\r
 348                         localcmd("-button4\n");\r
 349                         zoomscript_caught = 0;\r
 350                         ignore_minus_zoom += 1;\r
 351                 }\r
 352         }\r
 353 \r
 354         sbar_alpha_fg = cvar("sbar_alpha_fg" );\r
 355         sbar_hudselector = cvar("sbar_hudselector");\r
 356         sbar_hud_accuracy = cvar("sbar_hud_accuracy");\r
 357         ColorTranslateMode = cvar("cl_stripcolorcodes");\r
 358         activeweapon = getstati(STAT_SWITCHWEAPON);\r
 359         f = cvar("teamplay");\r
 360         if(f != teamplay)\r
 361         {\r
 362                 teamplay = f;\r
 363                 Sbar_InitScores();\r
 364         }\r
 365 \r
 366         if(last_weapon != activeweapon) {\r
 367                 weapontime = time;\r
 368                 last_weapon = activeweapon;\r
 369         }\r
 370 \r
 371         // ALWAYS Clear Current Scene First\r
 372         R_ClearScene();\r
 373 \r
 374         // Assign Standard Viewflags\r
 375         // Draw the World (and sky)\r
 376         R_SetView(VF_DRAWWORLD, 1);\r
 377 \r
 378         // Set the console size vars\r
 379         vid_conwidth = cvar("vid_conwidth");\r
 380         vid_conheight = cvar("vid_conheight");\r
 381         vid_pixelheight = cvar("vid_pixelheight");\r
 382 \r
 383         R_SetView(VF_FOV, GetCurrentFov(fov));\r
 384 \r
 385         // Camera for demo playback\r
 386         if(camera_active)\r
 387         {\r
 388                 if(cvar("camera_enable"))\r
 389                         CSQC_Demo_Camera();\r
 390                 else\r
 391                 {\r
 392                         cvar_set("chase_active", ftos(chase_active_backup));\r
 393                         cvar_set("cl_demo_mousegrab", "0");\r
 394                         camera_active = FALSE;\r
 395                 }\r
 396         }\r
 397 #ifdef CAMERATEST\r
 398         else if(cvar("camera_enable"))\r
 399 #else\r
 400         else if(cvar("camera_enable") && isdemo())\r
 401 #endif\r
 402         {\r
 403                 // Enable required Darkplaces cvars\r
 404                 chase_active_backup = cvar("chase_active");\r
 405                 cvar_set("chase_active", "2");\r
 406                 cvar_set("cl_demo_mousegrab", "1");\r
 407                 camera_active = TRUE;\r
 408                 camera_mode = FALSE;\r
 409         }\r
 410 \r
 411         // Draw the Crosshair\r
 412         float scoreboard_active;\r
 413         scoreboard_active = Sbar_WouldDrawScoreboard();\r
 414         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden\r
 415 \r
 416         // Draw the Engine Status Bar (the default Quake HUD)\r
 417         R_SetView(VF_DRAWENGINESBAR, 0);\r
 418 \r
 419         // fetch this one only once per frame\r
 420         sbar_showbinds = cvar("sbar_showbinds");\r
 421         sbar_showbinds_limit = cvar("sbar_showbinds_limit");\r
 422 \r
 423         // Update the mouse position\r
 424         /*\r
 425         mousepos_x = vid_conwidth;\r
 426         mousepos_y = vid_conheight;\r
 427         mousepos = mousepos*0.5 + getmousepos();\r
 428         */\r
 429 \r
 430         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);\r
 431 \r
 432         e = self;\r
 433         for(self = world; (self = nextent(self)); )\r
 434                 if(self.draw)\r
 435                         self.draw();\r
 436         self = e;\r
 437         R_RenderScene();\r
 438 \r
 439         // now switch to 2D drawing mode by calling a 2D drawing function\r
 440         // then polygon drawing will draw as 2D stuff, and NOT get queued until the\r
 441         // next R_RenderScene call\r
 442         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);\r
 443 \r
 444         // Draw the mouse cursor\r
 445         // NOTE: drawpic must happen after R_RenderScene for some reason\r
 446         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);\r
 447         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);\r
 448         //self = edict_num(player_localnum);\r
 449         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);\r
 450         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);\r
 451         // as long as the ctf part isn't in, this is useless\r
 452         if(menu_visible)\r
 453                 menu_show();\r
 454 \r
 455         /*if(gametype == GAME_CTF)\r
 456         {\r
 457                 ctf_view();\r
 458         } else */\r
 459 \r
 460         // draw 2D entities\r
 461         e = self;\r
 462         for(self = world; (self = nextent(self)); )\r
 463                 if(self.draw2d)\r
 464                         self.draw2d();\r
 465         self = e;\r
 466 \r
 467         // draw radar\r
 468         if(\r
 469                 ons_showmap\r
 470                 ||\r
 471                 (\r
 472                         !scoreboard_active\r
 473                         &&\r
 474                         cvar_string("cl_teamradar") != "0"\r
 475                         &&\r
 476                         (\r
 477                                 cvar("cl_teamradar") == 2\r
 478                                 ||\r
 479                                 teamplay\r
 480                         )\r
 481                 )\r
 482         )\r
 483                 teamradar_view();\r
 484 \r
 485         if (cvar("cl_showpressedkeys")) // draw pressed keys when spectating and playing\r
 486         {\r
 487                 if(spectatee_status > 0 || cvar("cl_showpressedkeys") >= 2)\r
 488                         Sbar_DrawPressedKeys();\r
 489         }\r
 490 \r
 491         // draw sbar\r
 492         if(cvar("r_letterbox") == 0) {\r
 493                 Sbar_DrawCenterPrint(); // draw centerprint messages even if viewsize >= 120\r
 494                 \r
 495                 if(cvar("viewsize") < 120)\r
 496                         CSQC_common_hud();\r
 497         }\r
 498 \r
 499         // crosshair goes VERY LAST\r
 500         if(!scoreboard_active && !ons_showmap && !camera_active) {\r
 501                 // TrueAim check\r
 502                 float goodshot;\r
 503 \r
 504                 if(cvar("crosshair_hittest"))\r
 505                         goodshot = TrueAimCheck();\r
 506                 else\r
 507                         goodshot = TRUE;\r
 508 \r
 509                 string wcross_style;\r
 510                 wcross_style = cvar_string("crosshair");\r
 511 \r
 512                 if (wcross_style != "0") {\r
 513                         vector wcross_color, wcross_size;\r
 514                         string wcross_wep, wcross_name;\r
 515                         float wcross_alpha, wcross_sizefloat;\r
 516 \r
 517                         wcross_color_x = cvar("crosshair_color_red");\r
 518                         wcross_color_y = cvar("crosshair_color_green");\r
 519                         wcross_color_z = cvar("crosshair_color_blue");\r
 520                         wcross_alpha = cvar("crosshair_color_alpha");\r
 521                         wcross_sizefloat = cvar("crosshair_size");\r
 522                         if (cvar("crosshair_per_weapon")) {\r
 523                                 e = get_weaponinfo(activeweapon);\r
 524                                 if (e && e.netname != "")\r
 525                                 {\r
 526                                         wcross_wep = e.netname;\r
 527                                         wcross_style = cvar_string(strcat("crosshair_", wcross_wep));\r
 528                                         if(wcross_style == "")\r
 529                                                 wcross_style = e.netname;\r
 530 \r
 531                                         if(!cvar("crosshair_color_override"))\r
 532                                         {\r
 533                                                 wcross_color_x = cvar(strcat("crosshair_", wcross_wep, "_color_red"));\r
 534                                                 wcross_color_y = cvar(strcat("crosshair_", wcross_wep, "_color_green"));\r
 535                                                 wcross_color_z = cvar(strcat("crosshair_", wcross_wep, "_color_blue"));\r
 536                                         }\r
 537 \r
 538                                         wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_color_alpha"));\r
 539                                         wcross_sizefloat *= cvar(strcat("crosshair_", wcross_wep, "_size"));\r
 540                                 }\r
 541                         }\r
 542 \r
 543                         wcross_name = strcat("gfx/crosshair", wcross_style);\r
 544 \r
 545                         wcross_size = drawgetimagesize(wcross_name);\r
 546                         wcross_size_x *= wcross_sizefloat;\r
 547                         wcross_size_y *= wcross_sizefloat;\r
 548 \r
 549                         if(goodshot)\r
 550                         {\r
 551                                 drawpic('0.5 0 0' * (vid_conwidth - wcross_size_x) + '0 0.5 0' * (vid_conheight - wcross_size_y), wcross_name, wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL);\r
 552                         }\r
 553                         else\r
 554                         {\r
 555                                 wcross_alpha *= 0.04 * 0.75;\r
 556                                 for(i = -2; i <= 2; ++i)\r
 557                                         for(j = -2; j <= 2; ++j)\r
 558                                                 drawpic('0.5 0 0' * (vid_conwidth - wcross_size_x + i) + '0 0.5 0' * (vid_conheight - wcross_size_y + j), wcross_name, wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL);\r
 559                         }\r
 560                 }\r
 561         }\r
 562 \r
 563         if(NextFrameCommand)\r
 564         {\r
 565                 localcmd("\n", NextFrameCommand, "\n");\r
 566                 NextFrameCommand = string_null;\r
 567         }\r
 568 }\r
 569 \r
 570 void Sbar_Draw();\r
 571 void CSQC_common_hud(void)\r
 572 {\r
 573         // Sbar_SortFrags(); done in Sbar_Draw\r
 574         Sbar_Draw();\r
 575 }\r
 576 \r
 577 // following vectors must be global to allow seamless switching between camera modes\r
 578 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;\r
 579 void CSQC_Demo_Camera()\r
 580 {\r
 581         float speed, attenuation, dimensions;\r
 582         vector tmp, delta;\r
 583 \r
 584         if( cvar("camera_reset") || !camera_mode )\r
 585         {\r
 586                 camera_offset = '0 0 0';\r
 587                 current_angles = '0 0 0';\r
 588                 camera_direction = '0 0 0';\r
 589                 camera_offset_z += 30;\r
 590                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);\r
 591                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);\r
 592                 current_origin = view_origin;\r
 593                 current_camera_offset  = camera_offset;\r
 594                 cvar_set("camera_reset", "0");\r
 595                 camera_mode = CAMERA_CHASE;\r
 596         }\r
 597 \r
 598         // Camera angles\r
 599         if( camera_roll )\r
 600                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");\r
 601 \r
 602         if(cvar("camera_look_player"))\r
 603         {\r
 604                 local vector dir;\r
 605                 local float n;\r
 606 \r
 607                 dir = normalize(view_origin - current_position);\r
 608                 n = mouse_angles_z;\r
 609                 mouse_angles = vectoangles(dir);\r
 610                 mouse_angles_x = mouse_angles_x * -1;\r
 611                 mouse_angles_z = n;\r
 612         }\r
 613         else\r
 614         {\r
 615                 tmp = getmousepos() * 0.1;\r
 616                 if(vlen(tmp)>cvar("camera_mouse_treshold"))\r
 617                 {\r
 618                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));\r
 619                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));\r
 620                 }\r
 621         }\r
 622 \r
 623         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;\r
 624         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;\r
 625         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;\r
 626         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;\r
 627 \r
 628         // Fix difference when angles don't have the same sign\r
 629         delta = '0 0 0';\r
 630         if(mouse_angles_y < -60 && current_angles_y > 60)\r
 631                 delta = '0 360 0';\r
 632         if(mouse_angles_y > 60 && current_angles_y < -60)\r
 633                 delta = '0 -360 0';\r
 634 \r
 635         if(cvar("camera_look_player"))\r
 636                 attenuation = cvar("camera_look_attenuation");\r
 637         else\r
 638                 attenuation = cvar("camera_speed_attenuation");\r
 639 \r
 640         attenuation = 1 / max(1, attenuation);\r
 641         current_angles += (mouse_angles - current_angles + delta) * attenuation;\r
 642 \r
 643         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;\r
 644         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;\r
 645         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;\r
 646         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;\r
 647 \r
 648         // Camera position\r
 649         tmp = '0 0 0';\r
 650         dimensions = 0;\r
 651 \r
 652         if( camera_direction_x )\r
 653         {\r
 654                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);\r
 655                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);\r
 656                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )\r
 657                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);\r
 658                 ++dimensions;\r
 659         }\r
 660 \r
 661         if( camera_direction_y )\r
 662         {\r
 663                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);\r
 664                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);\r
 665                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);\r
 666                 ++dimensions;\r
 667         }\r
 668 \r
 669         if( camera_direction_z )\r
 670         {\r
 671                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);\r
 672                 ++dimensions;\r
 673         }\r
 674 \r
 675         if(cvar("camera_free"))\r
 676                 speed = cvar("camera_speed_free");\r
 677         else\r
 678                 speed = cvar("camera_speed_chase");\r
 679 \r
 680         if(dimensions)\r
 681         {\r
 682                 speed = speed * sqrt(1 / dimensions);\r
 683                 camera_offset += tmp * speed;\r
 684         }\r
 685 \r
 686         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;\r
 687 \r
 688         // Camera modes\r
 689         if( cvar("camera_free") )\r
 690         {\r
 691                 if ( camera_mode == CAMERA_CHASE )\r
 692                 {\r
 693                         current_camera_offset = current_origin + current_camera_offset;\r
 694                         camera_offset = current_origin + camera_offset;\r
 695                 }\r
 696 \r
 697                 camera_mode = CAMERA_FREE;\r
 698                 current_position = current_camera_offset;\r
 699         }\r
 700         else\r
 701         {\r
 702                 if ( camera_mode == CAMERA_FREE )\r
 703                 {\r
 704                         current_origin = view_origin;\r
 705                         camera_offset = camera_offset - current_origin;\r
 706                         current_camera_offset = current_camera_offset - current_origin;\r
 707                 }\r
 708 \r
 709                 camera_mode = CAMERA_CHASE;\r
 710 \r
 711                 if(cvar("camera_chase_smoothly"))\r
 712                         current_origin += (view_origin - current_origin) * attenuation;\r
 713                 else\r
 714                         current_origin = view_origin;\r
 715 \r
 716                 current_position = current_origin + current_camera_offset;\r
 717         }\r
 718 \r
 719         R_SetView(VF_ANGLES, current_angles);\r
 720         R_SetView(VF_ORIGIN, current_position);\r
 721 }\r