data/qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------\r
   2 // BEGIN REQUIRED CSQC FUNCTIONS\r
   3 //include "main.qh"\r
   4 \r
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
   6 \r
   7 void cvar_clientsettemp(string cv, string val)\r
   8 {\r
   9         entity e;\r
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  11                 if(e.netname == cv)\r
  12                         goto saved;\r
  13         e = spawn();\r
  14         e.classname = "saved_cvar_value";\r
  15         e.netname = strzone(cv);\r
  16         e.message = strzone(cvar_string(cv));\r
  17 :saved\r
  18         cvar_set(cv, val);\r
  19 }\r
  20 \r
  21 void cvar_clientsettemp_restore()\r
  22 {\r
  23         entity e;\r
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  25                         cvar_set(e.netname, e.message);\r
  26 }\r
  27 \r
  28 void() menu_show_error =\r
  29 {\r
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);\r
  31 };\r
  32 \r
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)\r
  34 // Useful for precaching things\r
  35 \r
  36 void() menu_sub_null =\r
  37 {\r
  38 };\r
  39 \r
  40 #ifdef USE_FTE\r
  41 float __engine_check;\r
  42 #endif\r
  43 \r
  44 string forcefog;\r
  45 void WaypointSprite_Load();\r
  46 void CSQC_Init(void)\r
  47 {\r
  48 #ifdef USE_FTE\r
  49 #pragma target ID\r
  50         __engine_check = checkextension("DP_SV_WRITEPICTURE");\r
  51         if(!__engine_check)\r
  52         {\r
  53                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");\r
  54                 localcmd("\ndisconnect\n");\r
  55                 return;\r
  56         }\r
  57 #pragma target FTE\r
  58 #endif\r
  59         \r
  60         float i;\r
  61         CSQC_CheckEngine();\r
  62         dprint_load();\r
  63 \r
  64         binddb = db_create();\r
  65         tempdb = db_create();\r
  66         compressShortVector_init();\r
  67 \r
  68         drawfont = 0;\r
  69         menu_visible = FALSE;\r
  70         menu_show = menu_show_error;\r
  71         menu_action = menu_sub_null;\r
  72 \r
  73         for(i = 0; i < 255; ++i)\r
  74                 if(getplayerkey(i, "viewentity") == "")\r
  75                         break;\r
  76         maxclients = i;\r
  77 \r
  78         //ctf_temp_1 = "";\r
  79         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used\r
  80         //registercmd("ctf_menu");\r
  81         registercmd("ons_map");\r
  82         //registercmd("menu_action");\r
  83 \r
  84         registercmd("+button3");\r
  85         registercmd("-button3");\r
  86         registercmd("+button4");\r
  87         registercmd("-button4");\r
  88 \r
  89 #ifndef CAMERATEST\r
  90         if(isdemo())\r
  91         {\r
  92 #endif\r
  93                 registercmd("+forward");registercmd("-forward");\r
  94                 registercmd("+back");registercmd("-back");\r
  95                 registercmd("+moveup");registercmd("-moveup");\r
  96                 registercmd("+movedown");registercmd("-movedown");\r
  97                 registercmd("+moveright");registercmd("-moveright");\r
  98                 registercmd("+moveleft");registercmd("-moveleft");\r
  99                 registercmd("+roll_right");registercmd("-roll_right");\r
 100                 registercmd("+roll_left");registercmd("-roll_left");\r
 101 #ifndef CAMERATEST\r
 102         }\r
 103 #endif\r
 104         registercvar("sbar_usecsqc", "1");\r
 105         registercvar("sbar_columns", "default", CVAR_SAVE);\r
 106 \r
 107         gametype = 0;\r
 108 \r
 109         // sbar_fields uses strunzone on the titles!\r
 110         for(i = 0; i < MAX_SBAR_FIELDS; ++i)\r
 111                 sbar_title[i] = strzone("(null)");\r
 112 \r
 113         postinit = false;\r
 114 \r
 115         teams = Sort_Spawn();\r
 116         players = Sort_Spawn();\r
 117         \r
 118         GetTeam(COLOR_SPECTATOR, true); // add specs first\r
 119 \r
 120         cvar_clientsettemp("_supports_weaponpriority", "1");\r
 121 \r
 122 \r
 123 \r
 124 \r
 125         cs_project_is_b0rked = TRUE;\r
 126         R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');\r
 127         R_SetView(VF_FOV, '90 90 0');\r
 128         R_SetView(VF_ORIGIN, '0 0 0');\r
 129         R_SetView(VF_ANGLES, '0 0 0');\r
 130         R_SetView(VF_PERSPECTIVE, 1);\r
 131         makevectors('0 0 0');\r
 132         vector v;\r
 133         v = cs_project(v_forward);\r
 134         if(v_x - 320 < +1)\r
 135         if(v_x - 320 > -1)\r
 136         if(v_y - 240 < +1)\r
 137         if(v_y - 240 > -1)\r
 138                 cs_project_is_b0rked = FALSE;\r
 139 \r
 140         RegisterWeapons();\r
 141 \r
 142         WaypointSprite_Load();\r
 143 \r
 144         Projectile_Precache();\r
 145         GibSplash_Precache();\r
 146         Casings_Precache();\r
 147         DamageInfo_Precache();\r
 148 \r
 149         get_mi_min_max_texcoords(1); // try the CLEVER way first\r
 150         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");\r
 151         shortmapname = mi_shortname;\r
 152 \r
 153         if(precache_pic(minimapname) == "")\r
 154         {\r
 155                 // but maybe we have a non-clever minimap\r
 156                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");\r
 157                 if(precache_pic(minimapname) == "")\r
 158                         minimapname = ""; // FAIL\r
 159                 else\r
 160                         get_mi_min_max_texcoords(0); // load new texcoords\r
 161         }\r
 162 \r
 163         mi_center = (mi_min + mi_max) * 0.5;\r
 164         mi_scale = mi_max - mi_min;\r
 165         minimapname = strzone(minimapname);\r
 166 }\r
 167 \r
 168 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)\r
 169 void CSQC_Shutdown(void)\r
 170 {\r
 171 #ifdef USE_FTE\r
 172 #pragma TARGET id\r
 173         if(!__engine_check)\r
 174                 return 0;\r
 175 #pragma TARGET fte\r
 176 #endif\r
 177 \r
 178         remove(teams);\r
 179         remove(players);\r
 180         db_close(binddb);\r
 181         db_close(tempdb);\r
 182 \r
 183         cvar_clientsettemp_restore();\r
 184 \r
 185         if(camera_active)\r
 186                 cvar_set("chase_active",ftos(chase_active_backup));\r
 187 }\r
 188 \r
 189 .float has_team;\r
 190 float SetTeam(entity o, float Team)\r
 191 {\r
 192         entity tm;\r
 193         if(Team == -1) // leave\r
 194         {\r
 195                 if(o.has_team)\r
 196                 {\r
 197                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");\r
 198                         tm = GetTeam(o.team, false);\r
 199                         tm.team_size -= 1;\r
 200                         o.has_team = 0;\r
 201                         return TRUE;\r
 202                 }\r
 203         }\r
 204         else\r
 205         {\r
 206                 if not(o.has_team)\r
 207                 {\r
 208                         //print("(CONNECT) enter team ", ftos(o.team), "\n");\r
 209                         o.team = Team;\r
 210                         tm = GetTeam(Team, true);\r
 211                         tm.team_size += 1;\r
 212                         o.has_team = 1;\r
 213                         return TRUE;\r
 214                 }\r
 215                 else if(Team != o.team)\r
 216                 {\r
 217                         //print("(CHANGE) leave team ", ftos(o.team), "\n");\r
 218                         tm = GetTeam(o.team, false);\r
 219                         tm.team_size -= 1;\r
 220                         o.team = Team;\r
 221                         //print("(CHANGE) enter team ", ftos(o.team), "\n");\r
 222                         tm = GetTeam(Team, true);\r
 223                         tm.team_size += 1;\r
 224                         return TRUE;\r
 225                 }\r
 226         }\r
 227         return FALSE;\r
 228 }\r
 229 \r
 230 void Playerchecker_Think()\r
 231 {\r
 232         float i;\r
 233         entity e;\r
 234         for(i = 0; i < maxclients; ++i)\r
 235         {\r
 236                 e = playerslots[i];\r
 237                 if(GetPlayerName(i) == "")\r
 238                 {\r
 239                         if(e.sort_prev)\r
 240                         {\r
 241                                 //print("playerchecker: KILL KILL KILL\n");\r
 242                                 // player disconnected\r
 243                                 SetTeam(e, -1);\r
 244                                 RemovePlayer(e);\r
 245                                 e.sort_prev = world;\r
 246                                 //e.gotscores = 0;\r
 247                         }\r
 248                 }\r
 249                 else\r
 250                 {\r
 251                         if not(e.sort_prev)\r
 252                         {\r
 253                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");\r
 254                                 // player connected\r
 255                                 if not(e)\r
 256                                         playerslots[i] = e = spawn();\r
 257                                 e.sv_entnum = i;\r
 258                                 //e.gotscores = 0; // we might already have the scores...\r
 259                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with Sbar_UpdatePlayerTeams\r
 260                                 RegisterPlayer(e);\r
 261                                 Sbar_UpdatePlayerPos(e);\r
 262                         }\r
 263                 }\r
 264         }\r
 265         self.nextthink = time + 0.2;\r
 266 }\r
 267 \r
 268 void Porto_Init();\r
 269 void PostInit(void)\r
 270 {\r
 271         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));\r
 272         localcmd(strcat("\nsbar_columns_set ", cvar_string("sbar_columns"), ";\n"));\r
 273 \r
 274         entity playerchecker;\r
 275         playerchecker = spawn();\r
 276         playerchecker.think = Playerchecker_Think;\r
 277         playerchecker.nextthink = time + 0.2;\r
 278 \r
 279         Porto_Init();\r
 280 \r
 281         postinit = true;\r
 282 }\r
 283 \r
 284 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function\r
 285 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.\r
 286 float button_zoom;\r
 287 void Cmd_Sbar_SetFields(float);\r
 288 void Cmd_Sbar_Help(float);\r
 289 float CSQC_ConsoleCommand(string strMessage)\r
 290 {\r
 291         float argc;\r
 292         // Tokenize String\r
 293         //argc = tokenize(strMessage);\r
 294         argc = tokenize_sane(strMessage);\r
 295         \r
 296         // Acquire Command\r
 297         local string strCmd;\r
 298         strCmd = argv(0);\r
 299 \r
 300         if(strCmd == "+button4") { // zoom\r
 301                 // return false, because the message shall be sent to the server anyway (for demos/speccing)\r
 302                 if(ignore_plus_zoom)\r
 303                 {\r
 304                         --ignore_plus_zoom;\r
 305                         return false;\r
 306                 }\r
 307                 button_zoom = 1;\r
 308                 return true;\r
 309         } else if(strCmd == "-button4") { // zoom\r
 310                 if(ignore_minus_zoom)\r
 311                 {\r
 312                         --ignore_minus_zoom;\r
 313                         return false;\r
 314                 }\r
 315                 button_zoom = 0;\r
 316                 return true;\r
 317         } else if(strCmd == "+button3") { // secondary\r
 318                 button_attack2 = 1;\r
 319                 return false;\r
 320         } else if(strCmd == "-button3") { // secondary\r
 321                 button_attack2 = 0;\r
 322                 return false;\r
 323         } else if(strCmd == "+showscores") {\r
 324                 sb_showscores = true;\r
 325                 return true;\r
 326         } else if(strCmd == "-showscores") {\r
 327                 sb_showscores = false;\r
 328                 return true;\r
 329         }\r
 330 \r
 331         if(camera_active)\r
 332         if(strCmd == "+forward" || strCmd == "-back") {\r
 333                 ++camera_direction_x;\r
 334                 return true;\r
 335         } else if(strCmd == "-forward" || strCmd == "+back") {\r
 336                 --camera_direction_x;\r
 337                 return true;\r
 338         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {\r
 339                 --camera_direction_y;\r
 340                 return true;\r
 341         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {\r
 342                 ++camera_direction_y;\r
 343                 return true;\r
 344         } else if(strCmd == "+moveup" || strCmd == "-movedown") {\r
 345                 ++camera_direction_z;\r
 346                 return true;\r
 347         } else if(strCmd == "-moveup" || strCmd == "+movedown") {\r
 348                 --camera_direction_z;\r
 349                 return true;\r
 350         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {\r
 351                 ++camera_roll;\r
 352                 return true;\r
 353         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {\r
 354                 --camera_roll;\r
 355                 return true;\r
 356         }\r
 357 \r
 358         return false;\r
 359 }\r
 360 \r
 361 .vector view_ofs;\r
 362 entity debug_shotorg;\r
 363 void ShotOrg_Draw()\r
 364 {\r
 365         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;\r
 366         self.angles = view_angles;\r
 367         self.angles_x = -self.angles_x;\r
 368         if not(self.cnt)\r
 369                 R_AddEntity(self);\r
 370 }\r
 371 void ShotOrg_Draw2D()\r
 372 {\r
 373         vector coord2d_topleft, coord2d_topright, coord2d;\r
 374         string s;\r
 375         vector fs;\r
 376 \r
 377         s = vtos(self.view_ofs);\r
 378         s = substring(s, 1, strlen(s) - 2);\r
 379         if(tokenize_sane(s) == 3)\r
 380                 s = strcat(argv(0), " ", argv(1), " ", argv(2));\r
 381 \r
 382         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);\r
 383         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);\r
 384 \r
 385         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE));\r
 386 \r
 387         coord2d = coord2d_topleft - '0 1 0' * fs_y;\r
 388         coord2d_z = 0;\r
 389         drawstring(coord2d, s, fs, '1 1 1', 1, 0);\r
 390 }\r
 391 \r
 392 void ShotOrg_Spawn()\r
 393 {\r
 394         debug_shotorg = spawn();\r
 395         debug_shotorg.draw = ShotOrg_Draw;\r
 396         debug_shotorg.draw2d = ShotOrg_Draw2D;\r
 397         debug_shotorg.renderflags = RF_VIEWMODEL;\r
 398         debug_shotorg.effects = EF_FULLBRIGHT;\r
 399         precache_model("models/shotorg_adjuster.md3");\r
 400         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");\r
 401         debug_shotorg.scale = 2;\r
 402         debug_shotorg.view_ofs = '25 8 -8';\r
 403 }\r
 404 \r
 405 void GameCommand(string msg)\r
 406 {\r
 407         float argc;\r
 408         argc = tokenize_sane(msg);\r
 409 \r
 410         if(argv(0) == "help" || argc == 0)\r
 411         {\r
 412                 print("Usage: sv_cmd COMMAND..., where possible commands are:\n");\r
 413                 print("  settemp cvar value\n");\r
 414                 print("  radar\n");\r
 415                 print("  sbar_columns_set ...\n");\r
 416                 print("  sbar_columns_help\n");\r
 417                 GameCommand_Generic("help");\r
 418         }\r
 419 \r
 420         if(GameCommand_Generic(msg))\r
 421                 return;\r
 422 \r
 423         string cmd;\r
 424         cmd = argv(0);\r
 425         if(cmd == "mv_download") {\r
 426                 Cmd_MapVote_MapDownload(argc);\r
 427         }\r
 428         else if(cmd == "settemp") {\r
 429                 cvar_clientsettemp(argv(1), argv(2));\r
 430         }\r
 431         else if(cmd == "radar") {\r
 432                 ons_showmap = !ons_showmap;\r
 433         }\r
 434         else if(cmd == "sbar_columns_set") {\r
 435                 Cmd_Sbar_SetFields(argc);\r
 436         }\r
 437         else if(cmd == "sbar_columns_help") {\r
 438                 Cmd_Sbar_Help(argc);\r
 439         }\r
 440 #ifdef BLURTEST\r
 441         else if(cmd == "blurtest") {\r
 442                 blurtest_time0 = time;\r
 443                 blurtest_time1 = time + stof(argv(1));\r
 444                 blurtest_radius = stof(argv(2));\r
 445                 blurtest_power = stof(argv(3));\r
 446         }\r
 447 #endif\r
 448         else if(cmd == "shotorg_move") {\r
 449                 if(!debug_shotorg)\r
 450                         ShotOrg_Spawn();\r
 451                 else\r
 452                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));\r
 453                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");\r
 454         }\r
 455         else if(cmd == "shotorg_movez") {\r
 456                 if(!debug_shotorg)\r
 457                         ShotOrg_Spawn();\r
 458                 else\r
 459                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos\r
 460                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");\r
 461         }\r
 462         else if(cmd == "shotorg_set") {\r
 463                 if(!debug_shotorg)\r
 464                         ShotOrg_Spawn();\r
 465                 else\r
 466                         debug_shotorg.view_ofs = stov(argv(1));\r
 467                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");\r
 468         }\r
 469         else if(cmd == "shotorg_setz") {\r
 470                 if(!debug_shotorg)\r
 471                         ShotOrg_Spawn();\r
 472                 else\r
 473                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos\r
 474                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");\r
 475         }\r
 476         else if(cmd == "shotorg_toggle_hide") {\r
 477                 if(debug_shotorg)\r
 478                 {\r
 479                         debug_shotorg.cnt = !debug_shotorg.cnt;\r
 480                 }\r
 481         }\r
 482         else if(cmd == "shotorg_end") {\r
 483                 if(debug_shotorg)\r
 484                 {\r
 485                         print(vtos(debug_shotorg.view_ofs), "\n");\r
 486                         remove(debug_shotorg);\r
 487                         debug_shotorg = world;\r
 488                 }\r
 489                 localcmd("sv_cmd debug_shotorg\n");\r
 490         }\r
 491         else\r
 492         {\r
 493                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");\r
 494         }\r
 495         \r
 496         return;\r
 497 }\r
 498 \r
 499 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.\r
 500 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.\r
 501 // All keys are in ascii.\r
 502 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.\r
 503 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.\r
 504 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.\r
 505 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)\r
 506 {\r
 507         local float bSkipKey;\r
 508         bSkipKey = false;\r
 509         \r
 510         if(menu_visible)\r
 511                 if(menu_action(bInputType, nPrimary, nSecondary))\r
 512                         return TRUE;\r
 513         return bSkipKey;\r
 514 }\r
 515 \r
 516 // END REQUIRED CSQC FUNCTIONS\r
 517 // --------------------------------------------------------------------------\r
 518 \r
 519 // --------------------------------------------------------------------------\r
 520 // BEGIN OPTIONAL CSQC FUNCTIONS\r
 521 void Ent_ReadEntCS()\r
 522 {\r
 523         InterpolateOrigin_Undo();\r
 524 \r
 525         self.classname = "entcs_receiver";\r
 526         self.sv_entnum = ReadByte() - 1;\r
 527         self.origin_x = ReadShort();\r
 528         self.origin_y = ReadShort();\r
 529         self.origin_z = ReadShort();\r
 530         self.angles_y = ReadByte() * 360.0 / 256;\r
 531         self.origin_z = self.angles_x = self.angles_z = 0;\r
 532 \r
 533         InterpolateOrigin_Note();\r
 534 }\r
 535 \r
 536 void Ent_Remove();\r
 537 \r
 538 void Ent_RemovePlayerScore()\r
 539 {\r
 540         float i;\r
 541 \r
 542         if(self.owner)\r
 543         {\r
 544                 SetTeam(self.owner, -1);\r
 545                 self.owner.gotscores = 0;\r
 546                 for(i = 0; i < MAX_SCORE; ++i)\r
 547                         self.owner.(scores[i]) = 0; // clear all scores\r
 548         }\r
 549 }\r
 550 \r
 551 void Ent_ReadPlayerScore()\r
 552 {\r
 553         float i, n;\r
 554         float isNew;\r
 555         entity o;\r
 556 \r
 557         // damnit -.- don't want to go change every single .sv_entnum in sbar.qc AGAIN\r
 558         // (no I've never heard of M-x replace-string, sed, or anything like that)\r
 559         isNew = !self.owner; // workaround for DP bug\r
 560         n = ReadByte()-1;\r
 561 \r
 562 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 563         if(!isNew && n != self.sv_entnum)\r
 564         {\r
 565                 print("A CSQC entity changed its owner!\n");\r
 566                 isNew = true;\r
 567                 Ent_Remove();\r
 568                 self.enttype = ENT_CLIENT_SCORES;\r
 569         }\r
 570 #endif\r
 571 \r
 572         self.sv_entnum = n;\r
 573 \r
 574         if not(playerslots[self.sv_entnum])\r
 575                 playerslots[self.sv_entnum] = spawn();\r
 576         o = self.owner = playerslots[self.sv_entnum];\r
 577         o.sv_entnum = self.sv_entnum;\r
 578         o.gotscores = 1;\r
 579 \r
 580         //if not(o.sort_prev)\r
 581         //      RegisterPlayer(o);\r
 582         //playerchecker will do this for us later, if it has not already done so\r
 583 \r
 584 #if MAX_SCORE <= 3\r
 585         for(i = 0; i < MAX_SCORE; ++i)\r
 586                 o.(scores[i]) = ReadShort();\r
 587 #else\r
 588         float sf;\r
 589 #if MAX_SCORE <= 8\r
 590         sf = ReadByte();\r
 591 #else\r
 592         sf = ReadShort();\r
 593 #endif\r
 594         float p;\r
 595         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)\r
 596                 if(sf & p)\r
 597                         o.(scores[i]) = ReadShort();\r
 598 #endif\r
 599 \r
 600         if(o.sort_prev)\r
 601                 Sbar_UpdatePlayerPos(o); // if not registered, we cannot do this yet!\r
 602         \r
 603         self.entremove = Ent_RemovePlayerScore;\r
 604 }\r
 605 \r
 606 void Ent_ReadTeamScore()\r
 607 {\r
 608         float i;\r
 609         entity o;\r
 610         \r
 611         self.team = ReadByte();\r
 612         o = self.owner = GetTeam(self.team, true);\r
 613 \r
 614 #if MAX_TEAMSCORE <= 3\r
 615         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 616                 o.(teamscores[i]) = ReadShort();\r
 617 #else\r
 618         float sf;\r
 619 #if MAX_TEAMSCORE <= 8\r
 620         sf = ReadByte();\r
 621 #else\r
 622         sf = ReadShort();\r
 623 #endif\r
 624         float p;\r
 625         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)\r
 626                 if(sf & p)\r
 627                         o.(teamscores[i]) = ReadShort();\r
 628 #endif\r
 629 \r
 630         Sbar_UpdateTeamPos(o);\r
 631 }\r
 632 \r
 633 void Net_Reset()\r
 634 {\r
 635 }\r
 636 \r
 637 void Ent_ClientData()\r
 638 {\r
 639         float f;\r
 640         float newspectatee_status;\r
 641 \r
 642         f = ReadByte();\r
 643 \r
 644         sb_showscores_force = (f & 1);\r
 645 \r
 646         if(f & 2)\r
 647         {\r
 648                 newspectatee_status = ReadByte();\r
 649                 if(newspectatee_status == player_localentnum)\r
 650                         newspectatee_status = -1; // observing\r
 651         }\r
 652         else\r
 653                 newspectatee_status = 0;\r
 654 \r
 655         spectatorbutton_zoom = (f & 4);\r
 656 \r
 657         if(f & 8)\r
 658         {\r
 659                 angles_held_status = 1;\r
 660                 angles_held_x = ReadAngle();\r
 661                 angles_held_y = ReadAngle();\r
 662                 angles_held_z = 0;\r
 663         }\r
 664         else\r
 665                 angles_held_status = 0;\r
 666         \r
 667         if(newspectatee_status != spectatee_status)\r
 668         {\r
 669                 // clear race stuff\r
 670                 race_laptime = 0;\r
 671                 race_checkpointtime = 0;\r
 672         }\r
 673         spectatee_status = newspectatee_status;\r
 674 }\r
 675 \r
 676 void Ent_Nagger()\r
 677 {\r
 678         float nags, i, j, b, f;\r
 679 \r
 680         nags = ReadByte();\r
 681 \r
 682         if(nags & 128)\r
 683         {\r
 684                 if(vote_called_vote)\r
 685                         strunzone(vote_called_vote);\r
 686                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));\r
 687         }\r
 688 \r
 689         if(nags & 1)\r
 690         {\r
 691                 for(j = 0; j < maxclients; ++j)\r
 692                         if(playerslots[j])\r
 693                                 playerslots[j].ready = 1;\r
 694                 for(i = 1; i <= maxclients; i += 8)\r
 695                 {\r
 696                         f = ReadByte();\r
 697                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)\r
 698                                 if not(f & b)\r
 699                                         if(playerslots[j])\r
 700                                                 playerslots[j].ready = 0;\r
 701                 }\r
 702         }\r
 703 \r
 704         ready_waiting = (nags & 1);\r
 705         ready_waiting_for_me = (nags & 2);\r
 706         vote_waiting = (nags & 4);\r
 707         vote_waiting_for_me = (nags & 8);\r
 708         warmup_stage = (nags & 16);\r
 709 }\r
 710 \r
 711 void Ent_RandomSeed()\r
 712 {\r
 713         float s;\r
 714         prandom_debug();\r
 715         s = ReadShort();\r
 716         psrandom(s);\r
 717 }\r
 718 \r
 719 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.\r
 720 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.\r
 721 void Ent_RadarLink();\r
 722 void Ent_Init();\r
 723 void Ent_ScoresInfo();\r
 724 void(float bIsNewEntity) CSQC_Ent_Update =\r
 725 {\r
 726         float t;\r
 727         float savetime;\r
 728         t = ReadByte();\r
 729 \r
 730         // set up the "time" global for received entities to be correct for interpolation purposes\r
 731         savetime = time;\r
 732         if(servertime)\r
 733         {\r
 734                 time = servertime;\r
 735         }\r
 736         else\r
 737         {\r
 738                 serverprevtime = time;\r
 739                 serverdeltatime = getstatf(STAT_SYS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);\r
 740                 time = serverprevtime + serverdeltatime;\r
 741         }\r
 742 \r
 743 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 744         if(self.enttype)\r
 745                 if(t != self.enttype)\r
 746                 {\r
 747                         print("A CSQC entity changed its type!\n");\r
 748                         Ent_Remove();\r
 749                 }\r
 750 #endif\r
 751         self.enttype = t;\r
 752         switch(t)\r
 753         {\r
 754                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;\r
 755                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;\r
 756                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;\r
 757                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;\r
 758                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;\r
 759                 case ENT_CLIENT_LASER: Ent_Laser(); break;\r
 760                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;\r
 761                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;\r
 762                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;\r
 763                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;\r
 764                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(); break;\r
 765                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(); break;\r
 766                 case ENT_CLIENT_CASING: Ent_Casing(); break;\r
 767                 case ENT_CLIENT_INIT: Ent_Init(); break;\r
 768                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;\r
 769                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;\r
 770                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;\r
 771                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;\r
 772                 default:\r
 773                         error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));\r
 774                         break;\r
 775         }\r
 776         \r
 777         time = savetime;\r
 778 };\r
 779 // Destructor, but does NOT deallocate the entity by calling remove(). Also\r
 780 // used when an entity changes its type. For an entity that someone interacts\r
 781 // with others, make sure it can no longer do so.\r
 782 void Ent_Remove()\r
 783 {\r
 784         if(self.entremove)\r
 785                 self.entremove();\r
 786 \r
 787         self.enttype = 0;\r
 788         self.classname = "";\r
 789         self.draw = menu_sub_null;\r
 790         self.entremove = menu_sub_null;\r
 791         // TODO possibly set more stuff to defaults\r
 792 }\r
 793 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.\r
 794 void CSQC_Ent_Remove()\r
 795 {\r
 796         if(self.enttype)\r
 797                 Ent_Remove();\r
 798         remove(self);\r
 799 }\r
 800 \r
 801 void Gamemode_Init()\r
 802 {\r
 803         if(gametype == GAME_ONSLAUGHT) {\r
 804                 print(strcat("Using ", minimapname, " as minimap.\n"));\r
 805                 precache_pic("gfx/ons-cp-neutral.tga");\r
 806                 precache_pic("gfx/ons-cp-red.tga");\r
 807                 precache_pic("gfx/ons-cp-blue.tga");\r
 808                 precache_pic("gfx/ons-frame.tga");\r
 809                 precache_pic("gfx/ons-frame-team.tga");\r
 810         } else if(gametype == GAME_KEYHUNT) {\r
 811                 precache_pic("gfx/sb_key_carrying");\r
 812                 precache_pic("gfx/sb_key_carrying_outline");\r
 813         }\r
 814 }\r
 815 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.\r
 816 void CSQC_Parse_StuffCmd(string strMessage)\r
 817 {\r
 818         localcmd(strMessage);\r
 819 }\r
 820 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.\r
 821 void CSQC_Parse_Print(string strMessage)\r
 822 {\r
 823         print(ColorTranslateRGB(strMessage));\r
 824 }\r
 825 \r
 826 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.  \r
 827 void CSQC_Parse_CenterPrint(string strMessage)\r
 828 {\r
 829         centerprint(strMessage);\r
 830 }\r
 831 \r
 832 void CSQC_CheckRevision();\r
 833 \r
 834 void Fog_Force()\r
 835 {\r
 836         // TODO somehow thwart prvm_globalset client ...\r
 837 \r
 838         if(forcefog != "")\r
 839                 localcmd(strcat("\nfog ", forcefog, "\nr_fog_exp2 0\nr_drawfog 1\n"));\r
 840 }\r
 841 \r
 842 void Gamemode_Init();\r
 843 void Ent_ScoresInfo()\r
 844 {\r
 845         float i;\r
 846         self.classname = "ent_client_scores_info";\r
 847         gametype = ReadByte();\r
 848         for(i = 0; i < MAX_SCORE; ++i)\r
 849         {\r
 850                 scores_label[i] = strzone(ReadString());\r
 851                 scores_flags[i] = ReadByte();\r
 852         }\r
 853         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 854         {\r
 855                 teamscores_label[i] = strzone(ReadString());\r
 856                 teamscores_flags[i] = ReadByte();\r
 857         }\r
 858         Sbar_InitScores();\r
 859         Gamemode_Init();\r
 860 }\r
 861 \r
 862 void Ent_Init()\r
 863 {\r
 864         float i;\r
 865         self.classname = "ent_client_init";\r
 866 \r
 867         csqc_revision = ReadShort();\r
 868 \r
 869         for(i = 0; i < 24; ++i)\r
 870                 weaponimpulse[i] = ReadByte() - 1;\r
 871         hook_shotorigin_x = ReadCoord();\r
 872         hook_shotorigin_y = ReadCoord();\r
 873         hook_shotorigin_z = ReadCoord();\r
 874 \r
 875         if(forcefog)\r
 876                 strunzone(forcefog);\r
 877         forcefog = strzone(ReadString());\r
 878 \r
 879         CSQC_CheckRevision();\r
 880         if(!postinit)\r
 881                 PostInit();\r
 882 }\r
 883 \r
 884 string Net_ReadPicture()\r
 885 {\r
 886         string img;\r
 887         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
 888         {\r
 889                 img = ReadPicture();\r
 890                 print(strcat("Got Picture: ", img, "\n"));\r
 891         } else {\r
 892                 img = ReadString();\r
 893                 print(strcat("^3Warning: ^7Couldn't download ", img, ". This is probably because your engine build is outdated.\n"));\r
 894                 float psize, i;\r
 895                 psize = ReadShort();\r
 896                 // Can I be sure that ReadShort is 2 bytes and ReadLong is 4 bytes?\r
 897                 // Because then this could be optimized to first get all 4-byte-groups,\r
 898                 // then the remaining 2, then the remaining 1\r
 899                 for(i = 0; i < psize; ++i)\r
 900                         ReadByte();\r
 901         }\r
 902         return img;\r
 903 }\r
 904 \r
 905 void Net_ReadRace()\r
 906 {\r
 907         float b;\r
 908 \r
 909         b = ReadByte();\r
 910 \r
 911         switch(b)\r
 912         {\r
 913                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:\r
 914                         race_checkpoint = ReadByte();\r
 915                         race_time = ReadShort();\r
 916                         race_previousbesttime = ReadShort();\r
 917                         if(race_previousbestname)\r
 918                                 strunzone(race_previousbestname);\r
 919                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));\r
 920 \r
 921                         race_checkpointtime = time;\r
 922 \r
 923                         if(race_checkpoint == 0)\r
 924                                 race_laptime = time; // valid\r
 925 \r
 926                         break;\r
 927 \r
 928                 case RACE_NET_CHECKPOINT_CLEAR:\r
 929                         race_laptime = 0;\r
 930                         race_checkpointtime = 0;\r
 931                         break;\r
 932 \r
 933                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:\r
 934                         race_laptime = ReadCoord();\r
 935                         race_checkpointtime = -99999;\r
 936                         // fall through\r
 937                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:\r
 938                         race_nextcheckpoint = ReadByte();\r
 939 \r
 940                         race_nextbesttime = ReadShort();\r
 941                         if(race_nextbestname)\r
 942                                 strunzone(race_nextbestname);\r
 943                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));\r
 944                         break;\r
 945 \r
 946                 case RACE_NET_CHECKPOINT_HIT_RACE:\r
 947                         race_mycheckpoint = ReadByte();\r
 948                         race_mycheckpointtime = time;\r
 949                         race_mycheckpointdelta = ReadShort();\r
 950                         race_mycheckpointlapsdelta = ReadByte();\r
 951                         if(race_mycheckpointlapsdelta >= 128)\r
 952                                 race_mycheckpointlapsdelta -= 256;\r
 953                         if(race_mycheckpointenemy)\r
 954                                 strunzone(race_mycheckpointenemy);\r
 955                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));\r
 956                         break;\r
 957 \r
 958                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:\r
 959                         race_othercheckpoint = ReadByte();\r
 960                         race_othercheckpointtime = time;\r
 961                         race_othercheckpointdelta = ReadShort();\r
 962                         race_othercheckpointlapsdelta = ReadByte();\r
 963                         if(race_othercheckpointlapsdelta >= 128)\r
 964                                 race_othercheckpointlapsdelta -= 256;\r
 965                         if(race_othercheckpointenemy)\r
 966                                 strunzone(race_othercheckpointenemy);\r
 967                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));\r
 968                         break;\r
 969         }\r
 970 }\r
 971 \r
 972 void Net_ReadSpawn()\r
 973 {\r
 974         zoomin_effect = 1;\r
 975         current_viewzoom = 0.6;\r
 976 }\r
 977 \r
 978 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.\r
 979 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.\r
 980 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.\r
 981 float CSQC_Parse_TempEntity()\r
 982 {\r
 983         local float bHandled;\r
 984                 bHandled  = true;\r
 985         // Acquire TE ID\r
 986         local float nTEID;\r
 987                 nTEID = ReadByte();\r
 988 \r
 989                 // NOTE: Could just do return instead of break...\r
 990         switch(nTEID)\r
 991         {\r
 992                 case TE_CSQC_PICTURE:\r
 993                         Net_MapVote_Picture();\r
 994                         bHandled = true;\r
 995                         break;\r
 996                 case TE_CSQC_RACE:\r
 997                         Net_ReadRace();\r
 998                         bHandled = true;\r
 999                         break;\r
1000                 case 13: // TE_BEAM\r
1001                         Net_GrapplingHook();\r
1002                         bHandled = true;\r
1003                         break;\r
1004                 case TE_CSQC_SPAWN:\r
1005                         Net_ReadSpawn();\r
1006                         bHandled = true;\r
1007                         break;\r
1008                 case TE_CSQC_ZCURVEPARTICLES:\r
1009                         Net_ReadZCurveParticles();\r
1010                         bHandled = true;\r
1011                         break;\r
1012                 case TE_CSQC_NEXGUNBEAMPARTICLE:\r
1013                         Net_ReadNexgunBeamParticle();\r
1014                         bHandled = true;\r
1015                         break;\r
1016                 default:\r
1017                         // No special logic for this temporary entity; return 0 so the engine can handle it\r
1018                         bHandled = false;\r
1019                         break;\r
1020         }\r
1021                 \r
1022         return bHandled;\r
1023 }\r
1024 \r
1025 // COMMIT-TODO: Update if necessare, before committing\r
1026 void CSQC_CheckRevision()\r
1027 {\r
1028         if(csqc_revision == CSQC_REVISION)\r
1029         {\r
1030                 print("^2SVQC and CSQC revisions are compatible.\n");\r
1031         } else if(csqc_revision < CSQC_REVISION) {\r
1032                 print("^1Your csprogs.dat (CSQC) version is newer than the one on the server.\n");\r
1033         } else if(csqc_revision > CSQC_REVISION) {\r
1034                 print("^1Your csprogs.dat (CSQC) is too old for this server.\n");\r
1035                 print("^1Please update to a newer version.\n");\r
1036         }\r
1037 }\r
1038 \r
1039 string getcommandkey(string text, string command)\r
1040 {\r
1041         string keys;\r
1042         float n, j, k, l;\r
1043 \r
1044         if (!sbar_showbinds)\r
1045                 return text;\r
1046 \r
1047         keys = db_get(binddb, command);\r
1048         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
1049         {\r
1050                 if (!keys) \r
1051                 {\r
1052                         n = tokenize_insane(findkeysforcommand(command)); // uses '...' strings\r
1053                         for(j = 0; j < n; ++j)\r
1054                         {\r
1055                                 k = stof(argv(j));\r
1056                                 if(k != -1) \r
1057                                 {\r
1058                                         if ("" == keys)\r
1059                                                 keys = keynumtostring(k);\r
1060                                         else\r
1061                                                 keys = strcat(keys, ", ", keynumtostring(k));\r
1062 \r
1063                                         ++l;\r
1064                                         if (sbar_showbinds_limit > 0 && sbar_showbinds_limit >= l) break;\r
1065                                 }\r
1066                         \r
1067                         }\r
1068                         db_put(binddb, command, keys);\r
1069                 }\r
1070         }\r
1071         \r
1072         if ("" == keys) {\r
1073                 if (sbar_showbinds > 1)\r
1074                         return strcat(text, " (not bound)");\r
1075                 else\r
1076                         return text;\r
1077         }\r
1078         else if (sbar_showbinds > 1)\r
1079                 return strcat(text, " (", keys, ")");\r
1080         else\r
1081                 return keys;\r
1082 }\r