data/qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------\r
   2 // BEGIN REQUIRED CSQC FUNCTIONS\r
   3 //include "main.qh"\r
   4 \r
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
   6 \r
   7 void cvar_clientsettemp(string cv, string val)\r
   8 {\r
   9         entity e;\r
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  11                 if(e.netname == cv)\r
  12                         goto saved;\r
  13         e = spawn();\r
  14         e.classname = "saved_cvar_value";\r
  15         e.netname = strzone(cv);\r
  16         e.message = strzone(cvar_string(cv));\r
  17 :saved\r
  18         cvar_set(cv, val);\r
  19 }\r
  20 \r
  21 void cvar_clientsettemp_restore()\r
  22 {\r
  23         entity e;\r
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
  25                         cvar_set(e.netname, e.message);\r
  26 }\r
  27 \r
  28 void() menu_show_error =\r
  29 {\r
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);\r
  31 };\r
  32 \r
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)\r
  34 // Useful for precaching things\r
  35 \r
  36 void() menu_sub_null =\r
  37 {\r
  38 };\r
  39 \r
  40 #ifdef USE_FTE\r
  41 float __engine_check;\r
  42 #endif\r
  43 \r
  44 string config_get(string key, string defaultvalue)\r
  45 {\r
  46         string s;\r
  47         s = db_get(configdb, strcat("/s/", key));\r
  48         if(s == "")\r
  49                 return defaultvalue;\r
  50         else\r
  51                 return db_get(configdb, strcat("/v/", key));\r
  52 }\r
  53 \r
  54 string forcefog;\r
  55 void WaypointSprite_Load();\r
  56 void CSQC_Init(void)\r
  57 {\r
  58 #ifdef USE_FTE\r
  59 #pragma target ID\r
  60         __engine_check = checkextension("DP_SV_WRITEPICTURE");\r
  61         if(!__engine_check)\r
  62         {\r
  63                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");\r
  64                 localcmd("\ndisconnect\n");\r
  65                 return;\r
  66         }\r
  67 #pragma target FTE\r
  68 #endif\r
  69         \r
  70         float i;\r
  71         CSQC_CheckEngine();\r
  72         dprint_load();\r
  73 \r
  74         configdb = db_create();\r
  75         binddb = db_create();\r
  76         tempdb = db_create();\r
  77         compressShortVector_init();\r
  78 \r
  79         drawfont = 0;\r
  80         menu_visible = FALSE;\r
  81         menu_show = menu_show_error;\r
  82         menu_action = menu_sub_null;\r
  83         maxclients = 255; // we later get the real maxclients to speed up stuff\r
  84         //ctf_temp_1 = "";\r
  85         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used\r
  86         //registercmd("ctf_menu");\r
  87         registercmd("ons_map");\r
  88         //registercmd("menu_action");\r
  89         registercmd("sbar_columns_set");\r
  90         registercmd("sbar_columns_help");\r
  91 \r
  92         registercmd("+button3");\r
  93         registercmd("-button3");\r
  94         registercmd("+button4");\r
  95         registercmd("-button4");\r
  96 \r
  97         registercvar("sbar_usecsqc", "1");\r
  98         registercvar("sbar_columns", "default", CVAR_SAVE);\r
  99 \r
 100         gametype = 0;\r
 101 \r
 102         // sbar_fields uses strunzone on the titles!\r
 103         for(i = 0; i < MAX_SBAR_FIELDS; ++i)\r
 104                 sbar_title[i] = strzone("(null)");\r
 105 \r
 106         postinit = false;\r
 107 \r
 108         teams = Sort_Spawn();\r
 109         players = Sort_Spawn();\r
 110         \r
 111         GetTeam(COLOR_SPECTATOR, true); // add specs first\r
 112 \r
 113         cvar_clientsettemp("_supports_weaponpriority", "1");\r
 114 \r
 115 \r
 116 \r
 117 \r
 118         cs_project_is_b0rked = TRUE;\r
 119         R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');\r
 120         R_SetView(VF_FOV, '90 90 0');\r
 121         R_SetView(VF_ORIGIN, '0 0 0');\r
 122         R_SetView(VF_ANGLES, '0 0 0');\r
 123         R_SetView(VF_PERSPECTIVE, 1);\r
 124         makevectors('0 0 0');\r
 125         vector v;\r
 126         v = cs_project(v_forward);\r
 127         if(v_x - 320 < +1)\r
 128         if(v_x - 320 > -1)\r
 129         if(v_y - 240 < +1)\r
 130         if(v_y - 240 > -1)\r
 131                 cs_project_is_b0rked = FALSE;\r
 132 \r
 133         WaypointSprite_Load();\r
 134 }\r
 135 \r
 136 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)\r
 137 void CSQC_Shutdown(void)\r
 138 {\r
 139 #ifdef USE_FTE\r
 140 #pragma TARGET id\r
 141         if(!__engine_check)\r
 142                 return 0;\r
 143 #pragma TARGET fte\r
 144 #endif\r
 145 \r
 146         remove(teams);\r
 147         remove(players);\r
 148         db_close(configdb);\r
 149         db_close(binddb);\r
 150         db_close(tempdb);\r
 151 \r
 152         cvar_clientsettemp_restore();\r
 153 }\r
 154 \r
 155 .float has_team;\r
 156 float SetTeam(entity o, float Team)\r
 157 {\r
 158         entity tm;\r
 159         if(Team == -1) // leave\r
 160         {\r
 161                 if(o.has_team)\r
 162                 {\r
 163                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");\r
 164                         tm = GetTeam(o.team, false);\r
 165                         tm.team_size -= 1;\r
 166                         o.has_team = 0;\r
 167                         return TRUE;\r
 168                 }\r
 169         }\r
 170         else\r
 171         {\r
 172                 if not(o.has_team)\r
 173                 {\r
 174                         //print("(CONNECT) enter team ", ftos(o.team), "\n");\r
 175                         o.team = Team;\r
 176                         tm = GetTeam(Team, true);\r
 177                         tm.team_size += 1;\r
 178                         o.has_team = 1;\r
 179                         return TRUE;\r
 180                 }\r
 181                 else if(Team != o.team)\r
 182                 {\r
 183                         //print("(CHANGE) leave team ", ftos(o.team), "\n");\r
 184                         tm = GetTeam(o.team, false);\r
 185                         tm.team_size -= 1;\r
 186                         o.team = Team;\r
 187                         //print("(CHANGE) enter team ", ftos(o.team), "\n");\r
 188                         tm = GetTeam(Team, true);\r
 189                         tm.team_size += 1;\r
 190                         return TRUE;\r
 191                 }\r
 192         }\r
 193         return FALSE;\r
 194 }\r
 195 \r
 196 void Playerchecker_Think()\r
 197 {\r
 198         float i;\r
 199         entity e;\r
 200         for(i = 0; i < maxclients; ++i)\r
 201         {\r
 202                 e = playerslots[i];\r
 203                 if(getplayerkey(i, "name") == "")\r
 204                 {\r
 205                         if(e.sort_prev)\r
 206                         {\r
 207                                 //print("playerchecker: KILL KILL KILL\n");\r
 208                                 // player disconnected\r
 209                                 SetTeam(e, -1);\r
 210                                 RemovePlayer(e);\r
 211                                 e.sort_prev = world;\r
 212                                 //e.gotscores = 0;\r
 213                         }\r
 214                 }\r
 215                 else\r
 216                 {\r
 217                         if not(e.sort_prev)\r
 218                         {\r
 219                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");\r
 220                                 // player connected\r
 221                                 if not(e)\r
 222                                         playerslots[i] = e = spawn();\r
 223                                 e.sv_entnum = i;\r
 224                                 //e.gotscores = 0; // we might already have the scores...\r
 225                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with Sbar_UpdatePlayerTeams\r
 226                                 RegisterPlayer(e);\r
 227                                 Sbar_UpdatePlayerPos(e);\r
 228                         }\r
 229                 }\r
 230         }\r
 231         self.nextthink = time + 0.2;\r
 232 }\r
 233 \r
 234 void Porto_Init();\r
 235 void PostInit(void)\r
 236 {\r
 237         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));\r
 238         localcmd(strcat("\nsbar_columns_set ", cvar_string("sbar_columns"), ";\n"));\r
 239 \r
 240         entity playerchecker;\r
 241         playerchecker = spawn();\r
 242         playerchecker.think = Playerchecker_Think;\r
 243         playerchecker.nextthink = time + 0.2;\r
 244 \r
 245         Porto_Init();\r
 246 \r
 247         postinit = true;\r
 248 }\r
 249 \r
 250 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function\r
 251 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.\r
 252 float button_zoom;\r
 253 void Cmd_Sbar_SetFields(float);\r
 254 void Cmd_Sbar_Help(float);\r
 255 float CSQC_ConsoleCommand(string strMessage)\r
 256 {\r
 257         float argc;\r
 258         // Tokenize String\r
 259         //argc = tokenize(strMessage);\r
 260         argc = tokenize_sane(strMessage);\r
 261         \r
 262         // Acquire Command\r
 263         local string strCmd;\r
 264         strCmd = argv(0);\r
 265 \r
 266         if(strCmd == "+button4") { // zoom\r
 267                 // return false, because the message shall be sent to the server anyway (for demos/speccing)\r
 268                 if(ignore_plus_zoom)\r
 269                 {\r
 270                         --ignore_plus_zoom;\r
 271                         return false;\r
 272                 }\r
 273                 button_zoom = 1;\r
 274                 return true;\r
 275         } else if(strCmd == "-button4") { // zoom\r
 276                 if(ignore_minus_zoom)\r
 277                 {\r
 278                         --ignore_minus_zoom;\r
 279                         return false;\r
 280                 }\r
 281                 button_zoom = 0;\r
 282                 return true;\r
 283         } else if(strCmd == "+button3") { // secondary\r
 284                 button_attack2 = 1;\r
 285                 return false;\r
 286         } else if(strCmd == "-button3") { // secondary\r
 287                 button_attack2 = 0;\r
 288                 return false;\r
 289         } else if(strCmd == "ons_map") {\r
 290                 ons_showmap = !ons_showmap;\r
 291                 return true;\r
 292         } else if(strCmd == "sbar_columns_set") {\r
 293                 Cmd_Sbar_SetFields(argc);\r
 294                 return true;\r
 295         } else if(strCmd == "sbar_columns_help") {\r
 296                 Cmd_Sbar_Help(argc);\r
 297                 return true;\r
 298         } else if(strCmd == "+showscores") {\r
 299                 sb_showscores = true;\r
 300                 return true;\r
 301         } else if(strCmd == "-showscores") {\r
 302                 sb_showscores = false;\r
 303                 return true;\r
 304         }\r
 305         \r
 306         return false;\r
 307 }\r
 308 \r
 309 float GameCommand(string msg)\r
 310 {\r
 311         float argc;\r
 312         argc = tokenize_sane(msg);\r
 313         string cmd;\r
 314         cmd = argv(0);\r
 315         if(cmd == "mv_download") {\r
 316                 Cmd_MapVote_MapDownload(argc);\r
 317                 return true;\r
 318         }\r
 319         else if(cmd == "settemp") {\r
 320                 cvar_clientsettemp(argv(1), argv(2));\r
 321         }\r
 322         \r
 323         return false;\r
 324 }\r
 325 \r
 326 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.\r
 327 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.\r
 328 // All keys are in ascii.\r
 329 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.\r
 330 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.\r
 331 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.\r
 332 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)\r
 333 {\r
 334         local float bSkipKey;\r
 335         bSkipKey = false;\r
 336         \r
 337         if(menu_visible)\r
 338                 if(menu_action(bInputType, nPrimary, nSecondary))\r
 339                         return TRUE;\r
 340         return bSkipKey;\r
 341 }\r
 342 \r
 343 // END REQUIRED CSQC FUNCTIONS\r
 344 // --------------------------------------------------------------------------\r
 345 \r
 346 // --------------------------------------------------------------------------\r
 347 // BEGIN OPTIONAL CSQC FUNCTIONS\r
 348 void Ent_ReadEntCS()\r
 349 {\r
 350         InterpolateOrigin_Undo();\r
 351 \r
 352         self.classname = "entcs_receiver";\r
 353         self.sv_entnum = ReadByte() - 1;\r
 354         self.origin_x = ReadShort();\r
 355         self.origin_y = ReadShort();\r
 356         self.origin_z = ReadShort();\r
 357         self.angles_y = ReadByte() * 360.0 / 256;\r
 358         self.origin_z = self.angles_x = self.angles_z = 0;\r
 359 \r
 360         InterpolateOrigin_Note();\r
 361 }\r
 362 \r
 363 void Ent_RemoveEntCS()\r
 364 {\r
 365 }\r
 366 \r
 367 void Ent_Remove();\r
 368 void Ent_ReadPlayerScore()\r
 369 {\r
 370         float i, n;\r
 371         float isNew;\r
 372         entity o;\r
 373 \r
 374         // damnit -.- don't want to go change every single .sv_entnum in sbar.qc AGAIN\r
 375         // (no I've never heard of M-x replace-string, sed, or anything like that)\r
 376         isNew = !self.owner; // workaround for DP bug\r
 377         n = ReadByte()-1;\r
 378 \r
 379 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 380         if(!isNew && n != self.sv_entnum)\r
 381         {\r
 382                 print("A CSQC entity changed its owner!\n");\r
 383                 isNew = true;\r
 384                 Ent_Remove();\r
 385                 self.enttype = ENT_CLIENT_SCORES;\r
 386         }\r
 387 #endif\r
 388 \r
 389         self.sv_entnum = n;\r
 390 \r
 391         if not(playerslots[self.sv_entnum])\r
 392                 playerslots[self.sv_entnum] = spawn();\r
 393         o = self.owner = playerslots[self.sv_entnum];\r
 394         o.sv_entnum = self.sv_entnum;\r
 395         o.gotscores = 1;\r
 396 \r
 397         //if not(o.sort_prev)\r
 398         //      RegisterPlayer(o);\r
 399         //playerchecker will do this for us later, if it has not already done so\r
 400 \r
 401 #if MAX_SCORE <= 3\r
 402         for(i = 0; i < MAX_SCORE; ++i)\r
 403                 o.(scores[i]) = ReadShort();\r
 404 #else\r
 405         float sf;\r
 406 #if MAX_SCORE <= 8\r
 407         sf = ReadByte();\r
 408 #else\r
 409         sf = ReadShort();\r
 410 #endif\r
 411         float p;\r
 412         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)\r
 413                 if(sf & p)\r
 414                         o.(scores[i]) = ReadShort();\r
 415 #endif\r
 416 \r
 417         if(o.sort_prev)\r
 418                 Sbar_UpdatePlayerPos(o); // if not registered, we cannot do this yet!\r
 419 }\r
 420 \r
 421 void Ent_ReadTeamScore()\r
 422 {\r
 423         float i;\r
 424         entity o;\r
 425         \r
 426         self.team = ReadByte();\r
 427         o = self.owner = GetTeam(self.team, true);\r
 428 \r
 429 #if MAX_TEAMSCORE <= 3\r
 430         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 431                 o.(teamscores[i]) = ReadShort();\r
 432 #else\r
 433         float sf;\r
 434 #if MAX_TEAMSCORE <= 8\r
 435         sf = ReadByte();\r
 436 #else\r
 437         sf = ReadShort();\r
 438 #endif\r
 439         float p;\r
 440         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)\r
 441                 if(sf & p)\r
 442                         o.(teamscores[i]) = ReadShort();\r
 443 #endif\r
 444 \r
 445         Sbar_UpdateTeamPos(o);\r
 446 }\r
 447 \r
 448 void Ent_Nagger()\r
 449 {\r
 450         float nags;\r
 451 \r
 452         nags = ReadByte();\r
 453 \r
 454         if(nags & 128)\r
 455         {\r
 456                 if(vote_called_vote)\r
 457                         strunzone(vote_called_vote);\r
 458                 vote_called_vote = strzone(ReadString());\r
 459         }\r
 460 \r
 461         ready_waiting = (nags & 1);\r
 462         ready_waiting_for_me = (nags & 2);\r
 463         vote_waiting = (nags & 4);\r
 464         vote_waiting_for_me = (nags & 8);\r
 465 }\r
 466 \r
 467 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.\r
 468 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.\r
 469 void Ent_RadarLink();\r
 470 void(float bIsNewEntity) CSQC_Ent_Update =\r
 471 {\r
 472         float t;\r
 473         t = ReadByte();\r
 474 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 475         if(self.enttype)\r
 476                 if(t != self.enttype)\r
 477                 {\r
 478                         print("A CSQC entity changed its type!\n");\r
 479                         Ent_Remove();\r
 480                 }\r
 481 #endif\r
 482         self.enttype = t;\r
 483         if(self.enttype == ENT_CLIENT_ENTCS)\r
 484                 Ent_ReadEntCS();\r
 485         else if(self.enttype == ENT_CLIENT_SCORES)\r
 486                 Ent_ReadPlayerScore();\r
 487         else if(self.enttype == ENT_CLIENT_TEAMSCORES)\r
 488                 Ent_ReadTeamScore();\r
 489         else if(self.enttype == ENT_CLIENT_POINTPARTICLES)\r
 490                 Ent_PointParticles();\r
 491         else if(self.enttype == ENT_CLIENT_RAINSNOW)\r
 492                 Ent_RainOrSnow();\r
 493         else if(self.enttype == ENT_CLIENT_LASER)\r
 494                 Ent_Laser();\r
 495         else if(self.enttype == ENT_CLIENT_NAGGER)\r
 496                 Ent_Nagger();\r
 497         else if(self.enttype == ENT_CLIENT_WAYPOINT)\r
 498                 Ent_WaypointSprite();\r
 499         else if(self.enttype == ENT_CLIENT_RADARLINK)\r
 500                 Ent_RadarLink();\r
 501         else\r
 502                 error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));\r
 503         \r
 504 };\r
 505 // Destructor, but does NOT deallocate the entity by calling remove(). Also\r
 506 // used when an entity changes its type. For an entity that someone interacts\r
 507 // with others, make sure it can no longer do so.\r
 508 void Ent_Remove()\r
 509 {\r
 510         float i;\r
 511         if(self.enttype == ENT_CLIENT_ENTCS)\r
 512         {\r
 513                 Ent_RemoveEntCS();\r
 514         } else if(self.enttype == ENT_CLIENT_SCORES)\r
 515         {\r
 516                 if(self.owner)\r
 517                 {\r
 518                         SetTeam(self.owner, -1);\r
 519                         self.owner.gotscores = 0;\r
 520                         for(i = 0; i < MAX_SCORE; ++i)\r
 521                                 self.owner.(scores[i]) = 0; // clear all scores\r
 522                 }\r
 523         } else if(self.enttype == ENT_CLIENT_TEAMSCORES)\r
 524         {\r
 525                 /*\r
 526                 if(self.owner)\r
 527                         RemoveTeam(self.owner);\r
 528                 */\r
 529                 // we don't NEED to remove them... they won't display anyway\r
 530                 // plus, svqc never does this anyway\r
 531         } else if(self.enttype == ENT_CLIENT_POINTPARTICLES)\r
 532         {\r
 533                 Ent_PointParticles_Remove();\r
 534         }\r
 535         else if(self.enttype == ENT_CLIENT_WAYPOINT)\r
 536                 Ent_RemoveWaypointSprite();\r
 537 \r
 538         self.enttype = 0;\r
 539         self.classname = "";\r
 540         self.draw = menu_sub_null;\r
 541         // TODO possibly set more stuff to defaults\r
 542 }\r
 543 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.\r
 544 void CSQC_Ent_Remove()\r
 545 {\r
 546         if(self.enttype)\r
 547                 Ent_Remove();\r
 548         remove(self);\r
 549 }\r
 550 \r
 551 void Gamemode_Init()\r
 552 {\r
 553         get_mi_min_max_texcoords(1); // try the CLEVER way first\r
 554         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");\r
 555         shortmapname = mi_shortname;\r
 556 \r
 557         if(precache_pic(minimapname) == "")\r
 558         {\r
 559                 // but maybe we have a non-clever minimap\r
 560                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");\r
 561                 if(precache_pic(minimapname) == "")\r
 562                         minimapname = ""; // FAIL\r
 563                 else\r
 564                         get_mi_min_max_texcoords(0); // load new texcoords\r
 565         }\r
 566 \r
 567         mi_center = (mi_min + mi_max) * 0.5;\r
 568         mi_scale = mi_max - mi_min;\r
 569         minimapname = strzone(minimapname);\r
 570 \r
 571         if(gametype == GAME_ONSLAUGHT) {\r
 572                 print(strcat("Using ", minimapname, " as minimap.\n"));\r
 573                 precache_pic("gfx/ons-cp-neutral.tga");\r
 574                 precache_pic("gfx/ons-cp-red.tga");\r
 575                 precache_pic("gfx/ons-cp-blue.tga");\r
 576                 precache_pic("gfx/ons-frame.tga");\r
 577                 precache_pic("gfx/ons-frame-team.tga");\r
 578         } else if(gametype == GAME_KEYHUNT) {\r
 579                 precache_pic("gfx/sb_key_carrying");\r
 580                 precache_pic("gfx/sb_key_carrying_outline");\r
 581         }\r
 582 }\r
 583 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.\r
 584 void CSQC_Parse_StuffCmd(string strMessage)\r
 585 {\r
 586         localcmd(strMessage);\r
 587 }\r
 588 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.\r
 589 void CSQC_Parse_Print(string strMessage)\r
 590 {\r
 591         print(strMessage);\r
 592 }\r
 593 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.  To execute standard behavior, simply execute cprint with the string.\r
 594 void CSQC_Parse_CenterPrint(string strMessage)\r
 595 {\r
 596         cprint(strMessage);\r
 597 }\r
 598 \r
 599 void CSQC_CheckRevision();\r
 600 \r
 601 void Fog_Force()\r
 602 {\r
 603         // TODO somehow thwart prvm_globalset client ...\r
 604 \r
 605         if(forcefog != "")\r
 606                 localcmd(strcat("\nfog ", forcefog, "\nr_fog_exp2 0\nr_drawfog 1\n"));\r
 607 }\r
 608 \r
 609 void Net_ReadFog()\r
 610 {\r
 611         if(forcefog)\r
 612                 strunzone(forcefog);\r
 613         ReadCoord(); // ignore fog interval\r
 614         forcefog = strzone(ReadString());\r
 615 }\r
 616 \r
 617 void Gamemode_Init();\r
 618 void Net_ReadScoresInfo()\r
 619 {\r
 620         float i;\r
 621         gametype = ReadByte();\r
 622         for(i = 0; i < MAX_SCORE; ++i)\r
 623         {\r
 624                 scores_label[i] = strzone(ReadString());\r
 625                 scores_flags[i] = ReadByte();\r
 626         }\r
 627         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 628         {\r
 629                 teamscores_label[i] = strzone(ReadString());\r
 630                 teamscores_flags[i] = ReadByte();\r
 631         }\r
 632         Sbar_InitScores();\r
 633         Gamemode_Init();\r
 634 }\r
 635 \r
 636 void Net_ReadInit()\r
 637 {\r
 638         float i;\r
 639         csqc_revision = ReadShort();\r
 640         maxclients = ReadByte();\r
 641         for(i = 0; i < 24; ++i)\r
 642                 weaponimpulse[i] = ReadByte() - 1;\r
 643         hook_shotorigin_x = ReadCoord();\r
 644         hook_shotorigin_y = ReadCoord();\r
 645         hook_shotorigin_z = ReadCoord();\r
 646         CSQC_CheckRevision();\r
 647 }\r
 648 \r
 649 string Net_ReadPicture()\r
 650 {\r
 651         string img;\r
 652         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
 653         {\r
 654                 img = ReadPicture();\r
 655                 print(strcat("Got Picture: ", img, "\n"));\r
 656         } else {\r
 657                 img = ReadString();\r
 658                 print(strcat("^3Warning: ^7Couldn't download ", img, ". This is probably because your engine build is outdated.\n"));\r
 659                 float psize, i;\r
 660                 psize = ReadShort();\r
 661                 // Can I be sure that ReadShort is 2 bytes and ReadLong is 4 bytes?\r
 662                 // Because then this could be optimized to first get all 4-byte-groups,\r
 663                 // then the remaining 2, then the remaining 1\r
 664                 for(i = 0; i < psize; ++i)\r
 665                         ReadByte();\r
 666         }\r
 667         return img;\r
 668 }\r
 669 \r
 670 void Net_Config()\r
 671 {\r
 672         string key, value;\r
 673         key = ReadString();\r
 674         value = ReadString();\r
 675         db_put(configdb, strcat("/v/", key), value);\r
 676         db_put(configdb, strcat("/s/", key), "1");\r
 677 }\r
 678 \r
 679 void Net_ReadRace()\r
 680 {\r
 681         float b;\r
 682 \r
 683         b = ReadByte();\r
 684 \r
 685         switch(b)\r
 686         {\r
 687                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:\r
 688                         race_checkpoint = ReadByte();\r
 689                         race_time = ReadShort();\r
 690                         race_previousbesttime = ReadShort();\r
 691                         if(race_previousbestname)\r
 692                                 strunzone(race_previousbestname);\r
 693                         race_previousbestname = strzone(ReadString());\r
 694 \r
 695                         race_checkpointtime = time;\r
 696 \r
 697                         if(race_checkpoint == 0)\r
 698                                 race_laptime = time; // valid\r
 699 \r
 700                         break;\r
 701 \r
 702                 case RACE_NET_CHECKPOINT_CLEAR:\r
 703                         race_laptime = 0;\r
 704                         race_checkpointtime = 0;\r
 705                         break;\r
 706 \r
 707                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:\r
 708                         race_laptime = ReadCoord();\r
 709                         race_checkpointtime = -99999;\r
 710                         // fall through\r
 711                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:\r
 712                         race_nextcheckpoint = ReadByte();\r
 713 \r
 714                         race_nextbesttime = ReadShort();\r
 715                         if(race_nextbestname)\r
 716                                 strunzone(race_nextbestname);\r
 717                         race_nextbestname = strzone(ReadString());\r
 718                         break;\r
 719 \r
 720                 case RACE_NET_CHECKPOINT_HIT_RACE:\r
 721                         race_mycheckpoint = ReadByte();\r
 722                         race_mycheckpointtime = time;\r
 723                         race_mycheckpointdelta = ReadShort();\r
 724                         race_mycheckpointlapsdelta = ReadByte();\r
 725                         if(race_mycheckpointlapsdelta >= 128)\r
 726                                 race_mycheckpointlapsdelta -= 256;\r
 727                         if(race_mycheckpointenemy)\r
 728                                 strunzone(race_mycheckpointenemy);\r
 729                         race_mycheckpointenemy = strzone(ReadString());\r
 730                         break;\r
 731 \r
 732                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:\r
 733                         race_othercheckpoint = ReadByte();\r
 734                         race_othercheckpointtime = time;\r
 735                         race_othercheckpointdelta = ReadShort();\r
 736                         race_othercheckpointlapsdelta = ReadByte();\r
 737                         if(race_othercheckpointlapsdelta >= 128)\r
 738                                 race_othercheckpointlapsdelta -= 256;\r
 739                         if(race_othercheckpointenemy)\r
 740                                 strunzone(race_othercheckpointenemy);\r
 741                         race_othercheckpointenemy = strzone(ReadString());\r
 742                         break;\r
 743         }\r
 744 }\r
 745 \r
 746 void Net_ReadForceScoreboard()\r
 747 {\r
 748         sb_showscores_force = ReadByte();\r
 749 }\r
 750 \r
 751 void Net_Reset()\r
 752 {\r
 753         float i;\r
 754         race_laptime = 0;\r
 755         race_checkpointtime = 0;\r
 756         for(i = 0; i < 24; ++i)\r
 757                 angles_held_status[i] = 0;\r
 758 }\r
 759 \r
 760 void Net_ReadSpectating()\r
 761 {\r
 762         float newspectatee_status;\r
 763         newspectatee_status = ReadByte();\r
 764         if(newspectatee_status == player_localentnum)\r
 765                 newspectatee_status = -1; // observing\r
 766         if(newspectatee_status != spectatee_status)\r
 767                 Net_Reset();\r
 768         spectatee_status = newspectatee_status;\r
 769 }\r
 770 \r
 771 void Net_ReadZoomNotify()\r
 772 {\r
 773         spectatorbutton_zoom = ReadByte();\r
 774 }\r
 775 \r
 776 void Net_ReadSpawn()\r
 777 {\r
 778         zoomin_effect = 1;\r
 779         current_viewzoom = 0.6;\r
 780 }\r
 781 \r
 782 void Net_ReadWarmupStage()\r
 783 {\r
 784         warmup_stage = ReadByte();\r
 785 }\r
 786 \r
 787 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.\r
 788 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.\r
 789 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.\r
 790 void Net_ReadHoldAngles();\r
 791 float CSQC_Parse_TempEntity()\r
 792 {\r
 793         local float bHandled;\r
 794                 bHandled  = true;\r
 795         // Acquire TE ID\r
 796         local float nTEID;\r
 797                 nTEID = ReadByte();\r
 798 \r
 799                 // NOTE: Could just do return instead of break...\r
 800         switch(nTEID)\r
 801         {\r
 802                 case TE_CSQC_INIT:\r
 803                         Net_ReadInit();\r
 804                         bHandled = true;\r
 805                         break;\r
 806                 case TE_CSQC_MAPVOTE:\r
 807                         Net_Mapvote();\r
 808                         bHandled = true;\r
 809                         break;\r
 810                 case TE_CSQC_CONFIG:\r
 811                         Net_Config();\r
 812                         bHandled = true;\r
 813                         break;\r
 814                 case TE_CSQC_SCORESINFO:\r
 815                         Net_ReadScoresInfo();\r
 816                         bHandled = true;\r
 817                         break;\r
 818                 case TE_CSQC_RACE:\r
 819                         Net_ReadRace();\r
 820                         bHandled = true;\r
 821                         break;\r
 822                 case TE_CSQC_FORCESCOREBOARD:\r
 823                         Net_ReadForceScoreboard();\r
 824                         bHandled = true;\r
 825                         break;\r
 826                 case TE_CSQC_SPECTATING:\r
 827                         Net_ReadSpectating();\r
 828                         bHandled = true;\r
 829                         break;\r
 830                 case 13: // TE_BEAM\r
 831                         Net_GrapplingHook();\r
 832                         bHandled = true;\r
 833                         break;\r
 834                 case TE_CSQC_SPAWN:\r
 835                         Net_ReadSpawn();\r
 836                         bHandled = true;\r
 837                         break;\r
 838                 case TE_CSQC_ZOOMNOTIFY:\r
 839                         Net_ReadZoomNotify();\r
 840                         bHandled = true;\r
 841                         break;\r
 842                 case TE_CSQC_HOLDANGLES:\r
 843                         Net_ReadHoldAngles();\r
 844                         bHandled = true;\r
 845                         break;\r
 846                 case TE_CSQC_WARMUP:\r
 847                         Net_ReadWarmupStage();\r
 848                         bHandled = true;\r
 849                         break;\r
 850                 case TE_CSQC_FOG:\r
 851                         Net_ReadFog();\r
 852                         bHandled = true;\r
 853                         break;\r
 854                 default:\r
 855                         // No special logic for this temporary entity; return 0 so the engine can handle it\r
 856                         bHandled = false;\r
 857                         break;\r
 858         }\r
 859         \r
 860         if(!postinit)\r
 861                 PostInit();\r
 862                 \r
 863         return bHandled;\r
 864 }\r
 865 \r
 866 // COMMIT-TODO: Update if necessare, before committing\r
 867 void CSQC_CheckRevision()\r
 868 {\r
 869         if(csqc_revision == CSQC_REVISION)\r
 870         {\r
 871                 print("^2SVQC and CSQC revisions are compatible.\n");\r
 872         } else if(csqc_revision < CSQC_REVISION) {\r
 873                 print("^1Your csprogs.dat (CSQC) version is newer than the one on the server.\n");\r
 874         } else if(csqc_revision > CSQC_REVISION) {\r
 875                 print("^1Your csprogs.dat (CSQC) is too old for this server.\n");\r
 876                 print("^1Please update to a newer version.\n");\r
 877         }\r
 878 }\r
 879 \r
 880 string getcommandkey(string text, string command)\r
 881 {\r
 882         string keys;\r
 883         float n, j, k, l;\r
 884 \r
 885         if (!sbar_showbinds)\r
 886                 return text;\r
 887 \r
 888         keys = db_get(binddb, command);\r
 889         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
 890         {\r
 891                 if (!keys) \r
 892                 {\r
 893                         n = tokenize_insane(findkeysforcommand(command)); // uses '...' strings\r
 894                         for(j = 0; j < n; ++j)\r
 895                         {\r
 896                                 k = stof(argv(j));\r
 897                                 if(k != -1) \r
 898                                 {\r
 899                                         if ("" == keys)\r
 900                                                 keys = keynumtostring(k);\r
 901                                         else\r
 902                                                 keys = strcat(keys, ", ", keynumtostring(k));\r
 903 \r
 904                                         ++l;\r
 905                                         if (sbar_showbinds_limit > 0 && sbar_showbinds_limit >= l) break;\r
 906                                 }\r
 907                         \r
 908                         }\r
 909                         db_put(binddb, command, keys);\r
 910                 }\r
 911         }\r
 912         \r
 913         if ("" == keys) {\r
 914                 if (sbar_showbinds > 1)\r
 915                         return strcat(text, " (not bound)");\r
 916                 else\r
 917                         return text;\r
 918         }\r
 919         else if (sbar_showbinds > 1)\r
 920                 return strcat(text, " (", keys, ")");\r
 921         else\r
 922                 return keys;\r
 923 }\r